Merge branch 'master' into terencehill/string_prefixes_cleanup
[xonotic/xonotic-data.pk3dir.git] / qcsrc / menu / xonotic / weaponslist.qc
1 #ifdef INTERFACE
2 CLASS(XonoticWeaponsList) EXTENDS(XonoticListBox)
3         METHOD(XonoticWeaponsList, configureXonoticWeaponsList, void(entity))
4         METHOD(XonoticWeaponsList, toString, string(entity))
5         ATTRIB(XonoticWeaponsList, rowsPerItem, float, 1)
6         METHOD(XonoticWeaponsList, draw, void(entity))
7         METHOD(XonoticWeaponsList, drawListBoxItem, void(entity, float, vector, float))
8         METHOD(XonoticWeaponsList, resizeNotify, void(entity, vector, vector, vector, vector))
9         METHOD(XonoticWeaponsList, keyDown, float(entity, float, float, float))
10         ATTRIB(XonoticWeaponsList, realFontSize, vector, '0 0 0')
11         ATTRIB(XonoticWeaponsList, realUpperMargin, float, 0)
12         METHOD(XonoticWeaponsList, mouseDrag, float(entity, vector))
13 ENDCLASS(XonoticWeaponsList)
14 entity makeXonoticWeaponsList();
15 void WeaponsList_MoveUp_Click(entity btn, entity me);
16 void WeaponsList_MoveDown_Click(entity box, entity me);
17 #endif
18
19 #ifdef IMPLEMENTATION
20 entity makeXonoticWeaponsList()
21 {
22         entity me;
23         me = spawnXonoticWeaponsList();
24         me.configureXonoticWeaponsList(me);
25         return me;
26 }
27 void XonoticWeaponsList_configureXonoticWeaponsList(entity me)
28 {
29         me.configureXonoticListBox(me);
30 }
31 void XonoticWeaponsList_draw(entity me)
32 {
33         // read in cvar?
34         string s, t;
35         s = W_NumberWeaponOrder(cvar_string("cl_weaponpriority"));
36         t = W_FixWeaponOrder(s, 1);
37         if(t != s)
38                 cvar_set("cl_weaponpriority", W_NameWeaponOrder(t));
39         me.nItems = tokenize_console(t);
40         SUPER(XonoticWeaponsList).draw(me);
41 }
42 void WeaponsList_MoveUp_Click(entity box, entity me)
43 {
44         if(me.selectedItem > 0)
45         {
46                 cvar_set("cl_weaponpriority", swapInPriorityList(cvar_string("cl_weaponpriority"), me.selectedItem - 1, me.selectedItem));
47                 me.selectedItem -= 1;
48         }
49 }
50 void WeaponsList_MoveDown_Click(entity box, entity me)
51 {
52         if(me.selectedItem < me.nItems - 1)
53         {
54                 cvar_set("cl_weaponpriority", swapInPriorityList(cvar_string("cl_weaponpriority"), me.selectedItem, me.selectedItem + 1));
55                 me.selectedItem += 1;
56         }
57 }
58 void XonoticWeaponsList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
59 {
60         SUPER(XonoticWeaponsList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
61
62         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
63         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
64         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
65 }
66 float XonoticWeaponsList_mouseDrag(entity me, vector pos)
67 {
68         float f, i;
69         i = me.selectedItem;
70         f = SUPER(XonoticWeaponsList).mouseDrag(me, pos);
71
72         if(me.pressed != 1) // don't change priority if the person is just scrolling
73         {
74                 if(me.selectedItem != i)
75                         cvar_set("cl_weaponpriority", swapInPriorityList(cvar_string("cl_weaponpriority"), me.selectedItem, i));
76         }
77
78         return f;
79 }
80 string XonoticWeaponsList_toString(entity me)
81 {
82         float n, i;
83         string s;
84         entity e;
85         n = tokenize_console(W_NumberWeaponOrder(cvar_string("cl_weaponpriority")));
86         s = "";
87         for(i = 0; i < n; ++i)
88         {
89                 e = get_weaponinfo(stof(argv(i)));
90                 s = strcat(s, e.message, ", ");
91         }
92         return substring(s, 0, strlen(s) - 2);
93 }
94 void XonoticWeaponsList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
95 {
96         entity e;
97         if(isSelected)
98                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
99         e = get_weaponinfo(stof(argv(i)));
100         string msg = e.message;
101         if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
102                 msg = sprintf(_("%s (mutator weapon)"), msg);
103
104         vector save_fontscale = draw_fontscale;
105         float f = draw_CondensedFontFactor(msg, false, me.realFontSize, 1);
106         draw_fontscale.x *= f;
107         vector fs = me.realFontSize;
108         fs.x *= f;
109         draw_Text(me.realUpperMargin * eY, msg, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
110         draw_fontscale = save_fontscale;
111 }
112
113 float XonoticWeaponsList_keyDown(entity me, float scan, float ascii, float shift)
114 {
115         if(ascii == 43) // +
116         {
117                 WeaponsList_MoveUp_Click(NULL, me);
118                 return 1;
119         }
120         else if(ascii == 45) // -
121         {
122                 WeaponsList_MoveDown_Click(NULL, me);
123                 return 1;
124         }
125         else if(SUPER(XonoticWeaponsList).keyDown(me, scan, ascii, shift))
126                 return 1;
127         return 0;
128 }
129 #endif