Split the gamelog code out of miscfunctions and into its own file
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / anticheat.qc
1 #include "anticheat.qh"
2
3 #include "antilag.qh"
4 #include "autocvars.qh"
5 #include "defs.qh"
6 #include <server/gamelog.qh>
7 #include "miscfunctions.qh"
8
9 #include "command/common.qh"
10 #include <common/playerstats.qh>
11 #include <common/state.qh>
12
13 .float anticheat_jointime;
14
15 .float anticheat_fixangle_endtime;
16
17 float anticheat_div0_evade_evasion_delta;
18 .float anticheat_div0_evade_offset;
19 .vector anticheat_div0_evade_v_angle;
20 .vector anticheat_div0_evade_forward_initial;
21 MEAN_DECLARE(anticheat_div0_evade, 5);
22
23 .vector anticheat_div0_strafebot_movement_prev;
24 MEAN_DECLARE(anticheat_div0_strafebot_old, 5);
25
26 .vector anticheat_div0_strafebot_forward_prev;
27 MEAN_DECLARE(anticheat_div0_strafebot_new, 5);
28
29 // Snap-aim detection: we track the average angular speed of aiming over time, in "radians per second".
30 // Signal: a high-power mean. Cheaters will have high "signal" here.
31 // Noise: a low-power mean. Active/shivery players will have high "noise" here.
32 // Note one can always artificially add noise - so very high values of both signal and noise need to be checked too.
33 MEAN_DECLARE(anticheat_idle_snapaim_signal, 5);
34 MEAN_DECLARE(anticheat_idle_snapaim_noise, 1);
35
36 // TEMP DEBUG STUFF.
37 MEAN_DECLARE(anticheat_idle_snapaim_m2, 2);
38 MEAN_DECLARE(anticheat_idle_snapaim_m3, 3);
39 MEAN_DECLARE(anticheat_idle_snapaim_m4, 4);
40 MEAN_DECLARE(anticheat_idle_snapaim_m7, 7);
41 MEAN_DECLARE(anticheat_idle_snapaim_m10, 10);
42
43 .float anticheat_speedhack_offset;
44 .float anticheat_speedhack_movetime, anticheat_speedhack_movetime_count, anticheat_speedhack_movetime_frac;
45 MEAN_DECLARE(anticheat_speedhack, 5);
46
47 .float anticheat_speedhack_accu;
48 .float anticheat_speedhack_lasttime;
49 MEAN_DECLARE(anticheat_speedhack_m1, 1);
50 MEAN_DECLARE(anticheat_speedhack_m2, 2);
51 MEAN_DECLARE(anticheat_speedhack_m3, 3);
52 MEAN_DECLARE(anticheat_speedhack_m4, 4);
53 MEAN_DECLARE(anticheat_speedhack_m5, 5);
54
55 float movement_oddity(vector m0, vector m1)
56 {
57         float cosangle = normalize(m0) * normalize(m1);
58         if(cosangle >= 0)
59                 return 0;
60         return 0.5 - 0.5 * cos(cosangle * cosangle * 4 * M_PI);
61                 // returns 0 for: -1, -sqrt(0.5), 0 (angles that commonly happen with kbd)
62 }
63
64 void anticheat_physics(entity this)
65 {
66         float f;
67
68         // div0_evade -> SPECTATORS
69         makevectors(this.v_angle);
70         if(CS(this).anticheat_div0_evade_offset == 0)
71         {
72                 f = fabs(anticheat_div0_evade_evasion_delta - floor(anticheat_div0_evade_evasion_delta) - 0.5) * 2; // triangle function
73                 CS(this).anticheat_div0_evade_offset = servertime + sys_frametime * (3 * f - 1);
74                 CS(this).anticheat_div0_evade_v_angle = this.v_angle;
75                 CS(this).anticheat_div0_evade_forward_initial = v_forward;
76                 MEAN_ACCUMULATE(CS(this), anticheat_div0_evade, 0, 1);
77         }
78         else
79         {
80                 if(time < CS(this).anticheat_div0_evade_offset)
81                         CS(this).anticheat_div0_evade_v_angle = this.v_angle;
82                 MEAN_ACCUMULATE(CS(this), anticheat_div0_evade, 0.5 - 0.5 * (CS(this).anticheat_div0_evade_forward_initial * v_forward), 1);
83         }
84
85         MEAN_ACCUMULATE(CS(this), anticheat_div0_strafebot_old, movement_oddity(CS(this).movement, CS(this).anticheat_div0_strafebot_movement_prev), 1);
86         CS(this).anticheat_div0_strafebot_movement_prev = CS(this).movement;
87
88         // Note: this actually tries to detect snap-aim.
89         if(CS(this).anticheat_div0_strafebot_forward_prev && time > CS(this).anticheat_fixangle_endtime) {
90                 float cosangle = CS(this).anticheat_div0_strafebot_forward_prev * v_forward;
91                 float angle = cosangle < -1 ? M_PI : cosangle > 1 ? 0 : acos(cosangle);
92                 /*
93                 if (angle >= 10 * M_PI / 180)
94                         printf("SNAP %s: %f for %f, %f since fixangle\n", this.netname, angle * 180 / M_PI, cosangle, time - CS(this).anticheat_fixangle_endtime);
95                 */
96                 MEAN_ACCUMULATE(CS(this), anticheat_div0_strafebot_new, angle / M_PI, 1);
97
98                 if (autocvar_slowmo > 0) {
99                         // Technically this is a NOP, as the engine should be ensuring
100                         // this in the first place. Let's guard against dividing by
101                         // zero anyway.
102                         float dt = max(0.001, frametime) / autocvar_slowmo;
103
104                         float anglespeed = angle / dt;
105                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_signal, anglespeed, dt);
106                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_noise, anglespeed, dt);
107                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m2, anglespeed, dt);
108                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m3, anglespeed, dt);
109                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m4, anglespeed, dt);
110                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m7, anglespeed, dt);
111                         MEAN_ACCUMULATE(CS(this), anticheat_idle_snapaim_m10, anglespeed, dt);
112                 }
113         }
114         CS(this).anticheat_div0_strafebot_forward_prev = v_forward;
115
116         // generic speedhack detection: correlate anticheat_speedhack_movetime (UPDATED BEFORE THIS) and server time
117         CS(this).anticheat_speedhack_movetime_frac += frametime;
118         f = floor(CS(this).anticheat_speedhack_movetime_frac);
119         CS(this).anticheat_speedhack_movetime_frac -= f;
120         CS(this).anticheat_speedhack_movetime_count += f;
121         CS(this).anticheat_speedhack_movetime = CS(this).anticheat_speedhack_movetime_frac + CS(this).anticheat_speedhack_movetime_count;
122         f = CS(this).anticheat_speedhack_movetime - servertime;
123         if(CS(this).anticheat_speedhack_offset == 0)
124                 CS(this).anticheat_speedhack_offset = f;
125         else
126         {
127                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack, max(0, f - CS(this).anticheat_speedhack_offset), 1);
128                 CS(this).anticheat_speedhack_offset += (f - CS(this).anticheat_speedhack_offset) * frametime * 0.1;
129         }
130
131         // new generic speedhack detection
132         if (CS(this).anticheat_speedhack_lasttime > 0) {
133                 float dt = servertime - CS(this).anticheat_speedhack_lasttime;
134                 const float falloff = 0.2;
135                 CS(this).anticheat_speedhack_accu *= exp(-dt * falloff);
136                 CS(this).anticheat_speedhack_accu += frametime * falloff;
137                 // NOTE: at cl_netfps x, this actually averages not to 1, but to 1/x * falloff / (1 - exp(-1/x * falloff))
138                 // For 15 netfps (absolute minimum bearable), and 0.2 falloff, this is: 1.0067
139                 CS(this).anticheat_speedhack_lasttime = servertime;
140                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m1, CS(this).anticheat_speedhack_accu, frametime);
141                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m2, CS(this).anticheat_speedhack_accu, frametime);
142                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m3, CS(this).anticheat_speedhack_accu, frametime);
143                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m4, CS(this).anticheat_speedhack_accu, frametime);
144                 MEAN_ACCUMULATE(CS(this), anticheat_speedhack_m5, CS(this).anticheat_speedhack_accu, frametime);
145         } else {
146                 CS(this).anticheat_speedhack_accu = 1;
147                 CS(this).anticheat_speedhack_lasttime = servertime;
148         }
149 }
150
151 void anticheat_spectatecopy(entity this, entity spectatee)
152 {
153         // div0_evade -> SPECTATORS
154         this.angles = CS(spectatee).anticheat_div0_evade_v_angle;
155 }
156
157 void anticheat_prethink(entity this)
158 {
159         // div0_evade -> SPECTATORS
160         CS(this).anticheat_div0_evade_offset = 0;
161 }
162
163 string anticheat_display(float f, float t, float tmin, float mi, float ma)
164 {
165         string s;
166         s = ftos(f);
167         if (t >= tmin) {
168                 if(f <= mi)
169                         return strcat(s, ":N");
170                 if(f >= ma)
171                         return strcat(s, ":Y");
172         }
173         return strcat(s, ":-");
174 }
175
176 #define ANTICHEATS(ANTICHEAT) \
177         ANTICHEAT("speedhack", MEAN_EVALUATE(CS(this), anticheat_speedhack), 240, 0, 9999); /* Actually this one seems broken. */ \
178         ANTICHEAT("speedhack_m1", MEAN_EVALUATE(CS(this), anticheat_speedhack_m1), 240, 1.01, 1.25); \
179         ANTICHEAT("speedhack_m2", MEAN_EVALUATE(CS(this), anticheat_speedhack_m2), 240, 1.01, 1.25); \
180         ANTICHEAT("speedhack_m3", MEAN_EVALUATE(CS(this), anticheat_speedhack_m3), 240, 1.01, 1.25); \
181         ANTICHEAT("speedhack_m4", MEAN_EVALUATE(CS(this), anticheat_speedhack_m4), 240, 1.01, 1.25); \
182         ANTICHEAT("speedhack_m5", MEAN_EVALUATE(CS(this), anticheat_speedhack_m5), 240, 1.01, 1.25); \
183         ANTICHEAT("div0_strafebot_old", MEAN_EVALUATE(CS(this), anticheat_div0_strafebot_old), 120, 0.15, 0.4); \
184         ANTICHEAT("div0_strafebot_new", MEAN_EVALUATE(CS(this), anticheat_div0_strafebot_new), 120, 0.25, 0.8); \
185         ANTICHEAT("div0_evade", MEAN_EVALUATE(CS(this), anticheat_div0_evade), 120, 0.2, 0.5); \
186         ANTICHEAT("idle_snapaim", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_signal) - MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_noise), 120, 0, 9999); \
187         ANTICHEAT("idle_snapaim_signal", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_signal), 120, 0, 9999); \
188         ANTICHEAT("idle_snapaim_noise", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_noise), 120, 0, 9999); \
189         ANTICHEAT("idle_snapaim_m2", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m2), 120, 0, 9999); \
190         ANTICHEAT("idle_snapaim_m3", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m3), 120, 0, 9999); \
191         ANTICHEAT("idle_snapaim_m4", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m4), 120, 0, 9999); \
192         ANTICHEAT("idle_snapaim_m7", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m7), 120, 0, 9999); \
193         ANTICHEAT("idle_snapaim_m10", MEAN_EVALUATE(CS(this), anticheat_idle_snapaim_m10), 120, 0, 9999)
194
195 void anticheat_report_to_eventlog(entity this) {
196         if(!autocvar_sv_eventlog)
197                 return;
198         GameLogEcho(strcat(":anticheat:_time:", ftos(this.playerid), ":", ftos(servertime - CS(this).anticheat_jointime)));
199 #define ANTICHEAT_REPORT_ONE(name, f, tmin, mi, ma) \
200         GameLogEcho(strcat(":anticheat:", name, ":", anticheat_display(f, servertime - CS(this).anticheat_jointime, tmin, mi, ma)))
201         ANTICHEATS(ANTICHEAT_REPORT_ONE);
202 #undef ANTICHEAT_REPORT_ONE
203 }
204
205 void anticheat_report_to_playerstats(entity this) {
206         PlayerStats_GameReport_Event_Player(this,
207                 strcat(PLAYERSTATS_ANTICHEAT, "_time"), servertime - CS(this).anticheat_jointime);
208 #define ANTICHEAT_REPORT_ONE(name, f, tmin, mi, ma) \
209         PlayerStats_GameReport_Event_Player(this, strcat(PLAYERSTATS_ANTICHEAT, name), f)
210         ANTICHEATS(ANTICHEAT_REPORT_ONE);
211 #undef ANTICHEAT_REPORT_ONE
212 }
213
214 void anticheat_register_to_playerstats() {
215         PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_ANTICHEAT, "_time"));
216 #define ANTICHEAT_REGISTER_ONE(name, unused_f, unused_tmin, unused_mi, unused_ma) \
217         PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_ANTICHEAT, name))
218         ANTICHEATS(ANTICHEAT_REGISTER_ONE);
219 #undef ANTICHEAT_REGISTER_ONE
220 }
221
222 #undef ANTICHEATS
223
224 void anticheat_startframe()
225 {
226         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
227 }
228
229 void anticheat_fixangle(entity this)
230 {
231         CS(this).anticheat_fixangle_endtime = servertime + ANTILAG_LATENCY(this) + 0.2;
232 }
233
234 void anticheat_endframe()
235 {
236         FOREACH_CLIENT(it.fixangle, anticheat_fixangle(it));
237         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
238 }
239
240 void anticheat_init(entity this)
241 {
242         CS(this).anticheat_speedhack_offset = 0;
243         CS(this).anticheat_jointime = servertime;
244 }