Merge branch 'terencehill/gameover_stuff' into 'master'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / bot.qc
1 #include "bot.qh"
2
3 #include "cvars.qh"
4
5 #include "aim.qh"
6 #include "navigation.qh"
7 #include "scripting.qh"
8 #include "waypoints.qh"
9
10 #include "havocbot/havocbot.qh"
11 #include "havocbot/scripting.qh"
12
13 #include "../../teamplay.qh"
14
15 #include "../../antilag.qh"
16 #include "../../autocvars.qh"
17 #include "../../campaign.qh"
18 #include "../../client.qh"
19 #include "../../constants.qh"
20 #include "../../defs.qh"
21 #include "../../race.qh"
22 #include <common/t_items.qh>
23
24 #include "../../mutators/_mod.qh"
25
26 #include "../../weapons/accuracy.qh"
27
28 #include <common/physics/player.qh>
29 #include <common/constants.qh>
30 #include <common/net_linked.qh>
31 #include <common/mapinfo.qh>
32 #include <common/teams.qh>
33 #include <common/util.qh>
34
35 #include <server/scores_rules.qh>
36
37 #include <common/weapons/_all.qh>
38
39 #include <lib/csqcmodel/sv_model.qh>
40
41 #include <lib/warpzone/common.qh>
42 #include <lib/warpzone/util_server.qh>
43
44 entity bot_spawn()
45 {
46         entity bot = spawnclient();
47         if (bot)
48         {
49                 currentbots = currentbots + 1;
50                 bot_setnameandstuff(bot);
51                 ClientConnect(bot);
52                 PutClientInServer(bot);
53         }
54         return bot;
55 }
56
57 void bot_think(entity this)
58 {
59         if (this.bot_nextthink > time)
60                 return;
61
62         this.flags &= ~FL_GODMODE;
63         if(autocvar_bot_god)
64                 this.flags |= FL_GODMODE;
65
66         this.bot_nextthink = this.bot_nextthink + autocvar_bot_ai_thinkinterval * pow(0.5, this.bot_aiskill);
67         //if (this.bot_painintensity > 0)
68         //      this.bot_painintensity = this.bot_painintensity - (skill + 1) * 40 * frametime;
69
70         //this.bot_painintensity = this.bot_painintensity + this.bot_oldhealth - this.health;
71         //this.bot_painintensity = bound(0, this.bot_painintensity, 100);
72
73         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
74         {
75                 this.movement = '0 0 0';
76                 this.bot_nextthink = time + 0.5;
77                 return;
78         }
79
80         if (this.fixangle)
81         {
82                 this.v_angle = this.angles;
83                 this.v_angle_z = 0;
84                 this.fixangle = false;
85         }
86
87         this.dmg_take = 0;
88         this.dmg_save = 0;
89         this.dmg_inflictor = NULL;
90
91         // calculate an aiming latency based on the skill setting
92         // (simulated network latency + naturally delayed reflexes)
93         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
94         // minimum ping 20+10 random
95         this.ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
96         // skill 10 = ping 0.2 (adrenaline)
97         // skill 0 = ping 0.7 (slightly drunk)
98
99         // clear buttons
100         PHYS_INPUT_BUTTON_ATCK(this) = false;
101         PHYS_INPUT_BUTTON_JUMP(this) = false;
102         PHYS_INPUT_BUTTON_ATCK2(this) = false;
103         PHYS_INPUT_BUTTON_ZOOM(this) = false;
104         PHYS_INPUT_BUTTON_CROUCH(this) = false;
105         PHYS_INPUT_BUTTON_HOOK(this) = false;
106         PHYS_INPUT_BUTTON_INFO(this) = false;
107         PHYS_INPUT_BUTTON_DRAG(this) = false;
108         PHYS_INPUT_BUTTON_CHAT(this) = false;
109         PHYS_INPUT_BUTTON_USE(this) = false;
110
111         if (time < game_starttime)
112         {
113                 // block the bot during the countdown to game start
114                 this.movement = '0 0 0';
115                 this.bot_nextthink = game_starttime;
116                 return;
117         }
118
119         // if dead, just wait until we can respawn
120         if (IS_DEAD(this))
121         {
122                 this.movement = '0 0 0';
123                 if (this.deadflag == DEAD_DEAD)
124                 {
125                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
126                         this.bot_strategytime = 0;
127                 }
128         }
129         else if(this.aistatus & AI_STATUS_STUCK)
130                 navigation_unstuck(this);
131
132         // now call the current bot AI (havocbot for example)
133         this.bot_ai(this);
134 }
135
136 void bot_setnameandstuff(entity this)
137 {
138         string readfile, s;
139         float file, tokens, prio;
140
141         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
142         string name, prefix, suffix;
143
144         if(autocvar_g_campaign)
145         {
146                 prefix = "";
147                 suffix = "";
148         }
149         else
150         {
151                 prefix = autocvar_bot_prefix;
152                 suffix = autocvar_bot_suffix;
153         }
154
155         file = fopen(autocvar_bot_config_file, FILE_READ);
156
157         if(file < 0)
158         {
159                 LOG_INFO(strcat("Error: Can not open the bot configuration file '",autocvar_bot_config_file,"'\n"));
160                 readfile = "";
161         }
162         else
163         {
164                 RandomSelection_Init();
165                 while((readfile = fgets(file)))
166                 {
167                         if(substring(readfile, 0, 2) == "//")
168                                 continue;
169                         if(substring(readfile, 0, 1) == "#")
170                                 continue;
171                         tokens = tokenizebyseparator(readfile, "\t");
172                         if(tokens == 0)
173                                 continue;
174                         s = argv(0);
175                         prio = 1;
176                         FOREACH_CLIENT(IS_BOT_CLIENT(it), LAMBDA(
177                                 if(s == it.cleanname)
178                                 {
179                                         prio = 0;
180                                         break;
181                                 }
182                         ));
183                         RandomSelection_AddString(readfile, 1, prio);
184                 }
185                 readfile = RandomSelection_chosen_string;
186                 fclose(file);
187         }
188
189         tokens = tokenizebyseparator(readfile, "\t");
190         if(argv(0) != "") bot_name = argv(0);
191         else bot_name = "Bot";
192
193         if(argv(1) != "") bot_model = argv(1);
194         else bot_model = "";
195
196         if(argv(2) != "") bot_skin = argv(2);
197         else bot_skin = "0";
198
199         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
200         else bot_shirt = ftos(floor(random() * 15));
201
202         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
203         else bot_pants = ftos(floor(random() * 15));
204
205         this.bot_forced_team = stof(argv(5));
206
207         prio = 6;
208
209         #define READSKILL(f,w,r) if(argv(prio) != "") this.f = stof(argv(prio)) * (w); else this.f = (!autocvar_g_campaign) * (2 * random() - 1) * (r) * (w); ++prio
210         //print(bot_name, ": ping=", argv(9), "\n");
211
212         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
213         READSKILL(bot_moveskill, 2, 0); // move skill
214         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
215
216         READSKILL(bot_pingskill, 0.5, 0); // ping skill
217
218         READSKILL(bot_weaponskill, 2, 0); // weapon skill
219         READSKILL(bot_aggresskill, 1, 0); // aggre skill
220         READSKILL(bot_rangepreference, 1, 0); // read skill
221
222         READSKILL(bot_aimskill, 2, 0); // aim skill
223         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
224         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
225
226         READSKILL(bot_thinkskill, 1, 0.5); // think skill
227         READSKILL(bot_aiskill, 2, 0); // "ai" skill
228
229         this.bot_config_loaded = true;
230
231         // this is really only a default, JoinBestTeam is called later
232         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
233         this.bot_preferredcolors = this.clientcolors;
234
235         // pick the name
236         if (autocvar_bot_usemodelnames)
237                 name = bot_model;
238         else
239                 name = bot_name;
240
241         // number bots with identical names
242         int j = 0;
243         FOREACH_CLIENT(IS_BOT_CLIENT(it), LAMBDA(
244                 if(it.cleanname == name)
245                         ++j;
246         ));
247         if (j)
248                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
249         else
250                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
251
252         this.cleanname = strzone(name);
253
254         // pick the model and skin
255         if(substring(bot_model, -4, 1) != ".")
256                 bot_model = strcat(bot_model, ".iqm");
257         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
258         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
259
260         this.cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the NULL
261         this.cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
262 }
263
264 void bot_custom_weapon_priority_setup()
265 {
266         float tokens, i, w;
267
268         bot_custom_weapon = false;
269
270         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
271                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
272                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
273                 autocvar_bot_ai_custom_weapon_priority_distances == ""
274         )
275                 return;
276
277         // Parse distances
278         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
279
280         if (tokens!=2)
281                 return;
282
283         bot_distance_far = stof(argv(0));
284         bot_distance_close = stof(argv(1));
285
286         if(bot_distance_far < bot_distance_close){
287                 bot_distance_far = stof(argv(1));
288                 bot_distance_close = stof(argv(0));
289         }
290
291         // Initialize list of weapons
292         bot_weapons_far[0] = -1;
293         bot_weapons_mid[0] = -1;
294         bot_weapons_close[0] = -1;
295
296         // Parse far distance weapon priorities
297         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
298
299         int c = 0;
300         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
301                 w = stof(argv(i));
302                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
303                         bot_weapons_far[c] = w;
304                         ++c;
305                 }
306         }
307         if(c < Weapons_COUNT)
308                 bot_weapons_far[c] = -1;
309
310         // Parse mid distance weapon priorities
311         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
312
313         c = 0;
314         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
315                 w = stof(argv(i));
316                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
317                         bot_weapons_mid[c] = w;
318                         ++c;
319                 }
320         }
321         if(c < Weapons_COUNT)
322                 bot_weapons_mid[c] = -1;
323
324         // Parse close distance weapon priorities
325         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
326
327         c = 0;
328         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
329                 w = stof(argv(i));
330                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
331                         bot_weapons_close[c] = w;
332                         ++c;
333                 }
334         }
335         if(c < Weapons_COUNT)
336                 bot_weapons_close[c] = -1;
337
338         bot_custom_weapon = true;
339 }
340
341 void bot_endgame()
342 {
343         entity e;
344         //dprint("bot_endgame\n");
345         e = bot_list;
346         while (e)
347         {
348                 setcolor(e, e.bot_preferredcolors);
349                 e = e.nextbot;
350         }
351         // if dynamic waypoints are ever implemented, save them here
352 }
353
354 void bot_relinkplayerlist()
355 {
356         player_count = 0;
357         currentbots = 0;
358         bot_list = NULL;
359
360         entity prevbot = NULL;
361         FOREACH_CLIENT(true,
362         {
363                 ++player_count;
364
365                 if(IS_BOT_CLIENT(it))
366                 {
367                         if(prevbot)
368                                 prevbot.nextbot = it;
369                         else
370                         {
371                                 bot_list = it;
372                                 bot_list.nextbot = NULL;
373                         }
374                         prevbot = it;
375                         ++currentbots;
376                 }
377         });
378         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
379         bot_strategytoken = bot_list;
380         bot_strategytoken_taken = true;
381 }
382
383 void bot_clientdisconnect(entity this)
384 {
385         if (!IS_BOT_CLIENT(this))
386                 return;
387         bot_clearqueue(this);
388         if(this.cleanname)
389                 strunzone(this.cleanname);
390         if(this.netname_freeme)
391                 strunzone(this.netname_freeme);
392         if(this.playermodel_freeme)
393                 strunzone(this.playermodel_freeme);
394         if(this.playerskin_freeme)
395                 strunzone(this.playerskin_freeme);
396         this.cleanname = string_null;
397         this.netname_freeme = string_null;
398         this.playermodel_freeme = string_null;
399         this.playerskin_freeme = string_null;
400         if(this.bot_cmd_current)
401                 delete(this.bot_cmd_current);
402         if(bot_waypoint_queue_owner==this)
403                 bot_waypoint_queue_owner = NULL;
404 }
405
406 void bot_clientconnect(entity this)
407 {
408         if (!IS_BOT_CLIENT(this)) return;
409         this.bot_preferredcolors = this.clientcolors;
410         this.bot_nextthink = time - random();
411         this.lag_func = bot_lagfunc;
412         this.isbot = true;
413         this.createdtime = this.bot_nextthink;
414
415         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
416                 bot_setnameandstuff(this);
417
418         if(this.bot_forced_team==1)
419                 this.team = NUM_TEAM_1;
420         else if(this.bot_forced_team==2)
421                 this.team = NUM_TEAM_2;
422         else if(this.bot_forced_team==3)
423                 this.team = NUM_TEAM_3;
424         else if(this.bot_forced_team==4)
425                 this.team = NUM_TEAM_4;
426         else
427                 JoinBestTeam(this, false, true);
428
429         havocbot_setupbot(this);
430 }
431
432 void bot_removefromlargestteam()
433 {
434         CheckAllowedTeams(NULL);
435         GetTeamCounts(NULL);
436
437         entity best = NULL;
438         float besttime = 0;
439         int bestcount = 0;
440
441         int bcount = 0;
442         FOREACH_CLIENT(it.isbot,
443         {
444                 ++bcount;
445
446                 if(!best)
447                 {
448                         best = it;
449                         besttime = it.createdtime;
450                 }
451
452                 int thiscount = 0;
453
454                 switch(it.team)
455                 {
456                         case NUM_TEAM_1: thiscount = c1; break;
457                         case NUM_TEAM_2: thiscount = c2; break;
458                         case NUM_TEAM_3: thiscount = c3; break;
459                         case NUM_TEAM_4: thiscount = c4; break;
460                 }
461
462                 if(thiscount > bestcount)
463                 {
464                         bestcount = thiscount;
465                         besttime = it.createdtime;
466                         best = it;
467                 }
468                 else if(thiscount == bestcount && besttime < it.createdtime)
469                 {
470                         besttime = it.createdtime;
471                         best = it;
472                 }
473         });
474         if(!bcount)
475                 return; // no bots to remove
476         currentbots = currentbots - 1;
477         dropclient(best);
478 }
479
480 void bot_removenewest()
481 {
482         if(teamplay)
483         {
484                 bot_removefromlargestteam();
485                 return;
486         }
487
488         float besttime = 0;
489         entity best = NULL;
490         int bcount = 0;
491
492         FOREACH_CLIENT(it.isbot,
493         {
494                 ++bcount;
495
496                 if(!best)
497                 {
498                         best = it;
499                         besttime = it.createdtime;
500                 }
501
502                 if(besttime < it.createdtime)
503                 {
504                         besttime = it.createdtime;
505                         best = it;
506                 }
507         });
508
509         if(!bcount)
510                 return; // no bots to remove
511
512         currentbots = currentbots - 1;
513         dropclient(best);
514 }
515
516 void autoskill(float factor)
517 {
518         float bestbot;
519         float bestplayer;
520
521         bestbot = -1;
522         bestplayer = -1;
523         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
524                 if(IS_REAL_CLIENT(it))
525                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
526                 else
527                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
528         ));
529
530         LOG_TRACE("autoskill: best player got ", ftos(bestplayer), ", ");
531         LOG_TRACE("best bot got ", ftos(bestbot), "; ");
532         if(bestbot < 0 || bestplayer < 0)
533         {
534                 LOG_TRACE("not doing anything");
535                 // don't return, let it reset all counters below
536         }
537         else if(bestbot <= bestplayer * factor - 2)
538         {
539                 if(autocvar_skill < 17)
540                 {
541                         LOG_TRACE("2 frags difference, increasing skill");
542                         cvar_set("skill", ftos(autocvar_skill + 1));
543                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
544                 }
545         }
546         else if(bestbot >= bestplayer * factor + 2)
547         {
548                 if(autocvar_skill > 0)
549                 {
550                         LOG_TRACE("2 frags difference, decreasing skill");
551                         cvar_set("skill", ftos(autocvar_skill - 1));
552                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
553                 }
554         }
555         else
556         {
557                 LOG_TRACE("not doing anything");
558                 return;
559                 // don't reset counters, wait for them to accumulate
560         }
561
562         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.totalfrags_lastcheck = it.totalfrags));
563 }
564
565 void bot_calculate_stepheightvec()
566 {
567         stepheightvec = autocvar_sv_stepheight * '0 0 1';
568         jumpstepheightvec = stepheightvec +
569                 ((autocvar_sv_jumpvelocity * autocvar_sv_jumpvelocity) / (2 * autocvar_sv_gravity)) * '0 0 0.85';
570                 // 0.75 factor is for safety to make the jumps easy
571 }
572
573 float bot_fixcount()
574 {
575         int activerealplayers = 0;
576         int realplayers = 0;
577         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
578                 activerealplayers = M_ARGV(0, int);
579                 realplayers = M_ARGV(1, int);
580         } else {
581                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
582                         if(IS_PLAYER(it))
583                                 ++activerealplayers;
584                         ++realplayers;
585                 ));
586         }
587
588         int bots;
589         // add/remove bots if needed to make sure there are at least
590         // minplayers+bot_number, or remove all bots if no one is playing
591         // But don't remove bots immediately on level change, as the real players
592         // usually haven't rejoined yet
593         bots_would_leave = false;
594         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
595                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
596         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
597         {
598                 float realminplayers, minplayers;
599                 realminplayers = autocvar_minplayers;
600                 minplayers = max(0, floor(realminplayers));
601
602                 float realminbots, minbots;
603                 realminbots = autocvar_bot_number;
604                 minbots = max(0, floor(realminbots));
605
606                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
607                 if(bots > minbots)
608                         bots_would_leave = true;
609         }
610         else
611         {
612                 // if there are no players, remove bots
613                 bots = 0;
614         }
615
616         // only add one bot per frame to avoid utter chaos
617         if(time > botframe_nextthink)
618         {
619                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
620                 while (currentbots < bots)
621                 {
622                         if (bot_spawn() == NULL)
623                         {
624                                 bprint("Can not add bot, server full.\n");
625                                 return false;
626                         }
627                 }
628                 while (currentbots > bots)
629                         bot_removenewest();
630         }
631
632         return true;
633 }
634
635 void bot_serverframe()
636 {
637         if (gameover)
638                 return;
639
640         if (time < 2)
641                 return;
642
643         bot_calculate_stepheightvec();
644         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
645
646         if(time > autoskill_nextthink)
647         {
648                 float a;
649                 a = autocvar_skill_auto;
650                 if(a)
651                         autoskill(a);
652                 autoskill_nextthink = time + 5;
653         }
654
655         if(time > botframe_nextthink)
656         {
657                 if(!bot_fixcount())
658                         botframe_nextthink = time + 10;
659         }
660
661         bot_ignore_bots = autocvar_bot_ignore_bots;
662
663         if(botframe_spawnedwaypoints)
664         {
665                 if(autocvar_waypoint_benchmark)
666                         localcmd("quit\n");
667         }
668
669         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
670         if (botframe_spawnedwaypoints)
671         {
672                 if(botframe_cachedwaypointlinks)
673                 {
674                         if(!botframe_loadedforcedlinks)
675                                 waypoint_load_links_hardwired();
676                 }
677                 else
678                 {
679                         // TODO: Make this check cleaner
680                         IL_EACH(g_waypoints, time - it.nextthink > 10,
681                         {
682                                 waypoint_save_links();
683                                 break;
684                         });
685                 }
686         }
687         else
688         {
689                 botframe_spawnedwaypoints = true;
690                 waypoint_loadall();
691                 if(!waypoint_load_links())
692                         waypoint_schedulerelinkall();
693         }
694
695         if (bot_list)
696         {
697                 // cycle the goal token from one bot to the next each frame
698                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
699                 //  frame, which causes choppy framerates)
700                 if (bot_strategytoken_taken)
701                 {
702                         bot_strategytoken_taken = false;
703                         if (bot_strategytoken)
704                                 bot_strategytoken = bot_strategytoken.nextbot;
705                         if (!bot_strategytoken)
706                                 bot_strategytoken = bot_list;
707                 }
708
709                 if (botframe_nextdangertime < time)
710                 {
711                         float interval;
712                         interval = autocvar_bot_ai_dangerdetectioninterval;
713                         if (botframe_nextdangertime < time - interval * 1.5)
714                                 botframe_nextdangertime = time;
715                         botframe_nextdangertime = botframe_nextdangertime + interval;
716                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
717                 }
718         }
719
720         if (autocvar_g_waypointeditor)
721                 botframe_showwaypointlinks();
722
723         if (autocvar_g_waypointeditor_auto)
724                 botframe_autowaypoints();
725
726         if(time > bot_cvar_nextthink)
727         {
728                 if(currentbots>0)
729                         bot_custom_weapon_priority_setup();
730                 bot_cvar_nextthink = time + 5;
731         }
732 }