qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/mapobjects/teleporters.qh>
  22 #include <common/mapobjects/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this && !bot_strategytoken_taken)
  37         {
  38                 if(this.havocbot_blockhead)
  39                 {
  40                         this.havocbot_blockhead = false;
  41                 }
  42                 else
  43                 {
  44                         if (!this.jumppadcount && !STAT(FROZEN, this))
  45                                 this.havocbot_role(this); // little too far down the rabbit hole
  46                 }
  47
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this) || STAT(FROZEN, this))
  87         {
  88                 if (this.goalcurrent)
  89                         navigation_clearroute(this);
  90                 return;
  91         }
  92
  93         havocbot_chooseenemy(this);
  94
  95         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  96         {
  97                 .entity weaponentity = weaponentities[slot];
  98                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  99                 if(this.(weaponentity).bot_chooseweapontime < time)
 100                 {
 101                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 102                         havocbot_chooseweapon(this, weaponentity);
 103                 }
 104         }
 105         havocbot_aim(this);
 106         lag_update(this);
 107         if (this.bot_aimtarg)
 108         {
 109                 this.aistatus |= AI_STATUS_ATTACKING;
 110                 this.aistatus &= ~AI_STATUS_ROAMING;
 111
 112                 if(STAT(WEAPONS, this))
 113                 {
 114                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 115                         {
 116                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 117                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 118                         }
 119                         else
 120                         {
 121                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 122                                 {
 123                                         .entity weaponentity = weaponentities[slot];
 124                                         Weapon w = this.(weaponentity).m_weapon;
 125                                         if(w == WEP_Null && slot != 0)
 126                                                 continue;
 127                                         w.wr_aim(w, this, weaponentity);
 128                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 129                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 130                                 }
 131                         }
 132                 }
 133                 else
 134                 {
 135                         if(IS_PLAYER(this.bot_aimtarg))
 136                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 137                 }
 138         }
 139         else if (this.goalcurrent)
 140         {
 141                 this.aistatus |= AI_STATUS_ROAMING;
 142                 this.aistatus &= ~AI_STATUS_ATTACKING;
 143
 144                 vector now, next;
 145                 float aimdistance,skillblend,distanceblend,blend;
 146
 147                 vector v = get_closer_dest(this.goalcurrent, this.origin);
 148                 if(this.goalcurrent.wpisbox)
 149                 {
 150                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 151                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 152                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 153                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 154                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 155                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 156                                 v = this.goalcurrent.origin;
 157                 }
 158                 next = now = v - (this.origin + this.view_ofs);
 159                 aimdistance = vlen(now);
 160
 161                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 162                 if(
 163                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 164                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 165                 )
 166                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 167
 168                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 169                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 170                 blend = skillblend * (1-distanceblend);
 171                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 172                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 173                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 174                 v = now + blend * (next - now);
 175                 //dprint(etos(this), " ");
 176                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 177                 //v = now * (distanceblend) + next * (1-distanceblend);
 178                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 179                         v.z = 0;
 180                 //dprint("walk at:", vtos(v), "\n");
 181                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 182                 bot_aimdir(this, v, -1);
 183         }
 184         havocbot_movetogoal(this);
 185
 186         // if the bot is not attacking, consider reloading weapons
 187         if (!(this.aistatus & AI_STATUS_ATTACKING))
 188         {
 189                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 190                 {
 191                         .entity weaponentity = weaponentities[slot];
 192
 193                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 194                                 continue;
 195
 196                         // we are currently holding a weapon that's not fully loaded, reload it
 197                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 198                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 199                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 200
 201                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 202                         // the code above executes next frame, starting the reloading then
 203                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 204                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 205                         {
 206                                 FOREACH(Weapons, it != WEP_Null, {
 207                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 208                                         {
 209                                                 this.(weaponentity).m_switchweapon = it;
 210                                                 break;
 211                                         }
 212                                 });
 213                         }
 214                 }
 215         }
 216 }
 217
 218 void havocbot_keyboard_movement(entity this, vector destorg)
 219 {
 220         vector keyboard;
 221
 222         if (time > this.havocbot_keyboardtime)
 223         {
 224                 float sk = skill + this.bot_moveskill;
 225                 this.havocbot_keyboardtime =
 226                         max(
 227                                 this.havocbot_keyboardtime
 228                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 229                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 230                         , time);
 231                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 232
 233                 float trigger = autocvar_bot_ai_keyboard_threshold;
 234                 float trigger1 = -trigger;
 235
 236                 // categorize forward movement
 237                 // at skill < 1.5 only forward
 238                 // at skill < 2.5 only individual directions
 239                 // at skill < 4.5 only individual directions, and forward diagonals
 240                 // at skill >= 4.5, all cases allowed
 241                 if (keyboard.x > trigger)
 242                 {
 243                         keyboard.x = 1;
 244                         if (sk < 2.5)
 245                                 keyboard.y = 0;
 246                 }
 247                 else if (keyboard.x < trigger1 && sk > 1.5)
 248                 {
 249                         keyboard.x = -1;
 250                         if (sk < 4.5)
 251                                 keyboard.y = 0;
 252                 }
 253                 else
 254                 {
 255                         keyboard.x = 0;
 256                         if (sk < 1.5)
 257                                 keyboard.y = 0;
 258                 }
 259                 if (sk < 4.5)
 260                         keyboard.z = 0;
 261
 262                 if (keyboard.y > trigger)
 263                         keyboard.y = 1;
 264                 else if (keyboard.y < trigger1)
 265                         keyboard.y = -1;
 266                 else
 267                         keyboard.y = 0;
 268
 269                 if (keyboard.z > trigger)
 270                         keyboard.z = 1;
 271                 else if (keyboard.z < trigger1)
 272                         keyboard.z = -1;
 273                 else
 274                         keyboard.z = 0;
 275
 276                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 277                 if (this.havocbot_ducktime > time)
 278                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 279         }
 280
 281         keyboard = this.havocbot_keyboard;
 282         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 283         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 284         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 285 }
 286
 287 void havocbot_bunnyhop(entity this, vector dir)
 288 {
 289         float bunnyhopdistance;
 290         vector deviation;
 291         float maxspeed;
 292
 293         // Don't jump when attacking
 294         if(this.aistatus & AI_STATUS_ATTACKING)
 295                 return;
 296
 297         if(IS_PLAYER(this.goalcurrent))
 298                 return;
 299
 300         maxspeed = autocvar_sv_maxspeed;
 301
 302         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 303                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 304         {
 305                 this.aistatus &= ~AI_STATUS_RUNNING;
 306                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 307                 this.bot_canruntogoal = 0;
 308                 this.bot_timelastseengoal = 0;
 309                 return;
 310         }
 311
 312         if(this.waterlevel > WATERLEVEL_WETFEET)
 313         {
 314                 this.aistatus &= ~AI_STATUS_RUNNING;
 315                 return;
 316         }
 317
 318         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 319         {
 320                 this.bot_canruntogoal = 0;
 321                 this.bot_timelastseengoal = 0;
 322         }
 323
 324         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 325         bunnyhopdistance = vlen(this.origin - gco);
 326
 327         // Run only to visible goals
 328         if(IS_ONGROUND(this))
 329         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 330         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 331         {
 332                         this.bot_lastseengoal = this.goalcurrent;
 333
 334                         // seen it before
 335                         if(this.bot_timelastseengoal)
 336                         {
 337                                 // for a period of time
 338                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 339                                 {
 340                                         float checkdistance;
 341                                         checkdistance = true;
 342
 343                                         // don't run if it is too close
 344                                         if(this.bot_canruntogoal==0)
 345                                         {
 346                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 347                                                         this.bot_canruntogoal = 1;
 348                                                 else
 349                                                         this.bot_canruntogoal = -1;
 350                                         }
 351
 352                                         if(this.bot_canruntogoal != 1)
 353                                                 return;
 354
 355                                         if(this.aistatus & AI_STATUS_ROAMING)
 356                                         if(this.goalcurrent.classname=="waypoint")
 357                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 358                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 359                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 360                                         {
 361                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 362                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 363                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 364                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 365
 366                                                 if(fabs(deviation.y) < 20)
 367                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 368                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 369                                                 {
 370                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 371                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 372                                                         {
 373                                                                 checkdistance = false;
 374                                                         }
 375                                                 }
 376                                         }
 377
 378                                         if(checkdistance)
 379                                         {
 380                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 381                                                 // increase stop distance in case the goal is on a slope or a lower platform
 382                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 383                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 384                                         }
 385                                         else
 386                                         {
 387                                                 this.aistatus |= AI_STATUS_RUNNING;
 388                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 389                                         }
 390                                 }
 391                         }
 392                         else
 393                         {
 394                                 this.bot_timelastseengoal = time;
 395                         }
 396         }
 397         else
 398         {
 399                 this.bot_timelastseengoal = 0;
 400         }
 401
 402 #if 0
 403         // Release jump button
 404         if(!cvar("sv_pogostick"))
 405         if((IS_ONGROUND(this)) == 0)
 406         {
 407                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 408                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 409
 410                 // Strafe
 411                 if(this.aistatus & AI_STATUS_RUNNING)
 412                 if(vlen(this.velocity)>maxspeed)
 413                 {
 414                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 415                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 416                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 417
 418                         if(fabs(deviation.y)>10)
 419                                 CS(this).movement_x = 0;
 420
 421                         if(deviation.y>10)
 422                                 CS(this).movement_y = maxspeed * -1;
 423                         else if(deviation.y<10)
 424                                 CS(this).movement_y = maxspeed;
 425
 426                 }
 427         }
 428 #endif
 429 }
 430
 431 // return true when bot isn't getting closer to the current goal
 432 bool havocbot_checkgoaldistance(entity this, vector gco)
 433 {
 434         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 435         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 436         float distance_time = this.goalcurrent_distance_time;
 437         if(distance_time < 0)
 438                 distance_time = -distance_time;
 439         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 440         {
 441                 if(!distance_time)
 442                         this.goalcurrent_distance_time = time;
 443                 else if (time - distance_time > 0.5)
 444                         return true;
 445         }
 446         else
 447         {
 448                 // reduce it a little bit so it works even with very small approaches to the goal
 449                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 450                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 451                 this.goalcurrent_distance_time = 0;
 452         }
 453         return false;
 454 }
 455
 456 entity havocbot_select_an_item_of_group(entity this, int gr)
 457 {
 458         entity selected = NULL;
 459         float selected_dist2 = 0;
 460         // select farthest item of this group from bot's position
 461         IL_EACH(g_items, it.item_group == gr && it.solid,
 462         {
 463                 float dist2 = vlen2(this.origin - it.origin);
 464                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 465                 {
 466                         selected = it;
 467                         selected_dist2 = vlen2(this.origin - selected.origin);
 468                 }
 469         });
 470
 471         if (!selected)
 472                 return NULL;
 473
 474         set_tracewalk_dest(selected, this.origin, false);
 475         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 476                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 477         {
 478                 return NULL;
 479         }
 480
 481         return selected;
 482 }
 483
 484 void havocbot_movetogoal(entity this)
 485 {
 486         vector diff;
 487         vector dir;
 488         vector flatdir;
 489         vector evadeobstacle;
 490         vector evadelava;
 491         float maxspeed;
 492         //float dist;
 493         vector dodge;
 494         //if (this.goalentity)
 495         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 496         CS(this).movement = '0 0 0';
 497         maxspeed = autocvar_sv_maxspeed;
 498
 499         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 500         // Jetpack navigation
 501         if(this.navigation_jetpack_goal)
 502         if(this.goalcurrent==this.navigation_jetpack_goal)
 503         if(GetResourceAmount(this, RESOURCE_FUEL))
 504         {
 505                 if(autocvar_bot_debug_goalstack)
 506                 {
 507                         debuggoalstack(this);
 508                         te_wizspike(this.navigation_jetpack_point);
 509                 }
 510
 511                 // Take off
 512                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 513                 {
 514                         // Brake almost completely so it can get a good direction
 515                         if(vdist(this.velocity, >, 10))
 516                                 return;
 517                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 518                 }
 519
 520                 makevectors(this.v_angle.y * '0 1 0');
 521                 dir = normalize(this.navigation_jetpack_point - this.origin);
 522
 523                 // Landing
 524                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 525                 {
 526                         // Calculate brake distance in xy
 527                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 528                         float v = vlen(vec2(this.velocity));
 529                         float db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 530                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 531                         if(d < db || d < 500)
 532                         {
 533                                 // Brake
 534                                 if(v > maxspeed * 0.3)
 535                                 {
 536                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 537                                         return;
 538                                 }
 539                                 // Switch to normal mode
 540                                 this.navigation_jetpack_goal = NULL;
 541                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 542                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 543                                 return;
 544                         }
 545                 }
 546                 else if(checkpvs(this.origin,this.goalcurrent))
 547                 {
 548                         // If I can see the goal switch to landing code
 549                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 550                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 551                         return;
 552                 }
 553
 554                 // Flying
 555                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 556                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 557                 {
 558                         CS(this).movement_x = dir * v_forward * maxspeed;
 559                         CS(this).movement_y = dir * v_right * maxspeed;
 560                 }
 561                 return;
 562         }
 563
 564         // Handling of jump pads
 565         if(this.jumppadcount)
 566         {
 567                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 568                 {
 569                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 570                         navigation_poptouchedgoals(this);
 571                         return;
 572                 }
 573                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 574                 {
 575                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 576                         // but with some randomness so it can try out different paths
 577                         if(!this.goalcurrent)
 578                         {
 579                                 entity newgoal = NULL;
 580                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 581                                 {
 582                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 583                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 584                                                 continue;
 585
 586                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 587
 588                                         if(trace_fraction < 1)
 589                                                 continue;
 590
 591                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 592                                                 newgoal = it;
 593                                 });
 594
 595                                 if(newgoal)
 596                                 {
 597                                         this.ignoregoal = this.goalcurrent;
 598                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 599                                         navigation_clearroute(this);
 600                                         navigation_routetogoal(this, newgoal, this.origin);
 601                                         if(autocvar_bot_debug_goalstack)
 602                                                 debuggoalstack(this);
 603                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 604                                 }
 605                         }
 606                         else
 607                         {
 608                                 if (this.goalcurrent.bot_pickup)
 609                                 {
 610                                         entity jumppad_wp = this.goalcurrent_prev;
 611                                         navigation_poptouchedgoals(this);
 612                                         if(!this.goalcurrent && jumppad_wp.wp00)
 613                                         {
 614                                                 // head to the jumppad destination once bot reaches the goal item
 615                                                 navigation_pushroute(this, jumppad_wp.wp00);
 616                                         }
 617                                 }
 618                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 619                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 620                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 621                                 else if(havocbot_checkgoaldistance(this, gco))
 622                                 {
 623                                         navigation_clearroute(this);
 624                                         navigation_goalrating_timeout_force(this);
 625                                 }
 626                                 else
 627                                         return;
 628                         }
 629                 }
 630                 else
 631                 {
 632                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 633                         {
 634                                 vector velxy = this.velocity; velxy_z = 0;
 635                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 636                                 {
 637                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 638                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 639                                 }
 640                                 return;
 641                         }
 642
 643                         // Don't chase players while using a jump pad
 644                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 645                                 return;
 646                 }
 647         }
 648         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 649                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 650
 651         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 652         if (skill > 6 && !(IS_ONGROUND(this)))
 653         {
 654                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 655                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 656                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 657
 658                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 659                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 660                 if(this.items & IT_JETPACK)
 661                 {
 662                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 663                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 664                         {
 665                                 if(this.velocity.z<0)
 666                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 667                         }
 668                         else
 669                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 670
 671                         // If there is no goal try to move forward
 672
 673                         if(this.goalcurrent==NULL)
 674                                 dir = v_forward;
 675                         else
 676                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 677
 678                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 679                         float xyspeed = xyvelocity * dir;
 680
 681                         if(xyspeed < (maxspeed / 2))
 682                         {
 683                                 makevectors(this.v_angle.y * '0 1 0');
 684                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 685                                 if(trace_fraction==1)
 686                                 {
 687                                         CS(this).movement_x = dir * v_forward * maxspeed;
 688                                         CS(this).movement_y = dir * v_right * maxspeed;
 689                                         if (skill < 10)
 690                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 691                                 }
 692                         }
 693
 694                         this.havocbot_blockhead = true;
 695
 696                         return;
 697                 }
 698                 else if(GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR) > ROCKETJUMP_DAMAGE())
 699                 {
 700                         if(this.velocity.z < 0)
 701                         {
 702                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 703                                 {
 704                                         .entity weaponentity = weaponentities[slot];
 705
 706                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 707                                                 continue;
 708
 709                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 710                                         {
 711                                                 CS(this).movement_x = maxspeed;
 712
 713                                                 if(this.rocketjumptime)
 714                                                 {
 715                                                         if(time > this.rocketjumptime)
 716                                                         {
 717                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 718                                                                 this.rocketjumptime = 0;
 719                                                         }
 720                                                         return;
 721                                                 }
 722
 723                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 724                                                 this.v_angle_x = 90;
 725                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 726                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 727                                                 return;
 728                                         }
 729                                 }
 730                         }
 731                 }
 732                 else
 733                 {
 734                         // If there is no goal try to move forward
 735                         if(this.goalcurrent==NULL)
 736                                 CS(this).movement_x = maxspeed;
 737                 }
 738         }
 739
 740         // If we are under water with no goals, swim up
 741         if(this.waterlevel && !this.goalcurrent)
 742         {
 743                 dir = '0 0 0';
 744                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 745                         dir.z = 1;
 746                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 747                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 748                 else
 749                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 750                 makevectors(this.v_angle.y * '0 1 0');
 751                 CS(this).movement_x = dir * v_forward * maxspeed;
 752                 CS(this).movement_y = dir * v_right * maxspeed;
 753                 CS(this).movement_z = dir * v_up * maxspeed;
 754         }
 755
 756         // if there is nowhere to go, exit
 757         if (this.goalcurrent == NULL)
 758                 return;
 759
 760
 761         bool locked_goal = false;
 762         if((this.goalentity && wasfreed(this.goalentity))
 763                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 764         {
 765                 navigation_clearroute(this);
 766                 navigation_goalrating_timeout_force(this);
 767                 return;
 768         }
 769         else if(this.goalentity.tag_entity)
 770         {
 771                 navigation_goalrating_timeout_expire(this, 2);
 772         }
 773         else if(this.goalentity.bot_pickup)
 774         {
 775                 if(this.goalentity.bot_pickup_respawning)
 776                 {
 777                         if(this.goalentity.solid) // item respawned
 778                                 this.goalentity.bot_pickup_respawning = false;
 779                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 780                         {
 781                                 if(checkpvs(this.origin, this.goalentity))
 782                                 {
 783                                         this.goalentity.bot_pickup_respawning = false;
 784                                         navigation_goalrating_timeout_expire(this, random());
 785                                 }
 786                                 locked_goal = true; // wait for item to respawn
 787                         }
 788                         else if(this.goalentity == this.goalcurrent)
 789                                 locked_goal = true; // wait for item to respawn
 790                 }
 791                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 792                 {
 793                         if(checkpvs(this.origin, this.goalentity))
 794                         {
 795                                 navigation_goalrating_timeout_expire(this, random());
 796                         }
 797                 }
 798         }
 799         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 800                 locked_goal = true;
 801
 802         navigation_shortenpath(this);
 803
 804         if (IS_MOVABLE(this.goalcurrent))
 805         {
 806                 if (IS_DEAD(this.goalcurrent))
 807                 {
 808                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 809                         {
 810                                 navigation_goalrating_timeout_force(this);
 811                                 return;
 812                         }
 813                 }
 814                 else if (this.bot_tracewalk_time < time)
 815                 {
 816                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 817                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 818                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 819                         {
 820                                 navigation_goalrating_timeout_force(this);
 821                                 return;
 822                         }
 823                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 824                 }
 825         }
 826         if(!locked_goal)
 827         {
 828                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 829                 // in this case path finding can start directly from a waypoint instead of
 830                 // looking for all the reachable waypoints up to a certain distance
 831                 if (navigation_poptouchedgoals(this))
 832                 {
 833                         if (this.goalcurrent)
 834                         {
 835                                 if (IS_MOVABLE(this.goalcurrent) && IS_DEAD(this.goalcurrent))
 836                                 {
 837                                         // remove even if not visible
 838                                         navigation_goalrating_timeout_force(this);
 839                                         return;
 840                                 }
 841                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 842                                         navigation_goalrating_timeout_force(this);
 843                         }
 844                         else
 845                         {
 846                                 entity old_goal = this.goalcurrent_prev;
 847                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 848                                 {
 849                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 850                                         // item of the group by telling the bot to head directly to the farthest item.
 851                                         // Next time we let the bot select a goal as usual which can be another item
 852                                         // of this group (the closest one) and so on
 853                                         this.item_group = old_goal.item_group;
 854                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 855                                         if (new_goal)
 856                                                 navigation_pushroute(this, new_goal);
 857                                 }
 858                         }
 859                 }
 860         }
 861
 862         // if ran out of goals try to use an alternative goal or get a new strategy asap
 863         if(this.goalcurrent == NULL)
 864         {
 865                 navigation_goalrating_timeout_force(this);
 866                 return;
 867         }
 868
 869
 870         if(autocvar_bot_debug_goalstack)
 871                 debuggoalstack(this);
 872
 873         bool bunnyhop_forbidden = false;
 874         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 875
 876         // in case bot ends up inside the teleport waypoint without touching
 877         // the teleport itself, head to the teleport origin
 878         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 879         {
 880                 bunnyhop_forbidden = true;
 881                 destorg = this.goalcurrent.origin;
 882                 if(destorg.z > this.origin.z)
 883                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 884         }
 885
 886         diff = destorg - this.origin;
 887
 888         // 1. stop if too close to target player (even if frozen)
 889         // 2. stop if the locked goal has been reached
 890         if ((IS_PLAYER(this.goalcurrent) && vdist(diff, <, 80))
 891                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 892         {
 893                 destorg = this.origin;
 894                 diff = '0 0 0';
 895         }
 896
 897         dir = normalize(diff);
 898         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 899
 900         //if (this.bot_dodgevector_time < time)
 901         {
 902                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 903                 //this.bot_dodgevector_jumpbutton = 1;
 904                 evadeobstacle = '0 0 0';
 905                 evadelava = '0 0 0';
 906
 907                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 908                 makevectors(this.v_angle.y * '0 1 0');
 909                 if (this.waterlevel)
 910                 {
 911                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 912                         {
 913                                 if(!this.goalcurrent)
 914                                         this.aistatus |= AI_STATUS_OUT_WATER;
 915                                 else if(destorg.z > this.origin.z)
 916                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 917                         }
 918                         else
 919                         {
 920                                 dir = flatdir;
 921                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 922                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 923                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 924                                 else
 925                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 926                         }
 927                 }
 928                 else
 929                 {
 930                         float s;
 931                         vector offset;
 932                         if(this.aistatus & AI_STATUS_OUT_WATER)
 933                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 934
 935                         // jump if going toward an obstacle that doesn't look like stairs we
 936                         // can walk up directly
 937                         vector deviation = '0 0 0';
 938                         if (this.velocity)
 939                         {
 940                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 941                                 while (deviation.y < -180) deviation.y += 360;
 942                                 while (deviation.y > 180) deviation.y -= 360;
 943                         }
 944                         vector flat_diff = vec2(diff);
 945                         offset = max(32, vlen(vec2(this.velocity)) * cos(deviation.y * DEG2RAD) * 0.2) * flatdir;
 946                         vector actual_destorg = this.origin + offset;
 947                         if (!this.goalstack01 || this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 948                         {
 949                                 if (vlen2(flat_diff) < vlen2(offset))
 950                                 {
 951                                         actual_destorg.x = destorg.x;
 952                                         actual_destorg.y = destorg.y;
 953                                 }
 954                         }
 955                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 956                         {
 957                                 actual_destorg.x = destorg.x;
 958                                 actual_destorg.y = destorg.y;
 959                         }
 960                         else if (vlen2(flat_diff) < vlen2(offset))
 961                         {
 962                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 963                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 964                                 float next_dist = vlen(vec2(this.origin + offset - destorg));
 965                                 actual_destorg = vec2(destorg) + next_dist * next_dir;
 966                                 actual_destorg.z = this.origin.z;
 967                         }
 968
 969                         tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
 970                         if (trace_fraction < 1)
 971                         if (trace_plane_normal.z < 0.7)
 972                         {
 973                                 s = trace_fraction;
 974                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
 975                                 if (trace_fraction < s + 0.01)
 976                                 if (trace_plane_normal.z < 0.7)
 977                                 {
 978                                         s = trace_fraction;
 979                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, actual_destorg + jumpstepheightvec, false, this);
 980                                         if (trace_fraction > s)
 981                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 982                                 }
 983                         }
 984
 985                         // if bot for some reason doesn't get close to the current goal find another one
 986                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
 987                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
 988                         if(havocbot_checkgoaldistance(this, destorg))
 989                         {
 990                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
 991                                 {
 992                                         navigation_clearroute(this);
 993                                         navigation_goalrating_timeout_force(this);
 994                                         return;
 995                                 }
 996
 997                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
 998                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
 999                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1000                                 {
1001                                         navigation_clearroute(this);
1002                                         navigation_goalrating_timeout_force(this);
1003                                         return;
1004                                 }
1005
1006                                 // give bot only another chance to prevent bot getting stuck
1007                                 // in case it thinks it can walk but actually can't
1008                                 this.goalcurrent_distance_z = FLOAT_MAX;
1009                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1010                                 this.goalcurrent_distance_time = -time; // mark second try
1011                         }
1012
1013                         // Check for water/slime/lava and dangerous edges
1014                         // (only when the bot is on the ground or jumping intentionally)
1015
1016                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
1017                         vector dst_ahead = this.origin + this.view_ofs + offset;
1018                         vector dst_down = dst_ahead - '0 0 3000';
1019                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1020
1021                         bool unreachable = false;
1022                         s = CONTENT_SOLID;
1023                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1024                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1025                         {
1026                                 // Look downwards
1027                                 traceline(dst_ahead , dst_down, true, NULL);
1028                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1029                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
1030                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1031                                 {
1032                                         s = pointcontents(trace_endpos + '0 0 1');
1033                                         if (s != CONTENT_SOLID)
1034                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1035                                                 evadelava = normalize(this.velocity) * -1;
1036                                         else if (s == CONTENT_SKY)
1037                                                 evadeobstacle = normalize(this.velocity) * -1;
1038                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1039                                         {
1040                                                 // the traceline check isn't enough but is good as optimization,
1041                                                 // when not true (most of the time) this tracebox call is avoided
1042                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1043                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1044                                                 {
1045                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1046                                                         {
1047                                                                 // the goal is probably on an upper platform, assume bot can't get there
1048                                                                 unreachable = true;
1049                                                         }
1050                                                         else
1051                                                                 evadelava = normalize(this.velocity) * -1;
1052                                                 }
1053                                         }
1054                                 }
1055                         }
1056
1057                         dir = flatdir;
1058                         evadeobstacle.z = 0;
1059                         evadelava.z = 0;
1060                         makevectors(this.v_angle.y * '0 1 0');
1061
1062                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1063                         {
1064                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1065                                 if(IS_PLAYER(this.goalcurrent))
1066                                         unreachable = true;
1067                         }
1068                         if(unreachable)
1069                         {
1070                                 navigation_clearroute(this);
1071                                 navigation_goalrating_timeout_force(this);
1072                                 this.ignoregoal = this.goalcurrent;
1073                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1074                         }
1075                 }
1076
1077                 dodge = havocbot_dodge(this);
1078                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
1079                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1080                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
1081                 if(IS_PLAYER(trace_ent))
1082                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
1083
1084                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
1085         //      this.bot_dodgevector = dir;
1086         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1087         }
1088
1089         if(time < this.ladder_time)
1090         {
1091                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1092                 {
1093                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1094                                 dir.z = 1;
1095                 }
1096                 else
1097                 {
1098                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1099                                 dir.z = -1;
1100                 }
1101         }
1102
1103         //dir = this.bot_dodgevector;
1104         //if (this.bot_dodgevector_jumpbutton)
1105         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1106         CS(this).movement_x = dir * v_forward * maxspeed;
1107         CS(this).movement_y = dir * v_right * maxspeed;
1108         CS(this).movement_z = dir * v_up * maxspeed;
1109
1110         // Emulate keyboard interface
1111         if (skill < 10)
1112                 havocbot_keyboard_movement(this, destorg);
1113
1114         // Bunnyhop!
1115         //if(this.aistatus & AI_STATUS_ROAMING)
1116         if(!bunnyhop_forbidden && this.goalcurrent)
1117         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1118                 havocbot_bunnyhop(this, dir);
1119
1120         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1121         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1122         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1123 }
1124
1125 entity havocbot_gettarget(entity this, bool secondary)
1126 {
1127         entity best = NULL;
1128         vector eye = CENTER_OR_VIEWOFS(this);
1129         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1130         {
1131                 vector v = CENTER_OR_VIEWOFS(it);
1132                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1133                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1134                 if(bot_shouldattack(this, it))
1135                 {
1136                         traceline(eye, v, true, this);
1137                         if (trace_ent == it || trace_fraction >= 1)
1138                                 best = it;
1139                 }
1140         });
1141
1142         return best;
1143 }
1144
1145 void havocbot_chooseenemy(entity this)
1146 {
1147         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1148         {
1149                 this.enemy = NULL;
1150                 return;
1151         }
1152         if (this.enemy)
1153         {
1154                 if (!bot_shouldattack(this, this.enemy))
1155                 {
1156                         // enemy died or something, find a new target
1157                         this.enemy = NULL;
1158                         this.havocbot_chooseenemy_finished = time;
1159                 }
1160                 else if (this.havocbot_stickenemy)
1161                 {
1162                         // tracking last chosen enemy
1163                         // if enemy is visible
1164                         // and not really really far away
1165                         // and we're not severely injured
1166                         // then keep tracking for a half second into the future
1167                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1168                         if (trace_ent == this.enemy || trace_fraction == 1)
1169                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1170                         if (GetResourceAmount(this, RESOURCE_HEALTH) > 30)
1171                         {
1172                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1173                                 this.havocbot_chooseenemy_finished = time + 0.5;
1174                                 return;
1175                         }
1176                         // enemy isn't visible, or is far away, or we're injured severely
1177                         // so stop preferring this enemy
1178                         // (it will still take a half second until a new one is chosen)
1179                         this.havocbot_stickenemy = 0;
1180                 }
1181         }
1182         if (time < this.havocbot_chooseenemy_finished)
1183                 return;
1184         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1185         vector eye = this.origin + this.view_ofs;
1186         entity best = NULL;
1187         float bestrating = 100000000;
1188
1189         // Backup hit flags
1190         int hf = this.dphitcontentsmask;
1191
1192         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1193
1194         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1195
1196         bool scan_transparent = false;
1197         bool scan_secondary_targets = false;
1198         bool have_secondary_targets = false;
1199         while(true)
1200         {
1201                 scan_secondary_targets = false;
1202 LABEL(scan_targets)
1203                 IL_EACH(g_bot_targets, it.bot_attack,
1204                 {
1205                         if(!scan_secondary_targets)
1206                         {
1207                                 if(it.classname == "misc_breakablemodel")
1208                                 {
1209                                         have_secondary_targets = true;
1210                                         continue;
1211                                 }
1212                         }
1213                         else if(it.classname != "misc_breakablemodel")
1214                                 continue;
1215
1216                         vector v = (it.absmin + it.absmax) * 0.5;
1217                         float rating = vlen2(v - eye);
1218                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1219                         if (bestrating > rating)
1220                         if (bot_shouldattack(this, it))
1221                         {
1222                                 traceline(eye, v, true, this);
1223                                 if (trace_ent == it || trace_fraction >= 1)
1224                                 {
1225                                         best = it;
1226                                         bestrating = rating;
1227                                 }
1228                         }
1229                 });
1230
1231                 if(!best && have_secondary_targets && !scan_secondary_targets)
1232                 {
1233                         scan_secondary_targets = true;
1234                         // restart the loop
1235                         bestrating = 100000000;
1236                         goto scan_targets;
1237                 }
1238
1239                 // I want to do a second scan if no enemy was found or I don't have weapons
1240                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1241                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1242                         break;
1243                 if(scan_transparent)
1244                         break;
1245
1246                 // Set flags to see through transparent objects
1247                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1248
1249                 scan_transparent = true;
1250         }
1251
1252         // Restore hit flags
1253         this.dphitcontentsmask = hf;
1254
1255         this.enemy = best;
1256         this.havocbot_stickenemy = true;
1257         if(best && best.classname == "misc_breakablemodel")
1258                 this.havocbot_stickenemy = false;
1259 }
1260
1261 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1262 {
1263         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1264         // so skip this for them, or they'll never get to reload their weapons at all.
1265         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1266         if(skill < 5)
1267                 return false;
1268
1269         // if this weapon is scheduled for reloading, don't switch to it during combat
1270         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1271         {
1272                 FOREACH(Weapons, it != WEP_Null, {
1273                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1274                                 return true; // other weapon available
1275                 });
1276         }
1277
1278         return false;
1279 }
1280
1281 void havocbot_chooseweapon(entity this, .entity weaponentity)
1282 {
1283         int i;
1284
1285         // ;)
1286         if(g_weaponarena_weapons == WEPSET(TUBA))
1287         {
1288                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1289                 return;
1290         }
1291
1292         // TODO: clean this up by moving it to weapon code
1293         if(this.enemy==NULL)
1294         {
1295                 // If no weapon was chosen get the first available weapon
1296                 if(this.(weaponentity).m_weapon==WEP_Null)
1297                 FOREACH(Weapons, it != WEP_Null, {
1298                         if(client_hasweapon(this, it, weaponentity, true, false))
1299                         {
1300                                 this.(weaponentity).m_switchweapon = it;
1301                                 return;
1302                         }
1303                 });
1304                 return;
1305         }
1306
1307         // Do not change weapon during the next second after a combo
1308         float f = time - this.lastcombotime;
1309         if(f < 1)
1310                 return;
1311
1312         float w;
1313         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1314
1315         // Should it do a weapon combo?
1316         float af, ct, combo_time, combo;
1317
1318         af = ATTACK_FINISHED(this, 0);
1319         ct = autocvar_bot_ai_weapon_combo_threshold;
1320
1321         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1322         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1323         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1324
1325         combo = false;
1326
1327         if(autocvar_bot_ai_weapon_combo)
1328         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1329         if(af > combo_time)
1330         {
1331                 combo = true;
1332                 this.lastcombotime = time;
1333         }
1334
1335         distance *= (2 ** this.bot_rangepreference);
1336
1337         // Custom weapon list based on distance to the enemy
1338         if(bot_custom_weapon){
1339
1340                 // Choose weapons for far distance
1341                 if ( distance > bot_distance_far ) {
1342                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1343                                 w = bot_weapons_far[i];
1344                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1345                                 {
1346                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1347                                                 continue;
1348                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1349                                         return;
1350                                 }
1351                         }
1352                 }
1353
1354                 // Choose weapons for mid distance
1355                 if ( distance > bot_distance_close) {
1356                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1357                                 w = bot_weapons_mid[i];
1358                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1359                                 {
1360                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1361                                                 continue;
1362                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1363                                         return;
1364                                 }
1365                         }
1366                 }
1367
1368                 // Choose weapons for close distance
1369                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1370                         w = bot_weapons_close[i];
1371                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1372                         {
1373                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1374                                         continue;
1375                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1376                                 return;
1377                         }
1378                 }
1379         }
1380 }
1381
1382 void havocbot_aim(entity this)
1383 {
1384         if (time < this.nextaim)
1385                 return;
1386         this.nextaim = time + 0.1;
1387         vector myvel = this.velocity;
1388         if (!this.waterlevel)
1389                 myvel.z = 0;
1390         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1391         else if (this.enemy)
1392         {
1393                 vector enemyvel = this.enemy.velocity;
1394                 if (!this.enemy.waterlevel)
1395                         enemyvel.z = 0;
1396                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1397         }
1398         else
1399                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1400 }
1401
1402 bool havocbot_moveto_refresh_route(entity this)
1403 {
1404         // Refresh path to goal if necessary
1405         entity wp;
1406         wp = this.havocbot_personal_waypoint;
1407         navigation_goalrating_start(this);
1408         navigation_routerating(this, wp, 10000, 10000);
1409         navigation_goalrating_end(this);
1410         return (this.goalentity != NULL);
1411 }
1412
1413 float havocbot_moveto(entity this, vector pos)
1414 {
1415         entity wp;
1416
1417         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1418         {
1419                 // Step 4: Move to waypoint
1420                 if(this.havocbot_personal_waypoint==NULL)
1421                 {
1422                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1423                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1424                         return CMD_STATUS_ERROR;
1425                 }
1426
1427                 if (!bot_strategytoken_taken)
1428                 if(this.havocbot_personal_waypoint_searchtime<time)
1429                 {
1430                         bot_strategytoken_taken = true;
1431                         if(havocbot_moveto_refresh_route(this))
1432                         {
1433                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1434                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1435                                 this.havocbot_personal_waypoint_failcounter = 0;
1436                         }
1437                         else
1438                         {
1439                                 this.havocbot_personal_waypoint_failcounter += 1;
1440                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1441                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1442                                 {
1443                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1444                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1445                                         delete(this.havocbot_personal_waypoint);
1446                                         return CMD_STATUS_ERROR;
1447                                 }
1448                                 else
1449                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1450                         }
1451                 }
1452
1453                 if(autocvar_bot_debug_goalstack)
1454                         debuggoalstack(this);
1455
1456                 // Heading
1457                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
1458                 dir = dir - (this.origin + this.view_ofs);
1459                 dir.z = 0;
1460                 bot_aimdir(this, dir, -1);
1461
1462                 // Go!
1463                 havocbot_movetogoal(this);
1464
1465                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1466                 {
1467                         // Step 5: Waypoint reached
1468                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1469                         delete(this.havocbot_personal_waypoint);
1470                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1471                         return CMD_STATUS_FINISHED;
1472                 }
1473
1474                 return CMD_STATUS_EXECUTING;
1475         }
1476
1477         // Step 2: Linking waypoint
1478         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1479         {
1480                 // Wait until it is linked
1481                 if(!this.havocbot_personal_waypoint.wplinked)
1482                 {
1483                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1484                         return CMD_STATUS_EXECUTING;
1485                 }
1486
1487                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1488                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1489                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1490
1491                 // Step 3: Route to waypoint
1492                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1493
1494                 return CMD_STATUS_EXECUTING;
1495         }
1496
1497         // Step 1: Spawning waypoint
1498         wp = waypoint_spawnpersonal(this, pos);
1499         if(wp==NULL)
1500         {
1501                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1502                 return CMD_STATUS_ERROR;
1503         }
1504
1505         this.havocbot_personal_waypoint = wp;
1506         this.havocbot_personal_waypoint_failcounter = 0;
1507         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1508
1509         // if pos is inside a teleport, then let's mark it as teleport waypoint
1510         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1511         {
1512                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1513                 this.lastteleporttime = 0;
1514         });
1515
1516 /*
1517         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1518                 print("routing to a teleporter\n");
1519         else
1520                 print("routing to a non-teleporter\n");
1521 */
1522
1523         return CMD_STATUS_EXECUTING;
1524 }
1525
1526 float havocbot_resetgoal(entity this)
1527 {
1528         navigation_clearroute(this);
1529         return CMD_STATUS_FINISHED;
1530 }
1531
1532 void havocbot_setupbot(entity this)
1533 {
1534         this.bot_ai = havocbot_ai;
1535         this.cmd_moveto = havocbot_moveto;
1536         this.cmd_resetgoal = havocbot_resetgoal;
1537
1538         havocbot_chooserole(this);
1539 }
1540
1541 vector havocbot_dodge(entity this)
1542 {
1543         // LordHavoc: disabled because this is too expensive
1544         return '0 0 0';
1545 #if 0
1546         entity head;
1547         vector dodge, v, n;
1548         float danger, bestdanger, vl, d;
1549         dodge = '0 0 0';
1550         bestdanger = -20;
1551         // check for dangerous objects near bot or approaching bot
1552         head = findchainfloat(bot_dodge, true);
1553         while(head)
1554         {
1555                 if (head.owner != this)
1556                 {
1557                         vl = vlen(head.velocity);
1558                         if (vl > autocvar_sv_maxspeed * 0.3)
1559                         {
1560                                 n = normalize(head.velocity);
1561                                 v = this.origin - head.origin;
1562                                 d = v * n;
1563                                 if (d > (0 - head.bot_dodgerating))
1564                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1565                                 {
1566                                         // calculate direction and distance from the flight path, by removing the forward axis
1567                                         v = v - (n * (v * n));
1568                                         danger = head.bot_dodgerating - vlen(v);
1569                                         if (bestdanger < danger)
1570                                         {
1571                                                 bestdanger = danger;
1572                                                 // dodge to the side of the object
1573                                                 dodge = normalize(v);
1574                                         }
1575                                 }
1576                         }
1577                         else
1578                         {
1579                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1580                                 if (bestdanger < danger)
1581                                 {
1582                                         bestdanger = danger;
1583                                         dodge = normalize(this.origin - head.origin);
1584                                 }
1585                         }
1586                 }
1587                 head = head.chain;
1588         }
1589         return dodge;
1590 #endif
1591 }