qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "../cvars.qh"
   4
   5 #include "../aim.qh"
   6 #include "../bot.qh"
   7 #include "../navigation.qh"
   8 #include "../scripting.qh"
   9 #include "../waypoints.qh"
  10
  11 #include <common/constants.qh>
  12 #include <common/impulses/all.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15 #include <common/state.qh>
  16 #include <common/items/_mod.qh>
  17 #include <common/wepent.qh>
  18
  19 #include <common/triggers/teleporters.qh>
  20 #include <common/triggers/trigger/jumppads.qh>
  21
  22 #include <lib/warpzone/common.qh>
  23
  24 .float speed;
  25
  26 void havocbot_ai(entity this)
  27 {
  28         if(this.draggedby)
  29                 return;
  30
  31         if(bot_execute_commands(this))
  32                 return;
  33
  34         if (bot_strategytoken == this)
  35         if (!bot_strategytoken_taken)
  36         {
  37                 if(this.havocbot_blockhead)
  38                 {
  39                         this.havocbot_blockhead = false;
  40                 }
  41                 else
  42                 {
  43                         if (!this.jumppadcount && !STAT(FROZEN, this))
  44                                 this.havocbot_role(this); // little too far down the rabbit hole
  45                 }
  46
  47                 // TODO: tracewalk() should take care of this job (better path finding under water)
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this) || STAT(FROZEN, this))
  87                 return;
  88
  89         havocbot_chooseenemy(this);
  90
  91         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  92         {
  93                 .entity weaponentity = weaponentities[slot];
  94                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  95                 if(this.(weaponentity).bot_chooseweapontime < time)
  96                 {
  97                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  98                         havocbot_chooseweapon(this, weaponentity);
  99                 }
 100         }
 101         havocbot_aim(this);
 102         lag_update(this);
 103         if (this.bot_aimtarg)
 104         {
 105                 this.aistatus |= AI_STATUS_ATTACKING;
 106                 this.aistatus &= ~AI_STATUS_ROAMING;
 107
 108                 if(this.weapons)
 109                 {
 110                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 111                         {
 112                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 113                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 114                         }
 115                         else
 116                         {
 117                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 118                                 {
 119                                         .entity weaponentity = weaponentities[slot];
 120                                         Weapon w = this.(weaponentity).m_weapon;
 121                                         if(w == WEP_Null && slot != 0)
 122                                                 continue;
 123                                         w.wr_aim(w, this, weaponentity);
 124                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 125                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 126                                 }
 127                         }
 128                 }
 129                 else
 130                 {
 131                         if(IS_PLAYER(this.bot_aimtarg))
 132                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 133                 }
 134         }
 135         else if (this.goalcurrent)
 136         {
 137                 this.aistatus |= AI_STATUS_ROAMING;
 138                 this.aistatus &= ~AI_STATUS_ATTACKING;
 139
 140                 vector now,v,next;//,heading;
 141                 float aimdistance,skillblend,distanceblend,blend;
 142                 next = now = ( (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5) - (this.origin + this.view_ofs);
 143                 aimdistance = vlen(now);
 144                 //heading = this.velocity;
 145                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 146                 if(
 147                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 148                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 149                 )
 150                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 151
 152                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 153                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 154                 blend = skillblend * (1-distanceblend);
 155                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 156                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 157                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 158                 v = now + blend * (next - now);
 159                 //dprint(etos(this), " ");
 160                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 161                 //v = now * (distanceblend) + next * (1-distanceblend);
 162                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 163                         v.z = 0;
 164                 //dprint("walk at:", vtos(v), "\n");
 165                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 166                 bot_aimdir(this, v, -1);
 167         }
 168         havocbot_movetogoal(this);
 169
 170         // if the bot is not attacking, consider reloading weapons
 171         if (!(this.aistatus & AI_STATUS_ATTACKING))
 172         {
 173                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 174                 {
 175                         .entity weaponentity = weaponentities[slot];
 176
 177                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 178                                 continue;
 179
 180                         // we are currently holding a weapon that's not fully loaded, reload it
 181                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 182                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 183                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 184
 185                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 186                         // the code above executes next frame, starting the reloading then
 187                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 188                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 189                         {
 190                                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
 191                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 192                                         {
 193                                                 this.(weaponentity).m_switchweapon = it;
 194                                                 break;
 195                                         }
 196                                 ));
 197                         }
 198                 }
 199         }
 200 }
 201
 202 void havocbot_keyboard_movement(entity this, vector destorg)
 203 {
 204         vector keyboard;
 205
 206         if (time > this.havocbot_keyboardtime)
 207         {
 208                 float sk = skill + this.bot_moveskill;
 209                 this.havocbot_keyboardtime =
 210                         max(
 211                                 this.havocbot_keyboardtime
 212                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 213                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 214                         , time);
 215                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 216
 217                 float trigger = autocvar_bot_ai_keyboard_threshold;
 218                 float trigger1 = -trigger;
 219
 220                 // categorize forward movement
 221                 // at skill < 1.5 only forward
 222                 // at skill < 2.5 only individual directions
 223                 // at skill < 4.5 only individual directions, and forward diagonals
 224                 // at skill >= 4.5, all cases allowed
 225                 if (keyboard.x > trigger)
 226                 {
 227                         keyboard.x = 1;
 228                         if (sk < 2.5)
 229                                 keyboard.y = 0;
 230                 }
 231                 else if (keyboard.x < trigger1 && sk > 1.5)
 232                 {
 233                         keyboard.x = -1;
 234                         if (sk < 4.5)
 235                                 keyboard.y = 0;
 236                 }
 237                 else
 238                 {
 239                         keyboard.x = 0;
 240                         if (sk < 1.5)
 241                                 keyboard.y = 0;
 242                 }
 243                 if (sk < 4.5)
 244                         keyboard.z = 0;
 245
 246                 if (keyboard.y > trigger)
 247                         keyboard.y = 1;
 248                 else if (keyboard.y < trigger1)
 249                         keyboard.y = -1;
 250                 else
 251                         keyboard.y = 0;
 252
 253                 if (keyboard.z > trigger)
 254                         keyboard.z = 1;
 255                 else if (keyboard.z < trigger1)
 256                         keyboard.z = -1;
 257                 else
 258                         keyboard.z = 0;
 259
 260                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 261                 if (this.havocbot_ducktime > time)
 262                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 263         }
 264
 265         keyboard = this.havocbot_keyboard;
 266         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 267         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 268         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 269 }
 270
 271 void havocbot_bunnyhop(entity this, vector dir)
 272 {
 273         float bunnyhopdistance;
 274         vector deviation;
 275         float maxspeed;
 276         vector gco, gno;
 277
 278         // Don't jump when attacking
 279         if(this.aistatus & AI_STATUS_ATTACKING)
 280                 return;
 281
 282         if(IS_PLAYER(this.goalcurrent))
 283                 return;
 284
 285         maxspeed = autocvar_sv_maxspeed;
 286
 287         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 288                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 289         {
 290                 this.aistatus &= ~AI_STATUS_RUNNING;
 291                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 292                 this.bot_canruntogoal = 0;
 293                 this.bot_timelastseengoal = 0;
 294                 return;
 295         }
 296
 297         if(this.waterlevel > WATERLEVEL_WETFEET)
 298         {
 299                 this.aistatus &= ~AI_STATUS_RUNNING;
 300                 return;
 301         }
 302
 303         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 304         {
 305                 this.bot_canruntogoal = 0;
 306                 this.bot_timelastseengoal = 0;
 307         }
 308
 309         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 310         bunnyhopdistance = vlen(this.origin - gco);
 311
 312         // Run only to visible goals
 313         if(IS_ONGROUND(this))
 314         if(vlen(this.velocity - eZ * this.velocity.z) >= autocvar_sv_maxspeed) // if -really- running
 315         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 316         {
 317                         this.bot_lastseengoal = this.goalcurrent;
 318
 319                         // seen it before
 320                         if(this.bot_timelastseengoal)
 321                         {
 322                                 // for a period of time
 323                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 324                                 {
 325                                         float checkdistance;
 326                                         checkdistance = true;
 327
 328                                         // don't run if it is too close
 329                                         if(this.bot_canruntogoal==0)
 330                                         {
 331                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 332                                                         this.bot_canruntogoal = 1;
 333                                                 else
 334                                                         this.bot_canruntogoal = -1;
 335                                         }
 336
 337                                         if(this.bot_canruntogoal != 1)
 338                                                 return;
 339
 340                                         if(this.aistatus & AI_STATUS_ROAMING)
 341                                         if(this.goalcurrent.classname=="waypoint")
 342                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 343                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 344                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 345                                         {
 346                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 347                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 348                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 349                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 350
 351                                                 if(fabs(deviation.y) < 20)
 352                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 353                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 354                                                 {
 355                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 356                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 357                                                         {
 358                                                                 checkdistance = false;
 359                                                         }
 360                                                 }
 361                                         }
 362
 363                                         if(checkdistance)
 364                                         {
 365                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 366                                                 // increase stop distance in case the goal is on a slope or a lower platform
 367                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 368                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 369                                         }
 370                                         else
 371                                         {
 372                                                 this.aistatus |= AI_STATUS_RUNNING;
 373                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 374                                         }
 375                                 }
 376                         }
 377                         else
 378                         {
 379                                 this.bot_timelastseengoal = time;
 380                         }
 381         }
 382         else
 383         {
 384                 this.bot_timelastseengoal = 0;
 385         }
 386
 387 #if 0
 388         // Release jump button
 389         if(!cvar("sv_pogostick"))
 390         if((IS_ONGROUND(this)) == 0)
 391         {
 392                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 393                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 394
 395                 // Strafe
 396                 if(this.aistatus & AI_STATUS_RUNNING)
 397                 if(vlen(this.velocity)>maxspeed)
 398                 {
 399                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 400                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 401                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 402
 403                         if(fabs(deviation.y)>10)
 404                                 CS(this).movement_x = 0;
 405
 406                         if(deviation.y>10)
 407                                 CS(this).movement_y = maxspeed * -1;
 408                         else if(deviation.y<10)
 409                                 CS(this).movement_y = maxspeed;
 410
 411                 }
 412         }
 413 #endif
 414 }
 415
 416 .entity goalcurrent_prev;
 417 .float goalcurrent_distance;
 418 .float goalcurrent_distance_time;
 419 void havocbot_movetogoal(entity this)
 420 {
 421         vector destorg;
 422         vector diff;
 423         vector dir;
 424         vector flatdir;
 425         vector m1;
 426         vector m2;
 427         vector evadeobstacle;
 428         vector evadelava;
 429         float maxspeed;
 430         vector gco;
 431         //float dist;
 432         vector dodge;
 433         //if (this.goalentity)
 434         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 435         CS(this).movement = '0 0 0';
 436         maxspeed = autocvar_sv_maxspeed;
 437
 438         // Jetpack navigation
 439         if(this.goalcurrent)
 440         if(this.navigation_jetpack_goal)
 441         if(this.goalcurrent==this.navigation_jetpack_goal)
 442         if(this.ammo_fuel)
 443         {
 444                 if(autocvar_bot_debug_goalstack)
 445                 {
 446                         debuggoalstack(this);
 447                         te_wizspike(this.navigation_jetpack_point);
 448                 }
 449
 450                 // Take off
 451                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 452                 {
 453                         // Brake almost completely so it can get a good direction
 454                         if(vdist(this.velocity, >, 10))
 455                                 return;
 456                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 457                 }
 458
 459                 makevectors(this.v_angle.y * '0 1 0');
 460                 dir = normalize(this.navigation_jetpack_point - this.origin);
 461
 462                 // Landing
 463                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 464                 {
 465                         // Calculate brake distance in xy
 466                         float db, v, d;
 467                         vector dxy;
 468
 469                         dxy = this.origin - ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ); dxy.z = 0;
 470                         d = vlen(dxy);
 471                         v = vlen(this.velocity -  this.velocity.z * '0 0 1');
 472                         db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 473                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 474                         if(d < db || d < 500)
 475                         {
 476                                 // Brake
 477                                 if(fabs(this.velocity.x)>maxspeed*0.3)
 478                                 {
 479                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 480                                         return;
 481                                 }
 482                                 // Switch to normal mode
 483                                 this.navigation_jetpack_goal = NULL;
 484                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 485                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 486                                 return;
 487                         }
 488                 }
 489                 else if(checkpvs(this.origin,this.goalcurrent))
 490                 {
 491                         // If I can see the goal switch to landing code
 492                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 493                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 494                         return;
 495                 }
 496
 497                 // Flying
 498                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 499                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 500                 {
 501                         CS(this).movement_x = dir * v_forward * maxspeed;
 502                         CS(this).movement_y = dir * v_right * maxspeed;
 503                 }
 504                 return;
 505         }
 506
 507         // Handling of jump pads
 508         if(this.jumppadcount)
 509         {
 510                 // If got stuck on the jump pad try to reach the farthest visible waypoint
 511                 // but with some randomness so it can try out different paths
 512                 if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 513                 {
 514                         if(fabs(this.velocity.z)<50)
 515                         {
 516                                 entity newgoal = NULL;
 517                                 if (vdist(this.origin - this.goalcurrent.origin, <, 150))
 518                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 519                                 else IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 520                                 {
 521                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 522
 523                                         if(trace_fraction < 1)
 524                                                 continue;
 525
 526                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 527                                                 newgoal = it;
 528                                 });
 529
 530                                 if(newgoal)
 531                                 {
 532                                         this.ignoregoal = this.goalcurrent;
 533                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 534                                         navigation_clearroute(this);
 535                                         navigation_routetogoal(this, newgoal, this.origin);
 536                                         if(autocvar_bot_debug_goalstack)
 537                                                 debuggoalstack(this);
 538                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 539                                 }
 540                         }
 541                         else
 542                                 return;
 543                 }
 544                 else
 545                 {
 546                         if(time - this.lastteleporttime > 0.3 && this.velocity.z > 0)
 547                         {
 548                                 vector velxy = this.velocity; velxy_z = 0;
 549                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 550                                 {
 551                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 552                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 553                                 }
 554                                 return;
 555                         }
 556
 557                         // Don't chase players while using a jump pad
 558                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 559                                 return;
 560                 }
 561         }
 562         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 563                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 564
 565         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 566         if(skill>6)
 567         if (!(IS_ONGROUND(this)))
 568         {
 569                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 570                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 571                 if(this.items & IT_JETPACK)
 572                 {
 573                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 574                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 575                         {
 576                                 if(this.velocity.z<0)
 577                                 {
 578                                         PHYS_INPUT_BUTTON_HOOK(this) = true;
 579                                 }
 580                         }
 581                         else
 582                                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 583
 584                         // If there is no goal try to move forward
 585
 586                         if(this.goalcurrent==NULL)
 587                                 dir = v_forward;
 588                         else
 589                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 590
 591                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 592                         float xyspeed = xyvelocity * dir;
 593
 594                         if(xyspeed < (maxspeed / 2))
 595                         {
 596                                 makevectors(this.v_angle.y * '0 1 0');
 597                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 598                                 if(trace_fraction==1)
 599                                 {
 600                                         CS(this).movement_x = dir * v_forward * maxspeed;
 601                                         CS(this).movement_y = dir * v_right * maxspeed;
 602                                         if (skill < 10)
 603                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 604                                 }
 605                         }
 606
 607                         this.havocbot_blockhead = true;
 608
 609                         return;
 610                 }
 611                 else if(this.health > WEP_CVAR(devastator, damage) * 0.5 * ((this.strength_finished < time) ? autocvar_g_balance_powerup_strength_selfdamage : 1))
 612                 {
 613                         if(this.velocity.z < 0)
 614                         {
 615                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 616                                 {
 617                                         .entity weaponentity = weaponentities[slot];
 618
 619                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 620                                                 continue;
 621
 622                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 623                                         {
 624                                                 CS(this).movement_x = maxspeed;
 625
 626                                                 if(this.rocketjumptime)
 627                                                 {
 628                                                         if(time > this.rocketjumptime)
 629                                                         {
 630                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 631                                                                 this.rocketjumptime = 0;
 632                                                         }
 633                                                         return;
 634                                                 }
 635
 636                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 637                                                 this.v_angle_x = 90;
 638                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 639                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 640                                                 return;
 641                                         }
 642                                 }
 643                         }
 644                 }
 645                 else
 646                 {
 647                         // If there is no goal try to move forward
 648                         if(this.goalcurrent==NULL)
 649                                 CS(this).movement_x = maxspeed;
 650                 }
 651         }
 652
 653         // If we are under water with no goals, swim up
 654         if(this.waterlevel)
 655         if(this.goalcurrent==NULL)
 656         {
 657                 dir = '0 0 0';
 658                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 659                         dir.z = 1;
 660                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 661                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 662                 else
 663                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 664                 makevectors(this.v_angle.y * '0 1 0');
 665                 CS(this).movement_x = dir * v_forward * maxspeed;
 666                 CS(this).movement_y = dir * v_right * maxspeed;
 667                 CS(this).movement_z = dir * v_up * maxspeed;
 668         }
 669
 670         // if there is nowhere to go, exit
 671         if (this.goalcurrent == NULL)
 672                 return;
 673
 674
 675         bool locked_goal = false;
 676         if(this.goalentity && wasfreed(this.goalentity))
 677         {
 678                 navigation_clearroute(this);
 679                 this.bot_strategytime = 0;
 680                 return;
 681         }
 682         else if(this.goalentity.bot_pickup)
 683         {
 684                 if(this.goalentity.bot_pickup_respawning)
 685                 {
 686                         if(this.goalentity.solid) // item respawned
 687                                 this.goalentity.bot_pickup_respawning = false;
 688                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 689                         {
 690                                 this.goalentity.bot_pickup_respawning = false;
 691                                 navigation_clearroute(this);
 692                                 this.bot_strategytime = 0;
 693                                 return;
 694                         }
 695                         else if(this.goalentity == this.goalcurrent)
 696                                 locked_goal = true; // wait for item to respawn
 697                 }
 698                 else if(!this.goalentity.solid)
 699                 {
 700                         navigation_clearroute(this);
 701                         this.bot_strategytime = 0;
 702                         return;
 703                 }
 704         }
 705         if(!locked_goal)
 706                 navigation_poptouchedgoals(this);
 707
 708         // if ran out of goals try to use an alternative goal or get a new strategy asap
 709         if(this.goalcurrent == NULL)
 710         {
 711                 this.bot_strategytime = 0;
 712                 return;
 713         }
 714
 715
 716         if(autocvar_bot_debug_goalstack)
 717                 debuggoalstack(this);
 718
 719         m1 = this.goalcurrent.origin + this.goalcurrent.mins;
 720         m2 = this.goalcurrent.origin + this.goalcurrent.maxs;
 721         destorg = this.origin;
 722         destorg.x = bound(m1_x, destorg.x, m2_x);
 723         destorg.y = bound(m1_y, destorg.y, m2_y);
 724         destorg.z = bound(m1_z, destorg.z, m2_z);
 725         diff = destorg - this.origin;
 726         //dist = vlen(diff);
 727         dir = normalize(diff);
 728         flatdir = diff;flatdir.z = 0;
 729         flatdir = normalize(flatdir);
 730         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 731
 732         //if (this.bot_dodgevector_time < time)
 733         {
 734         //      this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 735         //      this.bot_dodgevector_jumpbutton = 1;
 736                 evadeobstacle = '0 0 0';
 737                 evadelava = '0 0 0';
 738
 739                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 740                 makevectors(this.v_angle.y * '0 1 0');
 741                 if (this.waterlevel)
 742                 {
 743                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 744                         {
 745                         //      flatdir_z = 1;
 746                                 this.aistatus |= AI_STATUS_OUT_WATER;
 747                         }
 748                         else
 749                         {
 750                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 751                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 752                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 753                                 else
 754                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 755                         }
 756                         dir = normalize(flatdir);
 757                 }
 758                 else
 759                 {
 760                         float s;
 761                         vector offset;
 762                         if(this.aistatus & AI_STATUS_OUT_WATER)
 763                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 764
 765                         // jump if going toward an obstacle that doesn't look like stairs we
 766                         // can walk up directly
 767                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 768                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 769                         if (trace_fraction < 1)
 770                         if (trace_plane_normal.z < 0.7)
 771                         {
 772                                 s = trace_fraction;
 773                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 774                                 if (trace_fraction < s + 0.01)
 775                                 if (trace_plane_normal.z < 0.7)
 776                                 {
 777                                         s = trace_fraction;
 778                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 779                                         if (trace_fraction > s)
 780                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 781                                 }
 782                         }
 783
 784                         // if bot for some reason doesn't get close to the current goal find another one
 785                         if(!IS_PLAYER(this.goalcurrent) && !(this.goalcurrent.bot_pickup_respawning && this.goalcurrent_distance < 50))
 786                         {
 787                                 float curr_dist = vlen(this.origin - this.goalcurrent.origin);
 788                                 if(this.goalcurrent != this.goalcurrent_prev)
 789                                 {
 790                                         this.goalcurrent_prev = this.goalcurrent;
 791                                         this.goalcurrent_distance = curr_dist;
 792                                         this.goalcurrent_distance_time = 0;
 793                                 }
 794                                 else if(curr_dist > this.goalcurrent_distance)
 795                                 {
 796                                         if(!this.goalcurrent_distance_time)
 797                                                 this.goalcurrent_distance_time = time;
 798                                         else if (time - this.goalcurrent_distance_time > 0.5)
 799                                         {
 800                                                 this.goalcurrent_prev = NULL;
 801                                                 navigation_clearroute(this);
 802                                                 this.bot_strategytime = 0;
 803                                                 return;
 804                                         }
 805                                 }
 806                                 else
 807                                 {
 808                                         // reduce it a little bit so it works even with very small approaches to the goal
 809                                         this.goalcurrent_distance = max(20, curr_dist - 15);
 810                                         this.goalcurrent_distance_time = 0;
 811                                 }
 812                         }
 813
 814                         // Check for water/slime/lava and dangerous edges
 815                         // (only when the bot is on the ground or jumping intentionally)
 816
 817                         vector dst_ahead = this.origin + this.view_ofs + offset;
 818                         vector dst_down = dst_ahead - '0 0 3000';
 819                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 820
 821                         bool unreachable = false;
 822                         bool ignorehazards = false;
 823                         s = CONTENT_SOLID;
 824                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 825                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 826                         {
 827                                 // Look downwards
 828                                 traceline(dst_ahead , dst_down, true, NULL);
 829                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 830                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 831                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 832                                 {
 833                                         s = pointcontents(trace_endpos + '0 0 1');
 834                                         if (s != CONTENT_SOLID)
 835                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 836                                         {
 837                                                 evadelava = normalize(this.velocity) * -1;
 838                                                 if(this.waterlevel >= WATERLEVEL_WETFEET && (this.watertype == CONTENT_LAVA || this.watertype == CONTENT_SLIME))
 839                                                         ignorehazards = true;
 840                                         }
 841                                         else if (s == CONTENT_WATER)
 842                                         {
 843                                                 if(this.waterlevel >= WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER)
 844                                                         ignorehazards = true;
 845                                         }
 846                                         else if (s == CONTENT_SKY)
 847                                                 evadeobstacle = normalize(this.velocity) * -1;
 848                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 849                                         {
 850                                                 // the traceline check isn't enough but is good as optimization,
 851                                                 // when not true (most of the time) this tracebox call is avoided
 852                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 853                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 854                                                 {
 855                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 856                                                         {
 857                                                                 // the goal is probably on an upper platform, assume bot can't get there
 858                                                                 unreachable = true;
 859                                                         }
 860                                                         else
 861                                                                 evadelava = normalize(this.velocity) * -1;
 862                                                 }
 863                                         }
 864                                 }
 865                         }
 866
 867                         dir = flatdir;
 868                         evadeobstacle.z = 0;
 869                         evadelava.z = 0;
 870                         makevectors(this.v_angle.y * '0 1 0');
 871
 872                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 873                         {
 874                                 if(!ignorehazards)
 875                                         this.aistatus |= AI_STATUS_DANGER_AHEAD;
 876                                 if(IS_PLAYER(this.goalcurrent))
 877                                         unreachable = true;
 878                         }
 879                         if(unreachable)
 880                         {
 881                                 navigation_clearroute(this);
 882                                 this.bot_strategytime = 0;
 883                         }
 884                 }
 885
 886                 dodge = havocbot_dodge(this);
 887                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 888                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 889                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 890                 if(IS_PLAYER(trace_ent))
 891                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 892
 893                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 894         //      this.bot_dodgevector = dir;
 895         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 896         }
 897
 898         if(time < this.ladder_time)
 899         {
 900                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 901                 {
 902                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 903                                 dir.z = 1;
 904                 }
 905                 else
 906                 {
 907                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 908                                 dir.z = -1;
 909                 }
 910         }
 911
 912         //dir = this.bot_dodgevector;
 913         //if (this.bot_dodgevector_jumpbutton)
 914         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 915         CS(this).movement_x = dir * v_forward * maxspeed;
 916         CS(this).movement_y = dir * v_right * maxspeed;
 917         CS(this).movement_z = dir * v_up * maxspeed;
 918
 919         // Emulate keyboard interface
 920         if (skill < 10)
 921                 havocbot_keyboard_movement(this, destorg);
 922
 923         // Bunnyhop!
 924 //      if(this.aistatus & AI_STATUS_ROAMING)
 925         if(this.goalcurrent)
 926         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 927                 havocbot_bunnyhop(this, dir);
 928
 929         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
 930         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
 931         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
 932 }
 933
 934 entity havocbot_gettarget(entity this, bool secondary)
 935 {
 936         entity best = NULL;
 937         vector eye = CENTER_OR_VIEWOFS(this);
 938         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
 939         {
 940                 vector v = CENTER_OR_VIEWOFS(it);
 941                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 942                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
 943                 if(bot_shouldattack(this, it))
 944                 {
 945                         traceline(eye, v, true, this);
 946                         if (trace_ent == it || trace_fraction >= 1)
 947                                 best = it;
 948                 }
 949         });
 950
 951         return best;
 952 }
 953
 954 void havocbot_chooseenemy(entity this)
 955 {
 956         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 957         {
 958                 this.enemy = NULL;
 959                 return;
 960         }
 961         if (this.enemy)
 962         {
 963                 if (!bot_shouldattack(this, this.enemy))
 964                 {
 965                         // enemy died or something, find a new target
 966                         this.enemy = NULL;
 967                         this.havocbot_chooseenemy_finished = time;
 968                 }
 969                 else if (this.havocbot_stickenemy)
 970                 {
 971                         // tracking last chosen enemy
 972                         // if enemy is visible
 973                         // and not really really far away
 974                         // and we're not severely injured
 975                         // then keep tracking for a half second into the future
 976                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
 977                         if (trace_ent == this.enemy || trace_fraction == 1)
 978                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
 979                         if (this.health > 30)
 980                         {
 981                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 982                                 this.havocbot_chooseenemy_finished = time + 0.5;
 983                                 return;
 984                         }
 985                         // enemy isn't visible, or is far away, or we're injured severely
 986                         // so stop preferring this enemy
 987                         // (it will still take a half second until a new one is chosen)
 988                         this.havocbot_stickenemy = 0;
 989                 }
 990         }
 991         if (time < this.havocbot_chooseenemy_finished)
 992                 return;
 993         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
 994         vector eye = this.origin + this.view_ofs;
 995         entity best = NULL;
 996         float bestrating = 100000000;
 997
 998         // Backup hit flags
 999         int hf = this.dphitcontentsmask;
1000
1001         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1002
1003         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1004
1005         bool scan_transparent = false;
1006         bool scan_secondary_targets = false;
1007         bool have_secondary_targets = false;
1008         while(true)
1009         {
1010                 scan_secondary_targets = false;
1011 LABEL(scan_targets)
1012                 IL_EACH(g_bot_targets, it.bot_attack,
1013                 {
1014                         if(!scan_secondary_targets)
1015                         {
1016                                 if(it.classname == "misc_breakablemodel")
1017                                 {
1018                                         have_secondary_targets = true;
1019                                         continue;
1020                                 }
1021                         }
1022                         else if(it.classname != "misc_breakablemodel")
1023                                 continue;
1024
1025                         vector v = (it.absmin + it.absmax) * 0.5;
1026                         float rating = vlen2(v - eye);
1027                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1028                         if (bestrating > rating)
1029                         if (bot_shouldattack(this, it))
1030                         {
1031                                 traceline(eye, v, true, this);
1032                                 if (trace_ent == it || trace_fraction >= 1)
1033                                 {
1034                                         best = it;
1035                                         bestrating = rating;
1036                                 }
1037                         }
1038                 });
1039
1040                 if(!best && have_secondary_targets && !scan_secondary_targets)
1041                 {
1042                         scan_secondary_targets = true;
1043                         // restart the loop
1044                         bestrating = 100000000;
1045                         goto scan_targets;
1046                 }
1047
1048                 // I want to do a second scan if no enemy was found or I don't have weapons
1049                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1050                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1051                         break;
1052                 if(scan_transparent)
1053                         break;
1054
1055                 // Set flags to see through transparent objects
1056                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1057
1058                 scan_transparent = true;
1059         }
1060
1061         // Restore hit flags
1062         this.dphitcontentsmask = hf;
1063
1064         this.enemy = best;
1065         this.havocbot_stickenemy = true;
1066         if(best && best.classname == "misc_breakablemodel")
1067                 this.havocbot_stickenemy = false;
1068 }
1069
1070 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1071 {
1072         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1073         // so skip this for them, or they'll never get to reload their weapons at all.
1074         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1075         if(skill < 5)
1076                 return false;
1077
1078         // if this weapon is scheduled for reloading, don't switch to it during combat
1079         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1080         {
1081                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1082                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1083                                 return true; // other weapon available
1084                 ));
1085         }
1086
1087         return false;
1088 }
1089
1090 void havocbot_chooseweapon(entity this, .entity weaponentity)
1091 {
1092         int i;
1093
1094         // ;)
1095         if(g_weaponarena_weapons == WEPSET(TUBA))
1096         {
1097                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1098                 return;
1099         }
1100
1101         // TODO: clean this up by moving it to weapon code
1102         if(this.enemy==NULL)
1103         {
1104                 // If no weapon was chosen get the first available weapon
1105                 if(this.(weaponentity).m_weapon==WEP_Null)
1106                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
1107                         if(client_hasweapon(this, it, weaponentity, true, false))
1108                         {
1109                                 this.(weaponentity).m_switchweapon = it;
1110                                 return;
1111                         }
1112                 ));
1113                 return;
1114         }
1115
1116         // Do not change weapon during the next second after a combo
1117         float f = time - this.lastcombotime;
1118         if(f < 1)
1119                 return;
1120
1121         float w;
1122         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1123
1124         // Should it do a weapon combo?
1125         float af, ct, combo_time, combo;
1126
1127         af = ATTACK_FINISHED(this, 0);
1128         ct = autocvar_bot_ai_weapon_combo_threshold;
1129
1130         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1131         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1132         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1133
1134         combo = false;
1135
1136         if(autocvar_bot_ai_weapon_combo)
1137         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1138         if(af > combo_time)
1139         {
1140                 combo = true;
1141                 this.lastcombotime = time;
1142         }
1143
1144         distance *= (2 ** this.bot_rangepreference);
1145
1146         // Custom weapon list based on distance to the enemy
1147         if(bot_custom_weapon){
1148
1149                 // Choose weapons for far distance
1150                 if ( distance > bot_distance_far ) {
1151                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1152                                 w = bot_weapons_far[i];
1153                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1154                                 {
1155                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1156                                                 continue;
1157                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1158                                         return;
1159                                 }
1160                         }
1161                 }
1162
1163                 // Choose weapons for mid distance
1164                 if ( distance > bot_distance_close) {
1165                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1166                                 w = bot_weapons_mid[i];
1167                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1168                                 {
1169                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1170                                                 continue;
1171                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1172                                         return;
1173                                 }
1174                         }
1175                 }
1176
1177                 // Choose weapons for close distance
1178                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1179                         w = bot_weapons_close[i];
1180                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1181                         {
1182                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1183                                         continue;
1184                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1185                                 return;
1186                         }
1187                 }
1188         }
1189 }
1190
1191 void havocbot_aim(entity this)
1192 {
1193         if (time < this.nextaim)
1194                 return;
1195         this.nextaim = time + 0.1;
1196         vector myvel = this.velocity;
1197         if (!this.waterlevel)
1198                 myvel.z = 0;
1199         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1200         else if (this.enemy)
1201         {
1202                 vector enemyvel = this.enemy.velocity;
1203                 if (!this.enemy.waterlevel)
1204                         enemyvel.z = 0;
1205                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1206         }
1207         else
1208                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1209 }
1210
1211 bool havocbot_moveto_refresh_route(entity this)
1212 {
1213         // Refresh path to goal if necessary
1214         entity wp;
1215         wp = this.havocbot_personal_waypoint;
1216         navigation_goalrating_start(this);
1217         navigation_routerating(this, wp, 10000, 10000);
1218         navigation_goalrating_end(this);
1219         return (this.goalentity != NULL);
1220 }
1221
1222 float havocbot_moveto(entity this, vector pos)
1223 {
1224         entity wp;
1225
1226         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1227         {
1228                 // Step 4: Move to waypoint
1229                 if(this.havocbot_personal_waypoint==NULL)
1230                 {
1231                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1232                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1233                         return CMD_STATUS_ERROR;
1234                 }
1235
1236                 if (!bot_strategytoken_taken)
1237                 if(this.havocbot_personal_waypoint_searchtime<time)
1238                 {
1239                         bot_strategytoken_taken = true;
1240                         if(havocbot_moveto_refresh_route(this))
1241                         {
1242                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1243                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1244                                 this.havocbot_personal_waypoint_failcounter = 0;
1245                         }
1246                         else
1247                         {
1248                                 this.havocbot_personal_waypoint_failcounter += 1;
1249                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1250                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1251                                 {
1252                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1253                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1254                                         delete(this.havocbot_personal_waypoint);
1255                                         return CMD_STATUS_ERROR;
1256                                 }
1257                                 else
1258                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1259                         }
1260                 }
1261
1262                 if(autocvar_bot_debug_goalstack)
1263                         debuggoalstack(this);
1264
1265                 // Heading
1266                 vector dir = ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - (this.origin + this.view_ofs);
1267                 dir.z = 0;
1268                 bot_aimdir(this, dir, -1);
1269
1270                 // Go!
1271                 havocbot_movetogoal(this);
1272
1273                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1274                 {
1275                         // Step 5: Waypoint reached
1276                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1277                         delete(this.havocbot_personal_waypoint);
1278                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1279                         return CMD_STATUS_FINISHED;
1280                 }
1281
1282                 return CMD_STATUS_EXECUTING;
1283         }
1284
1285         // Step 2: Linking waypoint
1286         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1287         {
1288                 // Wait until it is linked
1289                 if(!this.havocbot_personal_waypoint.wplinked)
1290                 {
1291                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1292                         return CMD_STATUS_EXECUTING;
1293                 }
1294
1295                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1296                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1297                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1298
1299                 // Step 3: Route to waypoint
1300                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1301
1302                 return CMD_STATUS_EXECUTING;
1303         }
1304
1305         // Step 1: Spawning waypoint
1306         wp = waypoint_spawnpersonal(this, pos);
1307         if(wp==NULL)
1308         {
1309                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1310                 return CMD_STATUS_ERROR;
1311         }
1312
1313         this.havocbot_personal_waypoint = wp;
1314         this.havocbot_personal_waypoint_failcounter = 0;
1315         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1316
1317         // if pos is inside a teleport, then let's mark it as teleport waypoint
1318         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1319         {
1320                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1321                 this.lastteleporttime = 0;
1322         });
1323
1324 /*
1325         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1326                 print("routing to a teleporter\n");
1327         else
1328                 print("routing to a non-teleporter\n");
1329 */
1330
1331         return CMD_STATUS_EXECUTING;
1332 }
1333
1334 float havocbot_resetgoal(entity this)
1335 {
1336         navigation_clearroute(this);
1337         return CMD_STATUS_FINISHED;
1338 }
1339
1340 void havocbot_setupbot(entity this)
1341 {
1342         this.bot_ai = havocbot_ai;
1343         this.cmd_moveto = havocbot_moveto;
1344         this.cmd_resetgoal = havocbot_resetgoal;
1345
1346         havocbot_chooserole(this);
1347 }
1348
1349 vector havocbot_dodge(entity this)
1350 {
1351         // LordHavoc: disabled because this is too expensive
1352         return '0 0 0';
1353 #if 0
1354         entity head;
1355         vector dodge, v, n;
1356         float danger, bestdanger, vl, d;
1357         dodge = '0 0 0';
1358         bestdanger = -20;
1359         // check for dangerous objects near bot or approaching bot
1360         head = findchainfloat(bot_dodge, true);
1361         while(head)
1362         {
1363                 if (head.owner != this)
1364                 {
1365                         vl = vlen(head.velocity);
1366                         if (vl > autocvar_sv_maxspeed * 0.3)
1367                         {
1368                                 n = normalize(head.velocity);
1369                                 v = this.origin - head.origin;
1370                                 d = v * n;
1371                                 if (d > (0 - head.bot_dodgerating))
1372                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1373                                 {
1374                                         // calculate direction and distance from the flight path, by removing the forward axis
1375                                         v = v - (n * (v * n));
1376                                         danger = head.bot_dodgerating - vlen(v);
1377                                         if (bestdanger < danger)
1378                                         {
1379                                                 bestdanger = danger;
1380                                                 // dodge to the side of the object
1381                                                 dodge = normalize(v);
1382                                         }
1383                                 }
1384                         }
1385                         else
1386                         {
1387                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1388                                 if (bestdanger < danger)
1389                                 {
1390                                         bestdanger = danger;
1391                                         dodge = normalize(this.origin - head.origin);
1392                                 }
1393                         }
1394                 }
1395                 head = head.chain;
1396         }
1397         return dodge;
1398 #endif
1399 }