cb83896c22317169767e72ca953da029a0852e47
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / bot.qc
1 #include "bot.qh"
2
3 #include "cvars.qh"
4
5 #include "aim.qh"
6 #include "navigation.qh"
7 #include "scripting.qh"
8 #include "waypoints.qh"
9
10 #include "havocbot/havocbot.qh"
11 #include "havocbot/scripting.qh"
12
13 #include "../../teamplay.qh"
14
15 #include "../../antilag.qh"
16 #include "../../autocvars.qh"
17 #include "../../campaign.qh"
18 #include "../../client.qh"
19 #include "../../constants.qh"
20 #include "../../defs.qh"
21 #include "../../race.qh"
22 #include <common/t_items.qh>
23
24 #include <server/mutators/_mod.qh>
25
26 #include "../../weapons/accuracy.qh"
27
28 #include <common/physics/player.qh>
29 #include <common/constants.qh>
30 #include <common/net_linked.qh>
31 #include <common/mapinfo.qh>
32 #include <common/teams.qh>
33 #include <common/util.qh>
34
35 #include <server/scores_rules.qh>
36
37 #include <common/weapons/_all.qh>
38
39 #include <lib/csqcmodel/sv_model.qh>
40
41 #include <lib/warpzone/common.qh>
42 #include <lib/warpzone/util_server.qh>
43
44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
45
46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
47 void bot_setclientfields(entity this)
48 {
49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
51 }
52
53 entity bot_spawn()
54 {
55         entity bot = spawnclient();
56         if (bot)
57         {
58                 setItemGroupCount();
59                 currentbots = currentbots + 1;
60                 bot_setnameandstuff(bot);
61                 ClientConnect(bot);
62                 bot_setclientfields(bot);
63                 PutClientInServer(bot);
64         }
65         return bot;
66 }
67
68 void bot_think(entity this)
69 {
70         if (this.bot_nextthink > time)
71                 return;
72
73         this.flags &= ~FL_GODMODE;
74         if(autocvar_bot_god)
75                 this.flags |= FL_GODMODE;
76
77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
78
79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
80         {
81                 CS(this).movement = '0 0 0';
82                 this.bot_nextthink = time + 0.5;
83                 return;
84         }
85
86         if (this.fixangle)
87         {
88                 this.v_angle = this.angles;
89                 this.v_angle_z = 0;
90                 this.fixangle = false;
91         }
92
93         this.dmg_take = 0;
94         this.dmg_save = 0;
95         this.dmg_inflictor = NULL;
96
97         // calculate an aiming latency based on the skill setting
98         // (simulated network latency + naturally delayed reflexes)
99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
100         // minimum ping 20+10 random
101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
102         // skill 10 = ping 0.2 (adrenaline)
103         // skill 0 = ping 0.7 (slightly drunk)
104
105         // clear buttons
106         PHYS_INPUT_BUTTON_ATCK(this) = false;
107         PHYS_INPUT_BUTTON_JUMP(this) = false;
108         PHYS_INPUT_BUTTON_ATCK2(this) = false;
109         PHYS_INPUT_BUTTON_ZOOM(this) = false;
110         PHYS_INPUT_BUTTON_CROUCH(this) = false;
111         PHYS_INPUT_BUTTON_HOOK(this) = false;
112         PHYS_INPUT_BUTTON_INFO(this) = false;
113         PHYS_INPUT_BUTTON_DRAG(this) = false;
114         PHYS_INPUT_BUTTON_CHAT(this) = false;
115         PHYS_INPUT_BUTTON_USE(this) = false;
116
117         if (time < game_starttime)
118         {
119                 // block the bot during the countdown to game start
120                 CS(this).movement = '0 0 0';
121                 this.bot_nextthink = game_starttime;
122                 return;
123         }
124
125         // if dead, just wait until we can respawn
126         if (IS_DEAD(this))
127         {
128                 if (bot_waypoint_queue_owner == this)
129                         bot_waypoint_queue_owner = NULL;
130                 this.aistatus = 0;
131                 CS(this).movement = '0 0 0';
132                 if (this.deadflag == DEAD_DEAD)
133                 {
134                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
135                         navigation_goalrating_timeout_force(this);
136                 }
137         }
138         else if(this.aistatus & AI_STATUS_STUCK)
139                 navigation_unstuck(this);
140
141         // now call the current bot AI (havocbot for example)
142         this.bot_ai(this);
143 }
144
145 void bot_setnameandstuff(entity this)
146 {
147         string readfile, s;
148         float file, tokens, prio;
149
150         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
151         string name, prefix, suffix;
152
153         if(autocvar_g_campaign)
154         {
155                 prefix = "";
156                 suffix = "";
157         }
158         else
159         {
160                 prefix = autocvar_bot_prefix;
161                 suffix = autocvar_bot_suffix;
162         }
163
164         file = fopen(autocvar_bot_config_file, FILE_READ);
165
166         if(file < 0)
167         {
168                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
169                 readfile = "";
170         }
171         else
172         {
173                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
174                 TeamBalance_GetTeamCounts(balance, NULL);
175                 int smallest_team = -1;
176                 int smallest_count = -1;
177                 if (teamplay)
178                 {
179                         for (int i = 1; i <= AvailableTeams(); ++i)
180                         {
181                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
182                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
183                                 // since it keeps a spot for the real player in the desired team
184                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
185                                 if (smallest_count < 0 || count < smallest_count)
186                                 {
187                                         smallest_team = i;
188                                         smallest_count = count;
189                                 }
190                         }
191                 }
192                 TeamBalance_Destroy(balance);
193                 RandomSelection_Init();
194                 while((readfile = fgets(file)))
195                 {
196                         if(substring(readfile, 0, 2) == "//")
197                                 continue;
198                         if(substring(readfile, 0, 1) == "#")
199                                 continue;
200                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
201                         // will create 1 empty token because there's no separator (bug?)
202                         if (readfile == "")
203                                 continue;
204                         tokens = tokenizebyseparator(readfile, "\t");
205                         if(tokens == 0)
206                                 continue;
207                         s = argv(0);
208                         prio = 0;
209                         bool conflict = false;
210                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
211                                 if (s == it.cleanname)
212                                 {
213                                         conflict = true;
214                                         break;
215                                 }
216                         });
217                         if (!conflict)
218                                 prio += 1;
219                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
220                         {
221                                 int forced_team = stof(argv(5));
222                                 if (!Team_IsValidIndex(forced_team))
223                                         forced_team = 0;
224                                 if (!forced_team || forced_team == smallest_team)
225                                         prio += 2;
226                         }
227                         RandomSelection_AddString(readfile, 1, prio);
228                 }
229                 readfile = RandomSelection_chosen_string;
230                 fclose(file);
231         }
232
233         tokens = tokenizebyseparator(readfile, "\t");
234         if(argv(0) != "") bot_name = argv(0);
235         else bot_name = "Bot";
236
237         if(argv(1) != "") bot_model = argv(1);
238         else bot_model = "";
239
240         if(argv(2) != "") bot_skin = argv(2);
241         else bot_skin = "0";
242
243         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
244         else bot_shirt = ftos(floor(random() * 15));
245
246         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
247         else bot_pants = ftos(floor(random() * 15));
248
249         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
250                 this.bot_forced_team = stof(argv(5));
251         else
252                 this.bot_forced_team = 0;
253
254         prio = 6;
255
256         #define READSKILL(f, w, r) MACRO_BEGIN \
257                 if(argv(prio) != "") \
258                         this.f = stof(argv(prio)) * w; \
259                 else \
260                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
261                 prio++; \
262         MACRO_END
263         //print(bot_name, ": ping=", argv(9), "\n");
264
265         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
266         READSKILL(bot_moveskill, 2, 0); // move skill
267         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
268
269         READSKILL(bot_pingskill, 0.5, 0); // ping skill
270
271         READSKILL(bot_weaponskill, 2, 0); // weapon skill
272         READSKILL(bot_aggresskill, 1, 0); // aggre skill
273         READSKILL(bot_rangepreference, 1, 0); // read skill
274
275         READSKILL(bot_aimskill, 2, 0); // aim skill
276         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
277         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
278
279         READSKILL(bot_thinkskill, 1, 0.5); // think skill
280         READSKILL(bot_aiskill, 2, 0); // "ai" skill
281
282         if (file >= 0 && argv(prio) != "")
283                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
284
285         this.bot_config_loaded = true;
286
287         // this is really only a default, TeamBalance_JoinBestTeam is called later
288         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
289         this.bot_preferredcolors = this.clientcolors;
290
291         // pick the name
292         if (autocvar_bot_usemodelnames)
293                 name = bot_model;
294         else
295                 name = bot_name;
296
297         // number bots with identical names
298         if (name == "")
299         {
300                 name = ftos(etof(this));
301                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
302         }
303         else
304         {
305                 int j = 0;
306                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
307                         if(it.cleanname == name)
308                                 ++j;
309                 });
310                 if (j)
311                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
312                 else
313                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
314         }
315         this.cleanname = strzone(name);
316
317         // pick the model and skin
318         if(substring(bot_model, -4, 1) != ".")
319                 bot_model = strcat(bot_model, ".iqm");
320         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
321         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
322 }
323
324 void bot_custom_weapon_priority_setup()
325 {
326         float tokens, i, w;
327
328         bot_custom_weapon = false;
329
330         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
331                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
332                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
333                 autocvar_bot_ai_custom_weapon_priority_distances == ""
334         )
335                 return;
336
337         // Parse distances
338         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
339
340         if (tokens!=2)
341                 return;
342
343         bot_distance_far = stof(argv(0));
344         bot_distance_close = stof(argv(1));
345
346         if(bot_distance_far < bot_distance_close){
347                 bot_distance_far = stof(argv(1));
348                 bot_distance_close = stof(argv(0));
349         }
350
351         // Initialize list of weapons
352         bot_weapons_far[0] = -1;
353         bot_weapons_mid[0] = -1;
354         bot_weapons_close[0] = -1;
355
356         // Parse far distance weapon priorities
357         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
358
359         int c = 0;
360         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
361                 w = stof(argv(i));
362                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
363                         bot_weapons_far[c] = w;
364                         ++c;
365                 }
366         }
367         if(c < Weapons_COUNT)
368                 bot_weapons_far[c] = -1;
369
370         // Parse mid distance weapon priorities
371         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
372
373         c = 0;
374         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
375                 w = stof(argv(i));
376                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
377                         bot_weapons_mid[c] = w;
378                         ++c;
379                 }
380         }
381         if(c < Weapons_COUNT)
382                 bot_weapons_mid[c] = -1;
383
384         // Parse close distance weapon priorities
385         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
386
387         c = 0;
388         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
389                 w = stof(argv(i));
390                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
391                         bot_weapons_close[c] = w;
392                         ++c;
393                 }
394         }
395         if(c < Weapons_COUNT)
396                 bot_weapons_close[c] = -1;
397
398         bot_custom_weapon = true;
399 }
400
401 void bot_endgame()
402 {
403         bot_relinkplayerlist();
404         entity e = bot_list;
405         while (e)
406         {
407                 setcolor(e, e.bot_preferredcolors);
408                 e = e.nextbot;
409         }
410         // if dynamic waypoints are ever implemented, save them here
411 }
412
413 void bot_relinkplayerlist()
414 {
415         player_count = 0;
416         currentbots = 0;
417         bot_list = NULL;
418
419         entity prevbot = NULL;
420         FOREACH_CLIENT(true,
421         {
422                 ++player_count;
423
424                 if(IS_BOT_CLIENT(it))
425                 {
426                         if(prevbot)
427                                 prevbot.nextbot = it;
428                         else
429                                 bot_list = it;
430                         prevbot = it;
431                         ++currentbots;
432                 }
433         });
434         if(prevbot)
435                 prevbot.nextbot = NULL;
436         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
437         bot_strategytoken = bot_list;
438         bot_strategytoken_taken = true;
439 }
440
441 void bot_clientdisconnect(entity this)
442 {
443         if (!IS_BOT_CLIENT(this))
444                 return;
445         bot_clearqueue(this);
446         strfree(this.cleanname);
447         strfree(this.netname_freeme);
448         strfree(this.playermodel_freeme);
449         strfree(this.playerskin_freeme);
450         if(this.bot_cmd_current)
451                 delete(this.bot_cmd_current);
452         if(bot_waypoint_queue_owner == this)
453                 bot_waypoint_queue_owner = NULL;
454 }
455
456 void bot_clientconnect(entity this)
457 {
458         if (!IS_BOT_CLIENT(this)) return;
459         this.bot_preferredcolors = this.clientcolors;
460         this.bot_nextthink = time - random();
461         this.lag_func = bot_lagfunc;
462         this.isbot = true;
463         this.createdtime = this.bot_nextthink;
464
465         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
466         {
467                 bot_setnameandstuff(this);
468                 bot_setclientfields(this);
469         }
470
471         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
472         {
473                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
474         }
475         else
476         {
477                 this.bot_forced_team = 0;
478                 TeamBalance_JoinBestTeam(this);
479         }
480
481         havocbot_setupbot(this);
482 }
483
484 void bot_removefromlargestteam()
485 {
486         entity balance = TeamBalance_CheckAllowedTeams(NULL);
487         TeamBalance_GetTeamCounts(balance, NULL);
488
489         entity best = NULL;
490         float besttime = 0;
491         int bestcount = 0;
492
493         int bcount = 0;
494         FOREACH_CLIENT(it.isbot,
495         {
496                 ++bcount;
497
498                 if(!best)
499                 {
500                         best = it;
501                         besttime = it.createdtime;
502                 }
503
504                 int thiscount = 0;
505
506                 if (Team_IsValidTeam(it.team))
507                 {
508                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
509                                 Team_TeamToIndex(it.team));
510                 }
511
512                 if(thiscount > bestcount)
513                 {
514                         bestcount = thiscount;
515                         besttime = it.createdtime;
516                         best = it;
517                 }
518                 else if(thiscount == bestcount && besttime < it.createdtime)
519                 {
520                         besttime = it.createdtime;
521                         best = it;
522                 }
523         });
524         TeamBalance_Destroy(balance);
525         if(!bcount)
526                 return; // no bots to remove
527         currentbots = currentbots - 1;
528         dropclient(best);
529 }
530
531 void bot_removenewest()
532 {
533         if(teamplay)
534         {
535                 bot_removefromlargestteam();
536                 return;
537         }
538
539         float besttime = 0;
540         entity best = NULL;
541         int bcount = 0;
542
543         FOREACH_CLIENT(it.isbot,
544         {
545                 ++bcount;
546
547                 if(!best)
548                 {
549                         best = it;
550                         besttime = it.createdtime;
551                 }
552
553                 if(besttime < it.createdtime)
554                 {
555                         besttime = it.createdtime;
556                         best = it;
557                 }
558         });
559
560         if(!bcount)
561                 return; // no bots to remove
562
563         currentbots = currentbots - 1;
564         dropclient(best);
565 }
566
567 void autoskill(float factor)
568 {
569         float bestbot;
570         float bestplayer;
571
572         bestbot = -1;
573         bestplayer = -1;
574         FOREACH_CLIENT(IS_PLAYER(it), {
575                 if(IS_REAL_CLIENT(it))
576                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
577                 else
578                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
579         });
580
581         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
582         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
583         if(bestbot < 0 || bestplayer < 0)
584         {
585                 LOG_DEBUG("not doing anything");
586                 // don't return, let it reset all counters below
587         }
588         else if(bestbot <= bestplayer * factor - 2)
589         {
590                 if(autocvar_skill < 17)
591                 {
592                         LOG_DEBUG("2 frags difference, increasing skill");
593                         cvar_set("skill", ftos(autocvar_skill + 1));
594                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
595                 }
596         }
597         else if(bestbot >= bestplayer * factor + 2)
598         {
599                 if(autocvar_skill > 0)
600                 {
601                         LOG_DEBUG("2 frags difference, decreasing skill");
602                         cvar_set("skill", ftos(autocvar_skill - 1));
603                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
604                 }
605         }
606         else
607         {
608                 LOG_DEBUG("not doing anything");
609                 return;
610                 // don't reset counters, wait for them to accumulate
611         }
612
613         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
614 }
615
616 void bot_calculate_stepheightvec()
617 {
618         stepheightvec = autocvar_sv_stepheight * '0 0 1';
619         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
620         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
621         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
622 }
623
624 bool bot_fixcount()
625 {
626         int activerealplayers = 0;
627         int realplayers = 0;
628         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
629                 activerealplayers = M_ARGV(0, int);
630                 realplayers = M_ARGV(1, int);
631         } else {
632                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
633                         if(IS_PLAYER(it))
634                                 ++activerealplayers;
635                         ++realplayers;
636                 });
637         }
638
639         int bots;
640         // But don't remove bots immediately on level change, as the real players
641         // usually haven't rejoined yet
642         bots_would_leave = false;
643         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
644                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
645         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
646         {
647                 int minplayers = max(0, floor(autocvar_minplayers));
648                 if (teamplay)
649                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
650                 int minbots = max(0, floor(autocvar_bot_number));
651
652                 // add bots to reach minplayers if needed
653                 bots = max(minbots, minplayers - activerealplayers);
654                 // cap bots to the max players allowed by the server
655                 int player_limit = GetPlayerLimit();
656                 if(player_limit)
657                         bots = min(bots, max(player_limit - activerealplayers, 0));
658                 bots = min(bots, maxclients - realplayers);
659
660                 if(bots > minbots)
661                         bots_would_leave = true;
662         }
663         else
664         {
665                 // if there are no players, remove bots
666                 bots = 0;
667         }
668
669         // only add one bot per frame to avoid utter chaos
670         if(time > botframe_nextthink)
671         {
672                 if (currentbots < bots)
673                 {
674                         if (bot_spawn() == NULL)
675                         {
676                                 bprint("Can not add bot, server full.\n");
677                                 return false;
678                         }
679                 }
680                 while (currentbots > bots && bots >= 0)
681                         bot_removenewest();
682         }
683
684         return true;
685 }
686
687 void bot_remove_from_bot_list(entity this)
688 {
689         entity e = bot_list;
690         entity prev_bot = NULL;
691         while (e)
692         {
693                 if(e == this)
694                 {
695                         if(!prev_bot)
696                                 bot_list = this.nextbot;
697                         else
698                                 prev_bot.nextbot = this.nextbot;
699                         if(bot_strategytoken == this)
700                         {
701                                 bot_strategytoken = this.nextbot;
702                                 bot_strategytoken_taken = true;
703                         }
704                         this.nextbot = NULL;
705                         break;
706                 }
707                 prev_bot = e;
708                 e = e.nextbot;
709         }
710 }
711
712 void bot_clear(entity this)
713 {
714         bot_remove_from_bot_list(this);
715         if(bot_waypoint_queue_owner == this)
716                 bot_waypoint_queue_owner = NULL;
717         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
718 }
719
720 void bot_serverframe()
721 {
722         if (intermission_running && currentbots > 0)
723         {
724                 // after the end of the match all bots stay unless all human players disconnect
725                 int realplayers = 0;
726                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
727                 if (!realplayers)
728                 {
729                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
730                         currentbots = 0;
731                 }
732                 return;
733         }
734
735         if (game_stopped)
736                 return;
737
738         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
739         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
740         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
741         // either intentionally or automatically (sv_spectate 0)
742         if (time < 2.5)
743         {
744                 currentbots = -1;
745                 return;
746         }
747
748         if (currentbots == -1)
749         {
750                 // count bots already in the server from the previous match
751                 currentbots = 0;
752                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
753         }
754
755         if(autocvar_skill != skill)
756         {
757                 float wpcost_update = false;
758                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
759                         wpcost_update = true;
760                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
761                         wpcost_update = true;
762
763                 skill = autocvar_skill;
764                 if (wpcost_update)
765                         waypoint_updatecost_foralllinks();
766         }
767
768         bot_calculate_stepheightvec();
769         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
770
771         if(time > autoskill_nextthink)
772         {
773                 float a;
774                 a = autocvar_skill_auto;
775                 if(a)
776                         autoskill(a);
777                 autoskill_nextthink = time + 5;
778         }
779
780         if(time > botframe_nextthink)
781         {
782                 if(!bot_fixcount())
783                         botframe_nextthink = time + 10;
784         }
785
786         if(botframe_spawnedwaypoints)
787         {
788                 if(autocvar_waypoint_benchmark)
789                         localcmd("quit\n");
790         }
791
792         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
793         if (botframe_spawnedwaypoints)
794         {
795                 if(botframe_cachedwaypointlinks)
796                 {
797                         if(!botframe_loadedforcedlinks)
798                                 waypoint_load_hardwiredlinks();
799                 }
800                 else
801                 {
802                         // TODO: Make this check cleaner
803                         IL_EACH(g_waypoints, time - it.nextthink > 10,
804                         {
805                                 waypoint_save_links();
806                                 break;
807                         });
808                 }
809         }
810         else
811         {
812                 botframe_spawnedwaypoints = true;
813                 waypoint_loadall();
814                 waypoint_load_links();
815         }
816
817         if (bot_list)
818         {
819                 // cycle the goal token from one bot to the next each frame
820                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
821                 //  frame, which causes choppy framerates)
822                 if (bot_strategytoken_taken)
823                 {
824                         // give goal token to the first bot without goals; if all bots don't have
825                         // any goal (or are dead/frozen) simply give it to the next one
826                         bot_strategytoken_taken = false;
827                         entity bot_strategytoken_save = bot_strategytoken;
828                         while (true)
829                         {
830                                 if (bot_strategytoken)
831                                         bot_strategytoken = bot_strategytoken.nextbot;
832                                 if (!bot_strategytoken)
833                                         bot_strategytoken = bot_list;
834
835                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
836                                         && !bot_strategytoken.goalcurrent)
837                                         break;
838
839                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
840                                         break;
841                                 if (bot_strategytoken == bot_strategytoken_save)
842                                         bot_strategytoken_save = NULL; // looped through all the bots
843                         }
844                 }
845
846                 if (botframe_nextdangertime < time)
847                 {
848                         float interval;
849                         interval = autocvar_bot_ai_dangerdetectioninterval;
850                         if (botframe_nextdangertime < time - interval * 1.5)
851                                 botframe_nextdangertime = time;
852                         botframe_nextdangertime = botframe_nextdangertime + interval;
853                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
854                 }
855         }
856
857         if (autocvar_g_waypointeditor)
858                 botframe_showwaypointlinks();
859
860         if (autocvar_g_waypointeditor_auto)
861                 botframe_autowaypoints();
862
863         if(time > bot_cvar_nextthink)
864         {
865                 if(currentbots>0)
866                         bot_custom_weapon_priority_setup();
867                 bot_cvar_nextthink = time + 5;
868         }
869 }