qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  45
  46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  47 void bot_setclientfields(entity this)
  48 {
  49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  51 }
  52
  53 entity bot_spawn()
  54 {
  55         entity bot = spawnclient();
  56         if (bot)
  57         {
  58                 setItemGroupCount();
  59                 currentbots = currentbots + 1;
  60                 bot_setnameandstuff(bot);
  61                 ClientConnect(bot);
  62                 bot_setclientfields(bot);
  63                 PutClientInServer(bot);
  64         }
  65         return bot;
  66 }
  67
  68 void bot_think(entity this)
  69 {
  70         if (this.bot_nextthink > time)
  71                 return;
  72
  73         this.flags &= ~FL_GODMODE;
  74         if(autocvar_bot_god)
  75                 this.flags |= FL_GODMODE;
  76
  77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  78
  79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  80         {
  81                 CS(this).movement = '0 0 0';
  82                 this.bot_nextthink = time + 0.5;
  83                 return;
  84         }
  85
  86         if (this.fixangle)
  87         {
  88                 this.v_angle = this.angles;
  89                 this.v_angle_z = 0;
  90                 this.fixangle = false;
  91         }
  92
  93         this.dmg_take = 0;
  94         this.dmg_save = 0;
  95         this.dmg_inflictor = NULL;
  96
  97         // calculate an aiming latency based on the skill setting
  98         // (simulated network latency + naturally delayed reflexes)
  99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 100         // minimum ping 20+10 random
 101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 102         // skill 10 = ping 0.2 (adrenaline)
 103         // skill 0 = ping 0.7 (slightly drunk)
 104
 105         // clear buttons
 106         PHYS_INPUT_BUTTON_ATCK(this) = false;
 107         PHYS_INPUT_BUTTON_JUMP(this) = false;
 108         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 109         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 110         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 111         PHYS_INPUT_BUTTON_HOOK(this) = false;
 112         PHYS_INPUT_BUTTON_INFO(this) = false;
 113         PHYS_INPUT_BUTTON_DRAG(this) = false;
 114         PHYS_INPUT_BUTTON_CHAT(this) = false;
 115         PHYS_INPUT_BUTTON_USE(this) = false;
 116
 117         if (time < game_starttime)
 118         {
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 this.bot_nextthink = game_starttime;
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (this.deadflag == DEAD_DEAD)
 133                 {
 134                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 135                         navigation_goalrating_timeout_force(this);
 136                 }
 137         }
 138         else if(this.aistatus & AI_STATUS_STUCK)
 139                 navigation_unstuck(this);
 140
 141         // now call the current bot AI (havocbot for example)
 142         this.bot_ai(this);
 143 }
 144
 145 void bot_setnameandstuff(entity this)
 146 {
 147         string readfile, s;
 148         int file, tokens, prio;
 149
 150         file = fopen(autocvar_bot_config_file, FILE_READ);
 151
 152         if(file < 0)
 153         {
 154                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 155                 readfile = "";
 156         }
 157         else
 158         {
 159                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 160                 TeamBalance_GetTeamCounts(balance, NULL);
 161                 int smallest_team = -1;
 162                 int smallest_count = -1;
 163                 if (teamplay)
 164                 {
 165                         for (int i = 1; i <= AvailableTeams(); ++i)
 166                         {
 167                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 168                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 169                                 // since it keeps a spot for the real player in the desired team
 170                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 171                                 if (smallest_count < 0 || count < smallest_count)
 172                                 {
 173                                         smallest_team = i;
 174                                         smallest_count = count;
 175                                 }
 176                         }
 177                 }
 178                 TeamBalance_Destroy(balance);
 179                 RandomSelection_Init();
 180                 while((readfile = fgets(file)))
 181                 {
 182                         if(substring(readfile, 0, 2) == "//")
 183                                 continue;
 184                         if(substring(readfile, 0, 1) == "#")
 185                                 continue;
 186                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 187                         // will create 1 empty token because there's no separator (bug?)
 188                         if (readfile == "")
 189                                 continue;
 190                         tokens = tokenizebyseparator(readfile, "\t");
 191                         if(tokens == 0)
 192                                 continue;
 193                         s = argv(0);
 194                         prio = 0;
 195                         bool conflict = false;
 196                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 197                                 if (s == it.cleanname)
 198                                 {
 199                                         conflict = true;
 200                                         break;
 201                                 }
 202                         });
 203                         if (!conflict)
 204                                 prio += 1;
 205                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 206                         {
 207                                 int forced_team = stof(argv(5));
 208                                 if (!Team_IsValidIndex(forced_team))
 209                                         forced_team = 0;
 210                                 if (!forced_team || forced_team == smallest_team)
 211                                         prio += 2;
 212                         }
 213                         RandomSelection_AddString(readfile, 1, prio);
 214                 }
 215                 readfile = RandomSelection_chosen_string;
 216                 fclose(file);
 217         }
 218
 219         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 220
 221         tokens = tokenizebyseparator(readfile, "\t");
 222         if(argv(0) != "") bot_name = argv(0);
 223         else bot_name = "Bot";
 224
 225         if(argv(1) != "") bot_model = argv(1);
 226         else bot_model = "";
 227
 228         if(argv(2) != "") bot_skin = argv(2);
 229         else bot_skin = "0";
 230
 231         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 232         else bot_shirt = ftos(floor(random() * 15));
 233
 234         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 235         else bot_pants = ftos(floor(random() * 15));
 236
 237         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 238                 this.bot_forced_team = stof(argv(5));
 239         else
 240                 this.bot_forced_team = 0;
 241
 242         prio = 6;
 243
 244         #define READSKILL(f, w, r) MACRO_BEGIN \
 245                 if(argv(prio) != "") \
 246                         this.f = stof(argv(prio)) * w; \
 247                 else \
 248                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 249                 prio++; \
 250         MACRO_END
 251         //print(bot_name, ": ping=", argv(9), "\n");
 252
 253         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 254         READSKILL(bot_moveskill, 2, 0); // move skill
 255         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 256
 257         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 258
 259         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 260         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 261         READSKILL(bot_rangepreference, 1, 0); // read skill
 262
 263         READSKILL(bot_aimskill, 2, 0); // aim skill
 264         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 265         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 266
 267         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 268         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 269
 270         if (file >= 0 && argv(prio) != "")
 271                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 272
 273         this.bot_config_loaded = true;
 274
 275         // this is really only a default, TeamBalance_JoinBestTeam is called later
 276         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 277         this.bot_preferredcolors = this.clientcolors;
 278
 279         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 280         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 281         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 282
 283         if (name == "")
 284         {
 285                 name = ftos(etof(this));
 286                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 287         }
 288         else
 289         {
 290                 // number bots with identical names
 291                 int j = 0;
 292                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 293                         if(it.cleanname == name)
 294                                 ++j;
 295                 });
 296                 if (j)
 297                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 298                 else
 299                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 300         }
 301         this.cleanname = strzone(name);
 302
 303         // pick the model and skin
 304         if(substring(bot_model, -4, 1) != ".")
 305                 bot_model = strcat(bot_model, ".iqm");
 306         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 307         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 308 }
 309
 310 void bot_custom_weapon_priority_setup()
 311 {
 312         float tokens, i, w;
 313
 314         bot_custom_weapon = false;
 315
 316         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 317                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 318                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 319                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 320         )
 321                 return;
 322
 323         // Parse distances
 324         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 325
 326         if (tokens!=2)
 327                 return;
 328
 329         bot_distance_far = stof(argv(0));
 330         bot_distance_close = stof(argv(1));
 331
 332         if(bot_distance_far < bot_distance_close){
 333                 bot_distance_far = stof(argv(1));
 334                 bot_distance_close = stof(argv(0));
 335         }
 336
 337         // Initialize list of weapons
 338         bot_weapons_far[0] = -1;
 339         bot_weapons_mid[0] = -1;
 340         bot_weapons_close[0] = -1;
 341
 342         // Parse far distance weapon priorities
 343         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 344
 345         int c = 0;
 346         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 347                 w = stof(argv(i));
 348                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 349                         bot_weapons_far[c] = w;
 350                         ++c;
 351                 }
 352         }
 353         if(c < Weapons_COUNT)
 354                 bot_weapons_far[c] = -1;
 355
 356         // Parse mid distance weapon priorities
 357         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 358
 359         c = 0;
 360         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 361                 w = stof(argv(i));
 362                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 363                         bot_weapons_mid[c] = w;
 364                         ++c;
 365                 }
 366         }
 367         if(c < Weapons_COUNT)
 368                 bot_weapons_mid[c] = -1;
 369
 370         // Parse close distance weapon priorities
 371         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 372
 373         c = 0;
 374         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 375                 w = stof(argv(i));
 376                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 377                         bot_weapons_close[c] = w;
 378                         ++c;
 379                 }
 380         }
 381         if(c < Weapons_COUNT)
 382                 bot_weapons_close[c] = -1;
 383
 384         bot_custom_weapon = true;
 385 }
 386
 387 void bot_endgame()
 388 {
 389         bot_relinkplayerlist();
 390         entity e = bot_list;
 391         while (e)
 392         {
 393                 setcolor(e, e.bot_preferredcolors);
 394                 e = e.nextbot;
 395         }
 396         // if dynamic waypoints are ever implemented, save them here
 397 }
 398
 399 void bot_relinkplayerlist()
 400 {
 401         player_count = 0;
 402         currentbots = 0;
 403         bot_list = NULL;
 404
 405         entity prevbot = NULL;
 406         FOREACH_CLIENT(true,
 407         {
 408                 ++player_count;
 409
 410                 if(IS_BOT_CLIENT(it))
 411                 {
 412                         if(prevbot)
 413                                 prevbot.nextbot = it;
 414                         else
 415                                 bot_list = it;
 416                         prevbot = it;
 417                         ++currentbots;
 418                 }
 419         });
 420         if(prevbot)
 421                 prevbot.nextbot = NULL;
 422         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 423         bot_strategytoken = bot_list;
 424         bot_strategytoken_taken = true;
 425 }
 426
 427 void bot_clientdisconnect(entity this)
 428 {
 429         if (!IS_BOT_CLIENT(this))
 430                 return;
 431         bot_clearqueue(this);
 432         strfree(this.cleanname);
 433         strfree(this.netname_freeme);
 434         strfree(this.playermodel_freeme);
 435         strfree(this.playerskin_freeme);
 436         if(this.bot_cmd_current)
 437                 delete(this.bot_cmd_current);
 438         if(bot_waypoint_queue_owner == this)
 439                 bot_waypoint_queue_owner = NULL;
 440 }
 441
 442 void bot_clientconnect(entity this)
 443 {
 444         if (!IS_BOT_CLIENT(this)) return;
 445         this.bot_preferredcolors = this.clientcolors;
 446         this.bot_nextthink = time - random();
 447         this.lag_func = bot_lagfunc;
 448         this.isbot = true;
 449         this.createdtime = this.bot_nextthink;
 450
 451         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 452         {
 453                 bot_setnameandstuff(this);
 454                 bot_setclientfields(this);
 455         }
 456
 457         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 458         {
 459                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 460         }
 461         else
 462         {
 463                 this.bot_forced_team = 0;
 464                 TeamBalance_JoinBestTeam(this);
 465         }
 466
 467         havocbot_setupbot(this);
 468 }
 469
 470 void bot_removefromlargestteam()
 471 {
 472         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 473         TeamBalance_GetTeamCounts(balance, NULL);
 474
 475         entity best = NULL;
 476         float besttime = 0;
 477         int bestcount = 0;
 478
 479         int bcount = 0;
 480         FOREACH_CLIENT(it.isbot,
 481         {
 482                 ++bcount;
 483
 484                 if(!best)
 485                 {
 486                         best = it;
 487                         besttime = it.createdtime;
 488                 }
 489
 490                 int thiscount = 0;
 491
 492                 if (Team_IsValidTeam(it.team))
 493                 {
 494                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 495                                 Team_TeamToIndex(it.team));
 496                 }
 497
 498                 if(thiscount > bestcount)
 499                 {
 500                         bestcount = thiscount;
 501                         besttime = it.createdtime;
 502                         best = it;
 503                 }
 504                 else if(thiscount == bestcount && besttime < it.createdtime)
 505                 {
 506                         besttime = it.createdtime;
 507                         best = it;
 508                 }
 509         });
 510         TeamBalance_Destroy(balance);
 511         if(!bcount)
 512                 return; // no bots to remove
 513         currentbots = currentbots - 1;
 514         dropclient(best);
 515 }
 516
 517 void bot_removenewest()
 518 {
 519         if(teamplay)
 520         {
 521                 bot_removefromlargestteam();
 522                 return;
 523         }
 524
 525         float besttime = 0;
 526         entity best = NULL;
 527         int bcount = 0;
 528
 529         FOREACH_CLIENT(it.isbot,
 530         {
 531                 ++bcount;
 532
 533                 if(!best)
 534                 {
 535                         best = it;
 536                         besttime = it.createdtime;
 537                 }
 538
 539                 if(besttime < it.createdtime)
 540                 {
 541                         besttime = it.createdtime;
 542                         best = it;
 543                 }
 544         });
 545
 546         if(!bcount)
 547                 return; // no bots to remove
 548
 549         currentbots = currentbots - 1;
 550         dropclient(best);
 551 }
 552
 553 void autoskill(float factor)
 554 {
 555         float bestbot;
 556         float bestplayer;
 557
 558         bestbot = -1;
 559         bestplayer = -1;
 560         FOREACH_CLIENT(IS_PLAYER(it), {
 561                 if(IS_REAL_CLIENT(it))
 562                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 563                 else
 564                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 565         });
 566
 567         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 568         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 569         if(bestbot < 0 || bestplayer < 0)
 570         {
 571                 LOG_DEBUG("not doing anything");
 572                 // don't return, let it reset all counters below
 573         }
 574         else if(bestbot <= bestplayer * factor - 2)
 575         {
 576                 if(autocvar_skill < 17)
 577                 {
 578                         LOG_DEBUG("2 frags difference, increasing skill");
 579                         cvar_set("skill", ftos(autocvar_skill + 1));
 580                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 581                 }
 582         }
 583         else if(bestbot >= bestplayer * factor + 2)
 584         {
 585                 if(autocvar_skill > 0)
 586                 {
 587                         LOG_DEBUG("2 frags difference, decreasing skill");
 588                         cvar_set("skill", ftos(autocvar_skill - 1));
 589                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 590                 }
 591         }
 592         else
 593         {
 594                 LOG_DEBUG("not doing anything");
 595                 return;
 596                 // don't reset counters, wait for them to accumulate
 597         }
 598
 599         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 600 }
 601
 602 void bot_calculate_stepheightvec()
 603 {
 604         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 605         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 606         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 607         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 608 }
 609
 610 bool bot_fixcount()
 611 {
 612         int activerealplayers = 0;
 613         int realplayers = 0;
 614         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 615                 activerealplayers = M_ARGV(0, int);
 616                 realplayers = M_ARGV(1, int);
 617         } else {
 618                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 619                         if(IS_PLAYER(it))
 620                                 ++activerealplayers;
 621                         ++realplayers;
 622                 });
 623         }
 624
 625         int bots;
 626         // But don't remove bots immediately on level change, as the real players
 627         // usually haven't rejoined yet
 628         bots_would_leave = false;
 629         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 630                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 631         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 632         {
 633                 int minplayers = max(0, floor(autocvar_minplayers));
 634                 if (teamplay)
 635                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 636                 int minbots = max(0, floor(autocvar_bot_number));
 637
 638                 // add bots to reach minplayers if needed
 639                 bots = max(minbots, minplayers - activerealplayers);
 640                 // cap bots to the max players allowed by the server
 641                 int player_limit = GetPlayerLimit();
 642                 if(player_limit)
 643                         bots = min(bots, max(player_limit - activerealplayers, 0));
 644                 bots = min(bots, maxclients - realplayers);
 645
 646                 if(bots > minbots)
 647                         bots_would_leave = true;
 648         }
 649         else
 650         {
 651                 // if there are no players, remove bots
 652                 bots = 0;
 653         }
 654
 655         // only add one bot per frame to avoid utter chaos
 656         if(time > botframe_nextthink)
 657         {
 658                 if (currentbots < bots)
 659                 {
 660                         if (bot_spawn() == NULL)
 661                         {
 662                                 bprint("Can not add bot, server full.\n");
 663                                 return false;
 664                         }
 665                 }
 666                 while (currentbots > bots && bots >= 0)
 667                         bot_removenewest();
 668         }
 669
 670         return true;
 671 }
 672
 673 void bot_remove_from_bot_list(entity this)
 674 {
 675         entity e = bot_list;
 676         entity prev_bot = NULL;
 677         while (e)
 678         {
 679                 if(e == this)
 680                 {
 681                         if(!prev_bot)
 682                                 bot_list = this.nextbot;
 683                         else
 684                                 prev_bot.nextbot = this.nextbot;
 685                         if(bot_strategytoken == this)
 686                         {
 687                                 bot_strategytoken = this.nextbot;
 688                                 bot_strategytoken_taken = true;
 689                         }
 690                         this.nextbot = NULL;
 691                         break;
 692                 }
 693                 prev_bot = e;
 694                 e = e.nextbot;
 695         }
 696 }
 697
 698 void bot_clear(entity this)
 699 {
 700         bot_remove_from_bot_list(this);
 701         if(bot_waypoint_queue_owner == this)
 702                 bot_waypoint_queue_owner = NULL;
 703         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 704 }
 705
 706 void bot_serverframe()
 707 {
 708         if (intermission_running && currentbots > 0)
 709         {
 710                 // after the end of the match all bots stay unless all human players disconnect
 711                 int realplayers = 0;
 712                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 713                 if (!realplayers)
 714                 {
 715                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 716                         currentbots = 0;
 717                 }
 718                 return;
 719         }
 720
 721         if (game_stopped)
 722                 return;
 723
 724         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 725         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 726         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 727         // either intentionally or automatically (sv_spectate 0)
 728         if (time < 2.5)
 729         {
 730                 currentbots = -1;
 731                 return;
 732         }
 733
 734         if (currentbots == -1)
 735         {
 736                 // count bots already in the server from the previous match
 737                 currentbots = 0;
 738                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 739         }
 740
 741         if(autocvar_skill != skill)
 742         {
 743                 float wpcost_update = false;
 744                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 745                         wpcost_update = true;
 746                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 747                         wpcost_update = true;
 748
 749                 skill = autocvar_skill;
 750                 if (wpcost_update)
 751                         waypoint_updatecost_foralllinks();
 752         }
 753
 754         bot_calculate_stepheightvec();
 755         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 756
 757         if(time > autoskill_nextthink)
 758         {
 759                 float a;
 760                 a = autocvar_skill_auto;
 761                 if(a)
 762                         autoskill(a);
 763                 autoskill_nextthink = time + 5;
 764         }
 765
 766         if(time > botframe_nextthink)
 767         {
 768                 if(!bot_fixcount())
 769                         botframe_nextthink = time + 10;
 770         }
 771
 772         if(botframe_spawnedwaypoints)
 773         {
 774                 if(autocvar_waypoint_benchmark)
 775                         localcmd("quit\n");
 776         }
 777
 778         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 779         if (botframe_spawnedwaypoints)
 780         {
 781                 if(botframe_cachedwaypointlinks)
 782                 {
 783                         if(!botframe_loadedforcedlinks)
 784                                 waypoint_load_hardwiredlinks();
 785                 }
 786                 else
 787                 {
 788                         // TODO: Make this check cleaner
 789                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 790                         {
 791                                 waypoint_save_links();
 792                                 break;
 793                         });
 794                 }
 795         }
 796         else
 797         {
 798                 botframe_spawnedwaypoints = true;
 799                 waypoint_loadall();
 800                 waypoint_load_links();
 801         }
 802
 803         if (bot_list)
 804         {
 805                 // cycle the goal token from one bot to the next each frame
 806                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 807                 //  frame, which causes choppy framerates)
 808                 if (bot_strategytoken_taken)
 809                 {
 810                         // give goal token to the first bot without goals; if all bots don't have
 811                         // any goal (or are dead/frozen) simply give it to the next one
 812                         bot_strategytoken_taken = false;
 813                         entity bot_strategytoken_save = bot_strategytoken;
 814                         while (true)
 815                         {
 816                                 if (bot_strategytoken)
 817                                         bot_strategytoken = bot_strategytoken.nextbot;
 818                                 if (!bot_strategytoken)
 819                                         bot_strategytoken = bot_list;
 820
 821                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 822                                         && !bot_strategytoken.goalcurrent)
 823                                         break;
 824
 825                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 826                                         break;
 827                                 if (bot_strategytoken == bot_strategytoken_save)
 828                                         bot_strategytoken_save = NULL; // looped through all the bots
 829                         }
 830                 }
 831
 832                 if (botframe_nextdangertime < time)
 833                 {
 834                         float interval;
 835                         interval = autocvar_bot_ai_dangerdetectioninterval;
 836                         if (botframe_nextdangertime < time - interval * 1.5)
 837                                 botframe_nextdangertime = time;
 838                         botframe_nextdangertime = botframe_nextdangertime + interval;
 839                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 840                 }
 841         }
 842
 843         if (autocvar_g_waypointeditor)
 844                 botframe_showwaypointlinks();
 845
 846         if (autocvar_g_waypointeditor_auto)
 847                 botframe_autowaypoints();
 848
 849         if(time > bot_cvar_nextthink)
 850         {
 851                 if(currentbots>0)
 852                         bot_custom_weapon_priority_setup();
 853                 bot_cvar_nextthink = time + 5;
 854         }
 855 }