Bot AI: fix bots standing still for a few seconds after taking a dropped weapon
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / havocbot / havocbot.qc
1 #include "havocbot.qh"
2
3 #include "roles.qh"
4
5 #include <server/defs.qh>
6 #include <server/miscfunctions.qh>
7 #include "../cvars.qh"
8
9 #include "../aim.qh"
10 #include "../bot.qh"
11 #include "../navigation.qh"
12 #include "../scripting.qh"
13 #include "../waypoints.qh"
14
15 #include <common/constants.qh>
16 #include <common/impulses/all.qh>
17 #include <common/net_linked.qh>
18 #include <common/physics/player.qh>
19 #include <common/state.qh>
20 #include <common/items/_mod.qh>
21 #include <common/wepent.qh>
22
23 #include <common/mapobjects/func/ladder.qh>
24 #include <common/mapobjects/teleporters.qh>
25 #include <common/mapobjects/trigger/jumppads.qh>
26
27 #include <lib/warpzone/common.qh>
28
29 void havocbot_ai(entity this)
30 {
31         if(this.draggedby)
32                 return;
33
34         this.bot_aimdir_executed = false;
35         // lock aim if teleported or passing through a warpzone
36         if (this.lastteleporttime && !this.jumppadcount)
37                 this.bot_aimdir_executed = true;
38
39         if(bot_execute_commands(this))
40                 return;
41
42         if (bot_strategytoken == this && !bot_strategytoken_taken)
43         {
44                 if(this.havocbot_blockhead)
45                 {
46                         this.havocbot_blockhead = false;
47                 }
48                 else
49                 {
50                         if (!this.jumppadcount && !STAT(FROZEN, this))
51                                 this.havocbot_role(this); // little too far down the rabbit hole
52                 }
53
54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
56                 if(!this.goalcurrent)
57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
58                 {
59                         // Look for the closest waypoint out of water
60                         entity newgoal = NULL;
61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
62                         {
63                                 if(it.origin.z < this.origin.z)
64                                         continue;
65
66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
67                                         continue;
68
69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
70                                         continue;
71
72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
73
74                                 if(trace_fraction < 1)
75                                         continue;
76
77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
78                                         newgoal = it;
79                         });
80
81                         if(newgoal)
82                         {
83                         //      te_wizspike(newgoal.origin);
84                                 navigation_pushroute(this, newgoal);
85                         }
86                 }
87
88                 // token has been used this frame
89                 bot_strategytoken_taken = true;
90         }
91
92         if (this.goalcurrent && wasfreed(this.goalcurrent))
93         {
94                 navigation_clearroute(this);
95                 navigation_goalrating_timeout_force(this);
96                 return;
97         }
98
99         if(IS_DEAD(this) || STAT(FROZEN, this))
100         {
101                 if (this.goalcurrent)
102                         navigation_clearroute(this);
103                 return;
104         }
105
106         havocbot_chooseenemy(this);
107
108         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
109         {
110                 .entity weaponentity = weaponentities[slot];
111                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
112                 if(this.(weaponentity).bot_chooseweapontime < time)
113                 {
114                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
115                         havocbot_chooseweapon(this, weaponentity);
116                 }
117         }
118         havocbot_aim(this);
119         lag_update(this);
120
121         if (this.bot_aimtarg)
122         {
123                 this.aistatus |= AI_STATUS_ATTACKING;
124                 this.aistatus &= ~AI_STATUS_ROAMING;
125
126                 if(STAT(WEAPONS, this))
127                 {
128                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
129                         {
130                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
131                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
132                         }
133                         else
134                         {
135                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
136                                 {
137                                         .entity weaponentity = weaponentities[slot];
138                                         Weapon w = this.(weaponentity).m_weapon;
139                                         if(w == WEP_Null && slot != 0)
140                                                 continue;
141                                         w.wr_aim(w, this, weaponentity);
142                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
143                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
144                                 }
145                         }
146                 }
147                 else
148                 {
149                         if(IS_PLAYER(this.bot_aimtarg))
150                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
151                 }
152         }
153         else if (this.goalcurrent)
154         {
155                 this.aistatus |= AI_STATUS_ROAMING;
156                 this.aistatus &= ~AI_STATUS_ATTACKING;
157         }
158
159         havocbot_movetogoal(this);
160         if (!this.bot_aimdir_executed && this.goalcurrent)
161         {
162                 // Heading
163                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
164                 dir -= this.origin + this.view_ofs;
165                 dir.z = 0;
166                 bot_aimdir(this, dir, 0);
167         }
168
169         // if the bot is not attacking, consider reloading weapons
170         if (!(this.aistatus & AI_STATUS_ATTACKING))
171         {
172                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
173                 {
174                         .entity weaponentity = weaponentities[slot];
175
176                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
177                                 continue;
178
179                         // we are currently holding a weapon that's not fully loaded, reload it
180                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
181                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
182                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
183
184                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
185                         // the code above executes next frame, starting the reloading then
186                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
187                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
188                         {
189                                 FOREACH(Weapons, it != WEP_Null, {
190                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
191                                         {
192                                                 this.(weaponentity).m_switchweapon = it;
193                                                 break;
194                                         }
195                                 });
196                         }
197                 }
198         }
199 }
200
201 void havocbot_keyboard_movement(entity this, vector destorg)
202 {
203         if(time <= this.havocbot_keyboardtime)
204                 return;
205
206         float sk = skill + this.bot_moveskill;
207         this.havocbot_keyboardtime =
208                 max(
209                         this.havocbot_keyboardtime
210                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
211                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
212                 , time);
213         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
214
215         float trigger = autocvar_bot_ai_keyboard_threshold;
216
217         // categorize forward movement
218         // at skill < 1.5 only forward
219         // at skill < 2.5 only individual directions
220         // at skill < 4.5 only individual directions, and forward diagonals
221         // at skill >= 4.5, all cases allowed
222         if (keyboard.x > trigger)
223         {
224                 keyboard.x = 1;
225                 if (sk < 2.5)
226                         keyboard.y = 0;
227         }
228         else if (keyboard.x < -trigger && sk > 1.5)
229         {
230                 keyboard.x = -1;
231                 if (sk < 4.5)
232                         keyboard.y = 0;
233         }
234         else
235         {
236                 keyboard.x = 0;
237                 if (sk < 1.5)
238                         keyboard.y = 0;
239         }
240         if (sk < 4.5)
241                 keyboard.z = 0;
242
243         if (keyboard.y > trigger)
244                 keyboard.y = 1;
245         else if (keyboard.y < -trigger)
246                 keyboard.y = -1;
247         else
248                 keyboard.y = 0;
249
250         if (keyboard.z > trigger)
251                 keyboard.z = 1;
252         else if (keyboard.z < -trigger)
253                 keyboard.z = -1;
254         else
255                 keyboard.z = 0;
256
257         // make sure bots don't get stuck if havocbot_keyboardtime is very high
258         if (keyboard == '0 0 0')
259                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
260
261         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
262         if (this.havocbot_ducktime > time)
263                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
264
265         keyboard = this.havocbot_keyboard;
266         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
267         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
268         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
269 }
270
271 void havocbot_bunnyhop(entity this, vector dir)
272 {
273         // Don't jump when attacking
274         if(this.aistatus & AI_STATUS_ATTACKING)
275                 return;
276
277         if (!this.goalcurrent || IS_PLAYER(this.goalcurrent))
278                 return;
279
280         if((this.aistatus & AI_STATUS_RUNNING) && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
281                 || (this.aistatus & AI_STATUS_DANGER_AHEAD))
282         {
283                 this.aistatus &= ~AI_STATUS_RUNNING;
284                 PHYS_INPUT_BUTTON_JUMP(this) = false;
285                 this.bot_canruntogoal = 0;
286                 this.bot_timelastseengoal = 0;
287                 return;
288         }
289
290         if(this.waterlevel > WATERLEVEL_WETFEET || IS_DUCKED(this))
291         {
292                 this.aistatus &= ~AI_STATUS_RUNNING;
293                 return;
294         }
295
296         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
297         {
298                 this.bot_canruntogoal = 0;
299                 this.bot_timelastseengoal = 0;
300         }
301
302         // Run only to visible goals
303         if(IS_ONGROUND(this))
304         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed))
305         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
306         {
307                 this.bot_lastseengoal = this.goalcurrent;
308
309                 // seen it before
310                 if(this.bot_timelastseengoal)
311                 {
312                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
313                         // for a period of time
314                         if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
315                         {
316                                 bool checkdistance = true;
317
318                                 // don't run if it is too close
319                                 if(this.bot_canruntogoal==0)
320                                 {
321                                         if(vdist(this.origin - gco, >, autocvar_bot_ai_bunnyhop_startdistance))
322                                                 this.bot_canruntogoal = 1;
323                                         else
324                                                 this.bot_canruntogoal = -1;
325                                 }
326
327                                 if(this.bot_canruntogoal != 1)
328                                         return;
329
330                                 if(this.aistatus & AI_STATUS_ROAMING)
331                                 if(this.goalcurrent.classname == "waypoint")
332                                 if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
333                                 if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
334                                 if (this.goalstack01 && !wasfreed(this.goalstack01))
335                                 if (!(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP))
336                                 {
337                                         vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
338                                         vector deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
339                                         while (deviation.y < -180) deviation.y = deviation.y + 360;
340                                         while (deviation.y > 180) deviation.y = deviation.y - 360;
341
342                                         if(fabs(deviation.y) < 20)
343                                         if(vlen2(this.origin - gco) < vlen2(this.origin - gno))
344                                         if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
345                                         {
346                                                 if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
347                                                 if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
348                                                 {
349                                                         checkdistance = false;
350                                                 }
351                                         }
352                                 }
353
354                                 if(checkdistance)
355                                 {
356                                         this.aistatus &= ~AI_STATUS_RUNNING;
357                                         // increase stop distance in case the goal is on a slope or a lower platform
358                                         if(vdist(this.origin - gco, >, autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z)))
359                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
360                                 }
361                                 else
362                                 {
363                                         this.aistatus |= AI_STATUS_RUNNING;
364                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
365                                 }
366                         }
367                 }
368                 else
369                 {
370                         this.bot_timelastseengoal = time;
371                 }
372         }
373         else
374         {
375                 this.bot_timelastseengoal = 0;
376         }
377 }
378
379 // return true when bot isn't getting closer to the current goal
380 bool havocbot_checkgoaldistance(entity this, vector gco)
381 {
382         if (this.bot_stop_moving_timeout > time)
383                 return false;
384         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
385         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
386         float distance_time = this.goalcurrent_distance_time;
387         if(distance_time < 0)
388                 distance_time = -distance_time;
389         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
390         {
391                 if(!distance_time)
392                         this.goalcurrent_distance_time = time;
393                 else if (time - distance_time > 0.5)
394                         return true;
395         }
396         else
397         {
398                 // reduce it a little bit so it works even with very small approaches to the goal
399                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
400                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
401                 this.goalcurrent_distance_time = 0;
402         }
403         return false;
404 }
405
406 entity havocbot_select_an_item_of_group(entity this, int gr)
407 {
408         entity selected = NULL;
409         float selected_dist2 = 0;
410         // select farthest item of this group from bot's position
411         IL_EACH(g_items, it.item_group == gr && it.solid,
412         {
413                 float dist2 = vlen2(this.origin - it.origin);
414                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
415                 {
416                         selected = it;
417                         selected_dist2 = vlen2(this.origin - selected.origin);
418                 }
419         });
420
421         if (!selected)
422                 return NULL;
423
424         set_tracewalk_dest(selected, this.origin, false);
425         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
426                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
427         {
428                 return NULL;
429         }
430
431         return selected;
432 }
433
434 void havocbot_movetogoal(entity this)
435 {
436         vector diff;
437         vector dir;
438         vector flatdir;
439         vector evadeobstacle;
440         vector evadelava;
441         float dodge_enemy_factor = 1;
442         float maxspeed;
443         //float dist;
444         vector dodge;
445         //if (this.goalentity)
446         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
447         CS(this).movement = '0 0 0';
448         maxspeed = autocvar_sv_maxspeed;
449
450         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
451
452         PHYS_INPUT_BUTTON_JETPACK(this) = false;
453         // Jetpack navigation
454         if(this.navigation_jetpack_goal)
455         if(this.goalcurrent==this.navigation_jetpack_goal)
456         if(GetResource(this, RES_FUEL))
457         {
458                 if(autocvar_bot_debug_goalstack)
459                 {
460                         debuggoalstack(this);
461                         te_wizspike(this.navigation_jetpack_point);
462                 }
463
464                 // Take off
465                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
466                 {
467                         // Brake almost completely so it can get a good direction
468                         if(vdist(this.velocity, >, 10))
469                                 return;
470                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
471                 }
472
473                 makevectors(this.v_angle.y * '0 1 0');
474                 dir = normalize(this.navigation_jetpack_point - this.origin);
475
476                 // Landing
477                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
478                 {
479                         // Calculate brake distance in xy
480                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
481                         float vel2 = vlen2(vec2(this.velocity));
482                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
483                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
484                         if(d < db || d < 500)
485                         {
486                                 // Brake
487                                 if (vel2 > (maxspeed * 0.3) ** 2)
488                                 {
489                                         CS(this).movement_x = dir * v_forward * -maxspeed;
490                                         return;
491                                 }
492                                 // Switch to normal mode
493                                 this.navigation_jetpack_goal = NULL;
494                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
495                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
496                                 return;
497                         }
498                 }
499                 else if(checkpvs(this.origin,this.goalcurrent))
500                 {
501                         // If I can see the goal switch to landing code
502                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
503                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
504                         return;
505                 }
506
507                 // Flying
508                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
509                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
510                 {
511                         CS(this).movement_x = dir * v_forward * maxspeed;
512                         CS(this).movement_y = dir * v_right * maxspeed;
513                 }
514                 return;
515         }
516
517         // Handling of jump pads
518         if(this.jumppadcount)
519         {
520                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
521                 {
522                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
523                         if(navigation_poptouchedgoals(this))
524                                 return;
525                 }
526                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
527                 {
528                         // If got stuck on the jump pad try to reach the farthest visible waypoint
529                         // but with some randomness so it can try out different paths
530                         if(!this.goalcurrent)
531                         {
532                                 entity newgoal = NULL;
533                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
534                                 {
535                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
536                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
537                                                 continue;
538
539                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
540
541                                         if(trace_fraction < 1)
542                                                 continue;
543
544                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
545                                                 newgoal = it;
546                                 });
547
548                                 if(newgoal)
549                                 {
550                                         this.ignoregoal = this.goalcurrent;
551                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
552                                         navigation_clearroute(this);
553                                         navigation_routetogoal(this, newgoal, this.origin);
554                                         if(autocvar_bot_debug_goalstack)
555                                                 debuggoalstack(this);
556                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
557                                 }
558                         }
559                         else //if (this.goalcurrent)
560                         {
561                                 if (this.goalcurrent.bot_pickup)
562                                 {
563                                         entity jumppad_wp = this.goalcurrent_prev;
564                                         navigation_poptouchedgoals(this);
565                                         if(!this.goalcurrent && jumppad_wp.wp00)
566                                         {
567                                                 // head to the jumppad destination once bot reaches the goal item
568                                                 navigation_pushroute(this, jumppad_wp.wp00);
569                                         }
570                                 }
571                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
572                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
573                                 {
574                                         if (this.velocity.z < 0)
575                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
576                                 }
577                                 else if(havocbot_checkgoaldistance(this, gco))
578                                 {
579                                         navigation_clearroute(this);
580                                         navigation_goalrating_timeout_force(this);
581                                 }
582                                 else
583                                         return;
584                         }
585                 }
586                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
587                 {
588                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
589                         {
590                                 vector velxy = this.velocity; velxy_z = 0;
591                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
592                                 {
593                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
594                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
595                                 }
596                                 return;
597                         }
598
599                         // Don't chase players while using a jump pad
600                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
601                                 return;
602                 }
603         }
604         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
605                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
606
607         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
608         if (skill > 6 && !(IS_ONGROUND(this)))
609         {
610                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
611                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
612                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
613
614                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
615                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
616                 if(this.items & IT_JETPACK)
617                 {
618                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
619                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
620                         {
621                                 if(this.velocity.z<0)
622                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
623                         }
624                         else
625                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
626
627                         // If there is no goal try to move forward
628
629                         if(this.goalcurrent==NULL)
630                                 dir = v_forward;
631                         else
632                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
633
634                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
635                         float xyspeed = xyvelocity * dir;
636
637                         if(xyspeed < (maxspeed / 2))
638                         {
639                                 makevectors(this.v_angle.y * '0 1 0');
640                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
641                                 if(trace_fraction==1)
642                                 {
643                                         CS(this).movement_x = dir * v_forward * maxspeed;
644                                         CS(this).movement_y = dir * v_right * maxspeed;
645                                         if (skill < 10)
646                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
647                                 }
648                         }
649
650                         this.havocbot_blockhead = true;
651
652                         return;
653                 }
654                 else if(!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
655                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
656                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
657                 {
658                         if(this.velocity.z < 0)
659                         {
660                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
661                                 {
662                                         .entity weaponentity = weaponentities[slot];
663
664                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
665                                                 continue;
666
667                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
668                                         {
669                                                 CS(this).movement_x = maxspeed;
670
671                                                 if(this.rocketjumptime)
672                                                 {
673                                                         if(time > this.rocketjumptime)
674                                                         {
675                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
676                                                                 this.rocketjumptime = 0;
677                                                         }
678                                                         return;
679                                                 }
680
681                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
682                                                 this.v_angle_x = 90;
683                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
684                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
685                                                 return;
686                                         }
687                                 }
688                         }
689                 }
690                 else
691                 {
692                         // If there is no goal try to move forward
693                         if(this.goalcurrent==NULL)
694                                 CS(this).movement_x = maxspeed;
695                 }
696         }
697
698         // If we are under water with no goals, swim up
699         if(this.waterlevel && !this.goalcurrent)
700         {
701                 dir = '0 0 0';
702                 if(this.waterlevel>WATERLEVEL_SWIMMING)
703                         dir.z = 1;
704                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
705                         PHYS_INPUT_BUTTON_JUMP(this) = true;
706                 else
707                         PHYS_INPUT_BUTTON_JUMP(this) = false;
708                 makevectors(this.v_angle.y * '0 1 0');
709                 vector v = dir * maxspeed;
710                 CS(this).movement.x = v * v_forward;
711                 CS(this).movement.y = v * v_right;
712                 CS(this).movement.z = v * v_up;
713         }
714
715         // if there is nowhere to go, exit
716         if (this.goalcurrent == NULL)
717                 return;
718
719
720         bool locked_goal = false;
721         if((this.goalentity && wasfreed(this.goalentity))
722                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
723         {
724                 navigation_clearroute(this);
725                 navigation_goalrating_timeout_force(this);
726                 return;
727         }
728         else if(this.goalentity.tag_entity)
729         {
730                 navigation_goalrating_timeout_expire(this, 2);
731         }
732         else if(this.goalentity.bot_pickup)
733         {
734                 if(this.goalentity.bot_pickup_respawning)
735                 {
736                         if(this.goalentity.solid) // item respawned
737                                 this.goalentity.bot_pickup_respawning = false;
738                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
739                         {
740                                 if(checkpvs(this.origin, this.goalentity))
741                                 {
742                                         this.goalentity.bot_pickup_respawning = false;
743                                         navigation_goalrating_timeout_expire(this, random());
744                                 }
745                                 locked_goal = true; // wait for item to respawn
746                         }
747                         else if(this.goalentity == this.goalcurrent)
748                                 locked_goal = true; // wait for item to respawn
749                 }
750                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
751                 {
752                         if(checkpvs(this.origin, this.goalentity))
753                         {
754                                 navigation_goalrating_timeout_expire(this, random());
755                         }
756                 }
757         }
758         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
759                 locked_goal = true;
760
761         if (navigation_shortenpath(this))
762         {
763                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
764                         && navigation_goalrating_timeout_can_be_anticipated(this))
765                 {
766                         navigation_goalrating_timeout_force(this);
767                 }
768         }
769
770         bool goalcurrent_can_be_removed = false;
771         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
772         {
773                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
774                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
775                 {
776                         goalcurrent_can_be_removed = true;
777                         // don't remove if not visible
778                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
779                         {
780                                 if (IS_DEAD(this.goalcurrent))
781                                 {
782                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
783                                         {
784                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
785                                                 {
786                                                         navigation_clearroute(this);
787                                                         navigation_pushroute(this, it);
788                                                         // loot can't be immediately rated since it isn't on ground yet
789                                                         // it will be rated after a second when on ground, meanwhile head to it
790                                                         navigation_goalrating_timeout_expire(this, 1);
791                                                         return;
792                                                 }
793                                         });
794                                 }
795                                 if (!Item_IsLoot(this.goalcurrent))
796                                 {
797                                         navigation_goalrating_timeout_force(this);
798                                         return;
799                                 }
800                         }
801                 }
802                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
803                 {
804                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
805                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
806                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
807                         {
808                                 navigation_goalrating_timeout_force(this);
809                                 return;
810                         }
811                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
812                 }
813         }
814
815         if(!locked_goal)
816         {
817                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
818                 // in this case path finding can start directly from a waypoint instead of
819                 // looking for all the reachable waypoints up to a certain distance
820                 if (navigation_poptouchedgoals(this))
821                 {
822                         if (this.goalcurrent)
823                         {
824                                 if (goalcurrent_can_be_removed)
825                                 {
826                                         // remove even if not visible
827                                         navigation_goalrating_timeout_force(this);
828                                         return;
829                                 }
830                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
831                                         navigation_goalrating_timeout_force(this);
832                         }
833                         else
834                         {
835                                 entity old_goal = this.goalcurrent_prev;
836                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
837                                 {
838                                         // Avoid multiple costly calls of path finding code that selects one of the closest
839                                         // item of the group by telling the bot to head directly to the farthest item.
840                                         // Next time we let the bot select a goal as usual which can be another item
841                                         // of this group (the closest one) and so on
842                                         this.item_group = old_goal.item_group;
843                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
844                                         if (new_goal)
845                                                 navigation_pushroute(this, new_goal);
846                                 }
847                         }
848                 }
849         }
850
851         // if ran out of goals try to use an alternative goal or get a new strategy asap
852         if(this.goalcurrent == NULL)
853         {
854                 navigation_goalrating_timeout_force(this);
855                 return;
856         }
857
858
859         if(autocvar_bot_debug_goalstack)
860                 debuggoalstack(this);
861
862         bool bunnyhop_forbidden = false;
863         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
864         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
865         {
866                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
867                 destorg = this.goalcurrent.origin;
868         }
869         else if (this.goalcurrent.wpisbox)
870         {
871                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
872                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
873                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
874                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
875                 {
876                         bunnyhop_forbidden = true;
877                         destorg = this.goalcurrent.origin;
878                         if(destorg.z > this.origin.z)
879                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
880                 }
881         }
882
883         diff = destorg - this.origin;
884
885         if (time < this.bot_stop_moving_timeout
886                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
887         {
888                 // stop if the locked goal has been reached
889                 destorg = this.origin;
890                 diff = dir = '0 0 0';
891         }
892         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
893         {
894                 if (vdist(diff, <, 80))
895                 {
896                         // stop if too close to target player (even if frozen)
897                         destorg = this.origin;
898                         diff = dir = '0 0 0';
899                 }
900                 else
901                 {
902                         // move destorg out of target players, otherwise bot will consider them
903                         // an obstacle that needs to be jumped (especially if frozen)
904                         dir = normalize(diff);
905                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
906                         diff = destorg - this.origin;
907                 }
908         }
909         else
910                 dir = normalize(diff);
911         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
912
913         //if (this.bot_dodgevector_time < time)
914         {
915                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
916                 //this.bot_dodgevector_jumpbutton = 1;
917                 evadeobstacle = '0 0 0';
918                 evadelava = '0 0 0';
919
920                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
921                 makevectors(this.v_angle.y * '0 1 0');
922                 if (this.waterlevel > WATERLEVEL_WETFEET)
923                 {
924                         if (this.waterlevel > WATERLEVEL_SWIMMING)
925                         {
926                                 if(!this.goalcurrent)
927                                         this.aistatus |= AI_STATUS_OUT_WATER;
928                                 else if(destorg.z > this.origin.z)
929                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
930                         }
931                         else
932                         {
933                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
934                                         (this.aistatus & AI_STATUS_OUT_WATER))
935                                 {
936                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
937                                         dir = flatdir;
938                                 }
939                                 else
940                                 {
941                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
942                                         if (destorg.z > this.origin.z)
943                                                 dir = flatdir;
944                                 }
945                         }
946                 }
947                 else
948                 {
949                         float s;
950                         vector offset;
951                         if(this.aistatus & AI_STATUS_OUT_WATER)
952                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
953
954                         // jump if going toward an obstacle that doesn't look like stairs we
955                         // can walk up directly
956                         vector deviation = '0 0 0';
957                         float current_speed = vlen(vec2(this.velocity));
958                         if (current_speed < maxspeed * 0.2)
959                                 current_speed = maxspeed * 0.2;
960                         else
961                         {
962                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
963                                 while (deviation.y < -180) deviation.y += 360;
964                                 while (deviation.y > 180) deviation.y -= 360;
965                         }
966                         float turning = false;
967                         vector flat_diff = vec2(diff);
968                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
969                         vector actual_destorg = this.origin + offset;
970                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
971                         {
972                                 if (time > this.bot_stop_moving_timeout
973                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
974                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
975                                 {
976                                         this.bot_stop_moving_timeout = time + 0.1;
977                                 }
978                                 if (current_speed > autocvar_sv_maxspeed * 0.9
979                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
980                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
981                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
982                                 )
983                                 {
984                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
985                                         // avoid changing route while bot is jumping a gap
986                                         navigation_goalrating_timeout_extend_if_needed(this, 1.5);
987                                 }
988                         }
989                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
990                         {
991                                 if (vlen2(flat_diff) < vlen2(offset))
992                                 {
993                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
994                                         {
995                                                 // oblique warpzones need a jump otherwise bots gets stuck
996                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
997                                         }
998                                         else
999                                         {
1000                                                 actual_destorg.x = destorg.x;
1001                                                 actual_destorg.y = destorg.y;
1002                                         }
1003                                 }
1004                         }
1005                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
1006                         {
1007                                 actual_destorg.x = destorg.x;
1008                                 actual_destorg.y = destorg.y;
1009                         }
1010                         else if (vlen2(flat_diff) < vlen2(offset))
1011                         {
1012                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1013                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
1014                                 float dist = vlen(vec2(this.origin + offset - destorg));
1015                                 // if current and next goal are close to each other make sure
1016                                 // actual_destorg isn't set beyond next_goal_org
1017                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
1018                                         actual_destorg = next_goal_org;
1019                                 else
1020                                         actual_destorg = vec2(destorg) + dist * next_dir;
1021                                 actual_destorg.z = this.origin.z;
1022                                 turning = true;
1023                         }
1024
1025                         LABEL(jumpobstacle_check);
1026                         dir = flatdir = normalize(actual_destorg - this.origin);
1027
1028                         bool jump_forbidden = false;
1029                         if (!turning && fabs(deviation.y) > 50)
1030                                 jump_forbidden = true;
1031                         else if (IS_DUCKED(this))
1032                         {
1033                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
1034                                 if (trace_startsolid)
1035                                         jump_forbidden = true;
1036                         }
1037
1038                         if (!jump_forbidden)
1039                         {
1040                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1041                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1042                                 {
1043                                         s = trace_fraction;
1044                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1045                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1046                                         {
1047                                                 // found an obstacle
1048                                                 if (turning && fabs(deviation.y) > 5)
1049                                                 {
1050                                                         // check if the obstacle is still there without turning
1051                                                         actual_destorg = destorg;
1052                                                         turning = false;
1053                                                         this.bot_tracewalk_time = time + 0.25;
1054                                                         goto jumpobstacle_check;
1055                                                 }
1056                                                 s = trace_fraction;
1057                                                 // don't artificially reduce max jump height in real-time
1058                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1059                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1060                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1061                                                 if (trace_fraction > s)
1062                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1063                                                 else
1064                                                 {
1065                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1066                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1067                                                         if (trace_fraction > s)
1068                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1069                                                 }
1070                                         }
1071                                 }
1072                         }
1073
1074                         // if bot for some reason doesn't get close to the current goal find another one
1075                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1076                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1077                         if(havocbot_checkgoaldistance(this, destorg))
1078                         {
1079                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1080                                 {
1081                                         navigation_clearroute(this);
1082                                         navigation_goalrating_timeout_force(this);
1083                                         return;
1084                                 }
1085
1086                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1087                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1088                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1089                                 {
1090                                         navigation_clearroute(this);
1091                                         navigation_goalrating_timeout_force(this);
1092                                         return;
1093                                 }
1094
1095                                 // give bot only another chance to prevent bot getting stuck
1096                                 // in case it thinks it can walk but actually can't
1097                                 this.goalcurrent_distance_z = FLOAT_MAX;
1098                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1099                                 this.goalcurrent_distance_time = -time; // mark second try
1100                         }
1101
1102                         // Check for water/slime/lava and dangerous edges
1103                         // (only when the bot is on the ground or jumping intentionally)
1104
1105                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1106                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1107                         {
1108                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1109                         }
1110
1111                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1112                         vector dst_ahead = this.origin + this.view_ofs + offset;
1113                         vector dst_down = dst_ahead - '0 0 3000';
1114                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1115
1116                         bool unreachable = false;
1117                         s = CONTENT_SOLID;
1118                         if (trace_fraction == 1 && !this.jumppadcount
1119                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1120                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1121                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1122                         {
1123                                 // Look downwards
1124                                 traceline(dst_ahead , dst_down, true, NULL);
1125                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1126                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1127                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1128                                 {
1129                                         s = pointcontents(trace_endpos + '0 0 1');
1130                                         if (s != CONTENT_SOLID)
1131                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1132                                                 evadelava = normalize(this.velocity) * -1;
1133                                         else if (s == CONTENT_SKY)
1134                                                 evadeobstacle = normalize(this.velocity) * -1;
1135                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1136                                         {
1137                                                 // the traceline check isn't enough but is good as optimization,
1138                                                 // when not true (most of the time) this tracebox call is avoided
1139                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1140                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1141                                                 {
1142                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1143                                                         {
1144                                                                 // the goal is probably on an upper platform, assume bot can't get there
1145                                                                 unreachable = true;
1146                                                         }
1147                                                         else
1148                                                                 evadelava = normalize(this.velocity) * -1;
1149                                                 }
1150                                         }
1151                                 }
1152                         }
1153
1154                         dir = flatdir;
1155                         evadeobstacle.z = 0;
1156                         evadelava.z = 0;
1157                         makevectors(this.v_angle.y * '0 1 0');
1158
1159                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1160                         {
1161                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1162                                 if(IS_PLAYER(this.goalcurrent))
1163                                         unreachable = true;
1164                         }
1165
1166                         // slow down if bot is in the air and goal is under it
1167                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1168                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1169                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1170                         {
1171                                 // tracebox wouldn't work when bot is still on the ledge
1172                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1173                                 if (this.origin.z - trace_endpos.z > 120)
1174                                         evadeobstacle = normalize(this.velocity) * -1;
1175                         }
1176
1177                         if(unreachable)
1178                         {
1179                                 navigation_clearroute(this);
1180                                 navigation_goalrating_timeout_force(this);
1181                                 this.ignoregoal = this.goalcurrent;
1182                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1183                         }
1184                 }
1185
1186                 dodge = havocbot_dodge(this);
1187                 if (dodge)
1188                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1189                 dodge += evadeobstacle + evadelava;
1190                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1191                 if (this.enemy)
1192                 {
1193                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1194                         if (IS_PLAYER(trace_ent))
1195                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1196                 }
1197         //      this.bot_dodgevector = dir;
1198         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1199         }
1200
1201         float ladder_zdir = 0;
1202         if(time < this.ladder_time)
1203         {
1204                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1205                 {
1206                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1207                                 ladder_zdir = 1;
1208                 }
1209                 else
1210                 {
1211                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1212                                 ladder_zdir = -1;
1213                 }
1214                 if (ladder_zdir)
1215                 {
1216                         if (vdist(vec2(diff), <, 40))
1217                                 dir.z = ladder_zdir * 4;
1218                         else
1219                                 dir.z = ladder_zdir * 2;
1220                         dir = normalize(dir);
1221                 }
1222         }
1223
1224         if (this.goalcurrent.wpisbox
1225                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1226         {
1227                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1228                 // head to teleport origin
1229                 dir = (this.goalcurrent.origin - this.origin);
1230                 dir.z = 0;
1231                 dir = normalize(dir);
1232         }
1233
1234         // already executed when bot targets an enemy
1235         if (!this.bot_aimdir_executed)
1236         {
1237                 if (time < this.bot_stop_moving_timeout)
1238                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1239                 else
1240                         bot_aimdir(this, dir, 0);
1241         }
1242
1243         if (!ladder_zdir)
1244         {
1245                 dir *= dodge_enemy_factor;
1246                 dir = normalize(dir + dodge);
1247         }
1248
1249         makevectors(this.v_angle);
1250         //dir = this.bot_dodgevector;
1251         //if (this.bot_dodgevector_jumpbutton)
1252         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1253         CS(this).movement_x = dir * v_forward * maxspeed;
1254         CS(this).movement_y = dir * v_right * maxspeed;
1255         CS(this).movement_z = dir * v_up * maxspeed;
1256
1257         // Emulate keyboard interface
1258         if (skill < 10)
1259                 havocbot_keyboard_movement(this, destorg);
1260
1261         // Bunnyhop!
1262         if (!bunnyhop_forbidden && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1263                 havocbot_bunnyhop(this, dir);
1264
1265         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1266                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1267         if (dodge)
1268         {
1269                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1270                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1271                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1272                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1273         }
1274 }
1275
1276 entity havocbot_gettarget(entity this, bool secondary)
1277 {
1278         entity best = NULL;
1279         vector eye = CENTER_OR_VIEWOFS(this);
1280         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1281         {
1282                 vector v = CENTER_OR_VIEWOFS(it);
1283                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1284                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1285                 if(bot_shouldattack(this, it))
1286                 {
1287                         traceline(eye, v, true, this);
1288                         if (trace_ent == it || trace_fraction >= 1)
1289                                 best = it;
1290                 }
1291         });
1292
1293         return best;
1294 }
1295
1296 void havocbot_chooseenemy(entity this)
1297 {
1298         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1299         {
1300                 this.enemy = NULL;
1301                 return;
1302         }
1303         if (this.enemy)
1304         {
1305                 if (!bot_shouldattack(this, this.enemy))
1306                 {
1307                         // enemy died or something, find a new target
1308                         this.enemy = NULL;
1309                         this.havocbot_chooseenemy_finished = time;
1310                 }
1311                 else if (this.havocbot_stickenemy)
1312                 {
1313                         // tracking last chosen enemy
1314                         // if enemy is visible
1315                         // and not really really far away
1316                         // and we're not severely injured
1317                         // then keep tracking for a half second into the future
1318                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1319                         if (trace_ent == this.enemy || trace_fraction == 1)
1320                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1321                         if (GetResource(this, RES_HEALTH) > 30)
1322                         {
1323                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1324                                 this.havocbot_chooseenemy_finished = time + 0.5;
1325                                 return;
1326                         }
1327                         // enemy isn't visible, or is far away, or we're injured severely
1328                         // so stop preferring this enemy
1329                         // (it will still take a half second until a new one is chosen)
1330                         this.havocbot_stickenemy = 0;
1331                 }
1332         }
1333         if (time < this.havocbot_chooseenemy_finished)
1334                 return;
1335         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1336         vector eye = this.origin + this.view_ofs;
1337         entity best = NULL;
1338         float bestrating = 100000000;
1339
1340         // Backup hit flags
1341         int hf = this.dphitcontentsmask;
1342
1343         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1344
1345         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1346
1347         bool scan_transparent = false;
1348         bool scan_secondary_targets = false;
1349         bool have_secondary_targets = false;
1350         while(true)
1351         {
1352                 scan_secondary_targets = false;
1353 LABEL(scan_targets)
1354                 IL_EACH(g_bot_targets, it.bot_attack,
1355                 {
1356                         if(!scan_secondary_targets)
1357                         {
1358                                 if(it.classname == "misc_breakablemodel")
1359                                 {
1360                                         have_secondary_targets = true;
1361                                         continue;
1362                                 }
1363                         }
1364                         else if(it.classname != "misc_breakablemodel")
1365                                 continue;
1366
1367                         vector v = (it.absmin + it.absmax) * 0.5;
1368                         float rating = vlen2(v - eye);
1369                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1370                         if (bestrating > rating)
1371                         if (bot_shouldattack(this, it))
1372                         {
1373                                 traceline(eye, v, true, this);
1374                                 if (trace_ent == it || trace_fraction >= 1)
1375                                 {
1376                                         best = it;
1377                                         bestrating = rating;
1378                                 }
1379                         }
1380                 });
1381
1382                 if(!best && have_secondary_targets && !scan_secondary_targets)
1383                 {
1384                         scan_secondary_targets = true;
1385                         // restart the loop
1386                         bestrating = 100000000;
1387                         goto scan_targets;
1388                 }
1389
1390                 // I want to do a second scan if no enemy was found or I don't have weapons
1391                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1392                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1393                         break;
1394                 if(scan_transparent)
1395                         break;
1396
1397                 // Set flags to see through transparent objects
1398                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1399
1400                 scan_transparent = true;
1401         }
1402
1403         // Restore hit flags
1404         this.dphitcontentsmask = hf;
1405
1406         this.enemy = best;
1407         this.havocbot_stickenemy = true;
1408         if(best && best.classname == "misc_breakablemodel")
1409                 this.havocbot_stickenemy = false;
1410 }
1411
1412 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1413 {
1414         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1415         // so skip this for them, or they'll never get to reload their weapons at all.
1416         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1417         if(skill < 5)
1418                 return false;
1419
1420         // if this weapon is scheduled for reloading, don't switch to it during combat
1421         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1422         {
1423                 FOREACH(Weapons, it != WEP_Null, {
1424                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1425                                 return true; // other weapon available
1426                 });
1427         }
1428
1429         return false;
1430 }
1431
1432 void havocbot_chooseweapon(entity this, .entity weaponentity)
1433 {
1434         int i;
1435
1436         // ;)
1437         if(g_weaponarena_weapons == WEPSET(TUBA))
1438         {
1439                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1440                 return;
1441         }
1442
1443         // TODO: clean this up by moving it to weapon code
1444         if(this.enemy==NULL)
1445         {
1446                 // If no weapon was chosen get the first available weapon
1447                 if(this.(weaponentity).m_weapon==WEP_Null)
1448                 FOREACH(Weapons, it != WEP_Null, {
1449                         if(client_hasweapon(this, it, weaponentity, true, false))
1450                         {
1451                                 this.(weaponentity).m_switchweapon = it;
1452                                 return;
1453                         }
1454                 });
1455                 return;
1456         }
1457
1458         // Do not change weapon during the next second after a combo
1459         float f = time - this.lastcombotime;
1460         if(f < 1)
1461                 return;
1462
1463         float w;
1464         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1465
1466         // Should it do a weapon combo?
1467         float af, ct, combo_time, combo;
1468
1469         af = ATTACK_FINISHED(this, weaponentity);
1470         ct = autocvar_bot_ai_weapon_combo_threshold;
1471
1472         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1473         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1474         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1475
1476         combo = false;
1477
1478         if(autocvar_bot_ai_weapon_combo)
1479         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1480         if(af > combo_time)
1481         {
1482                 combo = true;
1483                 this.lastcombotime = time;
1484         }
1485
1486         distance *= (2 ** this.bot_rangepreference);
1487
1488         // Custom weapon list based on distance to the enemy
1489         if(bot_custom_weapon){
1490
1491                 // Choose weapons for far distance
1492                 if ( distance > bot_distance_far ) {
1493                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1494                                 w = bot_weapons_far[i];
1495                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1496                                 {
1497                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1498                                                 continue;
1499                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1500                                         return;
1501                                 }
1502                         }
1503                 }
1504
1505                 // Choose weapons for mid distance
1506                 if ( distance > bot_distance_close) {
1507                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1508                                 w = bot_weapons_mid[i];
1509                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1510                                 {
1511                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1512                                                 continue;
1513                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1514                                         return;
1515                                 }
1516                         }
1517                 }
1518
1519                 // Choose weapons for close distance
1520                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1521                         w = bot_weapons_close[i];
1522                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1523                         {
1524                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1525                                         continue;
1526                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1527                                 return;
1528                         }
1529                 }
1530         }
1531 }
1532
1533 void havocbot_aim(entity this)
1534 {
1535         if (time < this.nextaim)
1536                 return;
1537         this.nextaim = time + 0.1;
1538         vector myvel = this.velocity;
1539         if (!this.waterlevel)
1540                 myvel.z = 0;
1541         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1542         else if (this.enemy)
1543         {
1544                 vector enemyvel = this.enemy.velocity;
1545                 if (!this.enemy.waterlevel)
1546                         enemyvel.z = 0;
1547                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1548         }
1549         else
1550                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1551 }
1552
1553 bool havocbot_moveto_refresh_route(entity this)
1554 {
1555         // Refresh path to goal if necessary
1556         entity wp;
1557         wp = this.havocbot_personal_waypoint;
1558         navigation_goalrating_start(this);
1559         navigation_routerating(this, wp, 10000, 10000);
1560         navigation_goalrating_end(this);
1561         return (this.goalentity != NULL);
1562 }
1563
1564 float havocbot_moveto(entity this, vector pos)
1565 {
1566         entity wp;
1567
1568         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1569         {
1570                 // Step 4: Move to waypoint
1571                 if(this.havocbot_personal_waypoint==NULL)
1572                 {
1573                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1574                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1575                         return CMD_STATUS_ERROR;
1576                 }
1577
1578                 if (!bot_strategytoken_taken)
1579                 if(this.havocbot_personal_waypoint_searchtime<time)
1580                 {
1581                         bot_strategytoken_taken = true;
1582                         if(havocbot_moveto_refresh_route(this))
1583                         {
1584                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1585                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1586                                 this.havocbot_personal_waypoint_failcounter = 0;
1587                         }
1588                         else
1589                         {
1590                                 this.havocbot_personal_waypoint_failcounter += 1;
1591                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1592                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1593                                 {
1594                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1595                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1596                                         delete(this.havocbot_personal_waypoint);
1597                                         return CMD_STATUS_ERROR;
1598                                 }
1599                                 else
1600                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1601                         }
1602                 }
1603
1604                 if(autocvar_bot_debug_goalstack)
1605                         debuggoalstack(this);
1606
1607
1608                 // Go!
1609                 havocbot_movetogoal(this);
1610
1611                 if (!this.bot_aimdir_executed && this.goalcurrent)
1612                 {
1613                         // Heading
1614                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1615                         dir -= this.origin + this.view_ofs;
1616                         dir.z = 0;
1617                         bot_aimdir(this, dir, 0);
1618                 }
1619
1620                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1621                 {
1622                         // Step 5: Waypoint reached
1623                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1624                         waypoint_remove(this.havocbot_personal_waypoint);
1625                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1626                         return CMD_STATUS_FINISHED;
1627                 }
1628
1629                 return CMD_STATUS_EXECUTING;
1630         }
1631
1632         // Step 2: Linking waypoint
1633         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1634         {
1635                 // Wait until it is linked
1636                 if(!this.havocbot_personal_waypoint.wplinked)
1637                 {
1638                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1639                         return CMD_STATUS_EXECUTING;
1640                 }
1641
1642                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1643                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1644                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1645
1646                 // Step 3: Route to waypoint
1647                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1648
1649                 return CMD_STATUS_EXECUTING;
1650         }
1651
1652         // Step 1: Spawning waypoint
1653         wp = waypoint_spawnpersonal(this, pos);
1654         if(wp==NULL)
1655         {
1656                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1657                 return CMD_STATUS_ERROR;
1658         }
1659
1660         this.havocbot_personal_waypoint = wp;
1661         this.havocbot_personal_waypoint_failcounter = 0;
1662         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1663
1664         // if pos is inside a teleport, then let's mark it as teleport waypoint
1665         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1666         {
1667                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1668                 this.lastteleporttime = 0;
1669         });
1670
1671 /*
1672         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1673                 print("routing to a teleporter\n");
1674         else
1675                 print("routing to a non-teleporter\n");
1676 */
1677
1678         return CMD_STATUS_EXECUTING;
1679 }
1680
1681 float havocbot_resetgoal(entity this)
1682 {
1683         navigation_clearroute(this);
1684         return CMD_STATUS_FINISHED;
1685 }
1686
1687 void havocbot_setupbot(entity this)
1688 {
1689         this.bot_ai = havocbot_ai;
1690         this.cmd_moveto = havocbot_moveto;
1691         this.cmd_resetgoal = havocbot_resetgoal;
1692
1693         // NOTE: bot is not player yet
1694         havocbot_chooserole(this);
1695 }
1696
1697 vector havocbot_dodge(entity this)
1698 {
1699         // LordHavoc: disabled because this is too expensive
1700         return '0 0 0';
1701 #if 0
1702         entity head;
1703         vector dodge, v, n;
1704         float danger, bestdanger, vl, d;
1705         dodge = '0 0 0';
1706         bestdanger = -20;
1707         // check for dangerous objects near bot or approaching bot
1708         head = findchainfloat(bot_dodge, true);
1709         while(head)
1710         {
1711                 if (head.owner != this)
1712                 {
1713                         vl = vlen(head.velocity);
1714                         if (vl > autocvar_sv_maxspeed * 0.3)
1715                         {
1716                                 n = normalize(head.velocity);
1717                                 v = this.origin - head.origin;
1718                                 d = v * n;
1719                                 if (d > (0 - head.bot_dodgerating))
1720                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1721                                 {
1722                                         // calculate direction and distance from the flight path, by removing the forward axis
1723                                         v = v - (n * (v * n));
1724                                         danger = head.bot_dodgerating - vlen(v);
1725                                         if (bestdanger < danger)
1726                                         {
1727                                                 bestdanger = danger;
1728                                                 // dodge to the side of the object
1729                                                 dodge = normalize(v);
1730                                         }
1731                                 }
1732                         }
1733                         else
1734                         {
1735                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1736                                 if (bestdanger < danger)
1737                                 {
1738                                         bestdanger = danger;
1739                                         dodge = normalize(this.origin - head.origin);
1740                                 }
1741                         }
1742                 }
1743                 head = head.chain;
1744         }
1745         return dodge;
1746 #endif
1747 }