qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/defs.qh>
   6 #include <server/miscfunctions.qh>
   7 #include "../cvars.qh"
   8
   9 #include "../aim.qh"
  10 #include "../bot.qh"
  11 #include "../navigation.qh"
  12 #include "../scripting.qh"
  13 #include "../waypoints.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/impulses/all.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19 #include <common/state.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/wepent.qh>
  22
  23 #include <common/mapobjects/func/ladder.qh>
  24 #include <common/mapobjects/teleporters.qh>
  25 #include <common/mapobjects/trigger/jumppads.qh>
  26
  27 #include <lib/warpzone/common.qh>
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if (this.goalcurrent && wasfreed(this.goalcurrent))
  93         {
  94                 navigation_clearroute(this);
  95                 navigation_goalrating_timeout_force(this);
  96                 return;
  97         }
  98
  99         if(IS_DEAD(this) || STAT(FROZEN, this))
 100         {
 101                 if (this.goalcurrent)
 102                         navigation_clearroute(this);
 103                 return;
 104         }
 105
 106         havocbot_chooseenemy(this);
 107
 108         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 109         {
 110                 .entity weaponentity = weaponentities[slot];
 111                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 112                 if(this.(weaponentity).bot_chooseweapontime < time)
 113                 {
 114                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 115                         havocbot_chooseweapon(this, weaponentity);
 116                 }
 117         }
 118         havocbot_aim(this);
 119         lag_update(this);
 120
 121         if (this.bot_aimtarg)
 122         {
 123                 this.aistatus |= AI_STATUS_ATTACKING;
 124                 this.aistatus &= ~AI_STATUS_ROAMING;
 125
 126                 if(STAT(WEAPONS, this))
 127                 {
 128                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 129                         {
 130                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 131                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 132                         }
 133                         else
 134                         {
 135                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 136                                 {
 137                                         .entity weaponentity = weaponentities[slot];
 138                                         Weapon w = this.(weaponentity).m_weapon;
 139                                         if(w == WEP_Null && slot != 0)
 140                                                 continue;
 141                                         w.wr_aim(w, this, weaponentity);
 142                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 143                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 144                                 }
 145                         }
 146                 }
 147                 else
 148                 {
 149                         if(IS_PLAYER(this.bot_aimtarg))
 150                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 151                 }
 152         }
 153         else if (this.goalcurrent)
 154         {
 155                 this.aistatus |= AI_STATUS_ROAMING;
 156                 this.aistatus &= ~AI_STATUS_ATTACKING;
 157         }
 158
 159         havocbot_movetogoal(this);
 160         if (!this.bot_aimdir_executed && this.goalcurrent)
 161         {
 162                 // Heading
 163                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 164                 dir -= this.origin + this.view_ofs;
 165                 dir.z = 0;
 166                 bot_aimdir(this, dir, 0);
 167         }
 168
 169         // if the bot is not attacking, consider reloading weapons
 170         if (!(this.aistatus & AI_STATUS_ATTACKING))
 171         {
 172                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 173                 {
 174                         .entity weaponentity = weaponentities[slot];
 175
 176                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 177                                 continue;
 178
 179                         // we are currently holding a weapon that's not fully loaded, reload it
 180                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 181                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 182                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 183
 184                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 185                         // the code above executes next frame, starting the reloading then
 186                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 187                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 188                         {
 189                                 FOREACH(Weapons, it != WEP_Null, {
 190                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 191                                         {
 192                                                 this.(weaponentity).m_switchweapon = it;
 193                                                 break;
 194                                         }
 195                                 });
 196                         }
 197                 }
 198         }
 199 }
 200
 201 void havocbot_keyboard_movement(entity this, vector destorg)
 202 {
 203         if(time <= this.havocbot_keyboardtime)
 204                 return;
 205
 206         float sk = skill + this.bot_moveskill;
 207         this.havocbot_keyboardtime =
 208                 max(
 209                         this.havocbot_keyboardtime
 210                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 211                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 212                 , time);
 213         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 214
 215         float trigger = autocvar_bot_ai_keyboard_threshold;
 216
 217         // categorize forward movement
 218         // at skill < 1.5 only forward
 219         // at skill < 2.5 only individual directions
 220         // at skill < 4.5 only individual directions, and forward diagonals
 221         // at skill >= 4.5, all cases allowed
 222         if (keyboard.x > trigger)
 223         {
 224                 keyboard.x = 1;
 225                 if (sk < 2.5)
 226                         keyboard.y = 0;
 227         }
 228         else if (keyboard.x < -trigger && sk > 1.5)
 229         {
 230                 keyboard.x = -1;
 231                 if (sk < 4.5)
 232                         keyboard.y = 0;
 233         }
 234         else
 235         {
 236                 keyboard.x = 0;
 237                 if (sk < 1.5)
 238                         keyboard.y = 0;
 239         }
 240         if (sk < 4.5)
 241                 keyboard.z = 0;
 242
 243         if (keyboard.y > trigger)
 244                 keyboard.y = 1;
 245         else if (keyboard.y < -trigger)
 246                 keyboard.y = -1;
 247         else
 248                 keyboard.y = 0;
 249
 250         if (keyboard.z > trigger)
 251                 keyboard.z = 1;
 252         else if (keyboard.z < -trigger)
 253                 keyboard.z = -1;
 254         else
 255                 keyboard.z = 0;
 256
 257         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 258         if (keyboard == '0 0 0')
 259                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 260
 261         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 262         if (this.havocbot_ducktime > time)
 263                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 264
 265         keyboard = this.havocbot_keyboard;
 266         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 267         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 268         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 269 }
 270
 271 void havocbot_bunnyhop(entity this, vector dir)
 272 {
 273         // Don't jump when attacking
 274         if(this.aistatus & AI_STATUS_ATTACKING)
 275                 return;
 276
 277         if (!this.goalcurrent || IS_PLAYER(this.goalcurrent))
 278                 return;
 279
 280         if((this.aistatus & AI_STATUS_RUNNING) && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 281                 || (this.aistatus & AI_STATUS_DANGER_AHEAD))
 282         {
 283                 this.aistatus &= ~AI_STATUS_RUNNING;
 284                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 285                 this.bot_canruntogoal = 0;
 286                 this.bot_timelastseengoal = 0;
 287                 return;
 288         }
 289
 290         if(this.waterlevel > WATERLEVEL_WETFEET || IS_DUCKED(this))
 291         {
 292                 this.aistatus &= ~AI_STATUS_RUNNING;
 293                 return;
 294         }
 295
 296         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 297         {
 298                 this.bot_canruntogoal = 0;
 299                 this.bot_timelastseengoal = 0;
 300         }
 301
 302         // Run only to visible goals
 303         if(IS_ONGROUND(this))
 304         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed))
 305         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 306         {
 307                 this.bot_lastseengoal = this.goalcurrent;
 308
 309                 // seen it before
 310                 if(this.bot_timelastseengoal)
 311                 {
 312                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 313                         // for a period of time
 314                         if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 315                         {
 316                                 bool checkdistance = true;
 317
 318                                 // don't run if it is too close
 319                                 if(this.bot_canruntogoal==0)
 320                                 {
 321                                         if(vdist(this.origin - gco, >, autocvar_bot_ai_bunnyhop_startdistance))
 322                                                 this.bot_canruntogoal = 1;
 323                                         else
 324                                                 this.bot_canruntogoal = -1;
 325                                 }
 326
 327                                 if(this.bot_canruntogoal != 1)
 328                                         return;
 329
 330                                 if(this.aistatus & AI_STATUS_ROAMING)
 331                                 if(this.goalcurrent.classname == "waypoint")
 332                                 if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 333                                 if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 334                                 if (this.goalstack01 && !wasfreed(this.goalstack01))
 335                                 if (!(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP))
 336                                 {
 337                                         vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 338                                         vector deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 339                                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 340                                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 341
 342                                         if(fabs(deviation.y) < 20)
 343                                         if(vlen2(this.origin - gco) < vlen2(this.origin - gno))
 344                                         if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 345                                         {
 346                                                 if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 347                                                 if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 348                                                 {
 349                                                         checkdistance = false;
 350                                                 }
 351                                         }
 352                                 }
 353
 354                                 if(checkdistance)
 355                                 {
 356                                         this.aistatus &= ~AI_STATUS_RUNNING;
 357                                         // increase stop distance in case the goal is on a slope or a lower platform
 358                                         if(vdist(this.origin - gco, >, autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z)))
 359                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 360                                 }
 361                                 else
 362                                 {
 363                                         this.aistatus |= AI_STATUS_RUNNING;
 364                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 365                                 }
 366                         }
 367                 }
 368                 else
 369                 {
 370                         this.bot_timelastseengoal = time;
 371                 }
 372         }
 373         else
 374         {
 375                 this.bot_timelastseengoal = 0;
 376         }
 377 }
 378
 379 // return true when bot isn't getting closer to the current goal
 380 bool havocbot_checkgoaldistance(entity this, vector gco)
 381 {
 382         if (this.bot_stop_moving_timeout > time)
 383                 return false;
 384         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 385         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 386         float distance_time = this.goalcurrent_distance_time;
 387         if(distance_time < 0)
 388                 distance_time = -distance_time;
 389         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 390         {
 391                 if(!distance_time)
 392                         this.goalcurrent_distance_time = time;
 393                 else if (time - distance_time > 0.5)
 394                         return true;
 395         }
 396         else
 397         {
 398                 // reduce it a little bit so it works even with very small approaches to the goal
 399                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 400                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 401                 this.goalcurrent_distance_time = 0;
 402         }
 403         return false;
 404 }
 405
 406 entity havocbot_select_an_item_of_group(entity this, int gr)
 407 {
 408         entity selected = NULL;
 409         float selected_dist2 = 0;
 410         // select farthest item of this group from bot's position
 411         IL_EACH(g_items, it.item_group == gr && it.solid,
 412         {
 413                 float dist2 = vlen2(this.origin - it.origin);
 414                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 415                 {
 416                         selected = it;
 417                         selected_dist2 = vlen2(this.origin - selected.origin);
 418                 }
 419         });
 420
 421         if (!selected)
 422                 return NULL;
 423
 424         set_tracewalk_dest(selected, this.origin, false);
 425         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 426                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 427         {
 428                 return NULL;
 429         }
 430
 431         return selected;
 432 }
 433
 434 void havocbot_movetogoal(entity this)
 435 {
 436         vector diff;
 437         vector dir;
 438         vector flatdir;
 439         float dodge_enemy_factor = 1;
 440         float maxspeed;
 441         //float dist;
 442         vector dodge;
 443         //if (this.goalentity)
 444         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 445         CS(this).movement = '0 0 0';
 446         maxspeed = autocvar_sv_maxspeed;
 447
 448         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 449
 450         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 451         // Jetpack navigation
 452         if(this.navigation_jetpack_goal)
 453         if(this.goalcurrent==this.navigation_jetpack_goal)
 454         if(GetResource(this, RES_FUEL))
 455         {
 456                 if(autocvar_bot_debug_goalstack)
 457                 {
 458                         debuggoalstack(this);
 459                         te_wizspike(this.navigation_jetpack_point);
 460                 }
 461
 462                 // Take off
 463                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 464                 {
 465                         // Brake almost completely so it can get a good direction
 466                         if(vdist(this.velocity, >, 10))
 467                                 return;
 468                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 469                 }
 470
 471                 makevectors(this.v_angle.y * '0 1 0');
 472                 dir = normalize(this.navigation_jetpack_point - this.origin);
 473
 474                 // Landing
 475                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 476                 {
 477                         // Calculate brake distance in xy
 478                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 479                         float vel2 = vlen2(vec2(this.velocity));
 480                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 481                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 482                         if(d < db || d < 500)
 483                         {
 484                                 // Brake
 485                                 if (vel2 > (maxspeed * 0.3) ** 2)
 486                                 {
 487                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 488                                         return;
 489                                 }
 490                                 // Switch to normal mode
 491                                 this.navigation_jetpack_goal = NULL;
 492                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 493                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 494                                 return;
 495                         }
 496                 }
 497                 else if(checkpvs(this.origin,this.goalcurrent))
 498                 {
 499                         // If I can see the goal switch to landing code
 500                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 501                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 502                         return;
 503                 }
 504
 505                 // Flying
 506                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 507                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 508                 {
 509                         CS(this).movement_x = dir * v_forward * maxspeed;
 510                         CS(this).movement_y = dir * v_right * maxspeed;
 511                 }
 512                 return;
 513         }
 514
 515         // Handling of jump pads
 516         if(this.jumppadcount)
 517         {
 518                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 519                 {
 520                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 521                         if(navigation_poptouchedgoals(this))
 522                                 return;
 523                 }
 524                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 525                 {
 526                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 527                         // but with some randomness so it can try out different paths
 528                         if(!this.goalcurrent)
 529                         {
 530                                 entity newgoal = NULL;
 531                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 532                                 {
 533                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 534                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 535                                                 continue;
 536
 537                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 538
 539                                         if(trace_fraction < 1)
 540                                                 continue;
 541
 542                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 543                                                 newgoal = it;
 544                                 });
 545
 546                                 if(newgoal)
 547                                 {
 548                                         this.ignoregoal = this.goalcurrent;
 549                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 550                                         navigation_clearroute(this);
 551                                         navigation_routetogoal(this, newgoal, this.origin);
 552                                         if(autocvar_bot_debug_goalstack)
 553                                                 debuggoalstack(this);
 554                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 555                                 }
 556                         }
 557                         else //if (this.goalcurrent)
 558                         {
 559                                 if (this.goalcurrent.bot_pickup)
 560                                 {
 561                                         entity jumppad_wp = this.goalcurrent_prev;
 562                                         navigation_poptouchedgoals(this);
 563                                         if(!this.goalcurrent && jumppad_wp.wp00)
 564                                         {
 565                                                 // head to the jumppad destination once bot reaches the goal item
 566                                                 navigation_pushroute(this, jumppad_wp.wp00);
 567                                         }
 568                                 }
 569                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 570                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 571                                 {
 572                                         if (this.velocity.z < 0)
 573                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 574                                 }
 575                                 else if(havocbot_checkgoaldistance(this, gco))
 576                                 {
 577                                         navigation_clearroute(this);
 578                                         navigation_goalrating_timeout_force(this);
 579                                 }
 580                                 else
 581                                         return;
 582                         }
 583                 }
 584                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 585                 {
 586                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 587                         {
 588                                 vector velxy = this.velocity; velxy_z = 0;
 589                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 590                                 {
 591                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 592                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 593                                 }
 594                                 return;
 595                         }
 596
 597                         // Don't chase players while using a jump pad
 598                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 599                                 return;
 600                 }
 601         }
 602         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 603                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 604
 605         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 606         if (skill > 6 && !(IS_ONGROUND(this)))
 607         {
 608                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 609                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 610                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 611
 612                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 613                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 614                 if(this.items & IT_JETPACK)
 615                 {
 616                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 617                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 618                         {
 619                                 if(this.velocity.z<0)
 620                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 621                         }
 622                         else
 623                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 624
 625                         // If there is no goal try to move forward
 626
 627                         if(this.goalcurrent==NULL)
 628                                 dir = v_forward;
 629                         else
 630                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 631
 632                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 633                         float xyspeed = xyvelocity * dir;
 634
 635                         if(xyspeed < (maxspeed / 2))
 636                         {
 637                                 makevectors(this.v_angle.y * '0 1 0');
 638                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 639                                 if(trace_fraction==1)
 640                                 {
 641                                         CS(this).movement_x = dir * v_forward * maxspeed;
 642                                         CS(this).movement_y = dir * v_right * maxspeed;
 643                                         if (skill < 10)
 644                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 645                                 }
 646                         }
 647
 648                         this.havocbot_blockhead = true;
 649
 650                         return;
 651                 }
 652                 else if(!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 653                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 654                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 655                 {
 656                         if(this.velocity.z < 0)
 657                         {
 658                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 659                                 {
 660                                         .entity weaponentity = weaponentities[slot];
 661
 662                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 663                                                 continue;
 664
 665                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 666                                         {
 667                                                 CS(this).movement_x = maxspeed;
 668
 669                                                 if(this.rocketjumptime)
 670                                                 {
 671                                                         if(time > this.rocketjumptime)
 672                                                         {
 673                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 674                                                                 this.rocketjumptime = 0;
 675                                                         }
 676                                                         return;
 677                                                 }
 678
 679                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 680                                                 this.v_angle_x = 90;
 681                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 682                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 683                                                 return;
 684                                         }
 685                                 }
 686                         }
 687                 }
 688                 else
 689                 {
 690                         // If there is no goal try to move forward
 691                         if(this.goalcurrent==NULL)
 692                                 CS(this).movement_x = maxspeed;
 693                 }
 694         }
 695
 696         // If we are under water with no goals, swim up
 697         if(this.waterlevel && !this.goalcurrent)
 698         {
 699                 dir = '0 0 0';
 700                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 701                         dir.z = 1;
 702                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 703                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 704                 else
 705                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 706                 makevectors(this.v_angle.y * '0 1 0');
 707                 vector v = dir * maxspeed;
 708                 CS(this).movement.x = v * v_forward;
 709                 CS(this).movement.y = v * v_right;
 710                 CS(this).movement.z = v * v_up;
 711         }
 712
 713         // if there is nowhere to go, exit
 714         if (this.goalcurrent == NULL)
 715                 return;
 716
 717
 718         bool locked_goal = false;
 719         if((this.goalentity && wasfreed(this.goalentity))
 720                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 721         {
 722                 navigation_clearroute(this);
 723                 navigation_goalrating_timeout_force(this);
 724                 return;
 725         }
 726         else if(this.goalentity.tag_entity)
 727         {
 728                 navigation_goalrating_timeout_expire(this, 2);
 729         }
 730         else if(this.goalentity.bot_pickup)
 731         {
 732                 if(this.goalentity.bot_pickup_respawning)
 733                 {
 734                         if(this.goalentity.solid) // item respawned
 735                                 this.goalentity.bot_pickup_respawning = false;
 736                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 737                         {
 738                                 if(checkpvs(this.origin, this.goalentity))
 739                                 {
 740                                         this.goalentity.bot_pickup_respawning = false;
 741                                         navigation_goalrating_timeout_expire(this, random());
 742                                 }
 743                                 locked_goal = true; // wait for item to respawn
 744                         }
 745                         else if(this.goalentity == this.goalcurrent)
 746                                 locked_goal = true; // wait for item to respawn
 747                 }
 748                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 749                 {
 750                         if(checkpvs(this.origin, this.goalentity))
 751                         {
 752                                 navigation_goalrating_timeout_expire(this, random());
 753                         }
 754                 }
 755         }
 756         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 757                 locked_goal = true;
 758
 759         if (navigation_shortenpath(this))
 760         {
 761                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 762                         && navigation_goalrating_timeout_can_be_anticipated(this))
 763                 {
 764                         navigation_goalrating_timeout_force(this);
 765                 }
 766         }
 767
 768         bool goalcurrent_can_be_removed = false;
 769         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 770         {
 771                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 772                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 773                 {
 774                         goalcurrent_can_be_removed = true;
 775                         // don't remove if not visible
 776                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 777                         {
 778                                 if (IS_DEAD(this.goalcurrent))
 779                                 {
 780                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 781                                         {
 782                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 783                                                 {
 784                                                         navigation_clearroute(this);
 785                                                         navigation_pushroute(this, it);
 786                                                         // loot can't be immediately rated since it isn't on ground yet
 787                                                         // it will be rated after a second when on ground, meanwhile head to it
 788                                                         navigation_goalrating_timeout_expire(this, 1);
 789                                                         return;
 790                                                 }
 791                                         });
 792                                 }
 793                                 if (!Item_IsLoot(this.goalcurrent))
 794                                 {
 795                                         navigation_goalrating_timeout_force(this);
 796                                         return;
 797                                 }
 798                         }
 799                 }
 800                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 801                 {
 802                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 803                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 804                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 805                         {
 806                                 navigation_goalrating_timeout_force(this);
 807                                 return;
 808                         }
 809                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 810                 }
 811         }
 812
 813         if(!locked_goal)
 814         {
 815                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 816                 // in this case path finding can start directly from a waypoint instead of
 817                 // looking for all the reachable waypoints up to a certain distance
 818                 if (navigation_poptouchedgoals(this))
 819                 {
 820                         if (this.goalcurrent)
 821                         {
 822                                 if (goalcurrent_can_be_removed)
 823                                 {
 824                                         // remove even if not visible
 825                                         navigation_goalrating_timeout_force(this);
 826                                         return;
 827                                 }
 828                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 829                                         navigation_goalrating_timeout_force(this);
 830                         }
 831                         else
 832                         {
 833                                 entity old_goal = this.goalcurrent_prev;
 834                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 835                                 {
 836                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 837                                         // item of the group by telling the bot to head directly to the farthest item.
 838                                         // Next time we let the bot select a goal as usual which can be another item
 839                                         // of this group (the closest one) and so on
 840                                         this.item_group = old_goal.item_group;
 841                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 842                                         if (new_goal)
 843                                                 navigation_pushroute(this, new_goal);
 844                                 }
 845                         }
 846                 }
 847         }
 848
 849         // if ran out of goals try to use an alternative goal or get a new strategy asap
 850         if(this.goalcurrent == NULL)
 851         {
 852                 navigation_goalrating_timeout_force(this);
 853                 return;
 854         }
 855
 856
 857         if(autocvar_bot_debug_goalstack)
 858                 debuggoalstack(this);
 859
 860         bool bunnyhop_forbidden = false;
 861         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 862         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 863         {
 864                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 865                 destorg = this.goalcurrent.origin;
 866         }
 867         else if (this.goalcurrent.wpisbox)
 868         {
 869                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 870                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 871                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 872                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 873                 {
 874                         bunnyhop_forbidden = true;
 875                         destorg = this.goalcurrent.origin;
 876                         if(destorg.z > this.origin.z)
 877                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 878                 }
 879         }
 880
 881         diff = destorg - this.origin;
 882
 883         if (time < this.bot_stop_moving_timeout
 884                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 885         {
 886                 // stop if the locked goal has been reached
 887                 destorg = this.origin;
 888                 diff = dir = '0 0 0';
 889         }
 890         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 891         {
 892                 if (vdist(diff, <, 80))
 893                 {
 894                         // stop if too close to target player (even if frozen)
 895                         destorg = this.origin;
 896                         diff = dir = '0 0 0';
 897                 }
 898                 else
 899                 {
 900                         // move destorg out of target players, otherwise bot will consider them
 901                         // an obstacle that needs to be jumped (especially if frozen)
 902                         dir = normalize(diff);
 903                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 904                         diff = destorg - this.origin;
 905                 }
 906         }
 907         else
 908                 dir = normalize(diff);
 909         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 910
 911         vector evadedanger = '0 0 0';
 912
 913         //if (this.bot_dodgevector_time < time)
 914         {
 915                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 916                 //this.bot_dodgevector_jumpbutton = 1;
 917
 918                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 919                 makevectors(this.v_angle.y * '0 1 0');
 920                 if (this.waterlevel > WATERLEVEL_WETFEET)
 921                 {
 922                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 923                         {
 924                                 if(!this.goalcurrent)
 925                                         this.aistatus |= AI_STATUS_OUT_WATER;
 926                                 else if(destorg.z > this.origin.z)
 927                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 928                         }
 929                         else
 930                         {
 931                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 932                                         (this.aistatus & AI_STATUS_OUT_WATER))
 933                                 {
 934                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 935                                         dir = flatdir;
 936                                 }
 937                                 else
 938                                 {
 939                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 940                                         if (destorg.z > this.origin.z)
 941                                                 dir = flatdir;
 942                                 }
 943                         }
 944                 }
 945                 else
 946                 {
 947                         float s;
 948                         vector offset;
 949                         if(this.aistatus & AI_STATUS_OUT_WATER)
 950                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 951
 952                         // jump if going toward an obstacle that doesn't look like stairs we
 953                         // can walk up directly
 954                         vector deviation = '0 0 0';
 955                         float current_speed = vlen(vec2(this.velocity));
 956                         if (current_speed < maxspeed * 0.2)
 957                                 current_speed = maxspeed * 0.2;
 958                         else
 959                         {
 960                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 961                                 while (deviation.y < -180) deviation.y += 360;
 962                                 while (deviation.y > 180) deviation.y -= 360;
 963                         }
 964                         float turning = false;
 965                         vector flat_diff = vec2(diff);
 966                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 967                         vector actual_destorg = this.origin + offset;
 968                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 969                         {
 970                                 if (time > this.bot_stop_moving_timeout
 971                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 972                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 973                                 {
 974                                         this.bot_stop_moving_timeout = time + 0.1;
 975                                 }
 976                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 977                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 978                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 979                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 980                                 )
 981                                 {
 982                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 983                                         // avoid changing route while bot is jumping a gap
 984                                         navigation_goalrating_timeout_extend_if_needed(this, 1.5);
 985                                 }
 986                         }
 987                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 988                         {
 989                                 if (vlen2(flat_diff) < vlen2(offset))
 990                                 {
 991                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 992                                         {
 993                                                 // oblique warpzones need a jump otherwise bots gets stuck
 994                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 995                                         }
 996                                         else
 997                                         {
 998                                                 actual_destorg.x = destorg.x;
 999                                                 actual_destorg.y = destorg.y;
1000                                         }
1001                                 }
1002                         }
1003                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
1004                         {
1005                                 actual_destorg.x = destorg.x;
1006                                 actual_destorg.y = destorg.y;
1007                         }
1008                         else if (vlen2(flat_diff) < vlen2(offset))
1009                         {
1010                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1011                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
1012                                 float dist = vlen(vec2(this.origin + offset - destorg));
1013                                 // if current and next goal are close to each other make sure
1014                                 // actual_destorg isn't set beyond next_goal_org
1015                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
1016                                         actual_destorg = next_goal_org;
1017                                 else
1018                                         actual_destorg = vec2(destorg) + dist * next_dir;
1019                                 actual_destorg.z = this.origin.z;
1020                                 turning = true;
1021                         }
1022
1023                         LABEL(jumpobstacle_check);
1024                         dir = flatdir = normalize(actual_destorg - this.origin);
1025
1026                         bool jump_forbidden = false;
1027                         if (!turning && fabs(deviation.y) > 50)
1028                                 jump_forbidden = true;
1029                         else if (IS_DUCKED(this))
1030                         {
1031                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
1032                                 if (trace_startsolid)
1033                                         jump_forbidden = true;
1034                         }
1035
1036                         if (!jump_forbidden)
1037                         {
1038                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1039                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1040                                 {
1041                                         s = trace_fraction;
1042                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1043                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1044                                         {
1045                                                 // found an obstacle
1046                                                 if (turning && fabs(deviation.y) > 5)
1047                                                 {
1048                                                         // check if the obstacle is still there without turning
1049                                                         actual_destorg = destorg;
1050                                                         turning = false;
1051                                                         this.bot_tracewalk_time = time + 0.25;
1052                                                         goto jumpobstacle_check;
1053                                                 }
1054                                                 s = trace_fraction;
1055                                                 // don't artificially reduce max jump height in real-time
1056                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1057                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1058                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1059                                                 if (trace_fraction > s)
1060                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1061                                                 else
1062                                                 {
1063                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1064                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1065                                                         if (trace_fraction > s)
1066                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1067                                                 }
1068                                         }
1069                                 }
1070                         }
1071
1072                         // if bot for some reason doesn't get close to the current goal find another one
1073                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1074                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1075                         if(havocbot_checkgoaldistance(this, destorg))
1076                         {
1077                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1078                                 {
1079                                         navigation_clearroute(this);
1080                                         navigation_goalrating_timeout_force(this);
1081                                         return;
1082                                 }
1083
1084                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1085                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1086                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1087                                 {
1088                                         navigation_clearroute(this);
1089                                         navigation_goalrating_timeout_force(this);
1090                                         return;
1091                                 }
1092
1093                                 // give bot only another chance to prevent bot getting stuck
1094                                 // in case it thinks it can walk but actually can't
1095                                 this.goalcurrent_distance_z = FLOAT_MAX;
1096                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1097                                 this.goalcurrent_distance_time = -time; // mark second try
1098                         }
1099
1100                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1101                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1102                         {
1103                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1104                         }
1105
1106                         // Check for water/slime/lava and dangerous edges
1107                         // (only when the bot is on the ground or jumping intentionally)
1108
1109                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1110                         vector dst_ahead = this.origin + this.view_ofs + offset;
1111                         vector dst_down = dst_ahead - '0 0 3000';
1112                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1113
1114                         bool unreachable = false;
1115                         s = CONTENT_SOLID;
1116                         bool danger_detected = false;
1117                         if (trace_fraction == 1 && !this.jumppadcount
1118                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1119                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1120                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1121                         {
1122                                 // Look downwards
1123                                 traceline(dst_ahead , dst_down, true, NULL);
1124                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1125                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1126                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1127                                 {
1128                                         s = pointcontents(trace_endpos + '0 0 1');
1129                                         if (s != CONTENT_SOLID)
1130                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1131                                                 danger_detected = true;
1132                                         else if (s == CONTENT_SKY)
1133                                                 danger_detected = true;
1134                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1135                                         {
1136                                                 // the traceline check isn't enough but is good as optimization,
1137                                                 // when not true (most of the time) this tracebox call is avoided
1138                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1139                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1140                                                 {
1141                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1142                                                         {
1143                                                                 // the goal is probably on an upper platform, assume bot can't get there
1144                                                                 unreachable = true;
1145                                                         }
1146                                                         else
1147                                                                 danger_detected = true;
1148                                                 }
1149                                         }
1150                                 }
1151                         }
1152                         if (danger_detected && fabs(deviation.y) < 80
1153                                 && (fabs(deviation.y) > 5 || vdist(vec2(this.velocity), >, maxspeed * 1.5)))
1154                         {
1155                                 evadedanger = normalize(this.velocity) * -1;
1156                                 evadedanger.z = 0;
1157                         }
1158
1159                         dir = flatdir;
1160                         makevectors(this.v_angle.y * '0 1 0');
1161
1162                         if (danger_detected || (s == CONTENT_WATER))
1163                         {
1164                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1165                                 if(IS_PLAYER(this.goalcurrent))
1166                                         unreachable = true;
1167                         }
1168
1169                         // slow down if bot is in the air and goal is under it
1170                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1171                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1172                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1173                         {
1174                                 // tracebox wouldn't work when bot is still on the ledge
1175                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1176                                 if (this.origin.z - trace_endpos.z > 120)
1177                                         evadedanger = normalize(this.velocity) * -1;
1178                         }
1179
1180                         if(unreachable)
1181                         {
1182                                 navigation_clearroute(this);
1183                                 navigation_goalrating_timeout_force(this);
1184                                 this.ignoregoal = this.goalcurrent;
1185                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1186                         }
1187                 }
1188
1189                 dodge = havocbot_dodge(this);
1190                 if (dodge)
1191                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1192                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1193                 if (this.enemy)
1194                 {
1195                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1196                         if (IS_PLAYER(trace_ent))
1197                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1198                 }
1199         //      this.bot_dodgevector = dir;
1200         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1201         }
1202
1203         float ladder_zdir = 0;
1204         if(time < this.ladder_time)
1205         {
1206                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1207                 {
1208                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1209                                 ladder_zdir = 1;
1210                 }
1211                 else
1212                 {
1213                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1214                                 ladder_zdir = -1;
1215                 }
1216                 if (ladder_zdir)
1217                 {
1218                         if (vdist(vec2(diff), <, 40))
1219                                 dir.z = ladder_zdir * 4;
1220                         else
1221                                 dir.z = ladder_zdir * 2;
1222                         dir = normalize(dir);
1223                 }
1224         }
1225
1226         if (this.goalcurrent.wpisbox
1227                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1228         {
1229                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1230                 // head to teleport origin
1231                 dir = (this.goalcurrent.origin - this.origin);
1232                 dir.z = 0;
1233                 dir = normalize(dir);
1234         }
1235
1236         // already executed when bot targets an enemy
1237         if (!this.bot_aimdir_executed)
1238         {
1239                 if (time < this.bot_stop_moving_timeout)
1240                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1241                 else
1242                         bot_aimdir(this, dir, 0);
1243         }
1244
1245         if (!ladder_zdir)
1246         {
1247                 dir *= dodge_enemy_factor;
1248                 dir = normalize(dir + dodge + evadedanger);
1249         }
1250
1251         makevectors(this.v_angle);
1252         //dir = this.bot_dodgevector;
1253         //if (this.bot_dodgevector_jumpbutton)
1254         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1255         CS(this).movement_x = dir * v_forward * maxspeed;
1256         CS(this).movement_y = dir * v_right * maxspeed;
1257         CS(this).movement_z = dir * v_up * maxspeed;
1258
1259         // Emulate keyboard interface
1260         if (skill < 10)
1261                 havocbot_keyboard_movement(this, destorg);
1262
1263         // Bunnyhop!
1264         if (!bunnyhop_forbidden && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1265                 havocbot_bunnyhop(this, dir);
1266
1267         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1268                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1269         if (dodge)
1270         {
1271                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1272                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1273                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1274                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1275         }
1276 }
1277
1278 entity havocbot_gettarget(entity this, bool secondary)
1279 {
1280         entity best = NULL;
1281         vector eye = CENTER_OR_VIEWOFS(this);
1282         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1283         {
1284                 vector v = CENTER_OR_VIEWOFS(it);
1285                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1286                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1287                 if(bot_shouldattack(this, it))
1288                 {
1289                         traceline(eye, v, true, this);
1290                         if (trace_ent == it || trace_fraction >= 1)
1291                                 best = it;
1292                 }
1293         });
1294
1295         return best;
1296 }
1297
1298 void havocbot_chooseenemy(entity this)
1299 {
1300         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1301         {
1302                 this.enemy = NULL;
1303                 return;
1304         }
1305         if (this.enemy)
1306         {
1307                 if (!bot_shouldattack(this, this.enemy))
1308                 {
1309                         // enemy died or something, find a new target
1310                         this.enemy = NULL;
1311                         this.havocbot_chooseenemy_finished = time;
1312                 }
1313                 else if (this.havocbot_stickenemy)
1314                 {
1315                         // tracking last chosen enemy
1316                         // if enemy is visible
1317                         // and not really really far away
1318                         // and we're not severely injured
1319                         // then keep tracking for a half second into the future
1320                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1321                         if (trace_ent == this.enemy || trace_fraction == 1)
1322                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1323                         if (GetResource(this, RES_HEALTH) > 30)
1324                         {
1325                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1326                                 this.havocbot_chooseenemy_finished = time + 0.5;
1327                                 return;
1328                         }
1329                         // enemy isn't visible, or is far away, or we're injured severely
1330                         // so stop preferring this enemy
1331                         // (it will still take a half second until a new one is chosen)
1332                         this.havocbot_stickenemy = 0;
1333                 }
1334         }
1335         if (time < this.havocbot_chooseenemy_finished)
1336                 return;
1337         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1338         vector eye = this.origin + this.view_ofs;
1339         entity best = NULL;
1340         float bestrating = 100000000;
1341
1342         // Backup hit flags
1343         int hf = this.dphitcontentsmask;
1344
1345         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1346
1347         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1348
1349         bool scan_transparent = false;
1350         bool scan_secondary_targets = false;
1351         bool have_secondary_targets = false;
1352         while(true)
1353         {
1354                 scan_secondary_targets = false;
1355 LABEL(scan_targets)
1356                 IL_EACH(g_bot_targets, it.bot_attack,
1357                 {
1358                         if(!scan_secondary_targets)
1359                         {
1360                                 if(it.classname == "misc_breakablemodel")
1361                                 {
1362                                         have_secondary_targets = true;
1363                                         continue;
1364                                 }
1365                         }
1366                         else if(it.classname != "misc_breakablemodel")
1367                                 continue;
1368
1369                         vector v = (it.absmin + it.absmax) * 0.5;
1370                         float rating = vlen2(v - eye);
1371                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1372                         if (bestrating > rating)
1373                         if (bot_shouldattack(this, it))
1374                         {
1375                                 traceline(eye, v, true, this);
1376                                 if (trace_ent == it || trace_fraction >= 1)
1377                                 {
1378                                         best = it;
1379                                         bestrating = rating;
1380                                 }
1381                         }
1382                 });
1383
1384                 if(!best && have_secondary_targets && !scan_secondary_targets)
1385                 {
1386                         scan_secondary_targets = true;
1387                         // restart the loop
1388                         bestrating = 100000000;
1389                         goto scan_targets;
1390                 }
1391
1392                 // I want to do a second scan if no enemy was found or I don't have weapons
1393                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1394                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1395                         break;
1396                 if(scan_transparent)
1397                         break;
1398
1399                 // Set flags to see through transparent objects
1400                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1401
1402                 scan_transparent = true;
1403         }
1404
1405         // Restore hit flags
1406         this.dphitcontentsmask = hf;
1407
1408         this.enemy = best;
1409         this.havocbot_stickenemy = true;
1410         if(best && best.classname == "misc_breakablemodel")
1411                 this.havocbot_stickenemy = false;
1412 }
1413
1414 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1415 {
1416         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1417         // so skip this for them, or they'll never get to reload their weapons at all.
1418         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1419         if(skill < 5)
1420                 return false;
1421
1422         // if this weapon is scheduled for reloading, don't switch to it during combat
1423         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1424         {
1425                 FOREACH(Weapons, it != WEP_Null, {
1426                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1427                                 return true; // other weapon available
1428                 });
1429         }
1430
1431         return false;
1432 }
1433
1434 void havocbot_chooseweapon(entity this, .entity weaponentity)
1435 {
1436         int i;
1437
1438         // ;)
1439         if(g_weaponarena_weapons == WEPSET(TUBA))
1440         {
1441                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1442                 return;
1443         }
1444
1445         // TODO: clean this up by moving it to weapon code
1446         if(this.enemy==NULL)
1447         {
1448                 // If no weapon was chosen get the first available weapon
1449                 if(this.(weaponentity).m_weapon==WEP_Null)
1450                 FOREACH(Weapons, it != WEP_Null, {
1451                         if(client_hasweapon(this, it, weaponentity, true, false))
1452                         {
1453                                 this.(weaponentity).m_switchweapon = it;
1454                                 return;
1455                         }
1456                 });
1457                 return;
1458         }
1459
1460         // Do not change weapon during the next second after a combo
1461         float f = time - this.lastcombotime;
1462         if(f < 1)
1463                 return;
1464
1465         float w;
1466         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1467
1468         // Should it do a weapon combo?
1469         float af, ct, combo_time, combo;
1470
1471         af = ATTACK_FINISHED(this, weaponentity);
1472         ct = autocvar_bot_ai_weapon_combo_threshold;
1473
1474         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1475         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1476         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1477
1478         combo = false;
1479
1480         if(autocvar_bot_ai_weapon_combo)
1481         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1482         if(af > combo_time)
1483         {
1484                 combo = true;
1485                 this.lastcombotime = time;
1486         }
1487
1488         distance *= (2 ** this.bot_rangepreference);
1489
1490         // Custom weapon list based on distance to the enemy
1491         if(bot_custom_weapon){
1492
1493                 // Choose weapons for far distance
1494                 if ( distance > bot_distance_far ) {
1495                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1496                                 w = bot_weapons_far[i];
1497                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1498                                 {
1499                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1500                                                 continue;
1501                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1502                                         return;
1503                                 }
1504                         }
1505                 }
1506
1507                 // Choose weapons for mid distance
1508                 if ( distance > bot_distance_close) {
1509                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1510                                 w = bot_weapons_mid[i];
1511                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1512                                 {
1513                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1514                                                 continue;
1515                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1516                                         return;
1517                                 }
1518                         }
1519                 }
1520
1521                 // Choose weapons for close distance
1522                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1523                         w = bot_weapons_close[i];
1524                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1525                         {
1526                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1527                                         continue;
1528                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1529                                 return;
1530                         }
1531                 }
1532         }
1533 }
1534
1535 void havocbot_aim(entity this)
1536 {
1537         if (time < this.nextaim)
1538                 return;
1539         this.nextaim = time + 0.1;
1540         vector myvel = this.velocity;
1541         if (!this.waterlevel)
1542                 myvel.z = 0;
1543         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1544         else if (this.enemy)
1545         {
1546                 vector enemyvel = this.enemy.velocity;
1547                 if (!this.enemy.waterlevel)
1548                         enemyvel.z = 0;
1549                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1550         }
1551         else
1552                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1553 }
1554
1555 bool havocbot_moveto_refresh_route(entity this)
1556 {
1557         // Refresh path to goal if necessary
1558         entity wp;
1559         wp = this.havocbot_personal_waypoint;
1560         navigation_goalrating_start(this);
1561         navigation_routerating(this, wp, 10000, 10000);
1562         navigation_goalrating_end(this);
1563         return (this.goalentity != NULL);
1564 }
1565
1566 float havocbot_moveto(entity this, vector pos)
1567 {
1568         entity wp;
1569
1570         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1571         {
1572                 // Step 4: Move to waypoint
1573                 if(this.havocbot_personal_waypoint==NULL)
1574                 {
1575                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1576                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1577                         return CMD_STATUS_ERROR;
1578                 }
1579
1580                 if (!bot_strategytoken_taken)
1581                 if(this.havocbot_personal_waypoint_searchtime<time)
1582                 {
1583                         bot_strategytoken_taken = true;
1584                         if(havocbot_moveto_refresh_route(this))
1585                         {
1586                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1587                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1588                                 this.havocbot_personal_waypoint_failcounter = 0;
1589                         }
1590                         else
1591                         {
1592                                 this.havocbot_personal_waypoint_failcounter += 1;
1593                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1594                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1595                                 {
1596                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1597                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1598                                         delete(this.havocbot_personal_waypoint);
1599                                         return CMD_STATUS_ERROR;
1600                                 }
1601                                 else
1602                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1603                         }
1604                 }
1605
1606                 if(autocvar_bot_debug_goalstack)
1607                         debuggoalstack(this);
1608
1609
1610                 // Go!
1611                 havocbot_movetogoal(this);
1612
1613                 if (!this.bot_aimdir_executed && this.goalcurrent)
1614                 {
1615                         // Heading
1616                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1617                         dir -= this.origin + this.view_ofs;
1618                         dir.z = 0;
1619                         bot_aimdir(this, dir, 0);
1620                 }
1621
1622                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1623                 {
1624                         // Step 5: Waypoint reached
1625                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1626                         waypoint_remove(this.havocbot_personal_waypoint);
1627                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1628                         return CMD_STATUS_FINISHED;
1629                 }
1630
1631                 return CMD_STATUS_EXECUTING;
1632         }
1633
1634         // Step 2: Linking waypoint
1635         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1636         {
1637                 // Wait until it is linked
1638                 if(!this.havocbot_personal_waypoint.wplinked)
1639                 {
1640                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1641                         return CMD_STATUS_EXECUTING;
1642                 }
1643
1644                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1645                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1646                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1647
1648                 // Step 3: Route to waypoint
1649                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1650
1651                 return CMD_STATUS_EXECUTING;
1652         }
1653
1654         // Step 1: Spawning waypoint
1655         wp = waypoint_spawnpersonal(this, pos);
1656         if(wp==NULL)
1657         {
1658                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1659                 return CMD_STATUS_ERROR;
1660         }
1661
1662         this.havocbot_personal_waypoint = wp;
1663         this.havocbot_personal_waypoint_failcounter = 0;
1664         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1665
1666         // if pos is inside a teleport, then let's mark it as teleport waypoint
1667         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1668         {
1669                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1670                 this.lastteleporttime = 0;
1671         });
1672
1673 /*
1674         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1675                 print("routing to a teleporter\n");
1676         else
1677                 print("routing to a non-teleporter\n");
1678 */
1679
1680         return CMD_STATUS_EXECUTING;
1681 }
1682
1683 float havocbot_resetgoal(entity this)
1684 {
1685         navigation_clearroute(this);
1686         return CMD_STATUS_FINISHED;
1687 }
1688
1689 void havocbot_setupbot(entity this)
1690 {
1691         this.bot_ai = havocbot_ai;
1692         this.cmd_moveto = havocbot_moveto;
1693         this.cmd_resetgoal = havocbot_resetgoal;
1694
1695         // NOTE: bot is not player yet
1696         havocbot_chooserole(this);
1697 }
1698
1699 vector havocbot_dodge(entity this)
1700 {
1701         // LordHavoc: disabled because this is too expensive
1702         return '0 0 0';
1703 #if 0
1704         entity head;
1705         vector dodge, v, n;
1706         float danger, bestdanger, vl, d;
1707         dodge = '0 0 0';
1708         bestdanger = -20;
1709         // check for dangerous objects near bot or approaching bot
1710         head = findchainfloat(bot_dodge, true);
1711         while(head)
1712         {
1713                 if (head.owner != this)
1714                 {
1715                         vl = vlen(head.velocity);
1716                         if (vl > autocvar_sv_maxspeed * 0.3)
1717                         {
1718                                 n = normalize(head.velocity);
1719                                 v = this.origin - head.origin;
1720                                 d = v * n;
1721                                 if (d > (0 - head.bot_dodgerating))
1722                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1723                                 {
1724                                         // calculate direction and distance from the flight path, by removing the forward axis
1725                                         v = v - (n * (v * n));
1726                                         danger = head.bot_dodgerating - vlen(v);
1727                                         if (bestdanger < danger)
1728                                         {
1729                                                 bestdanger = danger;
1730                                                 // dodge to the side of the object
1731                                                 dodge = normalize(v);
1732                                         }
1733                                 }
1734                         }
1735                         else
1736                         {
1737                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1738                                 if (bestdanger < danger)
1739                                 {
1740                                         bestdanger = danger;
1741                                         dodge = normalize(this.origin - head.origin);
1742                                 }
1743                         }
1744                 }
1745                 head = head.chain;
1746         }
1747         return dodge;
1748 #endif
1749 }