Merge branch 'master' into terencehill/bot_waypoints
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / bot.qc
1 #include "bot.qh"
2
3 #include "cvars.qh"
4
5 #include "aim.qh"
6 #include "navigation.qh"
7 #include "scripting.qh"
8 #include "waypoints.qh"
9
10 #include "havocbot/havocbot.qh"
11 #include "havocbot/scripting.qh"
12
13 #include "../../teamplay.qh"
14
15 #include "../../antilag.qh"
16 #include "../../autocvars.qh"
17 #include "../../campaign.qh"
18 #include "../../client.qh"
19 #include "../../constants.qh"
20 #include "../../defs.qh"
21 #include "../../race.qh"
22 #include <common/t_items.qh>
23
24 #include "../../mutators/_mod.qh"
25
26 #include "../../weapons/accuracy.qh"
27
28 #include <common/physics/player.qh>
29 #include <common/constants.qh>
30 #include <common/net_linked.qh>
31 #include <common/mapinfo.qh>
32 #include <common/teams.qh>
33 #include <common/util.qh>
34
35 #include <server/scores_rules.qh>
36
37 #include <common/weapons/_all.qh>
38
39 #include <lib/csqcmodel/sv_model.qh>
40
41 #include <lib/warpzone/common.qh>
42 #include <lib/warpzone/util_server.qh>
43
44 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
45 void bot_setclientfields(entity this)
46 {
47         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
48         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
49 }
50
51 entity bot_spawn()
52 {
53         entity bot = spawnclient();
54         if (bot)
55         {
56                 setItemGroupCount();
57                 currentbots = currentbots + 1;
58                 bot_setnameandstuff(bot);
59                 ClientConnect(bot);
60                 bot_setclientfields(bot);
61                 PutClientInServer(bot);
62         }
63         return bot;
64 }
65
66 void bot_think(entity this)
67 {
68         if (this.bot_nextthink > time)
69                 return;
70
71         this.flags &= ~FL_GODMODE;
72         if(autocvar_bot_god)
73                 this.flags |= FL_GODMODE;
74
75         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
76
77         //if (this.bot_painintensity > 0)
78         //      this.bot_painintensity = this.bot_painintensity - (skill + 1) * 40 * frametime;
79
80         //this.bot_painintensity = this.bot_painintensity + this.bot_oldhealth - this.health;
81         //this.bot_painintensity = bound(0, this.bot_painintensity, 100);
82
83         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
84         {
85                 CS(this).movement = '0 0 0';
86                 this.bot_nextthink = time + 0.5;
87                 return;
88         }
89
90         if (this.fixangle)
91         {
92                 this.v_angle = this.angles;
93                 this.v_angle_z = 0;
94                 this.fixangle = false;
95         }
96
97         this.dmg_take = 0;
98         this.dmg_save = 0;
99         this.dmg_inflictor = NULL;
100
101         // calculate an aiming latency based on the skill setting
102         // (simulated network latency + naturally delayed reflexes)
103         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
104         // minimum ping 20+10 random
105         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
106         // skill 10 = ping 0.2 (adrenaline)
107         // skill 0 = ping 0.7 (slightly drunk)
108
109         // clear buttons
110         PHYS_INPUT_BUTTON_ATCK(this) = false;
111         PHYS_INPUT_BUTTON_JUMP(this) = false;
112         PHYS_INPUT_BUTTON_ATCK2(this) = false;
113         PHYS_INPUT_BUTTON_ZOOM(this) = false;
114         PHYS_INPUT_BUTTON_CROUCH(this) = false;
115         PHYS_INPUT_BUTTON_HOOK(this) = false;
116         PHYS_INPUT_BUTTON_INFO(this) = false;
117         PHYS_INPUT_BUTTON_DRAG(this) = false;
118         PHYS_INPUT_BUTTON_CHAT(this) = false;
119         PHYS_INPUT_BUTTON_USE(this) = false;
120
121         if (time < game_starttime)
122         {
123                 // block the bot during the countdown to game start
124                 CS(this).movement = '0 0 0';
125                 this.bot_nextthink = game_starttime;
126                 return;
127         }
128
129         // if dead, just wait until we can respawn
130         if (IS_DEAD(this))
131         {
132                 CS(this).movement = '0 0 0';
133                 if (this.deadflag == DEAD_DEAD)
134                 {
135                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
136                         this.bot_strategytime = 0;
137                 }
138         }
139         else if(this.aistatus & AI_STATUS_STUCK)
140                 navigation_unstuck(this);
141
142         // now call the current bot AI (havocbot for example)
143         this.bot_ai(this);
144 }
145
146 void bot_setnameandstuff(entity this)
147 {
148         string readfile, s;
149         float file, tokens, prio;
150
151         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
152         string name, prefix, suffix;
153
154         if(autocvar_g_campaign)
155         {
156                 prefix = "";
157                 suffix = "";
158         }
159         else
160         {
161                 prefix = autocvar_bot_prefix;
162                 suffix = autocvar_bot_suffix;
163         }
164
165         file = fopen(autocvar_bot_config_file, FILE_READ);
166
167         if(file < 0)
168         {
169                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
170                 readfile = "";
171         }
172         else
173         {
174                 RandomSelection_Init();
175                 while((readfile = fgets(file)))
176                 {
177                         if(substring(readfile, 0, 2) == "//")
178                                 continue;
179                         if(substring(readfile, 0, 1) == "#")
180                                 continue;
181                         tokens = tokenizebyseparator(readfile, "\t");
182                         if(tokens == 0)
183                                 continue;
184                         s = argv(0);
185                         prio = 1;
186                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
187                                 if(s == it.cleanname)
188                                 {
189                                         prio = 0;
190                                         break;
191                                 }
192                         });
193                         RandomSelection_AddString(readfile, 1, prio);
194                 }
195                 readfile = RandomSelection_chosen_string;
196                 fclose(file);
197         }
198
199         tokens = tokenizebyseparator(readfile, "\t");
200         if(argv(0) != "") bot_name = argv(0);
201         else bot_name = "Bot";
202
203         if(argv(1) != "") bot_model = argv(1);
204         else bot_model = "";
205
206         if(argv(2) != "") bot_skin = argv(2);
207         else bot_skin = "0";
208
209         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
210         else bot_shirt = ftos(floor(random() * 15));
211
212         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
213         else bot_pants = ftos(floor(random() * 15));
214
215         this.bot_forced_team = stof(argv(5));
216
217         prio = 6;
218
219         #define READSKILL(f, w, r) MACRO_BEGIN { \
220                 if(argv(prio) != "") \
221                         this.f = stof(argv(prio)) * w; \
222                 else \
223                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
224                 prio++; \
225         } MACRO_END
226         //print(bot_name, ": ping=", argv(9), "\n");
227
228         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
229         READSKILL(bot_moveskill, 2, 0); // move skill
230         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
231
232         READSKILL(bot_pingskill, 0.5, 0); // ping skill
233
234         READSKILL(bot_weaponskill, 2, 0); // weapon skill
235         READSKILL(bot_aggresskill, 1, 0); // aggre skill
236         READSKILL(bot_rangepreference, 1, 0); // read skill
237
238         READSKILL(bot_aimskill, 2, 0); // aim skill
239         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
240         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
241
242         READSKILL(bot_thinkskill, 1, 0.5); // think skill
243         READSKILL(bot_aiskill, 2, 0); // "ai" skill
244
245         this.bot_config_loaded = true;
246
247         // this is really only a default, JoinBestTeam is called later
248         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
249         this.bot_preferredcolors = this.clientcolors;
250
251         // pick the name
252         if (autocvar_bot_usemodelnames)
253                 name = bot_model;
254         else
255                 name = bot_name;
256
257         // number bots with identical names
258         int j = 0;
259         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
260                 if(it.cleanname == name)
261                         ++j;
262         });
263         if (j)
264                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
265         else
266                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
267
268         this.cleanname = strzone(name);
269
270         // pick the model and skin
271         if(substring(bot_model, -4, 1) != ".")
272                 bot_model = strcat(bot_model, ".iqm");
273         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
274         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
275 }
276
277 void bot_custom_weapon_priority_setup()
278 {
279         float tokens, i, w;
280
281         bot_custom_weapon = false;
282
283         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
284                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
285                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
286                 autocvar_bot_ai_custom_weapon_priority_distances == ""
287         )
288                 return;
289
290         // Parse distances
291         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
292
293         if (tokens!=2)
294                 return;
295
296         bot_distance_far = stof(argv(0));
297         bot_distance_close = stof(argv(1));
298
299         if(bot_distance_far < bot_distance_close){
300                 bot_distance_far = stof(argv(1));
301                 bot_distance_close = stof(argv(0));
302         }
303
304         // Initialize list of weapons
305         bot_weapons_far[0] = -1;
306         bot_weapons_mid[0] = -1;
307         bot_weapons_close[0] = -1;
308
309         // Parse far distance weapon priorities
310         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
311
312         int c = 0;
313         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
314                 w = stof(argv(i));
315                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
316                         bot_weapons_far[c] = w;
317                         ++c;
318                 }
319         }
320         if(c < Weapons_COUNT)
321                 bot_weapons_far[c] = -1;
322
323         // Parse mid distance weapon priorities
324         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
325
326         c = 0;
327         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
328                 w = stof(argv(i));
329                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
330                         bot_weapons_mid[c] = w;
331                         ++c;
332                 }
333         }
334         if(c < Weapons_COUNT)
335                 bot_weapons_mid[c] = -1;
336
337         // Parse close distance weapon priorities
338         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
339
340         c = 0;
341         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
342                 w = stof(argv(i));
343                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
344                         bot_weapons_close[c] = w;
345                         ++c;
346                 }
347         }
348         if(c < Weapons_COUNT)
349                 bot_weapons_close[c] = -1;
350
351         bot_custom_weapon = true;
352 }
353
354 void bot_endgame()
355 {
356         bot_relinkplayerlist();
357         entity e = bot_list;
358         while (e)
359         {
360                 setcolor(e, e.bot_preferredcolors);
361                 e = e.nextbot;
362         }
363         // if dynamic waypoints are ever implemented, save them here
364 }
365
366 void bot_relinkplayerlist()
367 {
368         player_count = 0;
369         currentbots = 0;
370         bot_list = NULL;
371
372         entity prevbot = NULL;
373         FOREACH_CLIENT(true,
374         {
375                 ++player_count;
376
377                 if(IS_BOT_CLIENT(it))
378                 {
379                         if(prevbot)
380                                 prevbot.nextbot = it;
381                         else
382                                 bot_list = it;
383                         prevbot = it;
384                         ++currentbots;
385                 }
386         });
387         if(prevbot)
388                 prevbot.nextbot = NULL;
389         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
390         bot_strategytoken = bot_list;
391         bot_strategytoken_taken = true;
392 }
393
394 void bot_clientdisconnect(entity this)
395 {
396         if (!IS_BOT_CLIENT(this))
397                 return;
398         bot_clearqueue(this);
399         if(this.cleanname)
400                 strunzone(this.cleanname);
401         if(this.netname_freeme)
402                 strunzone(this.netname_freeme);
403         if(this.playermodel_freeme)
404                 strunzone(this.playermodel_freeme);
405         if(this.playerskin_freeme)
406                 strunzone(this.playerskin_freeme);
407         this.cleanname = string_null;
408         this.netname_freeme = string_null;
409         this.playermodel_freeme = string_null;
410         this.playerskin_freeme = string_null;
411         if(this.bot_cmd_current)
412                 delete(this.bot_cmd_current);
413         if(bot_waypoint_queue_owner == this)
414                 bot_waypoint_queue_owner = NULL;
415 }
416
417 void bot_clientconnect(entity this)
418 {
419         if (!IS_BOT_CLIENT(this)) return;
420         this.bot_preferredcolors = this.clientcolors;
421         this.bot_nextthink = time - random();
422         this.lag_func = bot_lagfunc;
423         this.isbot = true;
424         this.createdtime = this.bot_nextthink;
425
426         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
427         {
428                 bot_setnameandstuff(this);
429                 bot_setclientfields(this);
430         }
431
432         if(this.bot_forced_team==1)
433                 this.team = NUM_TEAM_1;
434         else if(this.bot_forced_team==2)
435                 this.team = NUM_TEAM_2;
436         else if(this.bot_forced_team==3)
437                 this.team = NUM_TEAM_3;
438         else if(this.bot_forced_team==4)
439                 this.team = NUM_TEAM_4;
440         else
441                 JoinBestTeam(this, false, true);
442
443         havocbot_setupbot(this);
444 }
445
446 void bot_removefromlargestteam()
447 {
448         CheckAllowedTeams(NULL);
449         GetTeamCounts(NULL);
450
451         entity best = NULL;
452         float besttime = 0;
453         int bestcount = 0;
454
455         int bcount = 0;
456         FOREACH_CLIENT(it.isbot,
457         {
458                 ++bcount;
459
460                 if(!best)
461                 {
462                         best = it;
463                         besttime = it.createdtime;
464                 }
465
466                 int thiscount = 0;
467
468                 switch(it.team)
469                 {
470                         case NUM_TEAM_1: thiscount = c1; break;
471                         case NUM_TEAM_2: thiscount = c2; break;
472                         case NUM_TEAM_3: thiscount = c3; break;
473                         case NUM_TEAM_4: thiscount = c4; break;
474                 }
475
476                 if(thiscount > bestcount)
477                 {
478                         bestcount = thiscount;
479                         besttime = it.createdtime;
480                         best = it;
481                 }
482                 else if(thiscount == bestcount && besttime < it.createdtime)
483                 {
484                         besttime = it.createdtime;
485                         best = it;
486                 }
487         });
488         if(!bcount)
489                 return; // no bots to remove
490         currentbots = currentbots - 1;
491         dropclient(best);
492 }
493
494 void bot_removenewest()
495 {
496         if(teamplay)
497         {
498                 bot_removefromlargestteam();
499                 return;
500         }
501
502         float besttime = 0;
503         entity best = NULL;
504         int bcount = 0;
505
506         FOREACH_CLIENT(it.isbot,
507         {
508                 ++bcount;
509
510                 if(!best)
511                 {
512                         best = it;
513                         besttime = it.createdtime;
514                 }
515
516                 if(besttime < it.createdtime)
517                 {
518                         besttime = it.createdtime;
519                         best = it;
520                 }
521         });
522
523         if(!bcount)
524                 return; // no bots to remove
525
526         currentbots = currentbots - 1;
527         dropclient(best);
528 }
529
530 void autoskill(float factor)
531 {
532         float bestbot;
533         float bestplayer;
534
535         bestbot = -1;
536         bestplayer = -1;
537         FOREACH_CLIENT(IS_PLAYER(it), {
538                 if(IS_REAL_CLIENT(it))
539                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
540                 else
541                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
542         });
543
544         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
545         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
546         if(bestbot < 0 || bestplayer < 0)
547         {
548                 LOG_DEBUG("not doing anything");
549                 // don't return, let it reset all counters below
550         }
551         else if(bestbot <= bestplayer * factor - 2)
552         {
553                 if(autocvar_skill < 17)
554                 {
555                         LOG_DEBUG("2 frags difference, increasing skill");
556                         cvar_set("skill", ftos(autocvar_skill + 1));
557                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
558                 }
559         }
560         else if(bestbot >= bestplayer * factor + 2)
561         {
562                 if(autocvar_skill > 0)
563                 {
564                         LOG_DEBUG("2 frags difference, decreasing skill");
565                         cvar_set("skill", ftos(autocvar_skill - 1));
566                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
567                 }
568         }
569         else
570         {
571                 LOG_DEBUG("not doing anything");
572                 return;
573                 // don't reset counters, wait for them to accumulate
574         }
575
576         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
577 }
578
579 void bot_calculate_stepheightvec()
580 {
581         stepheightvec = autocvar_sv_stepheight * '0 0 1';
582         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
583         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
584 }
585
586 float bot_fixcount()
587 {
588         int activerealplayers = 0;
589         int realplayers = 0;
590         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
591                 activerealplayers = M_ARGV(0, int);
592                 realplayers = M_ARGV(1, int);
593         } else {
594                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
595                         if(IS_PLAYER(it))
596                                 ++activerealplayers;
597                         ++realplayers;
598                 });
599         }
600         if(currentbots == -1)
601         {
602                 currentbots = 0;
603                 // human players joining early may cause weird issues (bots appearing on
604                 // the scoreboard as spectators) when switching map with the gotomap
605                 // command, as it doesn't remove bots of the previous match, and with
606                 // minplayers > 1, so ignore human players in the first bot frame
607                 // TODO maybe find a cleaner solution
608                 activerealplayers = 0;
609         }
610
611         int bots;
612         // add/remove bots if needed to make sure there are at least
613         // minplayers+bot_number, or remove all bots if no one is playing
614         // But don't remove bots immediately on level change, as the real players
615         // usually haven't rejoined yet
616         bots_would_leave = false;
617         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
618                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
619         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
620         {
621                 float realminplayers, minplayers;
622                 realminplayers = autocvar_minplayers;
623                 minplayers = max(0, floor(realminplayers));
624
625                 float realminbots, minbots;
626                 realminbots = autocvar_bot_number;
627                 minbots = max(0, floor(realminbots));
628
629                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
630                 if(bots > minbots)
631                         bots_would_leave = true;
632         }
633         else
634         {
635                 // if there are no players, remove bots
636                 bots = 0;
637         }
638
639         // only add one bot per frame to avoid utter chaos
640         if(time > botframe_nextthink)
641         {
642                 if (currentbots < bots)
643                 {
644                         if (bot_spawn() == NULL)
645                         {
646                                 bprint("Can not add bot, server full.\n");
647                                 return false;
648                         }
649                 }
650                 while (currentbots > bots)
651                         bot_removenewest();
652         }
653
654         return true;
655 }
656
657 void bot_remove_from_bot_list(entity this)
658 {
659         entity e = bot_list;
660         entity prev_bot = NULL;
661         while (e)
662         {
663                 if(e == this)
664                 {
665                         if(!prev_bot)
666                                 bot_list = this.nextbot;
667                         else
668                                 prev_bot.nextbot = this.nextbot;
669                         if(bot_strategytoken == this)
670                         {
671                                 bot_strategytoken = this.nextbot;
672                                 bot_strategytoken_taken = true;
673                         }
674                         this.nextbot = NULL;
675                         break;
676                 }
677                 prev_bot = e;
678                 e = e.nextbot;
679         }
680 }
681
682 void bot_clear(entity this)
683 {
684         bot_remove_from_bot_list(this);
685         if(bot_waypoint_queue_owner == this)
686                 bot_waypoint_queue_owner = NULL;
687         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
688 }
689
690 void bot_serverframe()
691 {
692         if (game_stopped)
693                 return;
694
695         if (time < 2)
696         {
697                 currentbots = -1;
698                 return;
699         }
700
701         if(autocvar_skill != skill)
702         {
703                 float wpcost_update = false;
704                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
705                         wpcost_update = true;
706                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
707                         wpcost_update = true;
708
709                 skill = autocvar_skill;
710                 if (wpcost_update)
711                         waypoint_updatecost_foralllinks();
712         }
713
714         bot_calculate_stepheightvec();
715         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
716
717         if(time > autoskill_nextthink)
718         {
719                 float a;
720                 a = autocvar_skill_auto;
721                 if(a)
722                         autoskill(a);
723                 autoskill_nextthink = time + 5;
724         }
725
726         if(time > botframe_nextthink)
727         {
728                 if(!bot_fixcount())
729                         botframe_nextthink = time + 10;
730         }
731
732         bot_ignore_bots = autocvar_bot_ignore_bots;
733
734         if(botframe_spawnedwaypoints)
735         {
736                 if(autocvar_waypoint_benchmark)
737                         localcmd("quit\n");
738         }
739
740         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
741         if (botframe_spawnedwaypoints)
742         {
743                 if(botframe_cachedwaypointlinks)
744                 {
745                         if(!botframe_loadedforcedlinks)
746                                 waypoint_load_links_hardwired();
747                 }
748                 else
749                 {
750                         // TODO: Make this check cleaner
751                         IL_EACH(g_waypoints, time - it.nextthink > 10,
752                         {
753                                 waypoint_save_links();
754                                 break;
755                         });
756                 }
757         }
758         else
759         {
760                 botframe_spawnedwaypoints = true;
761                 waypoint_loadall();
762                 if(!waypoint_load_links())
763                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
764         }
765
766         if (bot_list)
767         {
768                 // cycle the goal token from one bot to the next each frame
769                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
770                 //  frame, which causes choppy framerates)
771                 if (bot_strategytoken_taken)
772                 {
773                         bot_strategytoken_taken = false;
774                         if (bot_strategytoken)
775                                 bot_strategytoken = bot_strategytoken.nextbot;
776                         if (!bot_strategytoken)
777                                 bot_strategytoken = bot_list;
778                 }
779
780                 if (botframe_nextdangertime < time)
781                 {
782                         float interval;
783                         interval = autocvar_bot_ai_dangerdetectioninterval;
784                         if (botframe_nextdangertime < time - interval * 1.5)
785                                 botframe_nextdangertime = time;
786                         botframe_nextdangertime = botframe_nextdangertime + interval;
787                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
788                 }
789         }
790
791         if (autocvar_g_waypointeditor)
792                 botframe_showwaypointlinks();
793
794         if (autocvar_g_waypointeditor_auto)
795                 botframe_autowaypoints();
796
797         if(time > bot_cvar_nextthink)
798         {
799                 if(currentbots>0)
800                         bot_custom_weapon_priority_setup();
801                 bot_cvar_nextthink = time + 5;
802         }
803 }