qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/mapobjects/func/ladder.qh>
  22 #include <common/mapobjects/teleporters.qh>
  23 #include <common/mapobjects/trigger/jumppads.qh>
  24
  25 #include <lib/warpzone/common.qh>
  26
  27 .float speed;
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         if(bot_execute_commands(this))
  35                 return;
  36
  37         if (bot_strategytoken == this && !bot_strategytoken_taken)
  38         {
  39                 if(this.havocbot_blockhead)
  40                 {
  41                         this.havocbot_blockhead = false;
  42                 }
  43                 else
  44                 {
  45                         if (!this.jumppadcount && !STAT(FROZEN, this))
  46                                 this.havocbot_role(this); // little too far down the rabbit hole
  47                 }
  48
  49                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  50                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  51                 if(!this.goalcurrent)
  52                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  53                 {
  54                         // Look for the closest waypoint out of water
  55                         entity newgoal = NULL;
  56                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  57                         {
  58                                 if(it.origin.z < this.origin.z)
  59                                         continue;
  60
  61                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  62                                         continue;
  63
  64                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  65                                         continue;
  66
  67                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  68
  69                                 if(trace_fraction < 1)
  70                                         continue;
  71
  72                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  73                                         newgoal = it;
  74                         });
  75
  76                         if(newgoal)
  77                         {
  78                         //      te_wizspike(newgoal.origin);
  79                                 navigation_pushroute(this, newgoal);
  80                         }
  81                 }
  82
  83                 // token has been used this frame
  84                 bot_strategytoken_taken = true;
  85         }
  86
  87         if(IS_DEAD(this) || STAT(FROZEN, this))
  88         {
  89                 if (this.goalcurrent)
  90                         navigation_clearroute(this);
  91                 return;
  92         }
  93
  94         havocbot_chooseenemy(this);
  95
  96         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  97         {
  98                 .entity weaponentity = weaponentities[slot];
  99                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 100                 if(this.(weaponentity).bot_chooseweapontime < time)
 101                 {
 102                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 103                         havocbot_chooseweapon(this, weaponentity);
 104                 }
 105         }
 106         havocbot_aim(this);
 107         lag_update(this);
 108
 109         this.bot_aimdir_executed = false;
 110
 111         if (this.bot_aimtarg)
 112         {
 113                 this.aistatus |= AI_STATUS_ATTACKING;
 114                 this.aistatus &= ~AI_STATUS_ROAMING;
 115
 116                 if(STAT(WEAPONS, this))
 117                 {
 118                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 119                         {
 120                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 121                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 122                         }
 123                         else
 124                         {
 125                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 126                                 {
 127                                         .entity weaponentity = weaponentities[slot];
 128                                         Weapon w = this.(weaponentity).m_weapon;
 129                                         if(w == WEP_Null && slot != 0)
 130                                                 continue;
 131                                         w.wr_aim(w, this, weaponentity);
 132                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 133                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 134                                 }
 135                         }
 136                 }
 137                 else
 138                 {
 139                         if(IS_PLAYER(this.bot_aimtarg))
 140                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 141                 }
 142         }
 143         else if (this.goalcurrent)
 144         {
 145                 this.aistatus |= AI_STATUS_ROAMING;
 146                 this.aistatus &= ~AI_STATUS_ATTACKING;
 147         }
 148
 149         havocbot_movetogoal(this);
 150         if (!this.bot_aimdir_executed && this.goalcurrent)
 151         {
 152                 // Heading
 153                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 154                 dir -= this.origin + this.view_ofs;
 155                 dir.z = 0;
 156                 bot_aimdir(this, dir, 0);
 157         }
 158
 159         // if the bot is not attacking, consider reloading weapons
 160         if (!(this.aistatus & AI_STATUS_ATTACKING))
 161         {
 162                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 163                 {
 164                         .entity weaponentity = weaponentities[slot];
 165
 166                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 167                                 continue;
 168
 169                         // we are currently holding a weapon that's not fully loaded, reload it
 170                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 171                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 172                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 173
 174                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 175                         // the code above executes next frame, starting the reloading then
 176                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 177                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 178                         {
 179                                 FOREACH(Weapons, it != WEP_Null, {
 180                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 181                                         {
 182                                                 this.(weaponentity).m_switchweapon = it;
 183                                                 break;
 184                                         }
 185                                 });
 186                         }
 187                 }
 188         }
 189 }
 190
 191 void havocbot_keyboard_movement(entity this, vector destorg)
 192 {
 193         vector keyboard;
 194
 195         if (time > this.havocbot_keyboardtime)
 196         {
 197                 float sk = skill + this.bot_moveskill;
 198                 this.havocbot_keyboardtime =
 199                         max(
 200                                 this.havocbot_keyboardtime
 201                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 202                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 203                         , time);
 204                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 205
 206                 float trigger = autocvar_bot_ai_keyboard_threshold;
 207                 float trigger1 = -trigger;
 208
 209                 // categorize forward movement
 210                 // at skill < 1.5 only forward
 211                 // at skill < 2.5 only individual directions
 212                 // at skill < 4.5 only individual directions, and forward diagonals
 213                 // at skill >= 4.5, all cases allowed
 214                 if (keyboard.x > trigger)
 215                 {
 216                         keyboard.x = 1;
 217                         if (sk < 2.5)
 218                                 keyboard.y = 0;
 219                 }
 220                 else if (keyboard.x < trigger1 && sk > 1.5)
 221                 {
 222                         keyboard.x = -1;
 223                         if (sk < 4.5)
 224                                 keyboard.y = 0;
 225                 }
 226                 else
 227                 {
 228                         keyboard.x = 0;
 229                         if (sk < 1.5)
 230                                 keyboard.y = 0;
 231                 }
 232                 if (sk < 4.5)
 233                         keyboard.z = 0;
 234
 235                 if (keyboard.y > trigger)
 236                         keyboard.y = 1;
 237                 else if (keyboard.y < trigger1)
 238                         keyboard.y = -1;
 239                 else
 240                         keyboard.y = 0;
 241
 242                 if (keyboard.z > trigger)
 243                         keyboard.z = 1;
 244                 else if (keyboard.z < trigger1)
 245                         keyboard.z = -1;
 246                 else
 247                         keyboard.z = 0;
 248
 249                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 250                 if (this.havocbot_ducktime > time)
 251                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 252         }
 253
 254         keyboard = this.havocbot_keyboard;
 255         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 256         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 257         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 258 }
 259
 260 void havocbot_bunnyhop(entity this, vector dir)
 261 {
 262         float bunnyhopdistance;
 263         vector deviation;
 264         float maxspeed;
 265
 266         // Don't jump when attacking
 267         if(this.aistatus & AI_STATUS_ATTACKING)
 268                 return;
 269
 270         if(IS_PLAYER(this.goalcurrent))
 271                 return;
 272
 273         maxspeed = autocvar_sv_maxspeed;
 274
 275         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 276                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 277         {
 278                 this.aistatus &= ~AI_STATUS_RUNNING;
 279                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 280                 this.bot_canruntogoal = 0;
 281                 this.bot_timelastseengoal = 0;
 282                 return;
 283         }
 284
 285         if(this.waterlevel > WATERLEVEL_WETFEET)
 286         {
 287                 this.aistatus &= ~AI_STATUS_RUNNING;
 288                 return;
 289         }
 290
 291         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 292         {
 293                 this.bot_canruntogoal = 0;
 294                 this.bot_timelastseengoal = 0;
 295         }
 296
 297         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 298         bunnyhopdistance = vlen(this.origin - gco);
 299
 300         // Run only to visible goals
 301         if(IS_ONGROUND(this))
 302         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 303         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 304         {
 305                         this.bot_lastseengoal = this.goalcurrent;
 306
 307                         // seen it before
 308                         if(this.bot_timelastseengoal)
 309                         {
 310                                 // for a period of time
 311                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 312                                 {
 313                                         float checkdistance;
 314                                         checkdistance = true;
 315
 316                                         // don't run if it is too close
 317                                         if(this.bot_canruntogoal==0)
 318                                         {
 319                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 320                                                         this.bot_canruntogoal = 1;
 321                                                 else
 322                                                         this.bot_canruntogoal = -1;
 323                                         }
 324
 325                                         if(this.bot_canruntogoal != 1)
 326                                                 return;
 327
 328                                         if(this.aistatus & AI_STATUS_ROAMING)
 329                                         if(this.goalcurrent.classname=="waypoint")
 330                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 331                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 332                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 333                                         {
 334                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 335                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 336                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 337                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 338
 339                                                 if(fabs(deviation.y) < 20)
 340                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 341                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 342                                                 {
 343                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 344                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 345                                                         {
 346                                                                 checkdistance = false;
 347                                                         }
 348                                                 }
 349                                         }
 350
 351                                         if(checkdistance)
 352                                         {
 353                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 354                                                 // increase stop distance in case the goal is on a slope or a lower platform
 355                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 356                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 357                                         }
 358                                         else
 359                                         {
 360                                                 this.aistatus |= AI_STATUS_RUNNING;
 361                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 362                                         }
 363                                 }
 364                         }
 365                         else
 366                         {
 367                                 this.bot_timelastseengoal = time;
 368                         }
 369         }
 370         else
 371         {
 372                 this.bot_timelastseengoal = 0;
 373         }
 374
 375 #if 0
 376         // Release jump button
 377         if(!cvar("sv_pogostick"))
 378         if((IS_ONGROUND(this)) == 0)
 379         {
 380                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 381                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 382
 383                 // Strafe
 384                 if(this.aistatus & AI_STATUS_RUNNING)
 385                 if(vlen(this.velocity)>maxspeed)
 386                 {
 387                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 388                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 389                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 390
 391                         if(fabs(deviation.y)>10)
 392                                 CS(this).movement_x = 0;
 393
 394                         if(deviation.y>10)
 395                                 CS(this).movement_y = maxspeed * -1;
 396                         else if(deviation.y<10)
 397                                 CS(this).movement_y = maxspeed;
 398
 399                 }
 400         }
 401 #endif
 402 }
 403
 404 // return true when bot isn't getting closer to the current goal
 405 bool havocbot_checkgoaldistance(entity this, vector gco)
 406 {
 407         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 408         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 409         float distance_time = this.goalcurrent_distance_time;
 410         if(distance_time < 0)
 411                 distance_time = -distance_time;
 412         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 413         {
 414                 if(!distance_time)
 415                         this.goalcurrent_distance_time = time;
 416                 else if (time - distance_time > 0.5)
 417                         return true;
 418         }
 419         else
 420         {
 421                 // reduce it a little bit so it works even with very small approaches to the goal
 422                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 423                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 424                 this.goalcurrent_distance_time = 0;
 425         }
 426         return false;
 427 }
 428
 429 entity havocbot_select_an_item_of_group(entity this, int gr)
 430 {
 431         entity selected = NULL;
 432         float selected_dist2 = 0;
 433         // select farthest item of this group from bot's position
 434         IL_EACH(g_items, it.item_group == gr && it.solid,
 435         {
 436                 float dist2 = vlen2(this.origin - it.origin);
 437                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 438                 {
 439                         selected = it;
 440                         selected_dist2 = vlen2(this.origin - selected.origin);
 441                 }
 442         });
 443
 444         if (!selected)
 445                 return NULL;
 446
 447         set_tracewalk_dest(selected, this.origin, false);
 448         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 449                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 450         {
 451                 return NULL;
 452         }
 453
 454         return selected;
 455 }
 456
 457 void havocbot_movetogoal(entity this)
 458 {
 459         vector diff;
 460         vector dir;
 461         vector flatdir;
 462         vector evadeobstacle;
 463         vector evadelava;
 464         float dodge_enemy_factor = 1;
 465         float maxspeed;
 466         //float dist;
 467         vector dodge;
 468         //if (this.goalentity)
 469         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 470         CS(this).movement = '0 0 0';
 471         maxspeed = autocvar_sv_maxspeed;
 472
 473         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 474         // Jetpack navigation
 475         if(this.navigation_jetpack_goal)
 476         if(this.goalcurrent==this.navigation_jetpack_goal)
 477         if(GetResourceAmount(this, RESOURCE_FUEL))
 478         {
 479                 if(autocvar_bot_debug_goalstack)
 480                 {
 481                         debuggoalstack(this);
 482                         te_wizspike(this.navigation_jetpack_point);
 483                 }
 484
 485                 // Take off
 486                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 487                 {
 488                         // Brake almost completely so it can get a good direction
 489                         if(vdist(this.velocity, >, 10))
 490                                 return;
 491                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 492                 }
 493
 494                 makevectors(this.v_angle.y * '0 1 0');
 495                 dir = normalize(this.navigation_jetpack_point - this.origin);
 496
 497                 // Landing
 498                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 499                 {
 500                         // Calculate brake distance in xy
 501                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 502                         float vel2 = vlen2(vec2(this.velocity));
 503                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 504                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 505                         if(d < db || d < 500)
 506                         {
 507                                 // Brake
 508                                 if (vel2 > (maxspeed * 0.3) ** 2)
 509                                 {
 510                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 511                                         return;
 512                                 }
 513                                 // Switch to normal mode
 514                                 this.navigation_jetpack_goal = NULL;
 515                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 516                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 517                                 return;
 518                         }
 519                 }
 520                 else if(checkpvs(this.origin,this.goalcurrent))
 521                 {
 522                         // If I can see the goal switch to landing code
 523                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 524                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 525                         return;
 526                 }
 527
 528                 // Flying
 529                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 530                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 531                 {
 532                         CS(this).movement_x = dir * v_forward * maxspeed;
 533                         CS(this).movement_y = dir * v_right * maxspeed;
 534                 }
 535                 return;
 536         }
 537
 538         // Handling of jump pads
 539         if(this.jumppadcount)
 540         {
 541                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 542                 {
 543                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 544                         if(navigation_poptouchedgoals(this))
 545                                 return;
 546                 }
 547                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 548                 {
 549                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 550                         // but with some randomness so it can try out different paths
 551                         if(!this.goalcurrent)
 552                         {
 553                                 entity newgoal = NULL;
 554                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 555                                 {
 556                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 557                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 558                                                 continue;
 559
 560                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 561
 562                                         if(trace_fraction < 1)
 563                                                 continue;
 564
 565                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 566                                                 newgoal = it;
 567                                 });
 568
 569                                 if(newgoal)
 570                                 {
 571                                         this.ignoregoal = this.goalcurrent;
 572                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 573                                         navigation_clearroute(this);
 574                                         navigation_routetogoal(this, newgoal, this.origin);
 575                                         if(autocvar_bot_debug_goalstack)
 576                                                 debuggoalstack(this);
 577                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 578                                 }
 579                         }
 580                         else
 581                         {
 582                                 if (this.goalcurrent.bot_pickup)
 583                                 {
 584                                         entity jumppad_wp = this.goalcurrent_prev;
 585                                         navigation_poptouchedgoals(this);
 586                                         if(!this.goalcurrent && jumppad_wp.wp00)
 587                                         {
 588                                                 // head to the jumppad destination once bot reaches the goal item
 589                                                 navigation_pushroute(this, jumppad_wp.wp00);
 590                                         }
 591                                 }
 592                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 593                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 594                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 595                                 else if(havocbot_checkgoaldistance(this, gco))
 596                                 {
 597                                         navigation_clearroute(this);
 598                                         navigation_goalrating_timeout_force(this);
 599                                 }
 600                                 else
 601                                         return;
 602                         }
 603                 }
 604                 else
 605                 {
 606                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 607                         {
 608                                 vector velxy = this.velocity; velxy_z = 0;
 609                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 610                                 {
 611                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 612                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 613                                 }
 614                                 return;
 615                         }
 616
 617                         // Don't chase players while using a jump pad
 618                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 619                                 return;
 620                 }
 621         }
 622         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 623                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 624
 625         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 626         if (skill > 6 && !(IS_ONGROUND(this)))
 627         {
 628                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 629                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 630                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 631
 632                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 633                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 634                 if(this.items & IT_JETPACK)
 635                 {
 636                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 637                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 638                         {
 639                                 if(this.velocity.z<0)
 640                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 641                         }
 642                         else
 643                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 644
 645                         // If there is no goal try to move forward
 646
 647                         if(this.goalcurrent==NULL)
 648                                 dir = v_forward;
 649                         else
 650                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 651
 652                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 653                         float xyspeed = xyvelocity * dir;
 654
 655                         if(xyspeed < (maxspeed / 2))
 656                         {
 657                                 makevectors(this.v_angle.y * '0 1 0');
 658                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 659                                 if(trace_fraction==1)
 660                                 {
 661                                         CS(this).movement_x = dir * v_forward * maxspeed;
 662                                         CS(this).movement_y = dir * v_right * maxspeed;
 663                                         if (skill < 10)
 664                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 665                                 }
 666                         }
 667
 668                         this.havocbot_blockhead = true;
 669
 670                         return;
 671                 }
 672                 else if(!this.jumppadcount && !this.goalcurrent.wphardwired
 673                         && GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR) > ROCKETJUMP_DAMAGE())
 674                 {
 675                         if(this.velocity.z < 0)
 676                         {
 677                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 678                                 {
 679                                         .entity weaponentity = weaponentities[slot];
 680
 681                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 682                                                 continue;
 683
 684                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 685                                         {
 686                                                 CS(this).movement_x = maxspeed;
 687
 688                                                 if(this.rocketjumptime)
 689                                                 {
 690                                                         if(time > this.rocketjumptime)
 691                                                         {
 692                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 693                                                                 this.rocketjumptime = 0;
 694                                                         }
 695                                                         return;
 696                                                 }
 697
 698                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 699                                                 this.v_angle_x = 90;
 700                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 701                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 702                                                 return;
 703                                         }
 704                                 }
 705                         }
 706                 }
 707                 else
 708                 {
 709                         // If there is no goal try to move forward
 710                         if(this.goalcurrent==NULL)
 711                                 CS(this).movement_x = maxspeed;
 712                 }
 713         }
 714
 715         // If we are under water with no goals, swim up
 716         if(this.waterlevel && !this.goalcurrent)
 717         {
 718                 dir = '0 0 0';
 719                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 720                         dir.z = 1;
 721                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 722                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 723                 else
 724                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 725                 makevectors(this.v_angle.y * '0 1 0');
 726                 vector v = dir * maxspeed;
 727                 CS(this).movement.x = v * v_forward;
 728                 CS(this).movement.y = v * v_right;
 729                 CS(this).movement.z = v * v_up;
 730         }
 731
 732         // if there is nowhere to go, exit
 733         if (this.goalcurrent == NULL)
 734                 return;
 735
 736
 737         bool locked_goal = false;
 738         if((this.goalentity && wasfreed(this.goalentity))
 739                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 740         {
 741                 navigation_clearroute(this);
 742                 navigation_goalrating_timeout_force(this);
 743                 return;
 744         }
 745         else if(this.goalentity.tag_entity)
 746         {
 747                 navigation_goalrating_timeout_expire(this, 2);
 748         }
 749         else if(this.goalentity.bot_pickup)
 750         {
 751                 if(this.goalentity.bot_pickup_respawning)
 752                 {
 753                         if(this.goalentity.solid) // item respawned
 754                                 this.goalentity.bot_pickup_respawning = false;
 755                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 756                         {
 757                                 if(checkpvs(this.origin, this.goalentity))
 758                                 {
 759                                         this.goalentity.bot_pickup_respawning = false;
 760                                         navigation_goalrating_timeout_expire(this, random());
 761                                 }
 762                                 locked_goal = true; // wait for item to respawn
 763                         }
 764                         else if(this.goalentity == this.goalcurrent)
 765                                 locked_goal = true; // wait for item to respawn
 766                 }
 767                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 768                 {
 769                         if(checkpvs(this.origin, this.goalentity))
 770                         {
 771                                 navigation_goalrating_timeout_expire(this, random());
 772                         }
 773                 }
 774         }
 775         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 776                 locked_goal = true;
 777
 778         if (navigation_shortenpath(this))
 779         {
 780                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 781                         && navigation_goalrating_timeout_can_be_anticipated(this))
 782                 {
 783                         navigation_goalrating_timeout_force(this);
 784                 }
 785         }
 786
 787         bool goalcurrent_can_be_removed = false;
 788         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 789         {
 790                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 791                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 792                 {
 793                         goalcurrent_can_be_removed = true;
 794                         // don't remove if not visible
 795                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 796                         {
 797                                 if (IS_DEAD(this.goalcurrent))
 798                                 {
 799                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 800                                         {
 801                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 802                                                 {
 803                                                         navigation_clearroute(this);
 804                                                         navigation_pushroute(this, it);
 805                                                         // loot can't be immediately rated since it isn't on ground yet
 806                                                         // it will be rated after a second when on ground, meanwhile head to it
 807                                                         navigation_goalrating_timeout_expire(this, 1);
 808                                                         return;
 809                                                 }
 810                                         });
 811                                 }
 812                                 if (!Item_IsLoot(this.goalcurrent))
 813                                 {
 814                                         navigation_goalrating_timeout_force(this);
 815                                         return;
 816                                 }
 817                         }
 818                 }
 819                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 820                 {
 821                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 822                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 823                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 824                         {
 825                                 navigation_goalrating_timeout_force(this);
 826                                 return;
 827                         }
 828                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 829                 }
 830         }
 831
 832         if(!locked_goal)
 833         {
 834                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 835                 // in this case path finding can start directly from a waypoint instead of
 836                 // looking for all the reachable waypoints up to a certain distance
 837                 if (navigation_poptouchedgoals(this))
 838                 {
 839                         if (this.goalcurrent)
 840                         {
 841                                 if (goalcurrent_can_be_removed)
 842                                 {
 843                                         // remove even if not visible
 844                                         navigation_goalrating_timeout_force(this);
 845                                         return;
 846                                 }
 847                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 848                                         navigation_goalrating_timeout_force(this);
 849                         }
 850                         else
 851                         {
 852                                 entity old_goal = this.goalcurrent_prev;
 853                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 854                                 {
 855                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 856                                         // item of the group by telling the bot to head directly to the farthest item.
 857                                         // Next time we let the bot select a goal as usual which can be another item
 858                                         // of this group (the closest one) and so on
 859                                         this.item_group = old_goal.item_group;
 860                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 861                                         if (new_goal)
 862                                                 navigation_pushroute(this, new_goal);
 863                                 }
 864                         }
 865                 }
 866         }
 867
 868         // if ran out of goals try to use an alternative goal or get a new strategy asap
 869         if(this.goalcurrent == NULL)
 870         {
 871                 navigation_goalrating_timeout_force(this);
 872                 return;
 873         }
 874
 875
 876         if(autocvar_bot_debug_goalstack)
 877                 debuggoalstack(this);
 878
 879         bool bunnyhop_forbidden = false;
 880         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 881         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 882         {
 883                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 884                 destorg = this.goalcurrent.origin;
 885         }
 886         else if (this.goalcurrent.wpisbox)
 887         {
 888                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 889                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 890                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 891                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 892                 {
 893                         bunnyhop_forbidden = true;
 894                         destorg = this.goalcurrent.origin;
 895                         if(destorg.z > this.origin.z)
 896                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 897                 }
 898         }
 899
 900         diff = destorg - this.origin;
 901
 902         if (time < this.bot_stop_moving_timeout
 903                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 904         {
 905                 // stop if the locked goal has been reached
 906                 destorg = this.origin;
 907                 diff = dir = '0 0 0';
 908         }
 909         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 910         {
 911                 if (vdist(diff, <, 80))
 912                 {
 913                         // stop if too close to target player (even if frozen)
 914                         destorg = this.origin;
 915                         diff = dir = '0 0 0';
 916                 }
 917                 else
 918                 {
 919                         // move destorg out of target players, otherwise bot will consider them
 920                         // an obstacle that needs to be jumped (especially if frozen)
 921                         dir = normalize(diff);
 922                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 923                         diff = destorg - this.origin;
 924                 }
 925         }
 926         else
 927                 dir = normalize(diff);
 928         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 929
 930         //if (this.bot_dodgevector_time < time)
 931         {
 932                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 933                 //this.bot_dodgevector_jumpbutton = 1;
 934                 evadeobstacle = '0 0 0';
 935                 evadelava = '0 0 0';
 936
 937                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 938                 makevectors(this.v_angle.y * '0 1 0');
 939                 if (this.waterlevel > WATERLEVEL_WETFEET)
 940                 {
 941                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 942                         {
 943                                 if(!this.goalcurrent)
 944                                         this.aistatus |= AI_STATUS_OUT_WATER;
 945                                 else if(destorg.z > this.origin.z)
 946                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 947                         }
 948                         else
 949                         {
 950                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 951                                         (this.aistatus & AI_STATUS_OUT_WATER))
 952                                 {
 953                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 954                                         dir = flatdir;
 955                                 }
 956                                 else
 957                                 {
 958                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 959                                         if (destorg.z > this.origin.z)
 960                                                 dir = flatdir;
 961                                 }
 962                         }
 963                 }
 964                 else
 965                 {
 966                         float s;
 967                         vector offset;
 968                         if(this.aistatus & AI_STATUS_OUT_WATER)
 969                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 970
 971                         // jump if going toward an obstacle that doesn't look like stairs we
 972                         // can walk up directly
 973                         vector deviation = '0 0 0';
 974                         float current_speed = vlen(vec2(this.velocity));
 975                         if (current_speed < maxspeed * 0.2)
 976                                 current_speed = maxspeed * 0.2;
 977                         else
 978                         {
 979                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 980                                 while (deviation.y < -180) deviation.y += 360;
 981                                 while (deviation.y > 180) deviation.y -= 360;
 982                         }
 983                         float turning = false;
 984                         vector flat_diff = vec2(diff);
 985                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 986                         vector actual_destorg = this.origin + offset;
 987                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
 988                         {
 989                                 if (vlen2(flat_diff) < vlen2(offset))
 990                                 {
 991                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 992                                         {
 993                                                 // oblique warpzones need a jump otherwise bots gets stuck
 994                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 995                                         }
 996                                         else
 997                                         {
 998                                                 actual_destorg.x = destorg.x;
 999                                                 actual_destorg.y = destorg.y;
1000                                         }
1001                                 }
1002                         }
1003                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
1004                         {
1005                                 actual_destorg.x = destorg.x;
1006                                 actual_destorg.y = destorg.y;
1007                         }
1008                         else if (vlen2(flat_diff) < vlen2(offset))
1009                         {
1010                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1011                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
1012                                 float dist = vlen(vec2(this.origin + offset - destorg));
1013                                 // if current and next goal are close to each other make sure
1014                                 // actual_destorg isn't set beyond next_goal_org
1015                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
1016                                         actual_destorg = next_goal_org;
1017                                 else
1018                                         actual_destorg = vec2(destorg) + dist * next_dir;
1019                                 actual_destorg.z = this.origin.z;
1020                                 turning = true;
1021                         }
1022
1023                         LABEL(jump_check);
1024                         dir = flatdir = normalize(actual_destorg - this.origin);
1025
1026                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
1027                         {
1028                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1029                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1030                                 {
1031                                         s = trace_fraction;
1032                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1033                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1034                                         {
1035                                                 // found an obstacle
1036                                                 if (turning && fabs(deviation.y) > 5)
1037                                                 {
1038                                                         // check if the obstacle is still there without turning
1039                                                         actual_destorg = destorg;
1040                                                         turning = false;
1041                                                         this.bot_tracewalk_time = time + 0.25;
1042                                                         goto jump_check;
1043                                                 }
1044                                                 s = trace_fraction;
1045                                                 // don't artificially reduce max jump height in real-time
1046                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1047                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1048                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1049                                                 if (trace_fraction > s)
1050                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1051                                                 else
1052                                                 {
1053                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1054                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1055                                                         if (trace_fraction > s)
1056                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1057                                                 }
1058                                         }
1059                                 }
1060                         }
1061
1062                         // if bot for some reason doesn't get close to the current goal find another one
1063                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1064                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1065                         if(havocbot_checkgoaldistance(this, destorg))
1066                         {
1067                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1068                                 {
1069                                         navigation_clearroute(this);
1070                                         navigation_goalrating_timeout_force(this);
1071                                         return;
1072                                 }
1073
1074                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1075                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1076                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1077                                 {
1078                                         navigation_clearroute(this);
1079                                         navigation_goalrating_timeout_force(this);
1080                                         return;
1081                                 }
1082
1083                                 // give bot only another chance to prevent bot getting stuck
1084                                 // in case it thinks it can walk but actually can't
1085                                 this.goalcurrent_distance_z = FLOAT_MAX;
1086                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1087                                 this.goalcurrent_distance_time = -time; // mark second try
1088                         }
1089
1090                         // Check for water/slime/lava and dangerous edges
1091                         // (only when the bot is on the ground or jumping intentionally)
1092
1093                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1094                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1095                         {
1096                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1097                         }
1098
1099                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
1100                         vector dst_ahead = this.origin + this.view_ofs + offset;
1101                         vector dst_down = dst_ahead - '0 0 3000';
1102                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1103
1104                         bool unreachable = false;
1105                         s = CONTENT_SOLID;
1106                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1107                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1108                         {
1109                                 // Look downwards
1110                                 traceline(dst_ahead , dst_down, true, NULL);
1111                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1112                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
1113                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1114                                 {
1115                                         s = pointcontents(trace_endpos + '0 0 1');
1116                                         if (s != CONTENT_SOLID)
1117                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1118                                                 evadelava = normalize(this.velocity) * -1;
1119                                         else if (s == CONTENT_SKY)
1120                                                 evadeobstacle = normalize(this.velocity) * -1;
1121                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1122                                         {
1123                                                 // the traceline check isn't enough but is good as optimization,
1124                                                 // when not true (most of the time) this tracebox call is avoided
1125                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1126                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1127                                                 {
1128                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1129                                                         {
1130                                                                 // the goal is probably on an upper platform, assume bot can't get there
1131                                                                 unreachable = true;
1132                                                         }
1133                                                         else
1134                                                                 evadelava = normalize(this.velocity) * -1;
1135                                                 }
1136                                         }
1137                                 }
1138                         }
1139
1140                         dir = flatdir;
1141                         evadeobstacle.z = 0;
1142                         evadelava.z = 0;
1143                         makevectors(this.v_angle.y * '0 1 0');
1144
1145                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1146                         {
1147                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1148                                 if(IS_PLAYER(this.goalcurrent))
1149                                         unreachable = true;
1150                         }
1151
1152                         // slow down if bot is in the air and goal is under it
1153                         if (!this.goalcurrent.wphardwired
1154                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1155                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1156                         {
1157                                 // tracebox wouldn't work when bot is still on the ledge
1158                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1159                                 if (this.origin.z - trace_endpos.z > 120)
1160                                         evadeobstacle = normalize(this.velocity) * -1;
1161                         }
1162
1163                         if(unreachable)
1164                         {
1165                                 navigation_clearroute(this);
1166                                 navigation_goalrating_timeout_force(this);
1167                                 this.ignoregoal = this.goalcurrent;
1168                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1169                         }
1170                 }
1171
1172                 dodge = havocbot_dodge(this);
1173                 if (dodge)
1174                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1175                 dodge += evadeobstacle + evadelava;
1176                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1177                 if (this.enemy)
1178                 {
1179                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1180                         if (IS_PLAYER(trace_ent))
1181                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1182                 }
1183         //      this.bot_dodgevector = dir;
1184         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1185         }
1186
1187         float ladder_zdir = 0;
1188         if(time < this.ladder_time)
1189         {
1190                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1191                 {
1192                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1193                                 ladder_zdir = 1;
1194                 }
1195                 else
1196                 {
1197                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1198                                 ladder_zdir = -1;
1199                 }
1200                 if (ladder_zdir)
1201                 {
1202                         if (vdist(vec2(diff), <, 40))
1203                                 dir.z = ladder_zdir * 4;
1204                         else
1205                                 dir.z = ladder_zdir * 2;
1206                         dir = normalize(dir);
1207                 }
1208         }
1209
1210         if (this.goalcurrent.wpisbox
1211                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1212         {
1213                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1214                 // head to teleport origin
1215                 dir = (this.goalcurrent.origin - this.origin);
1216                 dir.z = 0;
1217                 dir = normalize(dir);
1218         }
1219
1220         // already executed when bot targets an enemy
1221         if (!this.bot_aimdir_executed)
1222         {
1223                 if (time < this.bot_stop_moving_timeout)
1224                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1225                 else
1226                         bot_aimdir(this, dir, 0);
1227         }
1228
1229         if (!ladder_zdir)
1230         {
1231                 dir *= dodge_enemy_factor;
1232                 dir = normalize(dir + dodge);
1233         }
1234
1235         makevectors(this.v_angle);
1236         //dir = this.bot_dodgevector;
1237         //if (this.bot_dodgevector_jumpbutton)
1238         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1239         CS(this).movement_x = dir * v_forward * maxspeed;
1240         CS(this).movement_y = dir * v_right * maxspeed;
1241         CS(this).movement_z = dir * v_up * maxspeed;
1242
1243         // Emulate keyboard interface
1244         if (skill < 10)
1245                 havocbot_keyboard_movement(this, destorg);
1246
1247         // Bunnyhop!
1248         //if(this.aistatus & AI_STATUS_ROAMING)
1249         if(!bunnyhop_forbidden && this.goalcurrent)
1250         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1251                 havocbot_bunnyhop(this, dir);
1252
1253         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1254         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1255         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1256 }
1257
1258 entity havocbot_gettarget(entity this, bool secondary)
1259 {
1260         entity best = NULL;
1261         vector eye = CENTER_OR_VIEWOFS(this);
1262         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1263         {
1264                 vector v = CENTER_OR_VIEWOFS(it);
1265                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1266                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1267                 if(bot_shouldattack(this, it))
1268                 {
1269                         traceline(eye, v, true, this);
1270                         if (trace_ent == it || trace_fraction >= 1)
1271                                 best = it;
1272                 }
1273         });
1274
1275         return best;
1276 }
1277
1278 void havocbot_chooseenemy(entity this)
1279 {
1280         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1281         {
1282                 this.enemy = NULL;
1283                 return;
1284         }
1285         if (this.enemy)
1286         {
1287                 if (!bot_shouldattack(this, this.enemy))
1288                 {
1289                         // enemy died or something, find a new target
1290                         this.enemy = NULL;
1291                         this.havocbot_chooseenemy_finished = time;
1292                 }
1293                 else if (this.havocbot_stickenemy)
1294                 {
1295                         // tracking last chosen enemy
1296                         // if enemy is visible
1297                         // and not really really far away
1298                         // and we're not severely injured
1299                         // then keep tracking for a half second into the future
1300                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1301                         if (trace_ent == this.enemy || trace_fraction == 1)
1302                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1303                         if (GetResourceAmount(this, RESOURCE_HEALTH) > 30)
1304                         {
1305                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1306                                 this.havocbot_chooseenemy_finished = time + 0.5;
1307                                 return;
1308                         }
1309                         // enemy isn't visible, or is far away, or we're injured severely
1310                         // so stop preferring this enemy
1311                         // (it will still take a half second until a new one is chosen)
1312                         this.havocbot_stickenemy = 0;
1313                 }
1314         }
1315         if (time < this.havocbot_chooseenemy_finished)
1316                 return;
1317         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1318         vector eye = this.origin + this.view_ofs;
1319         entity best = NULL;
1320         float bestrating = 100000000;
1321
1322         // Backup hit flags
1323         int hf = this.dphitcontentsmask;
1324
1325         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1326
1327         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1328
1329         bool scan_transparent = false;
1330         bool scan_secondary_targets = false;
1331         bool have_secondary_targets = false;
1332         while(true)
1333         {
1334                 scan_secondary_targets = false;
1335 LABEL(scan_targets)
1336                 IL_EACH(g_bot_targets, it.bot_attack,
1337                 {
1338                         if(!scan_secondary_targets)
1339                         {
1340                                 if(it.classname == "misc_breakablemodel")
1341                                 {
1342                                         have_secondary_targets = true;
1343                                         continue;
1344                                 }
1345                         }
1346                         else if(it.classname != "misc_breakablemodel")
1347                                 continue;
1348
1349                         vector v = (it.absmin + it.absmax) * 0.5;
1350                         float rating = vlen2(v - eye);
1351                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1352                         if (bestrating > rating)
1353                         if (bot_shouldattack(this, it))
1354                         {
1355                                 traceline(eye, v, true, this);
1356                                 if (trace_ent == it || trace_fraction >= 1)
1357                                 {
1358                                         best = it;
1359                                         bestrating = rating;
1360                                 }
1361                         }
1362                 });
1363
1364                 if(!best && have_secondary_targets && !scan_secondary_targets)
1365                 {
1366                         scan_secondary_targets = true;
1367                         // restart the loop
1368                         bestrating = 100000000;
1369                         goto scan_targets;
1370                 }
1371
1372                 // I want to do a second scan if no enemy was found or I don't have weapons
1373                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1374                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1375                         break;
1376                 if(scan_transparent)
1377                         break;
1378
1379                 // Set flags to see through transparent objects
1380                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1381
1382                 scan_transparent = true;
1383         }
1384
1385         // Restore hit flags
1386         this.dphitcontentsmask = hf;
1387
1388         this.enemy = best;
1389         this.havocbot_stickenemy = true;
1390         if(best && best.classname == "misc_breakablemodel")
1391                 this.havocbot_stickenemy = false;
1392 }
1393
1394 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1395 {
1396         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1397         // so skip this for them, or they'll never get to reload their weapons at all.
1398         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1399         if(skill < 5)
1400                 return false;
1401
1402         // if this weapon is scheduled for reloading, don't switch to it during combat
1403         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1404         {
1405                 FOREACH(Weapons, it != WEP_Null, {
1406                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1407                                 return true; // other weapon available
1408                 });
1409         }
1410
1411         return false;
1412 }
1413
1414 void havocbot_chooseweapon(entity this, .entity weaponentity)
1415 {
1416         int i;
1417
1418         // ;)
1419         if(g_weaponarena_weapons == WEPSET(TUBA))
1420         {
1421                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1422                 return;
1423         }
1424
1425         // TODO: clean this up by moving it to weapon code
1426         if(this.enemy==NULL)
1427         {
1428                 // If no weapon was chosen get the first available weapon
1429                 if(this.(weaponentity).m_weapon==WEP_Null)
1430                 FOREACH(Weapons, it != WEP_Null, {
1431                         if(client_hasweapon(this, it, weaponentity, true, false))
1432                         {
1433                                 this.(weaponentity).m_switchweapon = it;
1434                                 return;
1435                         }
1436                 });
1437                 return;
1438         }
1439
1440         // Do not change weapon during the next second after a combo
1441         float f = time - this.lastcombotime;
1442         if(f < 1)
1443                 return;
1444
1445         float w;
1446         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1447
1448         // Should it do a weapon combo?
1449         float af, ct, combo_time, combo;
1450
1451         af = ATTACK_FINISHED(this, weaponentity);
1452         ct = autocvar_bot_ai_weapon_combo_threshold;
1453
1454         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1455         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1456         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1457
1458         combo = false;
1459
1460         if(autocvar_bot_ai_weapon_combo)
1461         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1462         if(af > combo_time)
1463         {
1464                 combo = true;
1465                 this.lastcombotime = time;
1466         }
1467
1468         distance *= (2 ** this.bot_rangepreference);
1469
1470         // Custom weapon list based on distance to the enemy
1471         if(bot_custom_weapon){
1472
1473                 // Choose weapons for far distance
1474                 if ( distance > bot_distance_far ) {
1475                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1476                                 w = bot_weapons_far[i];
1477                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1478                                 {
1479                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1480                                                 continue;
1481                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1482                                         return;
1483                                 }
1484                         }
1485                 }
1486
1487                 // Choose weapons for mid distance
1488                 if ( distance > bot_distance_close) {
1489                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1490                                 w = bot_weapons_mid[i];
1491                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1492                                 {
1493                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1494                                                 continue;
1495                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1496                                         return;
1497                                 }
1498                         }
1499                 }
1500
1501                 // Choose weapons for close distance
1502                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1503                         w = bot_weapons_close[i];
1504                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1505                         {
1506                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1507                                         continue;
1508                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1509                                 return;
1510                         }
1511                 }
1512         }
1513 }
1514
1515 void havocbot_aim(entity this)
1516 {
1517         if (time < this.nextaim)
1518                 return;
1519         this.nextaim = time + 0.1;
1520         vector myvel = this.velocity;
1521         if (!this.waterlevel)
1522                 myvel.z = 0;
1523         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1524         else if (this.enemy)
1525         {
1526                 vector enemyvel = this.enemy.velocity;
1527                 if (!this.enemy.waterlevel)
1528                         enemyvel.z = 0;
1529                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1530         }
1531         else
1532                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1533 }
1534
1535 bool havocbot_moveto_refresh_route(entity this)
1536 {
1537         // Refresh path to goal if necessary
1538         entity wp;
1539         wp = this.havocbot_personal_waypoint;
1540         navigation_goalrating_start(this);
1541         navigation_routerating(this, wp, 10000, 10000);
1542         navigation_goalrating_end(this);
1543         return (this.goalentity != NULL);
1544 }
1545
1546 float havocbot_moveto(entity this, vector pos)
1547 {
1548         entity wp;
1549
1550         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1551         {
1552                 // Step 4: Move to waypoint
1553                 if(this.havocbot_personal_waypoint==NULL)
1554                 {
1555                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1556                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1557                         return CMD_STATUS_ERROR;
1558                 }
1559
1560                 if (!bot_strategytoken_taken)
1561                 if(this.havocbot_personal_waypoint_searchtime<time)
1562                 {
1563                         bot_strategytoken_taken = true;
1564                         if(havocbot_moveto_refresh_route(this))
1565                         {
1566                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1567                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1568                                 this.havocbot_personal_waypoint_failcounter = 0;
1569                         }
1570                         else
1571                         {
1572                                 this.havocbot_personal_waypoint_failcounter += 1;
1573                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1574                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1575                                 {
1576                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1577                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1578                                         delete(this.havocbot_personal_waypoint);
1579                                         return CMD_STATUS_ERROR;
1580                                 }
1581                                 else
1582                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1583                         }
1584                 }
1585
1586                 if(autocvar_bot_debug_goalstack)
1587                         debuggoalstack(this);
1588
1589
1590                 // Go!
1591                 havocbot_movetogoal(this);
1592
1593                 if (!this.bot_aimdir_executed && this.goalcurrent)
1594                 {
1595                         // Heading
1596                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1597                         dir -= this.origin + this.view_ofs;
1598                         dir.z = 0;
1599                         bot_aimdir(this, dir, 0);
1600                 }
1601
1602                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1603                 {
1604                         // Step 5: Waypoint reached
1605                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1606                         delete(this.havocbot_personal_waypoint);
1607                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1608                         return CMD_STATUS_FINISHED;
1609                 }
1610
1611                 return CMD_STATUS_EXECUTING;
1612         }
1613
1614         // Step 2: Linking waypoint
1615         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1616         {
1617                 // Wait until it is linked
1618                 if(!this.havocbot_personal_waypoint.wplinked)
1619                 {
1620                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1621                         return CMD_STATUS_EXECUTING;
1622                 }
1623
1624                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1625                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1626                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1627
1628                 // Step 3: Route to waypoint
1629                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1630
1631                 return CMD_STATUS_EXECUTING;
1632         }
1633
1634         // Step 1: Spawning waypoint
1635         wp = waypoint_spawnpersonal(this, pos);
1636         if(wp==NULL)
1637         {
1638                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1639                 return CMD_STATUS_ERROR;
1640         }
1641
1642         this.havocbot_personal_waypoint = wp;
1643         this.havocbot_personal_waypoint_failcounter = 0;
1644         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1645
1646         // if pos is inside a teleport, then let's mark it as teleport waypoint
1647         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1648         {
1649                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1650                 this.lastteleporttime = 0;
1651         });
1652
1653 /*
1654         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1655                 print("routing to a teleporter\n");
1656         else
1657                 print("routing to a non-teleporter\n");
1658 */
1659
1660         return CMD_STATUS_EXECUTING;
1661 }
1662
1663 float havocbot_resetgoal(entity this)
1664 {
1665         navigation_clearroute(this);
1666         return CMD_STATUS_FINISHED;
1667 }
1668
1669 void havocbot_setupbot(entity this)
1670 {
1671         this.bot_ai = havocbot_ai;
1672         this.cmd_moveto = havocbot_moveto;
1673         this.cmd_resetgoal = havocbot_resetgoal;
1674
1675         // NOTE: bot is not player yet
1676         havocbot_chooserole(this);
1677 }
1678
1679 vector havocbot_dodge(entity this)
1680 {
1681         // LordHavoc: disabled because this is too expensive
1682         return '0 0 0';
1683 #if 0
1684         entity head;
1685         vector dodge, v, n;
1686         float danger, bestdanger, vl, d;
1687         dodge = '0 0 0';
1688         bestdanger = -20;
1689         // check for dangerous objects near bot or approaching bot
1690         head = findchainfloat(bot_dodge, true);
1691         while(head)
1692         {
1693                 if (head.owner != this)
1694                 {
1695                         vl = vlen(head.velocity);
1696                         if (vl > autocvar_sv_maxspeed * 0.3)
1697                         {
1698                                 n = normalize(head.velocity);
1699                                 v = this.origin - head.origin;
1700                                 d = v * n;
1701                                 if (d > (0 - head.bot_dodgerating))
1702                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1703                                 {
1704                                         // calculate direction and distance from the flight path, by removing the forward axis
1705                                         v = v - (n * (v * n));
1706                                         danger = head.bot_dodgerating - vlen(v);
1707                                         if (bestdanger < danger)
1708                                         {
1709                                                 bestdanger = danger;
1710                                                 // dodge to the side of the object
1711                                                 dodge = normalize(v);
1712                                         }
1713                                 }
1714                         }
1715                         else
1716                         {
1717                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1718                                 if (bestdanger < danger)
1719                                 {
1720                                         bestdanger = danger;
1721                                         dodge = normalize(this.origin - head.origin);
1722                                 }
1723                         }
1724                 }
1725                 head = head.chain;
1726         }
1727         return dodge;
1728 #endif
1729 }