qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/defs.qh>
   6 #include <server/miscfunctions.qh>
   7 #include "../cvars.qh"
   8
   9 #include "../aim.qh"
  10 #include "../bot.qh"
  11 #include "../navigation.qh"
  12 #include "../scripting.qh"
  13 #include "../waypoints.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/impulses/all.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19 #include <common/state.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/wepent.qh>
  22
  23 #include <common/mapobjects/func/ladder.qh>
  24 #include <common/mapobjects/teleporters.qh>
  25 #include <common/mapobjects/trigger/jumppads.qh>
  26
  27 #include <lib/warpzone/common.qh>
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this)
  51                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP) && !IS_ONGROUND(this)))
  52                         {
  53                                 // find a new goal
  54                                 this.havocbot_role(this); // little too far down the rabbit hole
  55                         }
  56                 }
  57
  58                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  59                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  60                 if(!this.goalcurrent)
  61                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  62                 {
  63                         // Look for the closest waypoint out of water
  64                         entity newgoal = NULL;
  65                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  66                         {
  67                                 if(it.origin.z < this.origin.z)
  68                                         continue;
  69
  70                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  71                                         continue;
  72
  73                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  74                                         continue;
  75
  76                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  77
  78                                 if(trace_fraction < 1)
  79                                         continue;
  80
  81                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  82                                         newgoal = it;
  83                         });
  84
  85                         if(newgoal)
  86                         {
  87                         //      te_wizspike(newgoal.origin);
  88                                 navigation_pushroute(this, newgoal);
  89                         }
  90                 }
  91
  92                 // token has been used this frame
  93                 bot_strategytoken_taken = true;
  94         }
  95
  96         if (this.goalcurrent && wasfreed(this.goalcurrent))
  97         {
  98                 navigation_clearroute(this);
  99                 navigation_goalrating_timeout_force(this);
 100                 return;
 101         }
 102
 103         if(IS_DEAD(this) || STAT(FROZEN, this))
 104         {
 105                 if (this.goalcurrent)
 106                         navigation_clearroute(this);
 107                 this.enemy = NULL;
 108                 this.bot_aimtarg = NULL;
 109                 return;
 110         }
 111
 112         havocbot_chooseenemy(this);
 113
 114         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 115         {
 116                 .entity weaponentity = weaponentities[slot];
 117                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 118                 if(this.(weaponentity).bot_chooseweapontime < time)
 119                 {
 120                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 121                         havocbot_chooseweapon(this, weaponentity);
 122                 }
 123         }
 124         havocbot_aim(this);
 125         lag_update(this);
 126
 127         if (this.bot_aimtarg)
 128         {
 129                 this.aistatus |= AI_STATUS_ATTACKING;
 130                 this.aistatus &= ~AI_STATUS_ROAMING;
 131
 132                 if(STAT(WEAPONS, this))
 133                 {
 134                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 135                         {
 136                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 137                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 138                         }
 139                         else
 140                         {
 141                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 142                                 {
 143                                         .entity weaponentity = weaponentities[slot];
 144                                         Weapon w = this.(weaponentity).m_weapon;
 145                                         if(w == WEP_Null && slot != 0)
 146                                                 continue;
 147                                         w.wr_aim(w, this, weaponentity);
 148                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 149                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 150                                 }
 151                         }
 152                 }
 153                 else
 154                 {
 155                         if(IS_PLAYER(this.bot_aimtarg))
 156                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 157                 }
 158         }
 159         else if (this.goalcurrent)
 160         {
 161                 this.aistatus |= AI_STATUS_ROAMING;
 162                 this.aistatus &= ~AI_STATUS_ATTACKING;
 163         }
 164
 165         havocbot_movetogoal(this);
 166         if (!this.bot_aimdir_executed && this.goalcurrent)
 167         {
 168                 // Heading
 169                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 170                 dir -= this.origin + this.view_ofs;
 171                 dir.z = 0;
 172                 bot_aimdir(this, dir, 0);
 173         }
 174
 175         // if the bot is not attacking, consider reloading weapons
 176         if (!(this.aistatus & AI_STATUS_ATTACKING))
 177         {
 178                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 179                 {
 180                         .entity weaponentity = weaponentities[slot];
 181
 182                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 183                                 continue;
 184
 185                         // we are currently holding a weapon that's not fully loaded, reload it
 186                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 187                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 188                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 189
 190                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 191                         // the code above executes next frame, starting the reloading then
 192                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 193                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 194                         {
 195                                 FOREACH(Weapons, it != WEP_Null, {
 196                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 197                                         {
 198                                                 this.(weaponentity).m_switchweapon = it;
 199                                                 break;
 200                                         }
 201                                 });
 202                         }
 203                 }
 204         }
 205 }
 206
 207 void havocbot_bunnyhop(entity this, vector dir)
 208 {
 209         bool can_run = false;
 210         if (!(this.aistatus & AI_STATUS_ATTACKING) && this.goalcurrent && !IS_PLAYER(this.goalcurrent)
 211                 && vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed) && !(this.aistatus & AI_STATUS_DANGER_AHEAD)
 212                 && this.waterlevel <= WATERLEVEL_WETFEET && !IS_DUCKED(this)
 213                 && IS_ONGROUND(this) && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
 214         {
 215                 vector vel_angles = vectoangles(this.velocity);
 216                 vector deviation = vel_angles - vectoangles(dir);
 217                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 218                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 219                 if (fabs(deviation.y) < autocvar_bot_ai_bunnyhop_dir_deviation_max)
 220                 {
 221                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 222                         float vel = vlen(vec2(this.velocity));
 223
 224                         // with the current physics, jump distance grows linearly with the speed
 225                         float jump_distance = 52.661 + 0.606 * vel;
 226                         jump_distance += this.origin.z - gco.z; // roughly take into account vertical distance too
 227                         if (vdist(vec2(gco - this.origin), >, max(0, jump_distance)))
 228                                 can_run = true;
 229                         else if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP)
 230                                 && !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 231                                 && this.goalstack01 && !wasfreed(this.goalstack01) && !(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP)
 232                                 && vdist(vec2(gco - this.goalstack01.origin), >, 70))
 233                         {
 234                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 235                                 vector ang = vectoangles(gco - this.origin);
 236                                 deviation = vectoangles(gno - gco) - vel_angles;
 237                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 238                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 239
 240                                 float max_turn_angle = autocvar_bot_ai_bunnyhop_turn_angle_max;
 241                                 max_turn_angle -= autocvar_bot_ai_bunnyhop_turn_angle_reduction * ((vel - autocvar_sv_maxspeed) / autocvar_sv_maxspeed);
 242                                 if ((ang.x < 90 || ang.x > 360 - autocvar_bot_ai_bunnyhop_downward_pitch_max)
 243                                         && fabs(deviation.y) < max(autocvar_bot_ai_bunnyhop_turn_angle_min, max_turn_angle))
 244                                 {
 245                                         can_run = true;
 246                                 }
 247                         }
 248                 }
 249         }
 250
 251         if (can_run)
 252         {
 253                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 254                 this.bot_jump_time = time;
 255                 this.aistatus |= AI_STATUS_RUNNING;
 256         }
 257         else
 258         {
 259                 if (IS_ONGROUND(this) || this.waterlevel > WATERLEVEL_WETFEET)
 260                         this.aistatus &= ~AI_STATUS_RUNNING;
 261         }
 262 }
 263
 264 void havocbot_keyboard_movement(entity this, vector destorg)
 265 {
 266         if(time <= this.havocbot_keyboardtime)
 267                 return;
 268
 269         float sk = skill + this.bot_moveskill;
 270         this.havocbot_keyboardtime =
 271                 max(
 272                         this.havocbot_keyboardtime
 273                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 274                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 275                 , time);
 276         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 277
 278         float trigger = autocvar_bot_ai_keyboard_threshold;
 279
 280         // categorize forward movement
 281         // at skill < 1.5 only forward
 282         // at skill < 2.5 only individual directions
 283         // at skill < 4.5 only individual directions, and forward diagonals
 284         // at skill >= 4.5, all cases allowed
 285         if (keyboard.x > trigger)
 286         {
 287                 keyboard.x = 1;
 288                 if (sk < 2.5)
 289                         keyboard.y = 0;
 290         }
 291         else if (keyboard.x < -trigger && sk > 1.5)
 292         {
 293                 keyboard.x = -1;
 294                 if (sk < 4.5)
 295                         keyboard.y = 0;
 296         }
 297         else
 298         {
 299                 keyboard.x = 0;
 300                 if (sk < 1.5)
 301                         keyboard.y = 0;
 302         }
 303         if (sk < 4.5)
 304                 keyboard.z = 0;
 305
 306         if (keyboard.y > trigger)
 307                 keyboard.y = 1;
 308         else if (keyboard.y < -trigger)
 309                 keyboard.y = -1;
 310         else
 311                 keyboard.y = 0;
 312
 313         if (keyboard.z > trigger)
 314                 keyboard.z = 1;
 315         else if (keyboard.z < -trigger)
 316                 keyboard.z = -1;
 317         else
 318                 keyboard.z = 0;
 319
 320         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 321         if (keyboard == '0 0 0')
 322                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 323
 324         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 325         if (this.havocbot_ducktime > time)
 326                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 327
 328         keyboard = this.havocbot_keyboard;
 329         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 330         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 331         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 332 }
 333
 334 // return true when bot isn't getting closer to the current goal
 335 bool havocbot_checkgoaldistance(entity this, vector gco)
 336 {
 337         if (this.bot_stop_moving_timeout > time)
 338                 return false;
 339         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 340         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 341         float distance_time = this.goalcurrent_distance_time;
 342         if(distance_time < 0)
 343                 distance_time = -distance_time;
 344         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 345         {
 346                 if(!distance_time)
 347                         this.goalcurrent_distance_time = time;
 348                 else if (time - distance_time > 0.5)
 349                         return true;
 350         }
 351         else
 352         {
 353                 // reduce it a little bit so it works even with very small approaches to the goal
 354                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 355                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 356                 this.goalcurrent_distance_time = 0;
 357         }
 358         return false;
 359 }
 360
 361 entity havocbot_select_an_item_of_group(entity this, int gr)
 362 {
 363         entity selected = NULL;
 364         float selected_dist2 = 0;
 365         // select farthest item of this group from bot's position
 366         IL_EACH(g_items, it.item_group == gr && it.solid,
 367         {
 368                 float dist2 = vlen2(this.origin - it.origin);
 369                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 370                 {
 371                         selected = it;
 372                         selected_dist2 = vlen2(this.origin - selected.origin);
 373                 }
 374         });
 375
 376         if (!selected)
 377                 return NULL;
 378
 379         set_tracewalk_dest(selected, this.origin, false);
 380         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 381                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 382         {
 383                 return NULL;
 384         }
 385
 386         return selected;
 387 }
 388
 389 void havocbot_movetogoal(entity this)
 390 {
 391         vector diff;
 392         vector dir;
 393         vector flatdir;
 394         float dodge_enemy_factor = 1;
 395         float maxspeed;
 396         //float dist;
 397         vector dodge;
 398         //if (this.goalentity)
 399         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 400         CS(this).movement = '0 0 0';
 401         maxspeed = autocvar_sv_maxspeed;
 402
 403         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 404
 405         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 406         // Jetpack navigation
 407         if(this.navigation_jetpack_goal)
 408         if(this.goalcurrent==this.navigation_jetpack_goal)
 409         if(GetResource(this, RES_FUEL))
 410         {
 411                 if(autocvar_bot_debug_goalstack)
 412                 {
 413                         debuggoalstack(this);
 414                         te_wizspike(this.navigation_jetpack_point);
 415                 }
 416
 417                 // Take off
 418                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 419                 {
 420                         // Brake almost completely so it can get a good direction
 421                         if(vdist(this.velocity, >, 10))
 422                                 return;
 423                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 424                 }
 425
 426                 makevectors(this.v_angle.y * '0 1 0');
 427                 dir = normalize(this.navigation_jetpack_point - this.origin);
 428
 429                 // Landing
 430                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 431                 {
 432                         // Calculate brake distance in xy
 433                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 434                         float vel2 = vlen2(vec2(this.velocity));
 435                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 436                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 437                         if(d < db || d < 500)
 438                         {
 439                                 // Brake
 440                                 if (vel2 > (maxspeed * 0.3) ** 2)
 441                                 {
 442                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 443                                         return;
 444                                 }
 445                                 // Switch to normal mode
 446                                 this.navigation_jetpack_goal = NULL;
 447                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 448                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 449                                 return;
 450                         }
 451                 }
 452                 else if(checkpvs(this.origin,this.goalcurrent))
 453                 {
 454                         // If I can see the goal switch to landing code
 455                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 456                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 457                         return;
 458                 }
 459
 460                 // Flying
 461                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 462                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 463                 {
 464                         CS(this).movement_x = dir * v_forward * maxspeed;
 465                         CS(this).movement_y = dir * v_right * maxspeed;
 466                 }
 467                 return;
 468         }
 469
 470         // Handling of jump pads
 471         if(this.jumppadcount)
 472         {
 473                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 474                 {
 475                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 476                         if(navigation_poptouchedgoals(this))
 477                                 return;
 478                 }
 479                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 480                 {
 481                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 482                         // but with some randomness so it can try out different paths
 483                         if(!this.goalcurrent)
 484                         {
 485                                 entity newgoal = NULL;
 486                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 487                                 {
 488                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 489                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 490                                                 continue;
 491
 492                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 493
 494                                         if(trace_fraction < 1)
 495                                                 continue;
 496
 497                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 498                                                 newgoal = it;
 499                                 });
 500
 501                                 if(newgoal)
 502                                 {
 503                                         this.ignoregoal = this.goalcurrent;
 504                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 505                                         navigation_clearroute(this);
 506                                         navigation_routetogoal(this, newgoal, this.origin);
 507                                         if(autocvar_bot_debug_goalstack)
 508                                                 debuggoalstack(this);
 509                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 510                                 }
 511                         }
 512                         else //if (this.goalcurrent)
 513                         {
 514                                 if (this.goalcurrent.bot_pickup)
 515                                 {
 516                                         entity jumppad_wp = this.goalcurrent_prev;
 517                                         navigation_poptouchedgoals(this);
 518                                         if(!this.goalcurrent && jumppad_wp.wp00)
 519                                         {
 520                                                 // head to the jumppad destination once bot reaches the goal item
 521                                                 navigation_pushroute(this, jumppad_wp.wp00);
 522                                         }
 523                                 }
 524                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 525                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 526                                 {
 527                                         if (this.velocity.z < 0)
 528                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 529                                 }
 530                                 else if(havocbot_checkgoaldistance(this, gco))
 531                                 {
 532                                         navigation_clearroute(this);
 533                                         navigation_goalrating_timeout_force(this);
 534                                 }
 535                                 else
 536                                         return;
 537                         }
 538                 }
 539                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 540                 {
 541                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 542                         {
 543                                 vector velxy = this.velocity; velxy_z = 0;
 544                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 545                                 {
 546                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 547                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 548                                 }
 549                                 return;
 550                         }
 551
 552                         // Don't chase players while using a jump pad
 553                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 554                                 return;
 555                 }
 556         }
 557         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 558                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 559
 560         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 561         if (skill > 6 && !(IS_ONGROUND(this)))
 562         {
 563                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 564                         * ((STAT(STRENGTH_FINISHED, this) > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 565                         * ((STAT(INVINCIBLE_FINISHED, this) > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 566
 567                 // save some CPU cycles by checking trigger_hurt after checking
 568                 // that something can be done to evade it (cheaper checks)
 569                 int action_for_trigger_hurt = 0;
 570                 if (this.items & IT_JETPACK)
 571                         action_for_trigger_hurt = 1;
 572                 else if (!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 573                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 574                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 575                 {
 576                         action_for_trigger_hurt = 2;
 577                 }
 578                 else if (!this.goalcurrent)
 579                         action_for_trigger_hurt = 3;
 580
 581                 if (action_for_trigger_hurt)
 582                 {
 583                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 584                         if(!tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos))
 585                                 action_for_trigger_hurt = 0;
 586                 }
 587
 588                 if(action_for_trigger_hurt == 1) // jetpack
 589                 {
 590                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 591                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 592                         {
 593                                 if(this.velocity.z<0)
 594                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 595                         }
 596                         else
 597                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 598
 599                         // If there is no goal try to move forward
 600
 601                         if(this.goalcurrent==NULL)
 602                                 dir = v_forward;
 603                         else
 604                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 605
 606                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 607                         float xyspeed = xyvelocity * dir;
 608
 609                         if(xyspeed < (maxspeed / 2))
 610                         {
 611                                 makevectors(this.v_angle.y * '0 1 0');
 612                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 613                                 if(trace_fraction==1)
 614                                 {
 615                                         CS(this).movement_x = dir * v_forward * maxspeed;
 616                                         CS(this).movement_y = dir * v_right * maxspeed;
 617                                         if (skill < 10)
 618                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 619                                 }
 620                         }
 621
 622                         this.havocbot_blockhead = true;
 623
 624                         return;
 625                 }
 626                 else if(action_for_trigger_hurt == 2) // rocketjump
 627                 {
 628                         if(this.velocity.z < 0)
 629                         {
 630                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 631                                 {
 632                                         .entity weaponentity = weaponentities[slot];
 633
 634                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 635                                                 continue;
 636
 637                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 638                                         {
 639                                                 CS(this).movement_x = maxspeed;
 640
 641                                                 if(this.rocketjumptime)
 642                                                 {
 643                                                         if(time > this.rocketjumptime)
 644                                                         {
 645                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 646                                                                 this.rocketjumptime = 0;
 647                                                         }
 648                                                         return;
 649                                                 }
 650
 651                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 652                                                 this.v_angle_x = 90;
 653                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 654                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 655                                                 return;
 656                                         }
 657                                 }
 658                         }
 659                 }
 660                 else if(action_for_trigger_hurt == 3) // no goal
 661                 {
 662                         // If there is no goal try to move forward
 663                         CS(this).movement_x = maxspeed;
 664                 }
 665         }
 666
 667         // If we are under water with no goals, swim up
 668         if(this.waterlevel && !this.goalcurrent)
 669         {
 670                 dir = '0 0 0';
 671                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 672                         dir.z = 1;
 673                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 674                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 675                 makevectors(this.v_angle.y * '0 1 0');
 676                 vector v = dir * maxspeed;
 677                 CS(this).movement.x = v * v_forward;
 678                 CS(this).movement.y = v * v_right;
 679                 CS(this).movement.z = v * v_up;
 680         }
 681
 682         // if there is nowhere to go, exit
 683         if (this.goalcurrent == NULL)
 684                 return;
 685
 686
 687         bool locked_goal = false;
 688         if((this.goalentity && wasfreed(this.goalentity))
 689                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 690         {
 691                 navigation_clearroute(this);
 692                 navigation_goalrating_timeout_force(this);
 693                 return;
 694         }
 695         else if(this.goalentity.tag_entity)
 696         {
 697                 navigation_goalrating_timeout_expire(this, 2);
 698         }
 699         else if(this.goalentity.bot_pickup)
 700         {
 701                 if(this.goalentity.bot_pickup_respawning)
 702                 {
 703                         if(this.goalentity.solid) // item respawned
 704                                 this.goalentity.bot_pickup_respawning = false;
 705                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 706                         {
 707                                 if(checkpvs(this.origin, this.goalentity))
 708                                 {
 709                                         this.goalentity.bot_pickup_respawning = false;
 710                                         navigation_goalrating_timeout_expire(this, random());
 711                                 }
 712                                 locked_goal = true; // wait for item to respawn
 713                         }
 714                         else if(this.goalentity == this.goalcurrent)
 715                                 locked_goal = true; // wait for item to respawn
 716                 }
 717                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 718                 {
 719                         if(checkpvs(this.origin, this.goalentity))
 720                         {
 721                                 navigation_goalrating_timeout_expire(this, random());
 722                         }
 723                 }
 724         }
 725         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 726                 locked_goal = true;
 727
 728         if (navigation_shortenpath(this))
 729         {
 730                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 731                         && navigation_goalrating_timeout_can_be_anticipated(this))
 732                 {
 733                         navigation_goalrating_timeout_force(this);
 734                 }
 735         }
 736
 737         bool goalcurrent_can_be_removed = false;
 738         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 739         {
 740                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 741                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 742                 {
 743                         goalcurrent_can_be_removed = true;
 744                         // don't remove if not visible
 745                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 746                         {
 747                                 if (IS_DEAD(this.goalcurrent))
 748                                 {
 749                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 750                                         {
 751                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 752                                                 {
 753                                                         navigation_clearroute(this);
 754                                                         navigation_pushroute(this, it);
 755                                                         // loot can't be immediately rated since it isn't on ground yet
 756                                                         // it will be rated after a second when on ground, meanwhile head to it
 757                                                         navigation_goalrating_timeout_expire(this, 1);
 758                                                         return;
 759                                                 }
 760                                         });
 761                                 }
 762                                 if (!Item_IsLoot(this.goalcurrent))
 763                                 {
 764                                         navigation_goalrating_timeout_force(this);
 765                                         return;
 766                                 }
 767                         }
 768                 }
 769                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 770                 {
 771                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 772                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 773                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 774                         {
 775                                 navigation_goalrating_timeout_force(this);
 776                                 return;
 777                         }
 778                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 779                 }
 780         }
 781
 782         if(!locked_goal)
 783         {
 784                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 785                 // in this case path finding can start directly from a waypoint instead of
 786                 // looking for all the reachable waypoints up to a certain distance
 787                 if (navigation_poptouchedgoals(this))
 788                 {
 789                         if (this.goalcurrent)
 790                         {
 791                                 if (goalcurrent_can_be_removed)
 792                                 {
 793                                         // remove even if not visible
 794                                         navigation_goalrating_timeout_force(this);
 795                                         return;
 796                                 }
 797                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 798                                         navigation_goalrating_timeout_force(this);
 799                         }
 800                         else
 801                         {
 802                                 entity old_goal = this.goalcurrent_prev;
 803                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 804                                 {
 805                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 806                                         // item of the group by telling the bot to head directly to the farthest item.
 807                                         // Next time we let the bot select a goal as usual which can be another item
 808                                         // of this group (the closest one) and so on
 809                                         this.item_group = old_goal.item_group;
 810                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 811                                         if (new_goal)
 812                                                 navigation_pushroute(this, new_goal);
 813                                 }
 814                         }
 815                 }
 816         }
 817
 818         // if ran out of goals try to use an alternative goal or get a new strategy asap
 819         if(this.goalcurrent == NULL)
 820         {
 821                 navigation_goalrating_timeout_force(this);
 822                 return;
 823         }
 824
 825
 826         if(autocvar_bot_debug_goalstack)
 827                 debuggoalstack(this);
 828
 829         bool bunnyhop_forbidden = false;
 830         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 831         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 832         {
 833                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 834                 destorg = this.goalcurrent.origin;
 835         }
 836         else if (this.goalcurrent.wpisbox)
 837         {
 838                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 839                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 840                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 841                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 842                 {
 843                         bunnyhop_forbidden = true;
 844                         destorg = this.goalcurrent.origin;
 845                         if(destorg.z > this.origin.z)
 846                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 847                 }
 848         }
 849
 850         diff = destorg - this.origin;
 851
 852         if (time < this.bot_stop_moving_timeout
 853                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 854         {
 855                 // stop if the locked goal has been reached
 856                 destorg = this.origin;
 857                 diff = dir = '0 0 0';
 858         }
 859         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 860         {
 861                 if (vdist(diff, <, 80))
 862                 {
 863                         // stop if too close to target player (even if frozen)
 864                         destorg = this.origin;
 865                         diff = dir = '0 0 0';
 866                 }
 867                 else
 868                 {
 869                         // move destorg out of target players, otherwise bot will consider them
 870                         // an obstacle that needs to be jumped (especially if frozen)
 871                         dir = normalize(diff);
 872                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 873                         diff = destorg - this.origin;
 874                 }
 875         }
 876         else
 877                 dir = normalize(diff);
 878         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 879
 880         bool danger_detected = false;
 881         vector do_break = '0 0 0';
 882
 883         //if (this.bot_dodgevector_time < time)
 884         {
 885                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 886                 //this.bot_dodgevector_jumpbutton = 1;
 887
 888                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 889                 makevectors(this.v_angle.y * '0 1 0');
 890                 if (this.waterlevel > WATERLEVEL_WETFEET)
 891                 {
 892                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 893                         {
 894                                 if(!this.goalcurrent)
 895                                         this.aistatus |= AI_STATUS_OUT_WATER;
 896                                 else if(destorg.z > this.origin.z)
 897                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 898                         }
 899                         else
 900                         {
 901                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 902                                         (this.aistatus & AI_STATUS_OUT_WATER))
 903                                 {
 904                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 905                                         dir = flatdir;
 906                                 }
 907                                 else
 908                                 {
 909                                         if (destorg.z > this.origin.z)
 910                                                 dir = flatdir;
 911                                 }
 912                         }
 913                 }
 914                 else
 915                 {
 916                         float s;
 917                         vector offset;
 918                         if(this.aistatus & AI_STATUS_OUT_WATER)
 919                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 920
 921                         // jump if going toward an obstacle that doesn't look like stairs we
 922                         // can walk up directly
 923                         vector deviation = '0 0 0';
 924                         float current_speed = vlen(vec2(this.velocity));
 925                         if (current_speed < maxspeed * 0.2)
 926                                 current_speed = maxspeed * 0.2;
 927                         else
 928                         {
 929                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 930                                 while (deviation.y < -180) deviation.y += 360;
 931                                 while (deviation.y > 180) deviation.y -= 360;
 932                         }
 933                         float turning = false;
 934                         vector flat_diff = vec2(diff);
 935                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 936                         vector actual_destorg = this.origin + offset;
 937                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 938                         {
 939                                 if (time > this.bot_stop_moving_timeout
 940                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 941                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 942                                 {
 943                                         this.bot_stop_moving_timeout = time + 0.1;
 944                                 }
 945                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 946                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 947                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 948                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 949                                 )
 950                                 {
 951                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 952                                         this.bot_jump_time = time;
 953                                 }
 954                         }
 955                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 956                         {
 957                                 if (vlen2(flat_diff) < vlen2(offset))
 958                                 {
 959                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 960                                         {
 961                                                 // oblique warpzones need a jump otherwise bots gets stuck
 962                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 963                                         }
 964                                         else
 965                                         {
 966                                                 actual_destorg.x = destorg.x;
 967                                                 actual_destorg.y = destorg.y;
 968                                         }
 969                                 }
 970                         }
 971                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 972                         {
 973                                 actual_destorg.x = destorg.x;
 974                                 actual_destorg.y = destorg.y;
 975                         }
 976                         else if (vlen2(flat_diff) < vlen2(offset))
 977                         {
 978                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 979                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 980                                 float dist = vlen(vec2(this.origin + offset - destorg));
 981                                 // if current and next goal are close to each other make sure
 982                                 // actual_destorg isn't set beyond next_goal_org
 983                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 984                                         actual_destorg = next_goal_org;
 985                                 else
 986                                         actual_destorg = vec2(destorg) + dist * next_dir;
 987                                 actual_destorg.z = this.origin.z;
 988                                 turning = true;
 989                         }
 990
 991                         LABEL(jumpobstacle_check);
 992                         dir = flatdir = normalize(actual_destorg - this.origin);
 993
 994                         bool jump_forbidden = false;
 995                         if (!turning && fabs(deviation.y) > 50)
 996                                 jump_forbidden = true;
 997                         else if (IS_DUCKED(this))
 998                         {
 999                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
1000                                 if (trace_startsolid)
1001                                         jump_forbidden = true;
1002                         }
1003
1004                         if (!jump_forbidden)
1005                         {
1006                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1007                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1008                                 {
1009                                         s = trace_fraction;
1010                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1011                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1012                                         {
1013                                                 // found an obstacle
1014                                                 if (turning && fabs(deviation.y) > 5)
1015                                                 {
1016                                                         // check if the obstacle is still there without turning
1017                                                         actual_destorg = destorg;
1018                                                         turning = false;
1019                                                         this.bot_tracewalk_time = time + 0.25;
1020                                                         goto jumpobstacle_check;
1021                                                 }
1022                                                 s = trace_fraction;
1023                                                 // don't artificially reduce max jump height in real-time
1024                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1025                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1026                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1027                                                 if (trace_fraction > s)
1028                                                 {
1029                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1030                                                         this.bot_jump_time = time;
1031                                                 }
1032                                                 else
1033                                                 {
1034                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1035                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1036                                                         if (trace_fraction > s)
1037                                                         {
1038                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1039                                                                 this.bot_jump_time = time;
1040                                                         }
1041                                                 }
1042                                         }
1043                                 }
1044                         }
1045
1046                         // if bot for some reason doesn't get close to the current goal find another one
1047                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1048                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1049                         if(havocbot_checkgoaldistance(this, destorg))
1050                         {
1051                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1052                                 {
1053                                         navigation_clearroute(this);
1054                                         navigation_goalrating_timeout_force(this);
1055                                         return;
1056                                 }
1057
1058                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1059                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1060                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1061                                 {
1062                                         navigation_clearroute(this);
1063                                         navigation_goalrating_timeout_force(this);
1064                                         return;
1065                                 }
1066
1067                                 // give bot only another chance to prevent bot getting stuck
1068                                 // in case it thinks it can walk but actually can't
1069                                 this.goalcurrent_distance_z = FLOAT_MAX;
1070                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1071                                 this.goalcurrent_distance_time = -time; // mark second try
1072                         }
1073
1074                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1075                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1076                         {
1077                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1078                         }
1079
1080                         // Check for water/slime/lava and dangerous edges
1081                         // (only when the bot is on the ground or jumping intentionally)
1082
1083                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1084                         vector dst_ahead = this.origin + this.view_ofs + offset;
1085                         vector dst_down = dst_ahead - '0 0 3000';
1086                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1087
1088                         bool unreachable = false;
1089                         s = CONTENT_SOLID;
1090                         if (trace_fraction == 1 && !this.jumppadcount
1091                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1092                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1093                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1094                         {
1095                                 // Look downwards
1096                                 traceline(dst_ahead , dst_down, true, NULL);
1097                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1098                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1099                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1100                                 {
1101                                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1102                                                 danger_detected = true;
1103                                         else if (trace_endpos.z < min(this.origin.z + this.mins.z, this.goalcurrent.origin.z) - 100)
1104                                                 danger_detected = true;
1105                                         else
1106                                         {
1107                                                 s = pointcontents(trace_endpos + '0 0 1');
1108                                                 if (s != CONTENT_SOLID)
1109                                                 {
1110                                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1111                                                                 danger_detected = true;
1112                                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1113                                                         {
1114                                                                 // the traceline check isn't enough but is good as optimization,
1115                                                                 // when not true (most of the time) this tracebox call is avoided
1116                                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1117                                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1118                                                                 {
1119                                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1120                                                                         {
1121                                                                                 // the goal is probably on an upper platform, assume bot can't get there
1122                                                                                 unreachable = true;
1123                                                                         }
1124                                                                         else
1125                                                                                 danger_detected = true;
1126                                                                 }
1127                                                         }
1128                                                 }
1129                                         }
1130                                 }
1131                         }
1132
1133                         dir = flatdir;
1134                         makevectors(this.v_angle.y * '0 1 0');
1135
1136                         if (danger_detected || (s == CONTENT_WATER))
1137                         {
1138                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1139                                 if(IS_PLAYER(this.goalcurrent))
1140                                         unreachable = true;
1141                         }
1142
1143                         // slow down if bot is in the air and goal is under it
1144                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1145                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1146                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1147                         {
1148                                 // tracebox wouldn't work when bot is still on the ledge
1149                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1150                                 if (this.origin.z - trace_endpos.z > 120)
1151                                         do_break = normalize(this.velocity) * -1;
1152                         }
1153
1154                         if(unreachable)
1155                         {
1156                                 navigation_clearroute(this);
1157                                 navigation_goalrating_timeout_force(this);
1158                                 this.ignoregoal = this.goalcurrent;
1159                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1160                         }
1161                 }
1162
1163                 dodge = havocbot_dodge(this);
1164                 if (dodge)
1165                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1166                 if (this.enemy)
1167                 {
1168                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1169                         if (IS_PLAYER(trace_ent))
1170                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1171                 }
1172         //      this.bot_dodgevector = dir;
1173         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1174         }
1175
1176         float ladder_zdir = 0;
1177         if(time < this.ladder_time)
1178         {
1179                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1180                 {
1181                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1182                                 ladder_zdir = 1;
1183                 }
1184                 else
1185                 {
1186                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1187                                 ladder_zdir = -1;
1188                 }
1189                 if (ladder_zdir)
1190                 {
1191                         if (vdist(vec2(diff), <, 40))
1192                                 dir.z = ladder_zdir * 4;
1193                         else
1194                                 dir.z = ladder_zdir * 2;
1195                         dir = normalize(dir);
1196                 }
1197         }
1198
1199         if (this.goalcurrent.wpisbox
1200                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1201         {
1202                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1203                 // head to teleport origin
1204                 dir = (this.goalcurrent.origin - this.origin);
1205                 dir.z = 0;
1206                 dir = normalize(dir);
1207         }
1208
1209         // already executed when bot targets an enemy
1210         if (!this.bot_aimdir_executed)
1211         {
1212                 if (time < this.bot_stop_moving_timeout)
1213                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1214                 else
1215                         bot_aimdir(this, dir, 0);
1216         }
1217
1218         vector evadedanger = '0 0 0';
1219         if (!ladder_zdir)
1220         {
1221                 dir *= dodge_enemy_factor;
1222                 if (danger_detected && vdist(this.velocity, >, maxspeed * 0.8) && this.goalcurrent_prev
1223                         && this.goalcurrent.classname == "waypoint")
1224                 {
1225                         vector p = this.origin + this.velocity * 0.2;
1226                         vector evadedanger = point_line_vec(p, vec2(this.goalcurrent_prev.origin) + eZ * p.z,
1227                                 vec2(destorg - this.goalcurrent_prev.origin));
1228                         if (vdist(evadedanger, >, 20))
1229                         {
1230                                 if (vdist(evadedanger, >, 40))
1231                                         do_break = normalize(this.velocity) * -1;
1232                                 evadedanger = normalize(evadedanger);
1233                                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1234                         }
1235                         else
1236                                 evadedanger = '0 0 0';
1237                 }
1238                 dir = normalize(dir + dodge + do_break + evadedanger);
1239         }
1240
1241         makevectors(this.v_angle);
1242         //dir = this.bot_dodgevector;
1243         //if (this.bot_dodgevector_jumpbutton)
1244         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1245         CS(this).movement_x = dir * v_forward * maxspeed;
1246         CS(this).movement_y = dir * v_right * maxspeed;
1247         CS(this).movement_z = dir * v_up * maxspeed;
1248
1249         // Emulate keyboard interface
1250         if (skill < 10)
1251                 havocbot_keyboard_movement(this, destorg);
1252
1253         // Bunnyhop!
1254         if (!bunnyhop_forbidden && !evadedanger && !do_break && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1255                 havocbot_bunnyhop(this, dir);
1256
1257         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1258                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1259         if (dodge)
1260         {
1261                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1262                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1263                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1264                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1265         }
1266 }
1267
1268 entity havocbot_gettarget(entity this, bool secondary)
1269 {
1270         entity best = NULL;
1271         vector eye = CENTER_OR_VIEWOFS(this);
1272         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1273         {
1274                 vector v = CENTER_OR_VIEWOFS(it);
1275                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1276                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1277                 if(bot_shouldattack(this, it))
1278                 {
1279                         traceline(eye, v, true, this);
1280                         if (trace_ent == it || trace_fraction >= 1)
1281                                 best = it;
1282                 }
1283         });
1284
1285         return best;
1286 }
1287
1288 void havocbot_chooseenemy(entity this)
1289 {
1290         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1291         {
1292                 this.enemy = NULL;
1293                 return;
1294         }
1295
1296         if (this.enemy)
1297         {
1298                 if (!bot_shouldattack(this, this.enemy))
1299                 {
1300                         // enemy died or something, find a new target
1301                         this.enemy = NULL;
1302                         this.havocbot_chooseenemy_finished = time;
1303                 }
1304                 else if (this.havocbot_stickenemy_time && time < this.havocbot_stickenemy_time)
1305                 {
1306                         // tracking last chosen enemy
1307                         vector targ_pos = (this.enemy.absmin + this.enemy.absmax) * 0.5;
1308                         traceline(this.origin + this.view_ofs, targ_pos, false, NULL);
1309                         if (trace_ent == this.enemy || trace_fraction == 1)
1310                         if (vdist(targ_pos - this.origin, <, 1000))
1311                         {
1312                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1313                                 this.havocbot_chooseenemy_finished = time + 0.5;
1314                                 return;
1315                         }
1316
1317                         // stop preferring this enemy
1318                         this.havocbot_stickenemy_time = 0;
1319                 }
1320         }
1321         if (time < this.havocbot_chooseenemy_finished)
1322                 return;
1323         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1324         vector eye = this.origin + this.view_ofs;
1325         entity best = NULL;
1326         float bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1327
1328         // Backup hit flags
1329         int hf = this.dphitcontentsmask;
1330
1331         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1332
1333         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1334
1335         bool scan_transparent = false;
1336         bool scan_secondary_targets = false;
1337         bool have_secondary_targets = false;
1338         while(true)
1339         {
1340                 scan_secondary_targets = false;
1341 LABEL(scan_targets)
1342                 IL_EACH(g_bot_targets, it.bot_attack,
1343                 {
1344                         if(!scan_secondary_targets)
1345                         {
1346                                 if(it.classname == "misc_breakablemodel")
1347                                 {
1348                                         have_secondary_targets = true;
1349                                         continue;
1350                                 }
1351                         }
1352                         else if(it.classname != "misc_breakablemodel")
1353                                 continue;
1354
1355                         vector v = (it.absmin + it.absmax) * 0.5;
1356                         float rating = vlen2(v - eye);
1357                         if (rating < bestrating && bot_shouldattack(this, it))
1358                         {
1359                                 traceline(eye, v, true, this);
1360                                 if (trace_ent == it || trace_fraction >= 1)
1361                                 {
1362                                         best = it;
1363                                         bestrating = rating;
1364                                 }
1365                         }
1366                 });
1367
1368                 if(!best && have_secondary_targets && !scan_secondary_targets)
1369                 {
1370                         scan_secondary_targets = true;
1371                         // restart the loop
1372                         bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1373                         goto scan_targets;
1374                 }
1375
1376                 // I want to do a second scan if no enemy was found or I don't have weapons
1377                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1378                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1379                         break;
1380                 if(scan_transparent)
1381                         break;
1382
1383                 // Set flags to see through transparent objects
1384                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1385
1386                 scan_transparent = true;
1387         }
1388
1389         // Restore hit flags
1390         this.dphitcontentsmask = hf;
1391
1392         this.enemy = best;
1393         this.havocbot_stickenemy_time = time + autocvar_bot_ai_enemydetectioninterval_stickingtoenemy;
1394         if(best && best.classname == "misc_breakablemodel")
1395                 this.havocbot_stickenemy_time = 0;
1396 }
1397
1398 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1399 {
1400         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1401         // so skip this for them, or they'll never get to reload their weapons at all.
1402         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1403         if(skill < 5)
1404                 return false;
1405
1406         // if this weapon is scheduled for reloading, don't switch to it during combat
1407         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1408         {
1409                 FOREACH(Weapons, it != WEP_Null, {
1410                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1411                                 return true; // other weapon available
1412                 });
1413         }
1414
1415         return false;
1416 }
1417
1418 void havocbot_chooseweapon(entity this, .entity weaponentity)
1419 {
1420         int i;
1421
1422         // ;)
1423         if(g_weaponarena_weapons == WEPSET(TUBA))
1424         {
1425                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1426                 return;
1427         }
1428
1429         // TODO: clean this up by moving it to weapon code
1430         if(this.enemy==NULL)
1431         {
1432                 // If no weapon was chosen get the first available weapon
1433                 if(this.(weaponentity).m_weapon==WEP_Null)
1434                 FOREACH(Weapons, it != WEP_Null, {
1435                         if(client_hasweapon(this, it, weaponentity, true, false))
1436                         {
1437                                 this.(weaponentity).m_switchweapon = it;
1438                                 return;
1439                         }
1440                 });
1441                 return;
1442         }
1443
1444         // Do not change weapon during the next second after a combo
1445         float f = time - this.lastcombotime;
1446         if(f < 1)
1447                 return;
1448
1449         float w;
1450         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1451
1452         // Should it do a weapon combo?
1453         float af, ct, combo_time, combo;
1454
1455         af = ATTACK_FINISHED(this, weaponentity);
1456         ct = autocvar_bot_ai_weapon_combo_threshold;
1457
1458         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1459         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1460         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1461
1462         combo = false;
1463
1464         if(autocvar_bot_ai_weapon_combo)
1465         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1466         if(af > combo_time)
1467         {
1468                 combo = true;
1469                 this.lastcombotime = time;
1470         }
1471
1472         distance *= (2 ** this.bot_rangepreference);
1473
1474         // Custom weapon list based on distance to the enemy
1475         if(bot_custom_weapon){
1476
1477                 // Choose weapons for far distance
1478                 if ( distance > bot_distance_far ) {
1479                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1480                                 w = bot_weapons_far[i];
1481                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1482                                 {
1483                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1484                                                 continue;
1485                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1486                                         return;
1487                                 }
1488                         }
1489                 }
1490
1491                 // Choose weapons for mid distance
1492                 if ( distance > bot_distance_close) {
1493                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1494                                 w = bot_weapons_mid[i];
1495                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1496                                 {
1497                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1498                                                 continue;
1499                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1500                                         return;
1501                                 }
1502                         }
1503                 }
1504
1505                 // Choose weapons for close distance
1506                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1507                         w = bot_weapons_close[i];
1508                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1509                         {
1510                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1511                                         continue;
1512                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1513                                 return;
1514                         }
1515                 }
1516         }
1517 }
1518
1519 void havocbot_aim(entity this)
1520 {
1521         if (time < this.nextaim)
1522                 return;
1523         this.nextaim = time + 0.1;
1524         vector myvel = this.velocity;
1525         if (!this.waterlevel)
1526                 myvel.z = 0;
1527         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1528         else if (this.enemy)
1529         {
1530                 vector enemyvel = this.enemy.velocity;
1531                 if (!this.enemy.waterlevel)
1532                         enemyvel.z = 0;
1533                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1534         }
1535         else
1536                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1537 }
1538
1539 bool havocbot_moveto_refresh_route(entity this)
1540 {
1541         // Refresh path to goal if necessary
1542         entity wp;
1543         wp = this.havocbot_personal_waypoint;
1544         navigation_goalrating_start(this);
1545         navigation_routerating(this, wp, 10000, 10000);
1546         navigation_goalrating_end(this);
1547         return (this.goalentity != NULL);
1548 }
1549
1550 float havocbot_moveto(entity this, vector pos)
1551 {
1552         entity wp;
1553
1554         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1555         {
1556                 // Step 4: Move to waypoint
1557                 if(this.havocbot_personal_waypoint==NULL)
1558                 {
1559                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1560                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1561                         return CMD_STATUS_ERROR;
1562                 }
1563
1564                 if (!bot_strategytoken_taken)
1565                 if(this.havocbot_personal_waypoint_searchtime<time)
1566                 {
1567                         bot_strategytoken_taken = true;
1568                         if(havocbot_moveto_refresh_route(this))
1569                         {
1570                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1571                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1572                                 this.havocbot_personal_waypoint_failcounter = 0;
1573                         }
1574                         else
1575                         {
1576                                 this.havocbot_personal_waypoint_failcounter += 1;
1577                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1578                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1579                                 {
1580                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1581                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1582                                         delete(this.havocbot_personal_waypoint);
1583                                         return CMD_STATUS_ERROR;
1584                                 }
1585                                 else
1586                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1587                         }
1588                 }
1589
1590                 if(autocvar_bot_debug_goalstack)
1591                         debuggoalstack(this);
1592
1593
1594                 // Go!
1595                 havocbot_movetogoal(this);
1596
1597                 if (!this.bot_aimdir_executed && this.goalcurrent)
1598                 {
1599                         // Heading
1600                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1601                         dir -= this.origin + this.view_ofs;
1602                         dir.z = 0;
1603                         bot_aimdir(this, dir, 0);
1604                 }
1605
1606                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1607                 {
1608                         // Step 5: Waypoint reached
1609                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1610                         waypoint_remove(this.havocbot_personal_waypoint);
1611                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1612                         return CMD_STATUS_FINISHED;
1613                 }
1614
1615                 return CMD_STATUS_EXECUTING;
1616         }
1617
1618         // Step 2: Linking waypoint
1619         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1620         {
1621                 // Wait until it is linked
1622                 if(!this.havocbot_personal_waypoint.wplinked)
1623                 {
1624                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1625                         return CMD_STATUS_EXECUTING;
1626                 }
1627
1628                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1629                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1630                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1631
1632                 // Step 3: Route to waypoint
1633                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1634
1635                 return CMD_STATUS_EXECUTING;
1636         }
1637
1638         // Step 1: Spawning waypoint
1639         wp = waypoint_spawnpersonal(this, pos);
1640         if(wp==NULL)
1641         {
1642                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1643                 return CMD_STATUS_ERROR;
1644         }
1645
1646         this.havocbot_personal_waypoint = wp;
1647         this.havocbot_personal_waypoint_failcounter = 0;
1648         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1649
1650         // if pos is inside a teleport, then let's mark it as teleport waypoint
1651         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1652         {
1653                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1654                 this.lastteleporttime = 0;
1655         });
1656
1657 /*
1658         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1659                 print("routing to a teleporter\n");
1660         else
1661                 print("routing to a non-teleporter\n");
1662 */
1663
1664         return CMD_STATUS_EXECUTING;
1665 }
1666
1667 float havocbot_resetgoal(entity this)
1668 {
1669         navigation_clearroute(this);
1670         return CMD_STATUS_FINISHED;
1671 }
1672
1673 void havocbot_setupbot(entity this)
1674 {
1675         this.bot_ai = havocbot_ai;
1676         this.cmd_moveto = havocbot_moveto;
1677         this.cmd_resetgoal = havocbot_resetgoal;
1678
1679         // NOTE: bot is not player yet
1680         havocbot_chooserole(this);
1681 }
1682
1683 vector havocbot_dodge(entity this)
1684 {
1685         // LordHavoc: disabled because this is too expensive
1686         return '0 0 0';
1687 #if 0
1688         entity head;
1689         vector dodge, v, n;
1690         float danger, bestdanger, vl, d;
1691         dodge = '0 0 0';
1692         bestdanger = -20;
1693         // check for dangerous objects near bot or approaching bot
1694         head = findchainfloat(bot_dodge, true);
1695         while(head)
1696         {
1697                 if (head.owner != this)
1698                 {
1699                         vl = vlen(head.velocity);
1700                         if (vl > autocvar_sv_maxspeed * 0.3)
1701                         {
1702                                 n = normalize(head.velocity);
1703                                 v = this.origin - head.origin;
1704                                 d = v * n;
1705                                 if (d > (0 - head.bot_dodgerating))
1706                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1707                                 {
1708                                         // calculate direction and distance from the flight path, by removing the forward axis
1709                                         v = v - (n * (v * n));
1710                                         danger = head.bot_dodgerating - vlen(v);
1711                                         if (bestdanger < danger)
1712                                         {
1713                                                 bestdanger = danger;
1714                                                 // dodge to the side of the object
1715                                                 dodge = normalize(v);
1716                                         }
1717                                 }
1718                         }
1719                         else
1720                         {
1721                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1722                                 if (bestdanger < danger)
1723                                 {
1724                                         bestdanger = danger;
1725                                         dodge = normalize(this.origin - head.origin);
1726                                 }
1727                         }
1728                 }
1729                 head = head.chain;
1730         }
1731         return dodge;
1732 #endif
1733 }