qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/mapobjects/func/ladder.qh>
  22 #include <common/mapobjects/teleporters.qh>
  23 #include <common/mapobjects/trigger/jumppads.qh>
  24
  25 #include <lib/warpzone/common.qh>
  26
  27 .float speed;
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         if(bot_execute_commands(this))
  35                 return;
  36
  37         if (bot_strategytoken == this && !bot_strategytoken_taken)
  38         {
  39                 if(this.havocbot_blockhead)
  40                 {
  41                         this.havocbot_blockhead = false;
  42                 }
  43                 else
  44                 {
  45                         if (!this.jumppadcount && !STAT(FROZEN, this))
  46                                 this.havocbot_role(this); // little too far down the rabbit hole
  47                 }
  48
  49                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  50                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  51                 if(!this.goalcurrent)
  52                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  53                 {
  54                         // Look for the closest waypoint out of water
  55                         entity newgoal = NULL;
  56                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  57                         {
  58                                 if(it.origin.z < this.origin.z)
  59                                         continue;
  60
  61                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  62                                         continue;
  63
  64                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  65                                         continue;
  66
  67                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  68
  69                                 if(trace_fraction < 1)
  70                                         continue;
  71
  72                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  73                                         newgoal = it;
  74                         });
  75
  76                         if(newgoal)
  77                         {
  78                         //      te_wizspike(newgoal.origin);
  79                                 navigation_pushroute(this, newgoal);
  80                         }
  81                 }
  82
  83                 // token has been used this frame
  84                 bot_strategytoken_taken = true;
  85         }
  86
  87         if(IS_DEAD(this) || STAT(FROZEN, this))
  88         {
  89                 if (this.goalcurrent)
  90                         navigation_clearroute(this);
  91                 return;
  92         }
  93
  94         havocbot_chooseenemy(this);
  95
  96         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  97         {
  98                 .entity weaponentity = weaponentities[slot];
  99                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 100                 if(this.(weaponentity).bot_chooseweapontime < time)
 101                 {
 102                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 103                         havocbot_chooseweapon(this, weaponentity);
 104                 }
 105         }
 106         havocbot_aim(this);
 107         lag_update(this);
 108
 109         this.bot_aimdir_executed = false;
 110
 111         if (this.bot_aimtarg)
 112         {
 113                 this.aistatus |= AI_STATUS_ATTACKING;
 114                 this.aistatus &= ~AI_STATUS_ROAMING;
 115
 116                 if(STAT(WEAPONS, this))
 117                 {
 118                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 119                         {
 120                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 121                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 122                         }
 123                         else
 124                         {
 125                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 126                                 {
 127                                         .entity weaponentity = weaponentities[slot];
 128                                         Weapon w = this.(weaponentity).m_weapon;
 129                                         if(w == WEP_Null && slot != 0)
 130                                                 continue;
 131                                         w.wr_aim(w, this, weaponentity);
 132                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 133                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 134                                 }
 135                         }
 136                 }
 137                 else
 138                 {
 139                         if(IS_PLAYER(this.bot_aimtarg))
 140                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 141                 }
 142         }
 143         else if (this.goalcurrent)
 144         {
 145                 this.aistatus |= AI_STATUS_ROAMING;
 146                 this.aistatus &= ~AI_STATUS_ATTACKING;
 147         }
 148
 149         havocbot_movetogoal(this);
 150         if (!this.bot_aimdir_executed && this.goalcurrent)
 151         {
 152                 // Heading
 153                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 154                 dir -= this.origin + this.view_ofs;
 155                 dir.z = 0;
 156                 bot_aimdir(this, dir, -1);
 157         }
 158
 159         // if the bot is not attacking, consider reloading weapons
 160         if (!(this.aistatus & AI_STATUS_ATTACKING))
 161         {
 162                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 163                 {
 164                         .entity weaponentity = weaponentities[slot];
 165
 166                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 167                                 continue;
 168
 169                         // we are currently holding a weapon that's not fully loaded, reload it
 170                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 171                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 172                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 173
 174                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 175                         // the code above executes next frame, starting the reloading then
 176                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 177                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 178                         {
 179                                 FOREACH(Weapons, it != WEP_Null, {
 180                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 181                                         {
 182                                                 this.(weaponentity).m_switchweapon = it;
 183                                                 break;
 184                                         }
 185                                 });
 186                         }
 187                 }
 188         }
 189 }
 190
 191 void havocbot_keyboard_movement(entity this, vector destorg)
 192 {
 193         vector keyboard;
 194
 195         if (time > this.havocbot_keyboardtime)
 196         {
 197                 float sk = skill + this.bot_moveskill;
 198                 this.havocbot_keyboardtime =
 199                         max(
 200                                 this.havocbot_keyboardtime
 201                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 202                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 203                         , time);
 204                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 205
 206                 float trigger = autocvar_bot_ai_keyboard_threshold;
 207                 float trigger1 = -trigger;
 208
 209                 // categorize forward movement
 210                 // at skill < 1.5 only forward
 211                 // at skill < 2.5 only individual directions
 212                 // at skill < 4.5 only individual directions, and forward diagonals
 213                 // at skill >= 4.5, all cases allowed
 214                 if (keyboard.x > trigger)
 215                 {
 216                         keyboard.x = 1;
 217                         if (sk < 2.5)
 218                                 keyboard.y = 0;
 219                 }
 220                 else if (keyboard.x < trigger1 && sk > 1.5)
 221                 {
 222                         keyboard.x = -1;
 223                         if (sk < 4.5)
 224                                 keyboard.y = 0;
 225                 }
 226                 else
 227                 {
 228                         keyboard.x = 0;
 229                         if (sk < 1.5)
 230                                 keyboard.y = 0;
 231                 }
 232                 if (sk < 4.5)
 233                         keyboard.z = 0;
 234
 235                 if (keyboard.y > trigger)
 236                         keyboard.y = 1;
 237                 else if (keyboard.y < trigger1)
 238                         keyboard.y = -1;
 239                 else
 240                         keyboard.y = 0;
 241
 242                 if (keyboard.z > trigger)
 243                         keyboard.z = 1;
 244                 else if (keyboard.z < trigger1)
 245                         keyboard.z = -1;
 246                 else
 247                         keyboard.z = 0;
 248
 249                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 250                 if (this.havocbot_ducktime > time)
 251                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 252         }
 253
 254         keyboard = this.havocbot_keyboard;
 255         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 256         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 257         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 258 }
 259
 260 void havocbot_bunnyhop(entity this, vector dir)
 261 {
 262         float bunnyhopdistance;
 263         vector deviation;
 264         float maxspeed;
 265
 266         // Don't jump when attacking
 267         if(this.aistatus & AI_STATUS_ATTACKING)
 268                 return;
 269
 270         if(IS_PLAYER(this.goalcurrent))
 271                 return;
 272
 273         maxspeed = autocvar_sv_maxspeed;
 274
 275         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 276                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 277         {
 278                 this.aistatus &= ~AI_STATUS_RUNNING;
 279                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 280                 this.bot_canruntogoal = 0;
 281                 this.bot_timelastseengoal = 0;
 282                 return;
 283         }
 284
 285         if(this.waterlevel > WATERLEVEL_WETFEET)
 286         {
 287                 this.aistatus &= ~AI_STATUS_RUNNING;
 288                 return;
 289         }
 290
 291         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 292         {
 293                 this.bot_canruntogoal = 0;
 294                 this.bot_timelastseengoal = 0;
 295         }
 296
 297         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 298         bunnyhopdistance = vlen(this.origin - gco);
 299
 300         // Run only to visible goals
 301         if(IS_ONGROUND(this))
 302         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 303         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 304         {
 305                         this.bot_lastseengoal = this.goalcurrent;
 306
 307                         // seen it before
 308                         if(this.bot_timelastseengoal)
 309                         {
 310                                 // for a period of time
 311                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 312                                 {
 313                                         float checkdistance;
 314                                         checkdistance = true;
 315
 316                                         // don't run if it is too close
 317                                         if(this.bot_canruntogoal==0)
 318                                         {
 319                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 320                                                         this.bot_canruntogoal = 1;
 321                                                 else
 322                                                         this.bot_canruntogoal = -1;
 323                                         }
 324
 325                                         if(this.bot_canruntogoal != 1)
 326                                                 return;
 327
 328                                         if(this.aistatus & AI_STATUS_ROAMING)
 329                                         if(this.goalcurrent.classname=="waypoint")
 330                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 331                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 332                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 333                                         {
 334                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 335                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 336                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 337                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 338
 339                                                 if(fabs(deviation.y) < 20)
 340                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 341                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 342                                                 {
 343                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 344                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 345                                                         {
 346                                                                 checkdistance = false;
 347                                                         }
 348                                                 }
 349                                         }
 350
 351                                         if(checkdistance)
 352                                         {
 353                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 354                                                 // increase stop distance in case the goal is on a slope or a lower platform
 355                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 356                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 357                                         }
 358                                         else
 359                                         {
 360                                                 this.aistatus |= AI_STATUS_RUNNING;
 361                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 362                                         }
 363                                 }
 364                         }
 365                         else
 366                         {
 367                                 this.bot_timelastseengoal = time;
 368                         }
 369         }
 370         else
 371         {
 372                 this.bot_timelastseengoal = 0;
 373         }
 374
 375 #if 0
 376         // Release jump button
 377         if(!cvar("sv_pogostick"))
 378         if((IS_ONGROUND(this)) == 0)
 379         {
 380                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 381                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 382
 383                 // Strafe
 384                 if(this.aistatus & AI_STATUS_RUNNING)
 385                 if(vlen(this.velocity)>maxspeed)
 386                 {
 387                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 388                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 389                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 390
 391                         if(fabs(deviation.y)>10)
 392                                 CS(this).movement_x = 0;
 393
 394                         if(deviation.y>10)
 395                                 CS(this).movement_y = maxspeed * -1;
 396                         else if(deviation.y<10)
 397                                 CS(this).movement_y = maxspeed;
 398
 399                 }
 400         }
 401 #endif
 402 }
 403
 404 // return true when bot isn't getting closer to the current goal
 405 bool havocbot_checkgoaldistance(entity this, vector gco)
 406 {
 407         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 408         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 409         float distance_time = this.goalcurrent_distance_time;
 410         if(distance_time < 0)
 411                 distance_time = -distance_time;
 412         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 413         {
 414                 if(!distance_time)
 415                         this.goalcurrent_distance_time = time;
 416                 else if (time - distance_time > 0.5)
 417                         return true;
 418         }
 419         else
 420         {
 421                 // reduce it a little bit so it works even with very small approaches to the goal
 422                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 423                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 424                 this.goalcurrent_distance_time = 0;
 425         }
 426         return false;
 427 }
 428
 429 entity havocbot_select_an_item_of_group(entity this, int gr)
 430 {
 431         entity selected = NULL;
 432         float selected_dist2 = 0;
 433         // select farthest item of this group from bot's position
 434         IL_EACH(g_items, it.item_group == gr && it.solid,
 435         {
 436                 float dist2 = vlen2(this.origin - it.origin);
 437                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 438                 {
 439                         selected = it;
 440                         selected_dist2 = vlen2(this.origin - selected.origin);
 441                 }
 442         });
 443
 444         if (!selected)
 445                 return NULL;
 446
 447         set_tracewalk_dest(selected, this.origin, false);
 448         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 449                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 450         {
 451                 return NULL;
 452         }
 453
 454         return selected;
 455 }
 456
 457 void havocbot_movetogoal(entity this)
 458 {
 459         vector diff;
 460         vector dir;
 461         vector flatdir;
 462         vector evadeobstacle;
 463         vector evadelava;
 464         float dodge_enemy_factor = 1;
 465         float maxspeed;
 466         //float dist;
 467         vector dodge;
 468         //if (this.goalentity)
 469         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 470         CS(this).movement = '0 0 0';
 471         maxspeed = autocvar_sv_maxspeed;
 472
 473         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 474         // Jetpack navigation
 475         if(this.navigation_jetpack_goal)
 476         if(this.goalcurrent==this.navigation_jetpack_goal)
 477         if(GetResourceAmount(this, RESOURCE_FUEL))
 478         {
 479                 if(autocvar_bot_debug_goalstack)
 480                 {
 481                         debuggoalstack(this);
 482                         te_wizspike(this.navigation_jetpack_point);
 483                 }
 484
 485                 // Take off
 486                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 487                 {
 488                         // Brake almost completely so it can get a good direction
 489                         if(vdist(this.velocity, >, 10))
 490                                 return;
 491                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 492                 }
 493
 494                 makevectors(this.v_angle.y * '0 1 0');
 495                 dir = normalize(this.navigation_jetpack_point - this.origin);
 496
 497                 // Landing
 498                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 499                 {
 500                         // Calculate brake distance in xy
 501                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 502                         float vel2 = vlen2(vec2(this.velocity));
 503                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 504                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 505                         if(d < db || d < 500)
 506                         {
 507                                 // Brake
 508                                 if (vel2 > (maxspeed * 0.3) ** 2)
 509                                 {
 510                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 511                                         return;
 512                                 }
 513                                 // Switch to normal mode
 514                                 this.navigation_jetpack_goal = NULL;
 515                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 516                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 517                                 return;
 518                         }
 519                 }
 520                 else if(checkpvs(this.origin,this.goalcurrent))
 521                 {
 522                         // If I can see the goal switch to landing code
 523                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 524                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 525                         return;
 526                 }
 527
 528                 // Flying
 529                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 530                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 531                 {
 532                         CS(this).movement_x = dir * v_forward * maxspeed;
 533                         CS(this).movement_y = dir * v_right * maxspeed;
 534                 }
 535                 return;
 536         }
 537
 538         // Handling of jump pads
 539         if(this.jumppadcount)
 540         {
 541                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 542                 {
 543                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 544                         if(navigation_poptouchedgoals(this))
 545                                 return;
 546                 }
 547                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 548                 {
 549                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 550                         // but with some randomness so it can try out different paths
 551                         if(!this.goalcurrent)
 552                         {
 553                                 entity newgoal = NULL;
 554                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 555                                 {
 556                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 557                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 558                                                 continue;
 559
 560                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 561
 562                                         if(trace_fraction < 1)
 563                                                 continue;
 564
 565                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 566                                                 newgoal = it;
 567                                 });
 568
 569                                 if(newgoal)
 570                                 {
 571                                         this.ignoregoal = this.goalcurrent;
 572                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 573                                         navigation_clearroute(this);
 574                                         navigation_routetogoal(this, newgoal, this.origin);
 575                                         if(autocvar_bot_debug_goalstack)
 576                                                 debuggoalstack(this);
 577                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 578                                 }
 579                         }
 580                         else
 581                         {
 582                                 if (this.goalcurrent.bot_pickup)
 583                                 {
 584                                         entity jumppad_wp = this.goalcurrent_prev;
 585                                         navigation_poptouchedgoals(this);
 586                                         if(!this.goalcurrent && jumppad_wp.wp00)
 587                                         {
 588                                                 // head to the jumppad destination once bot reaches the goal item
 589                                                 navigation_pushroute(this, jumppad_wp.wp00);
 590                                         }
 591                                 }
 592                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 593                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 594                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 595                                 else if(havocbot_checkgoaldistance(this, gco))
 596                                 {
 597                                         navigation_clearroute(this);
 598                                         navigation_goalrating_timeout_force(this);
 599                                 }
 600                                 else
 601                                         return;
 602                         }
 603                 }
 604                 else
 605                 {
 606                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 607                         {
 608                                 vector velxy = this.velocity; velxy_z = 0;
 609                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 610                                 {
 611                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 612                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 613                                 }
 614                                 return;
 615                         }
 616
 617                         // Don't chase players while using a jump pad
 618                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 619                                 return;
 620                 }
 621         }
 622         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 623                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 624
 625         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 626         if (skill > 6 && !(IS_ONGROUND(this)))
 627         {
 628                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 629                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 630                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 631
 632                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 633                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 634                 if(this.items & IT_JETPACK)
 635                 {
 636                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 637                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 638                         {
 639                                 if(this.velocity.z<0)
 640                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 641                         }
 642                         else
 643                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 644
 645                         // If there is no goal try to move forward
 646
 647                         if(this.goalcurrent==NULL)
 648                                 dir = v_forward;
 649                         else
 650                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 651
 652                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 653                         float xyspeed = xyvelocity * dir;
 654
 655                         if(xyspeed < (maxspeed / 2))
 656                         {
 657                                 makevectors(this.v_angle.y * '0 1 0');
 658                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 659                                 if(trace_fraction==1)
 660                                 {
 661                                         CS(this).movement_x = dir * v_forward * maxspeed;
 662                                         CS(this).movement_y = dir * v_right * maxspeed;
 663                                         if (skill < 10)
 664                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 665                                 }
 666                         }
 667
 668                         this.havocbot_blockhead = true;
 669
 670                         return;
 671                 }
 672                 else if(GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR) > ROCKETJUMP_DAMAGE())
 673                 {
 674                         if(this.velocity.z < 0)
 675                         {
 676                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 677                                 {
 678                                         .entity weaponentity = weaponentities[slot];
 679
 680                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 681                                                 continue;
 682
 683                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 684                                         {
 685                                                 CS(this).movement_x = maxspeed;
 686
 687                                                 if(this.rocketjumptime)
 688                                                 {
 689                                                         if(time > this.rocketjumptime)
 690                                                         {
 691                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 692                                                                 this.rocketjumptime = 0;
 693                                                         }
 694                                                         return;
 695                                                 }
 696
 697                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 698                                                 this.v_angle_x = 90;
 699                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 700                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 701                                                 return;
 702                                         }
 703                                 }
 704                         }
 705                 }
 706                 else
 707                 {
 708                         // If there is no goal try to move forward
 709                         if(this.goalcurrent==NULL)
 710                                 CS(this).movement_x = maxspeed;
 711                 }
 712         }
 713
 714         // If we are under water with no goals, swim up
 715         if(this.waterlevel && !this.goalcurrent)
 716         {
 717                 dir = '0 0 0';
 718                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 719                         dir.z = 1;
 720                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 721                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 722                 else
 723                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 724                 makevectors(this.v_angle.y * '0 1 0');
 725                 vector v = dir * maxspeed;
 726                 CS(this).movement.x = v * v_forward;
 727                 CS(this).movement.y = v * v_right;
 728                 CS(this).movement.z = v * v_up;
 729         }
 730
 731         // if there is nowhere to go, exit
 732         if (this.goalcurrent == NULL)
 733                 return;
 734
 735
 736         bool locked_goal = false;
 737         if((this.goalentity && wasfreed(this.goalentity))
 738                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 739         {
 740                 navigation_clearroute(this);
 741                 navigation_goalrating_timeout_force(this);
 742                 return;
 743         }
 744         else if(this.goalentity.tag_entity)
 745         {
 746                 navigation_goalrating_timeout_expire(this, 2);
 747         }
 748         else if(this.goalentity.bot_pickup)
 749         {
 750                 if(this.goalentity.bot_pickup_respawning)
 751                 {
 752                         if(this.goalentity.solid) // item respawned
 753                                 this.goalentity.bot_pickup_respawning = false;
 754                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 755                         {
 756                                 if(checkpvs(this.origin, this.goalentity))
 757                                 {
 758                                         this.goalentity.bot_pickup_respawning = false;
 759                                         navigation_goalrating_timeout_expire(this, random());
 760                                 }
 761                                 locked_goal = true; // wait for item to respawn
 762                         }
 763                         else if(this.goalentity == this.goalcurrent)
 764                                 locked_goal = true; // wait for item to respawn
 765                 }
 766                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 767                 {
 768                         if(checkpvs(this.origin, this.goalentity))
 769                         {
 770                                 navigation_goalrating_timeout_expire(this, random());
 771                         }
 772                 }
 773         }
 774         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 775                 locked_goal = true;
 776
 777         if (navigation_shortenpath(this))
 778         {
 779                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 780                         && navigation_goalrating_timeout_can_be_anticipated(this))
 781                         navigation_goalrating_timeout_force(this);
 782         }
 783
 784         bool goalcurrent_can_be_removed = false;
 785         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 786         {
 787                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 788                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 789                 {
 790                         goalcurrent_can_be_removed = true;
 791                         // don't remove if not visible
 792                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 793                         {
 794                                 navigation_goalrating_timeout_force(this);
 795                                 return;
 796                         }
 797                 }
 798                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 799                 {
 800                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 801                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 802                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 803                         {
 804                                 navigation_goalrating_timeout_force(this);
 805                                 return;
 806                         }
 807                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 808                 }
 809         }
 810
 811         if(!locked_goal)
 812         {
 813                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 814                 // in this case path finding can start directly from a waypoint instead of
 815                 // looking for all the reachable waypoints up to a certain distance
 816                 if (navigation_poptouchedgoals(this))
 817                 {
 818                         if (this.goalcurrent)
 819                         {
 820                                 if (goalcurrent_can_be_removed)
 821                                 {
 822                                         // remove even if not visible
 823                                         navigation_goalrating_timeout_force(this);
 824                                         return;
 825                                 }
 826                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 827                                         navigation_goalrating_timeout_force(this);
 828                         }
 829                         else
 830                         {
 831                                 entity old_goal = this.goalcurrent_prev;
 832                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 833                                 {
 834                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 835                                         // item of the group by telling the bot to head directly to the farthest item.
 836                                         // Next time we let the bot select a goal as usual which can be another item
 837                                         // of this group (the closest one) and so on
 838                                         this.item_group = old_goal.item_group;
 839                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 840                                         if (new_goal)
 841                                                 navigation_pushroute(this, new_goal);
 842                                 }
 843                         }
 844                 }
 845         }
 846
 847         // if ran out of goals try to use an alternative goal or get a new strategy asap
 848         if(this.goalcurrent == NULL)
 849         {
 850                 navigation_goalrating_timeout_force(this);
 851                 return;
 852         }
 853
 854
 855         if(autocvar_bot_debug_goalstack)
 856                 debuggoalstack(this);
 857
 858         bool bunnyhop_forbidden = false;
 859         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 860         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 861         {
 862                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 863                 destorg = this.goalcurrent.origin;
 864         }
 865         else if (this.goalcurrent.wpisbox)
 866         {
 867                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 868                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 869                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 870                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 871                 {
 872                         bunnyhop_forbidden = true;
 873                         destorg = this.goalcurrent.origin;
 874                         if(destorg.z > this.origin.z)
 875                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 876                 }
 877         }
 878
 879         diff = destorg - this.origin;
 880
 881         if (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10))
 882         {
 883                 // stop if the locked goal has been reached
 884                 destorg = this.origin;
 885                 diff = dir = '0 0 0';
 886         }
 887         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 888         {
 889                 if (vdist(diff, <, 80))
 890                 {
 891                         // stop if too close to target player (even if frozen)
 892                         destorg = this.origin;
 893                         diff = dir = '0 0 0';
 894                 }
 895                 else
 896                 {
 897                         // move destorg out of target players, otherwise bot will consider them
 898                         // an obstacle that needs to be jumped (especially if frozen)
 899                         dir = normalize(diff);
 900                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 901                         diff = destorg - this.origin;
 902                 }
 903         }
 904         else
 905                 dir = normalize(diff);
 906         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 907
 908         //if (this.bot_dodgevector_time < time)
 909         {
 910                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 911                 //this.bot_dodgevector_jumpbutton = 1;
 912                 evadeobstacle = '0 0 0';
 913                 evadelava = '0 0 0';
 914
 915                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 916                 makevectors(this.v_angle.y * '0 1 0');
 917                 if (this.waterlevel > WATERLEVEL_WETFEET)
 918                 {
 919                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 920                         {
 921                                 if(!this.goalcurrent)
 922                                         this.aistatus |= AI_STATUS_OUT_WATER;
 923                                 else if(destorg.z > this.origin.z)
 924                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 925                         }
 926                         else
 927                         {
 928                                 dir = flatdir;
 929                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 930                                         (this.aistatus & AI_STATUS_OUT_WATER))
 931                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 932                                 else
 933                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 934                         }
 935                 }
 936                 else
 937                 {
 938                         float s;
 939                         vector offset;
 940                         if(this.aistatus & AI_STATUS_OUT_WATER)
 941                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 942
 943                         // jump if going toward an obstacle that doesn't look like stairs we
 944                         // can walk up directly
 945                         vector deviation = '0 0 0';
 946                         float current_speed = vlen(vec2(this.velocity));
 947                         if (current_speed < maxspeed * 0.2)
 948                                 current_speed = maxspeed * 0.2;
 949                         else
 950                         {
 951                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 952                                 while (deviation.y < -180) deviation.y += 360;
 953                                 while (deviation.y > 180) deviation.y -= 360;
 954                         }
 955                         float turning = false;
 956                         vector flat_diff = vec2(diff);
 957                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 958                         vector actual_destorg = this.origin + offset;
 959                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
 960                         {
 961                                 if (vlen2(flat_diff) < vlen2(offset))
 962                                 {
 963                                         actual_destorg.x = destorg.x;
 964                                         actual_destorg.y = destorg.y;
 965                                 }
 966                         }
 967                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 968                         {
 969                                 actual_destorg.x = destorg.x;
 970                                 actual_destorg.y = destorg.y;
 971                         }
 972                         else if (vlen2(flat_diff) < vlen2(offset))
 973                         {
 974                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 975                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 976                                 float dist = vlen(vec2(this.origin + offset - destorg));
 977                                 // if current and next goal are close to each other make sure
 978                                 // actual_destorg isn't set beyond next_goal_org
 979                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 980                                         actual_destorg = next_goal_org;
 981                                 else
 982                                         actual_destorg = vec2(destorg) + dist * next_dir;
 983                                 actual_destorg.z = this.origin.z;
 984                                 turning = true;
 985                         }
 986
 987                         LABEL(jump_check);
 988                         dir = flatdir = normalize(actual_destorg - this.origin);
 989
 990                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
 991                         {
 992                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
 993                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
 994                                 {
 995                                         s = trace_fraction;
 996                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
 997                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
 998                                         {
 999                                                 // found an obstacle
1000                                                 if (turning && fabs(deviation.y) > 5)
1001                                                 {
1002                                                         // check if the obstacle is still there without turning
1003                                                         actual_destorg = destorg;
1004                                                         turning = false;
1005                                                         this.bot_tracewalk_time = time + 0.25;
1006                                                         goto jump_check;
1007                                                 }
1008                                                 s = trace_fraction;
1009                                                 // don't artificially reduce max jump height in real-time
1010                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1011                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1012                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1013                                                 if (trace_fraction > s)
1014                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1015                                                 else
1016                                                 {
1017                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1018                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1019                                                         if (trace_fraction > s)
1020                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1021                                                 }
1022                                         }
1023                                 }
1024                         }
1025
1026                         // if bot for some reason doesn't get close to the current goal find another one
1027                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1028                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1029                         if(havocbot_checkgoaldistance(this, destorg))
1030                         {
1031                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1032                                 {
1033                                         navigation_clearroute(this);
1034                                         navigation_goalrating_timeout_force(this);
1035                                         return;
1036                                 }
1037
1038                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1039                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1040                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1041                                 {
1042                                         navigation_clearroute(this);
1043                                         navigation_goalrating_timeout_force(this);
1044                                         return;
1045                                 }
1046
1047                                 // give bot only another chance to prevent bot getting stuck
1048                                 // in case it thinks it can walk but actually can't
1049                                 this.goalcurrent_distance_z = FLOAT_MAX;
1050                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1051                                 this.goalcurrent_distance_time = -time; // mark second try
1052                         }
1053
1054                         // Check for water/slime/lava and dangerous edges
1055                         // (only when the bot is on the ground or jumping intentionally)
1056
1057                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
1058                         vector dst_ahead = this.origin + this.view_ofs + offset;
1059                         vector dst_down = dst_ahead - '0 0 3000';
1060                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1061
1062                         bool unreachable = false;
1063                         s = CONTENT_SOLID;
1064                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1065                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1066                         {
1067                                 // Look downwards
1068                                 traceline(dst_ahead , dst_down, true, NULL);
1069                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1070                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
1071                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1072                                 {
1073                                         s = pointcontents(trace_endpos + '0 0 1');
1074                                         if (s != CONTENT_SOLID)
1075                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1076                                                 evadelava = normalize(this.velocity) * -1;
1077                                         else if (s == CONTENT_SKY)
1078                                                 evadeobstacle = normalize(this.velocity) * -1;
1079                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1080                                         {
1081                                                 // the traceline check isn't enough but is good as optimization,
1082                                                 // when not true (most of the time) this tracebox call is avoided
1083                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1084                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1085                                                 {
1086                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1087                                                         {
1088                                                                 // the goal is probably on an upper platform, assume bot can't get there
1089                                                                 unreachable = true;
1090                                                         }
1091                                                         else
1092                                                                 evadelava = normalize(this.velocity) * -1;
1093                                                 }
1094                                         }
1095                                 }
1096                         }
1097
1098                         dir = flatdir;
1099                         evadeobstacle.z = 0;
1100                         evadelava.z = 0;
1101                         makevectors(this.v_angle.y * '0 1 0');
1102
1103                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1104                         {
1105                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1106                                 if(IS_PLAYER(this.goalcurrent))
1107                                         unreachable = true;
1108                         }
1109
1110                         // slow down if bot is in the air and goal is under it
1111                         if (!this.goalcurrent.wphardwired
1112                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1113                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1114                         {
1115                                 // tracebox wouldn't work when bot is still on the ledge
1116                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1117                                 if (this.origin.z - trace_endpos.z > 120)
1118                                         evadeobstacle = normalize(this.velocity) * -1;
1119                         }
1120
1121                         if(unreachable)
1122                         {
1123                                 navigation_clearroute(this);
1124                                 navigation_goalrating_timeout_force(this);
1125                                 this.ignoregoal = this.goalcurrent;
1126                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1127                         }
1128                 }
1129
1130                 dodge = havocbot_dodge(this);
1131                 if (dodge)
1132                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1133                 dodge += evadeobstacle + evadelava;
1134                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1135                 if (this.enemy)
1136                 {
1137                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1138                         if (IS_PLAYER(trace_ent))
1139                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1140                 }
1141         //      this.bot_dodgevector = dir;
1142         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1143         }
1144
1145         float ladder_zdir = 0;
1146         if(time < this.ladder_time)
1147         {
1148                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1149                 {
1150                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1151                                 ladder_zdir = 1;
1152                 }
1153                 else
1154                 {
1155                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1156                                 ladder_zdir = -1;
1157                 }
1158                 if (ladder_zdir)
1159                 {
1160                         if (vdist(flatdir, <, 15))
1161                                 dir = ladder_zdir * '0 0 1';
1162                         else
1163                         {
1164                                 dir.z = ladder_zdir * 1.3;
1165                                 dir = normalize(dir);
1166                         }
1167                 }
1168         }
1169
1170         if (this.goalcurrent.wpisbox
1171                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1172         {
1173                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1174                 // head to teleport origin
1175                 dir = (this.goalcurrent.origin - this.origin);
1176                 dir.z = 0;
1177                 dir = normalize(dir);
1178         }
1179
1180         if (!this.bot_aimdir_executed)
1181                 bot_aimdir(this, dir, -1);
1182
1183         if (!ladder_zdir)
1184         {
1185                 dir *= dodge_enemy_factor;
1186                 dir = normalize(dir + dodge);
1187         }
1188
1189         //dir = this.bot_dodgevector;
1190         //if (this.bot_dodgevector_jumpbutton)
1191         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1192         CS(this).movement_x = dir * v_forward * maxspeed;
1193         CS(this).movement_y = dir * v_right * maxspeed;
1194         CS(this).movement_z = dir * v_up * maxspeed;
1195
1196         // Emulate keyboard interface
1197         if (skill < 10)
1198                 havocbot_keyboard_movement(this, destorg);
1199
1200         // Bunnyhop!
1201         //if(this.aistatus & AI_STATUS_ROAMING)
1202         if(!bunnyhop_forbidden && this.goalcurrent)
1203         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1204                 havocbot_bunnyhop(this, dir);
1205
1206         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1207         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1208         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1209 }
1210
1211 entity havocbot_gettarget(entity this, bool secondary)
1212 {
1213         entity best = NULL;
1214         vector eye = CENTER_OR_VIEWOFS(this);
1215         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1216         {
1217                 vector v = CENTER_OR_VIEWOFS(it);
1218                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1219                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1220                 if(bot_shouldattack(this, it))
1221                 {
1222                         traceline(eye, v, true, this);
1223                         if (trace_ent == it || trace_fraction >= 1)
1224                                 best = it;
1225                 }
1226         });
1227
1228         return best;
1229 }
1230
1231 void havocbot_chooseenemy(entity this)
1232 {
1233         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1234         {
1235                 this.enemy = NULL;
1236                 return;
1237         }
1238         if (this.enemy)
1239         {
1240                 if (!bot_shouldattack(this, this.enemy))
1241                 {
1242                         // enemy died or something, find a new target
1243                         this.enemy = NULL;
1244                         this.havocbot_chooseenemy_finished = time;
1245                 }
1246                 else if (this.havocbot_stickenemy)
1247                 {
1248                         // tracking last chosen enemy
1249                         // if enemy is visible
1250                         // and not really really far away
1251                         // and we're not severely injured
1252                         // then keep tracking for a half second into the future
1253                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1254                         if (trace_ent == this.enemy || trace_fraction == 1)
1255                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1256                         if (GetResourceAmount(this, RESOURCE_HEALTH) > 30)
1257                         {
1258                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1259                                 this.havocbot_chooseenemy_finished = time + 0.5;
1260                                 return;
1261                         }
1262                         // enemy isn't visible, or is far away, or we're injured severely
1263                         // so stop preferring this enemy
1264                         // (it will still take a half second until a new one is chosen)
1265                         this.havocbot_stickenemy = 0;
1266                 }
1267         }
1268         if (time < this.havocbot_chooseenemy_finished)
1269                 return;
1270         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1271         vector eye = this.origin + this.view_ofs;
1272         entity best = NULL;
1273         float bestrating = 100000000;
1274
1275         // Backup hit flags
1276         int hf = this.dphitcontentsmask;
1277
1278         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1279
1280         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1281
1282         bool scan_transparent = false;
1283         bool scan_secondary_targets = false;
1284         bool have_secondary_targets = false;
1285         while(true)
1286         {
1287                 scan_secondary_targets = false;
1288 LABEL(scan_targets)
1289                 IL_EACH(g_bot_targets, it.bot_attack,
1290                 {
1291                         if(!scan_secondary_targets)
1292                         {
1293                                 if(it.classname == "misc_breakablemodel")
1294                                 {
1295                                         have_secondary_targets = true;
1296                                         continue;
1297                                 }
1298                         }
1299                         else if(it.classname != "misc_breakablemodel")
1300                                 continue;
1301
1302                         vector v = (it.absmin + it.absmax) * 0.5;
1303                         float rating = vlen2(v - eye);
1304                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1305                         if (bestrating > rating)
1306                         if (bot_shouldattack(this, it))
1307                         {
1308                                 traceline(eye, v, true, this);
1309                                 if (trace_ent == it || trace_fraction >= 1)
1310                                 {
1311                                         best = it;
1312                                         bestrating = rating;
1313                                 }
1314                         }
1315                 });
1316
1317                 if(!best && have_secondary_targets && !scan_secondary_targets)
1318                 {
1319                         scan_secondary_targets = true;
1320                         // restart the loop
1321                         bestrating = 100000000;
1322                         goto scan_targets;
1323                 }
1324
1325                 // I want to do a second scan if no enemy was found or I don't have weapons
1326                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1327                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1328                         break;
1329                 if(scan_transparent)
1330                         break;
1331
1332                 // Set flags to see through transparent objects
1333                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1334
1335                 scan_transparent = true;
1336         }
1337
1338         // Restore hit flags
1339         this.dphitcontentsmask = hf;
1340
1341         this.enemy = best;
1342         this.havocbot_stickenemy = true;
1343         if(best && best.classname == "misc_breakablemodel")
1344                 this.havocbot_stickenemy = false;
1345 }
1346
1347 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1348 {
1349         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1350         // so skip this for them, or they'll never get to reload their weapons at all.
1351         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1352         if(skill < 5)
1353                 return false;
1354
1355         // if this weapon is scheduled for reloading, don't switch to it during combat
1356         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1357         {
1358                 FOREACH(Weapons, it != WEP_Null, {
1359                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1360                                 return true; // other weapon available
1361                 });
1362         }
1363
1364         return false;
1365 }
1366
1367 void havocbot_chooseweapon(entity this, .entity weaponentity)
1368 {
1369         int i;
1370
1371         // ;)
1372         if(g_weaponarena_weapons == WEPSET(TUBA))
1373         {
1374                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1375                 return;
1376         }
1377
1378         // TODO: clean this up by moving it to weapon code
1379         if(this.enemy==NULL)
1380         {
1381                 // If no weapon was chosen get the first available weapon
1382                 if(this.(weaponentity).m_weapon==WEP_Null)
1383                 FOREACH(Weapons, it != WEP_Null, {
1384                         if(client_hasweapon(this, it, weaponentity, true, false))
1385                         {
1386                                 this.(weaponentity).m_switchweapon = it;
1387                                 return;
1388                         }
1389                 });
1390                 return;
1391         }
1392
1393         // Do not change weapon during the next second after a combo
1394         float f = time - this.lastcombotime;
1395         if(f < 1)
1396                 return;
1397
1398         float w;
1399         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1400
1401         // Should it do a weapon combo?
1402         float af, ct, combo_time, combo;
1403
1404         af = ATTACK_FINISHED(this, 0);
1405         ct = autocvar_bot_ai_weapon_combo_threshold;
1406
1407         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1408         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1409         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1410
1411         combo = false;
1412
1413         if(autocvar_bot_ai_weapon_combo)
1414         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1415         if(af > combo_time)
1416         {
1417                 combo = true;
1418                 this.lastcombotime = time;
1419         }
1420
1421         distance *= (2 ** this.bot_rangepreference);
1422
1423         // Custom weapon list based on distance to the enemy
1424         if(bot_custom_weapon){
1425
1426                 // Choose weapons for far distance
1427                 if ( distance > bot_distance_far ) {
1428                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1429                                 w = bot_weapons_far[i];
1430                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1431                                 {
1432                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1433                                                 continue;
1434                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1435                                         return;
1436                                 }
1437                         }
1438                 }
1439
1440                 // Choose weapons for mid distance
1441                 if ( distance > bot_distance_close) {
1442                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1443                                 w = bot_weapons_mid[i];
1444                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1445                                 {
1446                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1447                                                 continue;
1448                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1449                                         return;
1450                                 }
1451                         }
1452                 }
1453
1454                 // Choose weapons for close distance
1455                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1456                         w = bot_weapons_close[i];
1457                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1458                         {
1459                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1460                                         continue;
1461                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1462                                 return;
1463                         }
1464                 }
1465         }
1466 }
1467
1468 void havocbot_aim(entity this)
1469 {
1470         if (time < this.nextaim)
1471                 return;
1472         this.nextaim = time + 0.1;
1473         vector myvel = this.velocity;
1474         if (!this.waterlevel)
1475                 myvel.z = 0;
1476         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1477         else if (this.enemy)
1478         {
1479                 vector enemyvel = this.enemy.velocity;
1480                 if (!this.enemy.waterlevel)
1481                         enemyvel.z = 0;
1482                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1483         }
1484         else
1485                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1486 }
1487
1488 bool havocbot_moveto_refresh_route(entity this)
1489 {
1490         // Refresh path to goal if necessary
1491         entity wp;
1492         wp = this.havocbot_personal_waypoint;
1493         navigation_goalrating_start(this);
1494         navigation_routerating(this, wp, 10000, 10000);
1495         navigation_goalrating_end(this);
1496         return (this.goalentity != NULL);
1497 }
1498
1499 float havocbot_moveto(entity this, vector pos)
1500 {
1501         entity wp;
1502
1503         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1504         {
1505                 // Step 4: Move to waypoint
1506                 if(this.havocbot_personal_waypoint==NULL)
1507                 {
1508                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1509                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1510                         return CMD_STATUS_ERROR;
1511                 }
1512
1513                 if (!bot_strategytoken_taken)
1514                 if(this.havocbot_personal_waypoint_searchtime<time)
1515                 {
1516                         bot_strategytoken_taken = true;
1517                         if(havocbot_moveto_refresh_route(this))
1518                         {
1519                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1520                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1521                                 this.havocbot_personal_waypoint_failcounter = 0;
1522                         }
1523                         else
1524                         {
1525                                 this.havocbot_personal_waypoint_failcounter += 1;
1526                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1527                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1528                                 {
1529                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1530                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1531                                         delete(this.havocbot_personal_waypoint);
1532                                         return CMD_STATUS_ERROR;
1533                                 }
1534                                 else
1535                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1536                         }
1537                 }
1538
1539                 if(autocvar_bot_debug_goalstack)
1540                         debuggoalstack(this);
1541
1542
1543                 // Go!
1544                 havocbot_movetogoal(this);
1545
1546                 if (!this.bot_aimdir_executed && this.goalcurrent)
1547                 {
1548                         // Heading
1549                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1550                         dir -= this.origin + this.view_ofs;
1551                         dir.z = 0;
1552                         bot_aimdir(this, dir, -1);
1553                 }
1554
1555                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1556                 {
1557                         // Step 5: Waypoint reached
1558                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1559                         delete(this.havocbot_personal_waypoint);
1560                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1561                         return CMD_STATUS_FINISHED;
1562                 }
1563
1564                 return CMD_STATUS_EXECUTING;
1565         }
1566
1567         // Step 2: Linking waypoint
1568         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1569         {
1570                 // Wait until it is linked
1571                 if(!this.havocbot_personal_waypoint.wplinked)
1572                 {
1573                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1574                         return CMD_STATUS_EXECUTING;
1575                 }
1576
1577                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1578                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1579                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1580
1581                 // Step 3: Route to waypoint
1582                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1583
1584                 return CMD_STATUS_EXECUTING;
1585         }
1586
1587         // Step 1: Spawning waypoint
1588         wp = waypoint_spawnpersonal(this, pos);
1589         if(wp==NULL)
1590         {
1591                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1592                 return CMD_STATUS_ERROR;
1593         }
1594
1595         this.havocbot_personal_waypoint = wp;
1596         this.havocbot_personal_waypoint_failcounter = 0;
1597         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1598
1599         // if pos is inside a teleport, then let's mark it as teleport waypoint
1600         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1601         {
1602                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1603                 this.lastteleporttime = 0;
1604         });
1605
1606 /*
1607         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1608                 print("routing to a teleporter\n");
1609         else
1610                 print("routing to a non-teleporter\n");
1611 */
1612
1613         return CMD_STATUS_EXECUTING;
1614 }
1615
1616 float havocbot_resetgoal(entity this)
1617 {
1618         navigation_clearroute(this);
1619         return CMD_STATUS_FINISHED;
1620 }
1621
1622 void havocbot_setupbot(entity this)
1623 {
1624         this.bot_ai = havocbot_ai;
1625         this.cmd_moveto = havocbot_moveto;
1626         this.cmd_resetgoal = havocbot_resetgoal;
1627
1628         // NOTE: bot is not player yet
1629         havocbot_chooserole(this);
1630 }
1631
1632 vector havocbot_dodge(entity this)
1633 {
1634         // LordHavoc: disabled because this is too expensive
1635         return '0 0 0';
1636 #if 0
1637         entity head;
1638         vector dodge, v, n;
1639         float danger, bestdanger, vl, d;
1640         dodge = '0 0 0';
1641         bestdanger = -20;
1642         // check for dangerous objects near bot or approaching bot
1643         head = findchainfloat(bot_dodge, true);
1644         while(head)
1645         {
1646                 if (head.owner != this)
1647                 {
1648                         vl = vlen(head.velocity);
1649                         if (vl > autocvar_sv_maxspeed * 0.3)
1650                         {
1651                                 n = normalize(head.velocity);
1652                                 v = this.origin - head.origin;
1653                                 d = v * n;
1654                                 if (d > (0 - head.bot_dodgerating))
1655                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1656                                 {
1657                                         // calculate direction and distance from the flight path, by removing the forward axis
1658                                         v = v - (n * (v * n));
1659                                         danger = head.bot_dodgerating - vlen(v);
1660                                         if (bestdanger < danger)
1661                                         {
1662                                                 bestdanger = danger;
1663                                                 // dodge to the side of the object
1664                                                 dodge = normalize(v);
1665                                         }
1666                                 }
1667                         }
1668                         else
1669                         {
1670                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1671                                 if (bestdanger < danger)
1672                                 {
1673                                         bestdanger = danger;
1674                                         dodge = normalize(this.origin - head.origin);
1675                                 }
1676                         }
1677                 }
1678                 head = head.chain;
1679         }
1680         return dodge;
1681 #endif
1682 }