qcsrc/server/attic/nexball.qc

   1 //EF_BRIGHTFIELD|EF_BRIGHTLIGHT|EF_DIMLIGHT|EF_BLUE|EF_RED|EF_FLAME
   2 #define BALL_EFFECTMASK 1229
   3 #define BALL_MINS '-16 -16 -16'  // The model is 24*24*24
   4 #define BALL_MAXS '16 16 16'
   5 #define BALL_ATTACHORG '3 0 16'
   6 #define BALL_SPRITECOLOR '.91 .85 .62'
   7 #define BALL_FOOT   1
   8 #define BALL_BASKET 2
   9 //spawnflags
  10 #define GOAL_TOUCHPLAYER 1
  11 //goal types
  12 #define GOAL_FAULT -1
  13 #define GOAL_OUT -2
  14
  15 #define CVTOV(s) s = cvar( #s )
  16
  17 float g_nexball_football_boost_forward;
  18 float g_nexball_football_boost_up;
  19 float g_nexball_football_physics;
  20 float g_nexball_delay_idle;
  21 float g_nexball_basketball_delay_hold;
  22 float g_nexball_basketball_delay_hold_forteam;
  23 float g_nexball_basketball_effects_default;
  24 float g_nexball_basketball_teamsteal;
  25 float balls;
  26 float ball_scale;
  27 float nb_teams;
  28
  29 .float teamtime;
  30
  31 .float nb_dropperid;
  32 .float nb_droptime;
  33
  34 void nb_delayedinit();
  35 void nb_init() // Called early (worldspawn stage)
  36 {
  37         CVTOV(g_nexball_meter_period); //sent with the client init entity
  38         if (g_nexball_meter_period <= 0)
  39                 g_nexball_meter_period = 2; // avoid division by zero etc. due to silly users
  40         g_nexball_meter_period = rint(g_nexball_meter_period * 32) / 32; //Round to 1/32ths to send as a byte multiplied by 32
  41         addstat(STAT_NB_METERSTART, AS_FLOAT, metertime);
  42
  43         // General settings
  44         CVTOV(g_nexball_football_boost_forward);   //100
  45         CVTOV(g_nexball_football_boost_up);        //200
  46         CVTOV(g_nexball_delay_idle);               //10
  47         CVTOV(g_nexball_football_physics);         //0
  48
  49         radar_showennemies = autocvar_g_nexball_radar_showallplayers;
  50
  51         InitializeEntity(world, nb_delayedinit, INITPRIO_GAMETYPE);
  52 }
  53
  54 float OtherTeam(float t)  //works only if there are two teams on the map!
  55 {
  56         entity e;
  57         e = find(world, classname, "nexball_team");
  58         if (e.team == t)
  59                 e = find(e, classname, "nexball_team");
  60         return e.team;
  61 }
  62
  63 void ResetBall();
  64
  65 void LogNB(string mode, entity actor)
  66 {
  67         string s;
  68         if(!autocvar_sv_eventlog)
  69                 return;
  70         s = strcat(":nexball:", mode);
  71         if(actor != world)
  72                 s = strcat(s, ":", ftos(actor.playerid));
  73         GameLogEcho(s);
  74 }
  75
  76 void ball_restart (void)
  77 {
  78         if(self.owner)
  79                 DropBall(self, self.owner.origin, '0 0 0');
  80         ResetBall();
  81 }
  82
  83 void nexball_setstatus (void)
  84 {
  85         entity oldself;
  86         self.items &~= IT_KEY1;
  87         if (self.ballcarried)
  88         {
  89                 if (self.ballcarried.teamtime && (self.ballcarried.teamtime < time))
  90                 {
  91                         bprint("The ", ColoredTeamName(self.team), " held the ball for too long.\n");
  92                         oldself = self;
  93                         self = self.ballcarried;
  94                         DropBall(self, self.owner.origin, '0 0 0');
  95                         ResetBall();
  96                         self = oldself;
  97                 } else
  98                         self.items |= IT_KEY1;
  99         }
 100 }
 101
 102 void relocate_nexball (void)
 103 {
 104         tracebox(self.origin, BALL_MINS, BALL_MAXS, self.origin, TRUE, self);
 105         if (trace_startsolid)
 106         {
 107                 vector o;
 108                 o = self.origin;
 109                 if(!move_out_of_solid(self))
 110                         objerror("could not get out of solid at all!");
 111                 print("^1NOTE: this map needs FIXING. ", self.classname, " at ", vtos(o - '0 0 1'));
 112                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 113                 print(" ", ftos(self.origin_y - o_y));
 114                 print(" ", ftos(self.origin_z - o_z), "'\n");
 115                 self.origin = o;
 116         }
 117 }
 118
 119 void basketball_touch();
 120 void football_touch();
 121
 122 void DropOwner (void)
 123 {
 124         entity ownr;
 125         ownr = self.owner;
 126         DropBall(self, ownr.origin, ownr.velocity);
 127         makevectors(ownr.v_angle_y * '0 1 0');
 128         ownr.velocity += ('0 0 0.75' - v_forward) * 1000;
 129         ownr.flags &~= FL_ONGROUND;
 130 }
 131
 132 void GiveBall (entity plyr, entity ball)
 133 {
 134         entity ownr;
 135
 136         if ((ownr = ball.owner))
 137         {
 138                 ownr.effects &~= g_nexball_basketball_effects_default;
 139                 ownr.ballcarried = world;
 140                 if (ownr.metertime)
 141                 {
 142                         ownr.metertime = 0;
 143                         ownr.weaponentity.state = WS_READY;
 144                 }
 145                 WaypointSprite_Kill(ownr.waypointsprite_attachedforcarrier);
 146         }
 147         else
 148         {
 149                 WaypointSprite_Kill(ball.waypointsprite_attachedforcarrier);
 150         }
 151
 152         setattachment(ball, plyr, "");
 153         setorigin(ball, BALL_ATTACHORG);
 154
 155         if (ball.team != plyr.team)
 156                 ball.teamtime = time + g_nexball_basketball_delay_hold_forteam;
 157
 158         ball.owner = ball.pusher = plyr; //"owner" is set to the player carrying, "pusher" to the last player who touched it
 159         ball.team = plyr.team;
 160         plyr.ballcarried = ball;
 161         ball.nb_dropperid = plyr.playerid;
 162
 163         plyr.effects |= g_nexball_basketball_effects_default;
 164         ball.effects &~= g_nexball_basketball_effects_default;
 165
 166         ball.velocity = '0 0 0';
 167         ball.movetype = MOVETYPE_NONE;
 168         ball.touch = func_null;
 169         ball.effects |= EF_NOSHADOW;
 170         ball.scale = 1; // scale down.
 171
 172         WaypointSprite_AttachCarrier("nb-ball", plyr, RADARICON_FLAGCARRIER, BALL_SPRITECOLOR);
 173         WaypointSprite_UpdateRule(plyr.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 174
 175         if (g_nexball_basketball_delay_hold)
 176         {
 177                 ball.think = DropOwner;
 178                 ball.nextthink = time + g_nexball_basketball_delay_hold;
 179         }
 180 }
 181
 182 void DropBall (entity ball, vector org, vector vel)
 183 {
 184         ball.effects |= g_nexball_basketball_effects_default;
 185         ball.effects &~= EF_NOSHADOW;
 186         ball.owner.effects &~= g_nexball_basketball_effects_default;
 187
 188         setattachment(ball, world, "");
 189         setorigin (ball, org);
 190         ball.movetype = MOVETYPE_BOUNCE;
 191         ball.flags &~= FL_ONGROUND;
 192         ball.scale = ball_scale;
 193         ball.velocity = vel;
 194         ball.nb_droptime = time;
 195         ball.touch = basketball_touch;
 196         ball.think = ResetBall;
 197         ball.nextthink = min(time + g_nexball_delay_idle, ball.teamtime);
 198
 199         if (ball.owner.metertime)
 200         {
 201                 ball.owner.metertime = 0;
 202                 ball.owner.weaponentity.state = WS_READY;
 203         }
 204
 205         WaypointSprite_Kill(ball.owner.waypointsprite_attachedforcarrier);
 206         WaypointSprite_Spawn("nb-ball", 0, 0, ball, '0 0 64', world, ball.team, ball, waypointsprite_attachedforcarrier, FALSE, RADARICON_FLAGCARRIER, BALL_SPRITECOLOR); // no health bar please
 207         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 208
 209         ball.owner.ballcarried = world;
 210         ball.owner = world;
 211 }
 212
 213 void InitBall (void)
 214 {
 215         if (gameover) return;
 216         self.flags &~= FL_ONGROUND;
 217         self.movetype = MOVETYPE_BOUNCE;
 218         if (self.classname == "nexball_basketball")
 219                 self.touch = basketball_touch;
 220         else if (self.classname == "nexball_football")
 221                 self.touch = football_touch;
 222         self.cnt = 0;
 223         self.think = ResetBall;
 224         self.nextthink = time + g_nexball_delay_idle + 3;
 225         self.teamtime = 0;
 226         self.pusher = world;
 227         self.team = FALSE;
 228         sound (self, CH_TRIGGER, self.noise1, VOL_BASE, ATTN_NORM);
 229         WaypointSprite_Ping(self.waypointsprite_attachedforcarrier);
 230         LogNB("init", world);
 231 }
 232
 233 void ResetBall (void)
 234 {
 235         if (self.cnt < 2) { // step 1
 236                 if (time == self.teamtime)
 237                         bprint("The ", ColoredTeamName(self.team), " held the ball for too long.\n");
 238                 self.touch = func_null;
 239                 self.movetype = MOVETYPE_NOCLIP;
 240                 self.velocity = '0 0 0'; // just in case?
 241                 if(!self.cnt)
 242                         LogNB("resetidle", world);
 243                 self.cnt = 2;
 244                 self.nextthink = time;
 245         } else if (self.cnt < 4) { // step 2 and 3
 246 //              dprint("Step ", ftos(self.cnt), ": Calculated velocity: ", vtos(self.spawnorigin - self.origin), ", time: ", ftos(time), "\n");
 247                 self.velocity = (self.spawnorigin - self.origin) * (self.cnt - 1); // 1 or 0.5 second movement
 248                 self.nextthink = time + 0.5;
 249                 self.cnt += 1;
 250         } else { // step 4
 251 //              dprint("Step 4: time: ", ftos(time), "\n");
 252                 if (vlen(self.origin - self.spawnorigin) > 10) // should not happen anymore
 253                         dprint("The ball moved too far away from its spawn origin.\nOffset: ",
 254                                vtos(self.origin - self.spawnorigin), " Velocity: ", vtos(self.velocity), "\n");
 255                 self.velocity = '0 0 0';
 256                 setorigin(self, self.spawnorigin); // make sure it's positioned correctly anyway
 257                 self.movetype = MOVETYPE_NONE;
 258                 self.think = InitBall;
 259                 self.nextthink = max(time, game_starttime) + autocvar_g_nexball_delay_start;
 260         }
 261 }
 262
 263 void football_touch (void)
 264 {
 265         if (other.solid == SOLID_BSP) {
 266                 if (time > self.lastground + 0.1)
 267                 {
 268                         sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTN_NORM);
 269                         self.lastground = time;
 270                 }
 271                 if (vlen(self.velocity) && !self.cnt)
 272                         self.nextthink = time + g_nexball_delay_idle;
 273                 return;
 274         }
 275         if (other.classname != "player")
 276                 return;
 277         if (other.health < 1)
 278                 return;
 279         if (!self.cnt)
 280                 self.nextthink = time + g_nexball_delay_idle;
 281
 282         self.pusher = other;
 283         self.team = other.team;
 284
 285         if (g_nexball_football_physics == -1) { // MrBougo try 1, before decompiling Rev's original
 286                 if (vlen(other.velocity))
 287                         self.velocity = other.velocity * 1.5 + '0 0 1' * g_nexball_football_boost_up;
 288         } else if (g_nexball_football_physics == 1) { // MrBougo's modded Rev style: partially independant of the height of the aiming point
 289                 makevectors(other.v_angle);
 290                 self.velocity = other.velocity + v_forward * g_nexball_football_boost_forward + '0 0 1' * g_nexball_football_boost_up;
 291         } else if (g_nexball_football_physics == 2) { // 2nd mod try: totally independant. Really playable!
 292                 makevectors(other.v_angle_y * '0 1 0');
 293                 self.velocity = other.velocity + v_forward * g_nexball_football_boost_forward + v_up * g_nexball_football_boost_up;
 294         } else { // Revenant's original style (from the original mod's disassembly, acknowledged by Revenant)
 295                 makevectors(other.v_angle);
 296                 self.velocity = other.velocity + v_forward * g_nexball_football_boost_forward + v_up * g_nexball_football_boost_up;
 297         }
 298         self.avelocity = -250 * v_forward;  // maybe there is a way to make it look better?
 299 }
 300
 301 void basketball_touch (void)
 302 {
 303         if (other.ballcarried)
 304         {
 305                 football_touch();
 306                 return;
 307         }
 308         if (!self.cnt && other.classname == "player" && (other.playerid != self.nb_dropperid || time > self.nb_droptime + autocvar_g_nexball_delay_collect)) {
 309                 if (other.health <= 0)
 310                         return;
 311                 LogNB("caught", other);
 312                 GiveBall(other, self);
 313         } else if (other.solid == SOLID_BSP) {
 314                 sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTN_NORM);
 315                 if (vlen(self.velocity) && !self.cnt)
 316                         self.nextthink = min(time + g_nexball_delay_idle, self.teamtime);
 317         }
 318 }
 319
 320 void GoalTouch (void)
 321 {
 322         entity ball;
 323         float isclient, pscore, otherteam;
 324         string pname;
 325
 326         if (gameover) return;
 327         if ((self.spawnflags & GOAL_TOUCHPLAYER) && other.ballcarried)
 328                 ball = other.ballcarried;
 329         else
 330                 ball = other;
 331         if (ball.classname != "nexball_basketball")
 332         if (ball.classname != "nexball_football")
 333                 return;
 334         if ((!ball.pusher && self.team != GOAL_OUT) || ball.cnt)
 335                 return;
 336         EXACTTRIGGER_TOUCH;
 337
 338
 339         if(nb_teams == 2)
 340                 otherteam = OtherTeam(ball.team);
 341
 342         if((isclient = ball.pusher.flags & FL_CLIENT))
 343                 pname = ball.pusher.netname;
 344         else
 345                 pname = "Someone (?)";
 346
 347         if        (ball.team == self.team) //owngoal (regular goals)
 348         {
 349                 LogNB("owngoal", ball.pusher);
 350                 bprint("Boo! ", pname, "^7 scored a goal against their own team!\n");
 351                 pscore = -1;
 352         } else if (self.team == GOAL_FAULT) {
 353                 LogNB("fault", ball.pusher);
 354                 if (nb_teams == 2)
 355                         bprint(ColoredTeamName(otherteam), " gets a point due to ", pname, "^7's silliness.\n");
 356                 else
 357                         bprint(ColoredTeamName(ball.team), " loses a point due to ", pname, "^7's silliness.\n");
 358                 pscore = -1;
 359         } else if (self.team == GOAL_OUT) {
 360                 LogNB("out", ball.pusher);
 361                 if ((self.spawnflags & GOAL_TOUCHPLAYER) && ball.owner)
 362                         bprint(pname, "^7 went out of bounds.\n");
 363                 else
 364                         bprint("The ball was returned.\n");
 365                 pscore = 0;
 366         } else {                           //score
 367                 LogNB(strcat("goal:", ftos(self.team)), ball.pusher);
 368                 bprint("Goaaaaal! ", pname, "^7 scored a point for the ", ColoredTeamName(ball.team), ".\n");
 369                 pscore = 1;
 370         }
 371
 372         sound (ball, CH_TRIGGER, self.noise, VOL_BASE, ATTN_NONE);
 373
 374         if(ball.team && pscore)
 375         {
 376                 if (nb_teams == 2 && pscore < 0)
 377                         TeamScore_AddToTeam(otherteam, ST_NEXBALL_GOALS, -pscore);
 378                 else
 379                         TeamScore_AddToTeam(ball.team, ST_NEXBALL_GOALS, pscore);
 380         }
 381         if (isclient)
 382         {
 383                 if (pscore > 0)
 384                         PlayerScore_Add(ball.pusher, SP_NEXBALL_GOALS, pscore);
 385                 else if (pscore < 0)
 386                         PlayerScore_Add(ball.pusher, SP_NEXBALL_FAULTS, -pscore);
 387         }
 388
 389         if (ball.owner) // Happens on spawnflag GOAL_TOUCHPLAYER
 390                 DropBall(ball, ball.owner.origin, ball.owner.velocity);
 391
 392         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 393
 394         ball.cnt = 1;
 395         ball.think = ResetBall;
 396         if (ball.classname == "nexball_basketball")
 397                 ball.touch = football_touch; // better than func_null: football control until the ball gets reset
 398         ball.nextthink = time + autocvar_g_nexball_delay_goal * (self.team != GOAL_OUT);
 399 }
 400
 401 //=======================//
 402 //       team ents       //
 403 //=======================//
 404 void spawnfunc_nexball_team (void)
 405 {
 406         if(!g_nexball) { remove(self); return; }
 407         self.team = self.cnt + 1;
 408 }
 409
 410 void nb_spawnteam (string teamname, float teamcolor)
 411 {
 412         dprint("^2spawned team ", teamname, "\n");
 413         entity e;
 414         e = spawn();
 415         e.classname = "nexball_team";
 416         e.netname = teamname;
 417         e.cnt = teamcolor;
 418         e.team = e.cnt + 1;
 419         nb_teams += 1;
 420 }
 421
 422 void nb_spawnteams (void)
 423 {
 424         float t_r, t_b, t_y, t_p;
 425         entity e;
 426         for(e = world; (e = find(e, classname, "nexball_goal")); )
 427         {
 428                 switch(e.team)
 429                 {
 430                         case FL_TEAM_1: if(!t_r) { nb_spawnteam ("Red", e.team-1)   ; t_r = 1; } break;
 431                         case FL_TEAM_2: if(!t_b) { nb_spawnteam ("Blue", e.team-1)  ; t_b = 1; } break;
 432                         case FL_TEAM_3: if(!t_y) { nb_spawnteam ("Yellow", e.team-1); t_y = 1; } break;
 433                         case FL_TEAM_4: if(!t_p) { nb_spawnteam ("Pink", e.team-1)  ; t_p = 1; } break;
 434                 }
 435         }
 436 }
 437
 438 void nb_delayedinit (void)
 439 {
 440         if (find(world, classname, "nexball_team") == world)
 441                 nb_spawnteams();
 442         ScoreRules_nexball(nb_teams);
 443 }
 444
 445
 446 //=======================//
 447 //      spawnfuncs       //
 448 //=======================//
 449
 450 void SpawnBall (void)
 451 {
 452         if(!g_nexball) { remove(self); return; }
 453
 454 //      balls += 4; // using the remaining bits to count balls will leave more than the max edict count, so it's fine
 455
 456         if (!self.model) {
 457                 self.model = "models/nexball/ball.md3";
 458                 self.scale = 1.3;
 459         }
 460
 461         precache_model (self.model);
 462         setmodel (self, self.model);
 463         setsize (self, BALL_MINS, BALL_MAXS);
 464         ball_scale = self.scale;
 465
 466         relocate_nexball();
 467         self.spawnorigin = self.origin;
 468
 469         self.effects = self.effects | EF_LOWPRECISION;
 470
 471         if (cvar(strcat("g_", self.classname, "_trail"))) //nexball_basketball :p
 472         {
 473                 self.glow_color = autocvar_g_nexball_trail_color;
 474                 self.glow_trail = TRUE;
 475         }
 476
 477         self.movetype = MOVETYPE_FLY;
 478
 479         if (!autocvar_g_nexball_sound_bounce)
 480                 self.noise = "";
 481         else if (!self.noise)
 482                 self.noise = "sound/nexball/bounce.wav";
 483                 //bounce sound placeholder (FIXME)
 484         if (!self.noise1)
 485                 self.noise1 = "sound/nexball/drop.wav";
 486                 //ball drop sound placeholder (FIXME)
 487         if (!self.noise2)
 488                 self.noise2 = "sound/nexball/steal.wav";
 489                 //stealing sound placeholder (FIXME)
 490         if (self.noise) precache_sound (self.noise);
 491         precache_sound (self.noise1);
 492         precache_sound (self.noise2);
 493
 494         WaypointSprite_AttachCarrier("nb-ball", self, RADARICON_FLAGCARRIER, BALL_SPRITECOLOR); // the ball's team is not set yet, no rule update needed
 495
 496         self.reset = ball_restart;
 497         self.think = InitBall;
 498         self.nextthink = game_starttime + autocvar_g_nexball_delay_start;
 499 }
 500
 501 void spawnfunc_nexball_basketball (void)
 502 {
 503         self.classname = "nexball_basketball";
 504         if not(balls & BALL_BASKET)
 505         {
 506                 CVTOV(g_nexball_basketball_effects_default);
 507                 CVTOV(g_nexball_basketball_delay_hold);
 508                 CVTOV(g_nexball_basketball_delay_hold_forteam);
 509                 CVTOV(g_nexball_basketball_teamsteal);
 510                 g_nexball_basketball_effects_default = g_nexball_basketball_effects_default & BALL_EFFECTMASK;
 511         }
 512         if (!self.effects)
 513                 self.effects = g_nexball_basketball_effects_default;
 514         self.solid = SOLID_TRIGGER;
 515         balls |= BALL_BASKET;
 516         self.bouncefactor = autocvar_g_nexball_basketball_bouncefactor;
 517         self.bouncestop = autocvar_g_nexball_basketball_bouncestop;
 518         SpawnBall();
 519 }
 520
 521 void spawnfunc_nexball_football (void)
 522 {
 523         self.classname = "nexball_football";
 524         self.solid = SOLID_TRIGGER;
 525         balls |= BALL_FOOT;
 526         self.bouncefactor = autocvar_g_nexball_football_bouncefactor;
 527         self.bouncestop = autocvar_g_nexball_football_bouncestop;
 528         SpawnBall();
 529 }
 530
 531 void SpawnGoal (void)
 532 {
 533         if(!g_nexball) { remove(self); return; }
 534         EXACTTRIGGER_INIT;
 535         self.classname = "nexball_goal";
 536         if (!self.noise)
 537                 self.noise = "ctf/respawn.wav";
 538         precache_sound(self.noise);
 539         self.touch = GoalTouch;
 540 }
 541
 542 void spawnfunc_nexball_redgoal (void)
 543 {
 544         self.team = FL_TEAM_1;
 545         SpawnGoal();
 546 }
 547 void spawnfunc_nexball_bluegoal (void)
 548 {
 549         self.team = FL_TEAM_2;
 550         SpawnGoal();
 551 }
 552 void spawnfunc_nexball_yellowgoal (void)
 553 {
 554         self.team = FL_TEAM_3;
 555         SpawnGoal();
 556 }
 557 void spawnfunc_nexball_pinkgoal (void)
 558 {
 559         self.team = FL_TEAM_4;
 560         SpawnGoal();
 561 }
 562
 563 void spawnfunc_nexball_fault (void)
 564 {
 565         self.team = GOAL_FAULT;
 566         if (!self.noise)
 567                 self.noise = "misc/typehit.wav";
 568         SpawnGoal();
 569 }
 570
 571 void spawnfunc_nexball_out (void)
 572 {
 573         self.team = GOAL_OUT;
 574         if (!self.noise)
 575                 self.noise = "misc/typehit.wav";
 576         SpawnGoal();
 577 }
 578
 579 //
 580 //Spawnfuncs preserved for compatibility
 581 //
 582
 583 void spawnfunc_ball            (void) { spawnfunc_nexball_football(); }
 584 void spawnfunc_ball_football   (void) { spawnfunc_nexball_football(); }
 585 void spawnfunc_ball_basketball (void) { spawnfunc_nexball_basketball(); }
 586 // The "red goal" is defended by blue team. A ball in there counts as a point for red.
 587 void spawnfunc_ball_redgoal    (void) { spawnfunc_nexball_bluegoal(); } // I blame Revenant
 588 void spawnfunc_ball_bluegoal   (void) { spawnfunc_nexball_redgoal(); }  // but he didn't mean to cause trouble :p
 589 void spawnfunc_ball_fault      (void) { spawnfunc_nexball_fault(); }
 590 void spawnfunc_ball_bound      (void) { spawnfunc_nexball_out(); }
 591
 592 //=======================//
 593 //      Weapon code      //
 594 //=======================//
 595
 596 void W_Nexball_Touch (void)
 597 {
 598         entity ball, attacker;
 599         attacker = self.owner;
 600
 601         PROJECTILE_TOUCH;
 602         if(attacker.team != other.team || g_nexball_basketball_teamsteal)
 603         if((ball = other.ballcarried) && (attacker.classname == "player"))
 604         {
 605                 other.velocity = other.velocity + normalize(self.velocity) * other.damageforcescale * autocvar_g_balance_nexball_secondary_force;
 606                 other.flags &~= FL_ONGROUND;
 607                 if(!attacker.ballcarried)
 608                 {
 609                         LogNB("stole", attacker);
 610                         sound (other, CH_TRIGGER, ball.noise2, VOL_BASE, ATTN_NORM);
 611
 612                         if(attacker.team == other.team && time > attacker.teamkill_complain)
 613                         {
 614                                 attacker.teamkill_complain = time + 5;
 615                                 attacker.teamkill_soundtime = time + 0.4;
 616                                 attacker.teamkill_soundsource = other;
 617                         }
 618
 619                         GiveBall(attacker, other.ballcarried);
 620                 }
 621         }
 622         remove(self);
 623 }
 624
 625 void W_Nexball_Attack (float t)
 626 {
 627         entity ball;
 628         float mul, mi, ma;
 629         if (!(ball = self.ballcarried))
 630                 return;
 631
 632         W_SetupShot (self, FALSE, 4, "nexball/shoot1.wav", CH_WEAPON_A, 0);
 633         tracebox(w_shotorg, BALL_MINS, BALL_MAXS, w_shotorg, MOVE_WORLDONLY, world);
 634         if(trace_startsolid)
 635         {
 636                 if(self.metertime)
 637                         self.metertime = 0; // Shot failed, hide the power meter
 638                 return;
 639         }
 640
 641         //Calculate multiplier
 642         if (t < 0)
 643                 mul = 1;
 644         else
 645         {
 646                 mi = autocvar_g_nexball_basketball_meter_minpower;
 647                 ma = max(mi, autocvar_g_nexball_basketball_meter_maxpower); // avoid confusion
 648                 //One triangle wave period with 1 as max
 649                 mul = 2 * mod(t, g_nexball_meter_period) / g_nexball_meter_period;
 650                 if (mul > 1)
 651                         mul = 2 - mul;
 652                 mul = mi + (ma - mi) * mul; // range from the minimal power to the maximal power
 653         }
 654         DropBall (ball, w_shotorg, W_CalculateProjectileVelocity(self.velocity, w_shotdir * autocvar_g_balance_nexball_primary_speed * mul, FALSE));
 655         //TODO: use the speed_up cvar too ??
 656 }
 657
 658 void W_Nexball_Attack2 (void)
 659 {
 660         entity missile;
 661         if (!(balls & BALL_BASKET))
 662                 return;
 663         W_SetupShot (self, FALSE, 2, "nexball/shoot2.wav", CH_WEAPON_A, 0);
 664 //      pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 665         missile = spawn ();
 666
 667         missile.owner = self;
 668         missile.classname = "ballstealer";
 669
 670         missile.movetype = MOVETYPE_FLY;
 671         PROJECTILE_MAKETRIGGER(missile);
 672
 673         setmodel (missile, "models/elaser.mdl"); // precision set below
 674         setsize (missile, '0 0 0', '0 0 0');
 675         setorigin (missile, w_shotorg);
 676
 677         W_SetupProjectileVelocity(missile, autocvar_g_balance_nexball_secondary_speed, 0);
 678         missile.angles = vectoangles (missile.velocity);
 679         missile.touch = W_Nexball_Touch;
 680         missile.think = SUB_Remove;
 681         missile.nextthink = time + autocvar_g_balance_nexball_secondary_lifetime; //FIXME: use a distance instead?
 682
 683         missile.effects = EF_BRIGHTFIELD | EF_LOWPRECISION;
 684         missile.flags = FL_PROJECTILE;
 685 }
 686
 687 float w_nexball_weapon(float req)
 688 {
 689         if (req == WR_THINK)
 690         {
 691                 if (self.BUTTON_ATCK)
 692                 if (weapon_prepareattack(0, autocvar_g_balance_nexball_primary_refire))
 693                 if (autocvar_g_nexball_basketball_meter)
 694                 {
 695                         if (self.ballcarried && !self.metertime)
 696                                 self.metertime = time;
 697                         else
 698                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nexball_primary_animtime, w_ready);
 699                 }
 700                 else
 701                 {
 702                         W_Nexball_Attack(-1);
 703                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nexball_primary_animtime, w_ready);
 704                 }
 705                 if (self.BUTTON_ATCK2)
 706                 if (weapon_prepareattack(1, autocvar_g_balance_nexball_secondary_refire))
 707                 {
 708                         W_Nexball_Attack2();
 709                         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_nexball_secondary_animtime, w_ready);
 710                 }
 711
 712                 if (!self.BUTTON_ATCK && self.metertime && self.ballcarried)
 713                 {
 714                         W_Nexball_Attack(time - self.metertime);
 715                         // DropBall or stealing will set metertime back to 0
 716                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nexball_primary_animtime, w_ready);
 717                 }
 718         }
 719         else if (req == WR_PRECACHE)
 720         {
 721                 precache_model ("models/weapons/g_porto.md3");
 722                 precache_model ("models/weapons/v_porto.md3");
 723                 precache_model ("models/weapons/h_porto.iqm");
 724                 precache_model ("models/elaser.mdl");
 725                 precache_sound ("nexball/shoot1.wav");
 726                 precache_sound ("nexball/shoot2.wav");
 727                 precache_sound ("misc/typehit.wav");
 728         }
 729         else if (req == WR_SETUP)
 730                 weapon_setup(WEP_PORTO);
 731         else if (req == WR_SUICIDEMESSAGE)
 732         {
 733                 w_deathtypestring = "is a weirdo";
 734         }
 735         else if (req == WR_KILLMESSAGE)
 736         {
 737                 w_deathtypestring = "got killed by #'s black magic";
 738         }
 739         // No need to check WR_CHECKAMMO* or WR_AIM, it should always return TRUE
 740         return TRUE;
 741 }