qcsrc/server/antilag.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "vehicles/vehicles_def.qh"
   7     #include "antilag.qh"
   8 #endif
   9
  10 const int ANTILAG_MAX_ORIGINS = 64;
  11 .vector antilag_origins[ANTILAG_MAX_ORIGINS];
  12 .float antilag_times[ANTILAG_MAX_ORIGINS];
  13 .int antilag_index;
  14 .vector antilag_saved_origin;
  15 .float antilag_takenback;
  16
  17 .float antilag_debug;
  18
  19 void antilag_record(entity e, float t)
  20 {
  21     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
  22         return;
  23
  24     if(e.vehicle)
  25         antilag_record(e.vehicle, t);
  26
  27         if(time < e.(antilag_times[e.antilag_index]))
  28                 return;
  29         e.antilag_index = e.antilag_index + 1;
  30         if(e.antilag_index >= ANTILAG_MAX_ORIGINS)
  31                 e.antilag_index = 0;
  32         e.(antilag_times[e.antilag_index]) = t;
  33         e.(antilag_origins[e.antilag_index]) = e.origin;
  34
  35         if(e.antilag_debug)
  36                 te_spark(antilag_takebackorigin(e, t - e.antilag_debug), '0 0 0', 32);
  37
  38 }
  39
  40 // finds the index BEFORE t
  41 float antilag_find(entity e, float t)
  42 {
  43         for(int i = e.antilag_index; i > 0; --i)
  44                 if(e.(antilag_times[i]) >= t)
  45                         if(e.(antilag_times[i - 1]) < t)
  46                                 return i - 1;
  47
  48         if(e.(antilag_times[0]) >= t)
  49                 if(e.(antilag_times[ANTILAG_MAX_ORIGINS - 1]) < t)
  50                         return ANTILAG_MAX_ORIGINS - 1;
  51
  52         for(int i = ANTILAG_MAX_ORIGINS - 1; i > e.antilag_index + 1; --i)
  53                 if(e.(antilag_times[i]) >= t)
  54                         if(e.(antilag_times[i - 1]) < t)
  55                                 return i - 1;
  56
  57         // if we get here, t is sandwiched nowhere, so let's assume it's in the present
  58         return -1;
  59 }
  60
  61 vector lerpv(float t0, vector v0, float t1, vector v1, float t)
  62 {
  63         return v0 + (v1 - v0) * ((t - t0) / (t1 - t0));
  64 }
  65
  66 vector antilag_takebackorigin(entity e, float t)
  67 {
  68         float i0, i1;
  69
  70         i0 = antilag_find(e, t);
  71         if(i0 < 0)
  72         {
  73                 // IN THE PRESENT
  74                 if(e.antilag_takenback)
  75                         return e.antilag_saved_origin;
  76                 else
  77                         return e.origin;
  78         }
  79         i1 = i0 + 1;
  80         if(i1 >= ANTILAG_MAX_ORIGINS)
  81                 i1 = 0;
  82
  83         return lerpv(e.(antilag_times[i0]), e.(antilag_origins[i0]), e.(antilag_times[i1]), e.(antilag_origins[i1]), t);
  84 }
  85
  86 vector antilag_takebackavgvelocity(entity e, float t0, float t1)
  87 {
  88         vector o0, o1;
  89
  90         if(t0 >= t1)
  91                 return '0 0 0';
  92         o0 = antilag_takebackorigin(e, t0);
  93         o1 = antilag_takebackorigin(e, t1);
  94         return (o1 - o0) * (1 / (t1 - t0));
  95 }
  96
  97 void antilag_takeback(entity e, float t)
  98 {
  99
 100     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
 101         return;
 102
 103         if(e.vehicle)
 104                 antilag_takeback(e.vehicle, t);
 105
 106         if(!e.antilag_takenback)
 107                 e.antilag_saved_origin = e.origin;
 108
 109         setorigin(e, antilag_takebackorigin(e, t));
 110         e.antilag_takenback = true;
 111 }
 112
 113 void antilag_restore(entity e)
 114 {
 115     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
 116         return;
 117
 118         if(e.vehicle)
 119                 antilag_restore(e.vehicle);
 120
 121         if(!e.antilag_takenback)
 122                 return;
 123
 124         setorigin(e, e.antilag_saved_origin);
 125         e.antilag_takenback = false;
 126 }
 127
 128 void antilag_clear(entity e)
 129 {
 130         float i;
 131
 132         antilag_restore(e);
 133         for(i = 0; i < ANTILAG_MAX_ORIGINS; ++i)
 134         {
 135                 e.(antilag_times[i]) = -2342;
 136                 e.(antilag_origins[i]) = e.origin;
 137         }
 138         e.antilag_index = ANTILAG_MAX_ORIGINS - 1; // next one is 0
 139 }