qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  45
  46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  47 void bot_setclientfields(entity this)
  48 {
  49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  51 }
  52
  53 entity bot_spawn()
  54 {
  55         entity bot = spawnclient();
  56         if (bot)
  57         {
  58                 setItemGroupCount();
  59                 currentbots = currentbots + 1;
  60                 bot_setnameandstuff(bot);
  61                 ClientConnect(bot);
  62                 bot_setclientfields(bot);
  63                 PutClientInServer(bot);
  64         }
  65         return bot;
  66 }
  67
  68 void bot_think(entity this)
  69 {
  70         if (this.bot_nextthink > time)
  71                 return;
  72
  73         this.flags &= ~FL_GODMODE;
  74         if(autocvar_bot_god)
  75                 this.flags |= FL_GODMODE;
  76
  77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  78
  79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  80         {
  81                 CS(this).movement = '0 0 0';
  82                 this.bot_nextthink = time + 0.5;
  83                 return;
  84         }
  85
  86         if (this.fixangle)
  87         {
  88                 this.v_angle = this.angles;
  89                 this.v_angle_z = 0;
  90                 this.fixangle = false;
  91         }
  92
  93         this.dmg_take = 0;
  94         this.dmg_save = 0;
  95         this.dmg_inflictor = NULL;
  96
  97         // calculate an aiming latency based on the skill setting
  98         // (simulated network latency + naturally delayed reflexes)
  99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 100         // minimum ping 20+10 random
 101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 102         // skill 10 = ping 0.2 (adrenaline)
 103         // skill 0 = ping 0.7 (slightly drunk)
 104
 105         // clear buttons
 106         PHYS_INPUT_BUTTON_ATCK(this) = false;
 107         PHYS_INPUT_BUTTON_JUMP(this) = false;
 108         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 109         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 110         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 111         PHYS_INPUT_BUTTON_HOOK(this) = false;
 112         PHYS_INPUT_BUTTON_INFO(this) = false;
 113         PHYS_INPUT_BUTTON_DRAG(this) = false;
 114         PHYS_INPUT_BUTTON_CHAT(this) = false;
 115         PHYS_INPUT_BUTTON_USE(this) = false;
 116
 117         if (time < game_starttime)
 118         {
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 this.bot_nextthink = game_starttime;
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (this.deadflag == DEAD_DEAD)
 133                 {
 134                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 135                         navigation_goalrating_timeout_force(this);
 136                 }
 137         }
 138         else if(this.aistatus & AI_STATUS_STUCK)
 139                 navigation_unstuck(this);
 140
 141         // now call the current bot AI (havocbot for example)
 142         this.bot_ai(this);
 143 }
 144
 145 void bot_setnameandstuff(entity this)
 146 {
 147         string readfile, s;
 148         float file, tokens, prio;
 149
 150         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 151         string name, prefix, suffix;
 152
 153         if(autocvar_g_campaign)
 154         {
 155                 prefix = "";
 156                 suffix = "";
 157         }
 158         else
 159         {
 160                 prefix = autocvar_bot_prefix;
 161                 suffix = autocvar_bot_suffix;
 162         }
 163
 164         file = fopen(autocvar_bot_config_file, FILE_READ);
 165
 166         if(file < 0)
 167         {
 168                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 169                 readfile = "";
 170         }
 171         else
 172         {
 173                 RandomSelection_Init();
 174                 while((readfile = fgets(file)))
 175                 {
 176                         if(substring(readfile, 0, 2) == "//")
 177                                 continue;
 178                         if(substring(readfile, 0, 1) == "#")
 179                                 continue;
 180                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 181                         // will create 1 empty token because there's no separator (bug?)
 182                         if (readfile == "")
 183                                 continue;
 184                         tokens = tokenizebyseparator(readfile, "\t");
 185                         if(tokens == 0)
 186                                 continue;
 187                         s = argv(0);
 188                         prio = 1;
 189                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 190                                 if(s == it.cleanname)
 191                                 {
 192                                         prio = 0;
 193                                         break;
 194                                 }
 195                         });
 196                         RandomSelection_AddString(readfile, 1, prio);
 197                 }
 198                 readfile = RandomSelection_chosen_string;
 199                 fclose(file);
 200         }
 201
 202         tokens = tokenizebyseparator(readfile, "\t");
 203         if(argv(0) != "") bot_name = argv(0);
 204         else bot_name = "Bot";
 205
 206         if(argv(1) != "") bot_model = argv(1);
 207         else bot_model = "";
 208
 209         if(argv(2) != "") bot_skin = argv(2);
 210         else bot_skin = "0";
 211
 212         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 213         else bot_shirt = ftos(floor(random() * 15));
 214
 215         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 216         else bot_pants = ftos(floor(random() * 15));
 217
 218         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 219                 this.bot_forced_team = 0;
 220         else
 221                 this.bot_forced_team = stof(argv(5));
 222
 223         prio = 6;
 224
 225         #define READSKILL(f, w, r) MACRO_BEGIN \
 226                 if(argv(prio) != "") \
 227                         this.f = stof(argv(prio)) * w; \
 228                 else \
 229                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 230                 prio++; \
 231         MACRO_END
 232         //print(bot_name, ": ping=", argv(9), "\n");
 233
 234         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 235         READSKILL(bot_moveskill, 2, 0); // move skill
 236         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 237
 238         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 239
 240         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 241         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 242         READSKILL(bot_rangepreference, 1, 0); // read skill
 243
 244         READSKILL(bot_aimskill, 2, 0); // aim skill
 245         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 246         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 247
 248         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 249         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 250
 251         if (file >= 0 && argv(prio) != "")
 252                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 253
 254         this.bot_config_loaded = true;
 255
 256         // this is really only a default, TeamBalance_JoinBestTeam is called later
 257         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 258         this.bot_preferredcolors = this.clientcolors;
 259
 260         // pick the name
 261         if (autocvar_bot_usemodelnames)
 262                 name = bot_model;
 263         else
 264                 name = bot_name;
 265
 266         // number bots with identical names
 267         if (name == "")
 268         {
 269                 name = ftos(etof(this));
 270                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 271         }
 272         else
 273         {
 274                 int j = 0;
 275                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 276                         if(it.cleanname == name)
 277                                 ++j;
 278                 });
 279                 if (j)
 280                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 281                 else
 282                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 283         }
 284         this.cleanname = strzone(name);
 285
 286         // pick the model and skin
 287         if(substring(bot_model, -4, 1) != ".")
 288                 bot_model = strcat(bot_model, ".iqm");
 289         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 290         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 291 }
 292
 293 void bot_custom_weapon_priority_setup()
 294 {
 295         float tokens, i, w;
 296
 297         bot_custom_weapon = false;
 298
 299         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 300                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 301                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 302                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 303         )
 304                 return;
 305
 306         // Parse distances
 307         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 308
 309         if (tokens!=2)
 310                 return;
 311
 312         bot_distance_far = stof(argv(0));
 313         bot_distance_close = stof(argv(1));
 314
 315         if(bot_distance_far < bot_distance_close){
 316                 bot_distance_far = stof(argv(1));
 317                 bot_distance_close = stof(argv(0));
 318         }
 319
 320         // Initialize list of weapons
 321         bot_weapons_far[0] = -1;
 322         bot_weapons_mid[0] = -1;
 323         bot_weapons_close[0] = -1;
 324
 325         // Parse far distance weapon priorities
 326         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 327
 328         int c = 0;
 329         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 330                 w = stof(argv(i));
 331                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 332                         bot_weapons_far[c] = w;
 333                         ++c;
 334                 }
 335         }
 336         if(c < Weapons_COUNT)
 337                 bot_weapons_far[c] = -1;
 338
 339         // Parse mid distance weapon priorities
 340         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 341
 342         c = 0;
 343         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 344                 w = stof(argv(i));
 345                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 346                         bot_weapons_mid[c] = w;
 347                         ++c;
 348                 }
 349         }
 350         if(c < Weapons_COUNT)
 351                 bot_weapons_mid[c] = -1;
 352
 353         // Parse close distance weapon priorities
 354         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 355
 356         c = 0;
 357         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 358                 w = stof(argv(i));
 359                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 360                         bot_weapons_close[c] = w;
 361                         ++c;
 362                 }
 363         }
 364         if(c < Weapons_COUNT)
 365                 bot_weapons_close[c] = -1;
 366
 367         bot_custom_weapon = true;
 368 }
 369
 370 void bot_endgame()
 371 {
 372         bot_relinkplayerlist();
 373         entity e = bot_list;
 374         while (e)
 375         {
 376                 setcolor(e, e.bot_preferredcolors);
 377                 e = e.nextbot;
 378         }
 379         // if dynamic waypoints are ever implemented, save them here
 380 }
 381
 382 void bot_relinkplayerlist()
 383 {
 384         player_count = 0;
 385         currentbots = 0;
 386         bot_list = NULL;
 387
 388         entity prevbot = NULL;
 389         FOREACH_CLIENT(true,
 390         {
 391                 ++player_count;
 392
 393                 if(IS_BOT_CLIENT(it))
 394                 {
 395                         if(prevbot)
 396                                 prevbot.nextbot = it;
 397                         else
 398                                 bot_list = it;
 399                         prevbot = it;
 400                         ++currentbots;
 401                 }
 402         });
 403         if(prevbot)
 404                 prevbot.nextbot = NULL;
 405         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 406         bot_strategytoken = bot_list;
 407         bot_strategytoken_taken = true;
 408 }
 409
 410 void bot_clientdisconnect(entity this)
 411 {
 412         if (!IS_BOT_CLIENT(this))
 413                 return;
 414         bot_clearqueue(this);
 415         strfree(this.cleanname);
 416         strfree(this.netname_freeme);
 417         strfree(this.playermodel_freeme);
 418         strfree(this.playerskin_freeme);
 419         if(this.bot_cmd_current)
 420                 delete(this.bot_cmd_current);
 421         if(bot_waypoint_queue_owner == this)
 422                 bot_waypoint_queue_owner = NULL;
 423 }
 424
 425 void bot_clientconnect(entity this)
 426 {
 427         if (!IS_BOT_CLIENT(this)) return;
 428         this.bot_preferredcolors = this.clientcolors;
 429         this.bot_nextthink = time - random();
 430         this.lag_func = bot_lagfunc;
 431         this.isbot = true;
 432         this.createdtime = this.bot_nextthink;
 433
 434         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 435         {
 436                 bot_setnameandstuff(this);
 437                 bot_setclientfields(this);
 438         }
 439
 440         if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 441         {
 442                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 443         }
 444         else
 445         {
 446                 this.bot_forced_team = 0;
 447                 TeamBalance_JoinBestTeam(this);
 448         }
 449
 450         havocbot_setupbot(this);
 451 }
 452
 453 void bot_removefromlargestteam()
 454 {
 455         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 456         TeamBalance_GetTeamCounts(balance, NULL);
 457
 458         entity best = NULL;
 459         float besttime = 0;
 460         int bestcount = 0;
 461
 462         int bcount = 0;
 463         FOREACH_CLIENT(it.isbot,
 464         {
 465                 ++bcount;
 466
 467                 if(!best)
 468                 {
 469                         best = it;
 470                         besttime = it.createdtime;
 471                 }
 472
 473                 int thiscount = 0;
 474
 475                 if (Team_IsValidTeam(it.team))
 476                 {
 477                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 478                                 Team_TeamToIndex(it.team));
 479                 }
 480
 481                 if(thiscount > bestcount)
 482                 {
 483                         bestcount = thiscount;
 484                         besttime = it.createdtime;
 485                         best = it;
 486                 }
 487                 else if(thiscount == bestcount && besttime < it.createdtime)
 488                 {
 489                         besttime = it.createdtime;
 490                         best = it;
 491                 }
 492         });
 493         TeamBalance_Destroy(balance);
 494         if(!bcount)
 495                 return; // no bots to remove
 496         currentbots = currentbots - 1;
 497         dropclient(best);
 498 }
 499
 500 void bot_removenewest()
 501 {
 502         if(teamplay)
 503         {
 504                 bot_removefromlargestteam();
 505                 return;
 506         }
 507
 508         float besttime = 0;
 509         entity best = NULL;
 510         int bcount = 0;
 511
 512         FOREACH_CLIENT(it.isbot,
 513         {
 514                 ++bcount;
 515
 516                 if(!best)
 517                 {
 518                         best = it;
 519                         besttime = it.createdtime;
 520                 }
 521
 522                 if(besttime < it.createdtime)
 523                 {
 524                         besttime = it.createdtime;
 525                         best = it;
 526                 }
 527         });
 528
 529         if(!bcount)
 530                 return; // no bots to remove
 531
 532         currentbots = currentbots - 1;
 533         dropclient(best);
 534 }
 535
 536 void autoskill(float factor)
 537 {
 538         float bestbot;
 539         float bestplayer;
 540
 541         bestbot = -1;
 542         bestplayer = -1;
 543         FOREACH_CLIENT(IS_PLAYER(it), {
 544                 if(IS_REAL_CLIENT(it))
 545                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 546                 else
 547                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 548         });
 549
 550         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 551         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 552         if(bestbot < 0 || bestplayer < 0)
 553         {
 554                 LOG_DEBUG("not doing anything");
 555                 // don't return, let it reset all counters below
 556         }
 557         else if(bestbot <= bestplayer * factor - 2)
 558         {
 559                 if(autocvar_skill < 17)
 560                 {
 561                         LOG_DEBUG("2 frags difference, increasing skill");
 562                         cvar_set("skill", ftos(autocvar_skill + 1));
 563                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 564                 }
 565         }
 566         else if(bestbot >= bestplayer * factor + 2)
 567         {
 568                 if(autocvar_skill > 0)
 569                 {
 570                         LOG_DEBUG("2 frags difference, decreasing skill");
 571                         cvar_set("skill", ftos(autocvar_skill - 1));
 572                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 573                 }
 574         }
 575         else
 576         {
 577                 LOG_DEBUG("not doing anything");
 578                 return;
 579                 // don't reset counters, wait for them to accumulate
 580         }
 581
 582         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 583 }
 584
 585 void bot_calculate_stepheightvec()
 586 {
 587         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 588         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 589         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 590         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 591 }
 592
 593 bool bot_fixcount()
 594 {
 595         int activerealplayers = 0;
 596         int realplayers = 0;
 597         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 598                 activerealplayers = M_ARGV(0, int);
 599                 realplayers = M_ARGV(1, int);
 600         } else {
 601                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 602                         if(IS_PLAYER(it))
 603                                 ++activerealplayers;
 604                         ++realplayers;
 605                 });
 606         }
 607
 608         int bots;
 609         // But don't remove bots immediately on level change, as the real players
 610         // usually haven't rejoined yet
 611         bots_would_leave = false;
 612         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 613                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 614         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 615         {
 616                 int minplayers = max(0, floor(autocvar_minplayers));
 617                 if (teamplay)
 618                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 619                 int minbots = max(0, floor(autocvar_bot_number));
 620
 621                 // add bots to reach minplayers if needed
 622                 bots = max(minbots, minplayers - activerealplayers);
 623                 // cap bots to the max players allowed by the server
 624                 int player_limit = GetPlayerLimit();
 625                 if(player_limit)
 626                         bots = min(bots, max(player_limit - activerealplayers, 0));
 627                 bots = min(bots, maxclients - realplayers);
 628
 629                 if(bots > minbots)
 630                         bots_would_leave = true;
 631         }
 632         else
 633         {
 634                 // if there are no players, remove bots
 635                 bots = 0;
 636         }
 637
 638         // only add one bot per frame to avoid utter chaos
 639         if(time > botframe_nextthink)
 640         {
 641                 if (currentbots < bots)
 642                 {
 643                         if (bot_spawn() == NULL)
 644                         {
 645                                 bprint("Can not add bot, server full.\n");
 646                                 return false;
 647                         }
 648                 }
 649                 while (currentbots > bots && bots >= 0)
 650                         bot_removenewest();
 651         }
 652
 653         return true;
 654 }
 655
 656 void bot_remove_from_bot_list(entity this)
 657 {
 658         entity e = bot_list;
 659         entity prev_bot = NULL;
 660         while (e)
 661         {
 662                 if(e == this)
 663                 {
 664                         if(!prev_bot)
 665                                 bot_list = this.nextbot;
 666                         else
 667                                 prev_bot.nextbot = this.nextbot;
 668                         if(bot_strategytoken == this)
 669                         {
 670                                 bot_strategytoken = this.nextbot;
 671                                 bot_strategytoken_taken = true;
 672                         }
 673                         this.nextbot = NULL;
 674                         break;
 675                 }
 676                 prev_bot = e;
 677                 e = e.nextbot;
 678         }
 679 }
 680
 681 void bot_clear(entity this)
 682 {
 683         bot_remove_from_bot_list(this);
 684         if(bot_waypoint_queue_owner == this)
 685                 bot_waypoint_queue_owner = NULL;
 686         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 687 }
 688
 689 void bot_serverframe()
 690 {
 691         if (intermission_running && currentbots > 0)
 692         {
 693                 // after the end of the match all bots stay unless all human players disconnect
 694                 int realplayers = 0;
 695                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 696                 if (!realplayers)
 697                 {
 698                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 699                         currentbots = 0;
 700                 }
 701                 return;
 702         }
 703
 704         if (game_stopped)
 705                 return;
 706
 707         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 708         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 709         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 710         // either intentionally or automatically (sv_spectate 0)
 711         if (time < 2.5)
 712         {
 713                 currentbots = -1;
 714                 return;
 715         }
 716
 717         if (currentbots == -1)
 718         {
 719                 // count bots already in the server from the previous match
 720                 currentbots = 0;
 721                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 722         }
 723
 724         if(autocvar_skill != skill)
 725         {
 726                 float wpcost_update = false;
 727                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 728                         wpcost_update = true;
 729                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 730                         wpcost_update = true;
 731
 732                 skill = autocvar_skill;
 733                 if (wpcost_update)
 734                         waypoint_updatecost_foralllinks();
 735         }
 736
 737         bot_calculate_stepheightvec();
 738         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 739
 740         if(time > autoskill_nextthink)
 741         {
 742                 float a;
 743                 a = autocvar_skill_auto;
 744                 if(a)
 745                         autoskill(a);
 746                 autoskill_nextthink = time + 5;
 747         }
 748
 749         if(time > botframe_nextthink)
 750         {
 751                 if(!bot_fixcount())
 752                         botframe_nextthink = time + 10;
 753         }
 754
 755         if(botframe_spawnedwaypoints)
 756         {
 757                 if(autocvar_waypoint_benchmark)
 758                         localcmd("quit\n");
 759         }
 760
 761         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 762         if (botframe_spawnedwaypoints)
 763         {
 764                 if(botframe_cachedwaypointlinks)
 765                 {
 766                         if(!botframe_loadedforcedlinks)
 767                                 waypoint_load_hardwiredlinks();
 768                 }
 769                 else
 770                 {
 771                         // TODO: Make this check cleaner
 772                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 773                         {
 774                                 waypoint_save_links();
 775                                 break;
 776                         });
 777                 }
 778         }
 779         else
 780         {
 781                 botframe_spawnedwaypoints = true;
 782                 waypoint_loadall();
 783                 waypoint_load_links();
 784         }
 785
 786         if (bot_list)
 787         {
 788                 // cycle the goal token from one bot to the next each frame
 789                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 790                 //  frame, which causes choppy framerates)
 791                 if (bot_strategytoken_taken)
 792                 {
 793                         // give goal token to the first bot without goals; if all bots don't have
 794                         // any goal (or are dead/frozen) simply give it to the next one
 795                         bot_strategytoken_taken = false;
 796                         entity bot_strategytoken_save = bot_strategytoken;
 797                         while (true)
 798                         {
 799                                 if (bot_strategytoken)
 800                                         bot_strategytoken = bot_strategytoken.nextbot;
 801                                 if (!bot_strategytoken)
 802                                         bot_strategytoken = bot_list;
 803
 804                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 805                                         && !bot_strategytoken.goalcurrent)
 806                                         break;
 807
 808                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 809                                         break;
 810                                 if (bot_strategytoken == bot_strategytoken_save)
 811                                         bot_strategytoken_save = NULL; // looped through all the bots
 812                         }
 813                 }
 814
 815                 if (botframe_nextdangertime < time)
 816                 {
 817                         float interval;
 818                         interval = autocvar_bot_ai_dangerdetectioninterval;
 819                         if (botframe_nextdangertime < time - interval * 1.5)
 820                                 botframe_nextdangertime = time;
 821                         botframe_nextdangertime = botframe_nextdangertime + interval;
 822                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 823                 }
 824         }
 825
 826         if (autocvar_g_waypointeditor)
 827                 botframe_showwaypointlinks();
 828
 829         if (autocvar_g_waypointeditor_auto)
 830                 botframe_autowaypoints();
 831
 832         if(time > bot_cvar_nextthink)
 833         {
 834                 if(currentbots>0)
 835                         bot_custom_weapon_priority_setup();
 836                 bot_cvar_nextthink = time + 5;
 837         }
 838 }