qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/triggers/teleporters.qh>
  22 #include <common/triggers/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this)
  37         if (!bot_strategytoken_taken)
  38         {
  39                 if(this.havocbot_blockhead)
  40                 {
  41                         this.havocbot_blockhead = false;
  42                 }
  43                 else
  44                 {
  45                         if (!this.jumppadcount && !STAT(FROZEN, this))
  46                                 this.havocbot_role(this); // little too far down the rabbit hole
  47                 }
  48
  49                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  50                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  51                 if(!this.goalcurrent)
  52                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  53                 {
  54                         // Look for the closest waypoint out of water
  55                         entity newgoal = NULL;
  56                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  57                         {
  58                                 if(it.origin.z < this.origin.z)
  59                                         continue;
  60
  61                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  62                                         continue;
  63
  64                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  65                                         continue;
  66
  67                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  68
  69                                 if(trace_fraction < 1)
  70                                         continue;
  71
  72                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  73                                         newgoal = it;
  74                         });
  75
  76                         if(newgoal)
  77                         {
  78                         //      te_wizspike(newgoal.origin);
  79                                 navigation_pushroute(this, newgoal);
  80                         }
  81                 }
  82
  83                 // token has been used this frame
  84                 bot_strategytoken_taken = true;
  85         }
  86
  87         if(IS_DEAD(this) || STAT(FROZEN, this))
  88                 return;
  89
  90         havocbot_chooseenemy(this);
  91
  92         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  93         {
  94                 .entity weaponentity = weaponentities[slot];
  95                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  96                 if(this.(weaponentity).bot_chooseweapontime < time)
  97                 {
  98                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  99                         havocbot_chooseweapon(this, weaponentity);
 100                 }
 101         }
 102         havocbot_aim(this);
 103         lag_update(this);
 104         if (this.bot_aimtarg)
 105         {
 106                 this.aistatus |= AI_STATUS_ATTACKING;
 107                 this.aistatus &= ~AI_STATUS_ROAMING;
 108
 109                 if(this.weapons)
 110                 {
 111                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 112                         {
 113                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 114                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 115                         }
 116                         else
 117                         {
 118                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 119                                 {
 120                                         .entity weaponentity = weaponentities[slot];
 121                                         Weapon w = this.(weaponentity).m_weapon;
 122                                         if(w == WEP_Null && slot != 0)
 123                                                 continue;
 124                                         w.wr_aim(w, this, weaponentity);
 125                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 126                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 127                                 }
 128                         }
 129                 }
 130                 else
 131                 {
 132                         if(IS_PLAYER(this.bot_aimtarg))
 133                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 134                 }
 135         }
 136         else if (this.goalcurrent)
 137         {
 138                 this.aistatus |= AI_STATUS_ROAMING;
 139                 this.aistatus &= ~AI_STATUS_ATTACKING;
 140
 141                 vector v = '0 0 0', now, next;
 142                 float aimdistance,skillblend,distanceblend,blend;
 143
 144                 SET_DESTCOORDS(this.goalcurrent, this.origin, v);
 145                 if(this.goalcurrent.wpisbox)
 146                 {
 147                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 148                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 149                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 150                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 151                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 152                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 153                                 v = this.goalcurrent.origin;
 154                 }
 155                 next = now = v - (this.origin + this.view_ofs);
 156                 aimdistance = vlen(now);
 157
 158                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 159                 if(
 160                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 161                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 162                 )
 163                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 164
 165                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 166                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 167                 blend = skillblend * (1-distanceblend);
 168                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 169                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 170                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 171                 v = now + blend * (next - now);
 172                 //dprint(etos(this), " ");
 173                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 174                 //v = now * (distanceblend) + next * (1-distanceblend);
 175                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 176                         v.z = 0;
 177                 //dprint("walk at:", vtos(v), "\n");
 178                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 179                 bot_aimdir(this, v, -1);
 180         }
 181         havocbot_movetogoal(this);
 182
 183         // if the bot is not attacking, consider reloading weapons
 184         if (!(this.aistatus & AI_STATUS_ATTACKING))
 185         {
 186                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 187                 {
 188                         .entity weaponentity = weaponentities[slot];
 189
 190                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 191                                 continue;
 192
 193                         // we are currently holding a weapon that's not fully loaded, reload it
 194                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 195                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 196                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 197
 198                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 199                         // the code above executes next frame, starting the reloading then
 200                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 201                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 202                         {
 203                                 FOREACH(Weapons, it != WEP_Null, {
 204                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 205                                         {
 206                                                 this.(weaponentity).m_switchweapon = it;
 207                                                 break;
 208                                         }
 209                                 });
 210                         }
 211                 }
 212         }
 213 }
 214
 215 void havocbot_keyboard_movement(entity this, vector destorg)
 216 {
 217         vector keyboard;
 218
 219         if (time > this.havocbot_keyboardtime)
 220         {
 221                 float sk = skill + this.bot_moveskill;
 222                 this.havocbot_keyboardtime =
 223                         max(
 224                                 this.havocbot_keyboardtime
 225                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 226                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 227                         , time);
 228                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 229
 230                 float trigger = autocvar_bot_ai_keyboard_threshold;
 231                 float trigger1 = -trigger;
 232
 233                 // categorize forward movement
 234                 // at skill < 1.5 only forward
 235                 // at skill < 2.5 only individual directions
 236                 // at skill < 4.5 only individual directions, and forward diagonals
 237                 // at skill >= 4.5, all cases allowed
 238                 if (keyboard.x > trigger)
 239                 {
 240                         keyboard.x = 1;
 241                         if (sk < 2.5)
 242                                 keyboard.y = 0;
 243                 }
 244                 else if (keyboard.x < trigger1 && sk > 1.5)
 245                 {
 246                         keyboard.x = -1;
 247                         if (sk < 4.5)
 248                                 keyboard.y = 0;
 249                 }
 250                 else
 251                 {
 252                         keyboard.x = 0;
 253                         if (sk < 1.5)
 254                                 keyboard.y = 0;
 255                 }
 256                 if (sk < 4.5)
 257                         keyboard.z = 0;
 258
 259                 if (keyboard.y > trigger)
 260                         keyboard.y = 1;
 261                 else if (keyboard.y < trigger1)
 262                         keyboard.y = -1;
 263                 else
 264                         keyboard.y = 0;
 265
 266                 if (keyboard.z > trigger)
 267                         keyboard.z = 1;
 268                 else if (keyboard.z < trigger1)
 269                         keyboard.z = -1;
 270                 else
 271                         keyboard.z = 0;
 272
 273                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 274                 if (this.havocbot_ducktime > time)
 275                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 276         }
 277
 278         keyboard = this.havocbot_keyboard;
 279         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 280         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 281         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 282 }
 283
 284 void havocbot_bunnyhop(entity this, vector dir)
 285 {
 286         float bunnyhopdistance;
 287         vector deviation;
 288         float maxspeed;
 289         vector gco = '0 0 0', gno;
 290
 291         // Don't jump when attacking
 292         if(this.aistatus & AI_STATUS_ATTACKING)
 293                 return;
 294
 295         if(IS_PLAYER(this.goalcurrent))
 296                 return;
 297
 298         maxspeed = autocvar_sv_maxspeed;
 299
 300         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 301                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 302         {
 303                 this.aistatus &= ~AI_STATUS_RUNNING;
 304                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 305                 this.bot_canruntogoal = 0;
 306                 this.bot_timelastseengoal = 0;
 307                 return;
 308         }
 309
 310         if(this.waterlevel > WATERLEVEL_WETFEET)
 311         {
 312                 this.aistatus &= ~AI_STATUS_RUNNING;
 313                 return;
 314         }
 315
 316         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 317         {
 318                 this.bot_canruntogoal = 0;
 319                 this.bot_timelastseengoal = 0;
 320         }
 321
 322         SET_DESTCOORDS(this.goalcurrent, this.origin, gco);
 323         bunnyhopdistance = vlen(this.origin - gco);
 324
 325         // Run only to visible goals
 326         if(IS_ONGROUND(this))
 327         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 328         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 329         {
 330                         this.bot_lastseengoal = this.goalcurrent;
 331
 332                         // seen it before
 333                         if(this.bot_timelastseengoal)
 334                         {
 335                                 // for a period of time
 336                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 337                                 {
 338                                         float checkdistance;
 339                                         checkdistance = true;
 340
 341                                         // don't run if it is too close
 342                                         if(this.bot_canruntogoal==0)
 343                                         {
 344                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 345                                                         this.bot_canruntogoal = 1;
 346                                                 else
 347                                                         this.bot_canruntogoal = -1;
 348                                         }
 349
 350                                         if(this.bot_canruntogoal != 1)
 351                                                 return;
 352
 353                                         if(this.aistatus & AI_STATUS_ROAMING)
 354                                         if(this.goalcurrent.classname=="waypoint")
 355                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 356                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 357                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 358                                         {
 359                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 360                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 361                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 362                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 363
 364                                                 if(fabs(deviation.y) < 20)
 365                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 366                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 367                                                 {
 368                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 369                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 370                                                         {
 371                                                                 checkdistance = false;
 372                                                         }
 373                                                 }
 374                                         }
 375
 376                                         if(checkdistance)
 377                                         {
 378                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 379                                                 // increase stop distance in case the goal is on a slope or a lower platform
 380                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 381                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 382                                         }
 383                                         else
 384                                         {
 385                                                 this.aistatus |= AI_STATUS_RUNNING;
 386                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 387                                         }
 388                                 }
 389                         }
 390                         else
 391                         {
 392                                 this.bot_timelastseengoal = time;
 393                         }
 394         }
 395         else
 396         {
 397                 this.bot_timelastseengoal = 0;
 398         }
 399
 400 #if 0
 401         // Release jump button
 402         if(!cvar("sv_pogostick"))
 403         if((IS_ONGROUND(this)) == 0)
 404         {
 405                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 406                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 407
 408                 // Strafe
 409                 if(this.aistatus & AI_STATUS_RUNNING)
 410                 if(vlen(this.velocity)>maxspeed)
 411                 {
 412                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 413                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 414                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 415
 416                         if(fabs(deviation.y)>10)
 417                                 CS(this).movement_x = 0;
 418
 419                         if(deviation.y>10)
 420                                 CS(this).movement_y = maxspeed * -1;
 421                         else if(deviation.y<10)
 422                                 CS(this).movement_y = maxspeed;
 423
 424                 }
 425         }
 426 #endif
 427 }
 428
 429 // return true when bot isn't getting closer to the current goal
 430 bool havocbot_checkgoaldistance(entity this, vector gco)
 431 {
 432         float curr_dist = vlen(this.origin - gco);
 433         float curr_dist_2d = vlen(vec2(this.origin - gco));
 434         if(curr_dist > this.goalcurrent_distance && curr_dist_2d > this.goalcurrent_distance_2d)
 435         {
 436                 if(!this.goalcurrent_distance_time)
 437                         this.goalcurrent_distance_time = time;
 438                 else if (time - this.goalcurrent_distance_time > 0.5)
 439                         return true;
 440         }
 441         else
 442         {
 443                 // reduce it a little bit so it works even with very small approaches to the goal
 444                 this.goalcurrent_distance = max(20, curr_dist - 10);
 445                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 446                 this.goalcurrent_distance_time = 0;
 447         }
 448         return false;
 449 }
 450
 451 void havocbot_movetogoal(entity this)
 452 {
 453         vector destorg = '0 0 0';
 454         vector diff;
 455         vector dir;
 456         vector flatdir;
 457         vector evadeobstacle;
 458         vector evadelava;
 459         float maxspeed;
 460         vector gco;
 461         //float dist;
 462         vector dodge;
 463         //if (this.goalentity)
 464         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 465         CS(this).movement = '0 0 0';
 466         maxspeed = autocvar_sv_maxspeed;
 467
 468         // Jetpack navigation
 469         if(this.goalcurrent)
 470         if(this.navigation_jetpack_goal)
 471         if(this.goalcurrent==this.navigation_jetpack_goal)
 472         if(this.ammo_fuel)
 473         {
 474                 if(autocvar_bot_debug_goalstack)
 475                 {
 476                         debuggoalstack(this);
 477                         te_wizspike(this.navigation_jetpack_point);
 478                 }
 479
 480                 // Take off
 481                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 482                 {
 483                         // Brake almost completely so it can get a good direction
 484                         if(vdist(this.velocity, >, 10))
 485                                 return;
 486                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 487                 }
 488
 489                 makevectors(this.v_angle.y * '0 1 0');
 490                 dir = normalize(this.navigation_jetpack_point - this.origin);
 491
 492                 // Landing
 493                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 494                 {
 495                         // Calculate brake distance in xy
 496                         float db, v, d;
 497                         vector dxy;
 498
 499                         dxy = this.origin - ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ); dxy.z = 0;
 500                         d = vlen(dxy);
 501                         v = vlen(this.velocity -  this.velocity.z * '0 0 1');
 502                         db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 503                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 504                         if(d < db || d < 500)
 505                         {
 506                                 // Brake
 507                                 if(fabs(this.velocity.x)>maxspeed*0.3)
 508                                 {
 509                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 510                                         return;
 511                                 }
 512                                 // Switch to normal mode
 513                                 this.navigation_jetpack_goal = NULL;
 514                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 515                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 516                                 return;
 517                         }
 518                 }
 519                 else if(checkpvs(this.origin,this.goalcurrent))
 520                 {
 521                         // If I can see the goal switch to landing code
 522                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 523                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 524                         return;
 525                 }
 526
 527                 // Flying
 528                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 529                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 530                 {
 531                         CS(this).movement_x = dir * v_forward * maxspeed;
 532                         CS(this).movement_y = dir * v_right * maxspeed;
 533                 }
 534                 return;
 535         }
 536
 537         // Handling of jump pads
 538         if(this.jumppadcount)
 539         {
 540                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 541                 {
 542                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 543                         navigation_poptouchedgoals(this);
 544                         return;
 545                 }
 546                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 547                 {
 548                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 549                         // but with some randomness so it can try out different paths
 550                         if(!this.goalcurrent)
 551                         {
 552                                 entity newgoal = NULL;
 553                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 554                                 {
 555                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 556                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 557                                                 continue;
 558
 559                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 560
 561                                         if(trace_fraction < 1)
 562                                                 continue;
 563
 564                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 565                                                 newgoal = it;
 566                                 });
 567
 568                                 if(newgoal)
 569                                 {
 570                                         this.ignoregoal = this.goalcurrent;
 571                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 572                                         navigation_clearroute(this);
 573                                         navigation_routetogoal(this, newgoal, this.origin);
 574                                         if(autocvar_bot_debug_goalstack)
 575                                                 debuggoalstack(this);
 576                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 577                                 }
 578                         }
 579                         else
 580                         {
 581                                 gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 582                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 583                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 584                                 else if(havocbot_checkgoaldistance(this, gco))
 585                                 {
 586                                         navigation_clearroute(this);
 587                                         this.bot_strategytime = 0;
 588                                 }
 589                                 else
 590                                         return;
 591                         }
 592                 }
 593                 else
 594                 {
 595                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 596                         {
 597                                 vector velxy = this.velocity; velxy_z = 0;
 598                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 599                                 {
 600                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 601                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 602                                 }
 603                                 return;
 604                         }
 605
 606                         // Don't chase players while using a jump pad
 607                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 608                                 return;
 609                 }
 610         }
 611         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 612                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 613
 614         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 615         if(skill>6)
 616         if (!(IS_ONGROUND(this)))
 617         {
 618                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 619                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 620                 if(this.items & IT_JETPACK)
 621                 {
 622                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 623                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 624                         {
 625                                 if(this.velocity.z<0)
 626                                 {
 627                                         PHYS_INPUT_BUTTON_HOOK(this) = true;
 628                                 }
 629                         }
 630                         else
 631                                 PHYS_INPUT_BUTTON_HOOK(this) = true;
 632
 633                         // If there is no goal try to move forward
 634
 635                         if(this.goalcurrent==NULL)
 636                                 dir = v_forward;
 637                         else
 638                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 639
 640                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 641                         float xyspeed = xyvelocity * dir;
 642
 643                         if(xyspeed < (maxspeed / 2))
 644                         {
 645                                 makevectors(this.v_angle.y * '0 1 0');
 646                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 647                                 if(trace_fraction==1)
 648                                 {
 649                                         CS(this).movement_x = dir * v_forward * maxspeed;
 650                                         CS(this).movement_y = dir * v_right * maxspeed;
 651                                         if (skill < 10)
 652                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 653                                 }
 654                         }
 655
 656                         this.havocbot_blockhead = true;
 657
 658                         return;
 659                 }
 660                 else if(this.health > WEP_CVAR(devastator, damage) * 0.5 * ((this.strength_finished < time) ? autocvar_g_balance_powerup_strength_selfdamage : 1))
 661                 {
 662                         if(this.velocity.z < 0)
 663                         {
 664                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 665                                 {
 666                                         .entity weaponentity = weaponentities[slot];
 667
 668                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 669                                                 continue;
 670
 671                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 672                                         {
 673                                                 CS(this).movement_x = maxspeed;
 674
 675                                                 if(this.rocketjumptime)
 676                                                 {
 677                                                         if(time > this.rocketjumptime)
 678                                                         {
 679                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 680                                                                 this.rocketjumptime = 0;
 681                                                         }
 682                                                         return;
 683                                                 }
 684
 685                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 686                                                 this.v_angle_x = 90;
 687                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 688                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 689                                                 return;
 690                                         }
 691                                 }
 692                         }
 693                 }
 694                 else
 695                 {
 696                         // If there is no goal try to move forward
 697                         if(this.goalcurrent==NULL)
 698                                 CS(this).movement_x = maxspeed;
 699                 }
 700         }
 701
 702         // If we are under water with no goals, swim up
 703         if(this.waterlevel)
 704         if(this.goalcurrent==NULL)
 705         {
 706                 dir = '0 0 0';
 707                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 708                         dir.z = 1;
 709                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 710                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 711                 else
 712                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 713                 makevectors(this.v_angle.y * '0 1 0');
 714                 CS(this).movement_x = dir * v_forward * maxspeed;
 715                 CS(this).movement_y = dir * v_right * maxspeed;
 716                 CS(this).movement_z = dir * v_up * maxspeed;
 717         }
 718
 719         // if there is nowhere to go, exit
 720         if (this.goalcurrent == NULL)
 721                 return;
 722
 723
 724         bool locked_goal = false;
 725         if(this.goalentity && wasfreed(this.goalentity))
 726         {
 727                 navigation_clearroute(this);
 728                 this.bot_strategytime = 0;
 729                 return;
 730         }
 731         else if(this.goalentity.bot_pickup)
 732         {
 733                 if(this.goalentity.bot_pickup_respawning)
 734                 {
 735                         if(this.goalentity.solid) // item respawned
 736                                 this.goalentity.bot_pickup_respawning = false;
 737                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 738                         {
 739                                 if(checkpvs(this.origin, this.goalentity))
 740                                 {
 741                                         this.goalentity.bot_pickup_respawning = false;
 742                                         navigation_clearroute(this);
 743                                         this.bot_strategytime = 0;
 744                                         return;
 745                                 }
 746                         }
 747                         else if(this.goalentity == this.goalcurrent)
 748                                 locked_goal = true; // wait for item to respawn
 749                 }
 750                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 751                 {
 752                         if(checkpvs(this.origin, this.goalentity))
 753                         {
 754                                 navigation_clearroute(this);
 755                                 this.bot_strategytime = 0;
 756                                 return;
 757                         }
 758                 }
 759         }
 760         if(!locked_goal)
 761                 navigation_poptouchedgoals(this);
 762
 763         // if ran out of goals try to use an alternative goal or get a new strategy asap
 764         if(this.goalcurrent == NULL)
 765         {
 766                 this.bot_strategytime = 0;
 767                 return;
 768         }
 769
 770
 771         if(autocvar_bot_debug_goalstack)
 772                 debuggoalstack(this);
 773
 774         bool bunnyhop_forbidden = false;;
 775         SET_DESTCOORDS(this.goalcurrent, this.origin, destorg);
 776
 777         // in case bot ends up inside the teleport waypoint without touching
 778         // the teleport itself, head to the teleport origin
 779         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 780         {
 781                 bunnyhop_forbidden = true;
 782                 destorg = this.goalcurrent.origin;
 783                 if(destorg.z > this.origin.z)
 784                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 785         }
 786
 787         diff = destorg - this.origin;
 788         //dist = vlen(diff);
 789         dir = normalize(diff);
 790         flatdir = diff;flatdir.z = 0;
 791         flatdir = normalize(flatdir);
 792         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 793
 794         //if (this.bot_dodgevector_time < time)
 795         {
 796                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 797                 //this.bot_dodgevector_jumpbutton = 1;
 798                 evadeobstacle = '0 0 0';
 799                 evadelava = '0 0 0';
 800
 801                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 802                 makevectors(this.v_angle.y * '0 1 0');
 803                 if (this.waterlevel)
 804                 {
 805                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 806                         {
 807                                 if(!this.goalcurrent)
 808                                         this.aistatus |= AI_STATUS_OUT_WATER;
 809                                 else if(gco.z > this.origin.z)
 810                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 811                         }
 812                         else
 813                         {
 814                                 dir = flatdir;
 815                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 816                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 817                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 818                                 else
 819                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 820                         }
 821                 }
 822                 else
 823                 {
 824                         float s;
 825                         vector offset;
 826                         if(this.aistatus & AI_STATUS_OUT_WATER)
 827                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 828
 829                         // jump if going toward an obstacle that doesn't look like stairs we
 830                         // can walk up directly
 831                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 832                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 833                         if (trace_fraction < 1)
 834                         if (trace_plane_normal.z < 0.7)
 835                         {
 836                                 s = trace_fraction;
 837                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 838                                 if (trace_fraction < s + 0.01)
 839                                 if (trace_plane_normal.z < 0.7)
 840                                 {
 841                                         s = trace_fraction;
 842                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 843                                         if (trace_fraction > s)
 844                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 845                                 }
 846                         }
 847
 848                         // if bot for some reason doesn't get close to the current goal find another one
 849                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent) && !(this.goalcurrent.bot_pickup_respawning && this.goalcurrent_distance < 50))
 850                         if(havocbot_checkgoaldistance(this, gco))
 851                         {
 852                                 navigation_clearroute(this);
 853                                 this.bot_strategytime = 0;
 854                                 return;
 855                         }
 856
 857                         // Check for water/slime/lava and dangerous edges
 858                         // (only when the bot is on the ground or jumping intentionally)
 859
 860                         vector dst_ahead = this.origin + this.view_ofs + offset;
 861                         vector dst_down = dst_ahead - '0 0 3000';
 862                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 863
 864                         bool unreachable = false;
 865                         s = CONTENT_SOLID;
 866                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 867                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 868                         {
 869                                 // Look downwards
 870                                 traceline(dst_ahead , dst_down, true, NULL);
 871                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 872                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 873                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 874                                 {
 875                                         s = pointcontents(trace_endpos + '0 0 1');
 876                                         if (s != CONTENT_SOLID)
 877                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 878                                                 evadelava = normalize(this.velocity) * -1;
 879                                         else if (s == CONTENT_SKY)
 880                                                 evadeobstacle = normalize(this.velocity) * -1;
 881                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 882                                         {
 883                                                 // the traceline check isn't enough but is good as optimization,
 884                                                 // when not true (most of the time) this tracebox call is avoided
 885                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 886                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 887                                                 {
 888                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 889                                                         {
 890                                                                 // the goal is probably on an upper platform, assume bot can't get there
 891                                                                 unreachable = true;
 892                                                         }
 893                                                         else
 894                                                                 evadelava = normalize(this.velocity) * -1;
 895                                                 }
 896                                         }
 897                                 }
 898                         }
 899
 900                         dir = flatdir;
 901                         evadeobstacle.z = 0;
 902                         evadelava.z = 0;
 903                         makevectors(this.v_angle.y * '0 1 0');
 904
 905                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 906                         {
 907                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 908                                 if(IS_PLAYER(this.goalcurrent))
 909                                         unreachable = true;
 910                         }
 911                         if(unreachable)
 912                         {
 913                                 navigation_clearroute(this);
 914                                 this.bot_strategytime = 0;
 915                         }
 916                 }
 917
 918                 dodge = havocbot_dodge(this);
 919                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 920                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 921                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 922                 if(IS_PLAYER(trace_ent))
 923                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 924
 925                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 926         //      this.bot_dodgevector = dir;
 927         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 928         }
 929
 930         if(time < this.ladder_time)
 931         {
 932                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 933                 {
 934                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 935                                 dir.z = 1;
 936                 }
 937                 else
 938                 {
 939                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 940                                 dir.z = -1;
 941                 }
 942         }
 943
 944         //dir = this.bot_dodgevector;
 945         //if (this.bot_dodgevector_jumpbutton)
 946         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 947         CS(this).movement_x = dir * v_forward * maxspeed;
 948         CS(this).movement_y = dir * v_right * maxspeed;
 949         CS(this).movement_z = dir * v_up * maxspeed;
 950
 951         // Emulate keyboard interface
 952         if (skill < 10)
 953                 havocbot_keyboard_movement(this, destorg);
 954
 955         // Bunnyhop!
 956         //if(this.aistatus & AI_STATUS_ROAMING)
 957         if(!bunnyhop_forbidden && this.goalcurrent)
 958         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 959                 havocbot_bunnyhop(this, dir);
 960
 961         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
 962         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
 963         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
 964 }
 965
 966 entity havocbot_gettarget(entity this, bool secondary)
 967 {
 968         entity best = NULL;
 969         vector eye = CENTER_OR_VIEWOFS(this);
 970         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
 971         {
 972                 vector v = CENTER_OR_VIEWOFS(it);
 973                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 974                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
 975                 if(bot_shouldattack(this, it))
 976                 {
 977                         traceline(eye, v, true, this);
 978                         if (trace_ent == it || trace_fraction >= 1)
 979                                 best = it;
 980                 }
 981         });
 982
 983         return best;
 984 }
 985
 986 void havocbot_chooseenemy(entity this)
 987 {
 988         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 989         {
 990                 this.enemy = NULL;
 991                 return;
 992         }
 993         if (this.enemy)
 994         {
 995                 if (!bot_shouldattack(this, this.enemy))
 996                 {
 997                         // enemy died or something, find a new target
 998                         this.enemy = NULL;
 999                         this.havocbot_chooseenemy_finished = time;
1000                 }
1001                 else if (this.havocbot_stickenemy)
1002                 {
1003                         // tracking last chosen enemy
1004                         // if enemy is visible
1005                         // and not really really far away
1006                         // and we're not severely injured
1007                         // then keep tracking for a half second into the future
1008                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1009                         if (trace_ent == this.enemy || trace_fraction == 1)
1010                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1011                         if (this.health > 30)
1012                         {
1013                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1014                                 this.havocbot_chooseenemy_finished = time + 0.5;
1015                                 return;
1016                         }
1017                         // enemy isn't visible, or is far away, or we're injured severely
1018                         // so stop preferring this enemy
1019                         // (it will still take a half second until a new one is chosen)
1020                         this.havocbot_stickenemy = 0;
1021                 }
1022         }
1023         if (time < this.havocbot_chooseenemy_finished)
1024                 return;
1025         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1026         vector eye = this.origin + this.view_ofs;
1027         entity best = NULL;
1028         float bestrating = 100000000;
1029
1030         // Backup hit flags
1031         int hf = this.dphitcontentsmask;
1032
1033         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1034
1035         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1036
1037         bool scan_transparent = false;
1038         bool scan_secondary_targets = false;
1039         bool have_secondary_targets = false;
1040         while(true)
1041         {
1042                 scan_secondary_targets = false;
1043 LABEL(scan_targets)
1044                 IL_EACH(g_bot_targets, it.bot_attack,
1045                 {
1046                         if(!scan_secondary_targets)
1047                         {
1048                                 if(it.classname == "misc_breakablemodel")
1049                                 {
1050                                         have_secondary_targets = true;
1051                                         continue;
1052                                 }
1053                         }
1054                         else if(it.classname != "misc_breakablemodel")
1055                                 continue;
1056
1057                         vector v = (it.absmin + it.absmax) * 0.5;
1058                         float rating = vlen2(v - eye);
1059                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1060                         if (bestrating > rating)
1061                         if (bot_shouldattack(this, it))
1062                         {
1063                                 traceline(eye, v, true, this);
1064                                 if (trace_ent == it || trace_fraction >= 1)
1065                                 {
1066                                         best = it;
1067                                         bestrating = rating;
1068                                 }
1069                         }
1070                 });
1071
1072                 if(!best && have_secondary_targets && !scan_secondary_targets)
1073                 {
1074                         scan_secondary_targets = true;
1075                         // restart the loop
1076                         bestrating = 100000000;
1077                         goto scan_targets;
1078                 }
1079
1080                 // I want to do a second scan if no enemy was found or I don't have weapons
1081                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1082                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1083                         break;
1084                 if(scan_transparent)
1085                         break;
1086
1087                 // Set flags to see through transparent objects
1088                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1089
1090                 scan_transparent = true;
1091         }
1092
1093         // Restore hit flags
1094         this.dphitcontentsmask = hf;
1095
1096         this.enemy = best;
1097         this.havocbot_stickenemy = true;
1098         if(best && best.classname == "misc_breakablemodel")
1099                 this.havocbot_stickenemy = false;
1100 }
1101
1102 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1103 {
1104         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1105         // so skip this for them, or they'll never get to reload their weapons at all.
1106         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1107         if(skill < 5)
1108                 return false;
1109
1110         // if this weapon is scheduled for reloading, don't switch to it during combat
1111         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1112         {
1113                 FOREACH(Weapons, it != WEP_Null, {
1114                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1115                                 return true; // other weapon available
1116                 });
1117         }
1118
1119         return false;
1120 }
1121
1122 void havocbot_chooseweapon(entity this, .entity weaponentity)
1123 {
1124         int i;
1125
1126         // ;)
1127         if(g_weaponarena_weapons == WEPSET(TUBA))
1128         {
1129                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1130                 return;
1131         }
1132
1133         // TODO: clean this up by moving it to weapon code
1134         if(this.enemy==NULL)
1135         {
1136                 // If no weapon was chosen get the first available weapon
1137                 if(this.(weaponentity).m_weapon==WEP_Null)
1138                 FOREACH(Weapons, it != WEP_Null, {
1139                         if(client_hasweapon(this, it, weaponentity, true, false))
1140                         {
1141                                 this.(weaponentity).m_switchweapon = it;
1142                                 return;
1143                         }
1144                 });
1145                 return;
1146         }
1147
1148         // Do not change weapon during the next second after a combo
1149         float f = time - this.lastcombotime;
1150         if(f < 1)
1151                 return;
1152
1153         float w;
1154         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1155
1156         // Should it do a weapon combo?
1157         float af, ct, combo_time, combo;
1158
1159         af = ATTACK_FINISHED(this, 0);
1160         ct = autocvar_bot_ai_weapon_combo_threshold;
1161
1162         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1163         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1164         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1165
1166         combo = false;
1167
1168         if(autocvar_bot_ai_weapon_combo)
1169         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1170         if(af > combo_time)
1171         {
1172                 combo = true;
1173                 this.lastcombotime = time;
1174         }
1175
1176         distance *= (2 ** this.bot_rangepreference);
1177
1178         // Custom weapon list based on distance to the enemy
1179         if(bot_custom_weapon){
1180
1181                 // Choose weapons for far distance
1182                 if ( distance > bot_distance_far ) {
1183                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1184                                 w = bot_weapons_far[i];
1185                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1186                                 {
1187                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1188                                                 continue;
1189                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1190                                         return;
1191                                 }
1192                         }
1193                 }
1194
1195                 // Choose weapons for mid distance
1196                 if ( distance > bot_distance_close) {
1197                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1198                                 w = bot_weapons_mid[i];
1199                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1200                                 {
1201                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1202                                                 continue;
1203                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1204                                         return;
1205                                 }
1206                         }
1207                 }
1208
1209                 // Choose weapons for close distance
1210                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1211                         w = bot_weapons_close[i];
1212                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1213                         {
1214                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1215                                         continue;
1216                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1217                                 return;
1218                         }
1219                 }
1220         }
1221 }
1222
1223 void havocbot_aim(entity this)
1224 {
1225         if (time < this.nextaim)
1226                 return;
1227         this.nextaim = time + 0.1;
1228         vector myvel = this.velocity;
1229         if (!this.waterlevel)
1230                 myvel.z = 0;
1231         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1232         else if (this.enemy)
1233         {
1234                 vector enemyvel = this.enemy.velocity;
1235                 if (!this.enemy.waterlevel)
1236                         enemyvel.z = 0;
1237                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1238         }
1239         else
1240                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1241 }
1242
1243 bool havocbot_moveto_refresh_route(entity this)
1244 {
1245         // Refresh path to goal if necessary
1246         entity wp;
1247         wp = this.havocbot_personal_waypoint;
1248         navigation_goalrating_start(this);
1249         navigation_routerating(this, wp, 10000, 10000);
1250         navigation_goalrating_end(this);
1251         return (this.goalentity != NULL);
1252 }
1253
1254 float havocbot_moveto(entity this, vector pos)
1255 {
1256         entity wp;
1257
1258         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1259         {
1260                 // Step 4: Move to waypoint
1261                 if(this.havocbot_personal_waypoint==NULL)
1262                 {
1263                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1264                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1265                         return CMD_STATUS_ERROR;
1266                 }
1267
1268                 if (!bot_strategytoken_taken)
1269                 if(this.havocbot_personal_waypoint_searchtime<time)
1270                 {
1271                         bot_strategytoken_taken = true;
1272                         if(havocbot_moveto_refresh_route(this))
1273                         {
1274                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1275                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1276                                 this.havocbot_personal_waypoint_failcounter = 0;
1277                         }
1278                         else
1279                         {
1280                                 this.havocbot_personal_waypoint_failcounter += 1;
1281                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1282                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1283                                 {
1284                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1285                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1286                                         delete(this.havocbot_personal_waypoint);
1287                                         return CMD_STATUS_ERROR;
1288                                 }
1289                                 else
1290                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1291                         }
1292                 }
1293
1294                 if(autocvar_bot_debug_goalstack)
1295                         debuggoalstack(this);
1296
1297                 // Heading
1298                 vector dir = '0 0 0';
1299                 SET_DESTCOORDS(this.goalcurrent, this.origin, dir);
1300                 dir = dir - (this.origin + this.view_ofs);
1301                 dir.z = 0;
1302                 bot_aimdir(this, dir, -1);
1303
1304                 // Go!
1305                 havocbot_movetogoal(this);
1306
1307                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1308                 {
1309                         // Step 5: Waypoint reached
1310                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1311                         delete(this.havocbot_personal_waypoint);
1312                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1313                         return CMD_STATUS_FINISHED;
1314                 }
1315
1316                 return CMD_STATUS_EXECUTING;
1317         }
1318
1319         // Step 2: Linking waypoint
1320         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1321         {
1322                 // Wait until it is linked
1323                 if(!this.havocbot_personal_waypoint.wplinked)
1324                 {
1325                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1326                         return CMD_STATUS_EXECUTING;
1327                 }
1328
1329                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1330                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1331                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1332
1333                 // Step 3: Route to waypoint
1334                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1335
1336                 return CMD_STATUS_EXECUTING;
1337         }
1338
1339         // Step 1: Spawning waypoint
1340         wp = waypoint_spawnpersonal(this, pos);
1341         if(wp==NULL)
1342         {
1343                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1344                 return CMD_STATUS_ERROR;
1345         }
1346
1347         this.havocbot_personal_waypoint = wp;
1348         this.havocbot_personal_waypoint_failcounter = 0;
1349         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1350
1351         // if pos is inside a teleport, then let's mark it as teleport waypoint
1352         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1353         {
1354                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1355                 this.lastteleporttime = 0;
1356         });
1357
1358 /*
1359         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1360                 print("routing to a teleporter\n");
1361         else
1362                 print("routing to a non-teleporter\n");
1363 */
1364
1365         return CMD_STATUS_EXECUTING;
1366 }
1367
1368 float havocbot_resetgoal(entity this)
1369 {
1370         navigation_clearroute(this);
1371         return CMD_STATUS_FINISHED;
1372 }
1373
1374 void havocbot_setupbot(entity this)
1375 {
1376         this.bot_ai = havocbot_ai;
1377         this.cmd_moveto = havocbot_moveto;
1378         this.cmd_resetgoal = havocbot_resetgoal;
1379
1380         havocbot_chooserole(this);
1381 }
1382
1383 vector havocbot_dodge(entity this)
1384 {
1385         // LordHavoc: disabled because this is too expensive
1386         return '0 0 0';
1387 #if 0
1388         entity head;
1389         vector dodge, v, n;
1390         float danger, bestdanger, vl, d;
1391         dodge = '0 0 0';
1392         bestdanger = -20;
1393         // check for dangerous objects near bot or approaching bot
1394         head = findchainfloat(bot_dodge, true);
1395         while(head)
1396         {
1397                 if (head.owner != this)
1398                 {
1399                         vl = vlen(head.velocity);
1400                         if (vl > autocvar_sv_maxspeed * 0.3)
1401                         {
1402                                 n = normalize(head.velocity);
1403                                 v = this.origin - head.origin;
1404                                 d = v * n;
1405                                 if (d > (0 - head.bot_dodgerating))
1406                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1407                                 {
1408                                         // calculate direction and distance from the flight path, by removing the forward axis
1409                                         v = v - (n * (v * n));
1410                                         danger = head.bot_dodgerating - vlen(v);
1411                                         if (bestdanger < danger)
1412                                         {
1413                                                 bestdanger = danger;
1414                                                 // dodge to the side of the object
1415                                                 dodge = normalize(v);
1416                                         }
1417                                 }
1418                         }
1419                         else
1420                         {
1421                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1422                                 if (bestdanger < danger)
1423                                 {
1424                                         bestdanger = danger;
1425                                         dodge = normalize(this.origin - head.origin);
1426                                 }
1427                         }
1428                 }
1429                 head = head.chain;
1430         }
1431         return dodge;
1432 #endif
1433 }