qcsrc/server/bot/default/navigation.qc

   1 #include "navigation.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "waypoints.qh"
   7
   8 #include <common/t_items.qh>
   9
  10 #include <common/items/_mod.qh>
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/triggers/trigger/jumppads.qh>
  15
  16 .float speed;
  17
  18 void navigation_dynamicgoal_init(entity this, bool initially_static)
  19 {
  20         this.navigation_dynamicgoal = true;
  21         this.bot_basewaypoint = this.nearestwaypoint;
  22         if(initially_static)
  23                 this.nearestwaypointtimeout = -1;
  24         else
  25                 this.nearestwaypointtimeout = time;
  26 }
  27
  28 void navigation_dynamicgoal_set(entity this)
  29 {
  30         this.nearestwaypointtimeout = time;
  31 }
  32
  33 void navigation_dynamicgoal_unset(entity this)
  34 {
  35         if(this.bot_basewaypoint)
  36                 this.nearestwaypoint = this.bot_basewaypoint;
  37         this.nearestwaypointtimeout = -1;
  38 }
  39
  40 // rough simulation of walking from one point to another to test if a path
  41 // can be traveled, used for waypoint linking and havocbot
  42
  43 bool tracewalk(entity e, vector start, vector m1, vector m2, vector end, float movemode)
  44 {
  45         vector org;
  46         vector move;
  47         vector dir;
  48         float dist;
  49         float totaldist;
  50         float stepdist;
  51         float ignorehazards;
  52         float swimming;
  53
  54         if(autocvar_bot_debug_tracewalk)
  55         {
  56                 debugresetnodes();
  57                 debugnode(e, start);
  58         }
  59
  60         move = end - start;
  61         move.z = 0;
  62         org = start;
  63         dist = totaldist = vlen(move);
  64         dir = normalize(move);
  65         stepdist = 32;
  66         ignorehazards = false;
  67         swimming = false;
  68
  69         // Analyze starting point
  70         traceline(start, start, MOVE_NORMAL, e);
  71         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  72                 ignorehazards = true;
  73         else
  74         {
  75                 traceline( start, start + '0 0 -65536', MOVE_NORMAL, e);
  76                 if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  77                 {
  78                         ignorehazards = true;
  79                         swimming = true;
  80                 }
  81         }
  82         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
  83         if (trace_startsolid)
  84         {
  85                 // Bad start
  86                 if(autocvar_bot_debug_tracewalk)
  87                         debugnodestatus(start, DEBUG_NODE_FAIL);
  88
  89                 //print("tracewalk: ", vtos(start), " is a bad start\n");
  90                 return false;
  91         }
  92
  93         // Movement loop
  94         move = end - org;
  95         for (;;)
  96         {
  97                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
  98                 {
  99                         // Succeeded
 100                         if(autocvar_bot_debug_tracewalk)
 101                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
 102
 103                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 104                         return true;
 105                 }
 106                 if(autocvar_bot_debug_tracewalk)
 107                         debugnode(e, org);
 108
 109                 if (dist <= 0)
 110                         break;
 111                 if (stepdist > dist)
 112                         stepdist = dist;
 113                 dist = dist - stepdist;
 114                 traceline(org, org, MOVE_NORMAL, e);
 115                 if (!ignorehazards)
 116                 {
 117                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 118                         {
 119                                 // hazards blocking path
 120                                 if(autocvar_bot_debug_tracewalk)
 121                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 122
 123                                 //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 124                                 return false;
 125                         }
 126                 }
 127                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 128                 {
 129                         move = normalize(end - org);
 130                         tracebox(org, m1, m2, org + move * stepdist, movemode, e);
 131
 132                         if(autocvar_bot_debug_tracewalk)
 133                                 debugnode(e, trace_endpos);
 134
 135                         if (trace_fraction < 1)
 136                         {
 137                                 swimming = true;
 138                                 org = trace_endpos + normalize(org - trace_endpos) * stepdist;
 139                                 for (; org.z < end.z + e.maxs.z; org.z += stepdist)
 140                                 {
 141                                         if(autocvar_bot_debug_tracewalk)
 142                                                 debugnode(e, org);
 143
 144                                         if(pointcontents(org) == CONTENT_EMPTY)
 145                                                 break;
 146                                 }
 147
 148                                 if(pointcontents(org + '0 0 1') != CONTENT_EMPTY)
 149                                 {
 150                                         if(autocvar_bot_debug_tracewalk)
 151                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 152
 153                                         return false;
 154                                         //print("tracewalk: ", vtos(start), " failed under water\n");
 155                                 }
 156                                 continue;
 157
 158                         }
 159                         else
 160                                 org = trace_endpos;
 161                 }
 162                 else
 163                 {
 164                         move = dir * stepdist + org;
 165                         tracebox(org, m1, m2, move, movemode, e);
 166
 167                         if(autocvar_bot_debug_tracewalk)
 168                                 debugnode(e, trace_endpos);
 169
 170                         // hit something
 171                         if (trace_fraction < 1)
 172                         {
 173                                 // check if we can walk over this obstacle, possibly by jumpstepping
 174                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 175                                 if (trace_fraction < 1 || trace_startsolid)
 176                                 {
 177                                         tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 178                                         if (trace_fraction < 1 || trace_startsolid)
 179                                         {
 180                                                 bool ladder_found = false;
 181                                                 FOREACH_ENTITY_CLASS("func_ladder", true,
 182                                                 {
 183                                                         if(boxesoverlap(org + jumpheight_vec + m1 + '-1 -1 -1', org + jumpheight_vec + m2 + '1 1 1', it.absmin, it.absmax))
 184                                                         if(boxesoverlap(end, end, it.absmin + (m1 - eZ * m1.z - '1 1 0'), it.absmax + (m2 - eZ * m2.z + '1 1 0')))
 185                                                                 ladder_found = true; // can't return here ("Loop mutex held by tracewalk" error)
 186                                                 });
 187                                                 if(ladder_found)
 188                                                 {
 189                                                         if(autocvar_bot_debug_tracewalk)
 190                                                                 debugnodestatus(end, DEBUG_NODE_SUCCESS);
 191
 192                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 193                                                         return true;
 194                                                 }
 195
 196                                                 if(autocvar_bot_debug_tracewalk)
 197                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 198
 199                                                 traceline( org, move, movemode, e);
 200
 201                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 202                                                 {
 203                                                         vector nextmove;
 204                                                         move = trace_endpos;
 205                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 206                                                         {
 207                                                                 nextmove = move + (dir * stepdist);
 208                                                                 traceline( move, nextmove, movemode, e);
 209                                                                 move = nextmove;
 210                                                         }
 211                                                 }
 212                                                 else
 213                                                 {
 214                                                         if(autocvar_bot_debug_tracewalk)
 215                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 216
 217                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 218                                                         //te_explosion(trace_endpos);
 219                                                         //print(ftos(e.dphitcontentsmask), "\n");
 220                                                         return false; // failed
 221                                                 }
 222                                         }
 223                                         else
 224                                                 move = trace_endpos;
 225                                 }
 226                                 else
 227                                         move = trace_endpos;
 228                         }
 229                         else
 230                                 move = trace_endpos;
 231
 232                         // trace down from stepheight as far as possible and move there,
 233                         // if this starts in solid we try again without the stepup, and
 234                         // if that also fails we assume it is a wall
 235                         // (this is the same logic as the Quake walkmove function used)
 236                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 237
 238                         // moved successfully
 239                         if(swimming)
 240                         {
 241                                 float c;
 242                                 c = pointcontents(org + '0 0 1');
 243                                 if (!(c == CONTENT_WATER || c == CONTENT_LAVA || c == CONTENT_SLIME))
 244                                         swimming = false;
 245                                 else
 246                                         continue;
 247                         }
 248
 249                         org = trace_endpos;
 250                 }
 251         }
 252
 253         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 254
 255         // moved but didn't arrive at the intended destination
 256         if(autocvar_bot_debug_tracewalk)
 257                 debugnodestatus(org, DEBUG_NODE_FAIL);
 258
 259         return false;
 260 }
 261
 262 /////////////////////////////////////////////////////////////////////////////
 263 // goal stack
 264 /////////////////////////////////////////////////////////////////////////////
 265
 266 // completely empty the goal stack, used when deciding where to go
 267 void navigation_clearroute(entity this)
 268 {
 269         //print("bot ", etos(this), " clear\n");
 270         this.goalentity = NULL;
 271         this.goalcurrent = NULL;
 272         this.goalstack01 = NULL;
 273         this.goalstack02 = NULL;
 274         this.goalstack03 = NULL;
 275         this.goalstack04 = NULL;
 276         this.goalstack05 = NULL;
 277         this.goalstack06 = NULL;
 278         this.goalstack07 = NULL;
 279         this.goalstack08 = NULL;
 280         this.goalstack09 = NULL;
 281         this.goalstack10 = NULL;
 282         this.goalstack11 = NULL;
 283         this.goalstack12 = NULL;
 284         this.goalstack13 = NULL;
 285         this.goalstack14 = NULL;
 286         this.goalstack15 = NULL;
 287         this.goalstack16 = NULL;
 288         this.goalstack17 = NULL;
 289         this.goalstack18 = NULL;
 290         this.goalstack19 = NULL;
 291         this.goalstack20 = NULL;
 292         this.goalstack21 = NULL;
 293         this.goalstack22 = NULL;
 294         this.goalstack23 = NULL;
 295         this.goalstack24 = NULL;
 296         this.goalstack25 = NULL;
 297         this.goalstack26 = NULL;
 298         this.goalstack27 = NULL;
 299         this.goalstack28 = NULL;
 300         this.goalstack29 = NULL;
 301         this.goalstack30 = NULL;
 302         this.goalstack31 = NULL;
 303 }
 304
 305 // add a new goal at the beginning of the stack
 306 // (in other words: add a new prerequisite before going to the later goals)
 307 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 308 // next-closest WP on the shortest path to the WP
 309 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 310 // steps to the goal, and then recalculate the path.
 311 void navigation_pushroute(entity this, entity e)
 312 {
 313         //print("bot ", etos(this), " push ", etos(e), "\n");
 314         if(this.goalstack31 == this.goalentity)
 315                 this.goalentity = NULL;
 316         this.goalstack31 = this.goalstack30;
 317         this.goalstack30 = this.goalstack29;
 318         this.goalstack29 = this.goalstack28;
 319         this.goalstack28 = this.goalstack27;
 320         this.goalstack27 = this.goalstack26;
 321         this.goalstack26 = this.goalstack25;
 322         this.goalstack25 = this.goalstack24;
 323         this.goalstack24 = this.goalstack23;
 324         this.goalstack23 = this.goalstack22;
 325         this.goalstack22 = this.goalstack21;
 326         this.goalstack21 = this.goalstack20;
 327         this.goalstack20 = this.goalstack19;
 328         this.goalstack19 = this.goalstack18;
 329         this.goalstack18 = this.goalstack17;
 330         this.goalstack17 = this.goalstack16;
 331         this.goalstack16 = this.goalstack15;
 332         this.goalstack15 = this.goalstack14;
 333         this.goalstack14 = this.goalstack13;
 334         this.goalstack13 = this.goalstack12;
 335         this.goalstack12 = this.goalstack11;
 336         this.goalstack11 = this.goalstack10;
 337         this.goalstack10 = this.goalstack09;
 338         this.goalstack09 = this.goalstack08;
 339         this.goalstack08 = this.goalstack07;
 340         this.goalstack07 = this.goalstack06;
 341         this.goalstack06 = this.goalstack05;
 342         this.goalstack05 = this.goalstack04;
 343         this.goalstack04 = this.goalstack03;
 344         this.goalstack03 = this.goalstack02;
 345         this.goalstack02 = this.goalstack01;
 346         this.goalstack01 = this.goalcurrent;
 347         this.goalcurrent = e;
 348 }
 349
 350 // remove first goal from stack
 351 // (in other words: remove a prerequisite for reaching the later goals)
 352 // (used when a spawnfunc_waypoint is reached)
 353 void navigation_poproute(entity this)
 354 {
 355         //print("bot ", etos(this), " pop\n");
 356         if(this.goalcurrent == this.goalentity)
 357                 this.goalentity = NULL;
 358         this.goalcurrent = this.goalstack01;
 359         this.goalstack01 = this.goalstack02;
 360         this.goalstack02 = this.goalstack03;
 361         this.goalstack03 = this.goalstack04;
 362         this.goalstack04 = this.goalstack05;
 363         this.goalstack05 = this.goalstack06;
 364         this.goalstack06 = this.goalstack07;
 365         this.goalstack07 = this.goalstack08;
 366         this.goalstack08 = this.goalstack09;
 367         this.goalstack09 = this.goalstack10;
 368         this.goalstack10 = this.goalstack11;
 369         this.goalstack11 = this.goalstack12;
 370         this.goalstack12 = this.goalstack13;
 371         this.goalstack13 = this.goalstack14;
 372         this.goalstack14 = this.goalstack15;
 373         this.goalstack15 = this.goalstack16;
 374         this.goalstack16 = this.goalstack17;
 375         this.goalstack17 = this.goalstack18;
 376         this.goalstack18 = this.goalstack19;
 377         this.goalstack19 = this.goalstack20;
 378         this.goalstack20 = this.goalstack21;
 379         this.goalstack21 = this.goalstack22;
 380         this.goalstack22 = this.goalstack23;
 381         this.goalstack23 = this.goalstack24;
 382         this.goalstack24 = this.goalstack25;
 383         this.goalstack25 = this.goalstack26;
 384         this.goalstack26 = this.goalstack27;
 385         this.goalstack27 = this.goalstack28;
 386         this.goalstack28 = this.goalstack29;
 387         this.goalstack29 = this.goalstack30;
 388         this.goalstack30 = this.goalstack31;
 389         this.goalstack31 = NULL;
 390 }
 391
 392 float navigation_waypoint_will_link(vector v, vector org, entity ent, float walkfromwp, float bestdist)
 393 {
 394         float dist;
 395         dist = vlen(v - org);
 396         if (bestdist > dist)
 397         {
 398                 traceline(v, org, true, ent);
 399                 if (trace_fraction == 1)
 400                 {
 401                         if (walkfromwp)
 402                         {
 403                                 if (tracewalk(ent, v, PL_MIN_CONST, PL_MAX_CONST, org, bot_navigation_movemode))
 404                                         return true;
 405                         }
 406                         else
 407                         {
 408                                 if (tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, v, bot_navigation_movemode))
 409                                         return true;
 410                         }
 411                 }
 412         }
 413         return false;
 414 }
 415
 416 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 417 entity navigation_findnearestwaypoint_withdist_except(entity ent, float walkfromwp, float bestdist, entity except)
 418 {
 419         vector pm1 = ent.origin + ent.mins;
 420         vector pm2 = ent.origin + ent.maxs;
 421
 422         // do two scans, because box test is cheaper
 423         IL_EACH(g_waypoints, it != ent && it != except,
 424         {
 425                 if(boxesoverlap(pm1, pm2, it.absmin, it.absmax))
 426                         return it;
 427         });
 428
 429         vector org = ent.origin + 0.5 * (ent.mins + ent.maxs);
 430         org.z = ent.origin.z + ent.mins.z - PL_MIN_CONST.z; // player height
 431         // TODO possibly make other code have the same support for bboxes
 432         if(ent.tag_entity)
 433                 org = org + ent.tag_entity.origin;
 434         if (navigation_testtracewalk)
 435                 te_plasmaburn(org);
 436
 437         entity best = NULL;
 438         vector v;
 439
 440         if(!autocvar_g_waypointeditor && !ent.navigation_dynamicgoal)
 441         {
 442                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 443                 IL_EACH(g_waypoints, it != ent,
 444                 {
 445                         if(it.wpisbox)
 446                         {
 447                                 vector wm1 = it.absmin;
 448                                 vector wm2 = it.absmax;
 449                                 v.x = bound(wm1_x, org.x, wm2_x);
 450                                 v.y = bound(wm1_y, org.y, wm2_y);
 451                                 v.z = bound(wm1_z, org.z, wm2_z);
 452                         }
 453                         else
 454                                 v = it.origin;
 455                         if(navigation_waypoint_will_link(v, org, ent, walkfromwp, 1050))
 456                                 navigation_item_addlink(it, ent);
 457                 });
 458         }
 459
 460         // box check failed, try walk
 461         IL_EACH(g_waypoints, it != ent,
 462         {
 463                 if(it.wpisbox)
 464                 {
 465                         vector wm1 = it.origin + it.mins;
 466                         vector wm2 = it.origin + it.maxs;
 467                         v.x = bound(wm1_x, org.x, wm2_x);
 468                         v.y = bound(wm1_y, org.y, wm2_y);
 469                         v.z = bound(wm1_z, org.z, wm2_z);
 470                 }
 471                 else
 472                         v = it.origin;
 473                 if(navigation_waypoint_will_link(v, org, ent, walkfromwp, bestdist))
 474                 {
 475                         bestdist = vlen(v - org);
 476                         best = it;
 477                 }
 478         });
 479         return best;
 480 }
 481 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 482 {
 483         entity wp = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, NULL);
 484         if (autocvar_g_waypointeditor_auto)
 485         {
 486                 entity wp2 = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, wp);
 487                 if (wp && !wp2)
 488                         wp.wpflags |= WAYPOINTFLAG_PROTECTED;
 489         }
 490         return wp;
 491 }
 492
 493 // finds the waypoints near the bot initiating a navigation query
 494 float navigation_markroutes_nearestwaypoints(entity this, float maxdist)
 495 {
 496         vector v, m1, m2;
 497 //      navigation_testtracewalk = true;
 498         int c = 0;
 499         IL_EACH(g_waypoints, !it.wpconsidered,
 500         {
 501                 if (it.wpisbox)
 502                 {
 503                         m1 = it.origin + it.mins;
 504                         m2 = it.origin + it.maxs;
 505                         v = this.origin;
 506                         v.x = bound(m1_x, v.x, m2_x);
 507                         v.y = bound(m1_y, v.y, m2_y);
 508                         v.z = bound(m1_z, v.z, m2_z);
 509                 }
 510                 else
 511                         v = it.origin;
 512                 vector diff = v - this.origin;
 513                 diff.z = max(0, diff.z);
 514                 if(vdist(diff, <, maxdist))
 515                 {
 516                         it.wpconsidered = true;
 517                         if (tracewalk(this, this.origin, this.mins, this.maxs, v, bot_navigation_movemode))
 518                         {
 519                                 it.wpnearestpoint = v;
 520                                 it.wpcost = waypoint_getdistancecost(this.origin, v) + it.dmg;
 521                                 it.wpfire = 1;
 522                                 it.enemy = NULL;
 523                                 c = c + 1;
 524                         }
 525                 }
 526         });
 527         //navigation_testtracewalk = false;
 528         return c;
 529 }
 530
 531 // updates a path link if a spawnfunc_waypoint link is better than the current one
 532 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost, vector p)
 533 {
 534         vector m1;
 535         vector m2;
 536         vector v;
 537         if (wp.wpisbox)
 538         {
 539                 m1 = wp.absmin;
 540                 m2 = wp.absmax;
 541                 v.x = bound(m1_x, p.x, m2_x);
 542                 v.y = bound(m1_y, p.y, m2_y);
 543                 v.z = bound(m1_z, p.z, m2_z);
 544         }
 545         else
 546                 v = wp.origin;
 547         if (w.wpflags & WAYPOINTFLAG_TELEPORT)
 548                 cost += w.wp00mincost; // assuming teleport has exactly one destination
 549         else
 550                 cost += waypoint_getdistancecost(p, v);
 551         if (wp.wpcost > cost)
 552         {
 553                 wp.wpcost = cost;
 554                 wp.enemy = w;
 555                 wp.wpfire = 1;
 556                 wp.wpnearestpoint = v;
 557         }
 558 }
 559
 560 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 561 void navigation_markroutes(entity this, entity fixed_source_waypoint)
 562 {
 563         float cost, cost2;
 564         vector p;
 565
 566         IL_EACH(g_waypoints, true,
 567         {
 568                 it.wpconsidered = false;
 569                 it.wpnearestpoint = '0 0 0';
 570                 it.wpcost = 10000000;
 571                 it.wpfire = 0;
 572                 it.enemy = NULL;
 573         });
 574
 575         if(fixed_source_waypoint)
 576         {
 577                 fixed_source_waypoint.wpconsidered = true;
 578                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 579                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 580                 fixed_source_waypoint.wpfire = 1;
 581                 fixed_source_waypoint.enemy = NULL;
 582         }
 583         else
 584         {
 585                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 586                 // as this search is expensive we will use lower values if the bot is on the air
 587                 float increment, maxdistance;
 588                 if(IS_ONGROUND(this))
 589                 {
 590                         increment = 750;
 591                         maxdistance = 50000;
 592                 }
 593                 else
 594                 {
 595                         increment = 500;
 596                         maxdistance = 1500;
 597                 }
 598
 599                 for(int j = increment; !navigation_markroutes_nearestwaypoints(this, j) && j < maxdistance; j += increment);
 600         }
 601
 602         bool searching = true;
 603         while (searching)
 604         {
 605                 searching = false;
 606                 IL_EACH(g_waypoints, it.wpfire,
 607                 {
 608                         searching = true;
 609                         it.wpfire = 0;
 610                         cost = it.wpcost;
 611                         p = it.wpnearestpoint;
 612                         entity wp;
 613                         wp = it.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp00mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 614                         wp = it.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp01mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 615                         wp = it.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp02mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 616                         wp = it.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp03mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 617                         wp = it.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp04mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 618                         wp = it.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp05mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 619                         wp = it.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp06mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 620                         wp = it.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp07mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 621                         wp = it.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp08mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 622                         wp = it.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp09mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 623                         wp = it.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp10mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 624                         wp = it.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp11mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 625                         wp = it.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp12mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 626                         wp = it.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp13mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 627                         wp = it.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp14mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 628                         wp = it.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp15mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 629                         wp = it.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp16mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 630                         wp = it.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp17mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 631                         wp = it.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp18mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 632                         wp = it.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp19mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 633                         wp = it.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp20mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 634                         wp = it.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp21mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 635                         wp = it.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp22mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 636                         wp = it.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp23mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 637                         wp = it.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp24mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 638                         wp = it.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp25mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 639                         wp = it.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp26mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 640                         wp = it.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp27mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 641                         wp = it.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp28mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 642                         wp = it.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp29mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 643                         wp = it.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp30mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 644                         wp = it.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp31mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 645                         }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 646                 });
 647         }
 648 }
 649
 650 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 651 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 652 {
 653         float cost, cost2;
 654         vector p;
 655         IL_EACH(g_waypoints, true,
 656         {
 657                 it.wpconsidered = false;
 658                 it.wpnearestpoint = '0 0 0';
 659                 it.wpcost = 10000000;
 660                 it.wpfire = 0;
 661                 it.enemy = NULL;
 662         });
 663
 664         if(fixed_source_waypoint)
 665         {
 666                 fixed_source_waypoint.wpconsidered = true;
 667                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 668                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
 669                 fixed_source_waypoint.wpfire = 1;
 670                 fixed_source_waypoint.enemy = NULL;
 671         }
 672         else
 673         {
 674                 error("need to start with a waypoint\n");
 675         }
 676
 677         bool searching = true;
 678         while (searching)
 679         {
 680                 searching = false;
 681                 IL_EACH(g_waypoints, it.wpfire,
 682                 {
 683                         searching = true;
 684                         it.wpfire = 0;
 685                         cost = it.wpcost; // cost to walk from it to home
 686                         p = it.wpnearestpoint;
 687                         entity wp = it;
 688                         IL_EACH(g_waypoints, it != wp,
 689                         {
 690                                 if(!waypoint_islinked(it, wp))
 691                                         continue;
 692                                 cost2 = cost + it.dmg;
 693                                 navigation_markroutes_checkwaypoint(wp, it, cost2, p);
 694                         });
 695                 });
 696         }
 697 }
 698
 699 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
 700 void navigation_routerating(entity this, entity e, float f, float rangebias)
 701 {
 702         if (!e)
 703                 return;
 704
 705         if(e.blacklisted)
 706                 return;
 707
 708         rangebias = waypoint_getdistancecost_simple(rangebias);
 709         f = waypoint_getdistancecost_simple(f);
 710
 711         if (IS_PLAYER(e))
 712         {
 713                 bool rate_wps = false;
 714                 if((e.flags & FL_INWATER) || (e.flags & FL_PARTIALGROUND))
 715                         rate_wps = true;
 716
 717                 if(!IS_ONGROUND(e))
 718                 {
 719                         traceline(e.origin, e.origin + '0 0 -1500', true, NULL);
 720                         int t = pointcontents(trace_endpos + '0 0 1');
 721                         if(t != CONTENT_SOLID )
 722                         {
 723                                 if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
 724                                         rate_wps = true;
 725                                 else if(tracebox_hits_trigger_hurt(e.origin, e.mins, e.maxs, trace_endpos))
 726                                         return;
 727                         }
 728                 }
 729
 730                 if(rate_wps)
 731                 {
 732                         entity theEnemy = e;
 733                         entity best_wp = NULL;
 734                         float best_dist = 10000;
 735                         IL_EACH(g_waypoints, vdist(it.origin - theEnemy.origin, <, 500)
 736                                 && vdist(it.origin - this.origin, >, 100)
 737                                 && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 738                         {
 739                                 float dist = vlen(it.origin - theEnemy.origin);
 740                                 if (dist < best_dist)
 741                                 {
 742                                         best_wp = it;
 743                                         best_dist = dist;
 744                                 }
 745                         });
 746                         if (!best_wp)
 747                                 return;
 748                         e = best_wp;
 749                 }
 750         }
 751
 752         vector goal_org = (e.absmin + e.absmax) * 0.5;
 753
 754         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
 755
 756         // Evaluate path using jetpack
 757         if(g_jetpack)
 758         if(this.items & IT_JETPACK)
 759         if(autocvar_bot_ai_navigation_jetpack)
 760         if(vdist(this.origin - goal_org, >, autocvar_bot_ai_navigation_jetpack_mindistance))
 761         {
 762                 vector pointa, pointb;
 763
 764                 LOG_DEBUG("jetpack ai: evaluating path for ", e.classname);
 765
 766                 // Point A
 767                 traceline(this.origin, this.origin + '0 0 65535', MOVE_NORMAL, this);
 768                 pointa = trace_endpos - '0 0 1';
 769
 770                 // Point B
 771                 traceline(goal_org, goal_org + '0 0 65535', MOVE_NORMAL, e);
 772                 pointb = trace_endpos - '0 0 1';
 773
 774                 // Can I see these two points from the sky?
 775                 traceline(pointa, pointb, MOVE_NORMAL, this);
 776
 777                 if(trace_fraction==1)
 778                 {
 779                         LOG_DEBUG("jetpack ai: can bridge these two points");
 780
 781                         // Lower the altitude of these points as much as possible
 782                         float zdistance, xydistance, cost, t, fuel;
 783                         vector down, npa, npb;
 784
 785                         down = '0 0 -1' * (STAT(PL_MAX, this).z - STAT(PL_MIN, this).z) * 10;
 786
 787                         do{
 788                                 npa = pointa + down;
 789                                 npb = pointb + down;
 790
 791                                 if(npa.z<=this.absmax.z)
 792                                         break;
 793
 794                                 if(npb.z<=e.absmax.z)
 795                                         break;
 796
 797                                 traceline(npa, npb, MOVE_NORMAL, this);
 798                                 if(trace_fraction==1)
 799                                 {
 800                                         pointa = npa;
 801                                         pointb = npb;
 802                                 }
 803                         }
 804                         while(trace_fraction == 1);
 805
 806
 807                         // Rough estimation of fuel consumption
 808                         // (ignores acceleration and current xyz velocity)
 809                         xydistance = vlen(pointa - pointb);
 810                         zdistance = fabs(pointa.z - this.origin.z);
 811
 812                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
 813                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
 814                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
 815
 816                         LOG_DEBUG("jetpack ai: required fuel ", ftos(fuel), " this.ammo_fuel ", ftos(this.ammo_fuel));
 817
 818                         // enough fuel ?
 819                         if(this.ammo_fuel>fuel)
 820                         {
 821                                 // Estimate cost
 822                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
 823                                 //  - between air and ground speeds)
 824
 825                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
 826                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
 827                                 cost *= 1.5;
 828
 829                                 // Compare against other goals
 830                                 f = f * rangebias / (rangebias + cost);
 831
 832                                 if (navigation_bestrating < f)
 833                                 {
 834                                         LOG_DEBUG("jetpack path: added goal ", e.classname, " (with rating ", ftos(f), ")");
 835                                         navigation_bestrating = f;
 836                                         navigation_bestgoal = e;
 837                                         this.navigation_jetpack_goal = e;
 838                                         this.navigation_jetpack_point = pointb;
 839                                 }
 840                                 return;
 841                         }
 842                 }
 843         }
 844
 845         entity nwp;
 846         //te_wizspike(e.origin);
 847         //bprint(etos(e));
 848         //bprint("\n");
 849         // update the cached spawnfunc_waypoint link on a dynamic item entity
 850         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
 851         {
 852                 nwp = e;
 853         }
 854         else
 855         {
 856                 if(autocvar_g_waypointeditor && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
 857                         e.nearestwaypoint = NULL;
 858
 859                 if ((!e.nearestwaypoint || e.navigation_dynamicgoal)
 860                         && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
 861                 {
 862                         nwp = navigation_findnearestwaypoint(e, true);
 863                         if(nwp)
 864                         {
 865                                 e.nearestwaypoint = nwp;
 866
 867                                 vector m1 = nwp.absmin, m2 = nwp.absmax;
 868                                 m1.x = nwp.origin.x; m1.y = nwp.origin.y;
 869                                 m2.x = nwp.origin.x; m2.y = nwp.origin.y;
 870                                 vector ve = (e.absmin - e.absmax) * 0.5;
 871                                 ve.x = bound(m1.x, ve.x, m2.x);
 872                                 ve.y = bound(m1.y, ve.y, m2.y);
 873                                 ve.z = bound(m1.z, ve.z, m2.z);
 874
 875                                 m1 = e.absmin; m2 = e.absmax;
 876                                 m1.x = e.origin.x; m1.y = e.origin.y;
 877                                 m2.x = e.origin.x; m2.y = e.origin.y;
 878                                 vector vnwp = nwp.origin;
 879                                 vnwp.x = bound(m1.x, vnwp.x, m2.x);
 880                                 vnwp.y = bound(m1.y, vnwp.y, m2.y);
 881                                 vnwp.z = bound(m1.z, vnwp.z, m2.z);
 882                                 e.nearestwaypoint_dist = vlen(ve - vnwp);
 883                         }
 884                         else
 885                         {
 886                                 LOG_DEBUG("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e));
 887
 888                                 if(!e.navigation_dynamicgoal)
 889                                         e.blacklisted = true;
 890
 891                                 if(e.blacklisted)
 892                                 {
 893                                         LOG_DEBUG("The entity '", e.classname, "' is going to be excluded from path finding during this match");
 894                                         return;
 895                                 }
 896                         }
 897
 898                         if(e.navigation_dynamicgoal)
 899                                 e.nearestwaypointtimeout = time + 2;
 900                         else if(autocvar_g_waypointeditor)
 901                                 e.nearestwaypointtimeout = time + 3 + random() * 2;
 902                 }
 903                 nwp = e.nearestwaypoint;
 904         }
 905
 906         LOG_DEBUG("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")");
 907         if (nwp)
 908         if (nwp.wpcost < 10000000)
 909         {
 910                 //te_wizspike(nwp.wpnearestpoint);
 911                 float cost = nwp.wpcost + waypoint_getdistancecost(nwp.wpnearestpoint, goal_org);
 912                 LOG_DEBUG(e.classname, " ", ftos(f), "/(1+", ftos(cost), "/", ftos(rangebias), ") = ");
 913                 f = f * rangebias / (rangebias + cost);
 914                 LOG_DEBUG("considering ", e.classname, " (with rating ", ftos(f), ")");
 915                 if (navigation_bestrating < f)
 916                 {
 917                         LOG_DEBUG("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")");
 918                         navigation_bestrating = f;
 919                         navigation_bestgoal = e;
 920                 }
 921         }
 922 }
 923
 924 // adds an item to the the goal stack with the path to a given item
 925 bool navigation_routetogoal(entity this, entity e, vector startposition)
 926 {
 927         // if there is no goal, just exit
 928         if (!e)
 929                 return false;
 930
 931         if(e.wpflags & WAYPOINTFLAG_TELEPORT)
 932         {
 933                 // force teleport destination as route destination
 934                 e.wp00.enemy = e;
 935                 e = e.wp00;
 936         }
 937
 938         this.goalentity = e;
 939
 940         // put the entity on the goal stack
 941         //print("routetogoal ", etos(e), "\n");
 942         navigation_pushroute(this, e);
 943
 944         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
 945         {
 946                 this.wp_goal_prev1 = this.wp_goal_prev0;
 947                 this.wp_goal_prev0 = e;
 948         }
 949
 950         if(g_jetpack)
 951         if(e==this.navigation_jetpack_goal)
 952                 return true;
 953
 954         // if it can reach the goal there is nothing more to do
 955         if (tracewalk(this, startposition, STAT(PL_MIN, this), STAT(PL_MAX, this), (e.absmin + e.absmax) * 0.5, bot_navigation_movemode))
 956                 return true;
 957
 958         entity nearest_wp = NULL;
 959         // see if there are waypoints describing a path to the item
 960         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
 961         {
 962                 e = e.nearestwaypoint;
 963                 nearest_wp = e;
 964         }
 965         else
 966                 e = e.enemy; // we already have added it, so...
 967
 968         if(e == NULL)
 969                 return false;
 970
 971         if(nearest_wp && nearest_wp.enemy)
 972         {
 973                 // often path can be optimized by not adding the nearest waypoint
 974                 if (this.goalentity.nearestwaypoint_dist < 8
 975                         || (!this.goalentity.navigation_dynamicgoal && navigation_item_islinked(nearest_wp.enemy, this.goalentity))
 976                         || (this.goalentity.navigation_dynamicgoal && tracewalk(this, nearest_wp.enemy.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), (this.goalentity.absmin + this.goalentity.absmax) * 0.5, bot_navigation_movemode)))
 977                         e = nearest_wp.enemy;
 978         }
 979
 980         for (;;)
 981         {
 982                 // add the spawnfunc_waypoint to the path
 983                 navigation_pushroute(this, e);
 984                 e = e.enemy;
 985
 986                 if(e==NULL)
 987                         break;
 988         }
 989
 990         return false;
 991 }
 992
 993 // removes any currently touching waypoints from the goal stack
 994 // (this is how bots detect if they reached a goal)
 995 void navigation_poptouchedgoals(entity this)
 996 {
 997         if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 998         {
 999                 // make sure jumppad is really hit, don't rely on distance based checks
1000                 // as they may report a touch even if it didn't really happen
1001                 if(this.lastteleporttime > 0
1002                         && time - this.lastteleporttime < ((this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL) ? 2 : 0.15))
1003                 {
1004                         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1005                         if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1006                         {
1007                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1008                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1009                         }
1010                         navigation_poproute(this);
1011                 }
1012                 else
1013                         return;
1014         }
1015
1016         // If for some reason the bot is closer to the next goal, pop the current one
1017         if(this.goalstack01 && !wasfreed(this.goalstack01))
1018         if(vlen2(this.goalcurrent.origin - this.origin) > vlen2(this.goalstack01.origin - this.origin))
1019         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
1020         if(tracewalk(this, this.origin, this.mins, this.maxs, (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5, bot_navigation_movemode))
1021         {
1022                 LOG_DEBUG("path optimized for ", this.netname, ", removed a goal from the queue");
1023                 navigation_poproute(this);
1024                 // TODO this may also be a nice idea to do "early" (e.g. by
1025                 // manipulating the vlen() comparisons) to shorten paths in
1026                 // general - this would make bots walk more "on rails" than
1027                 // "zigzagging" which they currently do with sufficiently
1028                 // random-like waypoints, and thus can make a nice bot
1029                 // personality property
1030         }
1031
1032         // Loose goal touching check when running
1033         if(this.aistatus & AI_STATUS_RUNNING)
1034         if(this.goalcurrent.classname=="waypoint")
1035         if(vlen(this.velocity - eZ * this.velocity.z) >= autocvar_sv_maxspeed) // if -really- running
1036         {
1037                 if(vdist(this.origin - this.goalcurrent.origin, <, 150))
1038                 {
1039                         traceline(this.origin + this.view_ofs , this.goalcurrent.origin, true, NULL);
1040                         if(trace_fraction==1)
1041                         {
1042                                 // Detect personal waypoints
1043                                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1044                                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1045                                 {
1046                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1047                                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1048                                 }
1049
1050                                 navigation_poproute(this);
1051                         }
1052                 }
1053         }
1054
1055         while (this.goalcurrent && !IS_PLAYER(this.goalcurrent))
1056         {
1057                 vector gc_min = this.goalcurrent.absmin;
1058                 vector gc_max = this.goalcurrent.absmax;
1059                 if(this.goalcurrent.classname == "waypoint" && !this.goalcurrent.wpisbox)
1060                 {
1061                         gc_min = this.goalcurrent.origin - '1 1 1' * 12;
1062                         gc_max = this.goalcurrent.origin + '1 1 1' * 12;
1063                 }
1064                 if(!boxesoverlap(this.absmin, this.absmax, gc_min, gc_max))
1065                         break;
1066
1067                 // Detect personal waypoints
1068                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1069                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1070                 {
1071                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1072                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1073                 }
1074
1075                 navigation_poproute(this);
1076         }
1077 }
1078
1079 // begin a goal selection session (queries spawnfunc_waypoint network)
1080 void navigation_goalrating_start(entity this)
1081 {
1082         if(this.aistatus & AI_STATUS_STUCK)
1083                 return;
1084
1085         this.navigation_jetpack_goal = NULL;
1086         navigation_bestrating = -1;
1087         navigation_clearroute(this);
1088         navigation_bestgoal = NULL;
1089         navigation_markroutes(this, NULL);
1090 }
1091
1092 // ends a goal selection session (updates goal stack to the best goal)
1093 void navigation_goalrating_end(entity this)
1094 {
1095         if(this.aistatus & AI_STATUS_STUCK)
1096                 return;
1097
1098         navigation_routetogoal(this, navigation_bestgoal, this.origin);
1099         LOG_DEBUG("best goal ", this.goalcurrent.classname);
1100
1101         // If the bot got stuck then try to reach the farthest waypoint
1102         if (!this.goalentity && autocvar_bot_wander_enable)
1103         {
1104                 if (!(this.aistatus & AI_STATUS_STUCK))
1105                 {
1106                         LOG_DEBUG(this.netname, " cannot walk to any goal");
1107                         this.aistatus |= AI_STATUS_STUCK;
1108                 }
1109         }
1110 }
1111
1112 void botframe_updatedangerousobjects(float maxupdate)
1113 {
1114         vector m1, m2, v, o;
1115         float c, d, danger;
1116         c = 0;
1117         IL_EACH(g_waypoints, true,
1118         {
1119                 danger = 0;
1120                 m1 = it.absmin;
1121                 m2 = it.absmax;
1122                 IL_EACH(g_bot_dodge, it.bot_dodge,
1123                 {
1124                         v = it.origin;
1125                         v.x = bound(m1_x, v.x, m2_x);
1126                         v.y = bound(m1_y, v.y, m2_y);
1127                         v.z = bound(m1_z, v.z, m2_z);
1128                         o = (it.absmin + it.absmax) * 0.5;
1129                         d = waypoint_getdistancecost_simple(it.bot_dodgerating) - waypoint_getdistancecost(o, v);
1130                         if (d > 0)
1131                         {
1132                                 traceline(o, v, true, NULL);
1133                                 if (trace_fraction == 1)
1134                                         danger = danger + d;
1135                         }
1136                 });
1137                 it.dmg = danger;
1138                 c = c + 1;
1139                 if (c >= maxupdate)
1140                         break;
1141         });
1142 }
1143
1144 void navigation_unstuck(entity this)
1145 {
1146         float search_radius = 1000;
1147
1148         if (!autocvar_bot_wander_enable)
1149                 return;
1150
1151         if (!bot_waypoint_queue_owner)
1152         {
1153                 LOG_DEBUG(this.netname, " stuck, taking over the waypoints queue");
1154                 bot_waypoint_queue_owner = this;
1155                 bot_waypoint_queue_bestgoal = NULL;
1156                 bot_waypoint_queue_bestgoalrating = 0;
1157         }
1158
1159         if(bot_waypoint_queue_owner!=this)
1160                 return;
1161
1162         if (bot_waypoint_queue_goal)
1163         {
1164                 // evaluate the next goal on the queue
1165                 float d = vlen2(this.origin - bot_waypoint_queue_goal.origin);
1166                 LOG_DEBUG(this.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d));
1167                 if(tracewalk(bot_waypoint_queue_goal, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), bot_waypoint_queue_goal.origin, bot_navigation_movemode))
1168                 {
1169                         if( d > bot_waypoint_queue_bestgoalrating)
1170                         {
1171                                 bot_waypoint_queue_bestgoalrating = d;
1172                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1173                         }
1174                 }
1175                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1176
1177                 if (!bot_waypoint_queue_goal)
1178                 {
1179                         if (bot_waypoint_queue_bestgoal)
1180                         {
1181                                 LOG_DEBUG(this.netname, " stuck, reachable waypoint found, heading to it");
1182                                 navigation_routetogoal(this, bot_waypoint_queue_bestgoal, this.origin);
1183                                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1184                                 this.aistatus &= ~AI_STATUS_STUCK;
1185                         }
1186                         else
1187                         {
1188                                 LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1189                         }
1190
1191                         bot_waypoint_queue_owner = NULL;
1192                 }
1193         }
1194         else
1195         {
1196                 if(bot_strategytoken!=this)
1197                         return;
1198
1199                 // build a new queue
1200                 LOG_DEBUG(this.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu");
1201
1202                 entity first = NULL;
1203
1204                 FOREACH_ENTITY_RADIUS(this.origin, search_radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
1205                 {
1206                         if(bot_waypoint_queue_goal)
1207                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = it;
1208                         else
1209                                 first = it;
1210
1211                         bot_waypoint_queue_goal = it;
1212                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = NULL;
1213                 });
1214
1215                 if (first)
1216                         bot_waypoint_queue_goal = first;
1217                 else
1218                 {
1219                         LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1220                         bot_waypoint_queue_owner = NULL;
1221                 }
1222         }
1223 }
1224
1225 // Support for debugging tracewalk visually
1226
1227 void debugresetnodes()
1228 {
1229         debuglastnode = '0 0 0';
1230 }
1231
1232 void debugnode(entity this, vector node)
1233 {
1234         if (!IS_PLAYER(this))
1235                 return;
1236
1237         if(debuglastnode=='0 0 0')
1238         {
1239                 debuglastnode = node;
1240                 return;
1241         }
1242
1243         te_lightning2(NULL, node, debuglastnode);
1244         debuglastnode = node;
1245 }
1246
1247 void debugnodestatus(vector position, float status)
1248 {
1249         vector c;
1250
1251         switch (status)
1252         {
1253                 case DEBUG_NODE_SUCCESS:
1254                         c = '0 15 0';
1255                         break;
1256                 case DEBUG_NODE_WARNING:
1257                         c = '15 15 0';
1258                         break;
1259                 case DEBUG_NODE_FAIL:
1260                         c = '15 0 0';
1261                         break;
1262                 default:
1263                         c = '15 15 15';
1264         }
1265
1266         te_customflash(position, 40,  2, c);
1267 }
1268
1269 // Support for debugging the goal stack visually
1270
1271 .float goalcounter;
1272 .vector lastposition;
1273
1274 // Debug the goal stack visually
1275 void debuggoalstack(entity this)
1276 {
1277         entity goal;
1278         vector org, go;
1279
1280         if(this.goalcounter==0)goal=this.goalcurrent;
1281         else if(this.goalcounter==1)goal=this.goalstack01;
1282         else if(this.goalcounter==2)goal=this.goalstack02;
1283         else if(this.goalcounter==3)goal=this.goalstack03;
1284         else if(this.goalcounter==4)goal=this.goalstack04;
1285         else if(this.goalcounter==5)goal=this.goalstack05;
1286         else if(this.goalcounter==6)goal=this.goalstack06;
1287         else if(this.goalcounter==7)goal=this.goalstack07;
1288         else if(this.goalcounter==8)goal=this.goalstack08;
1289         else if(this.goalcounter==9)goal=this.goalstack09;
1290         else if(this.goalcounter==10)goal=this.goalstack10;
1291         else if(this.goalcounter==11)goal=this.goalstack11;
1292         else if(this.goalcounter==12)goal=this.goalstack12;
1293         else if(this.goalcounter==13)goal=this.goalstack13;
1294         else if(this.goalcounter==14)goal=this.goalstack14;
1295         else if(this.goalcounter==15)goal=this.goalstack15;
1296         else if(this.goalcounter==16)goal=this.goalstack16;
1297         else if(this.goalcounter==17)goal=this.goalstack17;
1298         else if(this.goalcounter==18)goal=this.goalstack18;
1299         else if(this.goalcounter==19)goal=this.goalstack19;
1300         else if(this.goalcounter==20)goal=this.goalstack20;
1301         else if(this.goalcounter==21)goal=this.goalstack21;
1302         else if(this.goalcounter==22)goal=this.goalstack22;
1303         else if(this.goalcounter==23)goal=this.goalstack23;
1304         else if(this.goalcounter==24)goal=this.goalstack24;
1305         else if(this.goalcounter==25)goal=this.goalstack25;
1306         else if(this.goalcounter==26)goal=this.goalstack26;
1307         else if(this.goalcounter==27)goal=this.goalstack27;
1308         else if(this.goalcounter==28)goal=this.goalstack28;
1309         else if(this.goalcounter==29)goal=this.goalstack29;
1310         else if(this.goalcounter==30)goal=this.goalstack30;
1311         else if(this.goalcounter==31)goal=this.goalstack31;
1312         else goal=NULL;
1313
1314         if(goal==NULL)
1315         {
1316                 this.goalcounter = 0;
1317                 this.lastposition='0 0 0';
1318                 return;
1319         }
1320
1321         if(this.lastposition=='0 0 0')
1322                 org = this.origin;
1323         else
1324                 org = this.lastposition;
1325
1326
1327         go = ( goal.absmin + goal.absmax ) * 0.5;
1328         te_lightning2(NULL, org, go);
1329         this.lastposition = go;
1330
1331         this.goalcounter++;
1332 }