Fix this bug: playing Arena the field score is never updated in the scoreboard. The...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / arena.qc
1 float maxspawned;
2 float numspawned;
3 float arena_roundbased;
4 .float spawned;
5 .entity spawnqueue_next;
6 .entity spawnqueue_prev;
7 .float spawnqueue_in;
8 entity spawnqueue_first;
9 entity spawnqueue_last;
10 entity champion;
11 float warmup;
12 float allowed_to_spawn;
13 float ca_players;
14 float required_ca_players;
15 .float caplayer;
16
17 void PutObserverInServer();
18 void PutClientInServer();
19 void(entity e) ReturnFlag;
20 void dom_controlpoint_setup();
21 void onslaught_generator_reset();
22 void onslaught_controlpoint_reset();
23 void func_breakable_reset();
24 void assault_objective_reset();
25 void target_assault_roundend_reset();
26
27 /**
28  * Resets the state of all clients, items, flags, runes, keys, weapons, waypoints, ... of the map.
29  * Sets the 'warmup' global variable.
30  */
31 void reset_map(float dorespawn)
32 {
33         entity oldself;
34         oldself = self;
35
36         if(g_arena && cvar("g_arena_warmup"))
37                 warmup = time + cvar("g_arena_warmup");
38         else if(g_ca) {
39                 warmup = time + cvar("g_ca_warmup");
40                 allowed_to_spawn = 1;
41         }
42
43         lms_lowest_lives = 999;
44         lms_next_place = player_count;
45
46         race_ReadyRestart();
47
48         for(self = world; (self = nextent(self)); )
49         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
50         {
51                 if(self.reset)
52                 {
53                         self.reset();
54                         continue;
55                 }
56
57                 if(self.team_saved)
58                         self.team = self.team_saved;
59
60                 if(self.flags & FL_PROJECTILE) // remove any projectiles left
61                 {
62                         stopsound(self, CHAN_PAIN);
63                         remove(self);
64                 }
65         }
66
67         // Waypoints and assault start come LAST
68         for(self = world; (self = nextent(self)); )
69         if(clienttype(self) == CLIENTTYPE_NOTACLIENT)
70         {
71                 if(self.reset2)
72                 {
73                         self.reset2();
74                         continue;
75                 }
76         }
77
78         // Moving the player reset code here since the player-reset depends
79         // on spawnpoint entities which have to be reset first --blub
80         if(dorespawn)
81         FOR_EACH_CLIENT(self) {
82                 if(self.flags & FL_CLIENT)                              // reset all players
83                 {
84                         if(g_arena)
85                         {
86                                 if(self.spawned)
87                                         PutClientInServer();
88                                 else
89                                         PutObserverInServer();
90                         }
91                         else if(g_ca && self.caplayer) {
92                                 self.classname = "player";
93                                 PutClientInServer();
94                         }
95                         else
96                         {
97                                 /*
98                                 only reset players if a restart countdown is active
99                                 this can either be due to cvar sv_ready_restart_after_countdown having set
100                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
101                                 sv_ready_restart_after_countdown is not used and countdown is still running
102                                 */
103                                 if (restart_mapalreadyrestarted || (time < game_starttime))
104                                 {
105                                         //NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
106                                         if (self.classname == "player") {
107                                                 //PlayerScore_Clear(self);
108                                                 if(g_lms)
109                                                         PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives());
110                                                 self.killcount = 0;
111                                                 //stop the player from moving so that he stands still once he gets respawned
112                                                 self.velocity = '0 0 0';
113                                                 self.avelocity = '0 0 0';
114                                                 self.movement = '0 0 0';
115                                                 PutClientInServer();
116                                         }
117                                 }
118                         }
119                 }
120         }
121
122         if(g_keyhunt)
123                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round")+(game_starttime - time), "", kh_StartRound);
124
125         if(g_arena || g_ca)
126         if(champion && champion.classname == "player" && player_count > 1)
127                 UpdateFrags(champion, +1);
128
129         self = oldself;
130 }
131
132 void Spawnqueue_Insert(entity e)
133 {
134         if(e.spawnqueue_in)
135                 return;
136         dprint(strcat("Into queue: ", e.netname, "\n"));
137         e.spawnqueue_in = TRUE;
138         e.spawnqueue_prev = spawnqueue_last;
139         e.spawnqueue_next = world;
140         if(spawnqueue_last)
141                 spawnqueue_last.spawnqueue_next = e;
142         spawnqueue_last = e;
143         if(!spawnqueue_first)
144                 spawnqueue_first = e;
145 }
146
147 void Spawnqueue_Remove(entity e)
148 {
149         if(!e.spawnqueue_in)
150                 return;
151         dprint(strcat("Out of queue: ", e.netname, "\n"));
152         e.spawnqueue_in = FALSE;
153         if(e == spawnqueue_first)
154                 spawnqueue_first = e.spawnqueue_next;
155         if(e == spawnqueue_last)
156                 spawnqueue_last = e.spawnqueue_prev;
157         if(e.spawnqueue_prev)
158                 e.spawnqueue_prev.spawnqueue_next = e.spawnqueue_next;
159         if(e.spawnqueue_next)
160                 e.spawnqueue_next.spawnqueue_prev = e.spawnqueue_prev;
161         e.spawnqueue_next = world;
162         e.spawnqueue_prev = world;
163 }
164
165 void Spawnqueue_Unmark(entity e)
166 {
167         if(!e.spawned)
168                 return;
169         e.spawned = FALSE;
170         numspawned = numspawned - 1;
171 }
172
173 void Spawnqueue_Mark(entity e)
174 {
175         if(e.spawned)
176                 return;
177         e.spawned = TRUE;
178         numspawned = numspawned + 1;
179 }
180
181 /**
182  * If roundbased arena game mode is active, it centerprints the texts for the
183  * player when player is waiting for the countdown to finish.
184  * Blocks the players movement while countdown is active.
185  * Unblocks the player once the countdown is over.
186  *
187  * Called in PlayerPostThink()
188  */
189 float roundStartTime_prev; // prevent networkspam
190 void Arena_Warmup()
191 {
192         float f;
193         string msg;
194
195         if((!g_arena && !g_ca) || (g_arena && !arena_roundbased) || (time < game_starttime))
196                 return;
197
198         f = floor(warmup - time + 1);
199
200         allowed_to_spawn = 0;
201
202         if(g_ca && (ca_players < required_ca_players || inWarmupStage))
203                 allowed_to_spawn = 1;
204
205         msg = NEWLINES;
206         if(time < warmup && !inWarmupStage)
207         {
208                 if (g_ca)
209                         allowed_to_spawn = 1;
210                 if(champion && g_arena)
211                         msg = strcat("The Champion is ", champion.netname, "^7\n");
212                         //centerprint(self, strcat(msg, "The Champion is ", champion.netname, "^7\n"));
213
214                 if(f != roundStartTime_prev) {
215                         msg = strcat(msg, "Round will start in ", ftos(f),"\n");
216                         //centerprint(self, strcat("Round will start in ", ftos(f),"\n"));
217                         roundStartTime_prev = f;
218                         if(f == 5)
219                                 Announce("prepareforbattle");
220                         else if(f == 3)
221                                 Announce("3");
222                         else if(f == 2)
223                                 Announce("2");
224                         else if(f == 1)
225                                 Announce("1");
226
227                         centerprint(self, msg);
228                 }
229
230                 if (g_arena) {
231                         if(self.spawned && self.classname == "player")
232                                 self.movetype = MOVETYPE_NONE;
233
234                         self.velocity = '0 0 0';
235                         self.avelocity = '0 0 0';
236                         self.movement = '0 0 0';
237                         //self.fixangle = TRUE;
238                 }
239         }
240
241         else if(f > -1 && f != roundStartTime_prev)
242         {
243                 roundStartTime_prev = f;
244                 Announce("begin");
245                 centerprint(self, "^1Begin!\n");
246
247                 if(g_ca) {
248                         ca_players = 0;
249
250                         FOR_EACH_PLAYER(self)
251                                 ca_players += 1;
252                 }
253         }
254
255         if(self.classname == "player" && self.health > 0)
256                 self.movetype = MOVETYPE_WALK;
257 }
258
259 float next_round;
260 /**
261  * This function finds out whether an arena round is over 1 player is left.
262  * It determines the last player who's still alive and saves it's entity reference
263  * in the global variable 'champion'. Then the new enemy/enemies are put into the server.
264  *
265  * Gets called in StartFrame()
266  */
267 void Spawnqueue_Check()
268 {
269         if(time < warmup + 1 || inWarmupStage)
270                 return;
271
272         if(g_ca) {
273                 // check the amount of spawned players in each team
274                 float redspawned, bluespawned;
275                 FOR_EACH_PLAYER(self) {
276                         if (self.team == COLOR_TEAM1) redspawned += 1;
277                         else if (self.team == COLOR_TEAM2) bluespawned += 1;
278                 }
279
280                 required_ca_players = max(2, fabs(cvar("bot_vs_human") + 1));
281
282                 if(ca_players < required_ca_players && (redspawned && bluespawned)) {
283                         reset_map(TRUE);
284                 }
285                 else if(ca_players < required_ca_players) {
286                         FOR_EACH_PLAYER(self)
287                                 centerprint(self, strcat("^1Need at least 1 player in each team to play CA", "^7\n"));
288
289                         allowed_to_spawn = 1;
290                         return;
291                 }
292                 else if(!next_round) {
293                         if((redspawned && !bluespawned) || (bluespawned && !redspawned)) {
294                                 next_round = time + 5;
295
296                                 champion = find(world, classname, "player");
297                                 string champion_team;
298                                 if(champion.team == COLOR_TEAM1) {
299                                         champion_team = "^1Red team";
300                                         play2all("ctf/red_capture.wav");
301                                 }
302                                 else if(champion.team == COLOR_TEAM2) {
303                                         champion_team = "^4Blue team";
304                                         play2all("ctf/blue_capture.wav");
305                                 }
306                                 FOR_EACH_CLIENT(self) centerprint(self, strcat(champion_team, "^7 wins the round.", "^7\n"));
307                         }
308                         else if(!redspawned && !bluespawned) {
309                                 FOR_EACH_CLIENT(self) centerprint(self, strcat("^7Round tied.", "^7\n"));
310                                 next_round = time + 5;
311                         }
312                 }
313
314                 if((next_round && next_round < time))
315                 {
316                         next_round = 0;
317                         reset_map(TRUE);
318                 }
319         } else { // arena
320                 //extend next_round if it isn't set yet and only 1 player is spawned
321                 if(!next_round)
322                 if(numspawned < 2)
323                         next_round = time + 3;
324
325                 if(!arena_roundbased || (next_round && next_round < time && player_count > 1))
326                 {
327                         next_round = 0;
328
329                         if(arena_roundbased)
330                         {
331                                 champion = find(world, classname, "player");
332                                 while(champion && champion.deadflag)
333                                         champion = find(champion, classname, "player");
334                                 reset_map(TRUE);
335                         }
336
337                         while(numspawned < maxspawned && spawnqueue_first)
338                         {
339                                 self = spawnqueue_first;
340
341                                 bprint ("^4", self.netname, "^4 is the next challenger\n");
342
343                                 Spawnqueue_Remove(self);
344                                 Spawnqueue_Mark(self);
345
346                                 self.classname = "player";
347                                 PutClientInServer();
348                         }
349                 }
350         }
351 }