qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/defs.qh>
   6 #include <server/miscfunctions.qh>
   7 #include "../cvars.qh"
   8
   9 #include "../aim.qh"
  10 #include "../bot.qh"
  11 #include "../navigation.qh"
  12 #include "../scripting.qh"
  13 #include "../waypoints.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/impulses/all.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19 #include <common/state.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/wepent.qh>
  22
  23 #include <common/mapobjects/func/ladder.qh>
  24 #include <common/mapobjects/teleporters.qh>
  25 #include <common/mapobjects/trigger/jumppads.qh>
  26
  27 #include <lib/warpzone/common.qh>
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this)
  51                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
  52                         {
  53                                 // find a new goal
  54                                 this.havocbot_role(this); // little too far down the rabbit hole
  55                         }
  56                 }
  57
  58                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  59                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  60                 if(!this.goalcurrent)
  61                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  62                 {
  63                         // Look for the closest waypoint out of water
  64                         entity newgoal = NULL;
  65                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  66                         {
  67                                 if(it.origin.z < this.origin.z)
  68                                         continue;
  69
  70                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  71                                         continue;
  72
  73                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  74                                         continue;
  75
  76                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  77
  78                                 if(trace_fraction < 1)
  79                                         continue;
  80
  81                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  82                                         newgoal = it;
  83                         });
  84
  85                         if(newgoal)
  86                         {
  87                         //      te_wizspike(newgoal.origin);
  88                                 navigation_pushroute(this, newgoal);
  89                         }
  90                 }
  91
  92                 // token has been used this frame
  93                 bot_strategytoken_taken = true;
  94         }
  95
  96         if (this.goalcurrent && wasfreed(this.goalcurrent))
  97         {
  98                 navigation_clearroute(this);
  99                 navigation_goalrating_timeout_force(this);
 100                 return;
 101         }
 102
 103         if(IS_DEAD(this) || STAT(FROZEN, this))
 104         {
 105                 if (this.goalcurrent)
 106                         navigation_clearroute(this);
 107                 return;
 108         }
 109
 110         havocbot_chooseenemy(this);
 111
 112         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 113         {
 114                 .entity weaponentity = weaponentities[slot];
 115                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 116                 if(this.(weaponentity).bot_chooseweapontime < time)
 117                 {
 118                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 119                         havocbot_chooseweapon(this, weaponentity);
 120                 }
 121         }
 122         havocbot_aim(this);
 123         lag_update(this);
 124
 125         if (this.bot_aimtarg)
 126         {
 127                 this.aistatus |= AI_STATUS_ATTACKING;
 128                 this.aistatus &= ~AI_STATUS_ROAMING;
 129
 130                 if(STAT(WEAPONS, this))
 131                 {
 132                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 133                         {
 134                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 135                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 136                         }
 137                         else
 138                         {
 139                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 140                                 {
 141                                         .entity weaponentity = weaponentities[slot];
 142                                         Weapon w = this.(weaponentity).m_weapon;
 143                                         if(w == WEP_Null && slot != 0)
 144                                                 continue;
 145                                         w.wr_aim(w, this, weaponentity);
 146                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 147                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 148                                 }
 149                         }
 150                 }
 151                 else
 152                 {
 153                         if(IS_PLAYER(this.bot_aimtarg))
 154                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 155                 }
 156         }
 157         else if (this.goalcurrent)
 158         {
 159                 this.aistatus |= AI_STATUS_ROAMING;
 160                 this.aistatus &= ~AI_STATUS_ATTACKING;
 161         }
 162
 163         havocbot_movetogoal(this);
 164         if (!this.bot_aimdir_executed && this.goalcurrent)
 165         {
 166                 // Heading
 167                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 168                 dir -= this.origin + this.view_ofs;
 169                 dir.z = 0;
 170                 bot_aimdir(this, dir, 0);
 171         }
 172
 173         // if the bot is not attacking, consider reloading weapons
 174         if (!(this.aistatus & AI_STATUS_ATTACKING))
 175         {
 176                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 177                 {
 178                         .entity weaponentity = weaponentities[slot];
 179
 180                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 181                                 continue;
 182
 183                         // we are currently holding a weapon that's not fully loaded, reload it
 184                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 185                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 186                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 187
 188                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 189                         // the code above executes next frame, starting the reloading then
 190                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 191                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 192                         {
 193                                 FOREACH(Weapons, it != WEP_Null, {
 194                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 195                                         {
 196                                                 this.(weaponentity).m_switchweapon = it;
 197                                                 break;
 198                                         }
 199                                 });
 200                         }
 201                 }
 202         }
 203 }
 204
 205 void havocbot_bunnyhop(entity this, vector dir)
 206 {
 207         bool can_run = false;
 208         if (!(this.aistatus & AI_STATUS_ATTACKING) && this.goalcurrent && !IS_PLAYER(this.goalcurrent)
 209                 && vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed) && !(this.aistatus & AI_STATUS_DANGER_AHEAD)
 210                 && this.waterlevel <= WATERLEVEL_WETFEET && !IS_DUCKED(this)
 211                 && IS_ONGROUND(this) && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
 212         {
 213                 vector vel_angles = vectoangles(this.velocity);
 214                 vector deviation = vel_angles - vectoangles(dir);
 215                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 216                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 217                 if (fabs(deviation.y) < autocvar_bot_ai_bunnyhop_dir_deviation_max)
 218                 {
 219                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 220                         float vel = vlen(vec2(this.velocity));
 221
 222                         // with the current physics, jump distance grows linearly with the speed
 223                         float jump_distance = 52.661 + 0.606 * vel;
 224                         jump_distance += this.origin.z - gco.z; // roughly take into account vertical distance too
 225                         if (vdist(vec2(gco - this.origin), >, max(0, jump_distance)))
 226                                 can_run = true;
 227                         else if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP)
 228                                 && !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 229                                 && this.goalstack01 && !wasfreed(this.goalstack01) && !(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP)
 230                                 && vdist(vec2(gco - this.goalstack01.origin), >, 70))
 231                         {
 232                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 233                                 vector ang = vectoangles(gco - this.origin);
 234                                 deviation = vectoangles(gno - gco) - vel_angles;
 235                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 236                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 237
 238                                 float max_turn_angle = autocvar_bot_ai_bunnyhop_turn_angle_max;
 239                                 max_turn_angle -= autocvar_bot_ai_bunnyhop_turn_angle_reduction * ((vel - autocvar_sv_maxspeed) / autocvar_sv_maxspeed);
 240                                 if ((ang.x < 90 || ang.x > 360 - autocvar_bot_ai_bunnyhop_downward_pitch_max)
 241                                         && fabs(deviation.y) < max(autocvar_bot_ai_bunnyhop_turn_angle_min, max_turn_angle))
 242                                 {
 243                                         can_run = true;
 244                                 }
 245                         }
 246                 }
 247         }
 248
 249         if (can_run)
 250         {
 251                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 252                 this.bot_jump_time = time;
 253                 this.aistatus |= AI_STATUS_RUNNING;
 254         }
 255         else
 256         {
 257                 if (IS_ONGROUND(this) || this.waterlevel > WATERLEVEL_WETFEET)
 258                         this.aistatus &= ~AI_STATUS_RUNNING;
 259         }
 260 }
 261
 262 void havocbot_keyboard_movement(entity this, vector destorg)
 263 {
 264         if(time <= this.havocbot_keyboardtime)
 265                 return;
 266
 267         float sk = skill + this.bot_moveskill;
 268         this.havocbot_keyboardtime =
 269                 max(
 270                         this.havocbot_keyboardtime
 271                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 272                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 273                 , time);
 274         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 275
 276         float trigger = autocvar_bot_ai_keyboard_threshold;
 277
 278         // categorize forward movement
 279         // at skill < 1.5 only forward
 280         // at skill < 2.5 only individual directions
 281         // at skill < 4.5 only individual directions, and forward diagonals
 282         // at skill >= 4.5, all cases allowed
 283         if (keyboard.x > trigger)
 284         {
 285                 keyboard.x = 1;
 286                 if (sk < 2.5)
 287                         keyboard.y = 0;
 288         }
 289         else if (keyboard.x < -trigger && sk > 1.5)
 290         {
 291                 keyboard.x = -1;
 292                 if (sk < 4.5)
 293                         keyboard.y = 0;
 294         }
 295         else
 296         {
 297                 keyboard.x = 0;
 298                 if (sk < 1.5)
 299                         keyboard.y = 0;
 300         }
 301         if (sk < 4.5)
 302                 keyboard.z = 0;
 303
 304         if (keyboard.y > trigger)
 305                 keyboard.y = 1;
 306         else if (keyboard.y < -trigger)
 307                 keyboard.y = -1;
 308         else
 309                 keyboard.y = 0;
 310
 311         if (keyboard.z > trigger)
 312                 keyboard.z = 1;
 313         else if (keyboard.z < -trigger)
 314                 keyboard.z = -1;
 315         else
 316                 keyboard.z = 0;
 317
 318         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 319         if (keyboard == '0 0 0')
 320                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 321
 322         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 323         if (this.havocbot_ducktime > time)
 324                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 325
 326         keyboard = this.havocbot_keyboard;
 327         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 328         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 329         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 330 }
 331
 332 // return true when bot isn't getting closer to the current goal
 333 bool havocbot_checkgoaldistance(entity this, vector gco)
 334 {
 335         if (this.bot_stop_moving_timeout > time)
 336                 return false;
 337         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 338         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 339         float distance_time = this.goalcurrent_distance_time;
 340         if(distance_time < 0)
 341                 distance_time = -distance_time;
 342         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 343         {
 344                 if(!distance_time)
 345                         this.goalcurrent_distance_time = time;
 346                 else if (time - distance_time > 0.5)
 347                         return true;
 348         }
 349         else
 350         {
 351                 // reduce it a little bit so it works even with very small approaches to the goal
 352                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 353                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 354                 this.goalcurrent_distance_time = 0;
 355         }
 356         return false;
 357 }
 358
 359 entity havocbot_select_an_item_of_group(entity this, int gr)
 360 {
 361         entity selected = NULL;
 362         float selected_dist2 = 0;
 363         // select farthest item of this group from bot's position
 364         IL_EACH(g_items, it.item_group == gr && it.solid,
 365         {
 366                 float dist2 = vlen2(this.origin - it.origin);
 367                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 368                 {
 369                         selected = it;
 370                         selected_dist2 = vlen2(this.origin - selected.origin);
 371                 }
 372         });
 373
 374         if (!selected)
 375                 return NULL;
 376
 377         set_tracewalk_dest(selected, this.origin, false);
 378         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 379                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 380         {
 381                 return NULL;
 382         }
 383
 384         return selected;
 385 }
 386
 387 void havocbot_movetogoal(entity this)
 388 {
 389         vector diff;
 390         vector dir;
 391         vector flatdir;
 392         float dodge_enemy_factor = 1;
 393         float maxspeed;
 394         //float dist;
 395         vector dodge;
 396         //if (this.goalentity)
 397         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 398         CS(this).movement = '0 0 0';
 399         maxspeed = autocvar_sv_maxspeed;
 400
 401         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 402
 403         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 404         // Jetpack navigation
 405         if(this.navigation_jetpack_goal)
 406         if(this.goalcurrent==this.navigation_jetpack_goal)
 407         if(GetResource(this, RES_FUEL))
 408         {
 409                 if(autocvar_bot_debug_goalstack)
 410                 {
 411                         debuggoalstack(this);
 412                         te_wizspike(this.navigation_jetpack_point);
 413                 }
 414
 415                 // Take off
 416                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 417                 {
 418                         // Brake almost completely so it can get a good direction
 419                         if(vdist(this.velocity, >, 10))
 420                                 return;
 421                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 422                 }
 423
 424                 makevectors(this.v_angle.y * '0 1 0');
 425                 dir = normalize(this.navigation_jetpack_point - this.origin);
 426
 427                 // Landing
 428                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 429                 {
 430                         // Calculate brake distance in xy
 431                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 432                         float vel2 = vlen2(vec2(this.velocity));
 433                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 434                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 435                         if(d < db || d < 500)
 436                         {
 437                                 // Brake
 438                                 if (vel2 > (maxspeed * 0.3) ** 2)
 439                                 {
 440                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 441                                         return;
 442                                 }
 443                                 // Switch to normal mode
 444                                 this.navigation_jetpack_goal = NULL;
 445                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 446                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 447                                 return;
 448                         }
 449                 }
 450                 else if(checkpvs(this.origin,this.goalcurrent))
 451                 {
 452                         // If I can see the goal switch to landing code
 453                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 454                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 455                         return;
 456                 }
 457
 458                 // Flying
 459                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 460                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 461                 {
 462                         CS(this).movement_x = dir * v_forward * maxspeed;
 463                         CS(this).movement_y = dir * v_right * maxspeed;
 464                 }
 465                 return;
 466         }
 467
 468         // Handling of jump pads
 469         if(this.jumppadcount)
 470         {
 471                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 472                 {
 473                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 474                         if(navigation_poptouchedgoals(this))
 475                                 return;
 476                 }
 477                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 478                 {
 479                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 480                         // but with some randomness so it can try out different paths
 481                         if(!this.goalcurrent)
 482                         {
 483                                 entity newgoal = NULL;
 484                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 485                                 {
 486                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 487                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 488                                                 continue;
 489
 490                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 491
 492                                         if(trace_fraction < 1)
 493                                                 continue;
 494
 495                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 496                                                 newgoal = it;
 497                                 });
 498
 499                                 if(newgoal)
 500                                 {
 501                                         this.ignoregoal = this.goalcurrent;
 502                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 503                                         navigation_clearroute(this);
 504                                         navigation_routetogoal(this, newgoal, this.origin);
 505                                         if(autocvar_bot_debug_goalstack)
 506                                                 debuggoalstack(this);
 507                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 508                                 }
 509                         }
 510                         else //if (this.goalcurrent)
 511                         {
 512                                 if (this.goalcurrent.bot_pickup)
 513                                 {
 514                                         entity jumppad_wp = this.goalcurrent_prev;
 515                                         navigation_poptouchedgoals(this);
 516                                         if(!this.goalcurrent && jumppad_wp.wp00)
 517                                         {
 518                                                 // head to the jumppad destination once bot reaches the goal item
 519                                                 navigation_pushroute(this, jumppad_wp.wp00);
 520                                         }
 521                                 }
 522                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 523                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 524                                 {
 525                                         if (this.velocity.z < 0)
 526                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 527                                 }
 528                                 else if(havocbot_checkgoaldistance(this, gco))
 529                                 {
 530                                         navigation_clearroute(this);
 531                                         navigation_goalrating_timeout_force(this);
 532                                 }
 533                                 else
 534                                         return;
 535                         }
 536                 }
 537                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 538                 {
 539                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 540                         {
 541                                 vector velxy = this.velocity; velxy_z = 0;
 542                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 543                                 {
 544                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 545                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 546                                 }
 547                                 return;
 548                         }
 549
 550                         // Don't chase players while using a jump pad
 551                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 552                                 return;
 553                 }
 554         }
 555         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 556                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 557
 558         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 559         if (skill > 6 && !(IS_ONGROUND(this)))
 560         {
 561                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 562                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 563                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 564
 565                 // save some CPU cycles by checking trigger_hurt after checking
 566                 // that something can be done to evade it (cheaper checks)
 567                 int action_for_trigger_hurt = 0;
 568                 if (this.items & IT_JETPACK)
 569                         action_for_trigger_hurt = 1;
 570                 else if (!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 571                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 572                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 573                 {
 574                         action_for_trigger_hurt = 2;
 575                 }
 576                 else if (!this.goalcurrent)
 577                         action_for_trigger_hurt = 3;
 578
 579                 if (action_for_trigger_hurt)
 580                 {
 581                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 582                         if(!tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos))
 583                                 action_for_trigger_hurt = 0;
 584                 }
 585
 586                 if(action_for_trigger_hurt == 1) // jetpack
 587                 {
 588                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 589                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 590                         {
 591                                 if(this.velocity.z<0)
 592                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 593                         }
 594                         else
 595                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 596
 597                         // If there is no goal try to move forward
 598
 599                         if(this.goalcurrent==NULL)
 600                                 dir = v_forward;
 601                         else
 602                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 603
 604                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 605                         float xyspeed = xyvelocity * dir;
 606
 607                         if(xyspeed < (maxspeed / 2))
 608                         {
 609                                 makevectors(this.v_angle.y * '0 1 0');
 610                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 611                                 if(trace_fraction==1)
 612                                 {
 613                                         CS(this).movement_x = dir * v_forward * maxspeed;
 614                                         CS(this).movement_y = dir * v_right * maxspeed;
 615                                         if (skill < 10)
 616                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 617                                 }
 618                         }
 619
 620                         this.havocbot_blockhead = true;
 621
 622                         return;
 623                 }
 624                 else if(action_for_trigger_hurt == 2) // rocketjump
 625                 {
 626                         if(this.velocity.z < 0)
 627                         {
 628                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 629                                 {
 630                                         .entity weaponentity = weaponentities[slot];
 631
 632                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 633                                                 continue;
 634
 635                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 636                                         {
 637                                                 CS(this).movement_x = maxspeed;
 638
 639                                                 if(this.rocketjumptime)
 640                                                 {
 641                                                         if(time > this.rocketjumptime)
 642                                                         {
 643                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 644                                                                 this.rocketjumptime = 0;
 645                                                         }
 646                                                         return;
 647                                                 }
 648
 649                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 650                                                 this.v_angle_x = 90;
 651                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 652                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 653                                                 return;
 654                                         }
 655                                 }
 656                         }
 657                 }
 658                 else if(action_for_trigger_hurt == 3) // no goal
 659                 {
 660                         // If there is no goal try to move forward
 661                         CS(this).movement_x = maxspeed;
 662                 }
 663         }
 664
 665         // If we are under water with no goals, swim up
 666         if(this.waterlevel && !this.goalcurrent)
 667         {
 668                 dir = '0 0 0';
 669                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 670                         dir.z = 1;
 671                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 672                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 673                 makevectors(this.v_angle.y * '0 1 0');
 674                 vector v = dir * maxspeed;
 675                 CS(this).movement.x = v * v_forward;
 676                 CS(this).movement.y = v * v_right;
 677                 CS(this).movement.z = v * v_up;
 678         }
 679
 680         // if there is nowhere to go, exit
 681         if (this.goalcurrent == NULL)
 682                 return;
 683
 684
 685         bool locked_goal = false;
 686         if((this.goalentity && wasfreed(this.goalentity))
 687                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 688         {
 689                 navigation_clearroute(this);
 690                 navigation_goalrating_timeout_force(this);
 691                 return;
 692         }
 693         else if(this.goalentity.tag_entity)
 694         {
 695                 navigation_goalrating_timeout_expire(this, 2);
 696         }
 697         else if(this.goalentity.bot_pickup)
 698         {
 699                 if(this.goalentity.bot_pickup_respawning)
 700                 {
 701                         if(this.goalentity.solid) // item respawned
 702                                 this.goalentity.bot_pickup_respawning = false;
 703                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 704                         {
 705                                 if(checkpvs(this.origin, this.goalentity))
 706                                 {
 707                                         this.goalentity.bot_pickup_respawning = false;
 708                                         navigation_goalrating_timeout_expire(this, random());
 709                                 }
 710                                 locked_goal = true; // wait for item to respawn
 711                         }
 712                         else if(this.goalentity == this.goalcurrent)
 713                                 locked_goal = true; // wait for item to respawn
 714                 }
 715                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 716                 {
 717                         if(checkpvs(this.origin, this.goalentity))
 718                         {
 719                                 navigation_goalrating_timeout_expire(this, random());
 720                         }
 721                 }
 722         }
 723         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 724                 locked_goal = true;
 725
 726         if (navigation_shortenpath(this))
 727         {
 728                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 729                         && navigation_goalrating_timeout_can_be_anticipated(this))
 730                 {
 731                         navigation_goalrating_timeout_force(this);
 732                 }
 733         }
 734
 735         bool goalcurrent_can_be_removed = false;
 736         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 737         {
 738                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 739                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 740                 {
 741                         goalcurrent_can_be_removed = true;
 742                         // don't remove if not visible
 743                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 744                         {
 745                                 if (IS_DEAD(this.goalcurrent))
 746                                 {
 747                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 748                                         {
 749                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 750                                                 {
 751                                                         navigation_clearroute(this);
 752                                                         navigation_pushroute(this, it);
 753                                                         // loot can't be immediately rated since it isn't on ground yet
 754                                                         // it will be rated after a second when on ground, meanwhile head to it
 755                                                         navigation_goalrating_timeout_expire(this, 1);
 756                                                         return;
 757                                                 }
 758                                         });
 759                                 }
 760                                 if (!Item_IsLoot(this.goalcurrent))
 761                                 {
 762                                         navigation_goalrating_timeout_force(this);
 763                                         return;
 764                                 }
 765                         }
 766                 }
 767                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 768                 {
 769                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 770                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 771                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 772                         {
 773                                 navigation_goalrating_timeout_force(this);
 774                                 return;
 775                         }
 776                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 777                 }
 778         }
 779
 780         if(!locked_goal)
 781         {
 782                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 783                 // in this case path finding can start directly from a waypoint instead of
 784                 // looking for all the reachable waypoints up to a certain distance
 785                 if (navigation_poptouchedgoals(this))
 786                 {
 787                         if (this.goalcurrent)
 788                         {
 789                                 if (goalcurrent_can_be_removed)
 790                                 {
 791                                         // remove even if not visible
 792                                         navigation_goalrating_timeout_force(this);
 793                                         return;
 794                                 }
 795                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 796                                         navigation_goalrating_timeout_force(this);
 797                         }
 798                         else
 799                         {
 800                                 entity old_goal = this.goalcurrent_prev;
 801                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 802                                 {
 803                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 804                                         // item of the group by telling the bot to head directly to the farthest item.
 805                                         // Next time we let the bot select a goal as usual which can be another item
 806                                         // of this group (the closest one) and so on
 807                                         this.item_group = old_goal.item_group;
 808                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 809                                         if (new_goal)
 810                                                 navigation_pushroute(this, new_goal);
 811                                 }
 812                         }
 813                 }
 814         }
 815
 816         // if ran out of goals try to use an alternative goal or get a new strategy asap
 817         if(this.goalcurrent == NULL)
 818         {
 819                 navigation_goalrating_timeout_force(this);
 820                 return;
 821         }
 822
 823
 824         if(autocvar_bot_debug_goalstack)
 825                 debuggoalstack(this);
 826
 827         bool bunnyhop_forbidden = false;
 828         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 829         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 830         {
 831                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 832                 destorg = this.goalcurrent.origin;
 833         }
 834         else if (this.goalcurrent.wpisbox)
 835         {
 836                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 837                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 838                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 839                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 840                 {
 841                         bunnyhop_forbidden = true;
 842                         destorg = this.goalcurrent.origin;
 843                         if(destorg.z > this.origin.z)
 844                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 845                 }
 846         }
 847
 848         diff = destorg - this.origin;
 849
 850         if (time < this.bot_stop_moving_timeout
 851                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 852         {
 853                 // stop if the locked goal has been reached
 854                 destorg = this.origin;
 855                 diff = dir = '0 0 0';
 856         }
 857         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 858         {
 859                 if (vdist(diff, <, 80))
 860                 {
 861                         // stop if too close to target player (even if frozen)
 862                         destorg = this.origin;
 863                         diff = dir = '0 0 0';
 864                 }
 865                 else
 866                 {
 867                         // move destorg out of target players, otherwise bot will consider them
 868                         // an obstacle that needs to be jumped (especially if frozen)
 869                         dir = normalize(diff);
 870                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 871                         diff = destorg - this.origin;
 872                 }
 873         }
 874         else
 875                 dir = normalize(diff);
 876         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 877
 878         bool danger_detected = false;
 879         vector do_break = '0 0 0';
 880
 881         //if (this.bot_dodgevector_time < time)
 882         {
 883                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 884                 //this.bot_dodgevector_jumpbutton = 1;
 885
 886                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 887                 makevectors(this.v_angle.y * '0 1 0');
 888                 if (this.waterlevel > WATERLEVEL_WETFEET)
 889                 {
 890                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 891                         {
 892                                 if(!this.goalcurrent)
 893                                         this.aistatus |= AI_STATUS_OUT_WATER;
 894                                 else if(destorg.z > this.origin.z)
 895                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 896                         }
 897                         else
 898                         {
 899                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 900                                         (this.aistatus & AI_STATUS_OUT_WATER))
 901                                 {
 902                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 903                                         dir = flatdir;
 904                                 }
 905                                 else
 906                                 {
 907                                         if (destorg.z > this.origin.z)
 908                                                 dir = flatdir;
 909                                 }
 910                         }
 911                 }
 912                 else
 913                 {
 914                         float s;
 915                         vector offset;
 916                         if(this.aistatus & AI_STATUS_OUT_WATER)
 917                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 918
 919                         // jump if going toward an obstacle that doesn't look like stairs we
 920                         // can walk up directly
 921                         vector deviation = '0 0 0';
 922                         float current_speed = vlen(vec2(this.velocity));
 923                         if (current_speed < maxspeed * 0.2)
 924                                 current_speed = maxspeed * 0.2;
 925                         else
 926                         {
 927                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 928                                 while (deviation.y < -180) deviation.y += 360;
 929                                 while (deviation.y > 180) deviation.y -= 360;
 930                         }
 931                         float turning = false;
 932                         vector flat_diff = vec2(diff);
 933                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 934                         vector actual_destorg = this.origin + offset;
 935                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 936                         {
 937                                 if (time > this.bot_stop_moving_timeout
 938                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 939                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 940                                 {
 941                                         this.bot_stop_moving_timeout = time + 0.1;
 942                                 }
 943                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 944                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 945                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 946                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 947                                 )
 948                                 {
 949                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 950                                         this.bot_jump_time = time;
 951                                 }
 952                         }
 953                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 954                         {
 955                                 if (vlen2(flat_diff) < vlen2(offset))
 956                                 {
 957                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 958                                         {
 959                                                 // oblique warpzones need a jump otherwise bots gets stuck
 960                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 961                                         }
 962                                         else
 963                                         {
 964                                                 actual_destorg.x = destorg.x;
 965                                                 actual_destorg.y = destorg.y;
 966                                         }
 967                                 }
 968                         }
 969                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 970                         {
 971                                 actual_destorg.x = destorg.x;
 972                                 actual_destorg.y = destorg.y;
 973                         }
 974                         else if (vlen2(flat_diff) < vlen2(offset))
 975                         {
 976                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 977                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 978                                 float dist = vlen(vec2(this.origin + offset - destorg));
 979                                 // if current and next goal are close to each other make sure
 980                                 // actual_destorg isn't set beyond next_goal_org
 981                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 982                                         actual_destorg = next_goal_org;
 983                                 else
 984                                         actual_destorg = vec2(destorg) + dist * next_dir;
 985                                 actual_destorg.z = this.origin.z;
 986                                 turning = true;
 987                         }
 988
 989                         LABEL(jumpobstacle_check);
 990                         dir = flatdir = normalize(actual_destorg - this.origin);
 991
 992                         bool jump_forbidden = false;
 993                         if (!turning && fabs(deviation.y) > 50)
 994                                 jump_forbidden = true;
 995                         else if (IS_DUCKED(this))
 996                         {
 997                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
 998                                 if (trace_startsolid)
 999                                         jump_forbidden = true;
1000                         }
1001
1002                         if (!jump_forbidden)
1003                         {
1004                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1005                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1006                                 {
1007                                         s = trace_fraction;
1008                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1009                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1010                                         {
1011                                                 // found an obstacle
1012                                                 if (turning && fabs(deviation.y) > 5)
1013                                                 {
1014                                                         // check if the obstacle is still there without turning
1015                                                         actual_destorg = destorg;
1016                                                         turning = false;
1017                                                         this.bot_tracewalk_time = time + 0.25;
1018                                                         goto jumpobstacle_check;
1019                                                 }
1020                                                 s = trace_fraction;
1021                                                 // don't artificially reduce max jump height in real-time
1022                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1023                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1024                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1025                                                 if (trace_fraction > s)
1026                                                 {
1027                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1028                                                         this.bot_jump_time = time;
1029                                                 }
1030                                                 else
1031                                                 {
1032                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1033                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1034                                                         if (trace_fraction > s)
1035                                                         {
1036                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1037                                                                 this.bot_jump_time = time;
1038                                                         }
1039                                                 }
1040                                         }
1041                                 }
1042                         }
1043
1044                         // if bot for some reason doesn't get close to the current goal find another one
1045                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1046                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1047                         if(havocbot_checkgoaldistance(this, destorg))
1048                         {
1049                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1050                                 {
1051                                         navigation_clearroute(this);
1052                                         navigation_goalrating_timeout_force(this);
1053                                         return;
1054                                 }
1055
1056                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1057                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1058                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1059                                 {
1060                                         navigation_clearroute(this);
1061                                         navigation_goalrating_timeout_force(this);
1062                                         return;
1063                                 }
1064
1065                                 // give bot only another chance to prevent bot getting stuck
1066                                 // in case it thinks it can walk but actually can't
1067                                 this.goalcurrent_distance_z = FLOAT_MAX;
1068                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1069                                 this.goalcurrent_distance_time = -time; // mark second try
1070                         }
1071
1072                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1073                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1074                         {
1075                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1076                         }
1077
1078                         // Check for water/slime/lava and dangerous edges
1079                         // (only when the bot is on the ground or jumping intentionally)
1080
1081                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1082                         vector dst_ahead = this.origin + this.view_ofs + offset;
1083                         vector dst_down = dst_ahead - '0 0 3000';
1084                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1085
1086                         bool unreachable = false;
1087                         s = CONTENT_SOLID;
1088                         if (trace_fraction == 1 && !this.jumppadcount
1089                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1090                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1091                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1092                         {
1093                                 // Look downwards
1094                                 traceline(dst_ahead , dst_down, true, NULL);
1095                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1096                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1097                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1098                                 {
1099                                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1100                                                 danger_detected = true;
1101                                         else if (trace_endpos.z < min(this.origin.z + this.mins.z, this.goalcurrent.origin.z) - 100)
1102                                                 danger_detected = true;
1103                                         else
1104                                         {
1105                                                 s = pointcontents(trace_endpos + '0 0 1');
1106                                                 if (s != CONTENT_SOLID)
1107                                                 {
1108                                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1109                                                                 danger_detected = true;
1110                                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1111                                                         {
1112                                                                 // the traceline check isn't enough but is good as optimization,
1113                                                                 // when not true (most of the time) this tracebox call is avoided
1114                                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1115                                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1116                                                                 {
1117                                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1118                                                                         {
1119                                                                                 // the goal is probably on an upper platform, assume bot can't get there
1120                                                                                 unreachable = true;
1121                                                                         }
1122                                                                         else
1123                                                                                 danger_detected = true;
1124                                                                 }
1125                                                         }
1126                                                 }
1127                                         }
1128                                 }
1129                         }
1130
1131                         dir = flatdir;
1132                         makevectors(this.v_angle.y * '0 1 0');
1133
1134                         if (danger_detected || (s == CONTENT_WATER))
1135                         {
1136                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1137                                 if(IS_PLAYER(this.goalcurrent))
1138                                         unreachable = true;
1139                         }
1140
1141                         // slow down if bot is in the air and goal is under it
1142                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1143                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1144                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1145                         {
1146                                 // tracebox wouldn't work when bot is still on the ledge
1147                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1148                                 if (this.origin.z - trace_endpos.z > 120)
1149                                         do_break = normalize(this.velocity) * -1;
1150                         }
1151
1152                         if(unreachable)
1153                         {
1154                                 navigation_clearroute(this);
1155                                 navigation_goalrating_timeout_force(this);
1156                                 this.ignoregoal = this.goalcurrent;
1157                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1158                         }
1159                 }
1160
1161                 dodge = havocbot_dodge(this);
1162                 if (dodge)
1163                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1164                 if (this.enemy)
1165                 {
1166                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1167                         if (IS_PLAYER(trace_ent))
1168                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1169                 }
1170         //      this.bot_dodgevector = dir;
1171         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1172         }
1173
1174         float ladder_zdir = 0;
1175         if(time < this.ladder_time)
1176         {
1177                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1178                 {
1179                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1180                                 ladder_zdir = 1;
1181                 }
1182                 else
1183                 {
1184                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1185                                 ladder_zdir = -1;
1186                 }
1187                 if (ladder_zdir)
1188                 {
1189                         if (vdist(vec2(diff), <, 40))
1190                                 dir.z = ladder_zdir * 4;
1191                         else
1192                                 dir.z = ladder_zdir * 2;
1193                         dir = normalize(dir);
1194                 }
1195         }
1196
1197         if (this.goalcurrent.wpisbox
1198                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1199         {
1200                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1201                 // head to teleport origin
1202                 dir = (this.goalcurrent.origin - this.origin);
1203                 dir.z = 0;
1204                 dir = normalize(dir);
1205         }
1206
1207         // already executed when bot targets an enemy
1208         if (!this.bot_aimdir_executed)
1209         {
1210                 if (time < this.bot_stop_moving_timeout)
1211                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1212                 else
1213                         bot_aimdir(this, dir, 0);
1214         }
1215
1216         vector evadedanger = '0 0 0';
1217         if (!ladder_zdir)
1218         {
1219                 dir *= dodge_enemy_factor;
1220                 if (danger_detected && vdist(this.velocity, >, maxspeed * 0.8) && this.goalcurrent_prev
1221                         && this.goalcurrent.classname == "waypoint")
1222                 {
1223                         vector p = this.origin + this.velocity * 0.2;
1224                         vector evadedanger = point_line_vec(p, vec2(this.goalcurrent_prev.origin) + eZ * p.z,
1225                                 vec2(destorg - this.goalcurrent_prev.origin));
1226                         if (vdist(evadedanger, >, 20))
1227                         {
1228                                 if (vdist(evadedanger, >, 40))
1229                                         do_break = normalize(this.velocity) * -1;
1230                                 evadedanger = normalize(evadedanger);
1231                                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1232                         }
1233                         else
1234                                 evadedanger = '0 0 0';
1235                 }
1236                 dir = normalize(dir + dodge + do_break + evadedanger);
1237         }
1238
1239         makevectors(this.v_angle);
1240         //dir = this.bot_dodgevector;
1241         //if (this.bot_dodgevector_jumpbutton)
1242         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1243         CS(this).movement_x = dir * v_forward * maxspeed;
1244         CS(this).movement_y = dir * v_right * maxspeed;
1245         CS(this).movement_z = dir * v_up * maxspeed;
1246
1247         // Emulate keyboard interface
1248         if (skill < 10)
1249                 havocbot_keyboard_movement(this, destorg);
1250
1251         // Bunnyhop!
1252         if (!bunnyhop_forbidden && !evadedanger && !do_break && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1253                 havocbot_bunnyhop(this, dir);
1254
1255         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1256                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1257         if (dodge)
1258         {
1259                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1260                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1261                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1262                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1263         }
1264 }
1265
1266 entity havocbot_gettarget(entity this, bool secondary)
1267 {
1268         entity best = NULL;
1269         vector eye = CENTER_OR_VIEWOFS(this);
1270         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1271         {
1272                 vector v = CENTER_OR_VIEWOFS(it);
1273                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1274                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1275                 if(bot_shouldattack(this, it))
1276                 {
1277                         traceline(eye, v, true, this);
1278                         if (trace_ent == it || trace_fraction >= 1)
1279                                 best = it;
1280                 }
1281         });
1282
1283         return best;
1284 }
1285
1286 void havocbot_chooseenemy(entity this)
1287 {
1288         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1289         {
1290                 this.enemy = NULL;
1291                 return;
1292         }
1293
1294         if (this.enemy)
1295         {
1296                 if (!bot_shouldattack(this, this.enemy))
1297                 {
1298                         // enemy died or something, find a new target
1299                         this.enemy = NULL;
1300                         this.havocbot_chooseenemy_finished = time;
1301                 }
1302                 else if (this.havocbot_stickenemy_time && time < this.havocbot_stickenemy_time)
1303                 {
1304                         // tracking last chosen enemy
1305                         vector targ_pos = (this.enemy.absmin + this.enemy.absmax) * 0.5;
1306                         traceline(this.origin + this.view_ofs, targ_pos, false, NULL);
1307                         if (trace_ent == this.enemy || trace_fraction == 1)
1308                         if (vdist(targ_pos - this.origin, <, 1000))
1309                         {
1310                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1311                                 this.havocbot_chooseenemy_finished = time + 0.5;
1312                                 return;
1313                         }
1314
1315                         // stop preferring this enemy
1316                         this.havocbot_stickenemy_time = 0;
1317                 }
1318         }
1319         if (time < this.havocbot_chooseenemy_finished)
1320                 return;
1321         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1322         vector eye = this.origin + this.view_ofs;
1323         entity best = NULL;
1324         float bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1325
1326         // Backup hit flags
1327         int hf = this.dphitcontentsmask;
1328
1329         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1330
1331         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1332
1333         bool scan_transparent = false;
1334         bool scan_secondary_targets = false;
1335         bool have_secondary_targets = false;
1336         while(true)
1337         {
1338                 scan_secondary_targets = false;
1339 LABEL(scan_targets)
1340                 IL_EACH(g_bot_targets, it.bot_attack,
1341                 {
1342                         if(!scan_secondary_targets)
1343                         {
1344                                 if(it.classname == "misc_breakablemodel")
1345                                 {
1346                                         have_secondary_targets = true;
1347                                         continue;
1348                                 }
1349                         }
1350                         else if(it.classname != "misc_breakablemodel")
1351                                 continue;
1352
1353                         vector v = (it.absmin + it.absmax) * 0.5;
1354                         float rating = vlen2(v - eye);
1355                         if (rating < bestrating && bot_shouldattack(this, it))
1356                         {
1357                                 traceline(eye, v, true, this);
1358                                 if (trace_ent == it || trace_fraction >= 1)
1359                                 {
1360                                         best = it;
1361                                         bestrating = rating;
1362                                 }
1363                         }
1364                 });
1365
1366                 if(!best && have_secondary_targets && !scan_secondary_targets)
1367                 {
1368                         scan_secondary_targets = true;
1369                         // restart the loop
1370                         bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1371                         goto scan_targets;
1372                 }
1373
1374                 // I want to do a second scan if no enemy was found or I don't have weapons
1375                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1376                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1377                         break;
1378                 if(scan_transparent)
1379                         break;
1380
1381                 // Set flags to see through transparent objects
1382                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1383
1384                 scan_transparent = true;
1385         }
1386
1387         // Restore hit flags
1388         this.dphitcontentsmask = hf;
1389
1390         this.enemy = best;
1391         this.havocbot_stickenemy_time = time + autocvar_bot_ai_enemydetectioninterval_stickingtoenemy;
1392         if(best && best.classname == "misc_breakablemodel")
1393                 this.havocbot_stickenemy_time = 0;
1394 }
1395
1396 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1397 {
1398         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1399         // so skip this for them, or they'll never get to reload their weapons at all.
1400         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1401         if(skill < 5)
1402                 return false;
1403
1404         // if this weapon is scheduled for reloading, don't switch to it during combat
1405         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1406         {
1407                 FOREACH(Weapons, it != WEP_Null, {
1408                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1409                                 return true; // other weapon available
1410                 });
1411         }
1412
1413         return false;
1414 }
1415
1416 void havocbot_chooseweapon(entity this, .entity weaponentity)
1417 {
1418         int i;
1419
1420         // ;)
1421         if(g_weaponarena_weapons == WEPSET(TUBA))
1422         {
1423                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1424                 return;
1425         }
1426
1427         // TODO: clean this up by moving it to weapon code
1428         if(this.enemy==NULL)
1429         {
1430                 // If no weapon was chosen get the first available weapon
1431                 if(this.(weaponentity).m_weapon==WEP_Null)
1432                 FOREACH(Weapons, it != WEP_Null, {
1433                         if(client_hasweapon(this, it, weaponentity, true, false))
1434                         {
1435                                 this.(weaponentity).m_switchweapon = it;
1436                                 return;
1437                         }
1438                 });
1439                 return;
1440         }
1441
1442         // Do not change weapon during the next second after a combo
1443         float f = time - this.lastcombotime;
1444         if(f < 1)
1445                 return;
1446
1447         float w;
1448         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1449
1450         // Should it do a weapon combo?
1451         float af, ct, combo_time, combo;
1452
1453         af = ATTACK_FINISHED(this, weaponentity);
1454         ct = autocvar_bot_ai_weapon_combo_threshold;
1455
1456         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1457         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1458         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1459
1460         combo = false;
1461
1462         if(autocvar_bot_ai_weapon_combo)
1463         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1464         if(af > combo_time)
1465         {
1466                 combo = true;
1467                 this.lastcombotime = time;
1468         }
1469
1470         distance *= (2 ** this.bot_rangepreference);
1471
1472         // Custom weapon list based on distance to the enemy
1473         if(bot_custom_weapon){
1474
1475                 // Choose weapons for far distance
1476                 if ( distance > bot_distance_far ) {
1477                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1478                                 w = bot_weapons_far[i];
1479                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1480                                 {
1481                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1482                                                 continue;
1483                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1484                                         return;
1485                                 }
1486                         }
1487                 }
1488
1489                 // Choose weapons for mid distance
1490                 if ( distance > bot_distance_close) {
1491                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1492                                 w = bot_weapons_mid[i];
1493                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1494                                 {
1495                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1496                                                 continue;
1497                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1498                                         return;
1499                                 }
1500                         }
1501                 }
1502
1503                 // Choose weapons for close distance
1504                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1505                         w = bot_weapons_close[i];
1506                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1507                         {
1508                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1509                                         continue;
1510                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1511                                 return;
1512                         }
1513                 }
1514         }
1515 }
1516
1517 void havocbot_aim(entity this)
1518 {
1519         if (time < this.nextaim)
1520                 return;
1521         this.nextaim = time + 0.1;
1522         vector myvel = this.velocity;
1523         if (!this.waterlevel)
1524                 myvel.z = 0;
1525         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1526         else if (this.enemy)
1527         {
1528                 vector enemyvel = this.enemy.velocity;
1529                 if (!this.enemy.waterlevel)
1530                         enemyvel.z = 0;
1531                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1532         }
1533         else
1534                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1535 }
1536
1537 bool havocbot_moveto_refresh_route(entity this)
1538 {
1539         // Refresh path to goal if necessary
1540         entity wp;
1541         wp = this.havocbot_personal_waypoint;
1542         navigation_goalrating_start(this);
1543         navigation_routerating(this, wp, 10000, 10000);
1544         navigation_goalrating_end(this);
1545         return (this.goalentity != NULL);
1546 }
1547
1548 float havocbot_moveto(entity this, vector pos)
1549 {
1550         entity wp;
1551
1552         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1553         {
1554                 // Step 4: Move to waypoint
1555                 if(this.havocbot_personal_waypoint==NULL)
1556                 {
1557                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1558                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1559                         return CMD_STATUS_ERROR;
1560                 }
1561
1562                 if (!bot_strategytoken_taken)
1563                 if(this.havocbot_personal_waypoint_searchtime<time)
1564                 {
1565                         bot_strategytoken_taken = true;
1566                         if(havocbot_moveto_refresh_route(this))
1567                         {
1568                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1569                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1570                                 this.havocbot_personal_waypoint_failcounter = 0;
1571                         }
1572                         else
1573                         {
1574                                 this.havocbot_personal_waypoint_failcounter += 1;
1575                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1576                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1577                                 {
1578                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1579                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1580                                         delete(this.havocbot_personal_waypoint);
1581                                         return CMD_STATUS_ERROR;
1582                                 }
1583                                 else
1584                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1585                         }
1586                 }
1587
1588                 if(autocvar_bot_debug_goalstack)
1589                         debuggoalstack(this);
1590
1591
1592                 // Go!
1593                 havocbot_movetogoal(this);
1594
1595                 if (!this.bot_aimdir_executed && this.goalcurrent)
1596                 {
1597                         // Heading
1598                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1599                         dir -= this.origin + this.view_ofs;
1600                         dir.z = 0;
1601                         bot_aimdir(this, dir, 0);
1602                 }
1603
1604                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1605                 {
1606                         // Step 5: Waypoint reached
1607                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1608                         waypoint_remove(this.havocbot_personal_waypoint);
1609                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1610                         return CMD_STATUS_FINISHED;
1611                 }
1612
1613                 return CMD_STATUS_EXECUTING;
1614         }
1615
1616         // Step 2: Linking waypoint
1617         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1618         {
1619                 // Wait until it is linked
1620                 if(!this.havocbot_personal_waypoint.wplinked)
1621                 {
1622                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1623                         return CMD_STATUS_EXECUTING;
1624                 }
1625
1626                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1627                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1628                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1629
1630                 // Step 3: Route to waypoint
1631                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1632
1633                 return CMD_STATUS_EXECUTING;
1634         }
1635
1636         // Step 1: Spawning waypoint
1637         wp = waypoint_spawnpersonal(this, pos);
1638         if(wp==NULL)
1639         {
1640                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1641                 return CMD_STATUS_ERROR;
1642         }
1643
1644         this.havocbot_personal_waypoint = wp;
1645         this.havocbot_personal_waypoint_failcounter = 0;
1646         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1647
1648         // if pos is inside a teleport, then let's mark it as teleport waypoint
1649         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1650         {
1651                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1652                 this.lastteleporttime = 0;
1653         });
1654
1655 /*
1656         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1657                 print("routing to a teleporter\n");
1658         else
1659                 print("routing to a non-teleporter\n");
1660 */
1661
1662         return CMD_STATUS_EXECUTING;
1663 }
1664
1665 float havocbot_resetgoal(entity this)
1666 {
1667         navigation_clearroute(this);
1668         return CMD_STATUS_FINISHED;
1669 }
1670
1671 void havocbot_setupbot(entity this)
1672 {
1673         this.bot_ai = havocbot_ai;
1674         this.cmd_moveto = havocbot_moveto;
1675         this.cmd_resetgoal = havocbot_resetgoal;
1676
1677         // NOTE: bot is not player yet
1678         havocbot_chooserole(this);
1679 }
1680
1681 vector havocbot_dodge(entity this)
1682 {
1683         // LordHavoc: disabled because this is too expensive
1684         return '0 0 0';
1685 #if 0
1686         entity head;
1687         vector dodge, v, n;
1688         float danger, bestdanger, vl, d;
1689         dodge = '0 0 0';
1690         bestdanger = -20;
1691         // check for dangerous objects near bot or approaching bot
1692         head = findchainfloat(bot_dodge, true);
1693         while(head)
1694         {
1695                 if (head.owner != this)
1696                 {
1697                         vl = vlen(head.velocity);
1698                         if (vl > autocvar_sv_maxspeed * 0.3)
1699                         {
1700                                 n = normalize(head.velocity);
1701                                 v = this.origin - head.origin;
1702                                 d = v * n;
1703                                 if (d > (0 - head.bot_dodgerating))
1704                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1705                                 {
1706                                         // calculate direction and distance from the flight path, by removing the forward axis
1707                                         v = v - (n * (v * n));
1708                                         danger = head.bot_dodgerating - vlen(v);
1709                                         if (bestdanger < danger)
1710                                         {
1711                                                 bestdanger = danger;
1712                                                 // dodge to the side of the object
1713                                                 dodge = normalize(v);
1714                                         }
1715                                 }
1716                         }
1717                         else
1718                         {
1719                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1720                                 if (bestdanger < danger)
1721                                 {
1722                                         bestdanger = danger;
1723                                         dodge = normalize(this.origin - head.origin);
1724                                 }
1725                         }
1726                 }
1727                 head = head.chain;
1728         }
1729         return dodge;
1730 #endif
1731 }