qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/mapobjects/func/ladder.qh>
  22 #include <common/mapobjects/teleporters.qh>
  23 #include <common/mapobjects/trigger/jumppads.qh>
  24
  25 #include <lib/warpzone/common.qh>
  26
  27 .float speed;
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if(IS_DEAD(this) || STAT(FROZEN, this))
  93         {
  94                 if (this.goalcurrent)
  95                         navigation_clearroute(this);
  96                 return;
  97         }
  98
  99         havocbot_chooseenemy(this);
 100
 101         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 102         {
 103                 .entity weaponentity = weaponentities[slot];
 104                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 105                 if(this.(weaponentity).bot_chooseweapontime < time)
 106                 {
 107                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 108                         havocbot_chooseweapon(this, weaponentity);
 109                 }
 110         }
 111         havocbot_aim(this);
 112         lag_update(this);
 113
 114         if (this.bot_aimtarg)
 115         {
 116                 this.aistatus |= AI_STATUS_ATTACKING;
 117                 this.aistatus &= ~AI_STATUS_ROAMING;
 118
 119                 if(STAT(WEAPONS, this))
 120                 {
 121                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 122                         {
 123                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 124                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 125                         }
 126                         else
 127                         {
 128                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 129                                 {
 130                                         .entity weaponentity = weaponentities[slot];
 131                                         Weapon w = this.(weaponentity).m_weapon;
 132                                         if(w == WEP_Null && slot != 0)
 133                                                 continue;
 134                                         w.wr_aim(w, this, weaponentity);
 135                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 136                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 137                                 }
 138                         }
 139                 }
 140                 else
 141                 {
 142                         if(IS_PLAYER(this.bot_aimtarg))
 143                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 144                 }
 145         }
 146         else if (this.goalcurrent)
 147         {
 148                 this.aistatus |= AI_STATUS_ROAMING;
 149                 this.aistatus &= ~AI_STATUS_ATTACKING;
 150         }
 151
 152         havocbot_movetogoal(this);
 153         if (!this.bot_aimdir_executed && this.goalcurrent)
 154         {
 155                 // Heading
 156                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 157                 dir -= this.origin + this.view_ofs;
 158                 dir.z = 0;
 159                 bot_aimdir(this, dir, 0);
 160         }
 161
 162         // if the bot is not attacking, consider reloading weapons
 163         if (!(this.aistatus & AI_STATUS_ATTACKING))
 164         {
 165                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 166                 {
 167                         .entity weaponentity = weaponentities[slot];
 168
 169                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 170                                 continue;
 171
 172                         // we are currently holding a weapon that's not fully loaded, reload it
 173                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 174                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 175                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 176
 177                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 178                         // the code above executes next frame, starting the reloading then
 179                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 180                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 181                         {
 182                                 FOREACH(Weapons, it != WEP_Null, {
 183                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 184                                         {
 185                                                 this.(weaponentity).m_switchweapon = it;
 186                                                 break;
 187                                         }
 188                                 });
 189                         }
 190                 }
 191         }
 192 }
 193
 194 void havocbot_keyboard_movement(entity this, vector destorg)
 195 {
 196         vector keyboard;
 197
 198         if (time > this.havocbot_keyboardtime)
 199         {
 200                 float sk = skill + this.bot_moveskill;
 201                 this.havocbot_keyboardtime =
 202                         max(
 203                                 this.havocbot_keyboardtime
 204                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 205                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 206                         , time);
 207                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 208
 209                 float trigger = autocvar_bot_ai_keyboard_threshold;
 210
 211                 // categorize forward movement
 212                 // at skill < 1.5 only forward
 213                 // at skill < 2.5 only individual directions
 214                 // at skill < 4.5 only individual directions, and forward diagonals
 215                 // at skill >= 4.5, all cases allowed
 216                 if (keyboard.x > trigger)
 217                 {
 218                         keyboard.x = 1;
 219                         if (sk < 2.5)
 220                                 keyboard.y = 0;
 221                 }
 222                 else if (keyboard.x < -trigger && sk > 1.5)
 223                 {
 224                         keyboard.x = -1;
 225                         if (sk < 4.5)
 226                                 keyboard.y = 0;
 227                 }
 228                 else
 229                 {
 230                         keyboard.x = 0;
 231                         if (sk < 1.5)
 232                                 keyboard.y = 0;
 233                 }
 234                 if (sk < 4.5)
 235                         keyboard.z = 0;
 236
 237                 if (keyboard.y > trigger)
 238                         keyboard.y = 1;
 239                 else if (keyboard.y < -trigger)
 240                         keyboard.y = -1;
 241                 else
 242                         keyboard.y = 0;
 243
 244                 if (keyboard.z > trigger)
 245                         keyboard.z = 1;
 246                 else if (keyboard.z < -trigger)
 247                         keyboard.z = -1;
 248                 else
 249                         keyboard.z = 0;
 250
 251                 // make sure bots don't get stuck if havocbot_keyboardtime is very high
 252                 if (keyboard == '0 0 0')
 253                         this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 254
 255                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 256                 if (this.havocbot_ducktime > time)
 257                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 258
 259                 keyboard = this.havocbot_keyboard;
 260                 float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 261                 //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 262                 CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 263         }
 264 }
 265
 266 void havocbot_bunnyhop(entity this, vector dir)
 267 {
 268         float bunnyhopdistance;
 269         vector deviation;
 270         float maxspeed;
 271
 272         // Don't jump when attacking
 273         if(this.aistatus & AI_STATUS_ATTACKING)
 274                 return;
 275
 276         if(IS_PLAYER(this.goalcurrent))
 277                 return;
 278
 279         maxspeed = autocvar_sv_maxspeed;
 280
 281         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 282                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 283         {
 284                 this.aistatus &= ~AI_STATUS_RUNNING;
 285                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 286                 this.bot_canruntogoal = 0;
 287                 this.bot_timelastseengoal = 0;
 288                 return;
 289         }
 290
 291         if(this.waterlevel > WATERLEVEL_WETFEET)
 292         {
 293                 this.aistatus &= ~AI_STATUS_RUNNING;
 294                 return;
 295         }
 296
 297         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 298         {
 299                 this.bot_canruntogoal = 0;
 300                 this.bot_timelastseengoal = 0;
 301         }
 302
 303         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 304         bunnyhopdistance = vlen(this.origin - gco);
 305
 306         // Run only to visible goals
 307         if(IS_ONGROUND(this))
 308         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 309         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 310         {
 311                         this.bot_lastseengoal = this.goalcurrent;
 312
 313                         // seen it before
 314                         if(this.bot_timelastseengoal)
 315                         {
 316                                 // for a period of time
 317                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 318                                 {
 319                                         float checkdistance;
 320                                         checkdistance = true;
 321
 322                                         // don't run if it is too close
 323                                         if(this.bot_canruntogoal==0)
 324                                         {
 325                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 326                                                         this.bot_canruntogoal = 1;
 327                                                 else
 328                                                         this.bot_canruntogoal = -1;
 329                                         }
 330
 331                                         if(this.bot_canruntogoal != 1)
 332                                                 return;
 333
 334                                         if(this.aistatus & AI_STATUS_ROAMING)
 335                                         if(this.goalcurrent.classname=="waypoint")
 336                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 337                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 338                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 339                                         if (!(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP))
 340                                         {
 341                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 342                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 343                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 344                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 345
 346                                                 if(fabs(deviation.y) < 20)
 347                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 348                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 349                                                 {
 350                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 351                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 352                                                         {
 353                                                                 checkdistance = false;
 354                                                         }
 355                                                 }
 356                                         }
 357
 358                                         if(checkdistance)
 359                                         {
 360                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 361                                                 // increase stop distance in case the goal is on a slope or a lower platform
 362                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 363                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 364                                         }
 365                                         else
 366                                         {
 367                                                 this.aistatus |= AI_STATUS_RUNNING;
 368                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 369                                         }
 370                                 }
 371                         }
 372                         else
 373                         {
 374                                 this.bot_timelastseengoal = time;
 375                         }
 376         }
 377         else
 378         {
 379                 this.bot_timelastseengoal = 0;
 380         }
 381
 382 #if 0
 383         // Release jump button
 384         if(!cvar("sv_pogostick"))
 385         if((IS_ONGROUND(this)) == 0)
 386         {
 387                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 388                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 389
 390                 // Strafe
 391                 if(this.aistatus & AI_STATUS_RUNNING)
 392                 if(vlen(this.velocity)>maxspeed)
 393                 {
 394                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 395                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 396                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 397
 398                         if(fabs(deviation.y)>10)
 399                                 CS(this).movement_x = 0;
 400
 401                         if(deviation.y>10)
 402                                 CS(this).movement_y = maxspeed * -1;
 403                         else if(deviation.y<10)
 404                                 CS(this).movement_y = maxspeed;
 405
 406                 }
 407         }
 408 #endif
 409 }
 410
 411 // return true when bot isn't getting closer to the current goal
 412 bool havocbot_checkgoaldistance(entity this, vector gco)
 413 {
 414         if (this.bot_stop_moving_timeout > time)
 415                 return false;
 416         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 417         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 418         float distance_time = this.goalcurrent_distance_time;
 419         if(distance_time < 0)
 420                 distance_time = -distance_time;
 421         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 422         {
 423                 if(!distance_time)
 424                         this.goalcurrent_distance_time = time;
 425                 else if (time - distance_time > 0.5)
 426                         return true;
 427         }
 428         else
 429         {
 430                 // reduce it a little bit so it works even with very small approaches to the goal
 431                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 432                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 433                 this.goalcurrent_distance_time = 0;
 434         }
 435         return false;
 436 }
 437
 438 entity havocbot_select_an_item_of_group(entity this, int gr)
 439 {
 440         entity selected = NULL;
 441         float selected_dist2 = 0;
 442         // select farthest item of this group from bot's position
 443         IL_EACH(g_items, it.item_group == gr && it.solid,
 444         {
 445                 float dist2 = vlen2(this.origin - it.origin);
 446                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 447                 {
 448                         selected = it;
 449                         selected_dist2 = vlen2(this.origin - selected.origin);
 450                 }
 451         });
 452
 453         if (!selected)
 454                 return NULL;
 455
 456         set_tracewalk_dest(selected, this.origin, false);
 457         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 458                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 459         {
 460                 return NULL;
 461         }
 462
 463         return selected;
 464 }
 465
 466 void havocbot_movetogoal(entity this)
 467 {
 468         vector diff;
 469         vector dir;
 470         vector flatdir;
 471         vector evadeobstacle;
 472         vector evadelava;
 473         float dodge_enemy_factor = 1;
 474         float maxspeed;
 475         //float dist;
 476         vector dodge;
 477         //if (this.goalentity)
 478         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 479         CS(this).movement = '0 0 0';
 480         maxspeed = autocvar_sv_maxspeed;
 481
 482         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 483         // Jetpack navigation
 484         if(this.navigation_jetpack_goal)
 485         if(this.goalcurrent==this.navigation_jetpack_goal)
 486         if(GetResource(this, RES_FUEL))
 487         {
 488                 if(autocvar_bot_debug_goalstack)
 489                 {
 490                         debuggoalstack(this);
 491                         te_wizspike(this.navigation_jetpack_point);
 492                 }
 493
 494                 // Take off
 495                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 496                 {
 497                         // Brake almost completely so it can get a good direction
 498                         if(vdist(this.velocity, >, 10))
 499                                 return;
 500                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 501                 }
 502
 503                 makevectors(this.v_angle.y * '0 1 0');
 504                 dir = normalize(this.navigation_jetpack_point - this.origin);
 505
 506                 // Landing
 507                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 508                 {
 509                         // Calculate brake distance in xy
 510                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 511                         float vel2 = vlen2(vec2(this.velocity));
 512                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 513                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 514                         if(d < db || d < 500)
 515                         {
 516                                 // Brake
 517                                 if (vel2 > (maxspeed * 0.3) ** 2)
 518                                 {
 519                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 520                                         return;
 521                                 }
 522                                 // Switch to normal mode
 523                                 this.navigation_jetpack_goal = NULL;
 524                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 525                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 526                                 return;
 527                         }
 528                 }
 529                 else if(checkpvs(this.origin,this.goalcurrent))
 530                 {
 531                         // If I can see the goal switch to landing code
 532                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 533                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 534                         return;
 535                 }
 536
 537                 // Flying
 538                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 539                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 540                 {
 541                         CS(this).movement_x = dir * v_forward * maxspeed;
 542                         CS(this).movement_y = dir * v_right * maxspeed;
 543                 }
 544                 return;
 545         }
 546
 547         // Handling of jump pads
 548         if(this.jumppadcount)
 549         {
 550                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 551                 {
 552                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 553                         if(navigation_poptouchedgoals(this))
 554                                 return;
 555                 }
 556                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 557                 {
 558                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 559                         // but with some randomness so it can try out different paths
 560                         if(!this.goalcurrent)
 561                         {
 562                                 entity newgoal = NULL;
 563                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 564                                 {
 565                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 566                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 567                                                 continue;
 568
 569                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 570
 571                                         if(trace_fraction < 1)
 572                                                 continue;
 573
 574                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 575                                                 newgoal = it;
 576                                 });
 577
 578                                 if(newgoal)
 579                                 {
 580                                         this.ignoregoal = this.goalcurrent;
 581                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 582                                         navigation_clearroute(this);
 583                                         navigation_routetogoal(this, newgoal, this.origin);
 584                                         if(autocvar_bot_debug_goalstack)
 585                                                 debuggoalstack(this);
 586                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 587                                 }
 588                         }
 589                         else //if (this.goalcurrent)
 590                         {
 591                                 if (this.goalcurrent.bot_pickup)
 592                                 {
 593                                         entity jumppad_wp = this.goalcurrent_prev;
 594                                         navigation_poptouchedgoals(this);
 595                                         if(!this.goalcurrent && jumppad_wp.wp00)
 596                                         {
 597                                                 // head to the jumppad destination once bot reaches the goal item
 598                                                 navigation_pushroute(this, jumppad_wp.wp00);
 599                                         }
 600                                 }
 601                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 602                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 603                                 {
 604                                         if (this.velocity.z < 0)
 605                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 606                                 }
 607                                 else if(havocbot_checkgoaldistance(this, gco))
 608                                 {
 609                                         navigation_clearroute(this);
 610                                         navigation_goalrating_timeout_force(this);
 611                                 }
 612                                 else
 613                                         return;
 614                         }
 615                 }
 616                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 617                 {
 618                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 619                         {
 620                                 vector velxy = this.velocity; velxy_z = 0;
 621                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 622                                 {
 623                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 624                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 625                                 }
 626                                 return;
 627                         }
 628
 629                         // Don't chase players while using a jump pad
 630                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 631                                 return;
 632                 }
 633         }
 634         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 635                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 636
 637         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 638         if (skill > 6 && !(IS_ONGROUND(this)))
 639         {
 640                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 641                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 642                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 643
 644                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 645                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 646                 if(this.items & IT_JETPACK)
 647                 {
 648                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 649                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 650                         {
 651                                 if(this.velocity.z<0)
 652                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 653                         }
 654                         else
 655                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 656
 657                         // If there is no goal try to move forward
 658
 659                         if(this.goalcurrent==NULL)
 660                                 dir = v_forward;
 661                         else
 662                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 663
 664                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 665                         float xyspeed = xyvelocity * dir;
 666
 667                         if(xyspeed < (maxspeed / 2))
 668                         {
 669                                 makevectors(this.v_angle.y * '0 1 0');
 670                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 671                                 if(trace_fraction==1)
 672                                 {
 673                                         CS(this).movement_x = dir * v_forward * maxspeed;
 674                                         CS(this).movement_y = dir * v_right * maxspeed;
 675                                         if (skill < 10)
 676                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 677                                 }
 678                         }
 679
 680                         this.havocbot_blockhead = true;
 681
 682                         return;
 683                 }
 684                 else if(!this.jumppadcount && !this.goalcurrent.wphardwired
 685                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 686                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 687                 {
 688                         if(this.velocity.z < 0)
 689                         {
 690                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 691                                 {
 692                                         .entity weaponentity = weaponentities[slot];
 693
 694                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 695                                                 continue;
 696
 697                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 698                                         {
 699                                                 CS(this).movement_x = maxspeed;
 700
 701                                                 if(this.rocketjumptime)
 702                                                 {
 703                                                         if(time > this.rocketjumptime)
 704                                                         {
 705                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 706                                                                 this.rocketjumptime = 0;
 707                                                         }
 708                                                         return;
 709                                                 }
 710
 711                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 712                                                 this.v_angle_x = 90;
 713                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 714                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 715                                                 return;
 716                                         }
 717                                 }
 718                         }
 719                 }
 720                 else
 721                 {
 722                         // If there is no goal try to move forward
 723                         if(this.goalcurrent==NULL)
 724                                 CS(this).movement_x = maxspeed;
 725                 }
 726         }
 727
 728         // If we are under water with no goals, swim up
 729         if(this.waterlevel && !this.goalcurrent)
 730         {
 731                 dir = '0 0 0';
 732                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 733                         dir.z = 1;
 734                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 735                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 736                 else
 737                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 738                 makevectors(this.v_angle.y * '0 1 0');
 739                 vector v = dir * maxspeed;
 740                 CS(this).movement.x = v * v_forward;
 741                 CS(this).movement.y = v * v_right;
 742                 CS(this).movement.z = v * v_up;
 743         }
 744
 745         // if there is nowhere to go, exit
 746         if (this.goalcurrent == NULL)
 747                 return;
 748
 749
 750         bool locked_goal = false;
 751         if((this.goalentity && wasfreed(this.goalentity))
 752                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 753         {
 754                 navigation_clearroute(this);
 755                 navigation_goalrating_timeout_force(this);
 756                 return;
 757         }
 758         else if(this.goalentity.tag_entity)
 759         {
 760                 navigation_goalrating_timeout_expire(this, 2);
 761         }
 762         else if(this.goalentity.bot_pickup)
 763         {
 764                 if(this.goalentity.bot_pickup_respawning)
 765                 {
 766                         if(this.goalentity.solid) // item respawned
 767                                 this.goalentity.bot_pickup_respawning = false;
 768                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 769                         {
 770                                 if(checkpvs(this.origin, this.goalentity))
 771                                 {
 772                                         this.goalentity.bot_pickup_respawning = false;
 773                                         navigation_goalrating_timeout_expire(this, random());
 774                                 }
 775                                 locked_goal = true; // wait for item to respawn
 776                         }
 777                         else if(this.goalentity == this.goalcurrent)
 778                                 locked_goal = true; // wait for item to respawn
 779                 }
 780                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 781                 {
 782                         if(checkpvs(this.origin, this.goalentity))
 783                         {
 784                                 navigation_goalrating_timeout_expire(this, random());
 785                         }
 786                 }
 787         }
 788         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 789                 locked_goal = true;
 790
 791         if (navigation_shortenpath(this))
 792         {
 793                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 794                         && navigation_goalrating_timeout_can_be_anticipated(this))
 795                 {
 796                         navigation_goalrating_timeout_force(this);
 797                 }
 798         }
 799
 800         bool goalcurrent_can_be_removed = false;
 801         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 802         {
 803                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 804                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 805                 {
 806                         goalcurrent_can_be_removed = true;
 807                         // don't remove if not visible
 808                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 809                         {
 810                                 if (IS_DEAD(this.goalcurrent))
 811                                 {
 812                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 813                                         {
 814                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 815                                                 {
 816                                                         navigation_clearroute(this);
 817                                                         navigation_pushroute(this, it);
 818                                                         // loot can't be immediately rated since it isn't on ground yet
 819                                                         // it will be rated after a second when on ground, meanwhile head to it
 820                                                         navigation_goalrating_timeout_expire(this, 1);
 821                                                         return;
 822                                                 }
 823                                         });
 824                                 }
 825                                 if (!Item_IsLoot(this.goalcurrent))
 826                                 {
 827                                         navigation_goalrating_timeout_force(this);
 828                                         return;
 829                                 }
 830                         }
 831                 }
 832                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 833                 {
 834                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 835                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 836                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 837                         {
 838                                 navigation_goalrating_timeout_force(this);
 839                                 return;
 840                         }
 841                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 842                 }
 843         }
 844
 845         if(!locked_goal)
 846         {
 847                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 848                 // in this case path finding can start directly from a waypoint instead of
 849                 // looking for all the reachable waypoints up to a certain distance
 850                 if (navigation_poptouchedgoals(this))
 851                 {
 852                         if (this.goalcurrent)
 853                         {
 854                                 if (goalcurrent_can_be_removed)
 855                                 {
 856                                         // remove even if not visible
 857                                         navigation_goalrating_timeout_force(this);
 858                                         return;
 859                                 }
 860                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 861                                         navigation_goalrating_timeout_force(this);
 862                         }
 863                         else
 864                         {
 865                                 entity old_goal = this.goalcurrent_prev;
 866                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 867                                 {
 868                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 869                                         // item of the group by telling the bot to head directly to the farthest item.
 870                                         // Next time we let the bot select a goal as usual which can be another item
 871                                         // of this group (the closest one) and so on
 872                                         this.item_group = old_goal.item_group;
 873                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 874                                         if (new_goal)
 875                                                 navigation_pushroute(this, new_goal);
 876                                 }
 877                         }
 878                 }
 879         }
 880
 881         // if ran out of goals try to use an alternative goal or get a new strategy asap
 882         if(this.goalcurrent == NULL)
 883         {
 884                 navigation_goalrating_timeout_force(this);
 885                 return;
 886         }
 887
 888
 889         if(autocvar_bot_debug_goalstack)
 890                 debuggoalstack(this);
 891
 892         bool bunnyhop_forbidden = false;
 893         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 894         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 895         {
 896                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 897                 destorg = this.goalcurrent.origin;
 898         }
 899         else if (this.goalcurrent.wpisbox)
 900         {
 901                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 902                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 903                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 904                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 905                 {
 906                         bunnyhop_forbidden = true;
 907                         destorg = this.goalcurrent.origin;
 908                         if(destorg.z > this.origin.z)
 909                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 910                 }
 911         }
 912
 913         diff = destorg - this.origin;
 914
 915         if (time < this.bot_stop_moving_timeout
 916                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 917         {
 918                 // stop if the locked goal has been reached
 919                 destorg = this.origin;
 920                 diff = dir = '0 0 0';
 921         }
 922         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 923         {
 924                 if (vdist(diff, <, 80))
 925                 {
 926                         // stop if too close to target player (even if frozen)
 927                         destorg = this.origin;
 928                         diff = dir = '0 0 0';
 929                 }
 930                 else
 931                 {
 932                         // move destorg out of target players, otherwise bot will consider them
 933                         // an obstacle that needs to be jumped (especially if frozen)
 934                         dir = normalize(diff);
 935                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 936                         diff = destorg - this.origin;
 937                 }
 938         }
 939         else
 940                 dir = normalize(diff);
 941         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 942
 943         //if (this.bot_dodgevector_time < time)
 944         {
 945                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 946                 //this.bot_dodgevector_jumpbutton = 1;
 947                 evadeobstacle = '0 0 0';
 948                 evadelava = '0 0 0';
 949
 950                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 951                 makevectors(this.v_angle.y * '0 1 0');
 952                 if (this.waterlevel > WATERLEVEL_WETFEET)
 953                 {
 954                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 955                         {
 956                                 if(!this.goalcurrent)
 957                                         this.aistatus |= AI_STATUS_OUT_WATER;
 958                                 else if(destorg.z > this.origin.z)
 959                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 960                         }
 961                         else
 962                         {
 963                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 964                                         (this.aistatus & AI_STATUS_OUT_WATER))
 965                                 {
 966                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 967                                         dir = flatdir;
 968                                 }
 969                                 else
 970                                 {
 971                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 972                                         if (destorg.z > this.origin.z)
 973                                                 dir = flatdir;
 974                                 }
 975                         }
 976                 }
 977                 else
 978                 {
 979                         float s;
 980                         vector offset;
 981                         if(this.aistatus & AI_STATUS_OUT_WATER)
 982                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 983
 984                         // jump if going toward an obstacle that doesn't look like stairs we
 985                         // can walk up directly
 986                         vector deviation = '0 0 0';
 987                         float current_speed = vlen(vec2(this.velocity));
 988                         if (current_speed < maxspeed * 0.2)
 989                                 current_speed = maxspeed * 0.2;
 990                         else
 991                         {
 992                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 993                                 while (deviation.y < -180) deviation.y += 360;
 994                                 while (deviation.y > 180) deviation.y -= 360;
 995                         }
 996                         float turning = false;
 997                         vector flat_diff = vec2(diff);
 998                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 999                         vector actual_destorg = this.origin + offset;
1000                         if (this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
1001                         {
1002                                 if (time > this.bot_stop_moving_timeout
1003                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
1004                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
1005                                 {
1006                                         this.bot_stop_moving_timeout = time + 0.1;
1007                                 }
1008                                 if (current_speed > autocvar_sv_maxspeed * 0.9
1009                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
1010                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
1011                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
1012                                 )
1013                                 {
1014                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1015                                         // avoid changing route while bot is jumping a gap
1016                                         navigation_goalrating_timeout_extend_if_needed(this, 1.5);
1017                                 }
1018                         }
1019                         else if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
1020                         {
1021                                 if (vlen2(flat_diff) < vlen2(offset))
1022                                 {
1023                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
1024                                         {
1025                                                 // oblique warpzones need a jump otherwise bots gets stuck
1026                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1027                                         }
1028                                         else
1029                                         {
1030                                                 actual_destorg.x = destorg.x;
1031                                                 actual_destorg.y = destorg.y;
1032                                         }
1033                                 }
1034                         }
1035                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
1036                         {
1037                                 actual_destorg.x = destorg.x;
1038                                 actual_destorg.y = destorg.y;
1039                         }
1040                         else if (vlen2(flat_diff) < vlen2(offset))
1041                         {
1042                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1043                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
1044                                 float dist = vlen(vec2(this.origin + offset - destorg));
1045                                 // if current and next goal are close to each other make sure
1046                                 // actual_destorg isn't set beyond next_goal_org
1047                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
1048                                         actual_destorg = next_goal_org;
1049                                 else
1050                                         actual_destorg = vec2(destorg) + dist * next_dir;
1051                                 actual_destorg.z = this.origin.z;
1052                                 turning = true;
1053                         }
1054
1055                         LABEL(jumpobstacle_check);
1056                         dir = flatdir = normalize(actual_destorg - this.origin);
1057
1058                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
1059                         {
1060                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1061                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1062                                 {
1063                                         s = trace_fraction;
1064                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1065                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1066                                         {
1067                                                 // found an obstacle
1068                                                 if (turning && fabs(deviation.y) > 5)
1069                                                 {
1070                                                         // check if the obstacle is still there without turning
1071                                                         actual_destorg = destorg;
1072                                                         turning = false;
1073                                                         this.bot_tracewalk_time = time + 0.25;
1074                                                         goto jumpobstacle_check;
1075                                                 }
1076                                                 s = trace_fraction;
1077                                                 // don't artificially reduce max jump height in real-time
1078                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1079                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1080                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1081                                                 if (trace_fraction > s)
1082                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1083                                                 else
1084                                                 {
1085                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1086                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1087                                                         if (trace_fraction > s)
1088                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1089                                                 }
1090                                         }
1091                                 }
1092                         }
1093
1094                         // if bot for some reason doesn't get close to the current goal find another one
1095                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1096                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1097                         if(havocbot_checkgoaldistance(this, destorg))
1098                         {
1099                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1100                                 {
1101                                         navigation_clearroute(this);
1102                                         navigation_goalrating_timeout_force(this);
1103                                         return;
1104                                 }
1105
1106                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1107                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1108                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1109                                 {
1110                                         navigation_clearroute(this);
1111                                         navigation_goalrating_timeout_force(this);
1112                                         return;
1113                                 }
1114
1115                                 // give bot only another chance to prevent bot getting stuck
1116                                 // in case it thinks it can walk but actually can't
1117                                 this.goalcurrent_distance_z = FLOAT_MAX;
1118                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1119                                 this.goalcurrent_distance_time = -time; // mark second try
1120                         }
1121
1122                         // Check for water/slime/lava and dangerous edges
1123                         // (only when the bot is on the ground or jumping intentionally)
1124
1125                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1126                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1127                         {
1128                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1129                         }
1130
1131                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1132                         vector dst_ahead = this.origin + this.view_ofs + offset;
1133                         vector dst_down = dst_ahead - '0 0 3000';
1134                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1135
1136                         bool unreachable = false;
1137                         s = CONTENT_SOLID;
1138                         if (trace_fraction == 1 && !this.jumppadcount && !this.goalcurrent.wphardwired
1139                                 && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP) )
1140                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1141                         {
1142                                 // Look downwards
1143                                 traceline(dst_ahead , dst_down, true, NULL);
1144                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1145                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1146                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1147                                 {
1148                                         s = pointcontents(trace_endpos + '0 0 1');
1149                                         if (s != CONTENT_SOLID)
1150                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1151                                                 evadelava = normalize(this.velocity) * -1;
1152                                         else if (s == CONTENT_SKY)
1153                                                 evadeobstacle = normalize(this.velocity) * -1;
1154                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1155                                         {
1156                                                 // the traceline check isn't enough but is good as optimization,
1157                                                 // when not true (most of the time) this tracebox call is avoided
1158                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1159                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1160                                                 {
1161                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1162                                                         {
1163                                                                 // the goal is probably on an upper platform, assume bot can't get there
1164                                                                 unreachable = true;
1165                                                         }
1166                                                         else
1167                                                                 evadelava = normalize(this.velocity) * -1;
1168                                                 }
1169                                         }
1170                                 }
1171                         }
1172
1173                         dir = flatdir;
1174                         evadeobstacle.z = 0;
1175                         evadelava.z = 0;
1176                         makevectors(this.v_angle.y * '0 1 0');
1177
1178                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1179                         {
1180                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1181                                 if(IS_PLAYER(this.goalcurrent))
1182                                         unreachable = true;
1183                         }
1184
1185                         // slow down if bot is in the air and goal is under it
1186                         if (!this.goalcurrent.wphardwired
1187                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1188                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1189                         {
1190                                 // tracebox wouldn't work when bot is still on the ledge
1191                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1192                                 if (this.origin.z - trace_endpos.z > 120)
1193                                         evadeobstacle = normalize(this.velocity) * -1;
1194                         }
1195
1196                         if(unreachable)
1197                         {
1198                                 navigation_clearroute(this);
1199                                 navigation_goalrating_timeout_force(this);
1200                                 this.ignoregoal = this.goalcurrent;
1201                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1202                         }
1203                 }
1204
1205                 dodge = havocbot_dodge(this);
1206                 if (dodge)
1207                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1208                 dodge += evadeobstacle + evadelava;
1209                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1210                 if (this.enemy)
1211                 {
1212                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1213                         if (IS_PLAYER(trace_ent))
1214                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1215                 }
1216         //      this.bot_dodgevector = dir;
1217         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1218         }
1219
1220         float ladder_zdir = 0;
1221         if(time < this.ladder_time)
1222         {
1223                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1224                 {
1225                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1226                                 ladder_zdir = 1;
1227                 }
1228                 else
1229                 {
1230                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1231                                 ladder_zdir = -1;
1232                 }
1233                 if (ladder_zdir)
1234                 {
1235                         if (vdist(vec2(diff), <, 40))
1236                                 dir.z = ladder_zdir * 4;
1237                         else
1238                                 dir.z = ladder_zdir * 2;
1239                         dir = normalize(dir);
1240                 }
1241         }
1242
1243         if (this.goalcurrent.wpisbox
1244                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1245         {
1246                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1247                 // head to teleport origin
1248                 dir = (this.goalcurrent.origin - this.origin);
1249                 dir.z = 0;
1250                 dir = normalize(dir);
1251         }
1252
1253         // already executed when bot targets an enemy
1254         if (!this.bot_aimdir_executed)
1255         {
1256                 if (time < this.bot_stop_moving_timeout)
1257                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1258                 else
1259                         bot_aimdir(this, dir, 0);
1260         }
1261
1262         if (!ladder_zdir)
1263         {
1264                 dir *= dodge_enemy_factor;
1265                 dir = normalize(dir + dodge);
1266         }
1267
1268         makevectors(this.v_angle);
1269         //dir = this.bot_dodgevector;
1270         //if (this.bot_dodgevector_jumpbutton)
1271         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1272         CS(this).movement_x = dir * v_forward * maxspeed;
1273         CS(this).movement_y = dir * v_right * maxspeed;
1274         CS(this).movement_z = dir * v_up * maxspeed;
1275
1276         // Emulate keyboard interface
1277         if (skill < 10)
1278                 havocbot_keyboard_movement(this, destorg);
1279
1280         // Bunnyhop!
1281         //if(this.aistatus & AI_STATUS_ROAMING)
1282         if(!bunnyhop_forbidden && this.goalcurrent)
1283         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1284                 havocbot_bunnyhop(this, dir);
1285
1286         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1287         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1288         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1289 }
1290
1291 entity havocbot_gettarget(entity this, bool secondary)
1292 {
1293         entity best = NULL;
1294         vector eye = CENTER_OR_VIEWOFS(this);
1295         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1296         {
1297                 vector v = CENTER_OR_VIEWOFS(it);
1298                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1299                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1300                 if(bot_shouldattack(this, it))
1301                 {
1302                         traceline(eye, v, true, this);
1303                         if (trace_ent == it || trace_fraction >= 1)
1304                                 best = it;
1305                 }
1306         });
1307
1308         return best;
1309 }
1310
1311 void havocbot_chooseenemy(entity this)
1312 {
1313         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1314         {
1315                 this.enemy = NULL;
1316                 return;
1317         }
1318         if (this.enemy)
1319         {
1320                 if (!bot_shouldattack(this, this.enemy))
1321                 {
1322                         // enemy died or something, find a new target
1323                         this.enemy = NULL;
1324                         this.havocbot_chooseenemy_finished = time;
1325                 }
1326                 else if (this.havocbot_stickenemy)
1327                 {
1328                         // tracking last chosen enemy
1329                         // if enemy is visible
1330                         // and not really really far away
1331                         // and we're not severely injured
1332                         // then keep tracking for a half second into the future
1333                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1334                         if (trace_ent == this.enemy || trace_fraction == 1)
1335                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1336                         if (GetResource(this, RES_HEALTH) > 30)
1337                         {
1338                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1339                                 this.havocbot_chooseenemy_finished = time + 0.5;
1340                                 return;
1341                         }
1342                         // enemy isn't visible, or is far away, or we're injured severely
1343                         // so stop preferring this enemy
1344                         // (it will still take a half second until a new one is chosen)
1345                         this.havocbot_stickenemy = 0;
1346                 }
1347         }
1348         if (time < this.havocbot_chooseenemy_finished)
1349                 return;
1350         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1351         vector eye = this.origin + this.view_ofs;
1352         entity best = NULL;
1353         float bestrating = 100000000;
1354
1355         // Backup hit flags
1356         int hf = this.dphitcontentsmask;
1357
1358         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1359
1360         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1361
1362         bool scan_transparent = false;
1363         bool scan_secondary_targets = false;
1364         bool have_secondary_targets = false;
1365         while(true)
1366         {
1367                 scan_secondary_targets = false;
1368 LABEL(scan_targets)
1369                 IL_EACH(g_bot_targets, it.bot_attack,
1370                 {
1371                         if(!scan_secondary_targets)
1372                         {
1373                                 if(it.classname == "misc_breakablemodel")
1374                                 {
1375                                         have_secondary_targets = true;
1376                                         continue;
1377                                 }
1378                         }
1379                         else if(it.classname != "misc_breakablemodel")
1380                                 continue;
1381
1382                         vector v = (it.absmin + it.absmax) * 0.5;
1383                         float rating = vlen2(v - eye);
1384                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1385                         if (bestrating > rating)
1386                         if (bot_shouldattack(this, it))
1387                         {
1388                                 traceline(eye, v, true, this);
1389                                 if (trace_ent == it || trace_fraction >= 1)
1390                                 {
1391                                         best = it;
1392                                         bestrating = rating;
1393                                 }
1394                         }
1395                 });
1396
1397                 if(!best && have_secondary_targets && !scan_secondary_targets)
1398                 {
1399                         scan_secondary_targets = true;
1400                         // restart the loop
1401                         bestrating = 100000000;
1402                         goto scan_targets;
1403                 }
1404
1405                 // I want to do a second scan if no enemy was found or I don't have weapons
1406                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1407                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1408                         break;
1409                 if(scan_transparent)
1410                         break;
1411
1412                 // Set flags to see through transparent objects
1413                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1414
1415                 scan_transparent = true;
1416         }
1417
1418         // Restore hit flags
1419         this.dphitcontentsmask = hf;
1420
1421         this.enemy = best;
1422         this.havocbot_stickenemy = true;
1423         if(best && best.classname == "misc_breakablemodel")
1424                 this.havocbot_stickenemy = false;
1425 }
1426
1427 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1428 {
1429         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1430         // so skip this for them, or they'll never get to reload their weapons at all.
1431         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1432         if(skill < 5)
1433                 return false;
1434
1435         // if this weapon is scheduled for reloading, don't switch to it during combat
1436         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1437         {
1438                 FOREACH(Weapons, it != WEP_Null, {
1439                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1440                                 return true; // other weapon available
1441                 });
1442         }
1443
1444         return false;
1445 }
1446
1447 void havocbot_chooseweapon(entity this, .entity weaponentity)
1448 {
1449         int i;
1450
1451         // ;)
1452         if(g_weaponarena_weapons == WEPSET(TUBA))
1453         {
1454                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1455                 return;
1456         }
1457
1458         // TODO: clean this up by moving it to weapon code
1459         if(this.enemy==NULL)
1460         {
1461                 // If no weapon was chosen get the first available weapon
1462                 if(this.(weaponentity).m_weapon==WEP_Null)
1463                 FOREACH(Weapons, it != WEP_Null, {
1464                         if(client_hasweapon(this, it, weaponentity, true, false))
1465                         {
1466                                 this.(weaponentity).m_switchweapon = it;
1467                                 return;
1468                         }
1469                 });
1470                 return;
1471         }
1472
1473         // Do not change weapon during the next second after a combo
1474         float f = time - this.lastcombotime;
1475         if(f < 1)
1476                 return;
1477
1478         float w;
1479         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1480
1481         // Should it do a weapon combo?
1482         float af, ct, combo_time, combo;
1483
1484         af = ATTACK_FINISHED(this, weaponentity);
1485         ct = autocvar_bot_ai_weapon_combo_threshold;
1486
1487         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1488         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1489         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1490
1491         combo = false;
1492
1493         if(autocvar_bot_ai_weapon_combo)
1494         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1495         if(af > combo_time)
1496         {
1497                 combo = true;
1498                 this.lastcombotime = time;
1499         }
1500
1501         distance *= (2 ** this.bot_rangepreference);
1502
1503         // Custom weapon list based on distance to the enemy
1504         if(bot_custom_weapon){
1505
1506                 // Choose weapons for far distance
1507                 if ( distance > bot_distance_far ) {
1508                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1509                                 w = bot_weapons_far[i];
1510                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1511                                 {
1512                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1513                                                 continue;
1514                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1515                                         return;
1516                                 }
1517                         }
1518                 }
1519
1520                 // Choose weapons for mid distance
1521                 if ( distance > bot_distance_close) {
1522                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1523                                 w = bot_weapons_mid[i];
1524                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1525                                 {
1526                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1527                                                 continue;
1528                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1529                                         return;
1530                                 }
1531                         }
1532                 }
1533
1534                 // Choose weapons for close distance
1535                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1536                         w = bot_weapons_close[i];
1537                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1538                         {
1539                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1540                                         continue;
1541                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1542                                 return;
1543                         }
1544                 }
1545         }
1546 }
1547
1548 void havocbot_aim(entity this)
1549 {
1550         if (time < this.nextaim)
1551                 return;
1552         this.nextaim = time + 0.1;
1553         vector myvel = this.velocity;
1554         if (!this.waterlevel)
1555                 myvel.z = 0;
1556         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1557         else if (this.enemy)
1558         {
1559                 vector enemyvel = this.enemy.velocity;
1560                 if (!this.enemy.waterlevel)
1561                         enemyvel.z = 0;
1562                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1563         }
1564         else
1565                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1566 }
1567
1568 bool havocbot_moveto_refresh_route(entity this)
1569 {
1570         // Refresh path to goal if necessary
1571         entity wp;
1572         wp = this.havocbot_personal_waypoint;
1573         navigation_goalrating_start(this);
1574         navigation_routerating(this, wp, 10000, 10000);
1575         navigation_goalrating_end(this);
1576         return (this.goalentity != NULL);
1577 }
1578
1579 float havocbot_moveto(entity this, vector pos)
1580 {
1581         entity wp;
1582
1583         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1584         {
1585                 // Step 4: Move to waypoint
1586                 if(this.havocbot_personal_waypoint==NULL)
1587                 {
1588                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1589                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1590                         return CMD_STATUS_ERROR;
1591                 }
1592
1593                 if (!bot_strategytoken_taken)
1594                 if(this.havocbot_personal_waypoint_searchtime<time)
1595                 {
1596                         bot_strategytoken_taken = true;
1597                         if(havocbot_moveto_refresh_route(this))
1598                         {
1599                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1600                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1601                                 this.havocbot_personal_waypoint_failcounter = 0;
1602                         }
1603                         else
1604                         {
1605                                 this.havocbot_personal_waypoint_failcounter += 1;
1606                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1607                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1608                                 {
1609                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1610                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1611                                         delete(this.havocbot_personal_waypoint);
1612                                         return CMD_STATUS_ERROR;
1613                                 }
1614                                 else
1615                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1616                         }
1617                 }
1618
1619                 if(autocvar_bot_debug_goalstack)
1620                         debuggoalstack(this);
1621
1622
1623                 // Go!
1624                 havocbot_movetogoal(this);
1625
1626                 if (!this.bot_aimdir_executed && this.goalcurrent)
1627                 {
1628                         // Heading
1629                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1630                         dir -= this.origin + this.view_ofs;
1631                         dir.z = 0;
1632                         bot_aimdir(this, dir, 0);
1633                 }
1634
1635                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1636                 {
1637                         // Step 5: Waypoint reached
1638                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1639                         waypoint_remove(this.havocbot_personal_waypoint);
1640                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1641                         return CMD_STATUS_FINISHED;
1642                 }
1643
1644                 return CMD_STATUS_EXECUTING;
1645         }
1646
1647         // Step 2: Linking waypoint
1648         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1649         {
1650                 // Wait until it is linked
1651                 if(!this.havocbot_personal_waypoint.wplinked)
1652                 {
1653                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1654                         return CMD_STATUS_EXECUTING;
1655                 }
1656
1657                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1658                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1659                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1660
1661                 // Step 3: Route to waypoint
1662                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1663
1664                 return CMD_STATUS_EXECUTING;
1665         }
1666
1667         // Step 1: Spawning waypoint
1668         wp = waypoint_spawnpersonal(this, pos);
1669         if(wp==NULL)
1670         {
1671                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1672                 return CMD_STATUS_ERROR;
1673         }
1674
1675         this.havocbot_personal_waypoint = wp;
1676         this.havocbot_personal_waypoint_failcounter = 0;
1677         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1678
1679         // if pos is inside a teleport, then let's mark it as teleport waypoint
1680         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1681         {
1682                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1683                 this.lastteleporttime = 0;
1684         });
1685
1686 /*
1687         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1688                 print("routing to a teleporter\n");
1689         else
1690                 print("routing to a non-teleporter\n");
1691 */
1692
1693         return CMD_STATUS_EXECUTING;
1694 }
1695
1696 float havocbot_resetgoal(entity this)
1697 {
1698         navigation_clearroute(this);
1699         return CMD_STATUS_FINISHED;
1700 }
1701
1702 void havocbot_setupbot(entity this)
1703 {
1704         this.bot_ai = havocbot_ai;
1705         this.cmd_moveto = havocbot_moveto;
1706         this.cmd_resetgoal = havocbot_resetgoal;
1707
1708         // NOTE: bot is not player yet
1709         havocbot_chooserole(this);
1710 }
1711
1712 vector havocbot_dodge(entity this)
1713 {
1714         // LordHavoc: disabled because this is too expensive
1715         return '0 0 0';
1716 #if 0
1717         entity head;
1718         vector dodge, v, n;
1719         float danger, bestdanger, vl, d;
1720         dodge = '0 0 0';
1721         bestdanger = -20;
1722         // check for dangerous objects near bot or approaching bot
1723         head = findchainfloat(bot_dodge, true);
1724         while(head)
1725         {
1726                 if (head.owner != this)
1727                 {
1728                         vl = vlen(head.velocity);
1729                         if (vl > autocvar_sv_maxspeed * 0.3)
1730                         {
1731                                 n = normalize(head.velocity);
1732                                 v = this.origin - head.origin;
1733                                 d = v * n;
1734                                 if (d > (0 - head.bot_dodgerating))
1735                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1736                                 {
1737                                         // calculate direction and distance from the flight path, by removing the forward axis
1738                                         v = v - (n * (v * n));
1739                                         danger = head.bot_dodgerating - vlen(v);
1740                                         if (bestdanger < danger)
1741                                         {
1742                                                 bestdanger = danger;
1743                                                 // dodge to the side of the object
1744                                                 dodge = normalize(v);
1745                                         }
1746                                 }
1747                         }
1748                         else
1749                         {
1750                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1751                                 if (bestdanger < danger)
1752                                 {
1753                                         bestdanger = danger;
1754                                         dodge = normalize(this.origin - head.origin);
1755                                 }
1756                         }
1757                 }
1758                 head = head.chain;
1759         }
1760         return dodge;
1761 #endif
1762 }