qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/defs.qh>
   6 #include <server/miscfunctions.qh>
   7 #include "../cvars.qh"
   8
   9 #include "../aim.qh"
  10 #include "../bot.qh"
  11 #include "../navigation.qh"
  12 #include "../scripting.qh"
  13 #include "../waypoints.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/impulses/all.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19 #include <common/state.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/wepent.qh>
  22
  23 #include <common/mapobjects/func/ladder.qh>
  24 #include <common/mapobjects/teleporters.qh>
  25 #include <common/mapobjects/trigger/jumppads.qh>
  26
  27 #include <lib/warpzone/common.qh>
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if(IS_DEAD(this) || STAT(FROZEN, this))
  93         {
  94                 if (this.goalcurrent)
  95                         navigation_clearroute(this);
  96                 return;
  97         }
  98
  99         havocbot_chooseenemy(this);
 100
 101         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 102         {
 103                 .entity weaponentity = weaponentities[slot];
 104                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 105                 if(this.(weaponentity).bot_chooseweapontime < time)
 106                 {
 107                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 108                         havocbot_chooseweapon(this, weaponentity);
 109                 }
 110         }
 111         havocbot_aim(this);
 112         lag_update(this);
 113
 114         if (this.bot_aimtarg)
 115         {
 116                 this.aistatus |= AI_STATUS_ATTACKING;
 117                 this.aistatus &= ~AI_STATUS_ROAMING;
 118
 119                 if(STAT(WEAPONS, this))
 120                 {
 121                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 122                         {
 123                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 124                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 125                         }
 126                         else
 127                         {
 128                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 129                                 {
 130                                         .entity weaponentity = weaponentities[slot];
 131                                         Weapon w = this.(weaponentity).m_weapon;
 132                                         if(w == WEP_Null && slot != 0)
 133                                                 continue;
 134                                         w.wr_aim(w, this, weaponentity);
 135                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 136                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 137                                 }
 138                         }
 139                 }
 140                 else
 141                 {
 142                         if(IS_PLAYER(this.bot_aimtarg))
 143                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 144                 }
 145         }
 146         else if (this.goalcurrent)
 147         {
 148                 this.aistatus |= AI_STATUS_ROAMING;
 149                 this.aistatus &= ~AI_STATUS_ATTACKING;
 150         }
 151
 152         havocbot_movetogoal(this);
 153         if (!this.bot_aimdir_executed && this.goalcurrent)
 154         {
 155                 // Heading
 156                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 157                 dir -= this.origin + this.view_ofs;
 158                 dir.z = 0;
 159                 bot_aimdir(this, dir, 0);
 160         }
 161
 162         // if the bot is not attacking, consider reloading weapons
 163         if (!(this.aistatus & AI_STATUS_ATTACKING))
 164         {
 165                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 166                 {
 167                         .entity weaponentity = weaponentities[slot];
 168
 169                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 170                                 continue;
 171
 172                         // we are currently holding a weapon that's not fully loaded, reload it
 173                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 174                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 175                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 176
 177                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 178                         // the code above executes next frame, starting the reloading then
 179                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 180                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 181                         {
 182                                 FOREACH(Weapons, it != WEP_Null, {
 183                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 184                                         {
 185                                                 this.(weaponentity).m_switchweapon = it;
 186                                                 break;
 187                                         }
 188                                 });
 189                         }
 190                 }
 191         }
 192 }
 193
 194 void havocbot_keyboard_movement(entity this, vector destorg)
 195 {
 196         if(time <= this.havocbot_keyboardtime)
 197                 return;
 198
 199         float sk = skill + this.bot_moveskill;
 200         this.havocbot_keyboardtime =
 201                 max(
 202                         this.havocbot_keyboardtime
 203                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 204                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 205                 , time);
 206         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 207
 208         float trigger = autocvar_bot_ai_keyboard_threshold;
 209
 210         // categorize forward movement
 211         // at skill < 1.5 only forward
 212         // at skill < 2.5 only individual directions
 213         // at skill < 4.5 only individual directions, and forward diagonals
 214         // at skill >= 4.5, all cases allowed
 215         if (keyboard.x > trigger)
 216         {
 217                 keyboard.x = 1;
 218                 if (sk < 2.5)
 219                         keyboard.y = 0;
 220         }
 221         else if (keyboard.x < -trigger && sk > 1.5)
 222         {
 223                 keyboard.x = -1;
 224                 if (sk < 4.5)
 225                         keyboard.y = 0;
 226         }
 227         else
 228         {
 229                 keyboard.x = 0;
 230                 if (sk < 1.5)
 231                         keyboard.y = 0;
 232         }
 233         if (sk < 4.5)
 234                 keyboard.z = 0;
 235
 236         if (keyboard.y > trigger)
 237                 keyboard.y = 1;
 238         else if (keyboard.y < -trigger)
 239                 keyboard.y = -1;
 240         else
 241                 keyboard.y = 0;
 242
 243         if (keyboard.z > trigger)
 244                 keyboard.z = 1;
 245         else if (keyboard.z < -trigger)
 246                 keyboard.z = -1;
 247         else
 248                 keyboard.z = 0;
 249
 250         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 251         if (keyboard == '0 0 0')
 252                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 253
 254         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 255         if (this.havocbot_ducktime > time)
 256                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 257
 258         keyboard = this.havocbot_keyboard;
 259         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 260         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 261         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 262 }
 263
 264 void havocbot_bunnyhop(entity this, vector dir)
 265 {
 266         // Don't jump when attacking
 267         if(this.aistatus & AI_STATUS_ATTACKING)
 268                 return;
 269
 270         if(IS_PLAYER(this.goalcurrent))
 271                 return;
 272
 273         if((this.aistatus & AI_STATUS_RUNNING) && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 274                 || (this.aistatus & AI_STATUS_DANGER_AHEAD))
 275         {
 276                 this.aistatus &= ~AI_STATUS_RUNNING;
 277                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 278                 this.bot_canruntogoal = 0;
 279                 this.bot_timelastseengoal = 0;
 280                 return;
 281         }
 282
 283         if(this.waterlevel > WATERLEVEL_WETFEET)
 284         {
 285                 this.aistatus &= ~AI_STATUS_RUNNING;
 286                 return;
 287         }
 288
 289         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 290         {
 291                 this.bot_canruntogoal = 0;
 292                 this.bot_timelastseengoal = 0;
 293         }
 294
 295         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 296
 297         // Run only to visible goals
 298         if(IS_ONGROUND(this))
 299         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed))
 300         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 301         {
 302                 this.bot_lastseengoal = this.goalcurrent;
 303
 304                 // seen it before
 305                 if(this.bot_timelastseengoal)
 306                 {
 307                         // for a period of time
 308                         if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 309                         {
 310                                 bool checkdistance = true;
 311
 312                                 // don't run if it is too close
 313                                 if(this.bot_canruntogoal==0)
 314                                 {
 315                                         if(vdist(this.origin - gco, >, autocvar_bot_ai_bunnyhop_startdistance))
 316                                                 this.bot_canruntogoal = 1;
 317                                         else
 318                                                 this.bot_canruntogoal = -1;
 319                                 }
 320
 321                                 if(this.bot_canruntogoal != 1)
 322                                         return;
 323
 324                                 if(this.aistatus & AI_STATUS_ROAMING)
 325                                 if(this.goalcurrent.classname == "waypoint")
 326                                 if(!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 327                                 if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 328                                 if(this.goalstack01 && !wasfreed(this.goalstack01))
 329                                 {
 330                                         vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 331                                         vector deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 332                                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 333                                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 334
 335                                         if(fabs(deviation.y) < 20)
 336                                         if(vlen2(this.origin - gco) < vlen2(this.origin - gno))
 337                                         if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 338                                         {
 339                                                 if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 340                                                 if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 341                                                 {
 342                                                         checkdistance = false;
 343                                                 }
 344                                         }
 345                                 }
 346
 347                                 if(checkdistance)
 348                                 {
 349                                         this.aistatus &= ~AI_STATUS_RUNNING;
 350                                         // increase stop distance in case the goal is on a slope or a lower platform
 351                                         if(vdist(this.origin - gco, >, autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z)))
 352                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 353                                 }
 354                                 else
 355                                 {
 356                                         this.aistatus |= AI_STATUS_RUNNING;
 357                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 358                                 }
 359                         }
 360                 }
 361                 else
 362                 {
 363                         this.bot_timelastseengoal = time;
 364                 }
 365         }
 366         else
 367         {
 368                 this.bot_timelastseengoal = 0;
 369         }
 370 }
 371
 372 // return true when bot isn't getting closer to the current goal
 373 bool havocbot_checkgoaldistance(entity this, vector gco)
 374 {
 375         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 376         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 377         float distance_time = this.goalcurrent_distance_time;
 378         if(distance_time < 0)
 379                 distance_time = -distance_time;
 380         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 381         {
 382                 if(!distance_time)
 383                         this.goalcurrent_distance_time = time;
 384                 else if (time - distance_time > 0.5)
 385                         return true;
 386         }
 387         else
 388         {
 389                 // reduce it a little bit so it works even with very small approaches to the goal
 390                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 391                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 392                 this.goalcurrent_distance_time = 0;
 393         }
 394         return false;
 395 }
 396
 397 entity havocbot_select_an_item_of_group(entity this, int gr)
 398 {
 399         entity selected = NULL;
 400         float selected_dist2 = 0;
 401         // select farthest item of this group from bot's position
 402         IL_EACH(g_items, it.item_group == gr && it.solid,
 403         {
 404                 float dist2 = vlen2(this.origin - it.origin);
 405                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 406                 {
 407                         selected = it;
 408                         selected_dist2 = vlen2(this.origin - selected.origin);
 409                 }
 410         });
 411
 412         if (!selected)
 413                 return NULL;
 414
 415         set_tracewalk_dest(selected, this.origin, false);
 416         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 417                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 418         {
 419                 return NULL;
 420         }
 421
 422         return selected;
 423 }
 424
 425 void havocbot_movetogoal(entity this)
 426 {
 427         vector diff;
 428         vector dir;
 429         vector flatdir;
 430         vector evadeobstacle;
 431         vector evadelava;
 432         float dodge_enemy_factor = 1;
 433         float maxspeed;
 434         //float dist;
 435         vector dodge;
 436         //if (this.goalentity)
 437         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 438         CS(this).movement = '0 0 0';
 439         maxspeed = autocvar_sv_maxspeed;
 440
 441         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 442         // Jetpack navigation
 443         if(this.navigation_jetpack_goal)
 444         if(this.goalcurrent==this.navigation_jetpack_goal)
 445         if(GetResource(this, RES_FUEL))
 446         {
 447                 if(autocvar_bot_debug_goalstack)
 448                 {
 449                         debuggoalstack(this);
 450                         te_wizspike(this.navigation_jetpack_point);
 451                 }
 452
 453                 // Take off
 454                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 455                 {
 456                         // Brake almost completely so it can get a good direction
 457                         if(vdist(this.velocity, >, 10))
 458                                 return;
 459                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 460                 }
 461
 462                 makevectors(this.v_angle.y * '0 1 0');
 463                 dir = normalize(this.navigation_jetpack_point - this.origin);
 464
 465                 // Landing
 466                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 467                 {
 468                         // Calculate brake distance in xy
 469                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 470                         float vel2 = vlen2(vec2(this.velocity));
 471                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 472                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 473                         if(d < db || d < 500)
 474                         {
 475                                 // Brake
 476                                 if (vel2 > (maxspeed * 0.3) ** 2)
 477                                 {
 478                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 479                                         return;
 480                                 }
 481                                 // Switch to normal mode
 482                                 this.navigation_jetpack_goal = NULL;
 483                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 484                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 485                                 return;
 486                         }
 487                 }
 488                 else if(checkpvs(this.origin,this.goalcurrent))
 489                 {
 490                         // If I can see the goal switch to landing code
 491                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 492                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 493                         return;
 494                 }
 495
 496                 // Flying
 497                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 498                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 499                 {
 500                         CS(this).movement_x = dir * v_forward * maxspeed;
 501                         CS(this).movement_y = dir * v_right * maxspeed;
 502                 }
 503                 return;
 504         }
 505
 506         // Handling of jump pads
 507         if(this.jumppadcount)
 508         {
 509                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 510                 {
 511                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 512                         if(navigation_poptouchedgoals(this))
 513                                 return;
 514                 }
 515                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 516                 {
 517                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 518                         // but with some randomness so it can try out different paths
 519                         if(!this.goalcurrent)
 520                         {
 521                                 entity newgoal = NULL;
 522                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 523                                 {
 524                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 525                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 526                                                 continue;
 527
 528                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 529
 530                                         if(trace_fraction < 1)
 531                                                 continue;
 532
 533                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 534                                                 newgoal = it;
 535                                 });
 536
 537                                 if(newgoal)
 538                                 {
 539                                         this.ignoregoal = this.goalcurrent;
 540                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 541                                         navigation_clearroute(this);
 542                                         navigation_routetogoal(this, newgoal, this.origin);
 543                                         if(autocvar_bot_debug_goalstack)
 544                                                 debuggoalstack(this);
 545                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 546                                 }
 547                         }
 548                         else //if (this.goalcurrent)
 549                         {
 550                                 if (this.goalcurrent.bot_pickup)
 551                                 {
 552                                         entity jumppad_wp = this.goalcurrent_prev;
 553                                         navigation_poptouchedgoals(this);
 554                                         if(!this.goalcurrent && jumppad_wp.wp00)
 555                                         {
 556                                                 // head to the jumppad destination once bot reaches the goal item
 557                                                 navigation_pushroute(this, jumppad_wp.wp00);
 558                                         }
 559                                 }
 560                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 561                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 562                                 {
 563                                         if (this.velocity.z < 0)
 564                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 565                                 }
 566                                 else if(havocbot_checkgoaldistance(this, gco))
 567                                 {
 568                                         navigation_clearroute(this);
 569                                         navigation_goalrating_timeout_force(this);
 570                                 }
 571                                 else
 572                                         return;
 573                         }
 574                 }
 575                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 576                 {
 577                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 578                         {
 579                                 vector velxy = this.velocity; velxy_z = 0;
 580                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 581                                 {
 582                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 583                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 584                                 }
 585                                 return;
 586                         }
 587
 588                         // Don't chase players while using a jump pad
 589                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 590                                 return;
 591                 }
 592         }
 593         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 594                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 595
 596         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 597         if (skill > 6 && !(IS_ONGROUND(this)))
 598         {
 599                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 600                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 601                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 602
 603                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 604                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 605                 if(this.items & IT_JETPACK)
 606                 {
 607                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 608                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 609                         {
 610                                 if(this.velocity.z<0)
 611                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 612                         }
 613                         else
 614                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 615
 616                         // If there is no goal try to move forward
 617
 618                         if(this.goalcurrent==NULL)
 619                                 dir = v_forward;
 620                         else
 621                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 622
 623                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 624                         float xyspeed = xyvelocity * dir;
 625
 626                         if(xyspeed < (maxspeed / 2))
 627                         {
 628                                 makevectors(this.v_angle.y * '0 1 0');
 629                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 630                                 if(trace_fraction==1)
 631                                 {
 632                                         CS(this).movement_x = dir * v_forward * maxspeed;
 633                                         CS(this).movement_y = dir * v_right * maxspeed;
 634                                         if (skill < 10)
 635                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 636                                 }
 637                         }
 638
 639                         this.havocbot_blockhead = true;
 640
 641                         return;
 642                 }
 643                 else if(!this.jumppadcount && !this.goalcurrent.wphardwired
 644                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 645                 {
 646                         if(this.velocity.z < 0)
 647                         {
 648                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 649                                 {
 650                                         .entity weaponentity = weaponentities[slot];
 651
 652                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 653                                                 continue;
 654
 655                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 656                                         {
 657                                                 CS(this).movement_x = maxspeed;
 658
 659                                                 if(this.rocketjumptime)
 660                                                 {
 661                                                         if(time > this.rocketjumptime)
 662                                                         {
 663                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 664                                                                 this.rocketjumptime = 0;
 665                                                         }
 666                                                         return;
 667                                                 }
 668
 669                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 670                                                 this.v_angle_x = 90;
 671                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 672                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 673                                                 return;
 674                                         }
 675                                 }
 676                         }
 677                 }
 678                 else
 679                 {
 680                         // If there is no goal try to move forward
 681                         if(this.goalcurrent==NULL)
 682                                 CS(this).movement_x = maxspeed;
 683                 }
 684         }
 685
 686         // If we are under water with no goals, swim up
 687         if(this.waterlevel && !this.goalcurrent)
 688         {
 689                 dir = '0 0 0';
 690                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 691                         dir.z = 1;
 692                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 693                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 694                 else
 695                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 696                 makevectors(this.v_angle.y * '0 1 0');
 697                 vector v = dir * maxspeed;
 698                 CS(this).movement.x = v * v_forward;
 699                 CS(this).movement.y = v * v_right;
 700                 CS(this).movement.z = v * v_up;
 701         }
 702
 703         // if there is nowhere to go, exit
 704         if (this.goalcurrent == NULL)
 705                 return;
 706
 707
 708         bool locked_goal = false;
 709         if((this.goalentity && wasfreed(this.goalentity))
 710                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 711         {
 712                 navigation_clearroute(this);
 713                 navigation_goalrating_timeout_force(this);
 714                 return;
 715         }
 716         else if(this.goalentity.tag_entity)
 717         {
 718                 navigation_goalrating_timeout_expire(this, 2);
 719         }
 720         else if(this.goalentity.bot_pickup)
 721         {
 722                 if(this.goalentity.bot_pickup_respawning)
 723                 {
 724                         if(this.goalentity.solid) // item respawned
 725                                 this.goalentity.bot_pickup_respawning = false;
 726                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 727                         {
 728                                 if(checkpvs(this.origin, this.goalentity))
 729                                 {
 730                                         this.goalentity.bot_pickup_respawning = false;
 731                                         navigation_goalrating_timeout_expire(this, random());
 732                                 }
 733                                 locked_goal = true; // wait for item to respawn
 734                         }
 735                         else if(this.goalentity == this.goalcurrent)
 736                                 locked_goal = true; // wait for item to respawn
 737                 }
 738                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 739                 {
 740                         if(checkpvs(this.origin, this.goalentity))
 741                         {
 742                                 navigation_goalrating_timeout_expire(this, random());
 743                         }
 744                 }
 745         }
 746         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 747                 locked_goal = true;
 748
 749         if (navigation_shortenpath(this))
 750         {
 751                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 752                         && navigation_goalrating_timeout_can_be_anticipated(this))
 753                 {
 754                         navigation_goalrating_timeout_force(this);
 755                 }
 756         }
 757
 758         bool goalcurrent_can_be_removed = false;
 759         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 760         {
 761                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 762                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 763                 {
 764                         goalcurrent_can_be_removed = true;
 765                         // don't remove if not visible
 766                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 767                         {
 768                                 if (IS_DEAD(this.goalcurrent))
 769                                 {
 770                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 771                                         {
 772                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 773                                                 {
 774                                                         navigation_clearroute(this);
 775                                                         navigation_pushroute(this, it);
 776                                                         // loot can't be immediately rated since it isn't on ground yet
 777                                                         // it will be rated after a second when on ground, meanwhile head to it
 778                                                         navigation_goalrating_timeout_expire(this, 1);
 779                                                         return;
 780                                                 }
 781                                         });
 782                                 }
 783                                 if (!Item_IsLoot(this.goalcurrent))
 784                                 {
 785                                         navigation_goalrating_timeout_force(this);
 786                                         return;
 787                                 }
 788                         }
 789                 }
 790                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 791                 {
 792                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 793                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 794                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 795                         {
 796                                 navigation_goalrating_timeout_force(this);
 797                                 return;
 798                         }
 799                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 800                 }
 801         }
 802
 803         if(!locked_goal)
 804         {
 805                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 806                 // in this case path finding can start directly from a waypoint instead of
 807                 // looking for all the reachable waypoints up to a certain distance
 808                 if (navigation_poptouchedgoals(this))
 809                 {
 810                         if (this.goalcurrent)
 811                         {
 812                                 if (goalcurrent_can_be_removed)
 813                                 {
 814                                         // remove even if not visible
 815                                         navigation_goalrating_timeout_force(this);
 816                                         return;
 817                                 }
 818                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 819                                         navigation_goalrating_timeout_force(this);
 820                         }
 821                         else
 822                         {
 823                                 entity old_goal = this.goalcurrent_prev;
 824                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 825                                 {
 826                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 827                                         // item of the group by telling the bot to head directly to the farthest item.
 828                                         // Next time we let the bot select a goal as usual which can be another item
 829                                         // of this group (the closest one) and so on
 830                                         this.item_group = old_goal.item_group;
 831                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 832                                         if (new_goal)
 833                                                 navigation_pushroute(this, new_goal);
 834                                 }
 835                         }
 836                 }
 837         }
 838
 839         // if ran out of goals try to use an alternative goal or get a new strategy asap
 840         if(this.goalcurrent == NULL)
 841         {
 842                 navigation_goalrating_timeout_force(this);
 843                 return;
 844         }
 845
 846
 847         if(autocvar_bot_debug_goalstack)
 848                 debuggoalstack(this);
 849
 850         bool bunnyhop_forbidden = false;
 851         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 852         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 853         {
 854                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 855                 destorg = this.goalcurrent.origin;
 856         }
 857         else if (this.goalcurrent.wpisbox)
 858         {
 859                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 860                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 861                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 862                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 863                 {
 864                         bunnyhop_forbidden = true;
 865                         destorg = this.goalcurrent.origin;
 866                         if(destorg.z > this.origin.z)
 867                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 868                 }
 869         }
 870
 871         diff = destorg - this.origin;
 872
 873         if (time < this.bot_stop_moving_timeout
 874                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 875         {
 876                 // stop if the locked goal has been reached
 877                 destorg = this.origin;
 878                 diff = dir = '0 0 0';
 879         }
 880         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 881         {
 882                 if (vdist(diff, <, 80))
 883                 {
 884                         // stop if too close to target player (even if frozen)
 885                         destorg = this.origin;
 886                         diff = dir = '0 0 0';
 887                 }
 888                 else
 889                 {
 890                         // move destorg out of target players, otherwise bot will consider them
 891                         // an obstacle that needs to be jumped (especially if frozen)
 892                         dir = normalize(diff);
 893                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 894                         diff = destorg - this.origin;
 895                 }
 896         }
 897         else
 898                 dir = normalize(diff);
 899         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 900
 901         //if (this.bot_dodgevector_time < time)
 902         {
 903                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 904                 //this.bot_dodgevector_jumpbutton = 1;
 905                 evadeobstacle = '0 0 0';
 906                 evadelava = '0 0 0';
 907
 908                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 909                 makevectors(this.v_angle.y * '0 1 0');
 910                 if (this.waterlevel > WATERLEVEL_WETFEET)
 911                 {
 912                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 913                         {
 914                                 if(!this.goalcurrent)
 915                                         this.aistatus |= AI_STATUS_OUT_WATER;
 916                                 else if(destorg.z > this.origin.z)
 917                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 918                         }
 919                         else
 920                         {
 921                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 922                                         (this.aistatus & AI_STATUS_OUT_WATER))
 923                                 {
 924                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 925                                         dir = flatdir;
 926                                 }
 927                                 else
 928                                 {
 929                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 930                                         if (destorg.z > this.origin.z)
 931                                                 dir = flatdir;
 932                                 }
 933                         }
 934                 }
 935                 else
 936                 {
 937                         float s;
 938                         vector offset;
 939                         if(this.aistatus & AI_STATUS_OUT_WATER)
 940                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 941
 942                         // jump if going toward an obstacle that doesn't look like stairs we
 943                         // can walk up directly
 944                         vector deviation = '0 0 0';
 945                         float current_speed = vlen(vec2(this.velocity));
 946                         if (current_speed < maxspeed * 0.2)
 947                                 current_speed = maxspeed * 0.2;
 948                         else
 949                         {
 950                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 951                                 while (deviation.y < -180) deviation.y += 360;
 952                                 while (deviation.y > 180) deviation.y -= 360;
 953                         }
 954                         float turning = false;
 955                         vector flat_diff = vec2(diff);
 956                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 957                         vector actual_destorg = this.origin + offset;
 958                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
 959                         {
 960                                 if (vlen2(flat_diff) < vlen2(offset))
 961                                 {
 962                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 963                                         {
 964                                                 // oblique warpzones need a jump otherwise bots gets stuck
 965                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 966                                         }
 967                                         else
 968                                         {
 969                                                 actual_destorg.x = destorg.x;
 970                                                 actual_destorg.y = destorg.y;
 971                                         }
 972                                 }
 973                         }
 974                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 975                         {
 976                                 actual_destorg.x = destorg.x;
 977                                 actual_destorg.y = destorg.y;
 978                         }
 979                         else if (vlen2(flat_diff) < vlen2(offset))
 980                         {
 981                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 982                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 983                                 float dist = vlen(vec2(this.origin + offset - destorg));
 984                                 // if current and next goal are close to each other make sure
 985                                 // actual_destorg isn't set beyond next_goal_org
 986                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 987                                         actual_destorg = next_goal_org;
 988                                 else
 989                                         actual_destorg = vec2(destorg) + dist * next_dir;
 990                                 actual_destorg.z = this.origin.z;
 991                                 turning = true;
 992                         }
 993
 994                         LABEL(jump_check);
 995                         dir = flatdir = normalize(actual_destorg - this.origin);
 996
 997                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
 998                         {
 999                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1000                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1001                                 {
1002                                         s = trace_fraction;
1003                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1004                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1005                                         {
1006                                                 // found an obstacle
1007                                                 if (turning && fabs(deviation.y) > 5)
1008                                                 {
1009                                                         // check if the obstacle is still there without turning
1010                                                         actual_destorg = destorg;
1011                                                         turning = false;
1012                                                         this.bot_tracewalk_time = time + 0.25;
1013                                                         goto jump_check;
1014                                                 }
1015                                                 s = trace_fraction;
1016                                                 // don't artificially reduce max jump height in real-time
1017                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1018                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1019                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1020                                                 if (trace_fraction > s)
1021                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1022                                                 else
1023                                                 {
1024                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1025                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1026                                                         if (trace_fraction > s)
1027                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1028                                                 }
1029                                         }
1030                                 }
1031                         }
1032
1033                         // if bot for some reason doesn't get close to the current goal find another one
1034                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1035                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1036                         if(havocbot_checkgoaldistance(this, destorg))
1037                         {
1038                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1039                                 {
1040                                         navigation_clearroute(this);
1041                                         navigation_goalrating_timeout_force(this);
1042                                         return;
1043                                 }
1044
1045                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1046                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1047                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1048                                 {
1049                                         navigation_clearroute(this);
1050                                         navigation_goalrating_timeout_force(this);
1051                                         return;
1052                                 }
1053
1054                                 // give bot only another chance to prevent bot getting stuck
1055                                 // in case it thinks it can walk but actually can't
1056                                 this.goalcurrent_distance_z = FLOAT_MAX;
1057                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1058                                 this.goalcurrent_distance_time = -time; // mark second try
1059                         }
1060
1061                         // Check for water/slime/lava and dangerous edges
1062                         // (only when the bot is on the ground or jumping intentionally)
1063
1064                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1065                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1066                         {
1067                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1068                         }
1069
1070                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1071                         vector dst_ahead = this.origin + this.view_ofs + offset;
1072                         vector dst_down = dst_ahead - '0 0 3000';
1073                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1074
1075                         bool unreachable = false;
1076                         s = CONTENT_SOLID;
1077                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1078                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1079                         {
1080                                 // Look downwards
1081                                 traceline(dst_ahead , dst_down, true, NULL);
1082                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1083                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1084                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1085                                 {
1086                                         s = pointcontents(trace_endpos + '0 0 1');
1087                                         if (s != CONTENT_SOLID)
1088                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1089                                                 evadelava = normalize(this.velocity) * -1;
1090                                         else if (s == CONTENT_SKY)
1091                                                 evadeobstacle = normalize(this.velocity) * -1;
1092                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1093                                         {
1094                                                 // the traceline check isn't enough but is good as optimization,
1095                                                 // when not true (most of the time) this tracebox call is avoided
1096                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1097                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1098                                                 {
1099                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1100                                                         {
1101                                                                 // the goal is probably on an upper platform, assume bot can't get there
1102                                                                 unreachable = true;
1103                                                         }
1104                                                         else
1105                                                                 evadelava = normalize(this.velocity) * -1;
1106                                                 }
1107                                         }
1108                                 }
1109                         }
1110
1111                         dir = flatdir;
1112                         evadeobstacle.z = 0;
1113                         evadelava.z = 0;
1114                         makevectors(this.v_angle.y * '0 1 0');
1115
1116                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1117                         {
1118                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1119                                 if(IS_PLAYER(this.goalcurrent))
1120                                         unreachable = true;
1121                         }
1122
1123                         // slow down if bot is in the air and goal is under it
1124                         if (!this.goalcurrent.wphardwired
1125                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1126                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1127                         {
1128                                 // tracebox wouldn't work when bot is still on the ledge
1129                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1130                                 if (this.origin.z - trace_endpos.z > 120)
1131                                         evadeobstacle = normalize(this.velocity) * -1;
1132                         }
1133
1134                         if(unreachable)
1135                         {
1136                                 navigation_clearroute(this);
1137                                 navigation_goalrating_timeout_force(this);
1138                                 this.ignoregoal = this.goalcurrent;
1139                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1140                         }
1141                 }
1142
1143                 dodge = havocbot_dodge(this);
1144                 if (dodge)
1145                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1146                 dodge += evadeobstacle + evadelava;
1147                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1148                 if (this.enemy)
1149                 {
1150                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1151                         if (IS_PLAYER(trace_ent))
1152                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1153                 }
1154         //      this.bot_dodgevector = dir;
1155         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1156         }
1157
1158         float ladder_zdir = 0;
1159         if(time < this.ladder_time)
1160         {
1161                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1162                 {
1163                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1164                                 ladder_zdir = 1;
1165                 }
1166                 else
1167                 {
1168                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1169                                 ladder_zdir = -1;
1170                 }
1171                 if (ladder_zdir)
1172                 {
1173                         if (vdist(vec2(diff), <, 40))
1174                                 dir.z = ladder_zdir * 4;
1175                         else
1176                                 dir.z = ladder_zdir * 2;
1177                         dir = normalize(dir);
1178                 }
1179         }
1180
1181         if (this.goalcurrent.wpisbox
1182                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1183         {
1184                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1185                 // head to teleport origin
1186                 dir = (this.goalcurrent.origin - this.origin);
1187                 dir.z = 0;
1188                 dir = normalize(dir);
1189         }
1190
1191         // already executed when bot targets an enemy
1192         if (!this.bot_aimdir_executed)
1193         {
1194                 if (time < this.bot_stop_moving_timeout)
1195                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1196                 else
1197                         bot_aimdir(this, dir, 0);
1198         }
1199
1200         if (!ladder_zdir)
1201         {
1202                 dir *= dodge_enemy_factor;
1203                 dir = normalize(dir + dodge);
1204         }
1205
1206         makevectors(this.v_angle);
1207         //dir = this.bot_dodgevector;
1208         //if (this.bot_dodgevector_jumpbutton)
1209         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1210         CS(this).movement_x = dir * v_forward * maxspeed;
1211         CS(this).movement_y = dir * v_right * maxspeed;
1212         CS(this).movement_z = dir * v_up * maxspeed;
1213
1214         // Emulate keyboard interface
1215         if (skill < 10)
1216                 havocbot_keyboard_movement(this, destorg);
1217
1218         // Bunnyhop!
1219         //if(this.aistatus & AI_STATUS_ROAMING)
1220         if(!bunnyhop_forbidden && this.goalcurrent)
1221         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1222                 havocbot_bunnyhop(this, dir);
1223
1224         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1225                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1226         if (dodge)
1227         {
1228                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1229                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1230                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1231                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1232         }
1233 }
1234
1235 entity havocbot_gettarget(entity this, bool secondary)
1236 {
1237         entity best = NULL;
1238         vector eye = CENTER_OR_VIEWOFS(this);
1239         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1240         {
1241                 vector v = CENTER_OR_VIEWOFS(it);
1242                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1243                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1244                 if(bot_shouldattack(this, it))
1245                 {
1246                         traceline(eye, v, true, this);
1247                         if (trace_ent == it || trace_fraction >= 1)
1248                                 best = it;
1249                 }
1250         });
1251
1252         return best;
1253 }
1254
1255 void havocbot_chooseenemy(entity this)
1256 {
1257         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1258         {
1259                 this.enemy = NULL;
1260                 return;
1261         }
1262         if (this.enemy)
1263         {
1264                 if (!bot_shouldattack(this, this.enemy))
1265                 {
1266                         // enemy died or something, find a new target
1267                         this.enemy = NULL;
1268                         this.havocbot_chooseenemy_finished = time;
1269                 }
1270                 else if (this.havocbot_stickenemy)
1271                 {
1272                         // tracking last chosen enemy
1273                         // if enemy is visible
1274                         // and not really really far away
1275                         // and we're not severely injured
1276                         // then keep tracking for a half second into the future
1277                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1278                         if (trace_ent == this.enemy || trace_fraction == 1)
1279                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1280                         if (GetResource(this, RES_HEALTH) > 30)
1281                         {
1282                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1283                                 this.havocbot_chooseenemy_finished = time + 0.5;
1284                                 return;
1285                         }
1286                         // enemy isn't visible, or is far away, or we're injured severely
1287                         // so stop preferring this enemy
1288                         // (it will still take a half second until a new one is chosen)
1289                         this.havocbot_stickenemy = 0;
1290                 }
1291         }
1292         if (time < this.havocbot_chooseenemy_finished)
1293                 return;
1294         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1295         vector eye = this.origin + this.view_ofs;
1296         entity best = NULL;
1297         float bestrating = 100000000;
1298
1299         // Backup hit flags
1300         int hf = this.dphitcontentsmask;
1301
1302         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1303
1304         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1305
1306         bool scan_transparent = false;
1307         bool scan_secondary_targets = false;
1308         bool have_secondary_targets = false;
1309         while(true)
1310         {
1311                 scan_secondary_targets = false;
1312 LABEL(scan_targets)
1313                 IL_EACH(g_bot_targets, it.bot_attack,
1314                 {
1315                         if(!scan_secondary_targets)
1316                         {
1317                                 if(it.classname == "misc_breakablemodel")
1318                                 {
1319                                         have_secondary_targets = true;
1320                                         continue;
1321                                 }
1322                         }
1323                         else if(it.classname != "misc_breakablemodel")
1324                                 continue;
1325
1326                         vector v = (it.absmin + it.absmax) * 0.5;
1327                         float rating = vlen2(v - eye);
1328                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1329                         if (bestrating > rating)
1330                         if (bot_shouldattack(this, it))
1331                         {
1332                                 traceline(eye, v, true, this);
1333                                 if (trace_ent == it || trace_fraction >= 1)
1334                                 {
1335                                         best = it;
1336                                         bestrating = rating;
1337                                 }
1338                         }
1339                 });
1340
1341                 if(!best && have_secondary_targets && !scan_secondary_targets)
1342                 {
1343                         scan_secondary_targets = true;
1344                         // restart the loop
1345                         bestrating = 100000000;
1346                         goto scan_targets;
1347                 }
1348
1349                 // I want to do a second scan if no enemy was found or I don't have weapons
1350                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1351                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1352                         break;
1353                 if(scan_transparent)
1354                         break;
1355
1356                 // Set flags to see through transparent objects
1357                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1358
1359                 scan_transparent = true;
1360         }
1361
1362         // Restore hit flags
1363         this.dphitcontentsmask = hf;
1364
1365         this.enemy = best;
1366         this.havocbot_stickenemy = true;
1367         if(best && best.classname == "misc_breakablemodel")
1368                 this.havocbot_stickenemy = false;
1369 }
1370
1371 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1372 {
1373         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1374         // so skip this for them, or they'll never get to reload their weapons at all.
1375         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1376         if(skill < 5)
1377                 return false;
1378
1379         // if this weapon is scheduled for reloading, don't switch to it during combat
1380         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1381         {
1382                 FOREACH(Weapons, it != WEP_Null, {
1383                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1384                                 return true; // other weapon available
1385                 });
1386         }
1387
1388         return false;
1389 }
1390
1391 void havocbot_chooseweapon(entity this, .entity weaponentity)
1392 {
1393         int i;
1394
1395         // ;)
1396         if(g_weaponarena_weapons == WEPSET(TUBA))
1397         {
1398                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1399                 return;
1400         }
1401
1402         // TODO: clean this up by moving it to weapon code
1403         if(this.enemy==NULL)
1404         {
1405                 // If no weapon was chosen get the first available weapon
1406                 if(this.(weaponentity).m_weapon==WEP_Null)
1407                 FOREACH(Weapons, it != WEP_Null, {
1408                         if(client_hasweapon(this, it, weaponentity, true, false))
1409                         {
1410                                 this.(weaponentity).m_switchweapon = it;
1411                                 return;
1412                         }
1413                 });
1414                 return;
1415         }
1416
1417         // Do not change weapon during the next second after a combo
1418         float f = time - this.lastcombotime;
1419         if(f < 1)
1420                 return;
1421
1422         float w;
1423         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1424
1425         // Should it do a weapon combo?
1426         float af, ct, combo_time, combo;
1427
1428         af = ATTACK_FINISHED(this, weaponentity);
1429         ct = autocvar_bot_ai_weapon_combo_threshold;
1430
1431         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1432         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1433         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1434
1435         combo = false;
1436
1437         if(autocvar_bot_ai_weapon_combo)
1438         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1439         if(af > combo_time)
1440         {
1441                 combo = true;
1442                 this.lastcombotime = time;
1443         }
1444
1445         distance *= (2 ** this.bot_rangepreference);
1446
1447         // Custom weapon list based on distance to the enemy
1448         if(bot_custom_weapon){
1449
1450                 // Choose weapons for far distance
1451                 if ( distance > bot_distance_far ) {
1452                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1453                                 w = bot_weapons_far[i];
1454                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1455                                 {
1456                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1457                                                 continue;
1458                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1459                                         return;
1460                                 }
1461                         }
1462                 }
1463
1464                 // Choose weapons for mid distance
1465                 if ( distance > bot_distance_close) {
1466                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1467                                 w = bot_weapons_mid[i];
1468                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1469                                 {
1470                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1471                                                 continue;
1472                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1473                                         return;
1474                                 }
1475                         }
1476                 }
1477
1478                 // Choose weapons for close distance
1479                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1480                         w = bot_weapons_close[i];
1481                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1482                         {
1483                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1484                                         continue;
1485                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1486                                 return;
1487                         }
1488                 }
1489         }
1490 }
1491
1492 void havocbot_aim(entity this)
1493 {
1494         if (time < this.nextaim)
1495                 return;
1496         this.nextaim = time + 0.1;
1497         vector myvel = this.velocity;
1498         if (!this.waterlevel)
1499                 myvel.z = 0;
1500         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1501         else if (this.enemy)
1502         {
1503                 vector enemyvel = this.enemy.velocity;
1504                 if (!this.enemy.waterlevel)
1505                         enemyvel.z = 0;
1506                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1507         }
1508         else
1509                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1510 }
1511
1512 bool havocbot_moveto_refresh_route(entity this)
1513 {
1514         // Refresh path to goal if necessary
1515         entity wp;
1516         wp = this.havocbot_personal_waypoint;
1517         navigation_goalrating_start(this);
1518         navigation_routerating(this, wp, 10000, 10000);
1519         navigation_goalrating_end(this);
1520         return (this.goalentity != NULL);
1521 }
1522
1523 float havocbot_moveto(entity this, vector pos)
1524 {
1525         entity wp;
1526
1527         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1528         {
1529                 // Step 4: Move to waypoint
1530                 if(this.havocbot_personal_waypoint==NULL)
1531                 {
1532                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1533                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1534                         return CMD_STATUS_ERROR;
1535                 }
1536
1537                 if (!bot_strategytoken_taken)
1538                 if(this.havocbot_personal_waypoint_searchtime<time)
1539                 {
1540                         bot_strategytoken_taken = true;
1541                         if(havocbot_moveto_refresh_route(this))
1542                         {
1543                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1544                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1545                                 this.havocbot_personal_waypoint_failcounter = 0;
1546                         }
1547                         else
1548                         {
1549                                 this.havocbot_personal_waypoint_failcounter += 1;
1550                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1551                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1552                                 {
1553                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1554                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1555                                         delete(this.havocbot_personal_waypoint);
1556                                         return CMD_STATUS_ERROR;
1557                                 }
1558                                 else
1559                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1560                         }
1561                 }
1562
1563                 if(autocvar_bot_debug_goalstack)
1564                         debuggoalstack(this);
1565
1566
1567                 // Go!
1568                 havocbot_movetogoal(this);
1569
1570                 if (!this.bot_aimdir_executed && this.goalcurrent)
1571                 {
1572                         // Heading
1573                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1574                         dir -= this.origin + this.view_ofs;
1575                         dir.z = 0;
1576                         bot_aimdir(this, dir, 0);
1577                 }
1578
1579                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1580                 {
1581                         // Step 5: Waypoint reached
1582                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1583                         waypoint_remove(this.havocbot_personal_waypoint);
1584                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1585                         return CMD_STATUS_FINISHED;
1586                 }
1587
1588                 return CMD_STATUS_EXECUTING;
1589         }
1590
1591         // Step 2: Linking waypoint
1592         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1593         {
1594                 // Wait until it is linked
1595                 if(!this.havocbot_personal_waypoint.wplinked)
1596                 {
1597                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1598                         return CMD_STATUS_EXECUTING;
1599                 }
1600
1601                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1602                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1603                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1604
1605                 // Step 3: Route to waypoint
1606                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1607
1608                 return CMD_STATUS_EXECUTING;
1609         }
1610
1611         // Step 1: Spawning waypoint
1612         wp = waypoint_spawnpersonal(this, pos);
1613         if(wp==NULL)
1614         {
1615                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1616                 return CMD_STATUS_ERROR;
1617         }
1618
1619         this.havocbot_personal_waypoint = wp;
1620         this.havocbot_personal_waypoint_failcounter = 0;
1621         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1622
1623         // if pos is inside a teleport, then let's mark it as teleport waypoint
1624         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1625         {
1626                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1627                 this.lastteleporttime = 0;
1628         });
1629
1630 /*
1631         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1632                 print("routing to a teleporter\n");
1633         else
1634                 print("routing to a non-teleporter\n");
1635 */
1636
1637         return CMD_STATUS_EXECUTING;
1638 }
1639
1640 float havocbot_resetgoal(entity this)
1641 {
1642         navigation_clearroute(this);
1643         return CMD_STATUS_FINISHED;
1644 }
1645
1646 void havocbot_setupbot(entity this)
1647 {
1648         this.bot_ai = havocbot_ai;
1649         this.cmd_moveto = havocbot_moveto;
1650         this.cmd_resetgoal = havocbot_resetgoal;
1651
1652         // NOTE: bot is not player yet
1653         havocbot_chooserole(this);
1654 }
1655
1656 vector havocbot_dodge(entity this)
1657 {
1658         // LordHavoc: disabled because this is too expensive
1659         return '0 0 0';
1660 #if 0
1661         entity head;
1662         vector dodge, v, n;
1663         float danger, bestdanger, vl, d;
1664         dodge = '0 0 0';
1665         bestdanger = -20;
1666         // check for dangerous objects near bot or approaching bot
1667         head = findchainfloat(bot_dodge, true);
1668         while(head)
1669         {
1670                 if (head.owner != this)
1671                 {
1672                         vl = vlen(head.velocity);
1673                         if (vl > autocvar_sv_maxspeed * 0.3)
1674                         {
1675                                 n = normalize(head.velocity);
1676                                 v = this.origin - head.origin;
1677                                 d = v * n;
1678                                 if (d > (0 - head.bot_dodgerating))
1679                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1680                                 {
1681                                         // calculate direction and distance from the flight path, by removing the forward axis
1682                                         v = v - (n * (v * n));
1683                                         danger = head.bot_dodgerating - vlen(v);
1684                                         if (bestdanger < danger)
1685                                         {
1686                                                 bestdanger = danger;
1687                                                 // dodge to the side of the object
1688                                                 dodge = normalize(v);
1689                                         }
1690                                 }
1691                         }
1692                         else
1693                         {
1694                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1695                                 if (bestdanger < danger)
1696                                 {
1697                                         bestdanger = danger;
1698                                         dodge = normalize(this.origin - head.origin);
1699                                 }
1700                         }
1701                 }
1702                 head = head.chain;
1703         }
1704         return dodge;
1705 #endif
1706 }