qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include "../../mutators/_mod.qh"
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 entity bot_spawn()
  45 {
  46         entity bot = spawnclient();
  47         if (bot)
  48         {
  49                 currentbots = currentbots + 1;
  50                 bot_setnameandstuff(bot);
  51                 ClientConnect(bot);
  52                 PutClientInServer(bot);
  53         }
  54         return bot;
  55 }
  56
  57 void bot_think(entity this)
  58 {
  59         if (this.bot_nextthink > time)
  60                 return;
  61
  62         this.flags &= ~FL_GODMODE;
  63         if(autocvar_bot_god)
  64                 this.flags |= FL_GODMODE;
  65
  66         this.bot_nextthink = this.bot_nextthink + autocvar_bot_ai_thinkinterval * pow(0.5, this.bot_aiskill);
  67         //if (this.bot_painintensity > 0)
  68         //      this.bot_painintensity = this.bot_painintensity - (skill + 1) * 40 * frametime;
  69
  70         //this.bot_painintensity = this.bot_painintensity + this.bot_oldhealth - this.health;
  71         //this.bot_painintensity = bound(0, this.bot_painintensity, 100);
  72
  73         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  74         {
  75                 this.movement = '0 0 0';
  76                 this.bot_nextthink = time + 0.5;
  77                 return;
  78         }
  79
  80         if (this.fixangle)
  81         {
  82                 this.v_angle = this.angles;
  83                 this.v_angle_z = 0;
  84                 this.fixangle = false;
  85         }
  86
  87         this.dmg_take = 0;
  88         this.dmg_save = 0;
  89         this.dmg_inflictor = NULL;
  90
  91         // calculate an aiming latency based on the skill setting
  92         // (simulated network latency + naturally delayed reflexes)
  93         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  94         // minimum ping 20+10 random
  95         this.ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  96         // skill 10 = ping 0.2 (adrenaline)
  97         // skill 0 = ping 0.7 (slightly drunk)
  98
  99         // clear buttons
 100         PHYS_INPUT_BUTTON_ATCK(this) = false;
 101         PHYS_INPUT_BUTTON_JUMP(this) = false;
 102         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 103         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 104         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 105         PHYS_INPUT_BUTTON_HOOK(this) = false;
 106         PHYS_INPUT_BUTTON_INFO(this) = false;
 107         PHYS_INPUT_BUTTON_DRAG(this) = false;
 108         PHYS_INPUT_BUTTON_CHAT(this) = false;
 109         PHYS_INPUT_BUTTON_USE(this) = false;
 110
 111         if (time < game_starttime)
 112         {
 113                 // block the bot during the countdown to game start
 114                 this.movement = '0 0 0';
 115                 this.bot_nextthink = game_starttime;
 116                 return;
 117         }
 118
 119         // if dead, just wait until we can respawn
 120         if (IS_DEAD(this))
 121         {
 122                 this.movement = '0 0 0';
 123                 if (this.deadflag == DEAD_DEAD)
 124                 {
 125                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 126                         this.bot_strategytime = 0;
 127                 }
 128         }
 129         else if(this.aistatus & AI_STATUS_STUCK)
 130                 navigation_unstuck(this);
 131
 132         // now call the current bot AI (havocbot for example)
 133         this.bot_ai(this);
 134 }
 135
 136 void bot_setnameandstuff(entity this)
 137 {
 138         string readfile, s;
 139         float file, tokens, prio;
 140
 141         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 142         string name, prefix, suffix;
 143
 144         if(autocvar_g_campaign)
 145         {
 146                 prefix = "";
 147                 suffix = "";
 148         }
 149         else
 150         {
 151                 prefix = autocvar_bot_prefix;
 152                 suffix = autocvar_bot_suffix;
 153         }
 154
 155         file = fopen(autocvar_bot_config_file, FILE_READ);
 156
 157         if(file < 0)
 158         {
 159                 LOG_INFO(strcat("Error: Can not open the bot configuration file '",autocvar_bot_config_file,"'\n"));
 160                 readfile = "";
 161         }
 162         else
 163         {
 164                 RandomSelection_Init();
 165                 while((readfile = fgets(file)))
 166                 {
 167                         if(substring(readfile, 0, 2) == "//")
 168                                 continue;
 169                         if(substring(readfile, 0, 1) == "#")
 170                                 continue;
 171                         tokens = tokenizebyseparator(readfile, "\t");
 172                         if(tokens == 0)
 173                                 continue;
 174                         s = argv(0);
 175                         prio = 1;
 176                         FOREACH_CLIENT(IS_BOT_CLIENT(it), LAMBDA(
 177                                 if(s == it.cleanname)
 178                                 {
 179                                         prio = 0;
 180                                         break;
 181                                 }
 182                         ));
 183                         RandomSelection_AddString(readfile, 1, prio);
 184                 }
 185                 readfile = RandomSelection_chosen_string;
 186                 fclose(file);
 187         }
 188
 189         tokens = tokenizebyseparator(readfile, "\t");
 190         if(argv(0) != "") bot_name = argv(0);
 191         else bot_name = "Bot";
 192
 193         if(argv(1) != "") bot_model = argv(1);
 194         else bot_model = "";
 195
 196         if(argv(2) != "") bot_skin = argv(2);
 197         else bot_skin = "0";
 198
 199         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 200         else bot_shirt = ftos(floor(random() * 15));
 201
 202         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 203         else bot_pants = ftos(floor(random() * 15));
 204
 205         this.bot_forced_team = stof(argv(5));
 206
 207         prio = 6;
 208
 209         #define READSKILL(f,w,r) if(argv(prio) != "") this.f = stof(argv(prio)) * (w); else this.f = (!autocvar_g_campaign) * (2 * random() - 1) * (r) * (w); ++prio
 210         //print(bot_name, ": ping=", argv(9), "\n");
 211
 212         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 213         READSKILL(bot_moveskill, 2, 0); // move skill
 214         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 215
 216         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 217
 218         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 219         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 220         READSKILL(bot_rangepreference, 1, 0); // read skill
 221
 222         READSKILL(bot_aimskill, 2, 0); // aim skill
 223         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 224         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 225
 226         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 227         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 228
 229         this.bot_config_loaded = true;
 230
 231         // this is really only a default, JoinBestTeam is called later
 232         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 233         this.bot_preferredcolors = this.clientcolors;
 234
 235         // pick the name
 236         if (autocvar_bot_usemodelnames)
 237                 name = bot_model;
 238         else
 239                 name = bot_name;
 240
 241         // number bots with identical names
 242         int j = 0;
 243         FOREACH_CLIENT(IS_BOT_CLIENT(it), LAMBDA(
 244                 if(it.cleanname == name)
 245                         ++j;
 246         ));
 247         if (j)
 248                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 249         else
 250                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 251
 252         this.cleanname = strzone(name);
 253
 254         // pick the model and skin
 255         if(substring(bot_model, -4, 1) != ".")
 256                 bot_model = strcat(bot_model, ".iqm");
 257         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 258         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 259
 260         this.cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the NULL
 261         this.cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
 262 }
 263
 264 void bot_custom_weapon_priority_setup()
 265 {
 266         float tokens, i, w;
 267
 268         bot_custom_weapon = false;
 269
 270         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 271                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 272                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 273                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 274         )
 275                 return;
 276
 277         // Parse distances
 278         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 279
 280         if (tokens!=2)
 281                 return;
 282
 283         bot_distance_far = stof(argv(0));
 284         bot_distance_close = stof(argv(1));
 285
 286         if(bot_distance_far < bot_distance_close){
 287                 bot_distance_far = stof(argv(1));
 288                 bot_distance_close = stof(argv(0));
 289         }
 290
 291         // Initialize list of weapons
 292         bot_weapons_far[0] = -1;
 293         bot_weapons_mid[0] = -1;
 294         bot_weapons_close[0] = -1;
 295
 296         // Parse far distance weapon priorities
 297         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 298
 299         int c = 0;
 300         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 301                 w = stof(argv(i));
 302                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 303                         bot_weapons_far[c] = w;
 304                         ++c;
 305                 }
 306         }
 307         if(c < Weapons_COUNT)
 308                 bot_weapons_far[c] = -1;
 309
 310         // Parse mid distance weapon priorities
 311         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 312
 313         c = 0;
 314         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 315                 w = stof(argv(i));
 316                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 317                         bot_weapons_mid[c] = w;
 318                         ++c;
 319                 }
 320         }
 321         if(c < Weapons_COUNT)
 322                 bot_weapons_mid[c] = -1;
 323
 324         // Parse close distance weapon priorities
 325         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 326
 327         c = 0;
 328         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 329                 w = stof(argv(i));
 330                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 331                         bot_weapons_close[c] = w;
 332                         ++c;
 333                 }
 334         }
 335         if(c < Weapons_COUNT)
 336                 bot_weapons_close[c] = -1;
 337
 338         bot_custom_weapon = true;
 339 }
 340
 341 void bot_endgame()
 342 {
 343         bot_relinkplayerlist();
 344         entity e = bot_list;
 345         while (e)
 346         {
 347                 setcolor(e, e.bot_preferredcolors);
 348                 e = e.nextbot;
 349         }
 350         // if dynamic waypoints are ever implemented, save them here
 351 }
 352
 353 void bot_relinkplayerlist()
 354 {
 355         player_count = 0;
 356         currentbots = 0;
 357         bot_list = NULL;
 358
 359         entity prevbot = NULL;
 360         FOREACH_CLIENT(true,
 361         {
 362                 ++player_count;
 363
 364                 if(IS_BOT_CLIENT(it))
 365                 {
 366                         if(prevbot)
 367                                 prevbot.nextbot = it;
 368                         else
 369                         {
 370                                 bot_list = it;
 371                                 bot_list.nextbot = NULL;
 372                         }
 373                         prevbot = it;
 374                         ++currentbots;
 375                 }
 376         });
 377         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 378         bot_strategytoken = bot_list;
 379         bot_strategytoken_taken = true;
 380 }
 381
 382 void bot_clientdisconnect(entity this)
 383 {
 384         if (!IS_BOT_CLIENT(this))
 385                 return;
 386         bot_clearqueue(this);
 387         if(this.cleanname)
 388                 strunzone(this.cleanname);
 389         if(this.netname_freeme)
 390                 strunzone(this.netname_freeme);
 391         if(this.playermodel_freeme)
 392                 strunzone(this.playermodel_freeme);
 393         if(this.playerskin_freeme)
 394                 strunzone(this.playerskin_freeme);
 395         this.cleanname = string_null;
 396         this.netname_freeme = string_null;
 397         this.playermodel_freeme = string_null;
 398         this.playerskin_freeme = string_null;
 399         if(this.bot_cmd_current)
 400                 delete(this.bot_cmd_current);
 401         if(bot_waypoint_queue_owner == this)
 402                 bot_waypoint_queue_owner = NULL;
 403 }
 404
 405 void bot_clientconnect(entity this)
 406 {
 407         if (!IS_BOT_CLIENT(this)) return;
 408         this.bot_preferredcolors = this.clientcolors;
 409         this.bot_nextthink = time - random();
 410         this.lag_func = bot_lagfunc;
 411         this.isbot = true;
 412         this.createdtime = this.bot_nextthink;
 413
 414         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 415                 bot_setnameandstuff(this);
 416
 417         if(this.bot_forced_team==1)
 418                 this.team = NUM_TEAM_1;
 419         else if(this.bot_forced_team==2)
 420                 this.team = NUM_TEAM_2;
 421         else if(this.bot_forced_team==3)
 422                 this.team = NUM_TEAM_3;
 423         else if(this.bot_forced_team==4)
 424                 this.team = NUM_TEAM_4;
 425         else
 426                 JoinBestTeam(this, false, true);
 427
 428         havocbot_setupbot(this);
 429 }
 430
 431 void bot_removefromlargestteam()
 432 {
 433         CheckAllowedTeams(NULL);
 434         GetTeamCounts(NULL);
 435
 436         entity best = NULL;
 437         float besttime = 0;
 438         int bestcount = 0;
 439
 440         int bcount = 0;
 441         FOREACH_CLIENT(it.isbot,
 442         {
 443                 ++bcount;
 444
 445                 if(!best)
 446                 {
 447                         best = it;
 448                         besttime = it.createdtime;
 449                 }
 450
 451                 int thiscount = 0;
 452
 453                 switch(it.team)
 454                 {
 455                         case NUM_TEAM_1: thiscount = c1; break;
 456                         case NUM_TEAM_2: thiscount = c2; break;
 457                         case NUM_TEAM_3: thiscount = c3; break;
 458                         case NUM_TEAM_4: thiscount = c4; break;
 459                 }
 460
 461                 if(thiscount > bestcount)
 462                 {
 463                         bestcount = thiscount;
 464                         besttime = it.createdtime;
 465                         best = it;
 466                 }
 467                 else if(thiscount == bestcount && besttime < it.createdtime)
 468                 {
 469                         besttime = it.createdtime;
 470                         best = it;
 471                 }
 472         });
 473         if(!bcount)
 474                 return; // no bots to remove
 475         currentbots = currentbots - 1;
 476         dropclient(best);
 477 }
 478
 479 void bot_removenewest()
 480 {
 481         if(teamplay)
 482         {
 483                 bot_removefromlargestteam();
 484                 return;
 485         }
 486
 487         float besttime = 0;
 488         entity best = NULL;
 489         int bcount = 0;
 490
 491         FOREACH_CLIENT(it.isbot,
 492         {
 493                 ++bcount;
 494
 495                 if(!best)
 496                 {
 497                         best = it;
 498                         besttime = it.createdtime;
 499                 }
 500
 501                 if(besttime < it.createdtime)
 502                 {
 503                         besttime = it.createdtime;
 504                         best = it;
 505                 }
 506         });
 507
 508         if(!bcount)
 509                 return; // no bots to remove
 510
 511         currentbots = currentbots - 1;
 512         dropclient(best);
 513 }
 514
 515 void autoskill(float factor)
 516 {
 517         float bestbot;
 518         float bestplayer;
 519
 520         bestbot = -1;
 521         bestplayer = -1;
 522         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 523                 if(IS_REAL_CLIENT(it))
 524                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 525                 else
 526                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 527         ));
 528
 529         LOG_TRACE("autoskill: best player got ", ftos(bestplayer), ", ");
 530         LOG_TRACE("best bot got ", ftos(bestbot), "; ");
 531         if(bestbot < 0 || bestplayer < 0)
 532         {
 533                 LOG_TRACE("not doing anything");
 534                 // don't return, let it reset all counters below
 535         }
 536         else if(bestbot <= bestplayer * factor - 2)
 537         {
 538                 if(autocvar_skill < 17)
 539                 {
 540                         LOG_TRACE("2 frags difference, increasing skill");
 541                         cvar_set("skill", ftos(autocvar_skill + 1));
 542                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 543                 }
 544         }
 545         else if(bestbot >= bestplayer * factor + 2)
 546         {
 547                 if(autocvar_skill > 0)
 548                 {
 549                         LOG_TRACE("2 frags difference, decreasing skill");
 550                         cvar_set("skill", ftos(autocvar_skill - 1));
 551                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 552                 }
 553         }
 554         else
 555         {
 556                 LOG_TRACE("not doing anything");
 557                 return;
 558                 // don't reset counters, wait for them to accumulate
 559         }
 560
 561         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(it.totalfrags_lastcheck = it.totalfrags));
 562 }
 563
 564 void bot_calculate_stepheightvec()
 565 {
 566         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 567         jumpstepheightvec = stepheightvec +
 568                 ((autocvar_sv_jumpvelocity * autocvar_sv_jumpvelocity) / (2 * autocvar_sv_gravity)) * '0 0 0.85';
 569                 // 0.75 factor is for safety to make the jumps easy
 570 }
 571
 572 float bot_fixcount()
 573 {
 574         int activerealplayers = 0;
 575         int realplayers = 0;
 576         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 577                 activerealplayers = M_ARGV(0, int);
 578                 realplayers = M_ARGV(1, int);
 579         } else {
 580                 FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 581                         if(IS_PLAYER(it))
 582                                 ++activerealplayers;
 583                         ++realplayers;
 584                 ));
 585         }
 586
 587         int bots;
 588         // add/remove bots if needed to make sure there are at least
 589         // minplayers+bot_number, or remove all bots if no one is playing
 590         // But don't remove bots immediately on level change, as the real players
 591         // usually haven't rejoined yet
 592         bots_would_leave = false;
 593         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 594                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 595         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 596         {
 597                 float realminplayers, minplayers;
 598                 realminplayers = autocvar_minplayers;
 599                 minplayers = max(0, floor(realminplayers));
 600
 601                 float realminbots, minbots;
 602                 realminbots = autocvar_bot_number;
 603                 minbots = max(0, floor(realminbots));
 604
 605                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 606                 if(bots > minbots)
 607                         bots_would_leave = true;
 608         }
 609         else
 610         {
 611                 // if there are no players, remove bots
 612                 bots = 0;
 613         }
 614
 615         // only add one bot per frame to avoid utter chaos
 616         if(time > botframe_nextthink)
 617         {
 618                 //dprint(ftos(bots), " ? ", ftos(currentbots), "\n");
 619                 while (currentbots < bots)
 620                 {
 621                         if (bot_spawn() == NULL)
 622                         {
 623                                 bprint("Can not add bot, server full.\n");
 624                                 return false;
 625                         }
 626                 }
 627                 while (currentbots > bots)
 628                         bot_removenewest();
 629         }
 630
 631         return true;
 632 }
 633
 634 void bot_remove_from_bot_list(entity this)
 635 {
 636         entity e = bot_list;
 637         entity prev_bot = NULL;
 638         while (e)
 639         {
 640                 if(e == this)
 641                 {
 642                         if(!prev_bot)
 643                                 bot_list = this.nextbot;
 644                         else
 645                                 prev_bot.nextbot = this.nextbot;
 646                         if(bot_strategytoken == this)
 647                         {
 648                                 bot_strategytoken = this.nextbot;
 649                                 bot_strategytoken_taken = true;
 650                         }
 651                         this.nextbot = NULL;
 652                         break;
 653                 }
 654                 prev_bot = e;
 655                 e = e.nextbot;
 656         }
 657 }
 658
 659 void bot_clear(entity this)
 660 {
 661         bot_remove_from_bot_list(this);
 662         if(bot_waypoint_queue_owner == this)
 663                 bot_waypoint_queue_owner = NULL;
 664         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 665 }
 666
 667 void bot_serverframe()
 668 {
 669         if (gameover)
 670                 return;
 671
 672         if (time < 2)
 673                 return;
 674
 675         bot_calculate_stepheightvec();
 676         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 677
 678         if(time > autoskill_nextthink)
 679         {
 680                 float a;
 681                 a = autocvar_skill_auto;
 682                 if(a)
 683                         autoskill(a);
 684                 autoskill_nextthink = time + 5;
 685         }
 686
 687         if(time > botframe_nextthink)
 688         {
 689                 if(!bot_fixcount())
 690                         botframe_nextthink = time + 10;
 691         }
 692
 693         bot_ignore_bots = autocvar_bot_ignore_bots;
 694
 695         if(botframe_spawnedwaypoints)
 696         {
 697                 if(autocvar_waypoint_benchmark)
 698                         localcmd("quit\n");
 699         }
 700
 701         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 702         if (botframe_spawnedwaypoints)
 703         {
 704                 if(botframe_cachedwaypointlinks)
 705                 {
 706                         if(!botframe_loadedforcedlinks)
 707                                 waypoint_load_links_hardwired();
 708                 }
 709                 else
 710                 {
 711                         // TODO: Make this check cleaner
 712                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 713                         {
 714                                 waypoint_save_links();
 715                                 break;
 716                         });
 717                 }
 718         }
 719         else
 720         {
 721                 botframe_spawnedwaypoints = true;
 722                 waypoint_loadall();
 723                 if(!waypoint_load_links())
 724                         waypoint_schedulerelinkall();
 725         }
 726
 727         if (bot_list)
 728         {
 729                 // cycle the goal token from one bot to the next each frame
 730                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 731                 //  frame, which causes choppy framerates)
 732                 if (bot_strategytoken_taken)
 733                 {
 734                         bot_strategytoken_taken = false;
 735                         if (bot_strategytoken)
 736                                 bot_strategytoken = bot_strategytoken.nextbot;
 737                         if (!bot_strategytoken)
 738                                 bot_strategytoken = bot_list;
 739                 }
 740
 741                 if (botframe_nextdangertime < time)
 742                 {
 743                         float interval;
 744                         interval = autocvar_bot_ai_dangerdetectioninterval;
 745                         if (botframe_nextdangertime < time - interval * 1.5)
 746                                 botframe_nextdangertime = time;
 747                         botframe_nextdangertime = botframe_nextdangertime + interval;
 748                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 749                 }
 750         }
 751
 752         if (autocvar_g_waypointeditor)
 753                 botframe_showwaypointlinks();
 754
 755         if (autocvar_g_waypointeditor_auto)
 756                 botframe_autowaypoints();
 757
 758         if(time > bot_cvar_nextthink)
 759         {
 760                 if(currentbots>0)
 761                         bot_custom_weapon_priority_setup();
 762                 bot_cvar_nextthink = time + 5;
 763         }
 764 }