qcsrc/server/antilag.qc

   1 #define ANTILAG_MAX_ORIGINS 64
   2 .vector antilag_origins[ANTILAG_MAX_ORIGINS];
   3 .float antilag_times[ANTILAG_MAX_ORIGINS];
   4 .float antilag_index;
   5 .vector antilag_saved_origin;
   6 .float antilag_takenback;
   7
   8 .float antilag_debug;
   9
  10 void antilag_record(entity e, float t)
  11 {
  12     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
  13         return;
  14
  15     if(e.vehicle)
  16         antilag_record(e.vehicle, t);
  17
  18         if(time < e.(antilag_times[e.antilag_index]))
  19                 return;
  20         e.antilag_index = e.antilag_index + 1;
  21         if(e.antilag_index >= ANTILAG_MAX_ORIGINS)
  22                 e.antilag_index = 0;
  23         e.(antilag_times[e.antilag_index]) = t;
  24         e.(antilag_origins[e.antilag_index]) = e.origin;
  25
  26         if(e.antilag_debug)
  27                 te_spark(antilag_takebackorigin(e, t - e.antilag_debug), '0 0 0', 32);
  28
  29 }
  30
  31 // finds the index BEFORE t
  32 float antilag_find(entity e, float t)
  33 {
  34         float i;
  35
  36         for(i = e.antilag_index; i > 0; --i)
  37                 if(e.(antilag_times[i]) >= t)
  38                         if(e.(antilag_times[i - 1]) < t)
  39                                 return i - 1;
  40
  41         if(e.(antilag_times[0]) >= t)
  42                 if(e.(antilag_times[ANTILAG_MAX_ORIGINS - 1]) < t)
  43                         return ANTILAG_MAX_ORIGINS - 1;
  44
  45         for(i = ANTILAG_MAX_ORIGINS - 1; i > e.antilag_index + 1; --i)
  46                 if(e.(antilag_times[i]) >= t)
  47                         if(e.(antilag_times[i - 1]) < t)
  48                                 return i - 1;
  49
  50         // if we get here, t is sandwiched nowhere, so let's assume it's in the present
  51         return -1;
  52 }
  53
  54 vector lerpv(float t0, vector v0, float t1, vector v1, float t)
  55 {
  56         return v0 + (v1 - v0) * ((t - t0) / (t1 - t0));
  57 }
  58
  59 vector antilag_takebackorigin(entity e, float t)
  60 {
  61         float i0, i1;
  62
  63         i0 = antilag_find(e, t);
  64         if(i0 < 0)
  65         {
  66                 // IN THE PRESENT
  67                 if(e.antilag_takenback)
  68                         return e.antilag_saved_origin;
  69                 else
  70                         return e.origin;
  71         }
  72         i1 = i0 + 1;
  73         if(i1 >= ANTILAG_MAX_ORIGINS)
  74                 i1 = 0;
  75
  76         return lerpv(e.(antilag_times[i0]), e.(antilag_origins[i0]), e.(antilag_times[i1]), e.(antilag_origins[i1]), t);
  77 }
  78
  79 vector antilag_takebackavgvelocity(entity e, float t0, float t1)
  80 {
  81         vector o0, o1;
  82
  83         if(t0 >= t1)
  84                 return '0 0 0';
  85         o0 = antilag_takebackorigin(e, t0);
  86         o1 = antilag_takebackorigin(e, t1);
  87         return (o1 - o0) * (1 / (t1 - t0));
  88 }
  89
  90 void antilag_takeback(entity e, float t)
  91 {
  92
  93     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
  94         return;
  95
  96         if(e.vehicle)
  97                 antilag_takeback(e.vehicle, t);
  98
  99         if(!e.antilag_takenback)
 100                 e.antilag_saved_origin = e.origin;
 101
 102         setorigin(e, antilag_takebackorigin(e, t));
 103         e.antilag_takenback = TRUE;
 104 }
 105
 106 void antilag_restore(entity e)
 107 {
 108     if (e.vehicle && e.vehicle.vehicle_flags == VHF_PLAYERSLOT)
 109         return;
 110
 111         if(e.vehicle)
 112                 antilag_restore(e.vehicle);
 113
 114         if(!e.antilag_takenback)
 115                 return;
 116
 117         setorigin(e, e.antilag_saved_origin);
 118         e.antilag_takenback = FALSE;
 119 }
 120
 121 void antilag_clear(entity e)
 122 {
 123         float i;
 124
 125         antilag_restore(e);
 126         for(i = 0; i < ANTILAG_MAX_ORIGINS; ++i)
 127         {
 128                 e.(antilag_times[i]) = -2342;
 129                 e.(antilag_origins[i]) = e.origin;
 130         }
 131         e.antilag_index = ANTILAG_MAX_ORIGINS - 1; // next one is 0
 132 }