Merge branch 'master' into terencehill/bot_ai
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / bot.qc
1 #include "bot.qh"
2
3 #include "cvars.qh"
4
5 #include "aim.qh"
6 #include "navigation.qh"
7 #include "scripting.qh"
8 #include "waypoints.qh"
9
10 #include "havocbot/havocbot.qh"
11 #include "havocbot/scripting.qh"
12
13 #include "../../teamplay.qh"
14
15 #include "../../antilag.qh"
16 #include "../../autocvars.qh"
17 #include "../../campaign.qh"
18 #include "../../client.qh"
19 #include "../../constants.qh"
20 #include "../../defs.qh"
21 #include "../../race.qh"
22 #include <common/t_items.qh>
23
24 #include <server/mutators/_mod.qh>
25
26 #include "../../weapons/accuracy.qh"
27
28 #include <common/physics/player.qh>
29 #include <common/constants.qh>
30 #include <common/net_linked.qh>
31 #include <common/mapinfo.qh>
32 #include <common/teams.qh>
33 #include <common/util.qh>
34
35 #include <server/scores_rules.qh>
36
37 #include <common/weapons/_all.qh>
38
39 #include <lib/csqcmodel/sv_model.qh>
40
41 #include <lib/warpzone/common.qh>
42 #include <lib/warpzone/util_server.qh>
43
44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
45
46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
47 void bot_setclientfields(entity this)
48 {
49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
51 }
52
53 entity bot_spawn()
54 {
55         entity bot = spawnclient();
56         if (bot)
57         {
58                 setItemGroupCount();
59                 currentbots = currentbots + 1;
60                 bot_setnameandstuff(bot);
61                 ClientConnect(bot);
62                 bot_setclientfields(bot);
63                 PutClientInServer(bot);
64         }
65         return bot;
66 }
67
68 void bot_think(entity this)
69 {
70         if (this.bot_nextthink > time)
71                 return;
72
73         this.flags &= ~FL_GODMODE;
74         if(autocvar_bot_god)
75                 this.flags |= FL_GODMODE;
76
77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
78
79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
80         {
81                 CS(this).movement = '0 0 0';
82                 this.bot_nextthink = time + 0.5;
83                 return;
84         }
85
86         if (this.fixangle)
87         {
88                 this.v_angle = this.angles;
89                 this.v_angle_z = 0;
90                 this.fixangle = false;
91         }
92
93         this.dmg_take = 0;
94         this.dmg_save = 0;
95         this.dmg_inflictor = NULL;
96
97         // calculate an aiming latency based on the skill setting
98         // (simulated network latency + naturally delayed reflexes)
99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
100         // minimum ping 20+10 random
101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
102         // skill 10 = ping 0.2 (adrenaline)
103         // skill 0 = ping 0.7 (slightly drunk)
104
105         // clear buttons
106         PHYS_INPUT_BUTTON_ATCK(this) = false;
107         // keep jump button pressed for a short while, useful with ramp jumps
108         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
109         PHYS_INPUT_BUTTON_ATCK2(this) = false;
110         PHYS_INPUT_BUTTON_ZOOM(this) = false;
111         PHYS_INPUT_BUTTON_CROUCH(this) = false;
112         PHYS_INPUT_BUTTON_HOOK(this) = false;
113         PHYS_INPUT_BUTTON_INFO(this) = false;
114         PHYS_INPUT_BUTTON_DRAG(this) = false;
115         PHYS_INPUT_BUTTON_CHAT(this) = false;
116         PHYS_INPUT_BUTTON_USE(this) = false;
117
118         if (time < game_starttime)
119         {
120                 // block the bot during the countdown to game start
121                 CS(this).movement = '0 0 0';
122                 this.bot_nextthink = game_starttime;
123                 return;
124         }
125
126         // if dead, just wait until we can respawn
127         if (IS_DEAD(this))
128         {
129                 if (bot_waypoint_queue_owner == this)
130                         bot_waypoint_queue_owner = NULL;
131                 this.aistatus = 0;
132                 CS(this).movement = '0 0 0';
133                 if (this.deadflag == DEAD_DEAD)
134                 {
135                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
136                         navigation_goalrating_timeout_force(this);
137                 }
138         }
139         else if(this.aistatus & AI_STATUS_STUCK)
140                 navigation_unstuck(this);
141
142         // now call the current bot AI (havocbot for example)
143         this.bot_ai(this);
144 }
145
146 void bot_setnameandstuff(entity this)
147 {
148         string readfile, s;
149         int file, tokens, prio;
150
151         file = fopen(autocvar_bot_config_file, FILE_READ);
152
153         if(file < 0)
154         {
155                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
156                 readfile = "";
157         }
158         else
159         {
160                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
161                 TeamBalance_GetTeamCounts(balance, NULL);
162                 int smallest_team = -1;
163                 int smallest_count = -1;
164                 if (teamplay)
165                 {
166                         for (int i = 1; i <= AvailableTeams(); ++i)
167                         {
168                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
169                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
170                                 // since it keeps a spot for the real player in the desired team
171                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
172                                 if (smallest_count < 0 || count < smallest_count)
173                                 {
174                                         smallest_team = i;
175                                         smallest_count = count;
176                                 }
177                         }
178                 }
179                 TeamBalance_Destroy(balance);
180                 RandomSelection_Init();
181                 while((readfile = fgets(file)))
182                 {
183                         if(substring(readfile, 0, 2) == "//")
184                                 continue;
185                         if(substring(readfile, 0, 1) == "#")
186                                 continue;
187                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
188                         // will create 1 empty token because there's no separator (bug?)
189                         if (readfile == "")
190                                 continue;
191                         tokens = tokenizebyseparator(readfile, "\t");
192                         if(tokens == 0)
193                                 continue;
194                         s = argv(0);
195                         prio = 0;
196                         bool conflict = false;
197                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
198                                 if (s == it.cleanname)
199                                 {
200                                         conflict = true;
201                                         break;
202                                 }
203                         });
204                         if (!conflict)
205                                 prio += 1;
206                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
207                         {
208                                 int forced_team = stof(argv(5));
209                                 if (!Team_IsValidIndex(forced_team))
210                                         forced_team = 0;
211                                 if (!forced_team || forced_team == smallest_team)
212                                         prio += 2;
213                         }
214                         RandomSelection_AddString(readfile, 1, prio);
215                 }
216                 readfile = RandomSelection_chosen_string;
217                 fclose(file);
218         }
219
220         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
221
222         tokens = tokenizebyseparator(readfile, "\t");
223         if(argv(0) != "") bot_name = argv(0);
224         else bot_name = "Bot";
225
226         if(argv(1) != "") bot_model = argv(1);
227         else bot_model = "";
228
229         if(argv(2) != "") bot_skin = argv(2);
230         else bot_skin = "0";
231
232         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
233         else bot_shirt = ftos(floor(random() * 15));
234
235         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
236         else bot_pants = ftos(floor(random() * 15));
237
238         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
239                 this.bot_forced_team = stof(argv(5));
240         else
241                 this.bot_forced_team = 0;
242
243         prio = 6;
244
245         #define READSKILL(f, w, r) MACRO_BEGIN \
246                 if(argv(prio) != "") \
247                         this.f = stof(argv(prio)) * w; \
248                 else \
249                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
250                 prio++; \
251         MACRO_END
252         //print(bot_name, ": ping=", argv(9), "\n");
253
254         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
255         READSKILL(bot_moveskill, 2, 0); // move skill
256         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
257
258         READSKILL(bot_pingskill, 0.5, 0); // ping skill
259
260         READSKILL(bot_weaponskill, 2, 0); // weapon skill
261         READSKILL(bot_aggresskill, 1, 0); // aggre skill
262         READSKILL(bot_rangepreference, 1, 0); // read skill
263
264         READSKILL(bot_aimskill, 2, 0); // aim skill
265         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
266         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
267
268         READSKILL(bot_thinkskill, 1, 0.5); // think skill
269         READSKILL(bot_aiskill, 2, 0); // "ai" skill
270
271         if (file >= 0 && argv(prio) != "")
272                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
273
274         this.bot_config_loaded = true;
275
276         // this is really only a default, TeamBalance_JoinBestTeam is called later
277         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
278         this.bot_preferredcolors = this.clientcolors;
279
280         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
281         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
282         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
283
284         if (name == "")
285         {
286                 name = ftos(etof(this));
287                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
288         }
289         else
290         {
291                 // number bots with identical names
292                 int j = 0;
293                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
294                         if(it.cleanname == name)
295                                 ++j;
296                 });
297                 if (j)
298                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
299                 else
300                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
301         }
302         this.cleanname = strzone(name);
303
304         // pick the model and skin
305         if(substring(bot_model, -4, 1) != ".")
306                 bot_model = strcat(bot_model, ".iqm");
307         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
308         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
309 }
310
311 void bot_custom_weapon_priority_setup()
312 {
313         static string bot_priority_far_prev;
314         static string bot_priority_mid_prev;
315         static string bot_priority_close_prev;
316         static string bot_priority_distances_prev;
317         float tokens, i, w;
318
319         bot_custom_weapon = false;
320
321         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
322                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
323                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
324                 autocvar_bot_ai_custom_weapon_priority_distances == ""
325         )
326                 return;
327
328         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
329         {
330                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
331                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
332
333                 if (tokens!=2)
334                         return;
335
336                 bot_distance_far = stof(argv(0));
337                 bot_distance_close = stof(argv(1));
338
339                 if(bot_distance_far < bot_distance_close){
340                         bot_distance_far = stof(argv(1));
341                         bot_distance_close = stof(argv(0));
342                 }
343         }
344
345         int c;
346
347         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
348                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
349                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
350                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
351                         bot_weapons_##dist[0] = -1; \
352                         c = 0; \
353                         for(i = 0; i < tokens && c < Weapons_COUNT; ++i) { \
354                                 w = stof(argv(i)); \
355                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
356                                         bot_weapons_##dist[c] = w; \
357                                         ++c; \
358                                 } \
359                         } \
360                         if (c < Weapons_COUNT) \
361                                 bot_weapons_##dist[c] = -1; \
362                 } \
363         MACRO_END
364
365         PARSE_WEAPON_PRIORITIES(far);
366         PARSE_WEAPON_PRIORITIES(mid);
367         PARSE_WEAPON_PRIORITIES(close);
368
369         bot_custom_weapon = true;
370 }
371
372 void bot_endgame()
373 {
374         bot_relinkplayerlist();
375         entity e = bot_list;
376         while (e)
377         {
378                 setcolor(e, e.bot_preferredcolors);
379                 e = e.nextbot;
380         }
381         // if dynamic waypoints are ever implemented, save them here
382 }
383
384 void bot_relinkplayerlist()
385 {
386         player_count = 0;
387         currentbots = 0;
388         bot_list = NULL;
389
390         entity prevbot = NULL;
391         FOREACH_CLIENT(true,
392         {
393                 ++player_count;
394
395                 if(IS_BOT_CLIENT(it))
396                 {
397                         if(prevbot)
398                                 prevbot.nextbot = it;
399                         else
400                                 bot_list = it;
401                         prevbot = it;
402                         ++currentbots;
403                 }
404         });
405         if(prevbot)
406                 prevbot.nextbot = NULL;
407         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
408         bot_strategytoken = bot_list;
409         bot_strategytoken_taken = true;
410 }
411
412 void bot_clientdisconnect(entity this)
413 {
414         if (!IS_BOT_CLIENT(this))
415                 return;
416         bot_clearqueue(this);
417         strfree(this.cleanname);
418         strfree(this.netname_freeme);
419         strfree(this.playermodel_freeme);
420         strfree(this.playerskin_freeme);
421         if(this.bot_cmd_current)
422                 delete(this.bot_cmd_current);
423         if(bot_waypoint_queue_owner == this)
424                 bot_waypoint_queue_owner = NULL;
425 }
426
427 void bot_clientconnect(entity this)
428 {
429         if (!IS_BOT_CLIENT(this)) return;
430         this.bot_preferredcolors = this.clientcolors;
431         this.bot_nextthink = time - random();
432         this.lag_func = bot_lagfunc;
433         this.isbot = true;
434         this.createdtime = this.bot_nextthink;
435
436         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
437         {
438                 bot_setnameandstuff(this);
439                 bot_setclientfields(this);
440         }
441
442         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
443         {
444                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
445         }
446         else
447         {
448                 this.bot_forced_team = 0;
449                 TeamBalance_JoinBestTeam(this);
450         }
451
452         havocbot_setupbot(this);
453 }
454
455 void bot_removefromlargestteam()
456 {
457         entity balance = TeamBalance_CheckAllowedTeams(NULL);
458         TeamBalance_GetTeamCounts(balance, NULL);
459
460         entity best = NULL;
461         float besttime = 0;
462         int bestcount = 0;
463
464         int bcount = 0;
465         FOREACH_CLIENT(it.isbot,
466         {
467                 ++bcount;
468
469                 if(!best)
470                 {
471                         best = it;
472                         besttime = it.createdtime;
473                 }
474
475                 int thiscount = 0;
476
477                 if (Team_IsValidTeam(it.team))
478                 {
479                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
480                                 Team_TeamToIndex(it.team));
481                 }
482
483                 if(thiscount > bestcount)
484                 {
485                         bestcount = thiscount;
486                         besttime = it.createdtime;
487                         best = it;
488                 }
489                 else if(thiscount == bestcount && besttime < it.createdtime)
490                 {
491                         besttime = it.createdtime;
492                         best = it;
493                 }
494         });
495         TeamBalance_Destroy(balance);
496         if(!bcount)
497                 return; // no bots to remove
498         currentbots = currentbots - 1;
499         dropclient(best);
500 }
501
502 void bot_removenewest()
503 {
504         if(teamplay)
505         {
506                 bot_removefromlargestteam();
507                 return;
508         }
509
510         float besttime = 0;
511         entity best = NULL;
512         int bcount = 0;
513
514         FOREACH_CLIENT(it.isbot,
515         {
516                 ++bcount;
517
518                 if(!best)
519                 {
520                         best = it;
521                         besttime = it.createdtime;
522                 }
523
524                 if(besttime < it.createdtime)
525                 {
526                         besttime = it.createdtime;
527                         best = it;
528                 }
529         });
530
531         if(!bcount)
532                 return; // no bots to remove
533
534         currentbots = currentbots - 1;
535         dropclient(best);
536 }
537
538 void autoskill(float factor)
539 {
540         float bestbot;
541         float bestplayer;
542
543         bestbot = -1;
544         bestplayer = -1;
545         FOREACH_CLIENT(IS_PLAYER(it), {
546                 if(IS_REAL_CLIENT(it))
547                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
548                 else
549                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
550         });
551
552         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
553         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
554         if(bestbot < 0 || bestplayer < 0)
555         {
556                 LOG_DEBUG("not doing anything");
557                 // don't return, let it reset all counters below
558         }
559         else if(bestbot <= bestplayer * factor - 2)
560         {
561                 if(autocvar_skill < 17)
562                 {
563                         LOG_DEBUG("2 frags difference, increasing skill");
564                         cvar_set("skill", ftos(autocvar_skill + 1));
565                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
566                 }
567         }
568         else if(bestbot >= bestplayer * factor + 2)
569         {
570                 if(autocvar_skill > 0)
571                 {
572                         LOG_DEBUG("2 frags difference, decreasing skill");
573                         cvar_set("skill", ftos(autocvar_skill - 1));
574                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
575                 }
576         }
577         else
578         {
579                 LOG_DEBUG("not doing anything");
580                 return;
581                 // don't reset counters, wait for them to accumulate
582         }
583
584         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
585 }
586
587 void bot_calculate_stepheightvec()
588 {
589         stepheightvec = autocvar_sv_stepheight * '0 0 1';
590         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
591         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
592         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
593 }
594
595 bool bot_fixcount()
596 {
597         int activerealplayers = 0;
598         int realplayers = 0;
599         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
600                 activerealplayers = M_ARGV(0, int);
601                 realplayers = M_ARGV(1, int);
602         } else {
603                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
604                         if(IS_PLAYER(it))
605                                 ++activerealplayers;
606                         ++realplayers;
607                 });
608         }
609
610         int bots;
611         // But don't remove bots immediately on level change, as the real players
612         // usually haven't rejoined yet
613         bots_would_leave = false;
614         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
615                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
616         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
617         {
618                 int minplayers = max(0, floor(autocvar_minplayers));
619                 if (teamplay)
620                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
621                 int minbots = max(0, floor(autocvar_bot_number));
622
623                 // add bots to reach minplayers if needed
624                 bots = max(minbots, minplayers - activerealplayers);
625                 // cap bots to the max players allowed by the server
626                 int player_limit = GetPlayerLimit();
627                 if(player_limit)
628                         bots = min(bots, max(player_limit - activerealplayers, 0));
629                 bots = min(bots, maxclients - realplayers);
630
631                 if(bots > minbots)
632                         bots_would_leave = true;
633         }
634         else
635         {
636                 // if there are no players, remove bots
637                 bots = 0;
638         }
639
640         // only add one bot per frame to avoid utter chaos
641         if(time > botframe_nextthink)
642         {
643                 if (currentbots < bots)
644                 {
645                         if (bot_spawn() == NULL)
646                         {
647                                 bprint("Can not add bot, server full.\n");
648                                 return false;
649                         }
650                 }
651                 while (currentbots > bots && bots >= 0)
652                         bot_removenewest();
653         }
654
655         return true;
656 }
657
658 void bot_remove_from_bot_list(entity this)
659 {
660         entity e = bot_list;
661         entity prev_bot = NULL;
662         while (e)
663         {
664                 if(e == this)
665                 {
666                         if(!prev_bot)
667                                 bot_list = this.nextbot;
668                         else
669                                 prev_bot.nextbot = this.nextbot;
670                         if(bot_strategytoken == this)
671                         {
672                                 bot_strategytoken = this.nextbot;
673                                 bot_strategytoken_taken = true;
674                         }
675                         this.nextbot = NULL;
676                         break;
677                 }
678                 prev_bot = e;
679                 e = e.nextbot;
680         }
681 }
682
683 void bot_clear(entity this)
684 {
685         bot_remove_from_bot_list(this);
686         if(bot_waypoint_queue_owner == this)
687                 bot_waypoint_queue_owner = NULL;
688         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
689 }
690
691 void bot_serverframe()
692 {
693         if (intermission_running && currentbots > 0)
694         {
695                 // after the end of the match all bots stay unless all human players disconnect
696                 int realplayers = 0;
697                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
698                 if (!realplayers)
699                 {
700                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
701                         currentbots = 0;
702                 }
703                 return;
704         }
705
706         if (game_stopped)
707                 return;
708
709         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
710         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
711         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
712         // either intentionally or automatically (sv_spectate 0)
713         if (time < 2.5)
714         {
715                 currentbots = -1;
716                 return;
717         }
718
719         if (currentbots == -1)
720         {
721                 // count bots already in the server from the previous match
722                 currentbots = 0;
723                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
724         }
725
726         if(autocvar_skill != skill)
727         {
728                 float wpcost_update = false;
729                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
730                         wpcost_update = true;
731                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
732                         wpcost_update = true;
733
734                 skill = autocvar_skill;
735                 if (wpcost_update)
736                         waypoint_updatecost_foralllinks();
737         }
738
739         bot_calculate_stepheightvec();
740         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
741
742         if(time > autoskill_nextthink)
743         {
744                 float a;
745                 a = autocvar_skill_auto;
746                 if(a)
747                         autoskill(a);
748                 autoskill_nextthink = time + 5;
749         }
750
751         if(time > botframe_nextthink)
752         {
753                 if(!bot_fixcount())
754                         botframe_nextthink = time + 10;
755         }
756
757         if(botframe_spawnedwaypoints)
758         {
759                 if(autocvar_waypoint_benchmark)
760                         localcmd("quit\n");
761         }
762
763         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
764         if (botframe_spawnedwaypoints)
765         {
766                 if(botframe_cachedwaypointlinks)
767                 {
768                         if(!botframe_loadedforcedlinks)
769                                 waypoint_load_hardwiredlinks();
770                 }
771                 else
772                 {
773                         // TODO: Make this check cleaner
774                         IL_EACH(g_waypoints, time - it.nextthink > 10,
775                         {
776                                 waypoint_save_links();
777                                 break;
778                         });
779                 }
780         }
781         else
782         {
783                 botframe_spawnedwaypoints = true;
784                 waypoint_loadall();
785                 waypoint_load_links();
786         }
787
788         if (bot_list)
789         {
790                 // cycle the goal token from one bot to the next each frame
791                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
792                 //  frame, which causes choppy framerates)
793                 if (bot_strategytoken_taken)
794                 {
795                         // give goal token to the first bot without goals; if all bots don't have
796                         // any goal (or are dead/frozen) simply give it to the next one
797                         bot_strategytoken_taken = false;
798                         entity bot_strategytoken_save = bot_strategytoken;
799                         while (true)
800                         {
801                                 if (bot_strategytoken)
802                                         bot_strategytoken = bot_strategytoken.nextbot;
803                                 if (!bot_strategytoken)
804                                         bot_strategytoken = bot_list;
805
806                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
807                                         && !bot_strategytoken.goalcurrent)
808                                         break;
809
810                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
811                                         break;
812                                 if (bot_strategytoken == bot_strategytoken_save)
813                                         bot_strategytoken_save = NULL; // looped through all the bots
814                         }
815                 }
816
817                 if (botframe_nextdangertime < time)
818                 {
819                         float interval;
820                         interval = autocvar_bot_ai_dangerdetectioninterval;
821                         if (botframe_nextdangertime < time - interval * 1.5)
822                                 botframe_nextdangertime = time;
823                         botframe_nextdangertime = botframe_nextdangertime + interval;
824                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
825                 }
826         }
827
828         if (autocvar_g_waypointeditor)
829                 botframe_showwaypointlinks();
830
831         if (autocvar_g_waypointeditor_auto)
832                 botframe_autowaypoints();
833
834         if (currentbots > 0)
835                 bot_custom_weapon_priority_setup();
836 }