qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  45 void bot_setclientfields(entity this)
  46 {
  47         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  48         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  49 }
  50
  51 entity bot_spawn()
  52 {
  53         entity bot = spawnclient();
  54         if (bot)
  55         {
  56                 setItemGroupCount();
  57                 currentbots = currentbots + 1;
  58                 bot_setnameandstuff(bot);
  59                 ClientConnect(bot);
  60                 bot_setclientfields(bot);
  61                 PutClientInServer(bot);
  62         }
  63         return bot;
  64 }
  65
  66 void bot_think(entity this)
  67 {
  68         if (this.bot_nextthink > time)
  69                 return;
  70
  71         this.flags &= ~FL_GODMODE;
  72         if(autocvar_bot_god)
  73                 this.flags |= FL_GODMODE;
  74
  75         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  76
  77         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  78         {
  79                 CS(this).movement = '0 0 0';
  80                 this.bot_nextthink = time + 0.5;
  81                 return;
  82         }
  83
  84         if (this.fixangle)
  85         {
  86                 this.v_angle = this.angles;
  87                 this.v_angle_z = 0;
  88                 this.fixangle = false;
  89         }
  90
  91         this.dmg_take = 0;
  92         this.dmg_save = 0;
  93         this.dmg_inflictor = NULL;
  94
  95         // calculate an aiming latency based on the skill setting
  96         // (simulated network latency + naturally delayed reflexes)
  97         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  98         // minimum ping 20+10 random
  99         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 100         // skill 10 = ping 0.2 (adrenaline)
 101         // skill 0 = ping 0.7 (slightly drunk)
 102
 103         // clear buttons
 104         PHYS_INPUT_BUTTON_ATCK(this) = false;
 105         PHYS_INPUT_BUTTON_JUMP(this) = false;
 106         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 107         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 108         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 109         PHYS_INPUT_BUTTON_HOOK(this) = false;
 110         PHYS_INPUT_BUTTON_INFO(this) = false;
 111         PHYS_INPUT_BUTTON_DRAG(this) = false;
 112         PHYS_INPUT_BUTTON_CHAT(this) = false;
 113         PHYS_INPUT_BUTTON_USE(this) = false;
 114
 115         if (time < game_starttime)
 116         {
 117                 // block the bot during the countdown to game start
 118                 CS(this).movement = '0 0 0';
 119                 this.bot_nextthink = game_starttime;
 120                 return;
 121         }
 122
 123         // if dead, just wait until we can respawn
 124         if (IS_DEAD(this))
 125         {
 126                 if (bot_waypoint_queue_owner == this)
 127                         bot_waypoint_queue_owner = NULL;
 128                 this.aistatus = 0;
 129                 CS(this).movement = '0 0 0';
 130                 if (this.deadflag == DEAD_DEAD)
 131                 {
 132                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 133                         navigation_goalrating_timeout_force(this);
 134                 }
 135         }
 136         else if(this.aistatus & AI_STATUS_STUCK)
 137                 navigation_unstuck(this);
 138
 139         // now call the current bot AI (havocbot for example)
 140         this.bot_ai(this);
 141 }
 142
 143 void bot_setnameandstuff(entity this)
 144 {
 145         string readfile, s;
 146         float file, tokens, prio;
 147
 148         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 149         string name, prefix, suffix;
 150
 151         if(autocvar_g_campaign)
 152         {
 153                 prefix = "";
 154                 suffix = "";
 155         }
 156         else
 157         {
 158                 prefix = autocvar_bot_prefix;
 159                 suffix = autocvar_bot_suffix;
 160         }
 161
 162         file = fopen(autocvar_bot_config_file, FILE_READ);
 163
 164         if(file < 0)
 165         {
 166                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 167                 readfile = "";
 168         }
 169         else
 170         {
 171                 RandomSelection_Init();
 172                 while((readfile = fgets(file)))
 173                 {
 174                         if(substring(readfile, 0, 2) == "//")
 175                                 continue;
 176                         if(substring(readfile, 0, 1) == "#")
 177                                 continue;
 178                         tokens = tokenizebyseparator(readfile, "\t");
 179                         if(tokens == 0)
 180                                 continue;
 181                         s = argv(0);
 182                         prio = 1;
 183                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 184                                 if(s == it.cleanname)
 185                                 {
 186                                         prio = 0;
 187                                         break;
 188                                 }
 189                         });
 190                         RandomSelection_AddString(readfile, 1, prio);
 191                 }
 192                 readfile = RandomSelection_chosen_string;
 193                 fclose(file);
 194         }
 195
 196         tokens = tokenizebyseparator(readfile, "\t");
 197         if(argv(0) != "") bot_name = argv(0);
 198         else bot_name = "Bot";
 199
 200         if(argv(1) != "") bot_model = argv(1);
 201         else bot_model = "";
 202
 203         if(argv(2) != "") bot_skin = argv(2);
 204         else bot_skin = "0";
 205
 206         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 207         else bot_shirt = ftos(floor(random() * 15));
 208
 209         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 210         else bot_pants = ftos(floor(random() * 15));
 211
 212         this.bot_forced_team = stof(argv(5));
 213
 214         prio = 6;
 215
 216         #define READSKILL(f, w, r) MACRO_BEGIN { \
 217                 if(argv(prio) != "") \
 218                         this.f = stof(argv(prio)) * w; \
 219                 else \
 220                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 221                 prio++; \
 222         } MACRO_END
 223         //print(bot_name, ": ping=", argv(9), "\n");
 224
 225         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 226         READSKILL(bot_moveskill, 2, 0); // move skill
 227         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 228
 229         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 230
 231         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 232         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 233         READSKILL(bot_rangepreference, 1, 0); // read skill
 234
 235         READSKILL(bot_aimskill, 2, 0); // aim skill
 236         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 237         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 238
 239         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 240         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 241
 242         this.bot_config_loaded = true;
 243
 244         // this is really only a default, JoinBestTeam is called later
 245         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 246         this.bot_preferredcolors = this.clientcolors;
 247
 248         // pick the name
 249         if (autocvar_bot_usemodelnames)
 250                 name = bot_model;
 251         else
 252                 name = bot_name;
 253
 254         // number bots with identical names
 255         if (name == "")
 256         {
 257                 name = ftos(etof(this));
 258                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 259         }
 260         else
 261         {
 262                 int j = 0;
 263                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 264                         if(it.cleanname == name)
 265                                 ++j;
 266                 });
 267                 if (j)
 268                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 269                 else
 270                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 271         }
 272         this.cleanname = strzone(name);
 273
 274         // pick the model and skin
 275         if(substring(bot_model, -4, 1) != ".")
 276                 bot_model = strcat(bot_model, ".iqm");
 277         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 278         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 279 }
 280
 281 void bot_custom_weapon_priority_setup()
 282 {
 283         float tokens, i, w;
 284
 285         bot_custom_weapon = false;
 286
 287         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 288                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 289                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 290                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 291         )
 292                 return;
 293
 294         // Parse distances
 295         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 296
 297         if (tokens!=2)
 298                 return;
 299
 300         bot_distance_far = stof(argv(0));
 301         bot_distance_close = stof(argv(1));
 302
 303         if(bot_distance_far < bot_distance_close){
 304                 bot_distance_far = stof(argv(1));
 305                 bot_distance_close = stof(argv(0));
 306         }
 307
 308         // Initialize list of weapons
 309         bot_weapons_far[0] = -1;
 310         bot_weapons_mid[0] = -1;
 311         bot_weapons_close[0] = -1;
 312
 313         // Parse far distance weapon priorities
 314         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 315
 316         int c = 0;
 317         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 318                 w = stof(argv(i));
 319                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 320                         bot_weapons_far[c] = w;
 321                         ++c;
 322                 }
 323         }
 324         if(c < Weapons_COUNT)
 325                 bot_weapons_far[c] = -1;
 326
 327         // Parse mid distance weapon priorities
 328         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 329
 330         c = 0;
 331         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 332                 w = stof(argv(i));
 333                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 334                         bot_weapons_mid[c] = w;
 335                         ++c;
 336                 }
 337         }
 338         if(c < Weapons_COUNT)
 339                 bot_weapons_mid[c] = -1;
 340
 341         // Parse close distance weapon priorities
 342         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 343
 344         c = 0;
 345         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 346                 w = stof(argv(i));
 347                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 348                         bot_weapons_close[c] = w;
 349                         ++c;
 350                 }
 351         }
 352         if(c < Weapons_COUNT)
 353                 bot_weapons_close[c] = -1;
 354
 355         bot_custom_weapon = true;
 356 }
 357
 358 void bot_endgame()
 359 {
 360         bot_relinkplayerlist();
 361         entity e = bot_list;
 362         while (e)
 363         {
 364                 setcolor(e, e.bot_preferredcolors);
 365                 e = e.nextbot;
 366         }
 367         // if dynamic waypoints are ever implemented, save them here
 368 }
 369
 370 void bot_relinkplayerlist()
 371 {
 372         player_count = 0;
 373         currentbots = 0;
 374         bot_list = NULL;
 375
 376         entity prevbot = NULL;
 377         FOREACH_CLIENT(true,
 378         {
 379                 ++player_count;
 380
 381                 if(IS_BOT_CLIENT(it))
 382                 {
 383                         if(prevbot)
 384                                 prevbot.nextbot = it;
 385                         else
 386                                 bot_list = it;
 387                         prevbot = it;
 388                         ++currentbots;
 389                 }
 390         });
 391         if(prevbot)
 392                 prevbot.nextbot = NULL;
 393         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 394         bot_strategytoken = bot_list;
 395         bot_strategytoken_taken = true;
 396 }
 397
 398 void bot_clientdisconnect(entity this)
 399 {
 400         if (!IS_BOT_CLIENT(this))
 401                 return;
 402         bot_clearqueue(this);
 403         strfree(this.cleanname);
 404         strfree(this.netname_freeme);
 405         strfree(this.playermodel_freeme);
 406         strfree(this.playerskin_freeme);
 407         if(this.bot_cmd_current)
 408                 delete(this.bot_cmd_current);
 409         if(bot_waypoint_queue_owner == this)
 410                 bot_waypoint_queue_owner = NULL;
 411 }
 412
 413 void bot_clientconnect(entity this)
 414 {
 415         if (!IS_BOT_CLIENT(this)) return;
 416         this.bot_preferredcolors = this.clientcolors;
 417         this.bot_nextthink = time - random();
 418         this.lag_func = bot_lagfunc;
 419         this.isbot = true;
 420         this.createdtime = this.bot_nextthink;
 421
 422         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 423         {
 424                 bot_setnameandstuff(this);
 425                 bot_setclientfields(this);
 426         }
 427
 428         if(this.bot_forced_team==1)
 429                 this.team = NUM_TEAM_1;
 430         else if(this.bot_forced_team==2)
 431                 this.team = NUM_TEAM_2;
 432         else if(this.bot_forced_team==3)
 433                 this.team = NUM_TEAM_3;
 434         else if(this.bot_forced_team==4)
 435                 this.team = NUM_TEAM_4;
 436         else
 437                 JoinBestTeam(this, true);
 438
 439         havocbot_setupbot(this);
 440 }
 441
 442 void bot_removefromlargestteam()
 443 {
 444         CheckAllowedTeams(NULL);
 445         GetTeamCounts(NULL);
 446
 447         entity best = NULL;
 448         float besttime = 0;
 449         int bestcount = 0;
 450
 451         int bcount = 0;
 452         FOREACH_CLIENT(it.isbot,
 453         {
 454                 ++bcount;
 455
 456                 if(!best)
 457                 {
 458                         best = it;
 459                         besttime = it.createdtime;
 460                 }
 461
 462                 int thiscount = 0;
 463
 464                 switch(it.team)
 465                 {
 466                         case NUM_TEAM_1: thiscount = c1; break;
 467                         case NUM_TEAM_2: thiscount = c2; break;
 468                         case NUM_TEAM_3: thiscount = c3; break;
 469                         case NUM_TEAM_4: thiscount = c4; break;
 470                 }
 471
 472                 if(thiscount > bestcount)
 473                 {
 474                         bestcount = thiscount;
 475                         besttime = it.createdtime;
 476                         best = it;
 477                 }
 478                 else if(thiscount == bestcount && besttime < it.createdtime)
 479                 {
 480                         besttime = it.createdtime;
 481                         best = it;
 482                 }
 483         });
 484         if(!bcount)
 485                 return; // no bots to remove
 486         currentbots = currentbots - 1;
 487         dropclient(best);
 488 }
 489
 490 void bot_removenewest()
 491 {
 492         if(teamplay)
 493         {
 494                 bot_removefromlargestteam();
 495                 return;
 496         }
 497
 498         float besttime = 0;
 499         entity best = NULL;
 500         int bcount = 0;
 501
 502         FOREACH_CLIENT(it.isbot,
 503         {
 504                 ++bcount;
 505
 506                 if(!best)
 507                 {
 508                         best = it;
 509                         besttime = it.createdtime;
 510                 }
 511
 512                 if(besttime < it.createdtime)
 513                 {
 514                         besttime = it.createdtime;
 515                         best = it;
 516                 }
 517         });
 518
 519         if(!bcount)
 520                 return; // no bots to remove
 521
 522         currentbots = currentbots - 1;
 523         dropclient(best);
 524 }
 525
 526 void autoskill(float factor)
 527 {
 528         float bestbot;
 529         float bestplayer;
 530
 531         bestbot = -1;
 532         bestplayer = -1;
 533         FOREACH_CLIENT(IS_PLAYER(it), {
 534                 if(IS_REAL_CLIENT(it))
 535                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 536                 else
 537                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 538         });
 539
 540         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 541         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 542         if(bestbot < 0 || bestplayer < 0)
 543         {
 544                 LOG_DEBUG("not doing anything");
 545                 // don't return, let it reset all counters below
 546         }
 547         else if(bestbot <= bestplayer * factor - 2)
 548         {
 549                 if(autocvar_skill < 17)
 550                 {
 551                         LOG_DEBUG("2 frags difference, increasing skill");
 552                         cvar_set("skill", ftos(autocvar_skill + 1));
 553                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 554                 }
 555         }
 556         else if(bestbot >= bestplayer * factor + 2)
 557         {
 558                 if(autocvar_skill > 0)
 559                 {
 560                         LOG_DEBUG("2 frags difference, decreasing skill");
 561                         cvar_set("skill", ftos(autocvar_skill - 1));
 562                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 563                 }
 564         }
 565         else
 566         {
 567                 LOG_DEBUG("not doing anything");
 568                 return;
 569                 // don't reset counters, wait for them to accumulate
 570         }
 571
 572         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 573 }
 574
 575 void bot_calculate_stepheightvec()
 576 {
 577         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 578         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 579         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 580 }
 581
 582 float bot_fixcount()
 583 {
 584         int activerealplayers = 0;
 585         int realplayers = 0;
 586         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 587                 activerealplayers = M_ARGV(0, int);
 588                 realplayers = M_ARGV(1, int);
 589         } else {
 590                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 591                         if(IS_PLAYER(it))
 592                                 ++activerealplayers;
 593                         ++realplayers;
 594                 });
 595         }
 596
 597         int bots;
 598         // add/remove bots if needed to make sure there are at least
 599         // minplayers+bot_number, or remove all bots if no one is playing
 600         // But don't remove bots immediately on level change, as the real players
 601         // usually haven't rejoined yet
 602         bots_would_leave = false;
 603         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 604                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 605         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 606         {
 607                 float realminplayers, minplayers;
 608                 realminplayers = autocvar_minplayers;
 609                 minplayers = max(0, floor(realminplayers));
 610
 611                 float realminbots, minbots;
 612                 realminbots = autocvar_bot_number;
 613                 minbots = max(0, floor(realminbots));
 614
 615                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 616                 if(bots > minbots)
 617                         bots_would_leave = true;
 618         }
 619         else
 620         {
 621                 // if there are no players, remove bots
 622                 bots = 0;
 623         }
 624
 625         // only add one bot per frame to avoid utter chaos
 626         if(time > botframe_nextthink)
 627         {
 628                 if (currentbots < bots)
 629                 {
 630                         if (bot_spawn() == NULL)
 631                         {
 632                                 bprint("Can not add bot, server full.\n");
 633                                 return false;
 634                         }
 635                 }
 636                 while (currentbots > bots)
 637                         bot_removenewest();
 638         }
 639
 640         return true;
 641 }
 642
 643 void bot_remove_from_bot_list(entity this)
 644 {
 645         entity e = bot_list;
 646         entity prev_bot = NULL;
 647         while (e)
 648         {
 649                 if(e == this)
 650                 {
 651                         if(!prev_bot)
 652                                 bot_list = this.nextbot;
 653                         else
 654                                 prev_bot.nextbot = this.nextbot;
 655                         if(bot_strategytoken == this)
 656                         {
 657                                 bot_strategytoken = this.nextbot;
 658                                 bot_strategytoken_taken = true;
 659                         }
 660                         this.nextbot = NULL;
 661                         break;
 662                 }
 663                 prev_bot = e;
 664                 e = e.nextbot;
 665         }
 666 }
 667
 668 void bot_clear(entity this)
 669 {
 670         bot_remove_from_bot_list(this);
 671         if(bot_waypoint_queue_owner == this)
 672                 bot_waypoint_queue_owner = NULL;
 673         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 674 }
 675
 676 void bot_serverframe()
 677 {
 678         if (intermission_running && currentbots > 0)
 679         {
 680                 // after the end of the match all bots stay unless all human players disconnect
 681                 int realplayers = 0;
 682                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 683                 if (!realplayers)
 684                 {
 685                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 686                         currentbots = 0;
 687                 }
 688                 return;
 689         }
 690
 691         if (game_stopped)
 692                 return;
 693
 694         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 695         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 696         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 697         // either intentionally or automatically (sv_spectate 0)
 698         if (time < 2.5)
 699         {
 700                 currentbots = -1;
 701                 return;
 702         }
 703
 704         if (currentbots == -1)
 705         {
 706                 // count bots already in the server from the previous match
 707                 currentbots = 0;
 708                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 709         }
 710
 711         if(autocvar_skill != skill)
 712         {
 713                 float wpcost_update = false;
 714                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 715                         wpcost_update = true;
 716                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 717                         wpcost_update = true;
 718
 719                 skill = autocvar_skill;
 720                 if (wpcost_update)
 721                         waypoint_updatecost_foralllinks();
 722         }
 723
 724         bot_calculate_stepheightvec();
 725         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 726
 727         if(time > autoskill_nextthink)
 728         {
 729                 float a;
 730                 a = autocvar_skill_auto;
 731                 if(a)
 732                         autoskill(a);
 733                 autoskill_nextthink = time + 5;
 734         }
 735
 736         if(time > botframe_nextthink)
 737         {
 738                 if(!bot_fixcount())
 739                         botframe_nextthink = time + 10;
 740         }
 741
 742         if(botframe_spawnedwaypoints)
 743         {
 744                 if(autocvar_waypoint_benchmark)
 745                         localcmd("quit\n");
 746         }
 747
 748         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 749         if (botframe_spawnedwaypoints)
 750         {
 751                 if(botframe_cachedwaypointlinks)
 752                 {
 753                         if(!botframe_loadedforcedlinks)
 754                                 waypoint_load_links_hardwired();
 755                 }
 756                 else
 757                 {
 758                         // TODO: Make this check cleaner
 759                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 760                         {
 761                                 waypoint_save_links();
 762                                 break;
 763                         });
 764                 }
 765         }
 766         else
 767         {
 768                 botframe_spawnedwaypoints = true;
 769                 waypoint_loadall();
 770                 waypoint_load_links();
 771         }
 772
 773         if (bot_list)
 774         {
 775                 // cycle the goal token from one bot to the next each frame
 776                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 777                 //  frame, which causes choppy framerates)
 778                 if (bot_strategytoken_taken)
 779                 {
 780                         // give goal token to the first bot without goals; if all bots don't have
 781                         // any goal (or are dead/frozen) simply give it to the next one
 782                         bot_strategytoken_taken = false;
 783                         entity bot_strategytoken_save = bot_strategytoken;
 784                         while (true)
 785                         {
 786                                 if (bot_strategytoken)
 787                                         bot_strategytoken = bot_strategytoken.nextbot;
 788                                 if (!bot_strategytoken)
 789                                         bot_strategytoken = bot_list;
 790
 791                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 792                                         && !bot_strategytoken.goalcurrent)
 793                                         break;
 794
 795                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 796                                         break;
 797                                 if (bot_strategytoken == bot_strategytoken_save)
 798                                         bot_strategytoken_save = NULL; // looped through all the bots
 799                         }
 800                 }
 801
 802                 if (botframe_nextdangertime < time)
 803                 {
 804                         float interval;
 805                         interval = autocvar_bot_ai_dangerdetectioninterval;
 806                         if (botframe_nextdangertime < time - interval * 1.5)
 807                                 botframe_nextdangertime = time;
 808                         botframe_nextdangertime = botframe_nextdangertime + interval;
 809                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 810                 }
 811         }
 812
 813         if (autocvar_g_waypointeditor)
 814                 botframe_showwaypointlinks();
 815
 816         if (autocvar_g_waypointeditor_auto)
 817                 botframe_autowaypoints();
 818
 819         if(time > bot_cvar_nextthink)
 820         {
 821                 if(currentbots>0)
 822                         bot_custom_weapon_priority_setup();
 823                 bot_cvar_nextthink = time + 5;
 824         }
 825 }