qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "../cvars.qh"
   4
   5 #include "../aim.qh"
   6 #include "../bot.qh"
   7 #include "../navigation.qh"
   8 #include "../scripting.qh"
   9 #include "../waypoints.qh"
  10
  11 #include <common/constants.qh>
  12 #include <common/physics/player.qh>
  13 #include <common/state.qh>
  14 #include <common/items/_mod.qh>
  15
  16 #include <common/triggers/teleporters.qh>
  17 #include <common/triggers/trigger/jumppads.qh>
  18
  19 #include <lib/warpzone/common.qh>
  20
  21 .float speed;
  22
  23 void havocbot_ai(entity this)
  24 {
  25         if(this.draggedby)
  26                 return;
  27
  28         if(bot_execute_commands(this))
  29                 return;
  30
  31         if (bot_strategytoken == this)
  32         if (!bot_strategytoken_taken)
  33         {
  34                 if(this.havocbot_blockhead)
  35                 {
  36                         this.havocbot_blockhead = false;
  37                 }
  38                 else
  39                 {
  40                         if (!this.jumppadcount)
  41                                 this.havocbot_role(this); // little too far down the rabbit hole
  42                 }
  43
  44                 // TODO: tracewalk() should take care of this job (better path finding under water)
  45                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  46                 if(IS_DEAD(this))
  47                 if(!this.goalcurrent)
  48                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  49                 {
  50                         // Look for the closest waypoint out of water
  51                         entity newgoal = NULL;
  52                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  53                         {
  54                                 if(it.origin.z < this.origin.z)
  55                                         continue;
  56
  57                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  58                                         continue;
  59
  60                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  61                                         continue;
  62
  63                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  64
  65                                 if(trace_fraction < 1)
  66                                         continue;
  67
  68                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  69                                         newgoal = it;
  70                         });
  71
  72                         if(newgoal)
  73                         {
  74                         //      te_wizspike(newgoal.origin);
  75                                 navigation_pushroute(this, newgoal);
  76                         }
  77                 }
  78
  79                 // token has been used this frame
  80                 bot_strategytoken_taken = true;
  81         }
  82
  83         if(IS_DEAD(this))
  84                 return;
  85
  86         havocbot_chooseenemy(this);
  87         if (this.bot_chooseweapontime < time )
  88         {
  89                 this.bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  90                 havocbot_chooseweapon(this);
  91         }
  92         havocbot_aim(this);
  93         lag_update(this);
  94         if (this.bot_aimtarg)
  95         {
  96                 this.aistatus |= AI_STATUS_ATTACKING;
  97                 this.aistatus &= ~AI_STATUS_ROAMING;
  98
  99                 if(this.weapons)
 100                 {
 101                         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 102                         Weapon w = this.(weaponentity).m_weapon;
 103                         w.wr_aim(w, this);
 104                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 105                         {
 106                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 107                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 108                         }
 109                         else
 110                         {
 111                                 if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))
 112                                         this.lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 113                         }
 114                 }
 115                 else
 116                 {
 117                         if(IS_PLAYER(this.bot_aimtarg))
 118                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 119                 }
 120         }
 121         else if (this.goalcurrent)
 122         {
 123                 this.aistatus |= AI_STATUS_ROAMING;
 124                 this.aistatus &= ~AI_STATUS_ATTACKING;
 125
 126                 vector now,v,next;//,heading;
 127                 float aimdistance,skillblend,distanceblend,blend;
 128                 next = now = ( (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5) - (this.origin + this.view_ofs);
 129                 aimdistance = vlen(now);
 130                 //heading = this.velocity;
 131                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 132                 if(
 133                         this.goalstack01 != this && this.goalstack01 != NULL && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 134                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 135                 )
 136                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 137
 138                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 139                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 140                 blend = skillblend * (1-distanceblend);
 141                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 142                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 143                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 144                 v = now + blend * (next - now);
 145                 //dprint(etos(this), " ");
 146                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 147                 //v = now * (distanceblend) + next * (1-distanceblend);
 148                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 149                         v.z = 0;
 150                 //dprint("walk at:", vtos(v), "\n");
 151                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 152                 bot_aimdir(this, v, -1);
 153         }
 154         havocbot_movetogoal(this);
 155
 156         // if the bot is not attacking, consider reloading weapons
 157         if (!(this.aistatus & AI_STATUS_ATTACKING))
 158         {
 159                 // we are currently holding a weapon that's not fully loaded, reload it
 160                 if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 161                 if(this.clip_load < this.clip_size)
 162                         this.impulse = 20; // "press" the reload button, not sure if this is done right
 163
 164                 // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 165                 // the code above executes next frame, starting the reloading then
 166                 if(skill >= 5) // bots can only look for unloaded weapons past this skill
 167                 if(this.clip_load >= 0) // only if we're not reloading a weapon already
 168                 {
 169                         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 170                         FOREACH(Weapons, it != WEP_Null, LAMBDA(
 171                                 if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.weapon_load[it.m_id] < it.reloading_ammo))
 172                                         this.(weaponentity).m_switchweapon = it;
 173                         ));
 174                 }
 175         }
 176 }
 177
 178 void havocbot_keyboard_movement(entity this, vector destorg)
 179 {
 180         vector keyboard;
 181         float blend, maxspeed;
 182         float sk;
 183
 184         sk = skill + this.bot_moveskill;
 185
 186         maxspeed = autocvar_sv_maxspeed;
 187
 188         if (time < this.havocbot_keyboardtime)
 189                 return;
 190
 191         this.havocbot_keyboardtime =
 192                 max(
 193                         this.havocbot_keyboardtime
 194                                 + 0.05/max(1, sk+this.havocbot_keyboardskill)
 195                                 + random()*0.025/max(0.00025, skill+this.havocbot_keyboardskill)
 196                 , time);
 197         keyboard = this.movement * (1.0 / maxspeed);
 198
 199         float trigger, trigger1;
 200         blend = bound(0,sk*0.1,1);
 201         trigger = autocvar_bot_ai_keyboard_threshold;
 202         trigger1 = 0 - trigger;
 203
 204         // categorize forward movement
 205         // at skill < 1.5 only forward
 206         // at skill < 2.5 only individual directions
 207         // at skill < 4.5 only individual directions, and forward diagonals
 208         // at skill >= 4.5, all cases allowed
 209         if (keyboard.x > trigger)
 210         {
 211                 keyboard.x = 1;
 212                 if (sk < 2.5)
 213                         keyboard.y = 0;
 214         }
 215         else if (keyboard.x < trigger1 && sk > 1.5)
 216         {
 217                 keyboard.x = -1;
 218                 if (sk < 4.5)
 219                         keyboard.y = 0;
 220         }
 221         else
 222         {
 223                 keyboard.x = 0;
 224                 if (sk < 1.5)
 225                         keyboard.y = 0;
 226         }
 227         if (sk < 4.5)
 228                 keyboard.z = 0;
 229
 230         if (keyboard.y > trigger)
 231                 keyboard.y = 1;
 232         else if (keyboard.y < trigger1)
 233                 keyboard.y = -1;
 234         else
 235                 keyboard.y = 0;
 236
 237         if (keyboard.z > trigger)
 238                 keyboard.z = 1;
 239         else if (keyboard.z < trigger1)
 240                 keyboard.z = -1;
 241         else
 242                 keyboard.z = 0;
 243
 244         this.havocbot_keyboard = keyboard * maxspeed;
 245         if (this.havocbot_ducktime>time) PHYS_INPUT_BUTTON_CROUCH(this) = true;
 246
 247         keyboard = this.havocbot_keyboard;
 248         blend = bound(0,vlen(destorg-this.origin)/autocvar_bot_ai_keyboard_distance,1); // When getting close move with 360 degree
 249         //dprint("movement ", vtos(this.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 250         this.movement = this.movement + (keyboard - this.movement) * blend;
 251 }
 252
 253 void havocbot_bunnyhop(entity this, vector dir)
 254 {
 255         float bunnyhopdistance;
 256         vector deviation;
 257         float maxspeed;
 258         vector gco, gno;
 259
 260         // Don't jump when attacking
 261         if(this.aistatus & AI_STATUS_ATTACKING)
 262                 return;
 263
 264         if(IS_PLAYER(this.goalcurrent))
 265                 return;
 266
 267         maxspeed = autocvar_sv_maxspeed;
 268
 269         if(this.aistatus & AI_STATUS_DANGER_AHEAD)
 270         {
 271                 this.aistatus &= ~AI_STATUS_RUNNING;
 272                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 273                 this.bot_canruntogoal = 0;
 274                 this.bot_timelastseengoal = 0;
 275                 return;
 276         }
 277
 278         if(this.waterlevel > WATERLEVEL_WETFEET)
 279         {
 280                 this.aistatus &= ~AI_STATUS_RUNNING;
 281                 return;
 282         }
 283
 284         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 285         {
 286                 this.bot_canruntogoal = 0;
 287                 this.bot_timelastseengoal = 0;
 288         }
 289
 290         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 291         bunnyhopdistance = vlen(this.origin - gco);
 292
 293         // Run only to visible goals
 294         if(IS_ONGROUND(this))
 295         if(this.speed==maxspeed)
 296         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 297         {
 298                         this.bot_lastseengoal = this.goalcurrent;
 299
 300                         // seen it before
 301                         if(this.bot_timelastseengoal)
 302                         {
 303                                 // for a period of time
 304                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 305                                 {
 306                                         float checkdistance;
 307                                         checkdistance = true;
 308
 309                                         // don't run if it is too close
 310                                         if(this.bot_canruntogoal==0)
 311                                         {
 312                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 313                                                         this.bot_canruntogoal = 1;
 314                                                 else
 315                                                         this.bot_canruntogoal = -1;
 316                                         }
 317
 318                                         if(this.bot_canruntogoal != 1)
 319                                                 return;
 320
 321                                         if(this.aistatus & AI_STATUS_ROAMING)
 322                                         if(this.goalcurrent.classname=="waypoint")
 323                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 324                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 325                                         if(this.goalstack01!=NULL)
 326                                         {
 327                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 328                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 329                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 330                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 331
 332                                                 if(fabs(deviation.y) < 20)
 333                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 334                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 335                                                 {
 336                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 337                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 338                                                         {
 339                                                                 checkdistance = false;
 340                                                         }
 341                                                 }
 342                                         }
 343
 344                                         if(checkdistance)
 345                                         {
 346                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 347                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance)
 348                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 349                                         }
 350                                         else
 351                                         {
 352                                                 this.aistatus |= AI_STATUS_RUNNING;
 353                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 354                                         }
 355                                 }
 356                         }
 357                         else
 358                         {
 359                                 this.bot_timelastseengoal = time;
 360                         }
 361         }
 362         else
 363         {
 364                 this.bot_timelastseengoal = 0;
 365         }
 366
 367 #if 0
 368         // Release jump button
 369         if(!cvar("sv_pogostick"))
 370         if((IS_ONGROUND(this)) == 0)
 371         {
 372                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 373                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 374
 375                 // Strafe
 376                 if(this.aistatus & AI_STATUS_RUNNING)
 377                 if(vlen(this.velocity)>maxspeed)
 378                 {
 379                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 380                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 381                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 382
 383                         if(fabs(deviation.y)>10)
 384                                 this.movement_x = 0;
 385
 386                         if(deviation.y>10)
 387                                 this.movement_y = maxspeed * -1;
 388                         else if(deviation.y<10)
 389                                 this.movement_y = maxspeed;
 390
 391                 }
 392         }
 393 #endif
 394 }
 395
 396 void havocbot_movetogoal(entity this)
 397 {
 398         vector destorg;
 399         vector diff;
 400         vector dir;
 401         vector flatdir;
 402         vector m1;
 403         vector m2;
 404         vector evadeobstacle;
 405         vector evadelava;
 406         float s;
 407         float maxspeed;
 408         vector gco;
 409         //float dist;
 410         vector dodge;
 411         //if (this.goalentity)
 412         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 413         this.movement = '0 0 0';
 414         maxspeed = autocvar_sv_maxspeed;
 415
 416         // Jetpack navigation
 417         if(this.goalcurrent)
 418         if(this.navigation_jetpack_goal)
 419         if(this.goalcurrent==this.navigation_jetpack_goal)
 420         if(this.ammo_fuel)
 421         {
 422                 if(autocvar_bot_debug_goalstack)
 423                 {
 424                         debuggoalstack(this);
 425                         te_wizspike(this.navigation_jetpack_point);
 426                 }
 427
 428                 // Take off
 429                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 430                 {
 431                         // Brake almost completely so it can get a good direction
 432                         if(vdist(this.velocity, >, 10))
 433                                 return;
 434                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 435                 }
 436
 437                 makevectors(this.v_angle.y * '0 1 0');
 438                 dir = normalize(this.navigation_jetpack_point - this.origin);
 439
 440                 // Landing
 441                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 442                 {
 443                         // Calculate brake distance in xy
 444                         float db, v, d;
 445                         vector dxy;
 446
 447                         dxy = this.origin - ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ); dxy.z = 0;
 448                         d = vlen(dxy);
 449                         v = vlen(this.velocity -  this.velocity.z * '0 0 1');
 450                         db = (pow(v,2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 451                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 452                         if(d < db || d < 500)
 453                         {
 454                                 // Brake
 455                                 if(fabs(this.velocity.x)>maxspeed*0.3)
 456                                 {
 457                                         this.movement_x = dir * v_forward * -maxspeed;
 458                                         return;
 459                                 }
 460                                 // Switch to normal mode
 461                                 this.navigation_jetpack_goal = NULL;
 462                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 463                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 464                                 return;
 465                         }
 466                 }
 467                 else if(checkpvs(this.origin,this.goalcurrent))
 468                 {
 469                         // If I can see the goal switch to landing code
 470                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 471                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 472                         return;
 473                 }
 474
 475                 // Flying
 476                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 477                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, NULL).z + STAT(PL_MIN, NULL).z < this.origin.z)
 478                 {
 479                         this.movement_x = dir * v_forward * maxspeed;
 480                         this.movement_y = dir * v_right * maxspeed;
 481                 }
 482                 return;
 483         }
 484
 485         // Handling of jump pads
 486         if(this.jumppadcount)
 487         {
 488                 // If got stuck on the jump pad try to reach the farthest visible waypoint
 489                 if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 490                 {
 491                         if(fabs(this.velocity.z)<50)
 492                         {
 493                                 entity newgoal = NULL;
 494                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 495                                 {
 496                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 497
 498                                         if(trace_fraction < 1)
 499                                                 continue;
 500
 501                                         if(!newgoal || vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin))
 502                                                 newgoal = it;
 503                                 });
 504
 505                                 if(newgoal)
 506                                 {
 507                                         this.ignoregoal = this.goalcurrent;
 508                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 509                                         navigation_clearroute(this);
 510                                         navigation_routetogoal(this, newgoal, this.origin);
 511                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 512                                 }
 513                         }
 514                         else
 515                                 return;
 516                 }
 517                 else
 518                 {
 519                         if(this.velocity.z>0)
 520                         {
 521                                 float threshold;
 522                                 vector velxy = this.velocity; velxy_z = 0;
 523                                 threshold = maxspeed * 0.2;
 524                                 if(vdist(velxy, <, threshold))
 525                                 {
 526                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 527                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 528                                 }
 529                                 return;
 530                         }
 531
 532                         // Don't chase players while using a jump pad
 533                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 534                                 return;
 535                 }
 536         }
 537         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 538                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 539
 540         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 541         if(skill>6)
 542         if (!(IS_ONGROUND(this)))
 543         {
 544                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 545                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 546                 if(this.items & IT_JETPACK)
 547                 {
 548                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 549                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 550                         {
 551                                 if(this.velocity.z<0)
 552                                 {
 553                                         PHYS_INPUT_BUTTON_HOOK(this) = true;
 554                                 }
 555                         }
 556                         else
 557                                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 558
 559                         // If there is no goal try to move forward
 560
 561                         if(this.goalcurrent==NULL)
 562                                 dir = v_forward;
 563                         else
 564                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 565
 566                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 567                         float xyspeed = xyvelocity * dir;
 568
 569                         if(xyspeed < (maxspeed / 2))
 570                         {
 571                                 makevectors(this.v_angle.y * '0 1 0');
 572                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 573                                 if(trace_fraction==1)
 574                                 {
 575                                         this.movement_x = dir * v_forward * maxspeed;
 576                                         this.movement_y = dir * v_right * maxspeed;
 577                                         if (skill < 10)
 578                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 579                                 }
 580                         }
 581
 582                         this.havocbot_blockhead = true;
 583
 584                         return;
 585                 }
 586                 else if(this.health>WEP_CVAR(devastator, damage)*0.5)
 587                 {
 588                         if(this.velocity.z < 0)
 589                         if(client_hasweapon(this, WEP_DEVASTATOR, true, false))
 590                         {
 591                                 this.movement_x = maxspeed;
 592
 593                                 if(this.rocketjumptime)
 594                                 {
 595                                         if(time > this.rocketjumptime)
 596                                         {
 597                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 598                                                 this.rocketjumptime = 0;
 599                                         }
 600                                         return;
 601                                 }
 602
 603                                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 604                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 605                                 this.v_angle_x = 90;
 606                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 607                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 608                                 return;
 609                         }
 610                 }
 611                 else
 612                 {
 613                         // If there is no goal try to move forward
 614                         if(this.goalcurrent==NULL)
 615                                 this.movement_x = maxspeed;
 616                 }
 617         }
 618
 619         // If we are under water with no goals, swim up
 620         if(this.waterlevel)
 621         if(this.goalcurrent==NULL)
 622         {
 623                 dir = '0 0 0';
 624                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 625                         dir.z = 1;
 626                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 627                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 628                 else
 629                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 630                 makevectors(this.v_angle.y * '0 1 0');
 631                 this.movement_x = dir * v_forward * maxspeed;
 632                 this.movement_y = dir * v_right * maxspeed;
 633                 this.movement_z = dir * v_up * maxspeed;
 634         }
 635
 636         // if there is nowhere to go, exit
 637         if (this.goalcurrent == NULL)
 638                 return;
 639
 640         if (this.goalcurrent)
 641                 navigation_poptouchedgoals(this);
 642
 643         // if ran out of goals try to use an alternative goal or get a new strategy asap
 644         if(this.goalcurrent == NULL)
 645         {
 646                 this.bot_strategytime = 0;
 647                 return;
 648         }
 649
 650
 651         if(autocvar_bot_debug_goalstack)
 652                 debuggoalstack(this);
 653
 654         m1 = this.goalcurrent.origin + this.goalcurrent.mins;
 655         m2 = this.goalcurrent.origin + this.goalcurrent.maxs;
 656         destorg = this.origin;
 657         destorg.x = bound(m1_x, destorg.x, m2_x);
 658         destorg.y = bound(m1_y, destorg.y, m2_y);
 659         destorg.z = bound(m1_z, destorg.z, m2_z);
 660         diff = destorg - this.origin;
 661         //dist = vlen(diff);
 662         dir = normalize(diff);
 663         flatdir = diff;flatdir.z = 0;
 664         flatdir = normalize(flatdir);
 665         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 666
 667         //if (this.bot_dodgevector_time < time)
 668         {
 669         //      this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 670         //      this.bot_dodgevector_jumpbutton = 1;
 671                 evadeobstacle = '0 0 0';
 672                 evadelava = '0 0 0';
 673
 674                 if (this.waterlevel)
 675                 {
 676                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 677                         {
 678                         //      flatdir_z = 1;
 679                                 this.aistatus |= AI_STATUS_OUT_WATER;
 680                         }
 681                         else
 682                         {
 683                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 684                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 685                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 686                                 else
 687                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 688                         }
 689                         dir = normalize(flatdir);
 690                         makevectors(this.v_angle.y * '0 1 0');
 691                 }
 692                 else
 693                 {
 694                         if(this.aistatus & AI_STATUS_OUT_WATER)
 695                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 696
 697                         // jump if going toward an obstacle that doesn't look like stairs we
 698                         // can walk up directly
 699                         tracebox(this.origin, this.mins, this.maxs, this.origin + this.velocity * 0.2, false, this);
 700                         if (trace_fraction < 1)
 701                         if (trace_plane_normal.z < 0.7)
 702                         {
 703                                 s = trace_fraction;
 704                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + this.velocity * 0.2 + stepheightvec, false, this);
 705                                 if (trace_fraction < s + 0.01)
 706                                 if (trace_plane_normal.z < 0.7)
 707                                 {
 708                                         s = trace_fraction;
 709                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + this.velocity * 0.2 + jumpstepheightvec, false, this);
 710                                         if (trace_fraction > s)
 711                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 712                                 }
 713                         }
 714
 715                         // avoiding dangers and obstacles
 716                         vector dst_ahead, dst_down;
 717                         makevectors(this.v_angle.y * '0 1 0');
 718                         dst_ahead = this.origin + this.view_ofs + (this.velocity * 0.4) + (v_forward * 32 * 3);
 719                         dst_down = dst_ahead - '0 0 1500';
 720
 721                         // Look ahead
 722                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 723
 724                         // Check head-banging against walls
 725                         if(vdist(this.origin + this.view_ofs - trace_endpos, <, 25) && !(this.aistatus & AI_STATUS_OUT_WATER))
 726                         {
 727                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 728                                 if(this.facingwalltime && time > this.facingwalltime)
 729                                 {
 730                                         this.ignoregoal = this.goalcurrent;
 731                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 732                                         this.bot_strategytime = 0;
 733                                         return;
 734                                 }
 735                                 else
 736                                 {
 737                                         this.facingwalltime = time + 0.05;
 738                                 }
 739                         }
 740                         else
 741                         {
 742                                 this.facingwalltime = 0;
 743
 744                                 if(this.ignoregoal != NULL && time > this.ignoregoaltime)
 745                                 {
 746                                         this.ignoregoal = NULL;
 747                                         this.ignoregoaltime = 0;
 748                                 }
 749                         }
 750
 751                         // Check for water/slime/lava and dangerous edges
 752                         // (only when the bot is on the ground or jumping intentionally)
 753                         this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 754
 755                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 756                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || PHYS_INPUT_BUTTON_JUMP(this))
 757                         {
 758                                 // Look downwards
 759                                 traceline(dst_ahead , dst_down, true, NULL);
 760                         //      te_lightning2(NULL, this.origin, dst_ahead);    // Draw "ahead" look
 761                         //      te_lightning2(NULL, dst_ahead, dst_down);               // Draw "downwards" look
 762                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 763                                 {
 764                                         s = pointcontents(trace_endpos + '0 0 1');
 765                                         if (s != CONTENT_SOLID)
 766                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 767                                                 evadelava = normalize(this.velocity) * -1;
 768                                         else if (s == CONTENT_SKY)
 769                                                 evadeobstacle = normalize(this.velocity) * -1;
 770                                         else if (!boxesoverlap(dst_ahead - this.view_ofs + this.mins, dst_ahead - this.view_ofs + this.maxs,
 771                                                                 this.goalcurrent.absmin, this.goalcurrent.absmax))
 772                                         {
 773                                                 // if ain't a safe goal with "holes" (like the jumpad on soylent)
 774                                                 // and there is a trigger_hurt below
 775                                                 if(tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 776                                                 {
 777                                                         // Remove dangerous dynamic goals from stack
 778                                                         LOG_TRACE("bot ", this.netname, " avoided the goal ", this.goalcurrent.classname, " ", etos(this.goalcurrent), " because it led to a dangerous path; goal stack cleared");
 779                                                         navigation_clearroute(this);
 780                                                         return;
 781                                                 }
 782                                         }
 783                                 }
 784                         }
 785
 786                         dir = flatdir;
 787                         evadeobstacle.z = 0;
 788                         evadelava.z = 0;
 789                         makevectors(this.v_angle.y * '0 1 0');
 790
 791                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
 792                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 793                 }
 794
 795                 dodge = havocbot_dodge(this);
 796                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 797                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 798                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 799                 if(IS_PLAYER(trace_ent))
 800                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 801
 802                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 803         //      this.bot_dodgevector = dir;
 804         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 805         }
 806
 807         if(time < this.ladder_time)
 808         {
 809                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 810                 {
 811                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 812                                 dir.z = 1;
 813                 }
 814                 else
 815                 {
 816                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 817                                 dir.z = -1;
 818                 }
 819         }
 820
 821         //dir = this.bot_dodgevector;
 822         //if (this.bot_dodgevector_jumpbutton)
 823         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 824         this.movement_x = dir * v_forward * maxspeed;
 825         this.movement_y = dir * v_right * maxspeed;
 826         this.movement_z = dir * v_up * maxspeed;
 827
 828         // Emulate keyboard interface
 829         if (skill < 10)
 830                 havocbot_keyboard_movement(this, destorg);
 831
 832         // Bunnyhop!
 833 //      if(this.aistatus & AI_STATUS_ROAMING)
 834         if(this.goalcurrent)
 835         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 836                 havocbot_bunnyhop(this, dir);
 837
 838         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
 839         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
 840         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
 841 }
 842
 843 entity havocbot_gettarget(entity this, bool secondary)
 844 {
 845         entity best = NULL;
 846         vector eye = CENTER_OR_VIEWOFS(this);
 847         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
 848         {
 849                 vector v = CENTER_OR_VIEWOFS(it);
 850                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 851                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
 852                 if(bot_shouldattack(this, it))
 853                 {
 854                         traceline(eye, v, true, this);
 855                         if (trace_ent == it || trace_fraction >= 1)
 856                                 best = it;
 857                 }
 858         });
 859
 860         return best;
 861 }
 862
 863 void havocbot_chooseenemy(entity this)
 864 {
 865         entity head, best, head2;
 866         float rating, bestrating, hf;
 867         vector eye, v;
 868         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 869         {
 870                 this.enemy = NULL;
 871                 return;
 872         }
 873         if (this.enemy)
 874         {
 875                 if (!bot_shouldattack(this, this.enemy))
 876                 {
 877                         // enemy died or something, find a new target
 878                         this.enemy = NULL;
 879                         this.havocbot_chooseenemy_finished = time;
 880                 }
 881                 else if (this.havocbot_stickenemy)
 882                 {
 883                         // tracking last chosen enemy
 884                         // if enemy is visible
 885                         // and not really really far away
 886                         // and we're not severely injured
 887                         // then keep tracking for a half second into the future
 888                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
 889                         if (trace_ent == this.enemy || trace_fraction == 1)
 890                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
 891                         if (this.health > 30)
 892                         {
 893                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 894                                 this.havocbot_chooseenemy_finished = time + 0.5;
 895                                 return;
 896                         }
 897                         // enemy isn't visible, or is far away, or we're injured severely
 898                         // so stop preferring this enemy
 899                         // (it will still take a half second until a new one is chosen)
 900                         this.havocbot_stickenemy = 0;
 901                 }
 902         }
 903         if (time < this.havocbot_chooseenemy_finished)
 904                 return;
 905         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
 906         eye = this.origin + this.view_ofs;
 907         best = NULL;
 908         bestrating = 100000000;
 909         head = head2 = findchainfloat(bot_attack, true);
 910
 911         // Backup hit flags
 912         hf = this.dphitcontentsmask;
 913
 914         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
 915
 916         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 917
 918         bool scan_transparent = false;
 919         bool scan_secondary_targets = false;
 920         bool have_secondary_targets = false;
 921         while(true)
 922         {
 923                 scan_secondary_targets = false;
 924 LABEL(scan_targets)
 925                 for( ; head; head = head.chain)
 926                 {
 927                         if(!scan_secondary_targets)
 928                         {
 929                                 if(head.classname == "misc_breakablemodel")
 930                                 {
 931                                         have_secondary_targets = true;
 932                                         continue;
 933                                 }
 934                         }
 935                         else
 936                         {
 937                                 if(head.classname != "misc_breakablemodel")
 938                                         continue;
 939                         }
 940
 941                         v = (head.absmin + head.absmax) * 0.5;
 942                         rating = vlen(v - eye);
 943                         if (rating<autocvar_bot_ai_enemydetectionradius)
 944                         if (bestrating > rating)
 945                         if (bot_shouldattack(this, head))
 946                         {
 947                                 traceline(eye, v, true, this);
 948                                 if (trace_ent == head || trace_fraction >= 1)
 949                                 {
 950                                         best = head;
 951                                         bestrating = rating;
 952                                 }
 953                         }
 954                 }
 955
 956                 if(!best && have_secondary_targets && !scan_secondary_targets)
 957                 {
 958                         scan_secondary_targets = true;
 959                         // restart the loop
 960                         head = head2;
 961                         bestrating = 100000000;
 962                         goto scan_targets;
 963                 }
 964
 965                 // I want to do a second scan if no enemy was found or I don't have weapons
 966                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
 967                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
 968                         break;
 969                 if(scan_transparent)
 970                         break;
 971
 972                 // Set flags to see through transparent objects
 973                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
 974
 975                 head = head2;
 976                 scan_transparent = true;
 977         }
 978
 979         // Restore hit flags
 980         this.dphitcontentsmask = hf;
 981
 982         this.enemy = best;
 983         this.havocbot_stickenemy = true;
 984         if(best && best.classname == "misc_breakablemodel")
 985                 this.havocbot_stickenemy = false;
 986 }
 987
 988 float havocbot_chooseweapon_checkreload(entity this, int new_weapon)
 989 {
 990         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
 991         // so skip this for them, or they'll never get to reload their weapons at all.
 992         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
 993         if(skill < 5)
 994                 return false;
 995
 996         // if this weapon is scheduled for reloading, don't switch to it during combat
 997         if (this.weapon_load[new_weapon] < 0)
 998         {
 999                 bool other_weapon_available = false;
1000                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1001                         if(it.wr_checkammo1(it, this) + it.wr_checkammo2(it, this))
1002                                 other_weapon_available = true;
1003                 ));
1004                 if(other_weapon_available)
1005                         return true;
1006         }
1007
1008         return false;
1009 }
1010
1011 void havocbot_chooseweapon(entity this)
1012 {
1013         int i;
1014
1015         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
1016
1017         // ;)
1018         if(g_weaponarena_weapons == WEPSET(TUBA))
1019         {
1020                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1021                 return;
1022         }
1023
1024         // TODO: clean this up by moving it to weapon code
1025         if(this.enemy==NULL)
1026         {
1027                 // If no weapon was chosen get the first available weapon
1028                 if(this.(weaponentity).m_weapon==WEP_Null)
1029                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1030                         if(client_hasweapon(this, it, true, false))
1031                         {
1032                                 this.(weaponentity).m_switchweapon = it;
1033                                 return;
1034                         }
1035                 ));
1036                 return;
1037         }
1038
1039         // Do not change weapon during the next second after a combo
1040         float f = time - this.lastcombotime;
1041         if(f < 1)
1042                 return;
1043
1044         float w;
1045         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1046
1047         // Should it do a weapon combo?
1048         float af, ct, combo_time, combo;
1049
1050         af = ATTACK_FINISHED(this, 0);
1051         ct = autocvar_bot_ai_weapon_combo_threshold;
1052
1053         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1054         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1055         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1056
1057         combo = false;
1058
1059         if(autocvar_bot_ai_weapon_combo)
1060         if(this.(weaponentity).m_weapon.m_id == this.lastfiredweapon)
1061         if(af > combo_time)
1062         {
1063                 combo = true;
1064                 this.lastcombotime = time;
1065         }
1066
1067         distance *= pow(2, this.bot_rangepreference);
1068
1069         // Custom weapon list based on distance to the enemy
1070         if(bot_custom_weapon){
1071
1072                 // Choose weapons for far distance
1073                 if ( distance > bot_distance_far ) {
1074                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1075                                 w = bot_weapons_far[i];
1076                                 if ( client_hasweapon(this, Weapons_from(w), true, false) )
1077                                 {
1078                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, w))
1079                                                 continue;
1080                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1081                                         return;
1082                                 }
1083                         }
1084                 }
1085
1086                 // Choose weapons for mid distance
1087                 if ( distance > bot_distance_close) {
1088                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1089                                 w = bot_weapons_mid[i];
1090                                 if ( client_hasweapon(this, Weapons_from(w), true, false) )
1091                                 {
1092                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, w))
1093                                                 continue;
1094                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1095                                         return;
1096                                 }
1097                         }
1098                 }
1099
1100                 // Choose weapons for close distance
1101                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1102                         w = bot_weapons_close[i];
1103                         if ( client_hasweapon(this, Weapons_from(w), true, false) )
1104                         {
1105                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, w))
1106                                         continue;
1107                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1108                                 return;
1109                         }
1110                 }
1111         }
1112 }
1113
1114 void havocbot_aim(entity this)
1115 {
1116         vector myvel, enemyvel;
1117 //      if(this.flags & FL_INWATER)
1118 //              return;
1119         if (time < this.nextaim)
1120                 return;
1121         this.nextaim = time + 0.1;
1122         myvel = this.velocity;
1123         if (!this.waterlevel)
1124                 myvel.z = 0;
1125         if (this.enemy)
1126         {
1127                 enemyvel = this.enemy.velocity;
1128                 if (!this.enemy.waterlevel)
1129                         enemyvel.z = 0;
1130                 lag_additem(this, time + this.ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1131         }
1132         else
1133                 lag_additem(this, time + this.ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1134 }
1135
1136 bool havocbot_moveto_refresh_route(entity this)
1137 {
1138         // Refresh path to goal if necessary
1139         entity wp;
1140         wp = this.havocbot_personal_waypoint;
1141         navigation_goalrating_start(this);
1142         navigation_routerating(this, wp, 10000, 10000);
1143         navigation_goalrating_end(this);
1144         return this.navigation_hasgoals;
1145 }
1146
1147 float havocbot_moveto(entity this, vector pos)
1148 {
1149         entity wp;
1150
1151         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1152         {
1153                 // Step 4: Move to waypoint
1154                 if(this.havocbot_personal_waypoint==NULL)
1155                 {
1156                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1157                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1158                         return CMD_STATUS_ERROR;
1159                 }
1160
1161                 if (!bot_strategytoken_taken)
1162                 if(this.havocbot_personal_waypoint_searchtime<time)
1163                 {
1164                         bot_strategytoken_taken = true;
1165                         if(havocbot_moveto_refresh_route(this))
1166                         {
1167                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1168                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1169                                 this.havocbot_personal_waypoint_failcounter = 0;
1170                         }
1171                         else
1172                         {
1173                                 this.havocbot_personal_waypoint_failcounter += 1;
1174                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1175                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1176                                 {
1177                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1178                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1179                                         delete(this.havocbot_personal_waypoint);
1180                                         return CMD_STATUS_ERROR;
1181                                 }
1182                                 else
1183                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1184                         }
1185                 }
1186
1187                 if(autocvar_bot_debug_goalstack)
1188                         debuggoalstack(this);
1189
1190                 // Heading
1191                 vector dir = ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - (this.origin + this.view_ofs);
1192                 dir.z = 0;
1193                 bot_aimdir(this, dir, -1);
1194
1195                 // Go!
1196                 havocbot_movetogoal(this);
1197
1198                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1199                 {
1200                         // Step 5: Waypoint reached
1201                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1202                         delete(this.havocbot_personal_waypoint);
1203                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1204                         return CMD_STATUS_FINISHED;
1205                 }
1206
1207                 return CMD_STATUS_EXECUTING;
1208         }
1209
1210         // Step 2: Linking waypoint
1211         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1212         {
1213                 // Wait until it is linked
1214                 if(!this.havocbot_personal_waypoint.wplinked)
1215                 {
1216                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1217                         return CMD_STATUS_EXECUTING;
1218                 }
1219
1220                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1221                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1222                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1223
1224                 // Step 3: Route to waypoint
1225                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1226
1227                 return CMD_STATUS_EXECUTING;
1228         }
1229
1230         // Step 1: Spawning waypoint
1231         wp = waypoint_spawnpersonal(this, pos);
1232         if(wp==NULL)
1233         {
1234                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1235                 return CMD_STATUS_ERROR;
1236         }
1237
1238         this.havocbot_personal_waypoint = wp;
1239         this.havocbot_personal_waypoint_failcounter = 0;
1240         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1241
1242         // if pos is inside a teleport, then let's mark it as teleport waypoint
1243         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1244         {
1245                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1246                 this.lastteleporttime = 0;
1247         });
1248
1249 /*
1250         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1251                 print("routing to a teleporter\n");
1252         else
1253                 print("routing to a non-teleporter\n");
1254 */
1255
1256         return CMD_STATUS_EXECUTING;
1257 }
1258
1259 float havocbot_resetgoal(entity this)
1260 {
1261         navigation_clearroute(this);
1262         return CMD_STATUS_FINISHED;
1263 }
1264
1265 void havocbot_setupbot(entity this)
1266 {
1267         this.bot_ai = havocbot_ai;
1268         this.cmd_moveto = havocbot_moveto;
1269         this.cmd_resetgoal = havocbot_resetgoal;
1270
1271         havocbot_chooserole(this);
1272 }
1273
1274 vector havocbot_dodge(entity this)
1275 {
1276         // LordHavoc: disabled because this is too expensive
1277         return '0 0 0';
1278 #if 0
1279         entity head;
1280         vector dodge, v, n;
1281         float danger, bestdanger, vl, d;
1282         dodge = '0 0 0';
1283         bestdanger = -20;
1284         // check for dangerous objects near bot or approaching bot
1285         head = findchainfloat(bot_dodge, true);
1286         while(head)
1287         {
1288                 if (head.owner != this)
1289                 {
1290                         vl = vlen(head.velocity);
1291                         if (vl > autocvar_sv_maxspeed * 0.3)
1292                         {
1293                                 n = normalize(head.velocity);
1294                                 v = this.origin - head.origin;
1295                                 d = v * n;
1296                                 if (d > (0 - head.bot_dodgerating))
1297                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1298                                 {
1299                                         // calculate direction and distance from the flight path, by removing the forward axis
1300                                         v = v - (n * (v * n));
1301                                         danger = head.bot_dodgerating - vlen(v);
1302                                         if (bestdanger < danger)
1303                                         {
1304                                                 bestdanger = danger;
1305                                                 // dodge to the side of the object
1306                                                 dodge = normalize(v);
1307                                         }
1308                                 }
1309                         }
1310                         else
1311                         {
1312                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1313                                 if (bestdanger < danger)
1314                                 {
1315                                         bestdanger = danger;
1316                                         dodge = normalize(this.origin - head.origin);
1317                                 }
1318                         }
1319                 }
1320                 head = head.chain;
1321         }
1322         return dodge;
1323 #endif
1324 }