qcsrc/server/antilag.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "../common/vehicles/sv_vehicles.qh"
   7     #include "../common/vehicles/vehicles.qh"
   8     #include "antilag.qh"
   9 #endif
  10
  11 const int ANTILAG_MAX_ORIGINS = 64;
  12 .vector antilag_origins[ANTILAG_MAX_ORIGINS];
  13 .float antilag_times[ANTILAG_MAX_ORIGINS];
  14 .int antilag_index;
  15 .vector antilag_saved_origin;
  16 .float antilag_takenback;
  17
  18 .float antilag_debug;
  19
  20 void antilag_record(entity e, float t)
  21 {
  22     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
  23         return;
  24
  25     if(e.vehicle)
  26         antilag_record(e.vehicle, t);
  27
  28         if(time < e.(antilag_times[e.antilag_index]))
  29                 return;
  30         e.antilag_index = e.antilag_index + 1;
  31         if(e.antilag_index >= ANTILAG_MAX_ORIGINS)
  32                 e.antilag_index = 0;
  33         e.(antilag_times[e.antilag_index]) = t;
  34         e.(antilag_origins[e.antilag_index]) = e.origin;
  35
  36         if(e.antilag_debug)
  37                 te_spark(antilag_takebackorigin(e, t - e.antilag_debug), '0 0 0', 32);
  38
  39 }
  40
  41 // finds the index BEFORE t
  42 float antilag_find(entity e, float t)
  43 {
  44         for(int i = e.antilag_index; i > 0; --i)
  45                 if(e.(antilag_times[i]) >= t)
  46                         if(e.(antilag_times[i - 1]) < t)
  47                                 return i - 1;
  48
  49         if(e.(antilag_times[0]) >= t)
  50                 if(e.(antilag_times[ANTILAG_MAX_ORIGINS - 1]) < t)
  51                         return ANTILAG_MAX_ORIGINS - 1;
  52
  53         for(int i = ANTILAG_MAX_ORIGINS - 1; i > e.antilag_index + 1; --i)
  54                 if(e.(antilag_times[i]) >= t)
  55                         if(e.(antilag_times[i - 1]) < t)
  56                                 return i - 1;
  57
  58         // if we get here, t is sandwiched nowhere, so let's assume it's in the present
  59         return -1;
  60 }
  61
  62 vector lerpv(float t0, vector v0, float t1, vector v1, float t)
  63 {
  64         return v0 + (v1 - v0) * ((t - t0) / (t1 - t0));
  65 }
  66
  67 vector antilag_takebackorigin(entity e, float t)
  68 {
  69         int i0 = antilag_find(e, t);
  70         if (i0 < 0)
  71         {
  72                 // IN THE PRESENT
  73                 if(e.antilag_takenback)
  74                         return e.antilag_saved_origin;
  75                 else
  76                         return e.origin;
  77         }
  78         int i1 = i0 + 1;
  79         if (i1 >= ANTILAG_MAX_ORIGINS)
  80                 i1 = 0;
  81
  82         return lerpv(e.(antilag_times[i0]), e.(antilag_origins[i0]), e.(antilag_times[i1]), e.(antilag_origins[i1]), t);
  83 }
  84
  85 vector antilag_takebackavgvelocity(entity e, float t0, float t1)
  86 {
  87         vector o0, o1;
  88
  89         if(t0 >= t1)
  90                 return '0 0 0';
  91         o0 = antilag_takebackorigin(e, t0);
  92         o1 = antilag_takebackorigin(e, t1);
  93         return (o1 - o0) * (1 / (t1 - t0));
  94 }
  95
  96 void antilag_takeback(entity e, float t)
  97 {
  98
  99     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
 100         return;
 101
 102         if(e.vehicle)
 103                 antilag_takeback(e.vehicle, t);
 104
 105         if(!e.antilag_takenback)
 106                 e.antilag_saved_origin = e.origin;
 107
 108         setorigin(e, antilag_takebackorigin(e, t));
 109         e.antilag_takenback = true;
 110 }
 111
 112 void antilag_restore(entity e)
 113 {
 114     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
 115         return;
 116
 117         if(e.vehicle)
 118                 antilag_restore(e.vehicle);
 119
 120         if(!e.antilag_takenback)
 121                 return;
 122
 123         setorigin(e, e.antilag_saved_origin);
 124         e.antilag_takenback = false;
 125 }
 126
 127 void antilag_clear(entity e)
 128 {
 129         antilag_restore(e);
 130         for (int i = 0; i < ANTILAG_MAX_ORIGINS; ++i)
 131         {
 132                 e.(antilag_times[i]) = -2342;
 133                 e.(antilag_origins[i]) = e.origin;
 134         }
 135         e.antilag_index = ANTILAG_MAX_ORIGINS - 1; // next one is 0
 136 }