qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/mapobjects/func/ladder.qh>
  22 #include <common/mapobjects/teleporters.qh>
  23 #include <common/mapobjects/trigger/jumppads.qh>
  24
  25 #include <lib/warpzone/common.qh>
  26
  27 .float speed;
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if(IS_DEAD(this) || STAT(FROZEN, this))
  93         {
  94                 if (this.goalcurrent)
  95                         navigation_clearroute(this);
  96                 return;
  97         }
  98
  99         havocbot_chooseenemy(this);
 100
 101         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 102         {
 103                 .entity weaponentity = weaponentities[slot];
 104                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 105                 if(this.(weaponentity).bot_chooseweapontime < time)
 106                 {
 107                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 108                         havocbot_chooseweapon(this, weaponentity);
 109                 }
 110         }
 111         havocbot_aim(this);
 112         lag_update(this);
 113
 114         if (this.bot_aimtarg)
 115         {
 116                 this.aistatus |= AI_STATUS_ATTACKING;
 117                 this.aistatus &= ~AI_STATUS_ROAMING;
 118
 119                 if(STAT(WEAPONS, this))
 120                 {
 121                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 122                         {
 123                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 124                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 125                         }
 126                         else
 127                         {
 128                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 129                                 {
 130                                         .entity weaponentity = weaponentities[slot];
 131                                         Weapon w = this.(weaponentity).m_weapon;
 132                                         if(w == WEP_Null && slot != 0)
 133                                                 continue;
 134                                         w.wr_aim(w, this, weaponentity);
 135                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 136                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 137                                 }
 138                         }
 139                 }
 140                 else
 141                 {
 142                         if(IS_PLAYER(this.bot_aimtarg))
 143                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 144                 }
 145         }
 146         else if (this.goalcurrent)
 147         {
 148                 this.aistatus |= AI_STATUS_ROAMING;
 149                 this.aistatus &= ~AI_STATUS_ATTACKING;
 150         }
 151
 152         havocbot_movetogoal(this);
 153         if (!this.bot_aimdir_executed && this.goalcurrent)
 154         {
 155                 // Heading
 156                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 157                 dir -= this.origin + this.view_ofs;
 158                 dir.z = 0;
 159                 bot_aimdir(this, dir, 0);
 160         }
 161
 162         // if the bot is not attacking, consider reloading weapons
 163         if (!(this.aistatus & AI_STATUS_ATTACKING))
 164         {
 165                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 166                 {
 167                         .entity weaponentity = weaponentities[slot];
 168
 169                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 170                                 continue;
 171
 172                         // we are currently holding a weapon that's not fully loaded, reload it
 173                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 174                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 175                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 176
 177                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 178                         // the code above executes next frame, starting the reloading then
 179                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 180                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 181                         {
 182                                 FOREACH(Weapons, it != WEP_Null, {
 183                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 184                                         {
 185                                                 this.(weaponentity).m_switchweapon = it;
 186                                                 break;
 187                                         }
 188                                 });
 189                         }
 190                 }
 191         }
 192 }
 193
 194 void havocbot_keyboard_movement(entity this, vector destorg)
 195 {
 196         vector keyboard;
 197
 198         if (time > this.havocbot_keyboardtime)
 199         {
 200                 float sk = skill + this.bot_moveskill;
 201                 this.havocbot_keyboardtime =
 202                         max(
 203                                 this.havocbot_keyboardtime
 204                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 205                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 206                         , time);
 207                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 208
 209                 float trigger = autocvar_bot_ai_keyboard_threshold;
 210
 211                 // categorize forward movement
 212                 // at skill < 1.5 only forward
 213                 // at skill < 2.5 only individual directions
 214                 // at skill < 4.5 only individual directions, and forward diagonals
 215                 // at skill >= 4.5, all cases allowed
 216                 if (keyboard.x > trigger)
 217                 {
 218                         keyboard.x = 1;
 219                         if (sk < 2.5)
 220                                 keyboard.y = 0;
 221                 }
 222                 else if (keyboard.x < -trigger && sk > 1.5)
 223                 {
 224                         keyboard.x = -1;
 225                         if (sk < 4.5)
 226                                 keyboard.y = 0;
 227                 }
 228                 else
 229                 {
 230                         keyboard.x = 0;
 231                         if (sk < 1.5)
 232                                 keyboard.y = 0;
 233                 }
 234                 if (sk < 4.5)
 235                         keyboard.z = 0;
 236
 237                 if (keyboard.y > trigger)
 238                         keyboard.y = 1;
 239                 else if (keyboard.y < -trigger)
 240                         keyboard.y = -1;
 241                 else
 242                         keyboard.y = 0;
 243
 244                 if (keyboard.z > trigger)
 245                         keyboard.z = 1;
 246                 else if (keyboard.z < -trigger)
 247                         keyboard.z = -1;
 248                 else
 249                         keyboard.z = 0;
 250
 251                 // make sure bots don't get stuck if havocbot_keyboardtime is very high
 252                 if (keyboard == '0 0 0')
 253                         this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 254
 255                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 256                 if (this.havocbot_ducktime > time)
 257                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 258
 259                 keyboard = this.havocbot_keyboard;
 260                 float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 261                 //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 262                 CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 263         }
 264 }
 265
 266 void havocbot_bunnyhop(entity this, vector dir)
 267 {
 268         float bunnyhopdistance;
 269         vector deviation;
 270         float maxspeed;
 271
 272         // Don't jump when attacking
 273         if(this.aistatus & AI_STATUS_ATTACKING)
 274                 return;
 275
 276         if(IS_PLAYER(this.goalcurrent))
 277                 return;
 278
 279         maxspeed = autocvar_sv_maxspeed;
 280
 281         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 282                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 283         {
 284                 this.aistatus &= ~AI_STATUS_RUNNING;
 285                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 286                 this.bot_canruntogoal = 0;
 287                 this.bot_timelastseengoal = 0;
 288                 return;
 289         }
 290
 291         if(this.waterlevel > WATERLEVEL_WETFEET || IS_DUCKED(this))
 292         {
 293                 this.aistatus &= ~AI_STATUS_RUNNING;
 294                 return;
 295         }
 296
 297         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 298         {
 299                 this.bot_canruntogoal = 0;
 300                 this.bot_timelastseengoal = 0;
 301         }
 302
 303         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 304         bunnyhopdistance = vlen(this.origin - gco);
 305
 306         // Run only to visible goals
 307         if(IS_ONGROUND(this))
 308         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 309         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 310         {
 311                         this.bot_lastseengoal = this.goalcurrent;
 312
 313                         // seen it before
 314                         if(this.bot_timelastseengoal)
 315                         {
 316                                 // for a period of time
 317                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 318                                 {
 319                                         float checkdistance;
 320                                         checkdistance = true;
 321
 322                                         // don't run if it is too close
 323                                         if(this.bot_canruntogoal==0)
 324                                         {
 325                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 326                                                         this.bot_canruntogoal = 1;
 327                                                 else
 328                                                         this.bot_canruntogoal = -1;
 329                                         }
 330
 331                                         if(this.bot_canruntogoal != 1)
 332                                                 return;
 333
 334                                         if(this.aistatus & AI_STATUS_ROAMING)
 335                                         if(this.goalcurrent.classname=="waypoint")
 336                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 337                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 338                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 339                                         if (!(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP))
 340                                         {
 341                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 342                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 343                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 344                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 345
 346                                                 if(fabs(deviation.y) < 20)
 347                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 348                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 349                                                 {
 350                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 351                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 352                                                         {
 353                                                                 checkdistance = false;
 354                                                         }
 355                                                 }
 356                                         }
 357
 358                                         if(checkdistance)
 359                                         {
 360                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 361                                                 // increase stop distance in case the goal is on a slope or a lower platform
 362                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 363                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 364                                         }
 365                                         else
 366                                         {
 367                                                 this.aistatus |= AI_STATUS_RUNNING;
 368                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 369                                         }
 370                                 }
 371                         }
 372                         else
 373                         {
 374                                 this.bot_timelastseengoal = time;
 375                         }
 376         }
 377         else
 378         {
 379                 this.bot_timelastseengoal = 0;
 380         }
 381
 382 #if 0
 383         // Release jump button
 384         if(!cvar("sv_pogostick"))
 385         if((IS_ONGROUND(this)) == 0)
 386         {
 387                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 388                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 389
 390                 // Strafe
 391                 if(this.aistatus & AI_STATUS_RUNNING)
 392                 if(vlen(this.velocity)>maxspeed)
 393                 {
 394                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 395                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 396                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 397
 398                         if(fabs(deviation.y)>10)
 399                                 CS(this).movement_x = 0;
 400
 401                         if(deviation.y>10)
 402                                 CS(this).movement_y = maxspeed * -1;
 403                         else if(deviation.y<10)
 404                                 CS(this).movement_y = maxspeed;
 405
 406                 }
 407         }
 408 #endif
 409 }
 410
 411 // return true when bot isn't getting closer to the current goal
 412 bool havocbot_checkgoaldistance(entity this, vector gco)
 413 {
 414         if (this.bot_stop_moving_timeout > time)
 415                 return false;
 416         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 417         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 418         float distance_time = this.goalcurrent_distance_time;
 419         if(distance_time < 0)
 420                 distance_time = -distance_time;
 421         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 422         {
 423                 if(!distance_time)
 424                         this.goalcurrent_distance_time = time;
 425                 else if (time - distance_time > 0.5)
 426                         return true;
 427         }
 428         else
 429         {
 430                 // reduce it a little bit so it works even with very small approaches to the goal
 431                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 432                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 433                 this.goalcurrent_distance_time = 0;
 434         }
 435         return false;
 436 }
 437
 438 entity havocbot_select_an_item_of_group(entity this, int gr)
 439 {
 440         entity selected = NULL;
 441         float selected_dist2 = 0;
 442         // select farthest item of this group from bot's position
 443         IL_EACH(g_items, it.item_group == gr && it.solid,
 444         {
 445                 float dist2 = vlen2(this.origin - it.origin);
 446                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 447                 {
 448                         selected = it;
 449                         selected_dist2 = vlen2(this.origin - selected.origin);
 450                 }
 451         });
 452
 453         if (!selected)
 454                 return NULL;
 455
 456         set_tracewalk_dest(selected, this.origin, false);
 457         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 458                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 459         {
 460                 return NULL;
 461         }
 462
 463         return selected;
 464 }
 465
 466 void havocbot_movetogoal(entity this)
 467 {
 468         vector diff;
 469         vector dir;
 470         vector flatdir;
 471         vector evadeobstacle;
 472         vector evadelava;
 473         float dodge_enemy_factor = 1;
 474         float maxspeed;
 475         //float dist;
 476         vector dodge;
 477         //if (this.goalentity)
 478         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 479         CS(this).movement = '0 0 0';
 480         maxspeed = autocvar_sv_maxspeed;
 481
 482         if (this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH)
 483                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 484         else
 485                 PHYS_INPUT_BUTTON_CROUCH(this) = false;
 486
 487         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 488         // Jetpack navigation
 489         if(this.navigation_jetpack_goal)
 490         if(this.goalcurrent==this.navigation_jetpack_goal)
 491         if(GetResource(this, RES_FUEL))
 492         {
 493                 if(autocvar_bot_debug_goalstack)
 494                 {
 495                         debuggoalstack(this);
 496                         te_wizspike(this.navigation_jetpack_point);
 497                 }
 498
 499                 // Take off
 500                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 501                 {
 502                         // Brake almost completely so it can get a good direction
 503                         if(vdist(this.velocity, >, 10))
 504                                 return;
 505                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 506                 }
 507
 508                 makevectors(this.v_angle.y * '0 1 0');
 509                 dir = normalize(this.navigation_jetpack_point - this.origin);
 510
 511                 // Landing
 512                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 513                 {
 514                         // Calculate brake distance in xy
 515                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 516                         float vel2 = vlen2(vec2(this.velocity));
 517                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 518                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 519                         if(d < db || d < 500)
 520                         {
 521                                 // Brake
 522                                 if (vel2 > (maxspeed * 0.3) ** 2)
 523                                 {
 524                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 525                                         return;
 526                                 }
 527                                 // Switch to normal mode
 528                                 this.navigation_jetpack_goal = NULL;
 529                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 530                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 531                                 return;
 532                         }
 533                 }
 534                 else if(checkpvs(this.origin,this.goalcurrent))
 535                 {
 536                         // If I can see the goal switch to landing code
 537                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 538                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 539                         return;
 540                 }
 541
 542                 // Flying
 543                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 544                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 545                 {
 546                         CS(this).movement_x = dir * v_forward * maxspeed;
 547                         CS(this).movement_y = dir * v_right * maxspeed;
 548                 }
 549                 return;
 550         }
 551
 552         // Handling of jump pads
 553         if(this.jumppadcount)
 554         {
 555                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 556                 {
 557                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 558                         if(navigation_poptouchedgoals(this))
 559                                 return;
 560                 }
 561                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 562                 {
 563                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 564                         // but with some randomness so it can try out different paths
 565                         if(!this.goalcurrent)
 566                         {
 567                                 entity newgoal = NULL;
 568                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 569                                 {
 570                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 571                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 572                                                 continue;
 573
 574                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 575
 576                                         if(trace_fraction < 1)
 577                                                 continue;
 578
 579                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 580                                                 newgoal = it;
 581                                 });
 582
 583                                 if(newgoal)
 584                                 {
 585                                         this.ignoregoal = this.goalcurrent;
 586                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 587                                         navigation_clearroute(this);
 588                                         navigation_routetogoal(this, newgoal, this.origin);
 589                                         if(autocvar_bot_debug_goalstack)
 590                                                 debuggoalstack(this);
 591                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 592                                 }
 593                         }
 594                         else //if (this.goalcurrent)
 595                         {
 596                                 if (this.goalcurrent.bot_pickup)
 597                                 {
 598                                         entity jumppad_wp = this.goalcurrent_prev;
 599                                         navigation_poptouchedgoals(this);
 600                                         if(!this.goalcurrent && jumppad_wp.wp00)
 601                                         {
 602                                                 // head to the jumppad destination once bot reaches the goal item
 603                                                 navigation_pushroute(this, jumppad_wp.wp00);
 604                                         }
 605                                 }
 606                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 607                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 608                                 {
 609                                         if (this.velocity.z < 0)
 610                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 611                                 }
 612                                 else if(havocbot_checkgoaldistance(this, gco))
 613                                 {
 614                                         navigation_clearroute(this);
 615                                         navigation_goalrating_timeout_force(this);
 616                                 }
 617                                 else
 618                                         return;
 619                         }
 620                 }
 621                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 622                 {
 623                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 624                         {
 625                                 vector velxy = this.velocity; velxy_z = 0;
 626                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 627                                 {
 628                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 629                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 630                                 }
 631                                 return;
 632                         }
 633
 634                         // Don't chase players while using a jump pad
 635                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 636                                 return;
 637                 }
 638         }
 639         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 640                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 641
 642         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 643         if (skill > 6 && !(IS_ONGROUND(this)))
 644         {
 645                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 646                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 647                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 648
 649                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 650                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 651                 if(this.items & IT_JETPACK)
 652                 {
 653                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 654                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 655                         {
 656                                 if(this.velocity.z<0)
 657                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 658                         }
 659                         else
 660                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 661
 662                         // If there is no goal try to move forward
 663
 664                         if(this.goalcurrent==NULL)
 665                                 dir = v_forward;
 666                         else
 667                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 668
 669                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 670                         float xyspeed = xyvelocity * dir;
 671
 672                         if(xyspeed < (maxspeed / 2))
 673                         {
 674                                 makevectors(this.v_angle.y * '0 1 0');
 675                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 676                                 if(trace_fraction==1)
 677                                 {
 678                                         CS(this).movement_x = dir * v_forward * maxspeed;
 679                                         CS(this).movement_y = dir * v_right * maxspeed;
 680                                         if (skill < 10)
 681                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 682                                 }
 683                         }
 684
 685                         this.havocbot_blockhead = true;
 686
 687                         return;
 688                 }
 689                 else if(!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 690                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 691                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 692                 {
 693                         if(this.velocity.z < 0)
 694                         {
 695                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 696                                 {
 697                                         .entity weaponentity = weaponentities[slot];
 698
 699                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 700                                                 continue;
 701
 702                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 703                                         {
 704                                                 CS(this).movement_x = maxspeed;
 705
 706                                                 if(this.rocketjumptime)
 707                                                 {
 708                                                         if(time > this.rocketjumptime)
 709                                                         {
 710                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 711                                                                 this.rocketjumptime = 0;
 712                                                         }
 713                                                         return;
 714                                                 }
 715
 716                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 717                                                 this.v_angle_x = 90;
 718                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 719                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 720                                                 return;
 721                                         }
 722                                 }
 723                         }
 724                 }
 725                 else
 726                 {
 727                         // If there is no goal try to move forward
 728                         if(this.goalcurrent==NULL)
 729                                 CS(this).movement_x = maxspeed;
 730                 }
 731         }
 732
 733         // If we are under water with no goals, swim up
 734         if(this.waterlevel && !this.goalcurrent)
 735         {
 736                 dir = '0 0 0';
 737                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 738                         dir.z = 1;
 739                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 740                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 741                 else
 742                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 743                 makevectors(this.v_angle.y * '0 1 0');
 744                 vector v = dir * maxspeed;
 745                 CS(this).movement.x = v * v_forward;
 746                 CS(this).movement.y = v * v_right;
 747                 CS(this).movement.z = v * v_up;
 748         }
 749
 750         // if there is nowhere to go, exit
 751         if (this.goalcurrent == NULL)
 752                 return;
 753
 754
 755         bool locked_goal = false;
 756         if((this.goalentity && wasfreed(this.goalentity))
 757                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 758         {
 759                 navigation_clearroute(this);
 760                 navigation_goalrating_timeout_force(this);
 761                 return;
 762         }
 763         else if(this.goalentity.tag_entity)
 764         {
 765                 navigation_goalrating_timeout_expire(this, 2);
 766         }
 767         else if(this.goalentity.bot_pickup)
 768         {
 769                 if(this.goalentity.bot_pickup_respawning)
 770                 {
 771                         if(this.goalentity.solid) // item respawned
 772                                 this.goalentity.bot_pickup_respawning = false;
 773                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 774                         {
 775                                 if(checkpvs(this.origin, this.goalentity))
 776                                 {
 777                                         this.goalentity.bot_pickup_respawning = false;
 778                                         navigation_goalrating_timeout_expire(this, random());
 779                                 }
 780                                 locked_goal = true; // wait for item to respawn
 781                         }
 782                         else if(this.goalentity == this.goalcurrent)
 783                                 locked_goal = true; // wait for item to respawn
 784                 }
 785                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 786                 {
 787                         if(checkpvs(this.origin, this.goalentity))
 788                         {
 789                                 navigation_goalrating_timeout_expire(this, random());
 790                         }
 791                 }
 792         }
 793         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 794                 locked_goal = true;
 795
 796         if (navigation_shortenpath(this))
 797         {
 798                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 799                         && navigation_goalrating_timeout_can_be_anticipated(this))
 800                 {
 801                         navigation_goalrating_timeout_force(this);
 802                 }
 803         }
 804
 805         bool goalcurrent_can_be_removed = false;
 806         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 807         {
 808                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 809                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 810                 {
 811                         goalcurrent_can_be_removed = true;
 812                         // don't remove if not visible
 813                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 814                         {
 815                                 if (IS_DEAD(this.goalcurrent))
 816                                 {
 817                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 818                                         {
 819                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 820                                                 {
 821                                                         navigation_clearroute(this);
 822                                                         navigation_pushroute(this, it);
 823                                                         // loot can't be immediately rated since it isn't on ground yet
 824                                                         // it will be rated after a second when on ground, meanwhile head to it
 825                                                         navigation_goalrating_timeout_expire(this, 1);
 826                                                         return;
 827                                                 }
 828                                         });
 829                                 }
 830                                 if (!Item_IsLoot(this.goalcurrent))
 831                                 {
 832                                         navigation_goalrating_timeout_force(this);
 833                                         return;
 834                                 }
 835                         }
 836                 }
 837                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 838                 {
 839                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 840                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 841                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 842                         {
 843                                 navigation_goalrating_timeout_force(this);
 844                                 return;
 845                         }
 846                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 847                 }
 848         }
 849
 850         if(!locked_goal)
 851         {
 852                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 853                 // in this case path finding can start directly from a waypoint instead of
 854                 // looking for all the reachable waypoints up to a certain distance
 855                 if (navigation_poptouchedgoals(this))
 856                 {
 857                         if (this.goalcurrent)
 858                         {
 859                                 if (goalcurrent_can_be_removed)
 860                                 {
 861                                         // remove even if not visible
 862                                         navigation_goalrating_timeout_force(this);
 863                                         return;
 864                                 }
 865                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 866                                         navigation_goalrating_timeout_force(this);
 867                         }
 868                         else
 869                         {
 870                                 entity old_goal = this.goalcurrent_prev;
 871                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 872                                 {
 873                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 874                                         // item of the group by telling the bot to head directly to the farthest item.
 875                                         // Next time we let the bot select a goal as usual which can be another item
 876                                         // of this group (the closest one) and so on
 877                                         this.item_group = old_goal.item_group;
 878                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 879                                         if (new_goal)
 880                                                 navigation_pushroute(this, new_goal);
 881                                 }
 882                         }
 883                 }
 884         }
 885
 886         // if ran out of goals try to use an alternative goal or get a new strategy asap
 887         if(this.goalcurrent == NULL)
 888         {
 889                 navigation_goalrating_timeout_force(this);
 890                 return;
 891         }
 892
 893
 894         if(autocvar_bot_debug_goalstack)
 895                 debuggoalstack(this);
 896
 897         bool bunnyhop_forbidden = false;
 898         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 899         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 900         {
 901                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 902                 destorg = this.goalcurrent.origin;
 903         }
 904         else if (this.goalcurrent.wpisbox)
 905         {
 906                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 907                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 908                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 909                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 910                 {
 911                         bunnyhop_forbidden = true;
 912                         destorg = this.goalcurrent.origin;
 913                         if(destorg.z > this.origin.z)
 914                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 915                 }
 916         }
 917
 918         diff = destorg - this.origin;
 919
 920         if (time < this.bot_stop_moving_timeout
 921                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 922         {
 923                 // stop if the locked goal has been reached
 924                 destorg = this.origin;
 925                 diff = dir = '0 0 0';
 926         }
 927         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 928         {
 929                 if (vdist(diff, <, 80))
 930                 {
 931                         // stop if too close to target player (even if frozen)
 932                         destorg = this.origin;
 933                         diff = dir = '0 0 0';
 934                 }
 935                 else
 936                 {
 937                         // move destorg out of target players, otherwise bot will consider them
 938                         // an obstacle that needs to be jumped (especially if frozen)
 939                         dir = normalize(diff);
 940                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 941                         diff = destorg - this.origin;
 942                 }
 943         }
 944         else
 945                 dir = normalize(diff);
 946         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 947
 948         //if (this.bot_dodgevector_time < time)
 949         {
 950                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 951                 //this.bot_dodgevector_jumpbutton = 1;
 952                 evadeobstacle = '0 0 0';
 953                 evadelava = '0 0 0';
 954
 955                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 956                 makevectors(this.v_angle.y * '0 1 0');
 957                 if (this.waterlevel > WATERLEVEL_WETFEET)
 958                 {
 959                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 960                         {
 961                                 if(!this.goalcurrent)
 962                                         this.aistatus |= AI_STATUS_OUT_WATER;
 963                                 else if(destorg.z > this.origin.z)
 964                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 965                         }
 966                         else
 967                         {
 968                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 969                                         (this.aistatus & AI_STATUS_OUT_WATER))
 970                                 {
 971                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 972                                         dir = flatdir;
 973                                 }
 974                                 else
 975                                 {
 976                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 977                                         if (destorg.z > this.origin.z)
 978                                                 dir = flatdir;
 979                                 }
 980                         }
 981                 }
 982                 else
 983                 {
 984                         float s;
 985                         vector offset;
 986                         if(this.aistatus & AI_STATUS_OUT_WATER)
 987                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 988
 989                         // jump if going toward an obstacle that doesn't look like stairs we
 990                         // can walk up directly
 991                         vector deviation = '0 0 0';
 992                         float current_speed = vlen(vec2(this.velocity));
 993                         if (current_speed < maxspeed * 0.2)
 994                                 current_speed = maxspeed * 0.2;
 995                         else
 996                         {
 997                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 998                                 while (deviation.y < -180) deviation.y += 360;
 999                                 while (deviation.y > 180) deviation.y -= 360;
1000                         }
1001                         float turning = false;
1002                         vector flat_diff = vec2(diff);
1003                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
1004                         vector actual_destorg = this.origin + offset;
1005                         if (this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
1006                         {
1007                                 if (time > this.bot_stop_moving_timeout
1008                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
1009                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
1010                                 {
1011                                         this.bot_stop_moving_timeout = time + 0.1;
1012                                 }
1013                                 if (current_speed > autocvar_sv_maxspeed * 0.9
1014                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
1015                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
1016                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
1017                                 )
1018                                 {
1019                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1020                                         // avoid changing route while bot is jumping a gap
1021                                         navigation_goalrating_timeout_extend_if_needed(this, 1.5);
1022                                 }
1023                         }
1024                         else if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
1025                         {
1026                                 if (vlen2(flat_diff) < vlen2(offset))
1027                                 {
1028                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
1029                                         {
1030                                                 // oblique warpzones need a jump otherwise bots gets stuck
1031                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1032                                         }
1033                                         else
1034                                         {
1035                                                 actual_destorg.x = destorg.x;
1036                                                 actual_destorg.y = destorg.y;
1037                                         }
1038                                 }
1039                         }
1040                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
1041                         {
1042                                 actual_destorg.x = destorg.x;
1043                                 actual_destorg.y = destorg.y;
1044                         }
1045                         else if (vlen2(flat_diff) < vlen2(offset))
1046                         {
1047                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1048                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
1049                                 float dist = vlen(vec2(this.origin + offset - destorg));
1050                                 // if current and next goal are close to each other make sure
1051                                 // actual_destorg isn't set beyond next_goal_org
1052                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
1053                                         actual_destorg = next_goal_org;
1054                                 else
1055                                         actual_destorg = vec2(destorg) + dist * next_dir;
1056                                 actual_destorg.z = this.origin.z;
1057                                 turning = true;
1058                         }
1059
1060                         LABEL(jumpobstacle_check);
1061                         dir = flatdir = normalize(actual_destorg - this.origin);
1062
1063                         bool jump_forbidden = false;
1064                         if (!turning && fabs(deviation.y) > 50)
1065                                 jump_forbidden = true;
1066                         else if (IS_DUCKED(this))
1067                         {
1068                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
1069                                 if (trace_startsolid)
1070                                         jump_forbidden = true;
1071                         }
1072
1073                         if (!jump_forbidden)
1074                         {
1075                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1076                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1077                                 {
1078                                         s = trace_fraction;
1079                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1080                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1081                                         {
1082                                                 // found an obstacle
1083                                                 if (turning && fabs(deviation.y) > 5)
1084                                                 {
1085                                                         // check if the obstacle is still there without turning
1086                                                         actual_destorg = destorg;
1087                                                         turning = false;
1088                                                         this.bot_tracewalk_time = time + 0.25;
1089                                                         goto jumpobstacle_check;
1090                                                 }
1091                                                 s = trace_fraction;
1092                                                 // don't artificially reduce max jump height in real-time
1093                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1094                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1095                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1096                                                 if (trace_fraction > s)
1097                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1098                                                 else
1099                                                 {
1100                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1101                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1102                                                         if (trace_fraction > s)
1103                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1104                                                 }
1105                                         }
1106                                 }
1107                         }
1108
1109                         // if bot for some reason doesn't get close to the current goal find another one
1110                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1111                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1112                         if(havocbot_checkgoaldistance(this, destorg))
1113                         {
1114                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1115                                 {
1116                                         navigation_clearroute(this);
1117                                         navigation_goalrating_timeout_force(this);
1118                                         return;
1119                                 }
1120
1121                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1122                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1123                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1124                                 {
1125                                         navigation_clearroute(this);
1126                                         navigation_goalrating_timeout_force(this);
1127                                         return;
1128                                 }
1129
1130                                 // give bot only another chance to prevent bot getting stuck
1131                                 // in case it thinks it can walk but actually can't
1132                                 this.goalcurrent_distance_z = FLOAT_MAX;
1133                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1134                                 this.goalcurrent_distance_time = -time; // mark second try
1135                         }
1136
1137                         // Check for water/slime/lava and dangerous edges
1138                         // (only when the bot is on the ground or jumping intentionally)
1139
1140                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1141                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1142                         {
1143                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1144                         }
1145
1146                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1147                         vector dst_ahead = this.origin + this.view_ofs + offset;
1148                         vector dst_down = dst_ahead - '0 0 3000';
1149                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1150
1151                         bool unreachable = false;
1152                         s = CONTENT_SOLID;
1153                         if (trace_fraction == 1 && !this.jumppadcount
1154                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1155                                 && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP) )
1156                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1157                         {
1158                                 // Look downwards
1159                                 traceline(dst_ahead , dst_down, true, NULL);
1160                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1161                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1162                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1163                                 {
1164                                         s = pointcontents(trace_endpos + '0 0 1');
1165                                         if (s != CONTENT_SOLID)
1166                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1167                                                 evadelava = normalize(this.velocity) * -1;
1168                                         else if (s == CONTENT_SKY)
1169                                                 evadeobstacle = normalize(this.velocity) * -1;
1170                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1171                                         {
1172                                                 // the traceline check isn't enough but is good as optimization,
1173                                                 // when not true (most of the time) this tracebox call is avoided
1174                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1175                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1176                                                 {
1177                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1178                                                         {
1179                                                                 // the goal is probably on an upper platform, assume bot can't get there
1180                                                                 unreachable = true;
1181                                                         }
1182                                                         else
1183                                                                 evadelava = normalize(this.velocity) * -1;
1184                                                 }
1185                                         }
1186                                 }
1187                         }
1188
1189                         dir = flatdir;
1190                         evadeobstacle.z = 0;
1191                         evadelava.z = 0;
1192                         makevectors(this.v_angle.y * '0 1 0');
1193
1194                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1195                         {
1196                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1197                                 if(IS_PLAYER(this.goalcurrent))
1198                                         unreachable = true;
1199                         }
1200
1201                         // slow down if bot is in the air and goal is under it
1202                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1203                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1204                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1205                         {
1206                                 // tracebox wouldn't work when bot is still on the ledge
1207                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1208                                 if (this.origin.z - trace_endpos.z > 120)
1209                                         evadeobstacle = normalize(this.velocity) * -1;
1210                         }
1211
1212                         if(unreachable)
1213                         {
1214                                 navigation_clearroute(this);
1215                                 navigation_goalrating_timeout_force(this);
1216                                 this.ignoregoal = this.goalcurrent;
1217                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1218                         }
1219                 }
1220
1221                 dodge = havocbot_dodge(this);
1222                 if (dodge)
1223                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1224                 dodge += evadeobstacle + evadelava;
1225                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1226                 if (this.enemy)
1227                 {
1228                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1229                         if (IS_PLAYER(trace_ent))
1230                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1231                 }
1232         //      this.bot_dodgevector = dir;
1233         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1234         }
1235
1236         float ladder_zdir = 0;
1237         if(time < this.ladder_time)
1238         {
1239                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1240                 {
1241                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1242                                 ladder_zdir = 1;
1243                 }
1244                 else
1245                 {
1246                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1247                                 ladder_zdir = -1;
1248                 }
1249                 if (ladder_zdir)
1250                 {
1251                         if (vdist(vec2(diff), <, 40))
1252                                 dir.z = ladder_zdir * 4;
1253                         else
1254                                 dir.z = ladder_zdir * 2;
1255                         dir = normalize(dir);
1256                 }
1257         }
1258
1259         if (this.goalcurrent.wpisbox
1260                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1261         {
1262                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1263                 // head to teleport origin
1264                 dir = (this.goalcurrent.origin - this.origin);
1265                 dir.z = 0;
1266                 dir = normalize(dir);
1267         }
1268
1269         // already executed when bot targets an enemy
1270         if (!this.bot_aimdir_executed)
1271         {
1272                 if (time < this.bot_stop_moving_timeout)
1273                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1274                 else
1275                         bot_aimdir(this, dir, 0);
1276         }
1277
1278         if (!ladder_zdir)
1279         {
1280                 dir *= dodge_enemy_factor;
1281                 dir = normalize(dir + dodge);
1282         }
1283
1284         makevectors(this.v_angle);
1285         //dir = this.bot_dodgevector;
1286         //if (this.bot_dodgevector_jumpbutton)
1287         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1288         CS(this).movement_x = dir * v_forward * maxspeed;
1289         CS(this).movement_y = dir * v_right * maxspeed;
1290         CS(this).movement_z = dir * v_up * maxspeed;
1291
1292         // Emulate keyboard interface
1293         if (skill < 10)
1294                 havocbot_keyboard_movement(this, destorg);
1295
1296         // Bunnyhop!
1297         //if(this.aistatus & AI_STATUS_ROAMING)
1298         if(!bunnyhop_forbidden && this.goalcurrent)
1299         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1300                 havocbot_bunnyhop(this, dir);
1301
1302         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1303         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1304         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1305 }
1306
1307 entity havocbot_gettarget(entity this, bool secondary)
1308 {
1309         entity best = NULL;
1310         vector eye = CENTER_OR_VIEWOFS(this);
1311         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1312         {
1313                 vector v = CENTER_OR_VIEWOFS(it);
1314                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1315                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1316                 if(bot_shouldattack(this, it))
1317                 {
1318                         traceline(eye, v, true, this);
1319                         if (trace_ent == it || trace_fraction >= 1)
1320                                 best = it;
1321                 }
1322         });
1323
1324         return best;
1325 }
1326
1327 void havocbot_chooseenemy(entity this)
1328 {
1329         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1330         {
1331                 this.enemy = NULL;
1332                 return;
1333         }
1334         if (this.enemy)
1335         {
1336                 if (!bot_shouldattack(this, this.enemy))
1337                 {
1338                         // enemy died or something, find a new target
1339                         this.enemy = NULL;
1340                         this.havocbot_chooseenemy_finished = time;
1341                 }
1342                 else if (this.havocbot_stickenemy)
1343                 {
1344                         // tracking last chosen enemy
1345                         // if enemy is visible
1346                         // and not really really far away
1347                         // and we're not severely injured
1348                         // then keep tracking for a half second into the future
1349                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1350                         if (trace_ent == this.enemy || trace_fraction == 1)
1351                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1352                         if (GetResource(this, RES_HEALTH) > 30)
1353                         {
1354                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1355                                 this.havocbot_chooseenemy_finished = time + 0.5;
1356                                 return;
1357                         }
1358                         // enemy isn't visible, or is far away, or we're injured severely
1359                         // so stop preferring this enemy
1360                         // (it will still take a half second until a new one is chosen)
1361                         this.havocbot_stickenemy = 0;
1362                 }
1363         }
1364         if (time < this.havocbot_chooseenemy_finished)
1365                 return;
1366         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1367         vector eye = this.origin + this.view_ofs;
1368         entity best = NULL;
1369         float bestrating = 100000000;
1370
1371         // Backup hit flags
1372         int hf = this.dphitcontentsmask;
1373
1374         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1375
1376         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1377
1378         bool scan_transparent = false;
1379         bool scan_secondary_targets = false;
1380         bool have_secondary_targets = false;
1381         while(true)
1382         {
1383                 scan_secondary_targets = false;
1384 LABEL(scan_targets)
1385                 IL_EACH(g_bot_targets, it.bot_attack,
1386                 {
1387                         if(!scan_secondary_targets)
1388                         {
1389                                 if(it.classname == "misc_breakablemodel")
1390                                 {
1391                                         have_secondary_targets = true;
1392                                         continue;
1393                                 }
1394                         }
1395                         else if(it.classname != "misc_breakablemodel")
1396                                 continue;
1397
1398                         vector v = (it.absmin + it.absmax) * 0.5;
1399                         float rating = vlen2(v - eye);
1400                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1401                         if (bestrating > rating)
1402                         if (bot_shouldattack(this, it))
1403                         {
1404                                 traceline(eye, v, true, this);
1405                                 if (trace_ent == it || trace_fraction >= 1)
1406                                 {
1407                                         best = it;
1408                                         bestrating = rating;
1409                                 }
1410                         }
1411                 });
1412
1413                 if(!best && have_secondary_targets && !scan_secondary_targets)
1414                 {
1415                         scan_secondary_targets = true;
1416                         // restart the loop
1417                         bestrating = 100000000;
1418                         goto scan_targets;
1419                 }
1420
1421                 // I want to do a second scan if no enemy was found or I don't have weapons
1422                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1423                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1424                         break;
1425                 if(scan_transparent)
1426                         break;
1427
1428                 // Set flags to see through transparent objects
1429                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1430
1431                 scan_transparent = true;
1432         }
1433
1434         // Restore hit flags
1435         this.dphitcontentsmask = hf;
1436
1437         this.enemy = best;
1438         this.havocbot_stickenemy = true;
1439         if(best && best.classname == "misc_breakablemodel")
1440                 this.havocbot_stickenemy = false;
1441 }
1442
1443 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1444 {
1445         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1446         // so skip this for them, or they'll never get to reload their weapons at all.
1447         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1448         if(skill < 5)
1449                 return false;
1450
1451         // if this weapon is scheduled for reloading, don't switch to it during combat
1452         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1453         {
1454                 FOREACH(Weapons, it != WEP_Null, {
1455                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1456                                 return true; // other weapon available
1457                 });
1458         }
1459
1460         return false;
1461 }
1462
1463 void havocbot_chooseweapon(entity this, .entity weaponentity)
1464 {
1465         int i;
1466
1467         // ;)
1468         if(g_weaponarena_weapons == WEPSET(TUBA))
1469         {
1470                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1471                 return;
1472         }
1473
1474         // TODO: clean this up by moving it to weapon code
1475         if(this.enemy==NULL)
1476         {
1477                 // If no weapon was chosen get the first available weapon
1478                 if(this.(weaponentity).m_weapon==WEP_Null)
1479                 FOREACH(Weapons, it != WEP_Null, {
1480                         if(client_hasweapon(this, it, weaponentity, true, false))
1481                         {
1482                                 this.(weaponentity).m_switchweapon = it;
1483                                 return;
1484                         }
1485                 });
1486                 return;
1487         }
1488
1489         // Do not change weapon during the next second after a combo
1490         float f = time - this.lastcombotime;
1491         if(f < 1)
1492                 return;
1493
1494         float w;
1495         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1496
1497         // Should it do a weapon combo?
1498         float af, ct, combo_time, combo;
1499
1500         af = ATTACK_FINISHED(this, weaponentity);
1501         ct = autocvar_bot_ai_weapon_combo_threshold;
1502
1503         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1504         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1505         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1506
1507         combo = false;
1508
1509         if(autocvar_bot_ai_weapon_combo)
1510         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1511         if(af > combo_time)
1512         {
1513                 combo = true;
1514                 this.lastcombotime = time;
1515         }
1516
1517         distance *= (2 ** this.bot_rangepreference);
1518
1519         // Custom weapon list based on distance to the enemy
1520         if(bot_custom_weapon){
1521
1522                 // Choose weapons for far distance
1523                 if ( distance > bot_distance_far ) {
1524                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1525                                 w = bot_weapons_far[i];
1526                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1527                                 {
1528                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1529                                                 continue;
1530                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1531                                         return;
1532                                 }
1533                         }
1534                 }
1535
1536                 // Choose weapons for mid distance
1537                 if ( distance > bot_distance_close) {
1538                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1539                                 w = bot_weapons_mid[i];
1540                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1541                                 {
1542                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1543                                                 continue;
1544                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1545                                         return;
1546                                 }
1547                         }
1548                 }
1549
1550                 // Choose weapons for close distance
1551                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1552                         w = bot_weapons_close[i];
1553                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1554                         {
1555                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1556                                         continue;
1557                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1558                                 return;
1559                         }
1560                 }
1561         }
1562 }
1563
1564 void havocbot_aim(entity this)
1565 {
1566         if (time < this.nextaim)
1567                 return;
1568         this.nextaim = time + 0.1;
1569         vector myvel = this.velocity;
1570         if (!this.waterlevel)
1571                 myvel.z = 0;
1572         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1573         else if (this.enemy)
1574         {
1575                 vector enemyvel = this.enemy.velocity;
1576                 if (!this.enemy.waterlevel)
1577                         enemyvel.z = 0;
1578                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1579         }
1580         else
1581                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1582 }
1583
1584 bool havocbot_moveto_refresh_route(entity this)
1585 {
1586         // Refresh path to goal if necessary
1587         entity wp;
1588         wp = this.havocbot_personal_waypoint;
1589         navigation_goalrating_start(this);
1590         navigation_routerating(this, wp, 10000, 10000);
1591         navigation_goalrating_end(this);
1592         return (this.goalentity != NULL);
1593 }
1594
1595 float havocbot_moveto(entity this, vector pos)
1596 {
1597         entity wp;
1598
1599         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1600         {
1601                 // Step 4: Move to waypoint
1602                 if(this.havocbot_personal_waypoint==NULL)
1603                 {
1604                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1605                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1606                         return CMD_STATUS_ERROR;
1607                 }
1608
1609                 if (!bot_strategytoken_taken)
1610                 if(this.havocbot_personal_waypoint_searchtime<time)
1611                 {
1612                         bot_strategytoken_taken = true;
1613                         if(havocbot_moveto_refresh_route(this))
1614                         {
1615                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1616                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1617                                 this.havocbot_personal_waypoint_failcounter = 0;
1618                         }
1619                         else
1620                         {
1621                                 this.havocbot_personal_waypoint_failcounter += 1;
1622                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1623                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1624                                 {
1625                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1626                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1627                                         delete(this.havocbot_personal_waypoint);
1628                                         return CMD_STATUS_ERROR;
1629                                 }
1630                                 else
1631                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1632                         }
1633                 }
1634
1635                 if(autocvar_bot_debug_goalstack)
1636                         debuggoalstack(this);
1637
1638
1639                 // Go!
1640                 havocbot_movetogoal(this);
1641
1642                 if (!this.bot_aimdir_executed && this.goalcurrent)
1643                 {
1644                         // Heading
1645                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1646                         dir -= this.origin + this.view_ofs;
1647                         dir.z = 0;
1648                         bot_aimdir(this, dir, 0);
1649                 }
1650
1651                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1652                 {
1653                         // Step 5: Waypoint reached
1654                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1655                         waypoint_remove(this.havocbot_personal_waypoint);
1656                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1657                         return CMD_STATUS_FINISHED;
1658                 }
1659
1660                 return CMD_STATUS_EXECUTING;
1661         }
1662
1663         // Step 2: Linking waypoint
1664         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1665         {
1666                 // Wait until it is linked
1667                 if(!this.havocbot_personal_waypoint.wplinked)
1668                 {
1669                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1670                         return CMD_STATUS_EXECUTING;
1671                 }
1672
1673                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1674                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1675                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1676
1677                 // Step 3: Route to waypoint
1678                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1679
1680                 return CMD_STATUS_EXECUTING;
1681         }
1682
1683         // Step 1: Spawning waypoint
1684         wp = waypoint_spawnpersonal(this, pos);
1685         if(wp==NULL)
1686         {
1687                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1688                 return CMD_STATUS_ERROR;
1689         }
1690
1691         this.havocbot_personal_waypoint = wp;
1692         this.havocbot_personal_waypoint_failcounter = 0;
1693         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1694
1695         // if pos is inside a teleport, then let's mark it as teleport waypoint
1696         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1697         {
1698                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1699                 this.lastteleporttime = 0;
1700         });
1701
1702 /*
1703         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1704                 print("routing to a teleporter\n");
1705         else
1706                 print("routing to a non-teleporter\n");
1707 */
1708
1709         return CMD_STATUS_EXECUTING;
1710 }
1711
1712 float havocbot_resetgoal(entity this)
1713 {
1714         navigation_clearroute(this);
1715         return CMD_STATUS_FINISHED;
1716 }
1717
1718 void havocbot_setupbot(entity this)
1719 {
1720         this.bot_ai = havocbot_ai;
1721         this.cmd_moveto = havocbot_moveto;
1722         this.cmd_resetgoal = havocbot_resetgoal;
1723
1724         // NOTE: bot is not player yet
1725         havocbot_chooserole(this);
1726 }
1727
1728 vector havocbot_dodge(entity this)
1729 {
1730         // LordHavoc: disabled because this is too expensive
1731         return '0 0 0';
1732 #if 0
1733         entity head;
1734         vector dodge, v, n;
1735         float danger, bestdanger, vl, d;
1736         dodge = '0 0 0';
1737         bestdanger = -20;
1738         // check for dangerous objects near bot or approaching bot
1739         head = findchainfloat(bot_dodge, true);
1740         while(head)
1741         {
1742                 if (head.owner != this)
1743                 {
1744                         vl = vlen(head.velocity);
1745                         if (vl > autocvar_sv_maxspeed * 0.3)
1746                         {
1747                                 n = normalize(head.velocity);
1748                                 v = this.origin - head.origin;
1749                                 d = v * n;
1750                                 if (d > (0 - head.bot_dodgerating))
1751                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1752                                 {
1753                                         // calculate direction and distance from the flight path, by removing the forward axis
1754                                         v = v - (n * (v * n));
1755                                         danger = head.bot_dodgerating - vlen(v);
1756                                         if (bestdanger < danger)
1757                                         {
1758                                                 bestdanger = danger;
1759                                                 // dodge to the side of the object
1760                                                 dodge = normalize(v);
1761                                         }
1762                                 }
1763                         }
1764                         else
1765                         {
1766                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1767                                 if (bestdanger < danger)
1768                                 {
1769                                         bestdanger = danger;
1770                                         dodge = normalize(this.origin - head.origin);
1771                                 }
1772                         }
1773                 }
1774                 head = head.chain;
1775         }
1776         return dodge;
1777 #endif
1778 }