qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/mapobjects/func/ladder.qh>
  22 #include <common/mapobjects/teleporters.qh>
  23 #include <common/mapobjects/trigger/jumppads.qh>
  24
  25 #include <lib/warpzone/common.qh>
  26
  27 .float speed;
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if(IS_DEAD(this) || STAT(FROZEN, this))
  93         {
  94                 if (this.goalcurrent)
  95                         navigation_clearroute(this);
  96                 return;
  97         }
  98
  99         havocbot_chooseenemy(this);
 100
 101         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 102         {
 103                 .entity weaponentity = weaponentities[slot];
 104                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 105                 if(this.(weaponentity).bot_chooseweapontime < time)
 106                 {
 107                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 108                         havocbot_chooseweapon(this, weaponentity);
 109                 }
 110         }
 111         havocbot_aim(this);
 112         lag_update(this);
 113
 114         if (this.bot_aimtarg)
 115         {
 116                 this.aistatus |= AI_STATUS_ATTACKING;
 117                 this.aistatus &= ~AI_STATUS_ROAMING;
 118
 119                 if(STAT(WEAPONS, this))
 120                 {
 121                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 122                         {
 123                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 124                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 125                         }
 126                         else
 127                         {
 128                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 129                                 {
 130                                         .entity weaponentity = weaponentities[slot];
 131                                         Weapon w = this.(weaponentity).m_weapon;
 132                                         if(w == WEP_Null && slot != 0)
 133                                                 continue;
 134                                         w.wr_aim(w, this, weaponentity);
 135                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 136                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 137                                 }
 138                         }
 139                 }
 140                 else
 141                 {
 142                         if(IS_PLAYER(this.bot_aimtarg))
 143                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 144                 }
 145         }
 146         else if (this.goalcurrent)
 147         {
 148                 this.aistatus |= AI_STATUS_ROAMING;
 149                 this.aistatus &= ~AI_STATUS_ATTACKING;
 150         }
 151
 152         havocbot_movetogoal(this);
 153         if (!this.bot_aimdir_executed && this.goalcurrent)
 154         {
 155                 // Heading
 156                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 157                 dir -= this.origin + this.view_ofs;
 158                 dir.z = 0;
 159                 bot_aimdir(this, dir, 0);
 160         }
 161
 162         // if the bot is not attacking, consider reloading weapons
 163         if (!(this.aistatus & AI_STATUS_ATTACKING))
 164         {
 165                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 166                 {
 167                         .entity weaponentity = weaponentities[slot];
 168
 169                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 170                                 continue;
 171
 172                         // we are currently holding a weapon that's not fully loaded, reload it
 173                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 174                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 175                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 176
 177                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 178                         // the code above executes next frame, starting the reloading then
 179                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 180                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 181                         {
 182                                 FOREACH(Weapons, it != WEP_Null, {
 183                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 184                                         {
 185                                                 this.(weaponentity).m_switchweapon = it;
 186                                                 break;
 187                                         }
 188                                 });
 189                         }
 190                 }
 191         }
 192 }
 193
 194 void havocbot_keyboard_movement(entity this, vector destorg)
 195 {
 196         vector keyboard;
 197
 198         if (time > this.havocbot_keyboardtime)
 199         {
 200                 float sk = skill + this.bot_moveskill;
 201                 this.havocbot_keyboardtime =
 202                         max(
 203                                 this.havocbot_keyboardtime
 204                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 205                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 206                         , time);
 207                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 208
 209                 float trigger = autocvar_bot_ai_keyboard_threshold;
 210
 211                 // categorize forward movement
 212                 // at skill < 1.5 only forward
 213                 // at skill < 2.5 only individual directions
 214                 // at skill < 4.5 only individual directions, and forward diagonals
 215                 // at skill >= 4.5, all cases allowed
 216                 if (keyboard.x > trigger)
 217                 {
 218                         keyboard.x = 1;
 219                         if (sk < 2.5)
 220                                 keyboard.y = 0;
 221                 }
 222                 else if (keyboard.x < -trigger && sk > 1.5)
 223                 {
 224                         keyboard.x = -1;
 225                         if (sk < 4.5)
 226                                 keyboard.y = 0;
 227                 }
 228                 else
 229                 {
 230                         keyboard.x = 0;
 231                         if (sk < 1.5)
 232                                 keyboard.y = 0;
 233                 }
 234                 if (sk < 4.5)
 235                         keyboard.z = 0;
 236
 237                 if (keyboard.y > trigger)
 238                         keyboard.y = 1;
 239                 else if (keyboard.y < -trigger)
 240                         keyboard.y = -1;
 241                 else
 242                         keyboard.y = 0;
 243
 244                 if (keyboard.z > trigger)
 245                         keyboard.z = 1;
 246                 else if (keyboard.z < -trigger)
 247                         keyboard.z = -1;
 248                 else
 249                         keyboard.z = 0;
 250
 251                 // make sure bots don't get stuck if havocbot_keyboardtime is very high
 252                 if (keyboard == '0 0 0')
 253                         this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 254
 255                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 256                 if (this.havocbot_ducktime > time)
 257                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 258
 259                 keyboard = this.havocbot_keyboard;
 260                 float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 261                 //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 262                 CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 263         }
 264 }
 265
 266 void havocbot_bunnyhop(entity this, vector dir)
 267 {
 268         float bunnyhopdistance;
 269         vector deviation;
 270         float maxspeed;
 271
 272         // Don't jump when attacking
 273         if(this.aistatus & AI_STATUS_ATTACKING)
 274                 return;
 275
 276         if(IS_PLAYER(this.goalcurrent))
 277                 return;
 278
 279         maxspeed = autocvar_sv_maxspeed;
 280
 281         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 282                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 283         {
 284                 this.aistatus &= ~AI_STATUS_RUNNING;
 285                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 286                 this.bot_canruntogoal = 0;
 287                 this.bot_timelastseengoal = 0;
 288                 return;
 289         }
 290
 291         if(this.waterlevel > WATERLEVEL_WETFEET)
 292         {
 293                 this.aistatus &= ~AI_STATUS_RUNNING;
 294                 return;
 295         }
 296
 297         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 298         {
 299                 this.bot_canruntogoal = 0;
 300                 this.bot_timelastseengoal = 0;
 301         }
 302
 303         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 304         bunnyhopdistance = vlen(this.origin - gco);
 305
 306         // Run only to visible goals
 307         if(IS_ONGROUND(this))
 308         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 309         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 310         {
 311                         this.bot_lastseengoal = this.goalcurrent;
 312
 313                         // seen it before
 314                         if(this.bot_timelastseengoal)
 315                         {
 316                                 // for a period of time
 317                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 318                                 {
 319                                         float checkdistance;
 320                                         checkdistance = true;
 321
 322                                         // don't run if it is too close
 323                                         if(this.bot_canruntogoal==0)
 324                                         {
 325                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 326                                                         this.bot_canruntogoal = 1;
 327                                                 else
 328                                                         this.bot_canruntogoal = -1;
 329                                         }
 330
 331                                         if(this.bot_canruntogoal != 1)
 332                                                 return;
 333
 334                                         if(this.aistatus & AI_STATUS_ROAMING)
 335                                         if(this.goalcurrent.classname=="waypoint")
 336                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 337                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 338                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 339                                         {
 340                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 341                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 342                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 343                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 344
 345                                                 if(fabs(deviation.y) < 20)
 346                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 347                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 348                                                 {
 349                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 350                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 351                                                         {
 352                                                                 checkdistance = false;
 353                                                         }
 354                                                 }
 355                                         }
 356
 357                                         if(checkdistance)
 358                                         {
 359                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 360                                                 // increase stop distance in case the goal is on a slope or a lower platform
 361                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 362                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 363                                         }
 364                                         else
 365                                         {
 366                                                 this.aistatus |= AI_STATUS_RUNNING;
 367                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 368                                         }
 369                                 }
 370                         }
 371                         else
 372                         {
 373                                 this.bot_timelastseengoal = time;
 374                         }
 375         }
 376         else
 377         {
 378                 this.bot_timelastseengoal = 0;
 379         }
 380
 381 #if 0
 382         // Release jump button
 383         if(!cvar("sv_pogostick"))
 384         if((IS_ONGROUND(this)) == 0)
 385         {
 386                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 387                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 388
 389                 // Strafe
 390                 if(this.aistatus & AI_STATUS_RUNNING)
 391                 if(vlen(this.velocity)>maxspeed)
 392                 {
 393                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 394                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 395                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 396
 397                         if(fabs(deviation.y)>10)
 398                                 CS(this).movement_x = 0;
 399
 400                         if(deviation.y>10)
 401                                 CS(this).movement_y = maxspeed * -1;
 402                         else if(deviation.y<10)
 403                                 CS(this).movement_y = maxspeed;
 404
 405                 }
 406         }
 407 #endif
 408 }
 409
 410 // return true when bot isn't getting closer to the current goal
 411 bool havocbot_checkgoaldistance(entity this, vector gco)
 412 {
 413         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 414         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 415         float distance_time = this.goalcurrent_distance_time;
 416         if(distance_time < 0)
 417                 distance_time = -distance_time;
 418         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 419         {
 420                 if(!distance_time)
 421                         this.goalcurrent_distance_time = time;
 422                 else if (time - distance_time > 0.5)
 423                         return true;
 424         }
 425         else
 426         {
 427                 // reduce it a little bit so it works even with very small approaches to the goal
 428                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 429                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 430                 this.goalcurrent_distance_time = 0;
 431         }
 432         return false;
 433 }
 434
 435 entity havocbot_select_an_item_of_group(entity this, int gr)
 436 {
 437         entity selected = NULL;
 438         float selected_dist2 = 0;
 439         // select farthest item of this group from bot's position
 440         IL_EACH(g_items, it.item_group == gr && it.solid,
 441         {
 442                 float dist2 = vlen2(this.origin - it.origin);
 443                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 444                 {
 445                         selected = it;
 446                         selected_dist2 = vlen2(this.origin - selected.origin);
 447                 }
 448         });
 449
 450         if (!selected)
 451                 return NULL;
 452
 453         set_tracewalk_dest(selected, this.origin, false);
 454         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 455                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 456         {
 457                 return NULL;
 458         }
 459
 460         return selected;
 461 }
 462
 463 void havocbot_movetogoal(entity this)
 464 {
 465         vector diff;
 466         vector dir;
 467         vector flatdir;
 468         vector evadeobstacle;
 469         vector evadelava;
 470         float dodge_enemy_factor = 1;
 471         float maxspeed;
 472         //float dist;
 473         vector dodge;
 474         //if (this.goalentity)
 475         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 476         CS(this).movement = '0 0 0';
 477         maxspeed = autocvar_sv_maxspeed;
 478
 479         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 480         // Jetpack navigation
 481         if(this.navigation_jetpack_goal)
 482         if(this.goalcurrent==this.navigation_jetpack_goal)
 483         if(GetResource(this, RES_FUEL))
 484         {
 485                 if(autocvar_bot_debug_goalstack)
 486                 {
 487                         debuggoalstack(this);
 488                         te_wizspike(this.navigation_jetpack_point);
 489                 }
 490
 491                 // Take off
 492                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 493                 {
 494                         // Brake almost completely so it can get a good direction
 495                         if(vdist(this.velocity, >, 10))
 496                                 return;
 497                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 498                 }
 499
 500                 makevectors(this.v_angle.y * '0 1 0');
 501                 dir = normalize(this.navigation_jetpack_point - this.origin);
 502
 503                 // Landing
 504                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 505                 {
 506                         // Calculate brake distance in xy
 507                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 508                         float vel2 = vlen2(vec2(this.velocity));
 509                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 510                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 511                         if(d < db || d < 500)
 512                         {
 513                                 // Brake
 514                                 if (vel2 > (maxspeed * 0.3) ** 2)
 515                                 {
 516                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 517                                         return;
 518                                 }
 519                                 // Switch to normal mode
 520                                 this.navigation_jetpack_goal = NULL;
 521                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 522                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 523                                 return;
 524                         }
 525                 }
 526                 else if(checkpvs(this.origin,this.goalcurrent))
 527                 {
 528                         // If I can see the goal switch to landing code
 529                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 530                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 531                         return;
 532                 }
 533
 534                 // Flying
 535                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 536                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 537                 {
 538                         CS(this).movement_x = dir * v_forward * maxspeed;
 539                         CS(this).movement_y = dir * v_right * maxspeed;
 540                 }
 541                 return;
 542         }
 543
 544         // Handling of jump pads
 545         if(this.jumppadcount)
 546         {
 547                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 548                 {
 549                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 550                         if(navigation_poptouchedgoals(this))
 551                                 return;
 552                 }
 553                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 554                 {
 555                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 556                         // but with some randomness so it can try out different paths
 557                         if(!this.goalcurrent)
 558                         {
 559                                 entity newgoal = NULL;
 560                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 561                                 {
 562                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 563                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 564                                                 continue;
 565
 566                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 567
 568                                         if(trace_fraction < 1)
 569                                                 continue;
 570
 571                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 572                                                 newgoal = it;
 573                                 });
 574
 575                                 if(newgoal)
 576                                 {
 577                                         this.ignoregoal = this.goalcurrent;
 578                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 579                                         navigation_clearroute(this);
 580                                         navigation_routetogoal(this, newgoal, this.origin);
 581                                         if(autocvar_bot_debug_goalstack)
 582                                                 debuggoalstack(this);
 583                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 584                                 }
 585                         }
 586                         else //if (this.goalcurrent)
 587                         {
 588                                 if (this.goalcurrent.bot_pickup)
 589                                 {
 590                                         entity jumppad_wp = this.goalcurrent_prev;
 591                                         navigation_poptouchedgoals(this);
 592                                         if(!this.goalcurrent && jumppad_wp.wp00)
 593                                         {
 594                                                 // head to the jumppad destination once bot reaches the goal item
 595                                                 navigation_pushroute(this, jumppad_wp.wp00);
 596                                         }
 597                                 }
 598                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 599                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 600                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 601                                 else if(havocbot_checkgoaldistance(this, gco))
 602                                 {
 603                                         navigation_clearroute(this);
 604                                         navigation_goalrating_timeout_force(this);
 605                                 }
 606                                 else
 607                                         return;
 608                         }
 609                 }
 610                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 611                 {
 612                         if(this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 613                         {
 614                                 vector velxy = this.velocity; velxy_z = 0;
 615                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 616                                 {
 617                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 618                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 619                                 }
 620                                 return;
 621                         }
 622
 623                         // Don't chase players while using a jump pad
 624                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 625                                 return;
 626                 }
 627         }
 628         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 629                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 630
 631         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 632         if (skill > 6 && !(IS_ONGROUND(this)))
 633         {
 634                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 635                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 636                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 637
 638                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 639                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 640                 if(this.items & IT_JETPACK)
 641                 {
 642                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 643                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 644                         {
 645                                 if(this.velocity.z<0)
 646                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 647                         }
 648                         else
 649                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 650
 651                         // If there is no goal try to move forward
 652
 653                         if(this.goalcurrent==NULL)
 654                                 dir = v_forward;
 655                         else
 656                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 657
 658                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 659                         float xyspeed = xyvelocity * dir;
 660
 661                         if(xyspeed < (maxspeed / 2))
 662                         {
 663                                 makevectors(this.v_angle.y * '0 1 0');
 664                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 665                                 if(trace_fraction==1)
 666                                 {
 667                                         CS(this).movement_x = dir * v_forward * maxspeed;
 668                                         CS(this).movement_y = dir * v_right * maxspeed;
 669                                         if (skill < 10)
 670                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 671                                 }
 672                         }
 673
 674                         this.havocbot_blockhead = true;
 675
 676                         return;
 677                 }
 678                 else if(!this.jumppadcount && !this.goalcurrent.wphardwired
 679                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 680                 {
 681                         if(this.velocity.z < 0)
 682                         {
 683                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 684                                 {
 685                                         .entity weaponentity = weaponentities[slot];
 686
 687                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 688                                                 continue;
 689
 690                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 691                                         {
 692                                                 CS(this).movement_x = maxspeed;
 693
 694                                                 if(this.rocketjumptime)
 695                                                 {
 696                                                         if(time > this.rocketjumptime)
 697                                                         {
 698                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 699                                                                 this.rocketjumptime = 0;
 700                                                         }
 701                                                         return;
 702                                                 }
 703
 704                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 705                                                 this.v_angle_x = 90;
 706                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 707                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 708                                                 return;
 709                                         }
 710                                 }
 711                         }
 712                 }
 713                 else
 714                 {
 715                         // If there is no goal try to move forward
 716                         if(this.goalcurrent==NULL)
 717                                 CS(this).movement_x = maxspeed;
 718                 }
 719         }
 720
 721         // If we are under water with no goals, swim up
 722         if(this.waterlevel && !this.goalcurrent)
 723         {
 724                 dir = '0 0 0';
 725                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 726                         dir.z = 1;
 727                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 728                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 729                 else
 730                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 731                 makevectors(this.v_angle.y * '0 1 0');
 732                 vector v = dir * maxspeed;
 733                 CS(this).movement.x = v * v_forward;
 734                 CS(this).movement.y = v * v_right;
 735                 CS(this).movement.z = v * v_up;
 736         }
 737
 738         // if there is nowhere to go, exit
 739         if (this.goalcurrent == NULL)
 740                 return;
 741
 742
 743         bool locked_goal = false;
 744         if((this.goalentity && wasfreed(this.goalentity))
 745                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 746         {
 747                 navigation_clearroute(this);
 748                 navigation_goalrating_timeout_force(this);
 749                 return;
 750         }
 751         else if(this.goalentity.tag_entity)
 752         {
 753                 navigation_goalrating_timeout_expire(this, 2);
 754         }
 755         else if(this.goalentity.bot_pickup)
 756         {
 757                 if(this.goalentity.bot_pickup_respawning)
 758                 {
 759                         if(this.goalentity.solid) // item respawned
 760                                 this.goalentity.bot_pickup_respawning = false;
 761                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 762                         {
 763                                 if(checkpvs(this.origin, this.goalentity))
 764                                 {
 765                                         this.goalentity.bot_pickup_respawning = false;
 766                                         navigation_goalrating_timeout_expire(this, random());
 767                                 }
 768                                 locked_goal = true; // wait for item to respawn
 769                         }
 770                         else if(this.goalentity == this.goalcurrent)
 771                                 locked_goal = true; // wait for item to respawn
 772                 }
 773                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 774                 {
 775                         if(checkpvs(this.origin, this.goalentity))
 776                         {
 777                                 navigation_goalrating_timeout_expire(this, random());
 778                         }
 779                 }
 780         }
 781         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 782                 locked_goal = true;
 783
 784         if (navigation_shortenpath(this))
 785         {
 786                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 787                         && navigation_goalrating_timeout_can_be_anticipated(this))
 788                 {
 789                         navigation_goalrating_timeout_force(this);
 790                 }
 791         }
 792
 793         bool goalcurrent_can_be_removed = false;
 794         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 795         {
 796                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 797                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 798                 {
 799                         goalcurrent_can_be_removed = true;
 800                         // don't remove if not visible
 801                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 802                         {
 803                                 if (IS_DEAD(this.goalcurrent))
 804                                 {
 805                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 806                                         {
 807                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 808                                                 {
 809                                                         navigation_clearroute(this);
 810                                                         navigation_pushroute(this, it);
 811                                                         // loot can't be immediately rated since it isn't on ground yet
 812                                                         // it will be rated after a second when on ground, meanwhile head to it
 813                                                         navigation_goalrating_timeout_expire(this, 1);
 814                                                         return;
 815                                                 }
 816                                         });
 817                                 }
 818                                 if (!Item_IsLoot(this.goalcurrent))
 819                                 {
 820                                         navigation_goalrating_timeout_force(this);
 821                                         return;
 822                                 }
 823                         }
 824                 }
 825                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 826                 {
 827                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 828                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 829                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 830                         {
 831                                 navigation_goalrating_timeout_force(this);
 832                                 return;
 833                         }
 834                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 835                 }
 836         }
 837
 838         if(!locked_goal)
 839         {
 840                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 841                 // in this case path finding can start directly from a waypoint instead of
 842                 // looking for all the reachable waypoints up to a certain distance
 843                 if (navigation_poptouchedgoals(this))
 844                 {
 845                         if (this.goalcurrent)
 846                         {
 847                                 if (goalcurrent_can_be_removed)
 848                                 {
 849                                         // remove even if not visible
 850                                         navigation_goalrating_timeout_force(this);
 851                                         return;
 852                                 }
 853                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 854                                         navigation_goalrating_timeout_force(this);
 855                         }
 856                         else
 857                         {
 858                                 entity old_goal = this.goalcurrent_prev;
 859                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 860                                 {
 861                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 862                                         // item of the group by telling the bot to head directly to the farthest item.
 863                                         // Next time we let the bot select a goal as usual which can be another item
 864                                         // of this group (the closest one) and so on
 865                                         this.item_group = old_goal.item_group;
 866                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 867                                         if (new_goal)
 868                                                 navigation_pushroute(this, new_goal);
 869                                 }
 870                         }
 871                 }
 872         }
 873
 874         // if ran out of goals try to use an alternative goal or get a new strategy asap
 875         if(this.goalcurrent == NULL)
 876         {
 877                 navigation_goalrating_timeout_force(this);
 878                 return;
 879         }
 880
 881
 882         if(autocvar_bot_debug_goalstack)
 883                 debuggoalstack(this);
 884
 885         bool bunnyhop_forbidden = false;
 886         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 887         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 888         {
 889                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 890                 destorg = this.goalcurrent.origin;
 891         }
 892         else if (this.goalcurrent.wpisbox)
 893         {
 894                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 895                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 896                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 897                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 898                 {
 899                         bunnyhop_forbidden = true;
 900                         destorg = this.goalcurrent.origin;
 901                         if(destorg.z > this.origin.z)
 902                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 903                 }
 904         }
 905
 906         diff = destorg - this.origin;
 907
 908         if (time < this.bot_stop_moving_timeout
 909                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 910         {
 911                 // stop if the locked goal has been reached
 912                 destorg = this.origin;
 913                 diff = dir = '0 0 0';
 914         }
 915         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 916         {
 917                 if (vdist(diff, <, 80))
 918                 {
 919                         // stop if too close to target player (even if frozen)
 920                         destorg = this.origin;
 921                         diff = dir = '0 0 0';
 922                 }
 923                 else
 924                 {
 925                         // move destorg out of target players, otherwise bot will consider them
 926                         // an obstacle that needs to be jumped (especially if frozen)
 927                         dir = normalize(diff);
 928                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 929                         diff = destorg - this.origin;
 930                 }
 931         }
 932         else
 933                 dir = normalize(diff);
 934         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 935
 936         //if (this.bot_dodgevector_time < time)
 937         {
 938                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 939                 //this.bot_dodgevector_jumpbutton = 1;
 940                 evadeobstacle = '0 0 0';
 941                 evadelava = '0 0 0';
 942
 943                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 944                 makevectors(this.v_angle.y * '0 1 0');
 945                 if (this.waterlevel > WATERLEVEL_WETFEET)
 946                 {
 947                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 948                         {
 949                                 if(!this.goalcurrent)
 950                                         this.aistatus |= AI_STATUS_OUT_WATER;
 951                                 else if(destorg.z > this.origin.z)
 952                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 953                         }
 954                         else
 955                         {
 956                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 957                                         (this.aistatus & AI_STATUS_OUT_WATER))
 958                                 {
 959                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 960                                         dir = flatdir;
 961                                 }
 962                                 else
 963                                 {
 964                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 965                                         if (destorg.z > this.origin.z)
 966                                                 dir = flatdir;
 967                                 }
 968                         }
 969                 }
 970                 else
 971                 {
 972                         float s;
 973                         vector offset;
 974                         if(this.aistatus & AI_STATUS_OUT_WATER)
 975                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 976
 977                         // jump if going toward an obstacle that doesn't look like stairs we
 978                         // can walk up directly
 979                         vector deviation = '0 0 0';
 980                         float current_speed = vlen(vec2(this.velocity));
 981                         if (current_speed < maxspeed * 0.2)
 982                                 current_speed = maxspeed * 0.2;
 983                         else
 984                         {
 985                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 986                                 while (deviation.y < -180) deviation.y += 360;
 987                                 while (deviation.y > 180) deviation.y -= 360;
 988                         }
 989                         float turning = false;
 990                         vector flat_diff = vec2(diff);
 991                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 992                         vector actual_destorg = this.origin + offset;
 993                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
 994                         {
 995                                 if (vlen2(flat_diff) < vlen2(offset))
 996                                 {
 997                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 998                                         {
 999                                                 // oblique warpzones need a jump otherwise bots gets stuck
1000                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1001                                         }
1002                                         else
1003                                         {
1004                                                 actual_destorg.x = destorg.x;
1005                                                 actual_destorg.y = destorg.y;
1006                                         }
1007                                 }
1008                         }
1009                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
1010                         {
1011                                 actual_destorg.x = destorg.x;
1012                                 actual_destorg.y = destorg.y;
1013                         }
1014                         else if (vlen2(flat_diff) < vlen2(offset))
1015                         {
1016                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1017                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
1018                                 float dist = vlen(vec2(this.origin + offset - destorg));
1019                                 // if current and next goal are close to each other make sure
1020                                 // actual_destorg isn't set beyond next_goal_org
1021                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
1022                                         actual_destorg = next_goal_org;
1023                                 else
1024                                         actual_destorg = vec2(destorg) + dist * next_dir;
1025                                 actual_destorg.z = this.origin.z;
1026                                 turning = true;
1027                         }
1028
1029                         LABEL(jump_check);
1030                         dir = flatdir = normalize(actual_destorg - this.origin);
1031
1032                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
1033                         {
1034                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1035                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1036                                 {
1037                                         s = trace_fraction;
1038                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1039                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1040                                         {
1041                                                 // found an obstacle
1042                                                 if (turning && fabs(deviation.y) > 5)
1043                                                 {
1044                                                         // check if the obstacle is still there without turning
1045                                                         actual_destorg = destorg;
1046                                                         turning = false;
1047                                                         this.bot_tracewalk_time = time + 0.25;
1048                                                         goto jump_check;
1049                                                 }
1050                                                 s = trace_fraction;
1051                                                 // don't artificially reduce max jump height in real-time
1052                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1053                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1054                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1055                                                 if (trace_fraction > s)
1056                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1057                                                 else
1058                                                 {
1059                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1060                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1061                                                         if (trace_fraction > s)
1062                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1063                                                 }
1064                                         }
1065                                 }
1066                         }
1067
1068                         // if bot for some reason doesn't get close to the current goal find another one
1069                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1070                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1071                         if(havocbot_checkgoaldistance(this, destorg))
1072                         {
1073                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1074                                 {
1075                                         navigation_clearroute(this);
1076                                         navigation_goalrating_timeout_force(this);
1077                                         return;
1078                                 }
1079
1080                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1081                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1082                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1083                                 {
1084                                         navigation_clearroute(this);
1085                                         navigation_goalrating_timeout_force(this);
1086                                         return;
1087                                 }
1088
1089                                 // give bot only another chance to prevent bot getting stuck
1090                                 // in case it thinks it can walk but actually can't
1091                                 this.goalcurrent_distance_z = FLOAT_MAX;
1092                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1093                                 this.goalcurrent_distance_time = -time; // mark second try
1094                         }
1095
1096                         // Check for water/slime/lava and dangerous edges
1097                         // (only when the bot is on the ground or jumping intentionally)
1098
1099                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1100                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1101                         {
1102                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1103                         }
1104
1105                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1106                         vector dst_ahead = this.origin + this.view_ofs + offset;
1107                         vector dst_down = dst_ahead - '0 0 3000';
1108                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1109
1110                         bool unreachable = false;
1111                         s = CONTENT_SOLID;
1112                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1113                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1114                         {
1115                                 // Look downwards
1116                                 traceline(dst_ahead , dst_down, true, NULL);
1117                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1118                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1119                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1120                                 {
1121                                         s = pointcontents(trace_endpos + '0 0 1');
1122                                         if (s != CONTENT_SOLID)
1123                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1124                                                 evadelava = normalize(this.velocity) * -1;
1125                                         else if (s == CONTENT_SKY)
1126                                                 evadeobstacle = normalize(this.velocity) * -1;
1127                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1128                                         {
1129                                                 // the traceline check isn't enough but is good as optimization,
1130                                                 // when not true (most of the time) this tracebox call is avoided
1131                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1132                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1133                                                 {
1134                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1135                                                         {
1136                                                                 // the goal is probably on an upper platform, assume bot can't get there
1137                                                                 unreachable = true;
1138                                                         }
1139                                                         else
1140                                                                 evadelava = normalize(this.velocity) * -1;
1141                                                 }
1142                                         }
1143                                 }
1144                         }
1145
1146                         dir = flatdir;
1147                         evadeobstacle.z = 0;
1148                         evadelava.z = 0;
1149                         makevectors(this.v_angle.y * '0 1 0');
1150
1151                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1152                         {
1153                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1154                                 if(IS_PLAYER(this.goalcurrent))
1155                                         unreachable = true;
1156                         }
1157
1158                         // slow down if bot is in the air and goal is under it
1159                         if (!this.goalcurrent.wphardwired
1160                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1161                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1162                         {
1163                                 // tracebox wouldn't work when bot is still on the ledge
1164                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1165                                 if (this.origin.z - trace_endpos.z > 120)
1166                                         evadeobstacle = normalize(this.velocity) * -1;
1167                         }
1168
1169                         if(unreachable)
1170                         {
1171                                 navigation_clearroute(this);
1172                                 navigation_goalrating_timeout_force(this);
1173                                 this.ignoregoal = this.goalcurrent;
1174                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1175                         }
1176                 }
1177
1178                 dodge = havocbot_dodge(this);
1179                 if (dodge)
1180                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1181                 dodge += evadeobstacle + evadelava;
1182                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1183                 if (this.enemy)
1184                 {
1185                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1186                         if (IS_PLAYER(trace_ent))
1187                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1188                 }
1189         //      this.bot_dodgevector = dir;
1190         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1191         }
1192
1193         float ladder_zdir = 0;
1194         if(time < this.ladder_time)
1195         {
1196                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1197                 {
1198                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1199                                 ladder_zdir = 1;
1200                 }
1201                 else
1202                 {
1203                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1204                                 ladder_zdir = -1;
1205                 }
1206                 if (ladder_zdir)
1207                 {
1208                         if (vdist(vec2(diff), <, 40))
1209                                 dir.z = ladder_zdir * 4;
1210                         else
1211                                 dir.z = ladder_zdir * 2;
1212                         dir = normalize(dir);
1213                 }
1214         }
1215
1216         if (this.goalcurrent.wpisbox
1217                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1218         {
1219                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1220                 // head to teleport origin
1221                 dir = (this.goalcurrent.origin - this.origin);
1222                 dir.z = 0;
1223                 dir = normalize(dir);
1224         }
1225
1226         // already executed when bot targets an enemy
1227         if (!this.bot_aimdir_executed)
1228         {
1229                 if (time < this.bot_stop_moving_timeout)
1230                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1231                 else
1232                         bot_aimdir(this, dir, 0);
1233         }
1234
1235         if (!ladder_zdir)
1236         {
1237                 dir *= dodge_enemy_factor;
1238                 dir = normalize(dir + dodge);
1239         }
1240
1241         makevectors(this.v_angle);
1242         //dir = this.bot_dodgevector;
1243         //if (this.bot_dodgevector_jumpbutton)
1244         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1245         CS(this).movement_x = dir * v_forward * maxspeed;
1246         CS(this).movement_y = dir * v_right * maxspeed;
1247         CS(this).movement_z = dir * v_up * maxspeed;
1248
1249         // Emulate keyboard interface
1250         if (skill < 10)
1251                 havocbot_keyboard_movement(this, destorg);
1252
1253         // Bunnyhop!
1254         //if(this.aistatus & AI_STATUS_ROAMING)
1255         if(!bunnyhop_forbidden && this.goalcurrent)
1256         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1257                 havocbot_bunnyhop(this, dir);
1258
1259         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1260         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1261         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1262 }
1263
1264 entity havocbot_gettarget(entity this, bool secondary)
1265 {
1266         entity best = NULL;
1267         vector eye = CENTER_OR_VIEWOFS(this);
1268         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1269         {
1270                 vector v = CENTER_OR_VIEWOFS(it);
1271                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1272                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1273                 if(bot_shouldattack(this, it))
1274                 {
1275                         traceline(eye, v, true, this);
1276                         if (trace_ent == it || trace_fraction >= 1)
1277                                 best = it;
1278                 }
1279         });
1280
1281         return best;
1282 }
1283
1284 void havocbot_chooseenemy(entity this)
1285 {
1286         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1287         {
1288                 this.enemy = NULL;
1289                 return;
1290         }
1291         if (this.enemy)
1292         {
1293                 if (!bot_shouldattack(this, this.enemy))
1294                 {
1295                         // enemy died or something, find a new target
1296                         this.enemy = NULL;
1297                         this.havocbot_chooseenemy_finished = time;
1298                 }
1299                 else if (this.havocbot_stickenemy)
1300                 {
1301                         // tracking last chosen enemy
1302                         // if enemy is visible
1303                         // and not really really far away
1304                         // and we're not severely injured
1305                         // then keep tracking for a half second into the future
1306                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1307                         if (trace_ent == this.enemy || trace_fraction == 1)
1308                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1309                         if (GetResource(this, RES_HEALTH) > 30)
1310                         {
1311                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1312                                 this.havocbot_chooseenemy_finished = time + 0.5;
1313                                 return;
1314                         }
1315                         // enemy isn't visible, or is far away, or we're injured severely
1316                         // so stop preferring this enemy
1317                         // (it will still take a half second until a new one is chosen)
1318                         this.havocbot_stickenemy = 0;
1319                 }
1320         }
1321         if (time < this.havocbot_chooseenemy_finished)
1322                 return;
1323         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1324         vector eye = this.origin + this.view_ofs;
1325         entity best = NULL;
1326         float bestrating = 100000000;
1327
1328         // Backup hit flags
1329         int hf = this.dphitcontentsmask;
1330
1331         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1332
1333         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1334
1335         bool scan_transparent = false;
1336         bool scan_secondary_targets = false;
1337         bool have_secondary_targets = false;
1338         while(true)
1339         {
1340                 scan_secondary_targets = false;
1341 LABEL(scan_targets)
1342                 IL_EACH(g_bot_targets, it.bot_attack,
1343                 {
1344                         if(!scan_secondary_targets)
1345                         {
1346                                 if(it.classname == "misc_breakablemodel")
1347                                 {
1348                                         have_secondary_targets = true;
1349                                         continue;
1350                                 }
1351                         }
1352                         else if(it.classname != "misc_breakablemodel")
1353                                 continue;
1354
1355                         vector v = (it.absmin + it.absmax) * 0.5;
1356                         float rating = vlen2(v - eye);
1357                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1358                         if (bestrating > rating)
1359                         if (bot_shouldattack(this, it))
1360                         {
1361                                 traceline(eye, v, true, this);
1362                                 if (trace_ent == it || trace_fraction >= 1)
1363                                 {
1364                                         best = it;
1365                                         bestrating = rating;
1366                                 }
1367                         }
1368                 });
1369
1370                 if(!best && have_secondary_targets && !scan_secondary_targets)
1371                 {
1372                         scan_secondary_targets = true;
1373                         // restart the loop
1374                         bestrating = 100000000;
1375                         goto scan_targets;
1376                 }
1377
1378                 // I want to do a second scan if no enemy was found or I don't have weapons
1379                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1380                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1381                         break;
1382                 if(scan_transparent)
1383                         break;
1384
1385                 // Set flags to see through transparent objects
1386                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1387
1388                 scan_transparent = true;
1389         }
1390
1391         // Restore hit flags
1392         this.dphitcontentsmask = hf;
1393
1394         this.enemy = best;
1395         this.havocbot_stickenemy = true;
1396         if(best && best.classname == "misc_breakablemodel")
1397                 this.havocbot_stickenemy = false;
1398 }
1399
1400 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1401 {
1402         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1403         // so skip this for them, or they'll never get to reload their weapons at all.
1404         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1405         if(skill < 5)
1406                 return false;
1407
1408         // if this weapon is scheduled for reloading, don't switch to it during combat
1409         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1410         {
1411                 FOREACH(Weapons, it != WEP_Null, {
1412                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1413                                 return true; // other weapon available
1414                 });
1415         }
1416
1417         return false;
1418 }
1419
1420 void havocbot_chooseweapon(entity this, .entity weaponentity)
1421 {
1422         int i;
1423
1424         // ;)
1425         if(g_weaponarena_weapons == WEPSET(TUBA))
1426         {
1427                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1428                 return;
1429         }
1430
1431         // TODO: clean this up by moving it to weapon code
1432         if(this.enemy==NULL)
1433         {
1434                 // If no weapon was chosen get the first available weapon
1435                 if(this.(weaponentity).m_weapon==WEP_Null)
1436                 FOREACH(Weapons, it != WEP_Null, {
1437                         if(client_hasweapon(this, it, weaponentity, true, false))
1438                         {
1439                                 this.(weaponentity).m_switchweapon = it;
1440                                 return;
1441                         }
1442                 });
1443                 return;
1444         }
1445
1446         // Do not change weapon during the next second after a combo
1447         float f = time - this.lastcombotime;
1448         if(f < 1)
1449                 return;
1450
1451         float w;
1452         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1453
1454         // Should it do a weapon combo?
1455         float af, ct, combo_time, combo;
1456
1457         af = ATTACK_FINISHED(this, weaponentity);
1458         ct = autocvar_bot_ai_weapon_combo_threshold;
1459
1460         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1461         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1462         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1463
1464         combo = false;
1465
1466         if(autocvar_bot_ai_weapon_combo)
1467         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1468         if(af > combo_time)
1469         {
1470                 combo = true;
1471                 this.lastcombotime = time;
1472         }
1473
1474         distance *= (2 ** this.bot_rangepreference);
1475
1476         // Custom weapon list based on distance to the enemy
1477         if(bot_custom_weapon){
1478
1479                 // Choose weapons for far distance
1480                 if ( distance > bot_distance_far ) {
1481                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1482                                 w = bot_weapons_far[i];
1483                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1484                                 {
1485                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1486                                                 continue;
1487                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1488                                         return;
1489                                 }
1490                         }
1491                 }
1492
1493                 // Choose weapons for mid distance
1494                 if ( distance > bot_distance_close) {
1495                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1496                                 w = bot_weapons_mid[i];
1497                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1498                                 {
1499                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1500                                                 continue;
1501                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1502                                         return;
1503                                 }
1504                         }
1505                 }
1506
1507                 // Choose weapons for close distance
1508                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1509                         w = bot_weapons_close[i];
1510                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1511                         {
1512                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1513                                         continue;
1514                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1515                                 return;
1516                         }
1517                 }
1518         }
1519 }
1520
1521 void havocbot_aim(entity this)
1522 {
1523         if (time < this.nextaim)
1524                 return;
1525         this.nextaim = time + 0.1;
1526         vector myvel = this.velocity;
1527         if (!this.waterlevel)
1528                 myvel.z = 0;
1529         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1530         else if (this.enemy)
1531         {
1532                 vector enemyvel = this.enemy.velocity;
1533                 if (!this.enemy.waterlevel)
1534                         enemyvel.z = 0;
1535                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1536         }
1537         else
1538                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1539 }
1540
1541 bool havocbot_moveto_refresh_route(entity this)
1542 {
1543         // Refresh path to goal if necessary
1544         entity wp;
1545         wp = this.havocbot_personal_waypoint;
1546         navigation_goalrating_start(this);
1547         navigation_routerating(this, wp, 10000, 10000);
1548         navigation_goalrating_end(this);
1549         return (this.goalentity != NULL);
1550 }
1551
1552 float havocbot_moveto(entity this, vector pos)
1553 {
1554         entity wp;
1555
1556         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1557         {
1558                 // Step 4: Move to waypoint
1559                 if(this.havocbot_personal_waypoint==NULL)
1560                 {
1561                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1562                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1563                         return CMD_STATUS_ERROR;
1564                 }
1565
1566                 if (!bot_strategytoken_taken)
1567                 if(this.havocbot_personal_waypoint_searchtime<time)
1568                 {
1569                         bot_strategytoken_taken = true;
1570                         if(havocbot_moveto_refresh_route(this))
1571                         {
1572                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1573                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1574                                 this.havocbot_personal_waypoint_failcounter = 0;
1575                         }
1576                         else
1577                         {
1578                                 this.havocbot_personal_waypoint_failcounter += 1;
1579                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1580                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1581                                 {
1582                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1583                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1584                                         delete(this.havocbot_personal_waypoint);
1585                                         return CMD_STATUS_ERROR;
1586                                 }
1587                                 else
1588                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1589                         }
1590                 }
1591
1592                 if(autocvar_bot_debug_goalstack)
1593                         debuggoalstack(this);
1594
1595
1596                 // Go!
1597                 havocbot_movetogoal(this);
1598
1599                 if (!this.bot_aimdir_executed && this.goalcurrent)
1600                 {
1601                         // Heading
1602                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1603                         dir -= this.origin + this.view_ofs;
1604                         dir.z = 0;
1605                         bot_aimdir(this, dir, 0);
1606                 }
1607
1608                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1609                 {
1610                         // Step 5: Waypoint reached
1611                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1612                         waypoint_remove(this.havocbot_personal_waypoint);
1613                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1614                         return CMD_STATUS_FINISHED;
1615                 }
1616
1617                 return CMD_STATUS_EXECUTING;
1618         }
1619
1620         // Step 2: Linking waypoint
1621         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1622         {
1623                 // Wait until it is linked
1624                 if(!this.havocbot_personal_waypoint.wplinked)
1625                 {
1626                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1627                         return CMD_STATUS_EXECUTING;
1628                 }
1629
1630                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1631                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1632                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1633
1634                 // Step 3: Route to waypoint
1635                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1636
1637                 return CMD_STATUS_EXECUTING;
1638         }
1639
1640         // Step 1: Spawning waypoint
1641         wp = waypoint_spawnpersonal(this, pos);
1642         if(wp==NULL)
1643         {
1644                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1645                 return CMD_STATUS_ERROR;
1646         }
1647
1648         this.havocbot_personal_waypoint = wp;
1649         this.havocbot_personal_waypoint_failcounter = 0;
1650         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1651
1652         // if pos is inside a teleport, then let's mark it as teleport waypoint
1653         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1654         {
1655                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1656                 this.lastteleporttime = 0;
1657         });
1658
1659 /*
1660         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1661                 print("routing to a teleporter\n");
1662         else
1663                 print("routing to a non-teleporter\n");
1664 */
1665
1666         return CMD_STATUS_EXECUTING;
1667 }
1668
1669 float havocbot_resetgoal(entity this)
1670 {
1671         navigation_clearroute(this);
1672         return CMD_STATUS_FINISHED;
1673 }
1674
1675 void havocbot_setupbot(entity this)
1676 {
1677         this.bot_ai = havocbot_ai;
1678         this.cmd_moveto = havocbot_moveto;
1679         this.cmd_resetgoal = havocbot_resetgoal;
1680
1681         // NOTE: bot is not player yet
1682         havocbot_chooserole(this);
1683 }
1684
1685 vector havocbot_dodge(entity this)
1686 {
1687         // LordHavoc: disabled because this is too expensive
1688         return '0 0 0';
1689 #if 0
1690         entity head;
1691         vector dodge, v, n;
1692         float danger, bestdanger, vl, d;
1693         dodge = '0 0 0';
1694         bestdanger = -20;
1695         // check for dangerous objects near bot or approaching bot
1696         head = findchainfloat(bot_dodge, true);
1697         while(head)
1698         {
1699                 if (head.owner != this)
1700                 {
1701                         vl = vlen(head.velocity);
1702                         if (vl > autocvar_sv_maxspeed * 0.3)
1703                         {
1704                                 n = normalize(head.velocity);
1705                                 v = this.origin - head.origin;
1706                                 d = v * n;
1707                                 if (d > (0 - head.bot_dodgerating))
1708                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1709                                 {
1710                                         // calculate direction and distance from the flight path, by removing the forward axis
1711                                         v = v - (n * (v * n));
1712                                         danger = head.bot_dodgerating - vlen(v);
1713                                         if (bestdanger < danger)
1714                                         {
1715                                                 bestdanger = danger;
1716                                                 // dodge to the side of the object
1717                                                 dodge = normalize(v);
1718                                         }
1719                                 }
1720                         }
1721                         else
1722                         {
1723                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1724                                 if (bestdanger < danger)
1725                                 {
1726                                         bestdanger = danger;
1727                                         dodge = normalize(this.origin - head.origin);
1728                                 }
1729                         }
1730                 }
1731                 head = head.chain;
1732         }
1733         return dodge;
1734 #endif
1735 }