qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/mapobjects/func/ladder.qh>
  22 #include <common/mapobjects/teleporters.qh>
  23 #include <common/mapobjects/trigger/jumppads.qh>
  24
  25 #include <lib/warpzone/common.qh>
  26
  27 .float speed;
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if(IS_DEAD(this) || STAT(FROZEN, this))
  93         {
  94                 if (this.goalcurrent)
  95                         navigation_clearroute(this);
  96                 return;
  97         }
  98
  99         havocbot_chooseenemy(this);
 100
 101         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 102         {
 103                 .entity weaponentity = weaponentities[slot];
 104                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 105                 if(this.(weaponentity).bot_chooseweapontime < time)
 106                 {
 107                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 108                         havocbot_chooseweapon(this, weaponentity);
 109                 }
 110         }
 111         havocbot_aim(this);
 112         lag_update(this);
 113
 114         if (this.bot_aimtarg)
 115         {
 116                 this.aistatus |= AI_STATUS_ATTACKING;
 117                 this.aistatus &= ~AI_STATUS_ROAMING;
 118
 119                 if(STAT(WEAPONS, this))
 120                 {
 121                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 122                         {
 123                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 124                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 125                         }
 126                         else
 127                         {
 128                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 129                                 {
 130                                         .entity weaponentity = weaponentities[slot];
 131                                         Weapon w = this.(weaponentity).m_weapon;
 132                                         if(w == WEP_Null && slot != 0)
 133                                                 continue;
 134                                         w.wr_aim(w, this, weaponentity);
 135                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 136                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 137                                 }
 138                         }
 139                 }
 140                 else
 141                 {
 142                         if(IS_PLAYER(this.bot_aimtarg))
 143                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 144                 }
 145         }
 146         else if (this.goalcurrent)
 147         {
 148                 this.aistatus |= AI_STATUS_ROAMING;
 149                 this.aistatus &= ~AI_STATUS_ATTACKING;
 150         }
 151
 152         havocbot_movetogoal(this);
 153         if (!this.bot_aimdir_executed && this.goalcurrent)
 154         {
 155                 // Heading
 156                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 157                 dir -= this.origin + this.view_ofs;
 158                 dir.z = 0;
 159                 bot_aimdir(this, dir, 0);
 160         }
 161
 162         // if the bot is not attacking, consider reloading weapons
 163         if (!(this.aistatus & AI_STATUS_ATTACKING))
 164         {
 165                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 166                 {
 167                         .entity weaponentity = weaponentities[slot];
 168
 169                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 170                                 continue;
 171
 172                         // we are currently holding a weapon that's not fully loaded, reload it
 173                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 174                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 175                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 176
 177                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 178                         // the code above executes next frame, starting the reloading then
 179                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 180                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 181                         {
 182                                 FOREACH(Weapons, it != WEP_Null, {
 183                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 184                                         {
 185                                                 this.(weaponentity).m_switchweapon = it;
 186                                                 break;
 187                                         }
 188                                 });
 189                         }
 190                 }
 191         }
 192 }
 193
 194 void havocbot_keyboard_movement(entity this, vector destorg)
 195 {
 196         vector keyboard;
 197
 198         if (time > this.havocbot_keyboardtime)
 199         {
 200                 float sk = skill + this.bot_moveskill;
 201                 this.havocbot_keyboardtime =
 202                         max(
 203                                 this.havocbot_keyboardtime
 204                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 205                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 206                         , time);
 207                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 208
 209                 float trigger = autocvar_bot_ai_keyboard_threshold;
 210                 float trigger1 = -trigger;
 211
 212                 // categorize forward movement
 213                 // at skill < 1.5 only forward
 214                 // at skill < 2.5 only individual directions
 215                 // at skill < 4.5 only individual directions, and forward diagonals
 216                 // at skill >= 4.5, all cases allowed
 217                 if (keyboard.x > trigger)
 218                 {
 219                         keyboard.x = 1;
 220                         if (sk < 2.5)
 221                                 keyboard.y = 0;
 222                 }
 223                 else if (keyboard.x < trigger1 && sk > 1.5)
 224                 {
 225                         keyboard.x = -1;
 226                         if (sk < 4.5)
 227                                 keyboard.y = 0;
 228                 }
 229                 else
 230                 {
 231                         keyboard.x = 0;
 232                         if (sk < 1.5)
 233                                 keyboard.y = 0;
 234                 }
 235                 if (sk < 4.5)
 236                         keyboard.z = 0;
 237
 238                 if (keyboard.y > trigger)
 239                         keyboard.y = 1;
 240                 else if (keyboard.y < trigger1)
 241                         keyboard.y = -1;
 242                 else
 243                         keyboard.y = 0;
 244
 245                 if (keyboard.z > trigger)
 246                         keyboard.z = 1;
 247                 else if (keyboard.z < trigger1)
 248                         keyboard.z = -1;
 249                 else
 250                         keyboard.z = 0;
 251
 252                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 253                 if (this.havocbot_ducktime > time)
 254                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 255         }
 256
 257         keyboard = this.havocbot_keyboard;
 258         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 259         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 260         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 261 }
 262
 263 void havocbot_bunnyhop(entity this, vector dir)
 264 {
 265         float bunnyhopdistance;
 266         vector deviation;
 267         float maxspeed;
 268
 269         // Don't jump when attacking
 270         if(this.aistatus & AI_STATUS_ATTACKING)
 271                 return;
 272
 273         if(IS_PLAYER(this.goalcurrent))
 274                 return;
 275
 276         maxspeed = autocvar_sv_maxspeed;
 277
 278         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 279                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 280         {
 281                 this.aistatus &= ~AI_STATUS_RUNNING;
 282                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 283                 this.bot_canruntogoal = 0;
 284                 this.bot_timelastseengoal = 0;
 285                 return;
 286         }
 287
 288         if(this.waterlevel > WATERLEVEL_WETFEET)
 289         {
 290                 this.aistatus &= ~AI_STATUS_RUNNING;
 291                 return;
 292         }
 293
 294         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 295         {
 296                 this.bot_canruntogoal = 0;
 297                 this.bot_timelastseengoal = 0;
 298         }
 299
 300         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 301         bunnyhopdistance = vlen(this.origin - gco);
 302
 303         // Run only to visible goals
 304         if(IS_ONGROUND(this))
 305         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 306         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 307         {
 308                         this.bot_lastseengoal = this.goalcurrent;
 309
 310                         // seen it before
 311                         if(this.bot_timelastseengoal)
 312                         {
 313                                 // for a period of time
 314                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 315                                 {
 316                                         float checkdistance;
 317                                         checkdistance = true;
 318
 319                                         // don't run if it is too close
 320                                         if(this.bot_canruntogoal==0)
 321                                         {
 322                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 323                                                         this.bot_canruntogoal = 1;
 324                                                 else
 325                                                         this.bot_canruntogoal = -1;
 326                                         }
 327
 328                                         if(this.bot_canruntogoal != 1)
 329                                                 return;
 330
 331                                         if(this.aistatus & AI_STATUS_ROAMING)
 332                                         if(this.goalcurrent.classname=="waypoint")
 333                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 334                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 335                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 336                                         {
 337                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 338                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 339                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 340                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 341
 342                                                 if(fabs(deviation.y) < 20)
 343                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 344                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 345                                                 {
 346                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 347                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 348                                                         {
 349                                                                 checkdistance = false;
 350                                                         }
 351                                                 }
 352                                         }
 353
 354                                         if(checkdistance)
 355                                         {
 356                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 357                                                 // increase stop distance in case the goal is on a slope or a lower platform
 358                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 359                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 360                                         }
 361                                         else
 362                                         {
 363                                                 this.aistatus |= AI_STATUS_RUNNING;
 364                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 365                                         }
 366                                 }
 367                         }
 368                         else
 369                         {
 370                                 this.bot_timelastseengoal = time;
 371                         }
 372         }
 373         else
 374         {
 375                 this.bot_timelastseengoal = 0;
 376         }
 377
 378 #if 0
 379         // Release jump button
 380         if(!cvar("sv_pogostick"))
 381         if((IS_ONGROUND(this)) == 0)
 382         {
 383                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 384                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 385
 386                 // Strafe
 387                 if(this.aistatus & AI_STATUS_RUNNING)
 388                 if(vlen(this.velocity)>maxspeed)
 389                 {
 390                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 391                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 392                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 393
 394                         if(fabs(deviation.y)>10)
 395                                 CS(this).movement_x = 0;
 396
 397                         if(deviation.y>10)
 398                                 CS(this).movement_y = maxspeed * -1;
 399                         else if(deviation.y<10)
 400                                 CS(this).movement_y = maxspeed;
 401
 402                 }
 403         }
 404 #endif
 405 }
 406
 407 // return true when bot isn't getting closer to the current goal
 408 bool havocbot_checkgoaldistance(entity this, vector gco)
 409 {
 410         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 411         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 412         float distance_time = this.goalcurrent_distance_time;
 413         if(distance_time < 0)
 414                 distance_time = -distance_time;
 415         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 416         {
 417                 if(!distance_time)
 418                         this.goalcurrent_distance_time = time;
 419                 else if (time - distance_time > 0.5)
 420                         return true;
 421         }
 422         else
 423         {
 424                 // reduce it a little bit so it works even with very small approaches to the goal
 425                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 426                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 427                 this.goalcurrent_distance_time = 0;
 428         }
 429         return false;
 430 }
 431
 432 entity havocbot_select_an_item_of_group(entity this, int gr)
 433 {
 434         entity selected = NULL;
 435         float selected_dist2 = 0;
 436         // select farthest item of this group from bot's position
 437         IL_EACH(g_items, it.item_group == gr && it.solid,
 438         {
 439                 float dist2 = vlen2(this.origin - it.origin);
 440                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 441                 {
 442                         selected = it;
 443                         selected_dist2 = vlen2(this.origin - selected.origin);
 444                 }
 445         });
 446
 447         if (!selected)
 448                 return NULL;
 449
 450         set_tracewalk_dest(selected, this.origin, false);
 451         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 452                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 453         {
 454                 return NULL;
 455         }
 456
 457         return selected;
 458 }
 459
 460 void havocbot_movetogoal(entity this)
 461 {
 462         vector diff;
 463         vector dir;
 464         vector flatdir;
 465         vector evadeobstacle;
 466         vector evadelava;
 467         float dodge_enemy_factor = 1;
 468         float maxspeed;
 469         //float dist;
 470         vector dodge;
 471         //if (this.goalentity)
 472         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 473         CS(this).movement = '0 0 0';
 474         maxspeed = autocvar_sv_maxspeed;
 475
 476         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 477         // Jetpack navigation
 478         if(this.navigation_jetpack_goal)
 479         if(this.goalcurrent==this.navigation_jetpack_goal)
 480         if(GetResourceAmount(this, RESOURCE_FUEL))
 481         {
 482                 if(autocvar_bot_debug_goalstack)
 483                 {
 484                         debuggoalstack(this);
 485                         te_wizspike(this.navigation_jetpack_point);
 486                 }
 487
 488                 // Take off
 489                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 490                 {
 491                         // Brake almost completely so it can get a good direction
 492                         if(vdist(this.velocity, >, 10))
 493                                 return;
 494                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 495                 }
 496
 497                 makevectors(this.v_angle.y * '0 1 0');
 498                 dir = normalize(this.navigation_jetpack_point - this.origin);
 499
 500                 // Landing
 501                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 502                 {
 503                         // Calculate brake distance in xy
 504                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 505                         float vel2 = vlen2(vec2(this.velocity));
 506                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 507                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 508                         if(d < db || d < 500)
 509                         {
 510                                 // Brake
 511                                 if (vel2 > (maxspeed * 0.3) ** 2)
 512                                 {
 513                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 514                                         return;
 515                                 }
 516                                 // Switch to normal mode
 517                                 this.navigation_jetpack_goal = NULL;
 518                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 519                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 520                                 return;
 521                         }
 522                 }
 523                 else if(checkpvs(this.origin,this.goalcurrent))
 524                 {
 525                         // If I can see the goal switch to landing code
 526                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 527                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 528                         return;
 529                 }
 530
 531                 // Flying
 532                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 533                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 534                 {
 535                         CS(this).movement_x = dir * v_forward * maxspeed;
 536                         CS(this).movement_y = dir * v_right * maxspeed;
 537                 }
 538                 return;
 539         }
 540
 541         // Handling of jump pads
 542         if(this.jumppadcount)
 543         {
 544                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 545                 {
 546                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 547                         if(navigation_poptouchedgoals(this))
 548                                 return;
 549                 }
 550                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 551                 {
 552                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 553                         // but with some randomness so it can try out different paths
 554                         if(!this.goalcurrent)
 555                         {
 556                                 entity newgoal = NULL;
 557                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 558                                 {
 559                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 560                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 561                                                 continue;
 562
 563                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 564
 565                                         if(trace_fraction < 1)
 566                                                 continue;
 567
 568                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 569                                                 newgoal = it;
 570                                 });
 571
 572                                 if(newgoal)
 573                                 {
 574                                         this.ignoregoal = this.goalcurrent;
 575                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 576                                         navigation_clearroute(this);
 577                                         navigation_routetogoal(this, newgoal, this.origin);
 578                                         if(autocvar_bot_debug_goalstack)
 579                                                 debuggoalstack(this);
 580                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 581                                 }
 582                         }
 583                         else //if (this.goalcurrent)
 584                         {
 585                                 if (this.goalcurrent.bot_pickup)
 586                                 {
 587                                         entity jumppad_wp = this.goalcurrent_prev;
 588                                         navigation_poptouchedgoals(this);
 589                                         if(!this.goalcurrent && jumppad_wp.wp00)
 590                                         {
 591                                                 // head to the jumppad destination once bot reaches the goal item
 592                                                 navigation_pushroute(this, jumppad_wp.wp00);
 593                                         }
 594                                 }
 595                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 596                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 597                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 598                                 else if(havocbot_checkgoaldistance(this, gco))
 599                                 {
 600                                         navigation_clearroute(this);
 601                                         navigation_goalrating_timeout_force(this);
 602                                 }
 603                                 else
 604                                         return;
 605                         }
 606                 }
 607                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 608                 {
 609                         if(this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 610                         {
 611                                 vector velxy = this.velocity; velxy_z = 0;
 612                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 613                                 {
 614                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 615                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 616                                 }
 617                                 return;
 618                         }
 619
 620                         // Don't chase players while using a jump pad
 621                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 622                                 return;
 623                 }
 624         }
 625         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 626                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 627
 628         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 629         if (skill > 6 && !(IS_ONGROUND(this)))
 630         {
 631                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 632                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 633                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 634
 635                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 636                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 637                 if(this.items & IT_JETPACK)
 638                 {
 639                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 640                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 641                         {
 642                                 if(this.velocity.z<0)
 643                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 644                         }
 645                         else
 646                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 647
 648                         // If there is no goal try to move forward
 649
 650                         if(this.goalcurrent==NULL)
 651                                 dir = v_forward;
 652                         else
 653                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 654
 655                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 656                         float xyspeed = xyvelocity * dir;
 657
 658                         if(xyspeed < (maxspeed / 2))
 659                         {
 660                                 makevectors(this.v_angle.y * '0 1 0');
 661                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 662                                 if(trace_fraction==1)
 663                                 {
 664                                         CS(this).movement_x = dir * v_forward * maxspeed;
 665                                         CS(this).movement_y = dir * v_right * maxspeed;
 666                                         if (skill < 10)
 667                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 668                                 }
 669                         }
 670
 671                         this.havocbot_blockhead = true;
 672
 673                         return;
 674                 }
 675                 else if(!this.jumppadcount && !this.goalcurrent.wphardwired
 676                         && GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR) > ROCKETJUMP_DAMAGE())
 677                 {
 678                         if(this.velocity.z < 0)
 679                         {
 680                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 681                                 {
 682                                         .entity weaponentity = weaponentities[slot];
 683
 684                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 685                                                 continue;
 686
 687                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 688                                         {
 689                                                 CS(this).movement_x = maxspeed;
 690
 691                                                 if(this.rocketjumptime)
 692                                                 {
 693                                                         if(time > this.rocketjumptime)
 694                                                         {
 695                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 696                                                                 this.rocketjumptime = 0;
 697                                                         }
 698                                                         return;
 699                                                 }
 700
 701                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 702                                                 this.v_angle_x = 90;
 703                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 704                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 705                                                 return;
 706                                         }
 707                                 }
 708                         }
 709                 }
 710                 else
 711                 {
 712                         // If there is no goal try to move forward
 713                         if(this.goalcurrent==NULL)
 714                                 CS(this).movement_x = maxspeed;
 715                 }
 716         }
 717
 718         // If we are under water with no goals, swim up
 719         if(this.waterlevel && !this.goalcurrent)
 720         {
 721                 dir = '0 0 0';
 722                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 723                         dir.z = 1;
 724                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 725                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 726                 else
 727                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 728                 makevectors(this.v_angle.y * '0 1 0');
 729                 vector v = dir * maxspeed;
 730                 CS(this).movement.x = v * v_forward;
 731                 CS(this).movement.y = v * v_right;
 732                 CS(this).movement.z = v * v_up;
 733         }
 734
 735         // if there is nowhere to go, exit
 736         if (this.goalcurrent == NULL)
 737                 return;
 738
 739
 740         bool locked_goal = false;
 741         if((this.goalentity && wasfreed(this.goalentity))
 742                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 743         {
 744                 navigation_clearroute(this);
 745                 navigation_goalrating_timeout_force(this);
 746                 return;
 747         }
 748         else if(this.goalentity.tag_entity)
 749         {
 750                 navigation_goalrating_timeout_expire(this, 2);
 751         }
 752         else if(this.goalentity.bot_pickup)
 753         {
 754                 if(this.goalentity.bot_pickup_respawning)
 755                 {
 756                         if(this.goalentity.solid) // item respawned
 757                                 this.goalentity.bot_pickup_respawning = false;
 758                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 759                         {
 760                                 if(checkpvs(this.origin, this.goalentity))
 761                                 {
 762                                         this.goalentity.bot_pickup_respawning = false;
 763                                         navigation_goalrating_timeout_expire(this, random());
 764                                 }
 765                                 locked_goal = true; // wait for item to respawn
 766                         }
 767                         else if(this.goalentity == this.goalcurrent)
 768                                 locked_goal = true; // wait for item to respawn
 769                 }
 770                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 771                 {
 772                         if(checkpvs(this.origin, this.goalentity))
 773                         {
 774                                 navigation_goalrating_timeout_expire(this, random());
 775                         }
 776                 }
 777         }
 778         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 779                 locked_goal = true;
 780
 781         if (navigation_shortenpath(this))
 782         {
 783                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 784                         && navigation_goalrating_timeout_can_be_anticipated(this))
 785                 {
 786                         navigation_goalrating_timeout_force(this);
 787                 }
 788         }
 789
 790         bool goalcurrent_can_be_removed = false;
 791         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 792         {
 793                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 794                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 795                 {
 796                         goalcurrent_can_be_removed = true;
 797                         // don't remove if not visible
 798                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 799                         {
 800                                 if (IS_DEAD(this.goalcurrent))
 801                                 {
 802                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 803                                         {
 804                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 805                                                 {
 806                                                         navigation_clearroute(this);
 807                                                         navigation_pushroute(this, it);
 808                                                         // loot can't be immediately rated since it isn't on ground yet
 809                                                         // it will be rated after a second when on ground, meanwhile head to it
 810                                                         navigation_goalrating_timeout_expire(this, 1);
 811                                                         return;
 812                                                 }
 813                                         });
 814                                 }
 815                                 if (!Item_IsLoot(this.goalcurrent))
 816                                 {
 817                                         navigation_goalrating_timeout_force(this);
 818                                         return;
 819                                 }
 820                         }
 821                 }
 822                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 823                 {
 824                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 825                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 826                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 827                         {
 828                                 navigation_goalrating_timeout_force(this);
 829                                 return;
 830                         }
 831                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 832                 }
 833         }
 834
 835         if(!locked_goal)
 836         {
 837                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 838                 // in this case path finding can start directly from a waypoint instead of
 839                 // looking for all the reachable waypoints up to a certain distance
 840                 if (navigation_poptouchedgoals(this))
 841                 {
 842                         if (this.goalcurrent)
 843                         {
 844                                 if (goalcurrent_can_be_removed)
 845                                 {
 846                                         // remove even if not visible
 847                                         navigation_goalrating_timeout_force(this);
 848                                         return;
 849                                 }
 850                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 851                                         navigation_goalrating_timeout_force(this);
 852                         }
 853                         else
 854                         {
 855                                 entity old_goal = this.goalcurrent_prev;
 856                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 857                                 {
 858                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 859                                         // item of the group by telling the bot to head directly to the farthest item.
 860                                         // Next time we let the bot select a goal as usual which can be another item
 861                                         // of this group (the closest one) and so on
 862                                         this.item_group = old_goal.item_group;
 863                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 864                                         if (new_goal)
 865                                                 navigation_pushroute(this, new_goal);
 866                                 }
 867                         }
 868                 }
 869         }
 870
 871         // if ran out of goals try to use an alternative goal or get a new strategy asap
 872         if(this.goalcurrent == NULL)
 873         {
 874                 navigation_goalrating_timeout_force(this);
 875                 return;
 876         }
 877
 878
 879         if(autocvar_bot_debug_goalstack)
 880                 debuggoalstack(this);
 881
 882         bool bunnyhop_forbidden = false;
 883         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 884         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 885         {
 886                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 887                 destorg = this.goalcurrent.origin;
 888         }
 889         else if (this.goalcurrent.wpisbox)
 890         {
 891                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 892                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 893                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 894                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 895                 {
 896                         bunnyhop_forbidden = true;
 897                         destorg = this.goalcurrent.origin;
 898                         if(destorg.z > this.origin.z)
 899                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 900                 }
 901         }
 902
 903         diff = destorg - this.origin;
 904
 905         if (time < this.bot_stop_moving_timeout
 906                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 907         {
 908                 // stop if the locked goal has been reached
 909                 destorg = this.origin;
 910                 diff = dir = '0 0 0';
 911         }
 912         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 913         {
 914                 if (vdist(diff, <, 80))
 915                 {
 916                         // stop if too close to target player (even if frozen)
 917                         destorg = this.origin;
 918                         diff = dir = '0 0 0';
 919                 }
 920                 else
 921                 {
 922                         // move destorg out of target players, otherwise bot will consider them
 923                         // an obstacle that needs to be jumped (especially if frozen)
 924                         dir = normalize(diff);
 925                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 926                         diff = destorg - this.origin;
 927                 }
 928         }
 929         else
 930                 dir = normalize(diff);
 931         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 932
 933         //if (this.bot_dodgevector_time < time)
 934         {
 935                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 936                 //this.bot_dodgevector_jumpbutton = 1;
 937                 evadeobstacle = '0 0 0';
 938                 evadelava = '0 0 0';
 939
 940                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 941                 makevectors(this.v_angle.y * '0 1 0');
 942                 if (this.waterlevel > WATERLEVEL_WETFEET)
 943                 {
 944                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 945                         {
 946                                 if(!this.goalcurrent)
 947                                         this.aistatus |= AI_STATUS_OUT_WATER;
 948                                 else if(destorg.z > this.origin.z)
 949                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 950                         }
 951                         else
 952                         {
 953                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 954                                         (this.aistatus & AI_STATUS_OUT_WATER))
 955                                 {
 956                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 957                                         dir = flatdir;
 958                                 }
 959                                 else
 960                                 {
 961                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 962                                         if (destorg.z > this.origin.z)
 963                                                 dir = flatdir;
 964                                 }
 965                         }
 966                 }
 967                 else
 968                 {
 969                         float s;
 970                         vector offset;
 971                         if(this.aistatus & AI_STATUS_OUT_WATER)
 972                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 973
 974                         // jump if going toward an obstacle that doesn't look like stairs we
 975                         // can walk up directly
 976                         vector deviation = '0 0 0';
 977                         float current_speed = vlen(vec2(this.velocity));
 978                         if (current_speed < maxspeed * 0.2)
 979                                 current_speed = maxspeed * 0.2;
 980                         else
 981                         {
 982                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 983                                 while (deviation.y < -180) deviation.y += 360;
 984                                 while (deviation.y > 180) deviation.y -= 360;
 985                         }
 986                         float turning = false;
 987                         vector flat_diff = vec2(diff);
 988                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 989                         vector actual_destorg = this.origin + offset;
 990                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
 991                         {
 992                                 if (vlen2(flat_diff) < vlen2(offset))
 993                                 {
 994                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 995                                         {
 996                                                 // oblique warpzones need a jump otherwise bots gets stuck
 997                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 998                                         }
 999                                         else
1000                                         {
1001                                                 actual_destorg.x = destorg.x;
1002                                                 actual_destorg.y = destorg.y;
1003                                         }
1004                                 }
1005                         }
1006                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
1007                         {
1008                                 actual_destorg.x = destorg.x;
1009                                 actual_destorg.y = destorg.y;
1010                         }
1011                         else if (vlen2(flat_diff) < vlen2(offset))
1012                         {
1013                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1014                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
1015                                 float dist = vlen(vec2(this.origin + offset - destorg));
1016                                 // if current and next goal are close to each other make sure
1017                                 // actual_destorg isn't set beyond next_goal_org
1018                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
1019                                         actual_destorg = next_goal_org;
1020                                 else
1021                                         actual_destorg = vec2(destorg) + dist * next_dir;
1022                                 actual_destorg.z = this.origin.z;
1023                                 turning = true;
1024                         }
1025
1026                         LABEL(jump_check);
1027                         dir = flatdir = normalize(actual_destorg - this.origin);
1028
1029                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
1030                         {
1031                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1032                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1033                                 {
1034                                         s = trace_fraction;
1035                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1036                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1037                                         {
1038                                                 // found an obstacle
1039                                                 if (turning && fabs(deviation.y) > 5)
1040                                                 {
1041                                                         // check if the obstacle is still there without turning
1042                                                         actual_destorg = destorg;
1043                                                         turning = false;
1044                                                         this.bot_tracewalk_time = time + 0.25;
1045                                                         goto jump_check;
1046                                                 }
1047                                                 s = trace_fraction;
1048                                                 // don't artificially reduce max jump height in real-time
1049                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1050                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1051                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1052                                                 if (trace_fraction > s)
1053                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1054                                                 else
1055                                                 {
1056                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1057                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1058                                                         if (trace_fraction > s)
1059                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1060                                                 }
1061                                         }
1062                                 }
1063                         }
1064
1065                         // if bot for some reason doesn't get close to the current goal find another one
1066                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1067                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1068                         if(havocbot_checkgoaldistance(this, destorg))
1069                         {
1070                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1071                                 {
1072                                         navigation_clearroute(this);
1073                                         navigation_goalrating_timeout_force(this);
1074                                         return;
1075                                 }
1076
1077                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1078                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1079                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1080                                 {
1081                                         navigation_clearroute(this);
1082                                         navigation_goalrating_timeout_force(this);
1083                                         return;
1084                                 }
1085
1086                                 // give bot only another chance to prevent bot getting stuck
1087                                 // in case it thinks it can walk but actually can't
1088                                 this.goalcurrent_distance_z = FLOAT_MAX;
1089                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1090                                 this.goalcurrent_distance_time = -time; // mark second try
1091                         }
1092
1093                         // Check for water/slime/lava and dangerous edges
1094                         // (only when the bot is on the ground or jumping intentionally)
1095
1096                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1097                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1098                         {
1099                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1100                         }
1101
1102                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
1103                         vector dst_ahead = this.origin + this.view_ofs + offset;
1104                         vector dst_down = dst_ahead - '0 0 3000';
1105                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1106
1107                         bool unreachable = false;
1108                         s = CONTENT_SOLID;
1109                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1110                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1111                         {
1112                                 // Look downwards
1113                                 traceline(dst_ahead , dst_down, true, NULL);
1114                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1115                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
1116                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1117                                 {
1118                                         s = pointcontents(trace_endpos + '0 0 1');
1119                                         if (s != CONTENT_SOLID)
1120                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1121                                                 evadelava = normalize(this.velocity) * -1;
1122                                         else if (s == CONTENT_SKY)
1123                                                 evadeobstacle = normalize(this.velocity) * -1;
1124                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1125                                         {
1126                                                 // the traceline check isn't enough but is good as optimization,
1127                                                 // when not true (most of the time) this tracebox call is avoided
1128                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1129                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1130                                                 {
1131                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1132                                                         {
1133                                                                 // the goal is probably on an upper platform, assume bot can't get there
1134                                                                 unreachable = true;
1135                                                         }
1136                                                         else
1137                                                                 evadelava = normalize(this.velocity) * -1;
1138                                                 }
1139                                         }
1140                                 }
1141                         }
1142
1143                         dir = flatdir;
1144                         evadeobstacle.z = 0;
1145                         evadelava.z = 0;
1146                         makevectors(this.v_angle.y * '0 1 0');
1147
1148                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1149                         {
1150                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1151                                 if(IS_PLAYER(this.goalcurrent))
1152                                         unreachable = true;
1153                         }
1154
1155                         // slow down if bot is in the air and goal is under it
1156                         if (!this.goalcurrent.wphardwired
1157                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1158                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1159                         {
1160                                 // tracebox wouldn't work when bot is still on the ledge
1161                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1162                                 if (this.origin.z - trace_endpos.z > 120)
1163                                         evadeobstacle = normalize(this.velocity) * -1;
1164                         }
1165
1166                         if(unreachable)
1167                         {
1168                                 navigation_clearroute(this);
1169                                 navigation_goalrating_timeout_force(this);
1170                                 this.ignoregoal = this.goalcurrent;
1171                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1172                         }
1173                 }
1174
1175                 dodge = havocbot_dodge(this);
1176                 if (dodge)
1177                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1178                 dodge += evadeobstacle + evadelava;
1179                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1180                 if (this.enemy)
1181                 {
1182                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1183                         if (IS_PLAYER(trace_ent))
1184                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1185                 }
1186         //      this.bot_dodgevector = dir;
1187         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1188         }
1189
1190         float ladder_zdir = 0;
1191         if(time < this.ladder_time)
1192         {
1193                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1194                 {
1195                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1196                                 ladder_zdir = 1;
1197                 }
1198                 else
1199                 {
1200                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1201                                 ladder_zdir = -1;
1202                 }
1203                 if (ladder_zdir)
1204                 {
1205                         if (vdist(vec2(diff), <, 40))
1206                                 dir.z = ladder_zdir * 4;
1207                         else
1208                                 dir.z = ladder_zdir * 2;
1209                         dir = normalize(dir);
1210                 }
1211         }
1212
1213         if (this.goalcurrent.wpisbox
1214                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1215         {
1216                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1217                 // head to teleport origin
1218                 dir = (this.goalcurrent.origin - this.origin);
1219                 dir.z = 0;
1220                 dir = normalize(dir);
1221         }
1222
1223         // already executed when bot targets an enemy
1224         if (!this.bot_aimdir_executed)
1225         {
1226                 if (time < this.bot_stop_moving_timeout)
1227                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1228                 else
1229                         bot_aimdir(this, dir, 0);
1230         }
1231
1232         if (!ladder_zdir)
1233         {
1234                 dir *= dodge_enemy_factor;
1235                 dir = normalize(dir + dodge);
1236         }
1237
1238         makevectors(this.v_angle);
1239         //dir = this.bot_dodgevector;
1240         //if (this.bot_dodgevector_jumpbutton)
1241         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1242         CS(this).movement_x = dir * v_forward * maxspeed;
1243         CS(this).movement_y = dir * v_right * maxspeed;
1244         CS(this).movement_z = dir * v_up * maxspeed;
1245
1246         // Emulate keyboard interface
1247         if (skill < 10)
1248                 havocbot_keyboard_movement(this, destorg);
1249
1250         // Bunnyhop!
1251         //if(this.aistatus & AI_STATUS_ROAMING)
1252         if(!bunnyhop_forbidden && this.goalcurrent)
1253         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1254                 havocbot_bunnyhop(this, dir);
1255
1256         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1257         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1258         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1259 }
1260
1261 entity havocbot_gettarget(entity this, bool secondary)
1262 {
1263         entity best = NULL;
1264         vector eye = CENTER_OR_VIEWOFS(this);
1265         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1266         {
1267                 vector v = CENTER_OR_VIEWOFS(it);
1268                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1269                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1270                 if(bot_shouldattack(this, it))
1271                 {
1272                         traceline(eye, v, true, this);
1273                         if (trace_ent == it || trace_fraction >= 1)
1274                                 best = it;
1275                 }
1276         });
1277
1278         return best;
1279 }
1280
1281 void havocbot_chooseenemy(entity this)
1282 {
1283         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1284         {
1285                 this.enemy = NULL;
1286                 return;
1287         }
1288         if (this.enemy)
1289         {
1290                 if (!bot_shouldattack(this, this.enemy))
1291                 {
1292                         // enemy died or something, find a new target
1293                         this.enemy = NULL;
1294                         this.havocbot_chooseenemy_finished = time;
1295                 }
1296                 else if (this.havocbot_stickenemy)
1297                 {
1298                         // tracking last chosen enemy
1299                         // if enemy is visible
1300                         // and not really really far away
1301                         // and we're not severely injured
1302                         // then keep tracking for a half second into the future
1303                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1304                         if (trace_ent == this.enemy || trace_fraction == 1)
1305                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1306                         if (GetResourceAmount(this, RESOURCE_HEALTH) > 30)
1307                         {
1308                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1309                                 this.havocbot_chooseenemy_finished = time + 0.5;
1310                                 return;
1311                         }
1312                         // enemy isn't visible, or is far away, or we're injured severely
1313                         // so stop preferring this enemy
1314                         // (it will still take a half second until a new one is chosen)
1315                         this.havocbot_stickenemy = 0;
1316                 }
1317         }
1318         if (time < this.havocbot_chooseenemy_finished)
1319                 return;
1320         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1321         vector eye = this.origin + this.view_ofs;
1322         entity best = NULL;
1323         float bestrating = 100000000;
1324
1325         // Backup hit flags
1326         int hf = this.dphitcontentsmask;
1327
1328         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1329
1330         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1331
1332         bool scan_transparent = false;
1333         bool scan_secondary_targets = false;
1334         bool have_secondary_targets = false;
1335         while(true)
1336         {
1337                 scan_secondary_targets = false;
1338 LABEL(scan_targets)
1339                 IL_EACH(g_bot_targets, it.bot_attack,
1340                 {
1341                         if(!scan_secondary_targets)
1342                         {
1343                                 if(it.classname == "misc_breakablemodel")
1344                                 {
1345                                         have_secondary_targets = true;
1346                                         continue;
1347                                 }
1348                         }
1349                         else if(it.classname != "misc_breakablemodel")
1350                                 continue;
1351
1352                         vector v = (it.absmin + it.absmax) * 0.5;
1353                         float rating = vlen2(v - eye);
1354                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1355                         if (bestrating > rating)
1356                         if (bot_shouldattack(this, it))
1357                         {
1358                                 traceline(eye, v, true, this);
1359                                 if (trace_ent == it || trace_fraction >= 1)
1360                                 {
1361                                         best = it;
1362                                         bestrating = rating;
1363                                 }
1364                         }
1365                 });
1366
1367                 if(!best && have_secondary_targets && !scan_secondary_targets)
1368                 {
1369                         scan_secondary_targets = true;
1370                         // restart the loop
1371                         bestrating = 100000000;
1372                         goto scan_targets;
1373                 }
1374
1375                 // I want to do a second scan if no enemy was found or I don't have weapons
1376                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1377                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1378                         break;
1379                 if(scan_transparent)
1380                         break;
1381
1382                 // Set flags to see through transparent objects
1383                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1384
1385                 scan_transparent = true;
1386         }
1387
1388         // Restore hit flags
1389         this.dphitcontentsmask = hf;
1390
1391         this.enemy = best;
1392         this.havocbot_stickenemy = true;
1393         if(best && best.classname == "misc_breakablemodel")
1394                 this.havocbot_stickenemy = false;
1395 }
1396
1397 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1398 {
1399         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1400         // so skip this for them, or they'll never get to reload their weapons at all.
1401         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1402         if(skill < 5)
1403                 return false;
1404
1405         // if this weapon is scheduled for reloading, don't switch to it during combat
1406         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1407         {
1408                 FOREACH(Weapons, it != WEP_Null, {
1409                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1410                                 return true; // other weapon available
1411                 });
1412         }
1413
1414         return false;
1415 }
1416
1417 void havocbot_chooseweapon(entity this, .entity weaponentity)
1418 {
1419         int i;
1420
1421         // ;)
1422         if(g_weaponarena_weapons == WEPSET(TUBA))
1423         {
1424                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1425                 return;
1426         }
1427
1428         // TODO: clean this up by moving it to weapon code
1429         if(this.enemy==NULL)
1430         {
1431                 // If no weapon was chosen get the first available weapon
1432                 if(this.(weaponentity).m_weapon==WEP_Null)
1433                 FOREACH(Weapons, it != WEP_Null, {
1434                         if(client_hasweapon(this, it, weaponentity, true, false))
1435                         {
1436                                 this.(weaponentity).m_switchweapon = it;
1437                                 return;
1438                         }
1439                 });
1440                 return;
1441         }
1442
1443         // Do not change weapon during the next second after a combo
1444         float f = time - this.lastcombotime;
1445         if(f < 1)
1446                 return;
1447
1448         float w;
1449         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1450
1451         // Should it do a weapon combo?
1452         float af, ct, combo_time, combo;
1453
1454         af = ATTACK_FINISHED(this, weaponentity);
1455         ct = autocvar_bot_ai_weapon_combo_threshold;
1456
1457         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1458         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1459         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1460
1461         combo = false;
1462
1463         if(autocvar_bot_ai_weapon_combo)
1464         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1465         if(af > combo_time)
1466         {
1467                 combo = true;
1468                 this.lastcombotime = time;
1469         }
1470
1471         distance *= (2 ** this.bot_rangepreference);
1472
1473         // Custom weapon list based on distance to the enemy
1474         if(bot_custom_weapon){
1475
1476                 // Choose weapons for far distance
1477                 if ( distance > bot_distance_far ) {
1478                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1479                                 w = bot_weapons_far[i];
1480                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1481                                 {
1482                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1483                                                 continue;
1484                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1485                                         return;
1486                                 }
1487                         }
1488                 }
1489
1490                 // Choose weapons for mid distance
1491                 if ( distance > bot_distance_close) {
1492                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1493                                 w = bot_weapons_mid[i];
1494                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1495                                 {
1496                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1497                                                 continue;
1498                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1499                                         return;
1500                                 }
1501                         }
1502                 }
1503
1504                 // Choose weapons for close distance
1505                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1506                         w = bot_weapons_close[i];
1507                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1508                         {
1509                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1510                                         continue;
1511                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1512                                 return;
1513                         }
1514                 }
1515         }
1516 }
1517
1518 void havocbot_aim(entity this)
1519 {
1520         if (time < this.nextaim)
1521                 return;
1522         this.nextaim = time + 0.1;
1523         vector myvel = this.velocity;
1524         if (!this.waterlevel)
1525                 myvel.z = 0;
1526         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1527         else if (this.enemy)
1528         {
1529                 vector enemyvel = this.enemy.velocity;
1530                 if (!this.enemy.waterlevel)
1531                         enemyvel.z = 0;
1532                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1533         }
1534         else
1535                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1536 }
1537
1538 bool havocbot_moveto_refresh_route(entity this)
1539 {
1540         // Refresh path to goal if necessary
1541         entity wp;
1542         wp = this.havocbot_personal_waypoint;
1543         navigation_goalrating_start(this);
1544         navigation_routerating(this, wp, 10000, 10000);
1545         navigation_goalrating_end(this);
1546         return (this.goalentity != NULL);
1547 }
1548
1549 float havocbot_moveto(entity this, vector pos)
1550 {
1551         entity wp;
1552
1553         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1554         {
1555                 // Step 4: Move to waypoint
1556                 if(this.havocbot_personal_waypoint==NULL)
1557                 {
1558                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1559                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1560                         return CMD_STATUS_ERROR;
1561                 }
1562
1563                 if (!bot_strategytoken_taken)
1564                 if(this.havocbot_personal_waypoint_searchtime<time)
1565                 {
1566                         bot_strategytoken_taken = true;
1567                         if(havocbot_moveto_refresh_route(this))
1568                         {
1569                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1570                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1571                                 this.havocbot_personal_waypoint_failcounter = 0;
1572                         }
1573                         else
1574                         {
1575                                 this.havocbot_personal_waypoint_failcounter += 1;
1576                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1577                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1578                                 {
1579                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1580                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1581                                         delete(this.havocbot_personal_waypoint);
1582                                         return CMD_STATUS_ERROR;
1583                                 }
1584                                 else
1585                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1586                         }
1587                 }
1588
1589                 if(autocvar_bot_debug_goalstack)
1590                         debuggoalstack(this);
1591
1592
1593                 // Go!
1594                 havocbot_movetogoal(this);
1595
1596                 if (!this.bot_aimdir_executed && this.goalcurrent)
1597                 {
1598                         // Heading
1599                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1600                         dir -= this.origin + this.view_ofs;
1601                         dir.z = 0;
1602                         bot_aimdir(this, dir, 0);
1603                 }
1604
1605                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1606                 {
1607                         // Step 5: Waypoint reached
1608                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1609                         waypoint_remove(this.havocbot_personal_waypoint);
1610                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1611                         return CMD_STATUS_FINISHED;
1612                 }
1613
1614                 return CMD_STATUS_EXECUTING;
1615         }
1616
1617         // Step 2: Linking waypoint
1618         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1619         {
1620                 // Wait until it is linked
1621                 if(!this.havocbot_personal_waypoint.wplinked)
1622                 {
1623                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1624                         return CMD_STATUS_EXECUTING;
1625                 }
1626
1627                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1628                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1629                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1630
1631                 // Step 3: Route to waypoint
1632                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1633
1634                 return CMD_STATUS_EXECUTING;
1635         }
1636
1637         // Step 1: Spawning waypoint
1638         wp = waypoint_spawnpersonal(this, pos);
1639         if(wp==NULL)
1640         {
1641                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1642                 return CMD_STATUS_ERROR;
1643         }
1644
1645         this.havocbot_personal_waypoint = wp;
1646         this.havocbot_personal_waypoint_failcounter = 0;
1647         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1648
1649         // if pos is inside a teleport, then let's mark it as teleport waypoint
1650         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1651         {
1652                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1653                 this.lastteleporttime = 0;
1654         });
1655
1656 /*
1657         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1658                 print("routing to a teleporter\n");
1659         else
1660                 print("routing to a non-teleporter\n");
1661 */
1662
1663         return CMD_STATUS_EXECUTING;
1664 }
1665
1666 float havocbot_resetgoal(entity this)
1667 {
1668         navigation_clearroute(this);
1669         return CMD_STATUS_FINISHED;
1670 }
1671
1672 void havocbot_setupbot(entity this)
1673 {
1674         this.bot_ai = havocbot_ai;
1675         this.cmd_moveto = havocbot_moveto;
1676         this.cmd_resetgoal = havocbot_resetgoal;
1677
1678         // NOTE: bot is not player yet
1679         havocbot_chooserole(this);
1680 }
1681
1682 vector havocbot_dodge(entity this)
1683 {
1684         // LordHavoc: disabled because this is too expensive
1685         return '0 0 0';
1686 #if 0
1687         entity head;
1688         vector dodge, v, n;
1689         float danger, bestdanger, vl, d;
1690         dodge = '0 0 0';
1691         bestdanger = -20;
1692         // check for dangerous objects near bot or approaching bot
1693         head = findchainfloat(bot_dodge, true);
1694         while(head)
1695         {
1696                 if (head.owner != this)
1697                 {
1698                         vl = vlen(head.velocity);
1699                         if (vl > autocvar_sv_maxspeed * 0.3)
1700                         {
1701                                 n = normalize(head.velocity);
1702                                 v = this.origin - head.origin;
1703                                 d = v * n;
1704                                 if (d > (0 - head.bot_dodgerating))
1705                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1706                                 {
1707                                         // calculate direction and distance from the flight path, by removing the forward axis
1708                                         v = v - (n * (v * n));
1709                                         danger = head.bot_dodgerating - vlen(v);
1710                                         if (bestdanger < danger)
1711                                         {
1712                                                 bestdanger = danger;
1713                                                 // dodge to the side of the object
1714                                                 dodge = normalize(v);
1715                                         }
1716                                 }
1717                         }
1718                         else
1719                         {
1720                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1721                                 if (bestdanger < danger)
1722                                 {
1723                                         bestdanger = danger;
1724                                         dodge = normalize(this.origin - head.origin);
1725                                 }
1726                         }
1727                 }
1728                 head = head.chain;
1729         }
1730         return dodge;
1731 #endif
1732 }