qcsrc/server/anticheat.qc

   1 #include "anticheat.qh"
   2
   3 #include "antilag.qh"
   4 #include "autocvars.qh"
   5 #include "defs.qh"
   6 #include "miscfunctions.qh"
   7
   8 #include "../dpdefs/progsdefs.qh"
   9 #include "../dpdefs/dpextensions.qh"
  10
  11 #include "../warpzonelib/mathlib.qh"
  12
  13 #include "command/common.qh"
  14
  15 .float anticheat_jointime;
  16
  17 void mean_accumulate(entity e, .float a, .float c, float mean, float value, float weight)
  18 {
  19         if (weight == 0)
  20                 return;
  21         if (mean == 0)
  22                 e.(a) *= pow(value, weight);
  23         else
  24                 e.(a) += pow(value, mean) * weight;
  25         e.(c) += weight;
  26 }
  27
  28 float mean_evaluate(entity e, .float a, .float c, float mean)
  29 {
  30         if (e.(c) == 0)
  31                 return 0;
  32         if (mean == 0)
  33                 return pow(e.(a), 1.0 / e.(c));
  34         else
  35                 return pow(e.(a) / e.(c), 1.0 / mean);
  36 }
  37
  38 #define MEAN_ACCUMULATE(prefix,v,w) mean_accumulate(self,prefix##_accumulator,prefix##_count,prefix##_mean,v,w)
  39 #define MEAN_EVALUATE(prefix) mean_evaluate(self,prefix##_accumulator,prefix##_count,prefix##_mean)
  40 #define MEAN_DECLARE(prefix,m) float prefix##_mean = m; .float prefix##_count, prefix##_accumulator
  41
  42 .float anticheat_fixangle_endtime;
  43
  44 float anticheat_div0_evade_evasion_delta;
  45 .float anticheat_div0_evade_offset;
  46 .vector anticheat_div0_evade_v_angle;
  47 .vector anticheat_div0_evade_forward_initial;
  48 MEAN_DECLARE(anticheat_div0_evade, 5);
  49
  50 .vector anticheat_div0_strafebot_movement_prev;
  51 MEAN_DECLARE(anticheat_div0_strafebot_old, 5);
  52
  53 .vector anticheat_div0_strafebot_forward_prev;
  54 MEAN_DECLARE(anticheat_div0_strafebot_new, 5);
  55
  56 // Snap-aim detection: we track the average angular speed of aiming over time, in "radians per second".
  57 // Signal: a high-power mean. Cheaters will have high "signal" here.
  58 // Noise: a low-power mean. Active/shivery players will have high "noise" here.
  59 // Note one can always artificially add noise - so very high values of both signal and noise need to be checked too.
  60 MEAN_DECLARE(anticheat_idle_snapaim_signal, 5);
  61 MEAN_DECLARE(anticheat_idle_snapaim_noise, 1);
  62
  63 // TEMP DEBUG STUFF.
  64 MEAN_DECLARE(anticheat_idle_snapaim_m2, 2);
  65 MEAN_DECLARE(anticheat_idle_snapaim_m3, 3);
  66 MEAN_DECLARE(anticheat_idle_snapaim_m4, 4);
  67 MEAN_DECLARE(anticheat_idle_snapaim_m7, 7);
  68 MEAN_DECLARE(anticheat_idle_snapaim_m10, 10);
  69
  70 .float anticheat_speedhack_offset;
  71 .float anticheat_speedhack_movetime, anticheat_speedhack_movetime_count, anticheat_speedhack_movetime_frac;
  72 MEAN_DECLARE(anticheat_speedhack, 5);
  73
  74 .float anticheat_speedhack_accu;
  75 .float anticheat_speedhack_lasttime;
  76 MEAN_DECLARE(anticheat_speedhack_m1, 1);
  77 MEAN_DECLARE(anticheat_speedhack_m2, 2);
  78 MEAN_DECLARE(anticheat_speedhack_m3, 3);
  79 MEAN_DECLARE(anticheat_speedhack_m4, 4);
  80 MEAN_DECLARE(anticheat_speedhack_m5, 5);
  81
  82 float movement_oddity(vector m0, vector m1)
  83 {
  84         float cosangle = normalize(m0) * normalize(m1);
  85         if(cosangle >= 0)
  86                 return 0;
  87         return 0.5 - 0.5 * cos(cosangle * cosangle * 4 * M_PI);
  88                 // returns 0 for: -1, -sqrt(0.5), 0 (angles that commonly happen with kbd)
  89 }
  90
  91 void anticheat_physics()
  92 {
  93         float f;
  94
  95         // div0_evade -> SPECTATORS
  96         makevectors(self.v_angle);
  97         if(self.anticheat_div0_evade_offset == 0)
  98         {
  99                 f = fabs(anticheat_div0_evade_evasion_delta - floor(anticheat_div0_evade_evasion_delta) - 0.5) * 2; // triangle function
 100                 self.anticheat_div0_evade_offset = servertime + sys_frametime * (3 * f - 1);
 101                 self.anticheat_div0_evade_v_angle = self.v_angle;
 102                 self.anticheat_div0_evade_forward_initial = v_forward;
 103                 MEAN_ACCUMULATE(anticheat_div0_evade, 0, 1);
 104         }
 105         else
 106         {
 107                 if(time < self.anticheat_div0_evade_offset)
 108                         self.anticheat_div0_evade_v_angle = self.v_angle;
 109                 MEAN_ACCUMULATE(anticheat_div0_evade, 0.5 - 0.5 * (self.anticheat_div0_evade_forward_initial * v_forward), 1);
 110         }
 111
 112         MEAN_ACCUMULATE(anticheat_div0_strafebot_old, movement_oddity(self.movement, self.anticheat_div0_strafebot_movement_prev), 1);
 113         self.anticheat_div0_strafebot_movement_prev = self.movement;
 114
 115         // Note: this actually tries to detect snap-aim.
 116         if(vlen(self.anticheat_div0_strafebot_forward_prev) && time > self.anticheat_fixangle_endtime) {
 117                 float cosangle = self.anticheat_div0_strafebot_forward_prev * v_forward;
 118                 float angle = cosangle < -1 ? M_PI : cosangle > 1 ? 0 : acos(cosangle);
 119                 /*
 120                 if (angle >= 10 * M_PI / 180)
 121                         printf("SNAP %s: %f for %f, %f since fixangle\n", self.netname, angle * 180 / M_PI, cosangle, time - self.anticheat_fixangle_endtime);
 122                 */
 123                 MEAN_ACCUMULATE(anticheat_div0_strafebot_new, angle / M_PI, 1);
 124
 125                 if (autocvar_slowmo > 0) {
 126                         // Technically this is a NOP, as the engine should be ensuring
 127                         // this in the first place. Let's guard against dividing by
 128                         // zero anyway.
 129                         float dt = max(0.001, frametime) / autocvar_slowmo;
 130
 131                         float anglespeed = angle / dt;
 132                         MEAN_ACCUMULATE(anticheat_idle_snapaim_signal, anglespeed, dt);
 133                         MEAN_ACCUMULATE(anticheat_idle_snapaim_noise, anglespeed, dt);
 134                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m2, anglespeed, dt);
 135                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m3, anglespeed, dt);
 136                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m4, anglespeed, dt);
 137                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m7, anglespeed, dt);
 138                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m10, anglespeed, dt);
 139                 }
 140         }
 141         self.anticheat_div0_strafebot_forward_prev = v_forward;
 142
 143         // generic speedhack detection: correlate anticheat_speedhack_movetime (UPDATED BEFORE THIS) and server time
 144         self.anticheat_speedhack_movetime_frac += frametime;
 145         f = floor(self.anticheat_speedhack_movetime_frac);
 146         self.anticheat_speedhack_movetime_frac -= f;
 147         self.anticheat_speedhack_movetime_count += f;
 148         self.anticheat_speedhack_movetime = self.anticheat_speedhack_movetime_frac + self.anticheat_speedhack_movetime_count;
 149         f = self.anticheat_speedhack_movetime - servertime;
 150         if(self.anticheat_speedhack_offset == 0)
 151                 self.anticheat_speedhack_offset = f;
 152         else
 153         {
 154                 MEAN_ACCUMULATE(anticheat_speedhack, max(0, f - self.anticheat_speedhack_offset), 1);
 155                 self.anticheat_speedhack_offset += (f - self.anticheat_speedhack_offset) * frametime * 0.1;
 156         }
 157
 158         // new generic speedhack detection
 159         if (self.anticheat_speedhack_lasttime > 0) {
 160                 float dt = servertime - self.anticheat_speedhack_lasttime;
 161                 const float falloff = 0.2;
 162                 self.anticheat_speedhack_accu *= exp(-dt * falloff);
 163                 self.anticheat_speedhack_accu += frametime * falloff;
 164                 // NOTE: at cl_netfps x, this actually averages not to 1, but to 1/x * falloff / (1 - exp(-1/x * falloff))
 165                 // For 15 netfps (absolute minimum bearable), and 0.2 falloff, this is: 1.0067
 166                 self.anticheat_speedhack_lasttime = servertime;
 167                 MEAN_ACCUMULATE(anticheat_speedhack_m1, self.anticheat_speedhack_accu, frametime);
 168                 MEAN_ACCUMULATE(anticheat_speedhack_m2, self.anticheat_speedhack_accu, frametime);
 169                 MEAN_ACCUMULATE(anticheat_speedhack_m3, self.anticheat_speedhack_accu, frametime);
 170                 MEAN_ACCUMULATE(anticheat_speedhack_m4, self.anticheat_speedhack_accu, frametime);
 171                 MEAN_ACCUMULATE(anticheat_speedhack_m5, self.anticheat_speedhack_accu, frametime);
 172         } else {
 173                 self.anticheat_speedhack_accu = 1;
 174                 self.anticheat_speedhack_lasttime = servertime;
 175         }
 176 }
 177
 178 void anticheat_spectatecopy(entity spectatee)
 179 {
 180         // div0_evade -> SPECTATORS
 181         self.angles = spectatee.anticheat_div0_evade_v_angle;
 182 }
 183
 184 void anticheat_prethink()
 185 {
 186         // div0_evade -> SPECTATORS
 187         self.anticheat_div0_evade_offset = 0;
 188 }
 189
 190 string anticheat_display(float f, float tmin, float mi, float ma)
 191 {
 192         string s;
 193         s = ftos(f);
 194         if(f <= mi)
 195                 return strcat(s, ":N");
 196         if(f >= ma)
 197                 return strcat(s, ":Y");
 198         return strcat(s, ":-");
 199 }
 200
 201 void anticheat_report()
 202 {
 203         if(!autocvar_sv_eventlog)
 204                 return;
 205         // TODO(divVerent): Use xonstat to acquire good thresholds.
 206         GameLogEcho(strcat(":anticheat:_time:", ftos(self.playerid), ":", ftos(servertime - self.anticheat_jointime)));
 207         GameLogEcho(strcat(":anticheat:speedhack:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack), 240, 0, 9999))); // Actually this one seems broken.
 208         GameLogEcho(strcat(":anticheat:speedhack_m1:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m1), 240, 1.01, 1.25)));
 209         GameLogEcho(strcat(":anticheat:speedhack_m2:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m2), 240, 1.01, 1.25)));
 210         GameLogEcho(strcat(":anticheat:speedhack_m3:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m3), 240, 1.01, 1.25)));
 211         GameLogEcho(strcat(":anticheat:speedhack_m4:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m4), 240, 1.01, 1.25)));
 212         GameLogEcho(strcat(":anticheat:speedhack_m5:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m5), 240, 1.01, 1.25)));
 213         GameLogEcho(strcat(":anticheat:div0_strafebot_old:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_div0_strafebot_old), 120, 0.15, 0.4)));
 214         GameLogEcho(strcat(":anticheat:div0_strafebot_new:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_div0_strafebot_new), 120, 0.25, 0.8)));
 215         GameLogEcho(strcat(":anticheat:div0_evade:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_div0_evade), 120, 0.2, 0.5)));
 216         GameLogEcho(strcat(":anticheat:idle_snapaim:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_signal) - MEAN_EVALUATE(anticheat_idle_snapaim_noise), 120, 0, 9999)));
 217         GameLogEcho(strcat(":anticheat:idle_snapaim_signal:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_signal), 120, 0, 9999)));
 218         GameLogEcho(strcat(":anticheat:idle_snapaim_noise:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_noise), 120, 0, 9999)));
 219         GameLogEcho(strcat(":anticheat:idle_snapaim_m2:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m2), 120, 0, 9999)));
 220         GameLogEcho(strcat(":anticheat:idle_snapaim_m3:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m3), 120, 0, 9999)));
 221         GameLogEcho(strcat(":anticheat:idle_snapaim_m4:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m4), 120, 0, 9999)));
 222         GameLogEcho(strcat(":anticheat:idle_snapaim_m7:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m7), 120, 0, 9999)));
 223         GameLogEcho(strcat(":anticheat:idle_snapaim_m10:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m10), 120, 0, 9999)));
 224 }
 225
 226 float anticheat_getvalue(string id)
 227 {
 228         switch(id) {
 229                 case "_time": return servertime - self.anticheat_jointime;
 230                 case "speedhack": return MEAN_EVALUATE(anticheat_speedhack);
 231                 case "speedhack_m1": return MEAN_EVALUATE(anticheat_speedhack_m1);
 232                 case "speedhack_m2": return MEAN_EVALUATE(anticheat_speedhack_m2);
 233                 case "speedhack_m3": return MEAN_EVALUATE(anticheat_speedhack_m3);
 234                 case "speedhack_m4": return MEAN_EVALUATE(anticheat_speedhack_m4);
 235                 case "speedhack_m5": return MEAN_EVALUATE(anticheat_speedhack_m5);
 236                 case "div0_strafebot_old": return MEAN_EVALUATE(anticheat_div0_strafebot_old);
 237                 case "div0_strafebot_new": return MEAN_EVALUATE(anticheat_div0_strafebot_new);
 238                 case "div0_evade": return MEAN_EVALUATE(anticheat_div0_evade);
 239                 case "idle_snapaim": return MEAN_EVALUATE(anticheat_idle_snapaim_signal) - MEAN_EVALUATE(anticheat_idle_snapaim_noise);
 240                 case "idle_snapaim_signal": return MEAN_EVALUATE(anticheat_idle_snapaim_signal);
 241                 case "idle_snapaim_noise": return MEAN_EVALUATE(anticheat_idle_snapaim_noise);
 242                 case "idle_snapaim_m2": return MEAN_EVALUATE(anticheat_idle_snapaim_m2);
 243                 case "idle_snapaim_m3": return MEAN_EVALUATE(anticheat_idle_snapaim_m3);
 244                 case "idle_snapaim_m4": return MEAN_EVALUATE(anticheat_idle_snapaim_m4);
 245                 case "idle_snapaim_m7": return MEAN_EVALUATE(anticheat_idle_snapaim_m7);
 246                 case "idle_snapaim_m10": return MEAN_EVALUATE(anticheat_idle_snapaim_m10);
 247         }
 248         return -1;
 249 }
 250
 251 void anticheat_startframe()
 252 {
 253         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
 254 }
 255
 256 void anticheat_fixangle()
 257 {
 258         self.anticheat_fixangle_endtime = servertime + ANTILAG_LATENCY(self) + 0.2;
 259 }
 260
 261 void anticheat_endframe()
 262 {
 263         entity oldself = self;
 264         FOR_EACH_CLIENT(self)
 265                 if (self.fixangle)
 266                         anticheat_fixangle();
 267         self = oldself;
 268         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
 269 }
 270
 271 void anticheat_init()
 272 {
 273         self.anticheat_speedhack_offset = 0;
 274         self.anticheat_jointime = servertime;
 275 }
 276
 277 void anticheat_shutdown()
 278 {
 279 }