qcsrc/server/bot/default/aim.qc

   1 #include "aim.qh"
   2
   3 #include <server/defs.qh>
   4
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8
   9 #include <common/physics/player.qh>
  10 #include <common/state.qh>
  11
  12 #include "../../weapons/weaponsystem.qh"
  13
  14 #include <server/mutators/_mod.qh>
  15
  16 // traces multiple trajectories to find one that will impact the target
  17 // 'end' vector is the place it aims for,
  18 // returns true only if it hit targ (don't target non-solid entities)
  19
  20 float findtrajectorywithleading(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore)
  21 {
  22         float c, savesolid, shottime;
  23         vector dir, end, v, o;
  24         if (shotspeed < 1)
  25                 return false; // could cause division by zero if calculated
  26         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
  27                 return false; // could never hit it
  28         if (!tracetossent)
  29                 tracetossent = new(tracetossent);
  30         tracetossent.owner = ignore;
  31         setsize(tracetossent, m1, m2);
  32         savesolid = targ.solid;
  33         targ.solid = SOLID_NOT;
  34         o = (targ.absmin + targ.absmax) * 0.5;
  35         shottime = ((vlen(o - org) / shotspeed) + shotdelay);
  36         v = targ.velocity * shottime + o;
  37         tracebox(o, targ.mins, targ.maxs, v, false, targ);
  38         v = trace_endpos;
  39         end = v + (targ.mins + targ.maxs) * 0.5;
  40         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
  41         {
  42                 // out of range
  43                 targ.solid = savesolid;
  44                 return false;
  45         }
  46
  47         if (!tracetossfaketarget)
  48                 tracetossfaketarget = new(tracetossfaketarget);
  49         tracetossfaketarget.solid = savesolid;
  50         set_movetype(tracetossfaketarget, targ.move_movetype);
  51         _setmodel(tracetossfaketarget, targ.model); // no low precision
  52         tracetossfaketarget.model = targ.model;
  53         tracetossfaketarget.modelindex = targ.modelindex;
  54         setsize(tracetossfaketarget, targ.mins, targ.maxs);
  55         setorigin(tracetossfaketarget, v);
  56
  57         c = 0;
  58         dir = normalize(end - org);
  59         while (c < 10) // 10 traces
  60         {
  61                 setorigin(tracetossent, org); // reset
  62                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
  63                 tracetoss(tracetossent, ignore); // love builtin functions...
  64                 if (trace_ent == tracetossfaketarget) // done
  65                 {
  66                         targ.solid = savesolid;
  67
  68                         // make it disappear
  69                         tracetossfaketarget.solid = SOLID_NOT;
  70                         set_movetype(tracetossfaketarget, MOVETYPE_NONE);
  71                         tracetossfaketarget.model = "";
  72                         tracetossfaketarget.modelindex = 0;
  73                         // relink to remove it from physics considerations
  74                         setorigin(tracetossfaketarget, v);
  75
  76                         return true;
  77                 }
  78                 dir.z = dir.z + 0.1; // aim up a little more
  79                 c = c + 1;
  80         }
  81         targ.solid = savesolid;
  82
  83         // make it disappear
  84         tracetossfaketarget.solid = SOLID_NOT;
  85         set_movetype(tracetossfaketarget, MOVETYPE_NONE);
  86         tracetossfaketarget.model = "";
  87         tracetossfaketarget.modelindex = 0;
  88         // relink to remove it from physics considerations
  89         setorigin(tracetossfaketarget, v);
  90
  91         // leave a valid one even if it won't reach
  92         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
  93         return false;
  94 }
  95
  96 void lag_update(entity this)
  97 {
  98         if (this.lag1_time && time > this.lag1_time) { this.lag_func(this, this.lag1_time, this.lag1_float1, this.lag1_float2, this.lag1_entity1, this.lag1_vec1, this.lag1_vec2, this.lag1_vec3, this.lag1_vec4); this.lag1_time = 0; }
  99         if (this.lag2_time && time > this.lag2_time) { this.lag_func(this, this.lag2_time, this.lag2_float1, this.lag2_float2, this.lag2_entity1, this.lag2_vec1, this.lag2_vec2, this.lag2_vec3, this.lag2_vec4); this.lag2_time = 0; }
 100         if (this.lag3_time && time > this.lag3_time) { this.lag_func(this, this.lag3_time, this.lag3_float1, this.lag3_float2, this.lag3_entity1, this.lag3_vec1, this.lag3_vec2, this.lag3_vec3, this.lag3_vec4); this.lag3_time = 0; }
 101         if (this.lag4_time && time > this.lag4_time) { this.lag_func(this, this.lag4_time, this.lag4_float1, this.lag4_float2, this.lag4_entity1, this.lag4_vec1, this.lag4_vec2, this.lag4_vec3, this.lag4_vec4); this.lag4_time = 0; }
 102         if (this.lag5_time && time > this.lag5_time) { this.lag_func(this, this.lag5_time, this.lag5_float1, this.lag5_float2, this.lag5_entity1, this.lag5_vec1, this.lag5_vec2, this.lag5_vec3, this.lag5_vec4); this.lag5_time = 0; }
 103 }
 104
 105 float lag_additem(entity this, float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
 106 {
 107         if (this.lag1_time == 0) {this.lag1_time = t;this.lag1_float1 = f1;this.lag1_float2 = f2;this.lag1_entity1 = e1;this.lag1_vec1 = v1;this.lag1_vec2 = v2;this.lag1_vec3 = v3;this.lag1_vec4 = v4;return true;}
 108         if (this.lag2_time == 0) {this.lag2_time = t;this.lag2_float1 = f1;this.lag2_float2 = f2;this.lag2_entity1 = e1;this.lag2_vec1 = v1;this.lag2_vec2 = v2;this.lag2_vec3 = v3;this.lag2_vec4 = v4;return true;}
 109         if (this.lag3_time == 0) {this.lag3_time = t;this.lag3_float1 = f1;this.lag3_float2 = f2;this.lag3_entity1 = e1;this.lag3_vec1 = v1;this.lag3_vec2 = v2;this.lag3_vec3 = v3;this.lag3_vec4 = v4;return true;}
 110         if (this.lag4_time == 0) {this.lag4_time = t;this.lag4_float1 = f1;this.lag4_float2 = f2;this.lag4_entity1 = e1;this.lag4_vec1 = v1;this.lag4_vec2 = v2;this.lag4_vec3 = v3;this.lag4_vec4 = v4;return true;}
 111         if (this.lag5_time == 0) {this.lag5_time = t;this.lag5_float1 = f1;this.lag5_float2 = f2;this.lag5_entity1 = e1;this.lag5_vec1 = v1;this.lag5_vec2 = v2;this.lag5_vec3 = v3;this.lag5_vec4 = v4;return true;}
 112         // no room for it (what is the best thing to do here??)
 113         return false;
 114 }
 115
 116 bool bot_shouldattack(entity this, entity targ)
 117 {
 118         if (targ.team == this.team)
 119         {
 120                 if (targ == this)
 121                         return false;
 122                 if (teamplay)
 123                 if (targ.team != 0)
 124                         return false;
 125         }
 126
 127         if(STAT(FROZEN, targ))
 128                 return false;
 129
 130         if(teamplay)
 131         {
 132                 if(targ.team==0)
 133                         return false;
 134         }
 135         else if (autocvar_bot_ignore_bots && IS_BOT_CLIENT(targ))
 136                 return false;
 137
 138         if (!targ.takedamage)
 139                 return false;
 140         if (IS_DEAD(targ))
 141                 return false;
 142         if (PHYS_INPUT_BUTTON_CHAT(targ) && !autocvar_bot_typefrag)
 143                 return false;
 144         if(targ.flags & FL_NOTARGET)
 145                 return false;
 146         if(targ.alpha <= 0.1 && targ.alpha != 0)
 147                 return false; // invisible via alpha
 148
 149         if(MUTATOR_CALLHOOK(BotShouldAttack, this, targ))
 150                 return false;
 151
 152         return true;
 153 }
 154
 155 void bot_lagfunc(entity this, float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
 156 {
 157         this.bot_aimtarg = e1;
 158         this.bot_aimlatency = CS(this).ping; // FIXME?  Shouldn't this be in the lag item?
 159         //this.bot_aimorigin = v1;
 160         //this.bot_aimvelocity = v2;
 161         this.bot_aimtargorigin = v3;
 162         this.bot_aimtargvelocity = v4;
 163         if(skill <= 0)
 164                 this.bot_canfire = (random() < 0.8);
 165         else if(skill <= 1)
 166                 this.bot_canfire = (random() < 0.9);
 167         else if(skill <= 2)
 168                 this.bot_canfire = (random() < 0.95);
 169         else
 170                 this.bot_canfire = 1;
 171 }
 172
 173 void bot_aimdir(entity this, vector v, float maxfiredeviation)
 174 {
 175         float dist, delta_t, blend;
 176         vector desiredang, diffang;
 177
 178         this.bot_aimdir_executed = true;
 179
 180         //dprint("aim ", this.netname, ": old:", vtos(this.v_angle));
 181         // make sure v_angle is sane first
 182         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
 183         this.v_angle_z = 0;
 184
 185         // invalid aim dir (can happen when bot overlaps target)
 186         if(!v) return;
 187
 188         // get the desired angles to aim at
 189         //dprint(" at:", vtos(v));
 190         v = normalize(v);
 191         //te_lightning2(NULL, this.origin + this.view_ofs, this.origin + this.view_ofs + v * 200);
 192         if (time >= this.bot_badaimtime)
 193         {
 194                 this.bot_badaimtime = max(this.bot_badaimtime + 0.3, time);
 195                 this.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+this.bot_offsetskill), 5) * autocvar_bot_ai_aimskill_offset;
 196         }
 197         desiredang = vectoangles(v) + this.bot_badaimoffset;
 198         //dprint(" desired:", vtos(desiredang));
 199         if (desiredang.x >= 180)
 200                 desiredang.x = desiredang.x - 360;
 201         desiredang.x = bound(-90, 0 - desiredang.x, 90);
 202         desiredang.z = this.v_angle.z;
 203         //dprint(" / ", vtos(desiredang));
 204
 205         //// pain throws off aim
 206         //if (this.bot_painintensity)
 207         //{
 208         //      // shake from pain
 209         //      desiredang = desiredang + randomvec() * this.bot_painintensity * 0.2;
 210         //}
 211
 212         // calculate turn angles
 213         diffang = (desiredang - this.bot_olddesiredang);
 214         // wrap yaw turn
 215         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 216         if (diffang.y >= 180)
 217                 diffang.y = diffang.y - 360;
 218         this.bot_olddesiredang = desiredang;
 219         //dprint(" diff:", vtos(diffang));
 220
 221         delta_t = time-this.bot_prevaimtime;
 222         this.bot_prevaimtime = time;
 223         // Here we will try to anticipate the comming aiming direction
 224         this.bot_1st_order_aimfilter= this.bot_1st_order_aimfilter
 225                 + (diffang * (1 / delta_t)    - this.bot_1st_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_1st,1);
 226         this.bot_2nd_order_aimfilter= this.bot_2nd_order_aimfilter
 227                 + (this.bot_1st_order_aimfilter - this.bot_2nd_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_2nd,1);
 228         this.bot_3th_order_aimfilter= this.bot_3th_order_aimfilter
 229                 + (this.bot_2nd_order_aimfilter - this.bot_3th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_3th,1);
 230         this.bot_4th_order_aimfilter= this.bot_4th_order_aimfilter
 231                 + (this.bot_3th_order_aimfilter - this.bot_4th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_4th,1);
 232         this.bot_5th_order_aimfilter= this.bot_5th_order_aimfilter
 233                 + (this.bot_4th_order_aimfilter - this.bot_5th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_5th,1);
 234
 235         //blend = (bound(0,skill,10)*0.1)*((1-bound(0,skill,10)*0.05) ** 2.5)*5.656854249; //Plot formule before changing !
 236         blend = bound(0,skill+this.bot_aimskill,10)*0.1;
 237         desiredang = desiredang + blend *
 238         (
 239                   this.bot_1st_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_1st
 240                 + this.bot_2nd_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_2nd
 241                 + this.bot_3th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_3th
 242                 + this.bot_4th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_4th
 243                 + this.bot_5th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_5th
 244         );
 245         desiredang.x = bound(-90, desiredang.x, 90);
 246
 247         // calculate turn angles
 248         diffang = desiredang - this.bot_mouseaim;
 249         // wrap yaw turn
 250         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 251         if (diffang.y >= 180)
 252                 diffang.y = diffang.y - 360;
 253         //dprint(" diff:", vtos(diffang));
 254
 255         if (time >= this.bot_aimthinktime)
 256         {
 257                 this.bot_aimthinktime = max(this.bot_aimthinktime + 0.5 - 0.05*(skill+this.bot_thinkskill), time);
 258                 this.bot_mouseaim = this.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-(skill+this.bot_thinkskill),10));
 259         }
 260
 261         //this.v_angle = this.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
 262
 263         diffang = this.bot_mouseaim - desiredang;
 264         // wrap yaw turn
 265         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 266         if (diffang.y >= 180)
 267                 diffang.y = diffang.y - 360;
 268         desiredang = desiredang + diffang * bound(0,autocvar_bot_ai_aimskill_think,1);
 269
 270         // calculate turn angles
 271         diffang = desiredang - this.v_angle;
 272         // wrap yaw turn
 273         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 274         if (diffang.y >= 180)
 275                 diffang.y = diffang.y - 360;
 276         //dprint(" diff:", vtos(diffang));
 277
 278         // jitter tracking
 279         dist = vlen(diffang);
 280         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
 281
 282         // turn
 283         float r, fixedrate, blendrate;
 284         fixedrate = autocvar_bot_ai_aimskill_fixedrate / bound(1,dist,1000);
 285         blendrate = autocvar_bot_ai_aimskill_blendrate;
 286         r = max(fixedrate, blendrate);
 287         //this.v_angle = this.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
 288         this.v_angle = this.v_angle + diffang * bound(delta_t, r * delta_t * (2 + ((skill + this.bot_mouseskill) ** 3) * 0.005 - random()), 1);
 289         this.v_angle = this.v_angle * bound(0,autocvar_bot_ai_aimskill_mouse,1) + desiredang * bound(0,(1-autocvar_bot_ai_aimskill_mouse),1);
 290         //this.v_angle = this.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
 291         //this.v_angle = this.v_angle + diffang * (1/ blendrate);
 292         this.v_angle_z = 0;
 293         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
 294         //dprint(" turn:", vtos(this.v_angle));
 295
 296         makevectors(this.v_angle);
 297         shotorg = this.origin + this.view_ofs;
 298         shotdir = v_forward;
 299
 300         //dprint(" dir:", vtos(v_forward));
 301         //te_lightning2(NULL, shotorg, shotorg + shotdir * 100);
 302
 303         // calculate turn angles again
 304         //diffang = desiredang - this.v_angle;
 305         //diffang_y = diffang_y - floor(diffang_y / 360) * 360;
 306         //if (diffang_y >= 180)
 307         //      diffang_y = diffang_y - 360;
 308
 309         //dprint("e ", vtos(diffang), " < ", ftos(maxfiredeviation), "\n");
 310
 311         // decide whether to fire this time
 312         if (maxfiredeviation != 0 && v * shotdir > cos(maxfiredeviation * DEG2RAD))
 313         {
 314                 traceline(shotorg, shotorg + shotdir * 1000, false, NULL);
 315                 if (vdist(trace_endpos - shotorg, <, 500 + 500 * bound(0, skill + this.bot_aggresskill, 10))
 316                         || random() * random() > bound(0, (skill + this.bot_aggresskill) * 0.05, 1))
 317                 {
 318                         this.bot_firetimer = time + bound(0.1, 0.5 - (skill + this.bot_aggresskill) * 0.05, 0.5);
 319                 }
 320         }
 321         //dprint(ftos(maxfiredeviation),"\n");
 322         //dprint(" diff:", vtos(diffang), "\n");
 323
 324         //return this.bot_canfire && (time < this.bot_firetimer);
 325 }
 326
 327 vector bot_shotlead(vector targorigin, vector targvelocity, float shotspeed, float shotdelay)
 328 {
 329         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
 330         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
 331 }
 332
 333 bool bot_aim(entity this, .entity weaponentity, float shotspeed, float shotspeedupward, float maxshottime, bool applygravity)
 334 {
 335         float r, hf, distanceratio;
 336         vector v;
 337         /*
 338         eprint(this);
 339         dprint("bot_aim(", ftos(shotspeed));
 340         dprint(", ", ftos(shotspeedupward));
 341         dprint(", ", ftos(maxshottime));
 342         dprint(", ", ftos(applygravity));
 343         dprint(");\n");
 344         */
 345
 346         hf = this.dphitcontentsmask;
 347         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 348
 349         shotspeed *= W_WeaponSpeedFactor(this);
 350         shotspeedupward *= W_WeaponSpeedFactor(this);
 351         if (!shotspeed)
 352         {
 353                 LOG_TRACE("bot_aim: WARNING: weapon ", this.(weaponentity).m_weapon.m_name, " shotspeed is zero!");
 354                 shotspeed = 1000000;
 355         }
 356         if (!maxshottime)
 357         {
 358                 LOG_TRACE("bot_aim: WARNING: weapon ", this.(weaponentity).m_weapon.m_name, " maxshottime is zero!");
 359                 maxshottime = 1;
 360         }
 361         makevectors(this.v_angle);
 362         shotorg = this.origin + this.view_ofs;
 363         shotdir = v_forward;
 364         v = bot_shotlead(this.bot_aimtargorigin, this.bot_aimtargvelocity, shotspeed, this.bot_aimlatency);
 365         distanceratio = sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/autocvar_bot_ai_aimskill_firetolerance_distdegrees;
 366         distanceratio = bound(0,distanceratio,1);
 367         r =  (autocvar_bot_ai_aimskill_firetolerance_maxdegrees-autocvar_bot_ai_aimskill_firetolerance_mindegrees)
 368                 * (1-distanceratio) + autocvar_bot_ai_aimskill_firetolerance_mindegrees;
 369         if (applygravity && this.bot_aimtarg)
 370         {
 371                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', this.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, this))
 372                 {
 373                         this.dphitcontentsmask = hf;
 374                         return false;
 375                 }
 376
 377                 bot_aimdir(this, findtrajectory_velocity - shotspeedupward * '0 0 1', r);
 378         }
 379         else
 380         {
 381                 bot_aimdir(this, v - shotorg, r);
 382                 //dprint("AIM: ");dprint(vtos(this.bot_aimtargorigin));dprint(" + ");dprint(vtos(this.bot_aimtargvelocity));dprint(" * ");dprint(ftos(this.bot_aimlatency + vlen(this.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
 383                 //traceline(shotorg, shotorg + shotdir * 10000, false, this);
 384                 //if (trace_ent.takedamage)
 385                 //if (trace_fraction < 1)
 386                 //if (!bot_shouldattack(this, trace_ent))
 387                 //      return false;
 388                 traceline(shotorg, this.bot_aimtargorigin, false, this);
 389                 if (trace_fraction < 1)
 390                 if (trace_ent != this.enemy)
 391                 if (!bot_shouldattack(this, trace_ent))
 392                 {
 393                         this.dphitcontentsmask = hf;
 394                         return false;
 395                 }
 396         }
 397
 398         if (time > this.bot_firetimer)
 399         {
 400                 this.dphitcontentsmask = hf;
 401                 return false;
 402         }
 403
 404         //if (r > maxshottime * shotspeed)
 405         //      return false;
 406         this.dphitcontentsmask = hf;
 407         return true;
 408 }