qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  45 void bot_setclientfields(entity this)
  46 {
  47         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  48         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  49 }
  50
  51 entity bot_spawn()
  52 {
  53         entity bot = spawnclient();
  54         if (bot)
  55         {
  56                 setItemGroupCount();
  57                 currentbots = currentbots + 1;
  58                 bot_setnameandstuff(bot);
  59                 ClientConnect(bot);
  60                 bot_setclientfields(bot);
  61                 PutClientInServer(bot);
  62         }
  63         return bot;
  64 }
  65
  66 void bot_think(entity this)
  67 {
  68         if (this.bot_nextthink > time)
  69                 return;
  70
  71         this.flags &= ~FL_GODMODE;
  72         if(autocvar_bot_god)
  73                 this.flags |= FL_GODMODE;
  74
  75         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  76
  77         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  78         {
  79                 CS(this).movement = '0 0 0';
  80                 this.bot_nextthink = time + 0.5;
  81                 return;
  82         }
  83
  84         if (this.fixangle)
  85         {
  86                 this.v_angle = this.angles;
  87                 this.v_angle_z = 0;
  88                 this.fixangle = false;
  89         }
  90
  91         this.dmg_take = 0;
  92         this.dmg_save = 0;
  93         this.dmg_inflictor = NULL;
  94
  95         // calculate an aiming latency based on the skill setting
  96         // (simulated network latency + naturally delayed reflexes)
  97         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  98         // minimum ping 20+10 random
  99         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 100         // skill 10 = ping 0.2 (adrenaline)
 101         // skill 0 = ping 0.7 (slightly drunk)
 102
 103         // clear buttons
 104         PHYS_INPUT_BUTTON_ATCK(this) = false;
 105         PHYS_INPUT_BUTTON_JUMP(this) = false;
 106         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 107         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 108         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 109         PHYS_INPUT_BUTTON_HOOK(this) = false;
 110         PHYS_INPUT_BUTTON_INFO(this) = false;
 111         PHYS_INPUT_BUTTON_DRAG(this) = false;
 112         PHYS_INPUT_BUTTON_CHAT(this) = false;
 113         PHYS_INPUT_BUTTON_USE(this) = false;
 114
 115         if (time < game_starttime)
 116         {
 117                 // block the bot during the countdown to game start
 118                 CS(this).movement = '0 0 0';
 119                 this.bot_nextthink = game_starttime;
 120                 return;
 121         }
 122
 123         // if dead, just wait until we can respawn
 124         if (IS_DEAD(this))
 125         {
 126                 CS(this).movement = '0 0 0';
 127                 if (this.deadflag == DEAD_DEAD)
 128                 {
 129                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 130                         navigation_goalrating_timeout_force(this);
 131                 }
 132         }
 133         else if(this.aistatus & AI_STATUS_STUCK)
 134                 navigation_unstuck(this);
 135
 136         // now call the current bot AI (havocbot for example)
 137         this.bot_ai(this);
 138 }
 139
 140 void bot_setnameandstuff(entity this)
 141 {
 142         string readfile, s;
 143         float file, tokens, prio;
 144
 145         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 146         string name, prefix, suffix;
 147
 148         if(autocvar_g_campaign)
 149         {
 150                 prefix = "";
 151                 suffix = "";
 152         }
 153         else
 154         {
 155                 prefix = autocvar_bot_prefix;
 156                 suffix = autocvar_bot_suffix;
 157         }
 158
 159         file = fopen(autocvar_bot_config_file, FILE_READ);
 160
 161         if(file < 0)
 162         {
 163                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 164                 readfile = "";
 165         }
 166         else
 167         {
 168                 RandomSelection_Init();
 169                 while((readfile = fgets(file)))
 170                 {
 171                         if(substring(readfile, 0, 2) == "//")
 172                                 continue;
 173                         if(substring(readfile, 0, 1) == "#")
 174                                 continue;
 175                         tokens = tokenizebyseparator(readfile, "\t");
 176                         if(tokens == 0)
 177                                 continue;
 178                         s = argv(0);
 179                         prio = 1;
 180                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 181                                 if(s == it.cleanname)
 182                                 {
 183                                         prio = 0;
 184                                         break;
 185                                 }
 186                         });
 187                         RandomSelection_AddString(readfile, 1, prio);
 188                 }
 189                 readfile = RandomSelection_chosen_string;
 190                 fclose(file);
 191         }
 192
 193         tokens = tokenizebyseparator(readfile, "\t");
 194         if(argv(0) != "") bot_name = argv(0);
 195         else bot_name = "Bot";
 196
 197         if(argv(1) != "") bot_model = argv(1);
 198         else bot_model = "";
 199
 200         if(argv(2) != "") bot_skin = argv(2);
 201         else bot_skin = "0";
 202
 203         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 204         else bot_shirt = ftos(floor(random() * 15));
 205
 206         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 207         else bot_pants = ftos(floor(random() * 15));
 208
 209         this.bot_forced_team = stof(argv(5));
 210
 211         prio = 6;
 212
 213         #define READSKILL(f, w, r) MACRO_BEGIN { \
 214                 if(argv(prio) != "") \
 215                         this.f = stof(argv(prio)) * w; \
 216                 else \
 217                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 218                 prio++; \
 219         } MACRO_END
 220         //print(bot_name, ": ping=", argv(9), "\n");
 221
 222         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 223         READSKILL(bot_moveskill, 2, 0); // move skill
 224         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 225
 226         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 227
 228         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 229         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 230         READSKILL(bot_rangepreference, 1, 0); // read skill
 231
 232         READSKILL(bot_aimskill, 2, 0); // aim skill
 233         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 234         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 235
 236         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 237         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 238
 239         this.bot_config_loaded = true;
 240
 241         // this is really only a default, JoinBestTeam is called later
 242         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 243         this.bot_preferredcolors = this.clientcolors;
 244
 245         // pick the name
 246         if (autocvar_bot_usemodelnames)
 247                 name = bot_model;
 248         else
 249                 name = bot_name;
 250
 251         // number bots with identical names
 252         int j = 0;
 253         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 254                 if(it.cleanname == name)
 255                         ++j;
 256         });
 257         if (j)
 258                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 259         else
 260                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 261
 262         this.cleanname = strzone(name);
 263
 264         // pick the model and skin
 265         if(substring(bot_model, -4, 1) != ".")
 266                 bot_model = strcat(bot_model, ".iqm");
 267         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 268         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 269 }
 270
 271 void bot_custom_weapon_priority_setup()
 272 {
 273         float tokens, i, w;
 274
 275         bot_custom_weapon = false;
 276
 277         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 278                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 279                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 280                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 281         )
 282                 return;
 283
 284         // Parse distances
 285         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 286
 287         if (tokens!=2)
 288                 return;
 289
 290         bot_distance_far = stof(argv(0));
 291         bot_distance_close = stof(argv(1));
 292
 293         if(bot_distance_far < bot_distance_close){
 294                 bot_distance_far = stof(argv(1));
 295                 bot_distance_close = stof(argv(0));
 296         }
 297
 298         // Initialize list of weapons
 299         bot_weapons_far[0] = -1;
 300         bot_weapons_mid[0] = -1;
 301         bot_weapons_close[0] = -1;
 302
 303         // Parse far distance weapon priorities
 304         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 305
 306         int c = 0;
 307         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 308                 w = stof(argv(i));
 309                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 310                         bot_weapons_far[c] = w;
 311                         ++c;
 312                 }
 313         }
 314         if(c < Weapons_COUNT)
 315                 bot_weapons_far[c] = -1;
 316
 317         // Parse mid distance weapon priorities
 318         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 319
 320         c = 0;
 321         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 322                 w = stof(argv(i));
 323                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 324                         bot_weapons_mid[c] = w;
 325                         ++c;
 326                 }
 327         }
 328         if(c < Weapons_COUNT)
 329                 bot_weapons_mid[c] = -1;
 330
 331         // Parse close distance weapon priorities
 332         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 333
 334         c = 0;
 335         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 336                 w = stof(argv(i));
 337                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 338                         bot_weapons_close[c] = w;
 339                         ++c;
 340                 }
 341         }
 342         if(c < Weapons_COUNT)
 343                 bot_weapons_close[c] = -1;
 344
 345         bot_custom_weapon = true;
 346 }
 347
 348 void bot_endgame()
 349 {
 350         bot_relinkplayerlist();
 351         entity e = bot_list;
 352         while (e)
 353         {
 354                 setcolor(e, e.bot_preferredcolors);
 355                 e = e.nextbot;
 356         }
 357         // if dynamic waypoints are ever implemented, save them here
 358 }
 359
 360 void bot_relinkplayerlist()
 361 {
 362         player_count = 0;
 363         currentbots = 0;
 364         bot_list = NULL;
 365
 366         entity prevbot = NULL;
 367         FOREACH_CLIENT(true,
 368         {
 369                 ++player_count;
 370
 371                 if(IS_BOT_CLIENT(it))
 372                 {
 373                         if(prevbot)
 374                                 prevbot.nextbot = it;
 375                         else
 376                                 bot_list = it;
 377                         prevbot = it;
 378                         ++currentbots;
 379                 }
 380         });
 381         if(prevbot)
 382                 prevbot.nextbot = NULL;
 383         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 384         bot_strategytoken = bot_list;
 385         bot_strategytoken_taken = true;
 386 }
 387
 388 void bot_clientdisconnect(entity this)
 389 {
 390         if (!IS_BOT_CLIENT(this))
 391                 return;
 392         bot_clearqueue(this);
 393         strfree(this.cleanname);
 394         strfree(this.netname_freeme);
 395         strfree(this.playermodel_freeme);
 396         strfree(this.playerskin_freeme);
 397         if(this.bot_cmd_current)
 398                 delete(this.bot_cmd_current);
 399         if(bot_waypoint_queue_owner == this)
 400                 bot_waypoint_queue_owner = NULL;
 401 }
 402
 403 void bot_clientconnect(entity this)
 404 {
 405         if (!IS_BOT_CLIENT(this)) return;
 406         this.bot_preferredcolors = this.clientcolors;
 407         this.bot_nextthink = time - random();
 408         this.lag_func = bot_lagfunc;
 409         this.isbot = true;
 410         this.createdtime = this.bot_nextthink;
 411
 412         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 413         {
 414                 bot_setnameandstuff(this);
 415                 bot_setclientfields(this);
 416         }
 417
 418         if(this.bot_forced_team==1)
 419                 this.team = NUM_TEAM_1;
 420         else if(this.bot_forced_team==2)
 421                 this.team = NUM_TEAM_2;
 422         else if(this.bot_forced_team==3)
 423                 this.team = NUM_TEAM_3;
 424         else if(this.bot_forced_team==4)
 425                 this.team = NUM_TEAM_4;
 426         else
 427                 TeamBalance_JoinBestTeam(this, true);
 428
 429         havocbot_setupbot(this);
 430 }
 431
 432 void bot_removefromlargestteam()
 433 {
 434         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 435         TeamBalance_GetTeamCounts(balance, NULL);
 436
 437         entity best = NULL;
 438         float besttime = 0;
 439         int bestcount = 0;
 440
 441         int bcount = 0;
 442         FOREACH_CLIENT(it.isbot,
 443         {
 444                 ++bcount;
 445
 446                 if(!best)
 447                 {
 448                         best = it;
 449                         besttime = it.createdtime;
 450                 }
 451
 452                 int thiscount = 0;
 453
 454                 if (Team_IsValidTeam(it.team))
 455                 {
 456                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 457                                 Team_TeamToIndex(it.team));
 458                 }
 459
 460                 if(thiscount > bestcount)
 461                 {
 462                         bestcount = thiscount;
 463                         besttime = it.createdtime;
 464                         best = it;
 465                 }
 466                 else if(thiscount == bestcount && besttime < it.createdtime)
 467                 {
 468                         besttime = it.createdtime;
 469                         best = it;
 470                 }
 471         });
 472         TeamBalance_Destroy(balance);
 473         if(!bcount)
 474                 return; // no bots to remove
 475         currentbots = currentbots - 1;
 476         dropclient(best);
 477 }
 478
 479 void bot_removenewest()
 480 {
 481         if(teamplay)
 482         {
 483                 bot_removefromlargestteam();
 484                 return;
 485         }
 486
 487         float besttime = 0;
 488         entity best = NULL;
 489         int bcount = 0;
 490
 491         FOREACH_CLIENT(it.isbot,
 492         {
 493                 ++bcount;
 494
 495                 if(!best)
 496                 {
 497                         best = it;
 498                         besttime = it.createdtime;
 499                 }
 500
 501                 if(besttime < it.createdtime)
 502                 {
 503                         besttime = it.createdtime;
 504                         best = it;
 505                 }
 506         });
 507
 508         if(!bcount)
 509                 return; // no bots to remove
 510
 511         currentbots = currentbots - 1;
 512         dropclient(best);
 513 }
 514
 515 void autoskill(float factor)
 516 {
 517         float bestbot;
 518         float bestplayer;
 519
 520         bestbot = -1;
 521         bestplayer = -1;
 522         FOREACH_CLIENT(IS_PLAYER(it), {
 523                 if(IS_REAL_CLIENT(it))
 524                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 525                 else
 526                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 527         });
 528
 529         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 530         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 531         if(bestbot < 0 || bestplayer < 0)
 532         {
 533                 LOG_DEBUG("not doing anything");
 534                 // don't return, let it reset all counters below
 535         }
 536         else if(bestbot <= bestplayer * factor - 2)
 537         {
 538                 if(autocvar_skill < 17)
 539                 {
 540                         LOG_DEBUG("2 frags difference, increasing skill");
 541                         cvar_set("skill", ftos(autocvar_skill + 1));
 542                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 543                 }
 544         }
 545         else if(bestbot >= bestplayer * factor + 2)
 546         {
 547                 if(autocvar_skill > 0)
 548                 {
 549                         LOG_DEBUG("2 frags difference, decreasing skill");
 550                         cvar_set("skill", ftos(autocvar_skill - 1));
 551                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 552                 }
 553         }
 554         else
 555         {
 556                 LOG_DEBUG("not doing anything");
 557                 return;
 558                 // don't reset counters, wait for them to accumulate
 559         }
 560
 561         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 562 }
 563
 564 void bot_calculate_stepheightvec()
 565 {
 566         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 567         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 568         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 569 }
 570
 571 float bot_fixcount()
 572 {
 573         int activerealplayers = 0;
 574         int realplayers = 0;
 575         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 576                 activerealplayers = M_ARGV(0, int);
 577                 realplayers = M_ARGV(1, int);
 578         } else {
 579                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 580                         if(IS_PLAYER(it))
 581                                 ++activerealplayers;
 582                         ++realplayers;
 583                 });
 584         }
 585
 586         int bots;
 587         // add/remove bots if needed to make sure there are at least
 588         // minplayers+bot_number, or remove all bots if no one is playing
 589         // But don't remove bots immediately on level change, as the real players
 590         // usually haven't rejoined yet
 591         bots_would_leave = false;
 592         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 593                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 594         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 595         {
 596                 float realminplayers, minplayers;
 597                 realminplayers = autocvar_minplayers;
 598                 minplayers = max(0, floor(realminplayers));
 599
 600                 float realminbots, minbots;
 601                 realminbots = autocvar_bot_number;
 602                 minbots = max(0, floor(realminbots));
 603
 604                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 605                 if(bots > minbots)
 606                         bots_would_leave = true;
 607         }
 608         else
 609         {
 610                 // if there are no players, remove bots
 611                 bots = 0;
 612         }
 613
 614         // only add one bot per frame to avoid utter chaos
 615         if(time > botframe_nextthink)
 616         {
 617                 if (currentbots < bots)
 618                 {
 619                         if (bot_spawn() == NULL)
 620                         {
 621                                 bprint("Can not add bot, server full.\n");
 622                                 return false;
 623                         }
 624                 }
 625                 while (currentbots > bots)
 626                         bot_removenewest();
 627         }
 628
 629         return true;
 630 }
 631
 632 void bot_remove_from_bot_list(entity this)
 633 {
 634         entity e = bot_list;
 635         entity prev_bot = NULL;
 636         while (e)
 637         {
 638                 if(e == this)
 639                 {
 640                         if(!prev_bot)
 641                                 bot_list = this.nextbot;
 642                         else
 643                                 prev_bot.nextbot = this.nextbot;
 644                         if(bot_strategytoken == this)
 645                         {
 646                                 bot_strategytoken = this.nextbot;
 647                                 bot_strategytoken_taken = true;
 648                         }
 649                         this.nextbot = NULL;
 650                         break;
 651                 }
 652                 prev_bot = e;
 653                 e = e.nextbot;
 654         }
 655 }
 656
 657 void bot_clear(entity this)
 658 {
 659         bot_remove_from_bot_list(this);
 660         if(bot_waypoint_queue_owner == this)
 661                 bot_waypoint_queue_owner = NULL;
 662         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 663 }
 664
 665 void bot_serverframe()
 666 {
 667         if (intermission_running && currentbots > 0)
 668         {
 669                 // after the end of the match all bots stay unless all human players disconnect
 670                 int realplayers = 0;
 671                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 672                 if (!realplayers)
 673                 {
 674                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 675                         currentbots = 0;
 676                 }
 677                 return;
 678         }
 679
 680         if (game_stopped)
 681                 return;
 682
 683         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 684         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 685         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 686         // either intentionally or automatically (sv_spectate 0)
 687         if (time < 2.5)
 688         {
 689                 currentbots = -1;
 690                 return;
 691         }
 692
 693         if (currentbots == -1)
 694         {
 695                 // count bots already in the server from the previous match
 696                 currentbots = 0;
 697                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 698         }
 699
 700         if(autocvar_skill != skill)
 701         {
 702                 float wpcost_update = false;
 703                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 704                         wpcost_update = true;
 705                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 706                         wpcost_update = true;
 707
 708                 skill = autocvar_skill;
 709                 if (wpcost_update)
 710                         waypoint_updatecost_foralllinks();
 711         }
 712
 713         bot_calculate_stepheightvec();
 714         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 715
 716         if(time > autoskill_nextthink)
 717         {
 718                 float a;
 719                 a = autocvar_skill_auto;
 720                 if(a)
 721                         autoskill(a);
 722                 autoskill_nextthink = time + 5;
 723         }
 724
 725         if(time > botframe_nextthink)
 726         {
 727                 if(!bot_fixcount())
 728                         botframe_nextthink = time + 10;
 729         }
 730
 731         if(botframe_spawnedwaypoints)
 732         {
 733                 if(autocvar_waypoint_benchmark)
 734                         localcmd("quit\n");
 735         }
 736
 737         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 738         if (botframe_spawnedwaypoints)
 739         {
 740                 if(botframe_cachedwaypointlinks)
 741                 {
 742                         if(!botframe_loadedforcedlinks)
 743                                 waypoint_load_links_hardwired();
 744                 }
 745                 else
 746                 {
 747                         // TODO: Make this check cleaner
 748                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 749                         {
 750                                 waypoint_save_links();
 751                                 break;
 752                         });
 753                 }
 754         }
 755         else
 756         {
 757                 botframe_spawnedwaypoints = true;
 758                 waypoint_loadall();
 759                 waypoint_load_links();
 760         }
 761
 762         if (bot_list)
 763         {
 764                 // cycle the goal token from one bot to the next each frame
 765                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 766                 //  frame, which causes choppy framerates)
 767                 if (bot_strategytoken_taken)
 768                 {
 769                         // give goal token to the first bot without goals; if all bots don't have
 770                         // any goal (or are dead/frozen) simply give it to the next one
 771                         bot_strategytoken_taken = false;
 772                         entity bot_strategytoken_save = bot_strategytoken;
 773                         while (true)
 774                         {
 775                                 if (bot_strategytoken)
 776                                         bot_strategytoken = bot_strategytoken.nextbot;
 777                                 if (!bot_strategytoken)
 778                                         bot_strategytoken = bot_list;
 779
 780                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 781                                         && !bot_strategytoken.goalcurrent)
 782                                         break;
 783
 784                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 785                                         break;
 786                                 if (bot_strategytoken == bot_strategytoken_save)
 787                                         bot_strategytoken_save = NULL; // looped through all the bots
 788                         }
 789                 }
 790
 791                 if (botframe_nextdangertime < time)
 792                 {
 793                         float interval;
 794                         interval = autocvar_bot_ai_dangerdetectioninterval;
 795                         if (botframe_nextdangertime < time - interval * 1.5)
 796                                 botframe_nextdangertime = time;
 797                         botframe_nextdangertime = botframe_nextdangertime + interval;
 798                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 799                 }
 800         }
 801
 802         if (autocvar_g_waypointeditor)
 803                 botframe_showwaypointlinks();
 804
 805         if (autocvar_g_waypointeditor_auto)
 806                 botframe_autowaypoints();
 807
 808         if(time > bot_cvar_nextthink)
 809         {
 810                 if(currentbots>0)
 811                         bot_custom_weapon_priority_setup();
 812                 bot_cvar_nextthink = time + 5;
 813         }
 814 }