qcsrc/server/antilag.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "vehicles/vehicles_def.qh"
   7     #include "antilag.qh"
   8 #endif
   9
  10 const float ANTILAG_MAX_ORIGINS = 64;
  11 .vector antilag_origins[ANTILAG_MAX_ORIGINS];
  12 .float antilag_times[ANTILAG_MAX_ORIGINS];
  13 .float antilag_index;
  14 .vector antilag_saved_origin;
  15 .float antilag_takenback;
  16
  17 .float antilag_debug;
  18
  19 void antilag_record(entity e, float t)
  20 {
  21     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
  22         return;
  23
  24     if(e.vehicle)
  25         antilag_record(e.vehicle, t);
  26
  27         if(time < e.(antilag_times[e.antilag_index]))
  28                 return;
  29         e.antilag_index = e.antilag_index + 1;
  30         if(e.antilag_index >= ANTILAG_MAX_ORIGINS)
  31                 e.antilag_index = 0;
  32         e.(antilag_times[e.antilag_index]) = t;
  33         e.(antilag_origins[e.antilag_index]) = e.origin;
  34
  35         if(e.antilag_debug)
  36                 te_spark(antilag_takebackorigin(e, t - e.antilag_debug), '0 0 0', 32);
  37
  38 }
  39
  40 // finds the index BEFORE t
  41 float antilag_find(entity e, float t)
  42 {
  43         float i;
  44
  45         for(i = e.antilag_index; i > 0; --i)
  46                 if(e.(antilag_times[i]) >= t)
  47                         if(e.(antilag_times[i - 1]) < t)
  48                                 return i - 1;
  49
  50         if(e.(antilag_times[0]) >= t)
  51                 if(e.(antilag_times[ANTILAG_MAX_ORIGINS - 1]) < t)
  52                         return ANTILAG_MAX_ORIGINS - 1;
  53
  54         for(i = ANTILAG_MAX_ORIGINS - 1; i > e.antilag_index + 1; --i)
  55                 if(e.(antilag_times[i]) >= t)
  56                         if(e.(antilag_times[i - 1]) < t)
  57                                 return i - 1;
  58
  59         // if we get here, t is sandwiched nowhere, so let's assume it's in the present
  60         return -1;
  61 }
  62
  63 vector lerpv(float t0, vector v0, float t1, vector v1, float t)
  64 {
  65         return v0 + (v1 - v0) * ((t - t0) / (t1 - t0));
  66 }
  67
  68 vector antilag_takebackorigin(entity e, float t)
  69 {
  70         float i0, i1;
  71
  72         i0 = antilag_find(e, t);
  73         if(i0 < 0)
  74         {
  75                 // IN THE PRESENT
  76                 if(e.antilag_takenback)
  77                         return e.antilag_saved_origin;
  78                 else
  79                         return e.origin;
  80         }
  81         i1 = i0 + 1;
  82         if(i1 >= ANTILAG_MAX_ORIGINS)
  83                 i1 = 0;
  84
  85         return lerpv(e.(antilag_times[i0]), e.(antilag_origins[i0]), e.(antilag_times[i1]), e.(antilag_origins[i1]), t);
  86 }
  87
  88 vector antilag_takebackavgvelocity(entity e, float t0, float t1)
  89 {
  90         vector o0, o1;
  91
  92         if(t0 >= t1)
  93                 return '0 0 0';
  94         o0 = antilag_takebackorigin(e, t0);
  95         o1 = antilag_takebackorigin(e, t1);
  96         return (o1 - o0) * (1 / (t1 - t0));
  97 }
  98
  99 void antilag_takeback(entity e, float t)
 100 {
 101
 102     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
 103         return;
 104
 105         if(e.vehicle)
 106                 antilag_takeback(e.vehicle, t);
 107
 108         if(!e.antilag_takenback)
 109                 e.antilag_saved_origin = e.origin;
 110
 111         setorigin(e, antilag_takebackorigin(e, t));
 112         e.antilag_takenback = true;
 113 }
 114
 115 void antilag_restore(entity e)
 116 {
 117     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
 118         return;
 119
 120         if(e.vehicle)
 121                 antilag_restore(e.vehicle);
 122
 123         if(!e.antilag_takenback)
 124                 return;
 125
 126         setorigin(e, e.antilag_saved_origin);
 127         e.antilag_takenback = false;
 128 }
 129
 130 void antilag_clear(entity e)
 131 {
 132         float i;
 133
 134         antilag_restore(e);
 135         for(i = 0; i < ANTILAG_MAX_ORIGINS; ++i)
 136         {
 137                 e.(antilag_times[i]) = -2342;
 138                 e.(antilag_origins[i]) = e.origin;
 139         }
 140         e.antilag_index = ANTILAG_MAX_ORIGINS - 1; // next one is 0
 141 }