qcsrc/server/anticheat.qc

   1 .float anticheat_jointime;
   2
   3 void mean_accumulate(entity e, .float a, .float c, float mean, float value, float weight)
   4 {
   5         if(weight == 0)
   6                 return;
   7         if(mean == 0)
   8                 e.a *= pow(value, weight);
   9         else
  10                 e.a += pow(value, mean) * weight;
  11         e.c += weight;
  12 }
  13
  14 float mean_evaluate(entity e, .float a, .float c, float mean)
  15 {
  16         if(e.c == 0)
  17                 return 0;
  18         if(mean == 0)
  19                 return pow(e.a, 1.0 / e.c);
  20         else
  21                 return pow(e.a / e.c, 1.0 / mean);
  22 }
  23
  24 #define MEAN_ACCUMULATE(prefix,v,w) mean_accumulate(self,prefix##_accumulator,prefix##_count,prefix##_mean,v,w)
  25 #define MEAN_EVALUATE(prefix) mean_evaluate(self,prefix##_accumulator,prefix##_count,prefix##_mean)
  26 #define MEAN_DECLARE(prefix,m) float prefix##_mean = m; .float prefix##_count, prefix##_accumulator
  27
  28 .float anticheat_fixangle_endtime;
  29
  30 float anticheat_div0_evade_evasion_delta;
  31 .float anticheat_div0_evade_offset;
  32 .vector anticheat_div0_evade_v_angle;
  33 .vector anticheat_div0_evade_forward_initial;
  34 MEAN_DECLARE(anticheat_div0_evade, 5);
  35
  36 .vector anticheat_div0_strafebot_movement_prev;
  37 MEAN_DECLARE(anticheat_div0_strafebot_old, 5);
  38
  39 .vector anticheat_div0_strafebot_forward_prev;
  40 MEAN_DECLARE(anticheat_div0_strafebot_new, 5);
  41
  42 // Snap-aim detection: we track the average angular speed of aiming over time, in "radians per second".
  43 // Signal: a high-power mean. Cheaters will have high "signal" here.
  44 // Noise: a low-power mean. Active/shivery players will have high "noise" here.
  45 // Note one can always artificially add noise - so very high values of both signal and noise need to be checked too.
  46 MEAN_DECLARE(anticheat_idle_snapaim_signal, 5);
  47 MEAN_DECLARE(anticheat_idle_snapaim_noise, 1);
  48
  49 // TEMP DEBUG STUFF.
  50 MEAN_DECLARE(anticheat_idle_snapaim_m2, 2);
  51 MEAN_DECLARE(anticheat_idle_snapaim_m3, 3);
  52 MEAN_DECLARE(anticheat_idle_snapaim_m4, 4);
  53 MEAN_DECLARE(anticheat_idle_snapaim_m7, 7);
  54 MEAN_DECLARE(anticheat_idle_snapaim_m10, 10);
  55
  56 .float anticheat_speedhack_offset;
  57 .float anticheat_speedhack_movetime, anticheat_speedhack_movetime_count, anticheat_speedhack_movetime_frac;
  58 MEAN_DECLARE(anticheat_speedhack, 5);
  59
  60 .float anticheat_speedhack_accu;
  61 .float anticheat_speedhack_lasttime;
  62 MEAN_DECLARE(anticheat_speedhack_m1, 1);
  63 MEAN_DECLARE(anticheat_speedhack_m2, 2);
  64 MEAN_DECLARE(anticheat_speedhack_m3, 3);
  65 MEAN_DECLARE(anticheat_speedhack_m4, 4);
  66 MEAN_DECLARE(anticheat_speedhack_m5, 5);
  67
  68 float movement_oddity(vector m0, vector m1)
  69 {
  70         float cosangle = normalize(m0) * normalize(m1);
  71         if(cosangle >= 0)
  72                 return 0;
  73         return 0.5 - 0.5 * cos(cosangle * cosangle * 4 * M_PI);
  74                 // returns 0 for: -1, -sqrt(0.5), 0 (angles that commonly happen with kbd)
  75 }
  76
  77 void anticheat_physics()
  78 {
  79         float f;
  80
  81         // div0_evade -> SPECTATORS
  82         makevectors(self.v_angle);
  83         if(self.anticheat_div0_evade_offset == 0)
  84         {
  85                 f = fabs(anticheat_div0_evade_evasion_delta - floor(anticheat_div0_evade_evasion_delta) - 0.5) * 2; // triangle function
  86                 self.anticheat_div0_evade_offset = servertime + sys_frametime * (3 * f - 1);
  87                 self.anticheat_div0_evade_v_angle = self.v_angle;
  88                 self.anticheat_div0_evade_forward_initial = v_forward;
  89                 MEAN_ACCUMULATE(anticheat_div0_evade, 0, 1);
  90         }
  91         else
  92         {
  93                 if(time < self.anticheat_div0_evade_offset)
  94                         self.anticheat_div0_evade_v_angle = self.v_angle;
  95                 MEAN_ACCUMULATE(anticheat_div0_evade, 0.5 - 0.5 * (self.anticheat_div0_evade_forward_initial * v_forward), 1);
  96         }
  97
  98         MEAN_ACCUMULATE(anticheat_div0_strafebot_old, movement_oddity(self.movement, self.anticheat_div0_strafebot_movement_prev), 1);
  99         self.anticheat_div0_strafebot_movement_prev = self.movement;
 100
 101         // Note: this actually tries to detect snap-aim.
 102         if(vlen(self.anticheat_div0_strafebot_forward_prev) && time > self.anticheat_fixangle_endtime) {
 103                 float cosangle = self.anticheat_div0_strafebot_forward_prev * v_forward;
 104                 float angle = cosangle < -1 ? M_PI : cosangle > 1 ? 0 : acos(cosangle);
 105                 /*
 106                 if (angle >= 10 * M_PI / 180)
 107                         printf("SNAP %s: %f for %f, %f since fixangle\n", self.netname, angle * 180 / M_PI, cosangle, time - self.anticheat_fixangle_endtime);
 108                 */
 109                 MEAN_ACCUMULATE(anticheat_div0_strafebot_new, angle / M_PI, 1);
 110
 111                 if (autocvar_slowmo > 0) {
 112                         // Technically this is a NOP, as the engine should be ensuring
 113                         // this in the first place. Let's guard against dividing by
 114                         // zero anyway.
 115                         float dt = max(0.001, frametime) / autocvar_slowmo;
 116
 117                         float anglespeed = angle / dt;
 118                         MEAN_ACCUMULATE(anticheat_idle_snapaim_signal, anglespeed, dt);
 119                         MEAN_ACCUMULATE(anticheat_idle_snapaim_noise, anglespeed, dt);
 120                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m2, anglespeed, dt);
 121                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m3, anglespeed, dt);
 122                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m4, anglespeed, dt);
 123                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m7, anglespeed, dt);
 124                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m10, anglespeed, dt);
 125                 }
 126         }
 127         self.anticheat_div0_strafebot_forward_prev = v_forward;
 128
 129         // generic speedhack detection: correlate anticheat_speedhack_movetime (UPDATED BEFORE THIS) and server time
 130         self.anticheat_speedhack_movetime_frac += frametime;
 131         f = floor(self.anticheat_speedhack_movetime_frac);
 132         self.anticheat_speedhack_movetime_frac -= f;
 133         self.anticheat_speedhack_movetime_count += f;
 134         self.anticheat_speedhack_movetime = self.anticheat_speedhack_movetime_frac + self.anticheat_speedhack_movetime_count;
 135         f = self.anticheat_speedhack_movetime - servertime;
 136         if(self.anticheat_speedhack_offset == 0)
 137                 self.anticheat_speedhack_offset = f;
 138         else
 139         {
 140                 MEAN_ACCUMULATE(anticheat_speedhack, max(0, f - self.anticheat_speedhack_offset), 1);
 141                 self.anticheat_speedhack_offset += (f - self.anticheat_speedhack_offset) * frametime * 0.1;
 142         }
 143
 144         // new generic speedhack detection
 145         if (self.anticheat_speedhack_lasttime > 0) {
 146                 float dt = servertime - self.anticheat_speedhack_lasttime;
 147                 const float falloff = 0.2;
 148                 self.anticheat_speedhack_accu *= exp(-dt * falloff);
 149                 self.anticheat_speedhack_accu += frametime * falloff;
 150                 // NOTE: at cl_netfps x, this actually averages not to 1, but to 1/x * falloff / (1 - exp(-1/x * falloff))
 151                 // For 15 netfps (absolute minimum bearable), and 0.2 falloff, this is: 1.0067
 152                 self.anticheat_speedhack_lasttime = servertime;
 153                 MEAN_ACCUMULATE(anticheat_speedhack_m1, self.anticheat_speedhack_accu, frametime);
 154                 MEAN_ACCUMULATE(anticheat_speedhack_m2, self.anticheat_speedhack_accu, frametime);
 155                 MEAN_ACCUMULATE(anticheat_speedhack_m3, self.anticheat_speedhack_accu, frametime);
 156                 MEAN_ACCUMULATE(anticheat_speedhack_m4, self.anticheat_speedhack_accu, frametime);
 157                 MEAN_ACCUMULATE(anticheat_speedhack_m5, self.anticheat_speedhack_accu, frametime);
 158         } else {
 159                 self.anticheat_speedhack_accu = 1;
 160                 self.anticheat_speedhack_lasttime = servertime;
 161         }
 162 }
 163
 164 void anticheat_spectatecopy(entity spectatee)
 165 {
 166         // div0_evade -> SPECTATORS
 167         self.angles = spectatee.anticheat_div0_evade_v_angle;
 168 }
 169
 170 void anticheat_prethink()
 171 {
 172         // div0_evade -> SPECTATORS
 173         self.anticheat_div0_evade_offset = 0;
 174 }
 175
 176 string anticheat_display(float f, float tmin, float mi, float ma)
 177 {
 178         string s;
 179         s = ftos(f);
 180         if(f <= mi)
 181                 return strcat(s, ":N");
 182         if(f >= ma)
 183                 return strcat(s, ":Y");
 184         return strcat(s, ":-");
 185 }
 186
 187 void anticheat_report()
 188 {
 189         if(!autocvar_sv_eventlog)
 190                 return;
 191         // TODO(divVerent): Use xonstat to acquire good thresholds.
 192         GameLogEcho(strcat(":anticheat:_time:", ftos(self.playerid), ":", ftos(servertime - self.anticheat_jointime)));
 193         GameLogEcho(strcat(":anticheat:speedhack:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack), 240, 0, 9999))); // Actually this one seems broken.
 194         GameLogEcho(strcat(":anticheat:speedhack_m1:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m1), 240, 1.01, 1.25)));
 195         GameLogEcho(strcat(":anticheat:speedhack_m2:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m2), 240, 1.01, 1.25)));
 196         GameLogEcho(strcat(":anticheat:speedhack_m3:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m3), 240, 1.01, 1.25)));
 197         GameLogEcho(strcat(":anticheat:speedhack_m4:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m4), 240, 1.01, 1.25)));
 198         GameLogEcho(strcat(":anticheat:speedhack_m5:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m5), 240, 1.01, 1.25)));
 199         GameLogEcho(strcat(":anticheat:div0_strafebot_old:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_div0_strafebot_old), 120, 0.15, 0.4)));
 200         GameLogEcho(strcat(":anticheat:div0_strafebot_new:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_div0_strafebot_new), 120, 0.25, 0.8)));
 201         GameLogEcho(strcat(":anticheat:div0_evade:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_div0_evade), 120, 0.2, 0.5)));
 202         GameLogEcho(strcat(":anticheat:idle_snapaim:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_signal) - MEAN_EVALUATE(anticheat_idle_snapaim_noise), 120, 0, 9999)));
 203         GameLogEcho(strcat(":anticheat:idle_snapaim_signal:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_signal), 120, 0, 9999)));
 204         GameLogEcho(strcat(":anticheat:idle_snapaim_noise:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_noise), 120, 0, 9999)));
 205         GameLogEcho(strcat(":anticheat:idle_snapaim_m2:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m2), 120, 0, 9999)));
 206         GameLogEcho(strcat(":anticheat:idle_snapaim_m3:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m3), 120, 0, 9999)));
 207         GameLogEcho(strcat(":anticheat:idle_snapaim_m4:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m4), 120, 0, 9999)));
 208         GameLogEcho(strcat(":anticheat:idle_snapaim_m7:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m7), 120, 0, 9999)));
 209         GameLogEcho(strcat(":anticheat:idle_snapaim_m10:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m10), 120, 0, 9999)));
 210 }
 211
 212 float anticheat_getvalue(string id)
 213 {
 214         switch(id) {
 215                 case "_time": return servertime - self.anticheat_jointime;
 216                 case "speedhack": return MEAN_EVALUATE(anticheat_speedhack);
 217                 case "speedhack_m1": return MEAN_EVALUATE(anticheat_speedhack_m1);
 218                 case "speedhack_m2": return MEAN_EVALUATE(anticheat_speedhack_m2);
 219                 case "speedhack_m3": return MEAN_EVALUATE(anticheat_speedhack_m3);
 220                 case "speedhack_m4": return MEAN_EVALUATE(anticheat_speedhack_m4);
 221                 case "speedhack_m5": return MEAN_EVALUATE(anticheat_speedhack_m5);
 222                 case "div0_strafebot_old": return MEAN_EVALUATE(anticheat_div0_strafebot_old);
 223                 case "div0_strafebot_new": return MEAN_EVALUATE(anticheat_div0_strafebot_new);
 224                 case "div0_evade": return MEAN_EVALUATE(anticheat_div0_evade);
 225                 case "idle_snapaim": return MEAN_EVALUATE(anticheat_idle_snapaim_signal) - MEAN_EVALUATE(anticheat_idle_snapaim_noise);
 226                 case "idle_snapaim_signal": return MEAN_EVALUATE(anticheat_idle_snapaim_signal);
 227                 case "idle_snapaim_noise": return MEAN_EVALUATE(anticheat_idle_snapaim_noise);
 228                 case "idle_snapaim_m2": return MEAN_EVALUATE(anticheat_idle_snapaim_m2);
 229                 case "idle_snapaim_m3": return MEAN_EVALUATE(anticheat_idle_snapaim_m3);
 230                 case "idle_snapaim_m4": return MEAN_EVALUATE(anticheat_idle_snapaim_m4);
 231                 case "idle_snapaim_m7": return MEAN_EVALUATE(anticheat_idle_snapaim_m7);
 232                 case "idle_snapaim_m10": return MEAN_EVALUATE(anticheat_idle_snapaim_m10);
 233         }
 234         return -1;
 235 }
 236
 237 void anticheat_startframe()
 238 {
 239         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
 240 }
 241
 242 void anticheat_fixangle()
 243 {
 244         self.anticheat_fixangle_endtime = servertime + ANTILAG_LATENCY(self) + 0.2;
 245 }
 246
 247 void anticheat_endframe()
 248 {
 249         entity oldself = self;
 250         FOR_EACH_CLIENT(self)
 251                 if (self.fixangle)
 252                         anticheat_fixangle();
 253         self = oldself;
 254         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
 255 }
 256
 257 void anticheat_init()
 258 {
 259         self.anticheat_speedhack_offset = 0;
 260         self.anticheat_jointime = servertime;
 261 }
 262
 263 void anticheat_shutdown()
 264 {
 265 }