qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/defs.qh>
   6 #include <server/miscfunctions.qh>
   7 #include "../cvars.qh"
   8
   9 #include "../aim.qh"
  10 #include "../bot.qh"
  11 #include "../navigation.qh"
  12 #include "../scripting.qh"
  13 #include "../waypoints.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/impulses/all.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19 #include <common/state.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/wepent.qh>
  22
  23 #include <common/mapobjects/func/ladder.qh>
  24 #include <common/mapobjects/teleporters.qh>
  25 #include <common/mapobjects/trigger/jumppads.qh>
  26
  27 #include <lib/warpzone/common.qh>
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if (this.goalcurrent && wasfreed(this.goalcurrent))
  93         {
  94                 navigation_clearroute(this);
  95                 navigation_goalrating_timeout_force(this);
  96                 return;
  97         }
  98
  99         if(IS_DEAD(this) || STAT(FROZEN, this))
 100         {
 101                 if (this.goalcurrent)
 102                         navigation_clearroute(this);
 103                 return;
 104         }
 105
 106         havocbot_chooseenemy(this);
 107
 108         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 109         {
 110                 .entity weaponentity = weaponentities[slot];
 111                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 112                 if(this.(weaponentity).bot_chooseweapontime < time)
 113                 {
 114                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 115                         havocbot_chooseweapon(this, weaponentity);
 116                 }
 117         }
 118         havocbot_aim(this);
 119         lag_update(this);
 120
 121         if (this.bot_aimtarg)
 122         {
 123                 this.aistatus |= AI_STATUS_ATTACKING;
 124                 this.aistatus &= ~AI_STATUS_ROAMING;
 125
 126                 if(STAT(WEAPONS, this))
 127                 {
 128                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 129                         {
 130                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 131                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 132                         }
 133                         else
 134                         {
 135                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 136                                 {
 137                                         .entity weaponentity = weaponentities[slot];
 138                                         Weapon w = this.(weaponentity).m_weapon;
 139                                         if(w == WEP_Null && slot != 0)
 140                                                 continue;
 141                                         w.wr_aim(w, this, weaponentity);
 142                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 143                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 144                                 }
 145                         }
 146                 }
 147                 else
 148                 {
 149                         if(IS_PLAYER(this.bot_aimtarg))
 150                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 151                 }
 152         }
 153         else if (this.goalcurrent)
 154         {
 155                 this.aistatus |= AI_STATUS_ROAMING;
 156                 this.aistatus &= ~AI_STATUS_ATTACKING;
 157         }
 158
 159         havocbot_movetogoal(this);
 160         if (!this.bot_aimdir_executed && this.goalcurrent)
 161         {
 162                 // Heading
 163                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 164                 dir -= this.origin + this.view_ofs;
 165                 dir.z = 0;
 166                 bot_aimdir(this, dir, 0);
 167         }
 168
 169         // if the bot is not attacking, consider reloading weapons
 170         if (!(this.aistatus & AI_STATUS_ATTACKING))
 171         {
 172                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 173                 {
 174                         .entity weaponentity = weaponentities[slot];
 175
 176                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 177                                 continue;
 178
 179                         // we are currently holding a weapon that's not fully loaded, reload it
 180                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 181                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 182                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 183
 184                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 185                         // the code above executes next frame, starting the reloading then
 186                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 187                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 188                         {
 189                                 FOREACH(Weapons, it != WEP_Null, {
 190                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 191                                         {
 192                                                 this.(weaponentity).m_switchweapon = it;
 193                                                 break;
 194                                         }
 195                                 });
 196                         }
 197                 }
 198         }
 199 }
 200
 201 void havocbot_bunnyhop(entity this, vector dir)
 202 {
 203         bool can_run = false;
 204         if (!(this.aistatus & AI_STATUS_ATTACKING) && this.goalcurrent && !IS_PLAYER(this.goalcurrent)
 205                 && vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed) && !(this.aistatus & AI_STATUS_DANGER_AHEAD)
 206                 && this.waterlevel <= WATERLEVEL_WETFEET && !IS_DUCKED(this)
 207                 && IS_ONGROUND(this) && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
 208         {
 209                 vector vel_angles = vectoangles(this.velocity);
 210                 vector deviation = vel_angles - vectoangles(dir);
 211                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 212                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 213                 if (fabs(deviation.y) < autocvar_bot_ai_bunnyhop_dir_deviation_max)
 214                 {
 215                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 216                         float vel = vlen(vec2(this.velocity));
 217
 218                         // with the current physics, jump distance grows linearly with the speed
 219                         float jump_distance = 52.661 + 0.606 * vel;
 220                         jump_distance += this.origin.z - gco.z; // roughly take into account vertical distance too
 221                         if (vdist(vec2(gco - this.origin), >, max(0, jump_distance)))
 222                                 can_run = true;
 223                         else if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP)
 224                                 && !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 225                                 && this.goalstack01 && !wasfreed(this.goalstack01) && !(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP)
 226                                 && vdist(vec2(gco - this.goalstack01.origin), >, 70))
 227                         {
 228                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 229                                 vector ang = vectoangles(gco - this.origin);
 230                                 deviation = vectoangles(gno - gco) - vel_angles;
 231                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 232                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 233
 234                                 float max_turn_angle = autocvar_bot_ai_bunnyhop_turn_angle_max;
 235                                 max_turn_angle -= autocvar_bot_ai_bunnyhop_turn_angle_reduction * ((vel - autocvar_sv_maxspeed) / autocvar_sv_maxspeed);
 236                                 if ((ang.x < 90 || ang.x > 360 - autocvar_bot_ai_bunnyhop_downward_pitch_max)
 237                                         && fabs(deviation.y) < max(autocvar_bot_ai_bunnyhop_turn_angle_min, max_turn_angle))
 238                                 {
 239                                         can_run = true;
 240                                 }
 241                         }
 242                 }
 243         }
 244
 245         if (can_run)
 246         {
 247                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 248                 this.aistatus |= AI_STATUS_RUNNING;
 249         }
 250         else
 251         {
 252                 if (IS_ONGROUND(this) || this.waterlevel > WATERLEVEL_WETFEET)
 253                         this.aistatus &= ~AI_STATUS_RUNNING;
 254         }
 255 }
 256
 257 void havocbot_keyboard_movement(entity this, vector destorg)
 258 {
 259         if(time <= this.havocbot_keyboardtime)
 260                 return;
 261
 262         float sk = skill + this.bot_moveskill;
 263         this.havocbot_keyboardtime =
 264                 max(
 265                         this.havocbot_keyboardtime
 266                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 267                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 268                 , time);
 269         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 270
 271         float trigger = autocvar_bot_ai_keyboard_threshold;
 272
 273         // categorize forward movement
 274         // at skill < 1.5 only forward
 275         // at skill < 2.5 only individual directions
 276         // at skill < 4.5 only individual directions, and forward diagonals
 277         // at skill >= 4.5, all cases allowed
 278         if (keyboard.x > trigger)
 279         {
 280                 keyboard.x = 1;
 281                 if (sk < 2.5)
 282                         keyboard.y = 0;
 283         }
 284         else if (keyboard.x < -trigger && sk > 1.5)
 285         {
 286                 keyboard.x = -1;
 287                 if (sk < 4.5)
 288                         keyboard.y = 0;
 289         }
 290         else
 291         {
 292                 keyboard.x = 0;
 293                 if (sk < 1.5)
 294                         keyboard.y = 0;
 295         }
 296         if (sk < 4.5)
 297                 keyboard.z = 0;
 298
 299         if (keyboard.y > trigger)
 300                 keyboard.y = 1;
 301         else if (keyboard.y < -trigger)
 302                 keyboard.y = -1;
 303         else
 304                 keyboard.y = 0;
 305
 306         if (keyboard.z > trigger)
 307                 keyboard.z = 1;
 308         else if (keyboard.z < -trigger)
 309                 keyboard.z = -1;
 310         else
 311                 keyboard.z = 0;
 312
 313         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 314         if (keyboard == '0 0 0')
 315                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 316
 317         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 318         if (this.havocbot_ducktime > time)
 319                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 320
 321         keyboard = this.havocbot_keyboard;
 322         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 323         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 324         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 325 }
 326
 327 // return true when bot isn't getting closer to the current goal
 328 bool havocbot_checkgoaldistance(entity this, vector gco)
 329 {
 330         if (this.bot_stop_moving_timeout > time)
 331                 return false;
 332         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 333         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 334         float distance_time = this.goalcurrent_distance_time;
 335         if(distance_time < 0)
 336                 distance_time = -distance_time;
 337         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 338         {
 339                 if(!distance_time)
 340                         this.goalcurrent_distance_time = time;
 341                 else if (time - distance_time > 0.5)
 342                         return true;
 343         }
 344         else
 345         {
 346                 // reduce it a little bit so it works even with very small approaches to the goal
 347                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 348                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 349                 this.goalcurrent_distance_time = 0;
 350         }
 351         return false;
 352 }
 353
 354 entity havocbot_select_an_item_of_group(entity this, int gr)
 355 {
 356         entity selected = NULL;
 357         float selected_dist2 = 0;
 358         // select farthest item of this group from bot's position
 359         IL_EACH(g_items, it.item_group == gr && it.solid,
 360         {
 361                 float dist2 = vlen2(this.origin - it.origin);
 362                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 363                 {
 364                         selected = it;
 365                         selected_dist2 = vlen2(this.origin - selected.origin);
 366                 }
 367         });
 368
 369         if (!selected)
 370                 return NULL;
 371
 372         set_tracewalk_dest(selected, this.origin, false);
 373         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 374                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 375         {
 376                 return NULL;
 377         }
 378
 379         return selected;
 380 }
 381
 382 void havocbot_movetogoal(entity this)
 383 {
 384         vector diff;
 385         vector dir;
 386         vector flatdir;
 387         float dodge_enemy_factor = 1;
 388         float maxspeed;
 389         //float dist;
 390         vector dodge;
 391         //if (this.goalentity)
 392         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 393         CS(this).movement = '0 0 0';
 394         maxspeed = autocvar_sv_maxspeed;
 395
 396         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 397
 398         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 399         // Jetpack navigation
 400         if(this.navigation_jetpack_goal)
 401         if(this.goalcurrent==this.navigation_jetpack_goal)
 402         if(GetResource(this, RES_FUEL))
 403         {
 404                 if(autocvar_bot_debug_goalstack)
 405                 {
 406                         debuggoalstack(this);
 407                         te_wizspike(this.navigation_jetpack_point);
 408                 }
 409
 410                 // Take off
 411                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 412                 {
 413                         // Brake almost completely so it can get a good direction
 414                         if(vdist(this.velocity, >, 10))
 415                                 return;
 416                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 417                 }
 418
 419                 makevectors(this.v_angle.y * '0 1 0');
 420                 dir = normalize(this.navigation_jetpack_point - this.origin);
 421
 422                 // Landing
 423                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 424                 {
 425                         // Calculate brake distance in xy
 426                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 427                         float vel2 = vlen2(vec2(this.velocity));
 428                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 429                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 430                         if(d < db || d < 500)
 431                         {
 432                                 // Brake
 433                                 if (vel2 > (maxspeed * 0.3) ** 2)
 434                                 {
 435                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 436                                         return;
 437                                 }
 438                                 // Switch to normal mode
 439                                 this.navigation_jetpack_goal = NULL;
 440                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 441                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 442                                 return;
 443                         }
 444                 }
 445                 else if(checkpvs(this.origin,this.goalcurrent))
 446                 {
 447                         // If I can see the goal switch to landing code
 448                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 449                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 450                         return;
 451                 }
 452
 453                 // Flying
 454                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 455                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 456                 {
 457                         CS(this).movement_x = dir * v_forward * maxspeed;
 458                         CS(this).movement_y = dir * v_right * maxspeed;
 459                 }
 460                 return;
 461         }
 462
 463         // Handling of jump pads
 464         if(this.jumppadcount)
 465         {
 466                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 467                 {
 468                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 469                         if(navigation_poptouchedgoals(this))
 470                                 return;
 471                 }
 472                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 473                 {
 474                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 475                         // but with some randomness so it can try out different paths
 476                         if(!this.goalcurrent)
 477                         {
 478                                 entity newgoal = NULL;
 479                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 480                                 {
 481                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 482                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 483                                                 continue;
 484
 485                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 486
 487                                         if(trace_fraction < 1)
 488                                                 continue;
 489
 490                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 491                                                 newgoal = it;
 492                                 });
 493
 494                                 if(newgoal)
 495                                 {
 496                                         this.ignoregoal = this.goalcurrent;
 497                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 498                                         navigation_clearroute(this);
 499                                         navigation_routetogoal(this, newgoal, this.origin);
 500                                         if(autocvar_bot_debug_goalstack)
 501                                                 debuggoalstack(this);
 502                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 503                                 }
 504                         }
 505                         else //if (this.goalcurrent)
 506                         {
 507                                 if (this.goalcurrent.bot_pickup)
 508                                 {
 509                                         entity jumppad_wp = this.goalcurrent_prev;
 510                                         navigation_poptouchedgoals(this);
 511                                         if(!this.goalcurrent && jumppad_wp.wp00)
 512                                         {
 513                                                 // head to the jumppad destination once bot reaches the goal item
 514                                                 navigation_pushroute(this, jumppad_wp.wp00);
 515                                         }
 516                                 }
 517                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 518                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 519                                 {
 520                                         if (this.velocity.z < 0)
 521                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 522                                 }
 523                                 else if(havocbot_checkgoaldistance(this, gco))
 524                                 {
 525                                         navigation_clearroute(this);
 526                                         navigation_goalrating_timeout_force(this);
 527                                 }
 528                                 else
 529                                         return;
 530                         }
 531                 }
 532                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 533                 {
 534                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 535                         {
 536                                 vector velxy = this.velocity; velxy_z = 0;
 537                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 538                                 {
 539                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 540                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 541                                 }
 542                                 return;
 543                         }
 544
 545                         // Don't chase players while using a jump pad
 546                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 547                                 return;
 548                 }
 549         }
 550         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 551                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 552
 553         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 554         if (skill > 6 && !(IS_ONGROUND(this)))
 555         {
 556                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 557                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 558                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 559
 560                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 561                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 562                 if(this.items & IT_JETPACK)
 563                 {
 564                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 565                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 566                         {
 567                                 if(this.velocity.z<0)
 568                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 569                         }
 570                         else
 571                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 572
 573                         // If there is no goal try to move forward
 574
 575                         if(this.goalcurrent==NULL)
 576                                 dir = v_forward;
 577                         else
 578                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 579
 580                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 581                         float xyspeed = xyvelocity * dir;
 582
 583                         if(xyspeed < (maxspeed / 2))
 584                         {
 585                                 makevectors(this.v_angle.y * '0 1 0');
 586                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 587                                 if(trace_fraction==1)
 588                                 {
 589                                         CS(this).movement_x = dir * v_forward * maxspeed;
 590                                         CS(this).movement_y = dir * v_right * maxspeed;
 591                                         if (skill < 10)
 592                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 593                                 }
 594                         }
 595
 596                         this.havocbot_blockhead = true;
 597
 598                         return;
 599                 }
 600                 else if(!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 601                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 602                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 603                 {
 604                         if(this.velocity.z < 0)
 605                         {
 606                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 607                                 {
 608                                         .entity weaponentity = weaponentities[slot];
 609
 610                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 611                                                 continue;
 612
 613                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 614                                         {
 615                                                 CS(this).movement_x = maxspeed;
 616
 617                                                 if(this.rocketjumptime)
 618                                                 {
 619                                                         if(time > this.rocketjumptime)
 620                                                         {
 621                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 622                                                                 this.rocketjumptime = 0;
 623                                                         }
 624                                                         return;
 625                                                 }
 626
 627                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 628                                                 this.v_angle_x = 90;
 629                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 630                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 631                                                 return;
 632                                         }
 633                                 }
 634                         }
 635                 }
 636                 else
 637                 {
 638                         // If there is no goal try to move forward
 639                         if(this.goalcurrent==NULL)
 640                                 CS(this).movement_x = maxspeed;
 641                 }
 642         }
 643
 644         // If we are under water with no goals, swim up
 645         if(this.waterlevel && !this.goalcurrent)
 646         {
 647                 dir = '0 0 0';
 648                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 649                         dir.z = 1;
 650                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 651                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 652                 else
 653                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 654                 makevectors(this.v_angle.y * '0 1 0');
 655                 vector v = dir * maxspeed;
 656                 CS(this).movement.x = v * v_forward;
 657                 CS(this).movement.y = v * v_right;
 658                 CS(this).movement.z = v * v_up;
 659         }
 660
 661         // if there is nowhere to go, exit
 662         if (this.goalcurrent == NULL)
 663                 return;
 664
 665
 666         bool locked_goal = false;
 667         if((this.goalentity && wasfreed(this.goalentity))
 668                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 669         {
 670                 navigation_clearroute(this);
 671                 navigation_goalrating_timeout_force(this);
 672                 return;
 673         }
 674         else if(this.goalentity.tag_entity)
 675         {
 676                 navigation_goalrating_timeout_expire(this, 2);
 677         }
 678         else if(this.goalentity.bot_pickup)
 679         {
 680                 if(this.goalentity.bot_pickup_respawning)
 681                 {
 682                         if(this.goalentity.solid) // item respawned
 683                                 this.goalentity.bot_pickup_respawning = false;
 684                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 685                         {
 686                                 if(checkpvs(this.origin, this.goalentity))
 687                                 {
 688                                         this.goalentity.bot_pickup_respawning = false;
 689                                         navigation_goalrating_timeout_expire(this, random());
 690                                 }
 691                                 locked_goal = true; // wait for item to respawn
 692                         }
 693                         else if(this.goalentity == this.goalcurrent)
 694                                 locked_goal = true; // wait for item to respawn
 695                 }
 696                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 697                 {
 698                         if(checkpvs(this.origin, this.goalentity))
 699                         {
 700                                 navigation_goalrating_timeout_expire(this, random());
 701                         }
 702                 }
 703         }
 704         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 705                 locked_goal = true;
 706
 707         if (navigation_shortenpath(this))
 708         {
 709                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 710                         && navigation_goalrating_timeout_can_be_anticipated(this))
 711                 {
 712                         navigation_goalrating_timeout_force(this);
 713                 }
 714         }
 715
 716         bool goalcurrent_can_be_removed = false;
 717         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 718         {
 719                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 720                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 721                 {
 722                         goalcurrent_can_be_removed = true;
 723                         // don't remove if not visible
 724                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 725                         {
 726                                 if (IS_DEAD(this.goalcurrent))
 727                                 {
 728                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 729                                         {
 730                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 731                                                 {
 732                                                         navigation_clearroute(this);
 733                                                         navigation_pushroute(this, it);
 734                                                         // loot can't be immediately rated since it isn't on ground yet
 735                                                         // it will be rated after a second when on ground, meanwhile head to it
 736                                                         navigation_goalrating_timeout_expire(this, 1);
 737                                                         return;
 738                                                 }
 739                                         });
 740                                 }
 741                                 if (!Item_IsLoot(this.goalcurrent))
 742                                 {
 743                                         navigation_goalrating_timeout_force(this);
 744                                         return;
 745                                 }
 746                         }
 747                 }
 748                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 749                 {
 750                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 751                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 752                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 753                         {
 754                                 navigation_goalrating_timeout_force(this);
 755                                 return;
 756                         }
 757                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 758                 }
 759         }
 760
 761         if(!locked_goal)
 762         {
 763                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 764                 // in this case path finding can start directly from a waypoint instead of
 765                 // looking for all the reachable waypoints up to a certain distance
 766                 if (navigation_poptouchedgoals(this))
 767                 {
 768                         if (this.goalcurrent)
 769                         {
 770                                 if (goalcurrent_can_be_removed)
 771                                 {
 772                                         // remove even if not visible
 773                                         navigation_goalrating_timeout_force(this);
 774                                         return;
 775                                 }
 776                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 777                                         navigation_goalrating_timeout_force(this);
 778                         }
 779                         else
 780                         {
 781                                 entity old_goal = this.goalcurrent_prev;
 782                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 783                                 {
 784                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 785                                         // item of the group by telling the bot to head directly to the farthest item.
 786                                         // Next time we let the bot select a goal as usual which can be another item
 787                                         // of this group (the closest one) and so on
 788                                         this.item_group = old_goal.item_group;
 789                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 790                                         if (new_goal)
 791                                                 navigation_pushroute(this, new_goal);
 792                                 }
 793                         }
 794                 }
 795         }
 796
 797         // if ran out of goals try to use an alternative goal or get a new strategy asap
 798         if(this.goalcurrent == NULL)
 799         {
 800                 navigation_goalrating_timeout_force(this);
 801                 return;
 802         }
 803
 804
 805         if(autocvar_bot_debug_goalstack)
 806                 debuggoalstack(this);
 807
 808         bool bunnyhop_forbidden = false;
 809         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 810         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 811         {
 812                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 813                 destorg = this.goalcurrent.origin;
 814         }
 815         else if (this.goalcurrent.wpisbox)
 816         {
 817                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 818                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 819                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 820                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 821                 {
 822                         bunnyhop_forbidden = true;
 823                         destorg = this.goalcurrent.origin;
 824                         if(destorg.z > this.origin.z)
 825                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 826                 }
 827         }
 828
 829         diff = destorg - this.origin;
 830
 831         if (time < this.bot_stop_moving_timeout
 832                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 833         {
 834                 // stop if the locked goal has been reached
 835                 destorg = this.origin;
 836                 diff = dir = '0 0 0';
 837         }
 838         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 839         {
 840                 if (vdist(diff, <, 80))
 841                 {
 842                         // stop if too close to target player (even if frozen)
 843                         destorg = this.origin;
 844                         diff = dir = '0 0 0';
 845                 }
 846                 else
 847                 {
 848                         // move destorg out of target players, otherwise bot will consider them
 849                         // an obstacle that needs to be jumped (especially if frozen)
 850                         dir = normalize(diff);
 851                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 852                         diff = destorg - this.origin;
 853                 }
 854         }
 855         else
 856                 dir = normalize(diff);
 857         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 858
 859         vector evadedanger = '0 0 0';
 860
 861         //if (this.bot_dodgevector_time < time)
 862         {
 863                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 864                 //this.bot_dodgevector_jumpbutton = 1;
 865
 866                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 867                 makevectors(this.v_angle.y * '0 1 0');
 868                 if (this.waterlevel > WATERLEVEL_WETFEET)
 869                 {
 870                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 871                         {
 872                                 if(!this.goalcurrent)
 873                                         this.aistatus |= AI_STATUS_OUT_WATER;
 874                                 else if(destorg.z > this.origin.z)
 875                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 876                         }
 877                         else
 878                         {
 879                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 880                                         (this.aistatus & AI_STATUS_OUT_WATER))
 881                                 {
 882                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 883                                         dir = flatdir;
 884                                 }
 885                                 else
 886                                 {
 887                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 888                                         if (destorg.z > this.origin.z)
 889                                                 dir = flatdir;
 890                                 }
 891                         }
 892                 }
 893                 else
 894                 {
 895                         float s;
 896                         vector offset;
 897                         if(this.aistatus & AI_STATUS_OUT_WATER)
 898                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 899
 900                         // jump if going toward an obstacle that doesn't look like stairs we
 901                         // can walk up directly
 902                         vector deviation = '0 0 0';
 903                         float current_speed = vlen(vec2(this.velocity));
 904                         if (current_speed < maxspeed * 0.2)
 905                                 current_speed = maxspeed * 0.2;
 906                         else
 907                         {
 908                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 909                                 while (deviation.y < -180) deviation.y += 360;
 910                                 while (deviation.y > 180) deviation.y -= 360;
 911                         }
 912                         float turning = false;
 913                         vector flat_diff = vec2(diff);
 914                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 915                         vector actual_destorg = this.origin + offset;
 916                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 917                         {
 918                                 if (time > this.bot_stop_moving_timeout
 919                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 920                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 921                                 {
 922                                         this.bot_stop_moving_timeout = time + 0.1;
 923                                 }
 924                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 925                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 926                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 927                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 928                                 )
 929                                 {
 930                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 931                                         // avoid changing route while bot is jumping a gap
 932                                         navigation_goalrating_timeout_extend_if_needed(this, 1.5);
 933                                 }
 934                         }
 935                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 936                         {
 937                                 if (vlen2(flat_diff) < vlen2(offset))
 938                                 {
 939                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 940                                         {
 941                                                 // oblique warpzones need a jump otherwise bots gets stuck
 942                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 943                                         }
 944                                         else
 945                                         {
 946                                                 actual_destorg.x = destorg.x;
 947                                                 actual_destorg.y = destorg.y;
 948                                         }
 949                                 }
 950                         }
 951                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 952                         {
 953                                 actual_destorg.x = destorg.x;
 954                                 actual_destorg.y = destorg.y;
 955                         }
 956                         else if (vlen2(flat_diff) < vlen2(offset))
 957                         {
 958                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 959                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 960                                 float dist = vlen(vec2(this.origin + offset - destorg));
 961                                 // if current and next goal are close to each other make sure
 962                                 // actual_destorg isn't set beyond next_goal_org
 963                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 964                                         actual_destorg = next_goal_org;
 965                                 else
 966                                         actual_destorg = vec2(destorg) + dist * next_dir;
 967                                 actual_destorg.z = this.origin.z;
 968                                 turning = true;
 969                         }
 970
 971                         LABEL(jumpobstacle_check);
 972                         dir = flatdir = normalize(actual_destorg - this.origin);
 973
 974                         bool jump_forbidden = false;
 975                         if (!turning && fabs(deviation.y) > 50)
 976                                 jump_forbidden = true;
 977                         else if (IS_DUCKED(this))
 978                         {
 979                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
 980                                 if (trace_startsolid)
 981                                         jump_forbidden = true;
 982                         }
 983
 984                         if (!jump_forbidden)
 985                         {
 986                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
 987                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
 988                                 {
 989                                         s = trace_fraction;
 990                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
 991                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
 992                                         {
 993                                                 // found an obstacle
 994                                                 if (turning && fabs(deviation.y) > 5)
 995                                                 {
 996                                                         // check if the obstacle is still there without turning
 997                                                         actual_destorg = destorg;
 998                                                         turning = false;
 999                                                         this.bot_tracewalk_time = time + 0.25;
1000                                                         goto jumpobstacle_check;
1001                                                 }
1002                                                 s = trace_fraction;
1003                                                 // don't artificially reduce max jump height in real-time
1004                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1005                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1006                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1007                                                 if (trace_fraction > s)
1008                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1009                                                 else
1010                                                 {
1011                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1012                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1013                                                         if (trace_fraction > s)
1014                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1015                                                 }
1016                                         }
1017                                 }
1018                         }
1019
1020                         // if bot for some reason doesn't get close to the current goal find another one
1021                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1022                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1023                         if(havocbot_checkgoaldistance(this, destorg))
1024                         {
1025                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1026                                 {
1027                                         navigation_clearroute(this);
1028                                         navigation_goalrating_timeout_force(this);
1029                                         return;
1030                                 }
1031
1032                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1033                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1034                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1035                                 {
1036                                         navigation_clearroute(this);
1037                                         navigation_goalrating_timeout_force(this);
1038                                         return;
1039                                 }
1040
1041                                 // give bot only another chance to prevent bot getting stuck
1042                                 // in case it thinks it can walk but actually can't
1043                                 this.goalcurrent_distance_z = FLOAT_MAX;
1044                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1045                                 this.goalcurrent_distance_time = -time; // mark second try
1046                         }
1047
1048                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1049                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1050                         {
1051                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1052                         }
1053
1054                         // Check for water/slime/lava and dangerous edges
1055                         // (only when the bot is on the ground or jumping intentionally)
1056
1057                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1058                         vector dst_ahead = this.origin + this.view_ofs + offset;
1059                         vector dst_down = dst_ahead - '0 0 3000';
1060                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1061
1062                         bool unreachable = false;
1063                         s = CONTENT_SOLID;
1064                         bool danger_detected = false;
1065                         if (trace_fraction == 1 && !this.jumppadcount
1066                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1067                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1068                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1069                         {
1070                                 // Look downwards
1071                                 traceline(dst_ahead , dst_down, true, NULL);
1072                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1073                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1074                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1075                                 {
1076                                         s = pointcontents(trace_endpos + '0 0 1');
1077                                         if (s != CONTENT_SOLID)
1078                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1079                                                 danger_detected = true;
1080                                         else if (s == CONTENT_SKY)
1081                                                 danger_detected = true;
1082                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1083                                         {
1084                                                 // the traceline check isn't enough but is good as optimization,
1085                                                 // when not true (most of the time) this tracebox call is avoided
1086                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1087                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1088                                                 {
1089                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1090                                                         {
1091                                                                 // the goal is probably on an upper platform, assume bot can't get there
1092                                                                 unreachable = true;
1093                                                         }
1094                                                         else
1095                                                                 danger_detected = true;
1096                                                 }
1097                                         }
1098                                 }
1099                         }
1100                         if (danger_detected && fabs(deviation.y) < 80
1101                                 && (fabs(deviation.y) > 5 || vdist(vec2(this.velocity), >, maxspeed * 1.5)))
1102                         {
1103                                 evadedanger = normalize(this.velocity) * -1;
1104                                 evadedanger.z = 0;
1105                         }
1106
1107                         dir = flatdir;
1108                         makevectors(this.v_angle.y * '0 1 0');
1109
1110                         if (danger_detected || (s == CONTENT_WATER))
1111                         {
1112                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1113                                 if(IS_PLAYER(this.goalcurrent))
1114                                         unreachable = true;
1115                         }
1116
1117                         // slow down if bot is in the air and goal is under it
1118                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1119                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1120                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1121                         {
1122                                 // tracebox wouldn't work when bot is still on the ledge
1123                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1124                                 if (this.origin.z - trace_endpos.z > 120)
1125                                         evadedanger = normalize(this.velocity) * -1;
1126                         }
1127
1128                         if(unreachable)
1129                         {
1130                                 navigation_clearroute(this);
1131                                 navigation_goalrating_timeout_force(this);
1132                                 this.ignoregoal = this.goalcurrent;
1133                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1134                         }
1135                 }
1136
1137                 dodge = havocbot_dodge(this);
1138                 if (dodge)
1139                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1140                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1141                 if (this.enemy)
1142                 {
1143                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1144                         if (IS_PLAYER(trace_ent))
1145                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1146                 }
1147         //      this.bot_dodgevector = dir;
1148         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1149         }
1150
1151         float ladder_zdir = 0;
1152         if(time < this.ladder_time)
1153         {
1154                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1155                 {
1156                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1157                                 ladder_zdir = 1;
1158                 }
1159                 else
1160                 {
1161                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1162                                 ladder_zdir = -1;
1163                 }
1164                 if (ladder_zdir)
1165                 {
1166                         if (vdist(vec2(diff), <, 40))
1167                                 dir.z = ladder_zdir * 4;
1168                         else
1169                                 dir.z = ladder_zdir * 2;
1170                         dir = normalize(dir);
1171                 }
1172         }
1173
1174         if (this.goalcurrent.wpisbox
1175                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1176         {
1177                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1178                 // head to teleport origin
1179                 dir = (this.goalcurrent.origin - this.origin);
1180                 dir.z = 0;
1181                 dir = normalize(dir);
1182         }
1183
1184         // already executed when bot targets an enemy
1185         if (!this.bot_aimdir_executed)
1186         {
1187                 if (time < this.bot_stop_moving_timeout)
1188                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1189                 else
1190                         bot_aimdir(this, dir, 0);
1191         }
1192
1193         if (!ladder_zdir)
1194         {
1195                 dir *= dodge_enemy_factor;
1196                 dir = normalize(dir + dodge + evadedanger);
1197         }
1198
1199         makevectors(this.v_angle);
1200         //dir = this.bot_dodgevector;
1201         //if (this.bot_dodgevector_jumpbutton)
1202         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1203         CS(this).movement_x = dir * v_forward * maxspeed;
1204         CS(this).movement_y = dir * v_right * maxspeed;
1205         CS(this).movement_z = dir * v_up * maxspeed;
1206
1207         // Emulate keyboard interface
1208         if (skill < 10)
1209                 havocbot_keyboard_movement(this, destorg);
1210
1211         // Bunnyhop!
1212         if (!bunnyhop_forbidden && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1213                 havocbot_bunnyhop(this, dir);
1214
1215         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1216                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1217         if (dodge)
1218         {
1219                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1220                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1221                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1222                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1223         }
1224 }
1225
1226 entity havocbot_gettarget(entity this, bool secondary)
1227 {
1228         entity best = NULL;
1229         vector eye = CENTER_OR_VIEWOFS(this);
1230         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1231         {
1232                 vector v = CENTER_OR_VIEWOFS(it);
1233                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1234                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1235                 if(bot_shouldattack(this, it))
1236                 {
1237                         traceline(eye, v, true, this);
1238                         if (trace_ent == it || trace_fraction >= 1)
1239                                 best = it;
1240                 }
1241         });
1242
1243         return best;
1244 }
1245
1246 void havocbot_chooseenemy(entity this)
1247 {
1248         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1249         {
1250                 this.enemy = NULL;
1251                 return;
1252         }
1253         if (this.enemy)
1254         {
1255                 if (!bot_shouldattack(this, this.enemy))
1256                 {
1257                         // enemy died or something, find a new target
1258                         this.enemy = NULL;
1259                         this.havocbot_chooseenemy_finished = time;
1260                 }
1261                 else if (this.havocbot_stickenemy)
1262                 {
1263                         // tracking last chosen enemy
1264                         // if enemy is visible
1265                         // and not really really far away
1266                         // and we're not severely injured
1267                         // then keep tracking for a half second into the future
1268                         vector targ_pos = (this.enemy.absmin + this.enemy.absmax) * 0.5;
1269                         traceline(this.origin + this.view_ofs, targ_pos, false, NULL);
1270                         if (trace_ent == this.enemy || trace_fraction == 1)
1271                         if (vdist(targ_pos - this.origin, <, 1000))
1272                         if (GetResource(this, RES_HEALTH) > 30)
1273                         {
1274                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1275                                 this.havocbot_chooseenemy_finished = time + 0.5;
1276                                 return;
1277                         }
1278                         // enemy isn't visible, or is far away, or we're injured severely
1279                         // so stop preferring this enemy
1280                         // (it will still take a half second until a new one is chosen)
1281                         this.havocbot_stickenemy = 0;
1282                 }
1283         }
1284         if (time < this.havocbot_chooseenemy_finished)
1285                 return;
1286         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1287         vector eye = this.origin + this.view_ofs;
1288         entity best = NULL;
1289         float bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1290
1291         // Backup hit flags
1292         int hf = this.dphitcontentsmask;
1293
1294         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1295
1296         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1297
1298         bool scan_transparent = false;
1299         bool scan_secondary_targets = false;
1300         bool have_secondary_targets = false;
1301         while(true)
1302         {
1303                 scan_secondary_targets = false;
1304 LABEL(scan_targets)
1305                 IL_EACH(g_bot_targets, it.bot_attack,
1306                 {
1307                         if(!scan_secondary_targets)
1308                         {
1309                                 if(it.classname == "misc_breakablemodel")
1310                                 {
1311                                         have_secondary_targets = true;
1312                                         continue;
1313                                 }
1314                         }
1315                         else if(it.classname != "misc_breakablemodel")
1316                                 continue;
1317
1318                         vector v = (it.absmin + it.absmax) * 0.5;
1319                         float rating = vlen2(v - eye);
1320                         if (rating < bestrating && bot_shouldattack(this, it))
1321                         {
1322                                 traceline(eye, v, true, this);
1323                                 if (trace_ent == it || trace_fraction >= 1)
1324                                 {
1325                                         best = it;
1326                                         bestrating = rating;
1327                                 }
1328                         }
1329                 });
1330
1331                 if(!best && have_secondary_targets && !scan_secondary_targets)
1332                 {
1333                         scan_secondary_targets = true;
1334                         // restart the loop
1335                         bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1336                         goto scan_targets;
1337                 }
1338
1339                 // I want to do a second scan if no enemy was found or I don't have weapons
1340                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1341                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1342                         break;
1343                 if(scan_transparent)
1344                         break;
1345
1346                 // Set flags to see through transparent objects
1347                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1348
1349                 scan_transparent = true;
1350         }
1351
1352         // Restore hit flags
1353         this.dphitcontentsmask = hf;
1354
1355         this.enemy = best;
1356         this.havocbot_stickenemy = true;
1357         if(best && best.classname == "misc_breakablemodel")
1358                 this.havocbot_stickenemy = false;
1359 }
1360
1361 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1362 {
1363         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1364         // so skip this for them, or they'll never get to reload their weapons at all.
1365         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1366         if(skill < 5)
1367                 return false;
1368
1369         // if this weapon is scheduled for reloading, don't switch to it during combat
1370         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1371         {
1372                 FOREACH(Weapons, it != WEP_Null, {
1373                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1374                                 return true; // other weapon available
1375                 });
1376         }
1377
1378         return false;
1379 }
1380
1381 void havocbot_chooseweapon(entity this, .entity weaponentity)
1382 {
1383         int i;
1384
1385         // ;)
1386         if(g_weaponarena_weapons == WEPSET(TUBA))
1387         {
1388                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1389                 return;
1390         }
1391
1392         // TODO: clean this up by moving it to weapon code
1393         if(this.enemy==NULL)
1394         {
1395                 // If no weapon was chosen get the first available weapon
1396                 if(this.(weaponentity).m_weapon==WEP_Null)
1397                 FOREACH(Weapons, it != WEP_Null, {
1398                         if(client_hasweapon(this, it, weaponentity, true, false))
1399                         {
1400                                 this.(weaponentity).m_switchweapon = it;
1401                                 return;
1402                         }
1403                 });
1404                 return;
1405         }
1406
1407         // Do not change weapon during the next second after a combo
1408         float f = time - this.lastcombotime;
1409         if(f < 1)
1410                 return;
1411
1412         float w;
1413         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1414
1415         // Should it do a weapon combo?
1416         float af, ct, combo_time, combo;
1417
1418         af = ATTACK_FINISHED(this, weaponentity);
1419         ct = autocvar_bot_ai_weapon_combo_threshold;
1420
1421         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1422         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1423         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1424
1425         combo = false;
1426
1427         if(autocvar_bot_ai_weapon_combo)
1428         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1429         if(af > combo_time)
1430         {
1431                 combo = true;
1432                 this.lastcombotime = time;
1433         }
1434
1435         distance *= (2 ** this.bot_rangepreference);
1436
1437         // Custom weapon list based on distance to the enemy
1438         if(bot_custom_weapon){
1439
1440                 // Choose weapons for far distance
1441                 if ( distance > bot_distance_far ) {
1442                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1443                                 w = bot_weapons_far[i];
1444                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1445                                 {
1446                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1447                                                 continue;
1448                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1449                                         return;
1450                                 }
1451                         }
1452                 }
1453
1454                 // Choose weapons for mid distance
1455                 if ( distance > bot_distance_close) {
1456                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1457                                 w = bot_weapons_mid[i];
1458                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1459                                 {
1460                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1461                                                 continue;
1462                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1463                                         return;
1464                                 }
1465                         }
1466                 }
1467
1468                 // Choose weapons for close distance
1469                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1470                         w = bot_weapons_close[i];
1471                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1472                         {
1473                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1474                                         continue;
1475                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1476                                 return;
1477                         }
1478                 }
1479         }
1480 }
1481
1482 void havocbot_aim(entity this)
1483 {
1484         if (time < this.nextaim)
1485                 return;
1486         this.nextaim = time + 0.1;
1487         vector myvel = this.velocity;
1488         if (!this.waterlevel)
1489                 myvel.z = 0;
1490         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1491         else if (this.enemy)
1492         {
1493                 vector enemyvel = this.enemy.velocity;
1494                 if (!this.enemy.waterlevel)
1495                         enemyvel.z = 0;
1496                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1497         }
1498         else
1499                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1500 }
1501
1502 bool havocbot_moveto_refresh_route(entity this)
1503 {
1504         // Refresh path to goal if necessary
1505         entity wp;
1506         wp = this.havocbot_personal_waypoint;
1507         navigation_goalrating_start(this);
1508         navigation_routerating(this, wp, 10000, 10000);
1509         navigation_goalrating_end(this);
1510         return (this.goalentity != NULL);
1511 }
1512
1513 float havocbot_moveto(entity this, vector pos)
1514 {
1515         entity wp;
1516
1517         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1518         {
1519                 // Step 4: Move to waypoint
1520                 if(this.havocbot_personal_waypoint==NULL)
1521                 {
1522                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1523                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1524                         return CMD_STATUS_ERROR;
1525                 }
1526
1527                 if (!bot_strategytoken_taken)
1528                 if(this.havocbot_personal_waypoint_searchtime<time)
1529                 {
1530                         bot_strategytoken_taken = true;
1531                         if(havocbot_moveto_refresh_route(this))
1532                         {
1533                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1534                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1535                                 this.havocbot_personal_waypoint_failcounter = 0;
1536                         }
1537                         else
1538                         {
1539                                 this.havocbot_personal_waypoint_failcounter += 1;
1540                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1541                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1542                                 {
1543                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1544                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1545                                         delete(this.havocbot_personal_waypoint);
1546                                         return CMD_STATUS_ERROR;
1547                                 }
1548                                 else
1549                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1550                         }
1551                 }
1552
1553                 if(autocvar_bot_debug_goalstack)
1554                         debuggoalstack(this);
1555
1556
1557                 // Go!
1558                 havocbot_movetogoal(this);
1559
1560                 if (!this.bot_aimdir_executed && this.goalcurrent)
1561                 {
1562                         // Heading
1563                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1564                         dir -= this.origin + this.view_ofs;
1565                         dir.z = 0;
1566                         bot_aimdir(this, dir, 0);
1567                 }
1568
1569                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1570                 {
1571                         // Step 5: Waypoint reached
1572                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1573                         waypoint_remove(this.havocbot_personal_waypoint);
1574                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1575                         return CMD_STATUS_FINISHED;
1576                 }
1577
1578                 return CMD_STATUS_EXECUTING;
1579         }
1580
1581         // Step 2: Linking waypoint
1582         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1583         {
1584                 // Wait until it is linked
1585                 if(!this.havocbot_personal_waypoint.wplinked)
1586                 {
1587                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1588                         return CMD_STATUS_EXECUTING;
1589                 }
1590
1591                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1592                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1593                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1594
1595                 // Step 3: Route to waypoint
1596                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1597
1598                 return CMD_STATUS_EXECUTING;
1599         }
1600
1601         // Step 1: Spawning waypoint
1602         wp = waypoint_spawnpersonal(this, pos);
1603         if(wp==NULL)
1604         {
1605                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1606                 return CMD_STATUS_ERROR;
1607         }
1608
1609         this.havocbot_personal_waypoint = wp;
1610         this.havocbot_personal_waypoint_failcounter = 0;
1611         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1612
1613         // if pos is inside a teleport, then let's mark it as teleport waypoint
1614         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1615         {
1616                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1617                 this.lastteleporttime = 0;
1618         });
1619
1620 /*
1621         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1622                 print("routing to a teleporter\n");
1623         else
1624                 print("routing to a non-teleporter\n");
1625 */
1626
1627         return CMD_STATUS_EXECUTING;
1628 }
1629
1630 float havocbot_resetgoal(entity this)
1631 {
1632         navigation_clearroute(this);
1633         return CMD_STATUS_FINISHED;
1634 }
1635
1636 void havocbot_setupbot(entity this)
1637 {
1638         this.bot_ai = havocbot_ai;
1639         this.cmd_moveto = havocbot_moveto;
1640         this.cmd_resetgoal = havocbot_resetgoal;
1641
1642         // NOTE: bot is not player yet
1643         havocbot_chooserole(this);
1644 }
1645
1646 vector havocbot_dodge(entity this)
1647 {
1648         // LordHavoc: disabled because this is too expensive
1649         return '0 0 0';
1650 #if 0
1651         entity head;
1652         vector dodge, v, n;
1653         float danger, bestdanger, vl, d;
1654         dodge = '0 0 0';
1655         bestdanger = -20;
1656         // check for dangerous objects near bot or approaching bot
1657         head = findchainfloat(bot_dodge, true);
1658         while(head)
1659         {
1660                 if (head.owner != this)
1661                 {
1662                         vl = vlen(head.velocity);
1663                         if (vl > autocvar_sv_maxspeed * 0.3)
1664                         {
1665                                 n = normalize(head.velocity);
1666                                 v = this.origin - head.origin;
1667                                 d = v * n;
1668                                 if (d > (0 - head.bot_dodgerating))
1669                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1670                                 {
1671                                         // calculate direction and distance from the flight path, by removing the forward axis
1672                                         v = v - (n * (v * n));
1673                                         danger = head.bot_dodgerating - vlen(v);
1674                                         if (bestdanger < danger)
1675                                         {
1676                                                 bestdanger = danger;
1677                                                 // dodge to the side of the object
1678                                                 dodge = normalize(v);
1679                                         }
1680                                 }
1681                         }
1682                         else
1683                         {
1684                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1685                                 if (bestdanger < danger)
1686                                 {
1687                                         bestdanger = danger;
1688                                         dodge = normalize(this.origin - head.origin);
1689                                 }
1690                         }
1691                 }
1692                 head = head.chain;
1693         }
1694         return dodge;
1695 #endif
1696 }