Add a list for domination control points
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / havocbot / roles.qc
1 #include "roles.qh"
2
3 #include "havocbot.qh"
4
5 #include "../cvars.qh"
6
7 #include "../bot.qh"
8 #include "../navigation.qh"
9
10 .float max_armorvalue;
11 .float havocbot_role_timeout;
12
13 .void(entity this) havocbot_previous_role;
14 .void(entity this) havocbot_role;
15
16 void havocbot_goalrating_items(entity this, float ratingscale, vector org, float sradius)
17 {
18         float rating, d, discard, friend_distance, enemy_distance;
19         vector o;
20         ratingscale = ratingscale * 0.0001; // items are rated around 10000 already
21
22         IL_EACH(g_items, it.bot_pickup,
23         {
24                 o = (it.absmin + it.absmax) * 0.5;
25                 friend_distance = 10000; enemy_distance = 10000;
26                 rating = 0;
27
28                 if(!it.solid || vdist(o - org, >, sradius) || (it == this.ignoregoal && time < this.ignoregoaltime) )
29                         continue;
30
31                 // Check if the item can be picked up safely
32                 if(it.classname == "droppedweapon")
33                 {
34                         traceline(o, o + '0 0 -1500', true, NULL);
35
36                         d = pointcontents(trace_endpos + '0 0 1');
37                         if(d & CONTENT_WATER || d & CONTENT_SLIME || d & CONTENT_LAVA)
38                                 continue;
39                         if(tracebox_hits_trigger_hurt(it.origin, it.mins, it.maxs, trace_endpos))
40                                 continue;
41                 }
42                 else
43                 {
44                         // Ignore items under water
45                         traceline(it.origin + it.maxs, it.origin + it.maxs, MOVE_NORMAL, it);
46                         if(trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
47                                 continue;
48                 }
49
50                 if(teamplay)
51                 {
52                         discard = false;
53
54                         entity picker = it;
55                         FOREACH_CLIENT(IS_PLAYER(it) && it != this && !IS_DEAD(it),
56                         {
57                                 d = vlen(it.origin - o); // distance between player and item
58
59                                 if ( it.team == this.team )
60                                 {
61                                         if ( !IS_REAL_CLIENT(it) || discard )
62                                                 continue;
63
64                                         if( d > friend_distance)
65                                                 continue;
66
67                                         friend_distance = d;
68
69                                         discard = true;
70
71                                         if( picker.health && it.health > this.health )
72                                                 continue;
73
74                                         if( picker.armorvalue && it.armorvalue > this.armorvalue)
75                                                 continue;
76
77                                         if( picker.weapons )
78                                         if( picker.weapons & ~it.weapons )
79                                                 continue;
80
81                                         if (picker.ammo_shells && it.ammo_shells > this.ammo_shells)
82                                                 continue;
83
84                                         if (picker.ammo_nails && it.ammo_nails > this.ammo_nails)
85                                                 continue;
86
87                                         if (picker.ammo_rockets && it.ammo_rockets > this.ammo_rockets)
88                                                 continue;
89
90                                         if (picker.ammo_cells && it.ammo_cells > this.ammo_cells)
91                                                 continue;
92
93                                         if (picker.ammo_plasma && it.ammo_plasma > this.ammo_plasma)
94                                                 continue;
95
96                                         discard = false;
97                                 }
98                                 else
99                                 {
100                                         // If enemy only track distances
101                                         // TODO: track only if visible ?
102                                         if( d < enemy_distance )
103                                                 enemy_distance = d;
104                                 }
105                         });
106
107                         // Rate the item only if no one needs it, or if an enemy is closer to it
108                         if ( (enemy_distance < friend_distance && vdist(o - org, <, enemy_distance)) ||
109                                 (friend_distance > autocvar_bot_ai_friends_aware_pickup_radius ) || !discard )
110                                 rating = it.bot_pickupevalfunc(this, it);
111
112                 }
113                 else
114                         rating = it.bot_pickupevalfunc(this, it);
115
116                 if(rating > 0)
117                         navigation_routerating(this, it, rating * ratingscale, 2000);
118         });
119 }
120
121 void havocbot_goalrating_enemyplayers(entity this, float ratingscale, vector org, float sradius)
122 {
123         if (autocvar_bot_nofire)
124                 return;
125
126         // don't chase players if we're under water
127         if(this.waterlevel>WATERLEVEL_WETFEET)
128                 return;
129
130         int t;
131
132         FOREACH_CLIENT(IS_PLAYER(it) && bot_shouldattack(this, it), LAMBDA(
133                 // TODO: Merge this logic with the bot_shouldattack function
134                 if(vdist(it.origin - org, <, 100) || vdist(it.origin - org, >, sradius))
135                         continue;
136
137                 // rate only visible enemies
138                 /*
139                 traceline(this.origin + this.view_ofs, it.origin, MOVE_NOMONSTERS, this);
140                 if (trace_fraction < 1 || trace_ent != it)
141                         continue;
142                 */
143
144                 if((it.flags & FL_INWATER) || (it.flags & FL_PARTIALGROUND))
145                         continue;
146
147                 // not falling
148                 if((IS_ONGROUND(it)) == 0)
149                 {
150                         traceline(it.origin, it.origin + '0 0 -1500', true, NULL);
151                         t = pointcontents(trace_endpos + '0 0 1');
152                         if(t != CONTENT_SOLID )
153                         if(t & CONTENT_WATER || t & CONTENT_SLIME || t & CONTENT_LAVA)
154                                 continue;
155                         if(tracebox_hits_trigger_hurt(it.origin, it.mins, it.maxs, trace_endpos))
156                                 continue;
157                 }
158
159                 // TODO: rate waypoints near the targetted player at that moment, instead of the player itthis
160                 //               adding a player as a goal seems to be quite dangerous, especially on space maps
161                 //               remove hack in navigation_poptouchedgoals() after performing this change
162
163                 t = (this.health + this.armorvalue ) / (it.health + it.armorvalue );
164                 navigation_routerating(this, it, t * ratingscale, 2000);
165         ));
166 }
167
168 // legacy bot role for standard gamemodes
169 // go to best items
170 void havocbot_role_generic(entity this)
171 {
172         if(IS_DEAD(this))
173                 return;
174
175         if (this.bot_strategytime < time)
176         {
177                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
178                 navigation_goalrating_start(this);
179                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
180                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
181                 //havocbot_goalrating_waypoints(1, this.origin, 1000);
182                 navigation_goalrating_end(this);
183         }
184 }
185
186 void havocbot_chooserole_generic(entity this)
187 {
188         this.havocbot_role = havocbot_role_generic;
189 }
190
191 void havocbot_chooserole(entity this)
192 {
193         LOG_TRACE("choosing a role...");
194         this.bot_strategytime = 0;
195         if(!MUTATOR_CALLHOOK(HavocBot_ChooseRole, this))
196                 havocbot_chooserole_generic(this);
197 }