qcsrc/server/bot/default/navigation.qc

   1 #include "navigation.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "waypoints.qh"
   9
  10 #include <common/t_items.qh>
  11
  12 #include <common/items/_mod.qh>
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/triggers/trigger/jumppads.qh>
  17
  18 .float speed;
  19
  20 void navigation_goalrating_timeout_set(entity this)
  21 {
  22         if(IS_MOVABLE(this.goalentity))
  23                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval_movingtarget;
  24         else
  25                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  26 }
  27
  28 // use this when current goal must be discarded immediately
  29 void navigation_goalrating_timeout_force(entity this)
  30 {
  31         navigation_goalrating_timeout_expire(this, 0);
  32 }
  33
  34 // use this when current goal can be kept for a short while to increase the chance
  35 // of bot touching a waypoint, which helps to find a new goal more efficiently
  36 void navigation_goalrating_timeout_expire(entity this, float seconds)
  37 {
  38         if (seconds <= 0)
  39                 this.bot_strategytime = 0;
  40         else if (this.bot_strategytime > time + seconds)
  41                 this.bot_strategytime = time + seconds;
  42 }
  43
  44 bool navigation_goalrating_timeout(entity this)
  45 {
  46         return this.bot_strategytime < time;
  47 }
  48
  49 #define MAX_CHASE_DISTANCE 700
  50 bool navigation_goalrating_timeout_can_be_anticipated(entity this)
  51 {
  52         if(time > this.bot_strategytime - (IS_MOVABLE(this.goalentity) ? 3 : 2))
  53                 return true;
  54
  55         if (this.goalentity.bot_pickup && time > this.bot_strategytime - 5)
  56         {
  57                 vector gco = (this.goalentity.absmin + this.goalentity.absmax) * 0.5;
  58                 if(!havocbot_goalrating_item_pickable_check_players(this, this.origin, this.goalentity, gco))
  59                 {
  60                         this.ignoregoal = this.goalentity;
  61                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
  62                         return true;
  63                 }
  64         }
  65         return false;
  66 }
  67
  68 void navigation_dynamicgoal_init(entity this, bool initially_static)
  69 {
  70         this.navigation_dynamicgoal = true;
  71         this.bot_basewaypoint = this.nearestwaypoint;
  72         if(initially_static)
  73                 this.nearestwaypointtimeout = -1;
  74         else
  75                 this.nearestwaypointtimeout = time;
  76 }
  77
  78 void navigation_dynamicgoal_set(entity this)
  79 {
  80         this.nearestwaypointtimeout = time;
  81         if (this.nearestwaypoint)
  82                 this.nearestwaypointtimeout += 2;
  83 }
  84
  85 void navigation_dynamicgoal_unset(entity this)
  86 {
  87         if(this.bot_basewaypoint)
  88                 this.nearestwaypoint = this.bot_basewaypoint;
  89         this.nearestwaypointtimeout = -1;
  90 }
  91
  92 // returns point of ent closer to org
  93 vector get_closer_dest(entity ent, vector org)
  94 {
  95         vector dest = '0 0 0';
  96         if ((ent.classname != "waypoint") || ent.wpisbox)
  97         {
  98                 vector wm1 = ent.origin + ent.mins;
  99                 vector wm2 = ent.origin + ent.maxs;
 100                 dest.x = bound(wm1.x, org.x, wm2.x);
 101                 dest.y = bound(wm1.y, org.y, wm2.y);
 102                 dest.z = bound(wm1.z, org.z, wm2.z);
 103         }
 104         else
 105                 dest = ent.origin;
 106         return dest;
 107 }
 108
 109 void set_tracewalk_dest(entity ent, vector org, bool fix_player_dest)
 110 {
 111         if ((ent.classname != "waypoint") || ent.wpisbox)
 112         {
 113                 vector wm1 = ent.origin + ent.mins;
 114                 vector wm2 = ent.origin + ent.maxs;
 115                 if (IS_PLAYER(ent) || IS_MONSTER(ent))
 116                 {
 117                         // move destination point out of player bbox otherwise tracebox always fails
 118                         // (if bot_navigation_ignoreplayers is false)
 119                         wm1 += vec2(PL_MIN_CONST) + '-1 -1 0';
 120                         wm2 += vec2(PL_MAX_CONST) + '1 1 0';
 121                 }
 122                 // set destination point to x and y coords of ent that are closer to org
 123                 // z coord is set to ent's min height
 124                 tracewalk_dest.x = bound(wm1.x, org.x, wm2.x);
 125                 tracewalk_dest.y = bound(wm1.y, org.y, wm2.y);
 126                 tracewalk_dest.z = wm1.z;
 127                 tracewalk_dest_height = wm2.z - wm1.z; // destination height
 128         }
 129         else
 130         {
 131                 tracewalk_dest = ent.origin;
 132                 tracewalk_dest_height = 0;
 133         }
 134         if (fix_player_dest && IS_PLAYER(ent) && !IS_ONGROUND(ent))
 135         {
 136                 // snap player to the ground
 137                 if (org.x == tracewalk_dest.x && org.y == tracewalk_dest.y)
 138                 {
 139                         // bot is right under the player
 140                         tracebox(ent.origin, ent.mins, ent.maxs, ent.origin - '0 0 700', MOVE_NORMAL, ent);
 141                         tracewalk_dest = trace_endpos;
 142                         tracewalk_dest_height = 0;
 143                 }
 144                 else
 145                 {
 146                         tracebox(tracewalk_dest, ent.mins, ent.maxs, tracewalk_dest - '0 0 700', MOVE_NORMAL, ent);
 147                         if (!trace_startsolid && tracewalk_dest.z - trace_endpos.z > 0)
 148                         {
 149                                 tracewalk_dest_height = tracewalk_dest.z - trace_endpos.z;
 150                                 tracewalk_dest.z = trace_endpos.z;
 151                         }
 152                 }
 153         }
 154 }
 155
 156 // returns point of ent closer to org
 157 vector set_tracewalk_dest_2(entity ent, vector org)
 158 {
 159         vector closer_dest = '0 0 0';
 160         if ((ent.classname != "waypoint") || ent.wpisbox)
 161         {
 162                 vector wm1 = ent.origin + ent.mins;
 163                 vector wm2 = ent.origin + ent.maxs;
 164                 closer_dest.x = bound(wm1.x, org.x, wm2.x);
 165                 closer_dest.y = bound(wm1.y, org.y, wm2.y);
 166                 closer_dest.z = bound(wm1.z, org.z, wm2.z);
 167                 // set destination point to x and y coords of ent that are closer to org
 168                 // z coord is set to ent's min height
 169                 tracewalk_dest.x = closer_dest.x;
 170                 tracewalk_dest.y = closer_dest.y;
 171                 tracewalk_dest.z = wm1.z;
 172                 tracewalk_dest_height = wm2.z - wm1.z; // destination height
 173         }
 174         else
 175         {
 176                 closer_dest = ent.origin;
 177                 tracewalk_dest = closer_dest;
 178                 tracewalk_dest_height = 0;
 179         }
 180         return closer_dest;
 181 }
 182
 183 bool navigation_check_submerged_state(entity ent, vector pos)
 184 {
 185         bool submerged;
 186         if(IS_PLAYER(ent))
 187                 submerged = (ent.waterlevel == WATERLEVEL_SUBMERGED);
 188         else if(ent.nav_submerged_state != SUBMERGED_UNDEFINED)
 189                 submerged = (ent.nav_submerged_state == SUBMERGED_YES);
 190         else
 191         {
 192                 submerged = SUBMERGED(pos);
 193                 // NOTE: SUBMERGED check of box waypoint origin may fail even if origin
 194                 //  is actually submerged because often they are inside some solid.
 195                 //  That's why submerged state is saved now that we know current pos is
 196                 //  not stuck in solid (previous tracewalk call to this pos was successfully)
 197                 if(!ent.navigation_dynamicgoal)
 198                         ent.nav_submerged_state = (submerged) ? SUBMERGED_YES : SUBMERGED_NO;
 199         }
 200         return submerged;
 201 }
 202
 203 bool navigation_checkladders(entity e, vector org, vector m1, vector m2, vector end, vector end2, int movemode)
 204 {
 205         IL_EACH(g_ladders, it.classname == "func_ladder",
 206         {
 207                 if(it.bot_pickup)
 208                 if(boxesoverlap(org + m1 + '-1 -1 -1', org + m2 + '1 1 1', it.absmin, it.absmax))
 209                 if(boxesoverlap(end, end2, it.absmin + vec2(m1) + '-1 -1 0', it.absmax + vec2(m2) + '1 1 0'))
 210                 {
 211                         vector top = org;
 212                         top.z = it.absmax.z + (PL_MAX_CONST.z - PL_MIN_CONST.z);
 213                         tracebox(org, m1, m2, top, movemode, e);
 214                         if(trace_fraction == 1)
 215                                 return true;
 216                 }
 217         });
 218         return false;
 219 }
 220
 221 vector resurface_limited(vector org, float lim, vector m1)
 222 {
 223         if (WETFEET(org + eZ * (lim - org.z)))
 224                 org.z = lim;
 225         else
 226         {
 227                 float RES_min_h = org.z;
 228                 float RES_max_h = lim;
 229                 do {
 230                         org.z = 0.5 * (RES_min_h + RES_max_h);
 231                         if(WETFEET(org))
 232                                 RES_min_h = org.z;
 233                         else
 234                                 RES_max_h = org.z;
 235                 } while (RES_max_h - RES_min_h >= 1);
 236                 org.z = RES_min_h;
 237         }
 238         return org;
 239 }
 240 #define RESURFACE_LIMITED(org, lim) org = resurface_limited(org, lim, m1)
 241
 242 #define NAV_WALK 0
 243 #define NAV_SWIM_ONWATER 1
 244 #define NAV_SWIM_UNDERWATER 2
 245
 246 // rough simulation of walking from one point to another to test if a path
 247 // can be traveled, used for waypoint linking and havocbot
 248 // if end_height is > 0 destination is any point in the vertical segment [end, end + end_height * eZ]
 249 bool tracewalk(entity e, vector start, vector m1, vector m2, vector end, float end_height, float movemode)
 250 {
 251         if(autocvar_bot_debug_tracewalk)
 252         {
 253                 debugresetnodes();
 254                 debugnode(e, start);
 255         }
 256
 257         vector org = start;
 258         vector flatdir = end - start;
 259         flatdir.z = 0;
 260         float flatdist = vlen(flatdir);
 261         flatdir = normalize(flatdir);
 262         float stepdist = 32;
 263         bool ignorehazards = false;
 264         int nav_action;
 265
 266         // Analyze starting point
 267         traceline(start, start, MOVE_NORMAL, e);
 268         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 269                 ignorehazards = true;
 270
 271         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
 272         if (trace_startsolid)
 273         {
 274                 // Bad start
 275                 if(autocvar_bot_debug_tracewalk)
 276                         debugnodestatus(start, DEBUG_NODE_FAIL);
 277
 278                 //print("tracewalk: ", vtos(start), " is a bad start\n");
 279                 return false;
 280         }
 281
 282         vector end2 = end;
 283         if(end_height)
 284                 end2.z += end_height;
 285
 286         vector fixed_end = end;
 287         vector move;
 288
 289         if (flatdist > 0 && WETFEET(org))
 290         {
 291                 if (SUBMERGED(org))
 292                         nav_action = NAV_SWIM_UNDERWATER;
 293                 else
 294                 {
 295                         // tracebox down by player's height
 296                         // useful to know if water level is so low that bot can still walk
 297                         tracebox(org, m1, m2, org - eZ * (m2.z - m1.z), movemode, e);
 298                         if (SUBMERGED(trace_endpos))
 299                         {
 300                                 org = trace_endpos;
 301                                 nav_action = NAV_SWIM_UNDERWATER;
 302                         }
 303                         else
 304                                 nav_action = NAV_WALK;
 305                 }
 306         }
 307         else
 308                 nav_action =  NAV_WALK;
 309
 310         // Movement loop
 311         while (true)
 312         {
 313                 if (flatdist <= 0)
 314                 {
 315                         bool success = true;
 316                         if (org.z > end2.z + 1)
 317                         {
 318                                 tracebox(org, m1, m2, end2, movemode, e);
 319                                 org = trace_endpos;
 320                                 if (org.z > end2.z + 1)
 321                                         success = false;
 322                         }
 323                         else if (org.z < end.z - 1)
 324                         {
 325                                 tracebox(org, m1, m2, org - jumpheight_vec, movemode, e);
 326                                 if (SUBMERGED(trace_endpos))
 327                                 {
 328                                         vector v = trace_endpos;
 329                                         tracebox(v, m1, m2, end, movemode, e);
 330                                         if(trace_endpos.z >= end.z - 1)
 331                                         {
 332                                                 RESURFACE_LIMITED(v, trace_endpos.z);
 333                                                 trace_endpos = v;
 334                                         }
 335                                 }
 336                                 else if (trace_endpos.z > org.z - jumpheight_vec.z)
 337                                         tracebox(trace_endpos, m1, m2, trace_endpos + jumpheight_vec, movemode, e);
 338                                 org = trace_endpos;
 339                                 if (org.z < end.z - 1)
 340                                         success = false;
 341                         }
 342
 343                         if (success)
 344                         {
 345                                 // Succeeded
 346                                 if(autocvar_bot_debug_tracewalk)
 347                                 {
 348                                         debugnode(e, org);
 349                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 350                                 }
 351
 352                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 353                                 return true;
 354                         }
 355                 }
 356
 357                 if(autocvar_bot_debug_tracewalk)
 358                         debugnode(e, org);
 359
 360                 if (flatdist <= 0)
 361                         break;
 362
 363                 if (stepdist > flatdist)
 364                         stepdist = flatdist;
 365                 if(nav_action == NAV_SWIM_UNDERWATER || (nav_action == NAV_SWIM_ONWATER && org.z > end2.z))
 366                 {
 367                         // can't use movement direction here to calculate move because of
 368                         // precision errors especially when direction has a high enough z value
 369                         //water_dir = normalize(water_end - org);
 370                         //move = org + water_dir * stepdist;
 371                         fixed_end.z = bound(end.z, org.z, end2.z);
 372                         if (stepdist == flatdist) {
 373                                 move = fixed_end;
 374                                 flatdist = 0;
 375                         } else {
 376                                 move = org + (fixed_end - org) * (stepdist / flatdist);
 377                                 flatdist = vlen(vec2(fixed_end - move));
 378                         }
 379                 }
 380                 else // horiz. direction
 381                 {
 382                         flatdist -= stepdist;
 383                         move = org + flatdir * stepdist;
 384                 }
 385
 386                 if(nav_action == NAV_SWIM_ONWATER)
 387                 {
 388                         tracebox(org, m1, m2, move, movemode, e); // swim
 389
 390                         // hit something
 391                         if (trace_fraction < 1)
 392                         {
 393                                 // stepswim
 394                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 395
 396                                 if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 397                                 {
 398                                         org = trace_endpos;
 399                                         if(navigation_checkladders(e, org, m1, m2, end, end2, movemode))
 400                                         {
 401                                                 if(autocvar_bot_debug_tracewalk)
 402                                                 {
 403                                                         debugnode(e, org);
 404                                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 405                                                 }
 406
 407                                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 408                                                 return true;
 409                                         }
 410
 411                                         if(autocvar_bot_debug_tracewalk)
 412                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 413
 414                                         return false;
 415                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 416                                 }
 417
 418                                 //succesful stepswim
 419
 420                                 if (flatdist <= 0)
 421                                 {
 422                                         org = trace_endpos;
 423                                         continue;
 424                                 }
 425
 426                                 if (org.z <= move.z) // going horiz.
 427                                 {
 428                                         tracebox(trace_endpos, m1, m2, move, movemode, e);
 429                                         org = trace_endpos;
 430                                         nav_action = NAV_WALK;
 431                                         continue;
 432                                 }
 433                         }
 434
 435                         if (org.z <= move.z) // going horiz.
 436                         {
 437                                 org = trace_endpos;
 438                                 nav_action = NAV_SWIM_ONWATER;
 439                         }
 440                         else // going down
 441                         {
 442                                 org = trace_endpos;
 443                                 if (SUBMERGED(org))
 444                                         nav_action = NAV_SWIM_UNDERWATER;
 445                                 else
 446                                         nav_action = NAV_SWIM_ONWATER;
 447                         }
 448                 }
 449                 else if(nav_action == NAV_SWIM_UNDERWATER)
 450                 {
 451                         if (move.z >= org.z) // swimming upwards or horiz.
 452                         {
 453                                 tracebox(org, m1, m2, move, movemode, e); // swim
 454
 455                                 bool stepswum = false;
 456
 457                                 // hit something
 458                                 if (trace_fraction < 1)
 459                                 {
 460                                         // stepswim
 461                                         vector stepswim_move = move + stepheightvec;
 462                                         if (flatdist > 0 && stepswim_move.z > end2.z + stepheightvec.z) // don't allow stepswim to go higher than destination
 463                                                 stepswim_move.z = end2.z;
 464
 465                                         tracebox(org + stepheightvec, m1, m2, stepswim_move, movemode, e);
 466
 467                                         // hit something
 468                                         if (trace_startsolid)
 469                                         {
 470                                                 if(autocvar_bot_debug_tracewalk)
 471                                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 472
 473                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 474                                                 return false;
 475                                         }
 476
 477                                         if (trace_fraction < 1)
 478                                         {
 479                                                 float org_z_prev = org.z;
 480                                                 RESURFACE_LIMITED(org, end2.z);
 481                                                 if(org.z == org_z_prev)
 482                                                 {
 483                                                         if(autocvar_bot_debug_tracewalk)
 484                                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 485
 486                                                         //print("tracewalk: ", vtos(start), " can't reach ", vtos(end), "\n");
 487                                                         return false;
 488                                                 }
 489                                                 if(SUBMERGED(org))
 490                                                         nav_action = NAV_SWIM_UNDERWATER;
 491                                                 else
 492                                                         nav_action = NAV_SWIM_ONWATER;
 493
 494                                                 // we didn't advance horiz. in this step, flatdist decrease should be reverted
 495                                                 // but we can't do it properly right now... apply this workaround instead
 496                                                 if (flatdist <= 0)
 497                                                         flatdist = 1;
 498
 499                                                 continue;
 500                                         }
 501
 502                                         //succesful stepswim
 503
 504                                         if (flatdist <= 0)
 505                                         {
 506                                                 org = trace_endpos;
 507                                                 continue;
 508                                         }
 509
 510                                         stepswum = true;
 511                                 }
 512
 513                                 if (!WETFEET(trace_endpos))
 514                                 {
 515                                         tracebox(trace_endpos, m1, m2, trace_endpos - eZ * (stepdist + (m2.z - m1.z)), movemode, e);
 516                                         // if stepswum we'll land on the obstacle, avoid the SUBMERGED check
 517                                         if (!stepswum && SUBMERGED(trace_endpos))
 518                                         {
 519                                                 RESURFACE_LIMITED(trace_endpos, end2.z);
 520                                                 org = trace_endpos;
 521                                                 nav_action = NAV_SWIM_ONWATER;
 522                                                 continue;
 523                                         }
 524
 525                                         // not submerged
 526                                         org = trace_endpos;
 527                                         nav_action = NAV_WALK;
 528                                         continue;
 529                                 }
 530
 531                                 // wetfeet
 532                                 org = trace_endpos;
 533                                 nav_action = NAV_SWIM_UNDERWATER;
 534                                 continue;
 535                         }
 536                         else //if (move.z < org.z) // swimming downwards
 537                         {
 538                                 tracebox(org, m1, m2, move, movemode, e); // swim
 539
 540                                 // hit something
 541                                 if (trace_fraction < 1)
 542                                 {
 543                                         // stepswim
 544                                         tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 545
 546                                         // hit something
 547                                         if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 548                                         {
 549                                                 if(autocvar_bot_debug_tracewalk)
 550                                                         debugnodestatus(move, DEBUG_NODE_FAIL);
 551
 552                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 553                                                 return false;
 554                                         }
 555
 556                                         //succesful stepswim
 557
 558                                         if (flatdist <= 0)
 559                                         {
 560                                                 org = trace_endpos;
 561                                                 continue;
 562                                         }
 563
 564                                         if (trace_endpos.z > org.z && !SUBMERGED(trace_endpos))
 565                                         {
 566                                                 // stepswim caused upwards direction
 567                                                 tracebox(trace_endpos, m1, m2, trace_endpos - stepheightvec, movemode, e);
 568                                                 if (!SUBMERGED(trace_endpos))
 569                                                 {
 570                                                         org = trace_endpos;
 571                                                         nav_action = NAV_WALK;
 572                                                         continue;
 573                                                 }
 574                                         }
 575                                 }
 576
 577                                 org = trace_endpos;
 578                                 nav_action = NAV_SWIM_UNDERWATER;
 579                                 continue;
 580                         }
 581                 }
 582                 else if(nav_action == NAV_WALK)
 583                 {
 584                         // walk
 585                         tracebox(org, m1, m2, move, movemode, e);
 586
 587                         if(autocvar_bot_debug_tracewalk)
 588                                 debugnode(e, trace_endpos);
 589
 590                         // hit something
 591                         if (trace_fraction < 1)
 592                         {
 593                                 // check if we can walk over this obstacle, possibly by jumpstepping
 594                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 595                                 if (trace_fraction < 1 || trace_startsolid)
 596                                 {
 597                                         if (trace_startsolid) // hit ceiling above org
 598                                         {
 599                                                 // reduce stepwalk height
 600                                                 tracebox(org, m1, m2, org + stepheightvec, movemode, e);
 601                                                 tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 602                                         }
 603                                         else //if (trace_fraction < 1)
 604                                         {
 605                                                 tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 606                                                 if (trace_startsolid) // hit ceiling above org
 607                                                 {
 608                                                         // reduce jumpstepwalk height
 609                                                         tracebox(org, m1, m2, org + jumpstepheightvec, movemode, e);
 610                                                         tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 611                                                 }
 612                                         }
 613
 614                                         if (trace_fraction < 1)
 615                                         {
 616                                                 vector v = trace_endpos;
 617                                                 v.z = org.z + jumpheight_vec.z;
 618                                                 if(navigation_checkladders(e, v, m1, m2, end, end2, movemode))
 619                                                 {
 620                                                         if(autocvar_bot_debug_tracewalk)
 621                                                         {
 622                                                                 debugnode(e, v);
 623                                                                 debugnodestatus(v, DEBUG_NODE_SUCCESS);
 624                                                         }
 625
 626                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 627                                                         return true;
 628                                                 }
 629
 630                                                 if(autocvar_bot_debug_tracewalk)
 631                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 632
 633                                                 traceline( org, move, movemode, e);
 634
 635                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 636                                                 {
 637                                                         vector nextmove;
 638                                                         move = trace_endpos;
 639                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 640                                                         {
 641                                                                 nextmove = move + (flatdir * stepdist);
 642                                                                 traceline( move, nextmove, movemode, e);
 643                                                                 move = nextmove;
 644                                                         }
 645                                                         flatdist = vlen(vec2(end - move));
 646                                                 }
 647                                                 else
 648                                                 {
 649                                                         if(autocvar_bot_debug_tracewalk)
 650                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 651
 652                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 653                                                         //te_explosion(trace_endpos);
 654                                                         //print(ftos(e.dphitcontentsmask), "\n");
 655                                                         return false; // failed
 656                                                 }
 657                                         }
 658                                         else
 659                                                 move = trace_endpos;
 660                                 }
 661                                 else
 662                                         move = trace_endpos;
 663                         }
 664                         else
 665                                 move = trace_endpos;
 666
 667                         // trace down from stepheight as far as possible and move there,
 668                         // if this starts in solid we try again without the stepup, and
 669                         // if that also fails we assume it is a wall
 670                         // (this is the same logic as the Quake walkmove function used)
 671                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 672
 673                         org = trace_endpos;
 674
 675                         if (!ignorehazards)
 676                         {
 677                                 if (IN_LAVA(org))
 678                                 {
 679                                         if(autocvar_bot_debug_tracewalk)
 680                                         {
 681                                                 debugnode(e, trace_endpos);
 682                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 683                                         }
 684
 685                                         //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 686                                         return false;
 687                                 }
 688                         }
 689
 690                         if (flatdist <= 0)
 691                         {
 692                                 if(move.z >= end2.z && org.z < end2.z)
 693                                         org.z = end2.z;
 694                                 continue;
 695                         }
 696
 697                         if(org.z > move.z - 1 || !SUBMERGED(org))
 698                         {
 699                                 nav_action = NAV_WALK;
 700                                 continue;
 701                         }
 702
 703                         // ended up submerged while walking
 704                         if(autocvar_bot_debug_tracewalk)
 705                                 debugnode(e, org);
 706
 707                         RESURFACE_LIMITED(org, move.z);
 708                         nav_action = NAV_SWIM_ONWATER;
 709                         continue;
 710                 }
 711         }
 712
 713         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 714
 715         // moved but didn't arrive at the intended destination
 716         if(autocvar_bot_debug_tracewalk)
 717                 debugnodestatus(org, DEBUG_NODE_FAIL);
 718
 719         return false;
 720 }
 721
 722 /////////////////////////////////////////////////////////////////////////////
 723 // goal stack
 724 /////////////////////////////////////////////////////////////////////////////
 725
 726 // completely empty the goal stack, used when deciding where to go
 727 void navigation_clearroute(entity this)
 728 {
 729         this.goalcurrent_prev = this.goalcurrent;
 730         this.goalcurrent_distance_2d = FLOAT_MAX;
 731         this.goalcurrent_distance_z = FLOAT_MAX;
 732         this.goalcurrent_distance_time = 0;
 733         this.goalentity_lock_timeout = 0;
 734         this.goalentity_shouldbefrozen = false;
 735         this.goalentity = NULL;
 736         this.goalcurrent = NULL;
 737         this.goalstack01 = NULL;
 738         this.goalstack02 = NULL;
 739         this.goalstack03 = NULL;
 740         this.goalstack04 = NULL;
 741         this.goalstack05 = NULL;
 742         this.goalstack06 = NULL;
 743         this.goalstack07 = NULL;
 744         this.goalstack08 = NULL;
 745         this.goalstack09 = NULL;
 746         this.goalstack10 = NULL;
 747         this.goalstack11 = NULL;
 748         this.goalstack12 = NULL;
 749         this.goalstack13 = NULL;
 750         this.goalstack14 = NULL;
 751         this.goalstack15 = NULL;
 752         this.goalstack16 = NULL;
 753         this.goalstack17 = NULL;
 754         this.goalstack18 = NULL;
 755         this.goalstack19 = NULL;
 756         this.goalstack20 = NULL;
 757         this.goalstack21 = NULL;
 758         this.goalstack22 = NULL;
 759         this.goalstack23 = NULL;
 760         this.goalstack24 = NULL;
 761         this.goalstack25 = NULL;
 762         this.goalstack26 = NULL;
 763         this.goalstack27 = NULL;
 764         this.goalstack28 = NULL;
 765         this.goalstack29 = NULL;
 766         this.goalstack30 = NULL;
 767         this.goalstack31 = NULL;
 768 }
 769
 770 // add a new goal at the beginning of the stack
 771 // (in other words: add a new prerequisite before going to the later goals)
 772 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 773 // next-closest WP on the shortest path to the WP
 774 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 775 // steps to the goal, and then recalculate the path.
 776 void navigation_pushroute(entity this, entity e)
 777 {
 778         this.goalcurrent_prev = this.goalcurrent;
 779         this.goalcurrent_distance_2d = FLOAT_MAX;
 780         this.goalcurrent_distance_z = FLOAT_MAX;
 781         this.goalcurrent_distance_time = 0;
 782         //print("bot ", etos(this), " push ", etos(e), "\n");
 783         if(this.goalstack31 == this.goalentity)
 784                 this.goalentity = NULL;
 785         this.goalstack31 = this.goalstack30;
 786         this.goalstack30 = this.goalstack29;
 787         this.goalstack29 = this.goalstack28;
 788         this.goalstack28 = this.goalstack27;
 789         this.goalstack27 = this.goalstack26;
 790         this.goalstack26 = this.goalstack25;
 791         this.goalstack25 = this.goalstack24;
 792         this.goalstack24 = this.goalstack23;
 793         this.goalstack23 = this.goalstack22;
 794         this.goalstack22 = this.goalstack21;
 795         this.goalstack21 = this.goalstack20;
 796         this.goalstack20 = this.goalstack19;
 797         this.goalstack19 = this.goalstack18;
 798         this.goalstack18 = this.goalstack17;
 799         this.goalstack17 = this.goalstack16;
 800         this.goalstack16 = this.goalstack15;
 801         this.goalstack15 = this.goalstack14;
 802         this.goalstack14 = this.goalstack13;
 803         this.goalstack13 = this.goalstack12;
 804         this.goalstack12 = this.goalstack11;
 805         this.goalstack11 = this.goalstack10;
 806         this.goalstack10 = this.goalstack09;
 807         this.goalstack09 = this.goalstack08;
 808         this.goalstack08 = this.goalstack07;
 809         this.goalstack07 = this.goalstack06;
 810         this.goalstack06 = this.goalstack05;
 811         this.goalstack05 = this.goalstack04;
 812         this.goalstack04 = this.goalstack03;
 813         this.goalstack03 = this.goalstack02;
 814         this.goalstack02 = this.goalstack01;
 815         this.goalstack01 = this.goalcurrent;
 816         this.goalcurrent = e;
 817 }
 818
 819 // remove first goal from stack
 820 // (in other words: remove a prerequisite for reaching the later goals)
 821 // (used when a spawnfunc_waypoint is reached)
 822 void navigation_poproute(entity this)
 823 {
 824         this.goalcurrent_prev = this.goalcurrent;
 825         this.goalcurrent_distance_2d = FLOAT_MAX;
 826         this.goalcurrent_distance_z = FLOAT_MAX;
 827         this.goalcurrent_distance_time = 0;
 828         //print("bot ", etos(this), " pop\n");
 829         if(this.goalcurrent == this.goalentity)
 830         {
 831                 this.goalentity = NULL;
 832                 this.goalentity_lock_timeout = 0;
 833         }
 834         this.goalcurrent = this.goalstack01;
 835         this.goalstack01 = this.goalstack02;
 836         this.goalstack02 = this.goalstack03;
 837         this.goalstack03 = this.goalstack04;
 838         this.goalstack04 = this.goalstack05;
 839         this.goalstack05 = this.goalstack06;
 840         this.goalstack06 = this.goalstack07;
 841         this.goalstack07 = this.goalstack08;
 842         this.goalstack08 = this.goalstack09;
 843         this.goalstack09 = this.goalstack10;
 844         this.goalstack10 = this.goalstack11;
 845         this.goalstack11 = this.goalstack12;
 846         this.goalstack12 = this.goalstack13;
 847         this.goalstack13 = this.goalstack14;
 848         this.goalstack14 = this.goalstack15;
 849         this.goalstack15 = this.goalstack16;
 850         this.goalstack16 = this.goalstack17;
 851         this.goalstack17 = this.goalstack18;
 852         this.goalstack18 = this.goalstack19;
 853         this.goalstack19 = this.goalstack20;
 854         this.goalstack20 = this.goalstack21;
 855         this.goalstack21 = this.goalstack22;
 856         this.goalstack22 = this.goalstack23;
 857         this.goalstack23 = this.goalstack24;
 858         this.goalstack24 = this.goalstack25;
 859         this.goalstack25 = this.goalstack26;
 860         this.goalstack26 = this.goalstack27;
 861         this.goalstack27 = this.goalstack28;
 862         this.goalstack28 = this.goalstack29;
 863         this.goalstack29 = this.goalstack30;
 864         this.goalstack30 = this.goalstack31;
 865         this.goalstack31 = NULL;
 866 }
 867
 868 // walking to wp (walkfromwp == false) v2 and v2_height will be used as
 869 // waypoint destination coordinates instead of v (only useful for box waypoints)
 870 // for normal waypoints v2 == v and v2_height == 0
 871 float navigation_waypoint_will_link(vector v, vector org, entity ent, vector v2, float v2_height, vector o2, float o2_height, float walkfromwp, float bestdist)
 872 {
 873         if (vdist(v - org, <, bestdist))
 874         {
 875                 traceline(v, org, true, ent);
 876                 if (trace_fraction == 1)
 877                 {
 878                         if (walkfromwp)
 879                         {
 880                                 if (tracewalk(ent, v, PL_MIN_CONST, PL_MAX_CONST, v2, v2_height, bot_navigation_movemode))
 881                                         return true;
 882                         }
 883                         else
 884                         {
 885                                 if (tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, o2, o2_height, bot_navigation_movemode))
 886                                         return true;
 887                         }
 888                 }
 889         }
 890         return false;
 891 }
 892
 893 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 894 entity navigation_findnearestwaypoint_withdist_except(entity ent, float walkfromwp, float bestdist, entity except)
 895 {
 896         if(ent.tag_entity)
 897                 ent = ent.tag_entity;
 898
 899         vector pm1 = ent.origin + ent.mins;
 900         vector pm2 = ent.origin + ent.maxs;
 901
 902         // do two scans, because box test is cheaper
 903         IL_EACH(g_waypoints, it != ent && it != except,
 904         {
 905                 if(boxesoverlap(pm1, pm2, it.absmin, it.absmax))
 906                 {
 907                         if(!autocvar_g_waypointeditor && walkfromwp && !ent.navigation_dynamicgoal)
 908                         {
 909                                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 910                                 navigation_item_addlink(it, ent);
 911                         }
 912                         return it;
 913                 }
 914         });
 915
 916         vector org = ent.origin;
 917         if (navigation_testtracewalk)
 918                 te_plasmaburn(org);
 919
 920         entity best = NULL;
 921         vector v = '0 0 0';
 922
 923         if(ent.size && !IS_PLAYER(ent))
 924         {
 925                 org += 0.5 * (ent.mins + ent.maxs);
 926                 org.z = ent.origin.z + ent.mins.z - PL_MIN_CONST.z; // player height
 927         }
 928
 929         if(!autocvar_g_waypointeditor && walkfromwp && !ent.navigation_dynamicgoal)
 930         {
 931                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 932                 IL_EACH(g_waypoints, it != ent,
 933                 {
 934                         if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 935                                 continue;
 936
 937                         set_tracewalk_dest(ent, it.origin, false);
 938                         if (vdist(tracewalk_dest - it.origin, <, 1050)
 939                                 && tracewalk(ent, it.origin, PL_MIN_CONST, PL_MAX_CONST,
 940                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 941                         {
 942                                 navigation_item_addlink(it, ent);
 943                         }
 944                 });
 945         }
 946
 947         // box check failed, try walk
 948         IL_EACH(g_waypoints, it != ent,
 949         {
 950                 if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 951                         continue;
 952                 v = it.origin;
 953
 954                 if (walkfromwp)
 955                 {
 956                         set_tracewalk_dest(ent, v, true);
 957                         if (trace_ent == ent)
 958                         {
 959                                 bestdist = 0;
 960                                 best = it;
 961                                 break;
 962                         }
 963                 }
 964                 else
 965                         set_tracewalk_dest(it, org, false);
 966
 967                 if (navigation_waypoint_will_link(v, org, ent,
 968                         tracewalk_dest, tracewalk_dest_height,
 969                         tracewalk_dest, tracewalk_dest_height, walkfromwp, bestdist))
 970                 {
 971                         if (walkfromwp)
 972                                 bestdist = vlen(tracewalk_dest - v);
 973                         else
 974                                 bestdist = vlen(v - org);
 975                         best = it;
 976                 }
 977         });
 978         if(!best && !ent.navigation_dynamicgoal)
 979         {
 980                 int solid_save = ent.solid;
 981                 ent.solid = SOLID_BSP;
 982                 IL_EACH(g_jumppads, true,
 983                 {
 984                         if(trigger_push_test(it, ent))
 985                         {
 986                                 best = it.nearestwaypoint;
 987                                 break;
 988                         }
 989                 });
 990                 ent.solid = solid_save;
 991         }
 992         return best;
 993 }
 994 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 995 {
 996         entity wp = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, NULL);
 997         if (autocvar_g_waypointeditor_auto)
 998         {
 999                 entity wp2 = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, wp);
1000                 if (wp && !wp2)
1001                         wp.wpflags |= WAYPOINTFLAG_PROTECTED;
1002         }
1003         return wp;
1004 }
1005
1006 // finds the waypoints near the bot initiating a navigation query
1007 float navigation_markroutes_nearestwaypoints(entity this, float maxdist)
1008 {
1009         //navigation_testtracewalk = true;
1010         int c = 0;
1011         IL_EACH(g_waypoints, !it.wpconsidered,
1012         {
1013                 set_tracewalk_dest(it, this.origin, false);
1014
1015                 vector diff = tracewalk_dest - this.origin;
1016                 diff.z = max(0, diff.z);
1017                 if(vdist(diff, <, maxdist))
1018                 {
1019                         it.wpconsidered = true;
1020                         if (tracewalk(this, this.origin, this.mins, this.maxs,
1021                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1022                         {
1023                                 it.wpnearestpoint = tracewalk_dest;
1024                                 it.wpcost = waypoint_gettravelcost(this.origin, tracewalk_dest, this, it) + it.dmg;
1025                                 it.wpfire = 1;
1026                                 it.enemy = NULL;
1027                                 c = c + 1;
1028                         }
1029                 }
1030         });
1031         //navigation_testtracewalk = false;
1032         return c;
1033 }
1034
1035 // updates a path link if a spawnfunc_waypoint link is better than the current one
1036 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost, vector p)
1037 {
1038         vector m1, m2;
1039         vector v;
1040         if (wp.wpisbox)
1041         {
1042                 m1 = wp.origin + wp.mins;
1043                 m2 = wp.origin + wp.maxs;
1044                 v.x = bound(m1_x, p.x, m2_x);
1045                 v.y = bound(m1_y, p.y, m2_y);
1046                 v.z = bound(m1_z, p.z, m2_z);
1047         }
1048         else
1049                 v = wp.origin;
1050         if (w.wpflags & WAYPOINTFLAG_TELEPORT)
1051                 cost += w.wp00mincost; // assuming teleport has exactly one destination
1052         else
1053                 cost += waypoint_gettravelcost(p, v, w, wp);
1054         if (wp.wpcost > cost)
1055         {
1056                 wp.wpcost = cost;
1057                 wp.enemy = w;
1058                 wp.wpfire = 1;
1059                 wp.wpnearestpoint = v;
1060         }
1061 }
1062
1063 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
1064 void navigation_markroutes(entity this, entity fixed_source_waypoint)
1065 {
1066         float cost, cost2;
1067         vector p;
1068
1069         IL_EACH(g_waypoints, true,
1070         {
1071                 it.wpconsidered = false;
1072                 it.wpnearestpoint = '0 0 0';
1073                 it.wpcost = 10000000;
1074                 it.wpfire = 0;
1075                 it.enemy = NULL;
1076         });
1077
1078         if(fixed_source_waypoint)
1079         {
1080                 fixed_source_waypoint.wpconsidered = true;
1081                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
1082                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
1083                 fixed_source_waypoint.wpfire = 1;
1084                 fixed_source_waypoint.enemy = NULL;
1085         }
1086         else
1087         {
1088                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
1089                 // as this search is expensive we will use lower values if the bot is on the air
1090                 float increment, maxdistance;
1091                 if(IS_ONGROUND(this))
1092                 {
1093                         increment = 750;
1094                         maxdistance = 50000;
1095                 }
1096                 else
1097                 {
1098                         increment = 500;
1099                         maxdistance = 1500;
1100                 }
1101
1102                 for(int j = increment; !navigation_markroutes_nearestwaypoints(this, j) && j < maxdistance; j += increment);
1103         }
1104
1105         bool searching = true;
1106         while (searching)
1107         {
1108                 searching = false;
1109                 IL_EACH(g_waypoints, it.wpfire,
1110                 {
1111                         searching = true;
1112                         it.wpfire = 0;
1113                         cost = it.wpcost;
1114                         p = it.wpnearestpoint;
1115                         entity wp;
1116                         wp = it.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp00mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1117                         wp = it.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp01mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1118                         wp = it.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp02mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1119                         wp = it.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp03mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1120                         wp = it.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp04mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1121                         wp = it.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp05mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1122                         wp = it.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp06mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1123                         wp = it.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp07mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1124                         wp = it.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp08mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1125                         wp = it.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp09mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1126                         wp = it.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp10mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1127                         wp = it.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp11mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1128                         wp = it.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp12mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1129                         wp = it.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp13mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1130                         wp = it.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp14mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1131                         wp = it.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp15mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1132                         wp = it.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp16mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1133                         wp = it.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp17mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1134                         wp = it.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp18mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1135                         wp = it.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp19mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1136                         wp = it.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp20mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1137                         wp = it.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp21mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1138                         wp = it.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp22mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1139                         wp = it.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp23mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1140                         wp = it.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp24mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1141                         wp = it.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp25mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1142                         wp = it.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp26mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1143                         wp = it.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp27mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1144                         wp = it.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp28mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1145                         wp = it.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp29mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1146                         wp = it.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp30mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1147                         wp = it.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp31mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
1148                         }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
1149                 });
1150         }
1151 }
1152
1153 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
1154 void navigation_markroutes_inverted(entity fixed_source_waypoint)
1155 {
1156         float cost, cost2;
1157         vector p;
1158         IL_EACH(g_waypoints, true,
1159         {
1160                 it.wpconsidered = false;
1161                 it.wpnearestpoint = '0 0 0';
1162                 it.wpcost = 10000000;
1163                 it.wpfire = 0;
1164                 it.enemy = NULL;
1165         });
1166
1167         if(fixed_source_waypoint)
1168         {
1169                 fixed_source_waypoint.wpconsidered = true;
1170                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
1171                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
1172                 fixed_source_waypoint.wpfire = 1;
1173                 fixed_source_waypoint.enemy = NULL;
1174         }
1175         else
1176         {
1177                 error("need to start with a waypoint\n");
1178         }
1179
1180         bool searching = true;
1181         while (searching)
1182         {
1183                 searching = false;
1184                 IL_EACH(g_waypoints, it.wpfire,
1185                 {
1186                         searching = true;
1187                         it.wpfire = 0;
1188                         cost = it.wpcost; // cost to walk from it to home
1189                         p = it.wpnearestpoint;
1190                         entity wp = it;
1191                         IL_EACH(g_waypoints, it != wp,
1192                         {
1193                                 if(!waypoint_islinked(it, wp))
1194                                         continue;
1195                                 cost2 = cost + it.dmg;
1196                                 navigation_markroutes_checkwaypoint(wp, it, cost2, p);
1197                         });
1198                 });
1199         }
1200 }
1201
1202 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
1203 void navigation_routerating(entity this, entity e, float f, float rangebias)
1204 {
1205         if (!e)
1206                 return;
1207
1208         if(e.blacklisted)
1209                 return;
1210
1211         rangebias = waypoint_getlinearcost(rangebias);
1212         f = waypoint_getlinearcost(f);
1213
1214         if (IS_PLAYER(e))
1215         {
1216                 bool rate_wps = false;
1217                 if((e.flags & FL_INWATER) || (e.flags & FL_PARTIALGROUND))
1218                         rate_wps = true;
1219
1220                 if(!IS_ONGROUND(e))
1221                 {
1222                         traceline(e.origin, e.origin + '0 0 -1500', true, NULL);
1223                         int t = pointcontents(trace_endpos + '0 0 1');
1224                         if(t != CONTENT_SOLID )
1225                         {
1226                                 if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
1227                                         rate_wps = true;
1228                                 else if(tracebox_hits_trigger_hurt(e.origin, e.mins, e.maxs, trace_endpos))
1229                                         return;
1230                         }
1231                 }
1232
1233                 if(rate_wps)
1234                 {
1235                         entity theEnemy = e;
1236                         entity best_wp = NULL;
1237                         float best_dist = 10000;
1238                         IL_EACH(g_waypoints, vdist(it.origin - theEnemy.origin, <, 500)
1239                                 && vdist(it.origin - this.origin, >, 100)
1240                                 && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1241                         {
1242                                 float dist = vlen(it.origin - theEnemy.origin);
1243                                 if (dist < best_dist)
1244                                 {
1245                                         best_wp = it;
1246                                         best_dist = dist;
1247                                 }
1248                         });
1249                         if (!best_wp)
1250                                 return;
1251                         e = best_wp;
1252                 }
1253         }
1254
1255         vector goal_org = (e.absmin + e.absmax) * 0.5;
1256
1257         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
1258
1259         // Evaluate path using jetpack
1260         if(g_jetpack)
1261         if(this.items & IT_JETPACK)
1262         if(autocvar_bot_ai_navigation_jetpack)
1263         if(vdist(this.origin - goal_org, >, autocvar_bot_ai_navigation_jetpack_mindistance))
1264         {
1265                 vector pointa, pointb;
1266
1267                 LOG_DEBUG("jetpack ai: evaluating path for ", e.classname);
1268
1269                 // Point A
1270                 traceline(this.origin, this.origin + '0 0 65535', MOVE_NORMAL, this);
1271                 pointa = trace_endpos - '0 0 1';
1272
1273                 // Point B
1274                 traceline(goal_org, goal_org + '0 0 65535', MOVE_NORMAL, e);
1275                 pointb = trace_endpos - '0 0 1';
1276
1277                 // Can I see these two points from the sky?
1278                 traceline(pointa, pointb, MOVE_NORMAL, this);
1279
1280                 if(trace_fraction==1)
1281                 {
1282                         LOG_DEBUG("jetpack ai: can bridge these two points");
1283
1284                         // Lower the altitude of these points as much as possible
1285                         float zdistance, xydistance, cost, t, fuel;
1286                         vector down, npa, npb;
1287
1288                         down = '0 0 -1' * (STAT(PL_MAX, this).z - STAT(PL_MIN, this).z) * 10;
1289
1290                         do{
1291                                 npa = pointa + down;
1292                                 npb = pointb + down;
1293
1294                                 if(npa.z<=this.absmax.z)
1295                                         break;
1296
1297                                 if(npb.z<=e.absmax.z)
1298                                         break;
1299
1300                                 traceline(npa, npb, MOVE_NORMAL, this);
1301                                 if(trace_fraction==1)
1302                                 {
1303                                         pointa = npa;
1304                                         pointb = npb;
1305                                 }
1306                         }
1307                         while(trace_fraction == 1);
1308
1309
1310                         // Rough estimation of fuel consumption
1311                         // (ignores acceleration and current xyz velocity)
1312                         xydistance = vlen(pointa - pointb);
1313                         zdistance = fabs(pointa.z - this.origin.z);
1314
1315                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
1316                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
1317                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
1318
1319                         LOG_DEBUG("jetpack ai: required fuel ", ftos(fuel), " this.ammo_fuel ", ftos(this.ammo_fuel));
1320
1321                         // enough fuel ?
1322                         if(this.ammo_fuel>fuel)
1323                         {
1324                                 // Estimate cost
1325                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
1326                                 //  - between air and ground speeds)
1327
1328                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
1329                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
1330                                 cost *= 1.5;
1331
1332                                 // Compare against other goals
1333                                 f = f * rangebias / (rangebias + cost);
1334
1335                                 if (navigation_bestrating < f)
1336                                 {
1337                                         LOG_DEBUG("jetpack path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1338                                         navigation_bestrating = f;
1339                                         navigation_bestgoal = e;
1340                                         this.navigation_jetpack_goal = e;
1341                                         this.navigation_jetpack_point = pointb;
1342                                 }
1343                                 return;
1344                         }
1345                 }
1346         }
1347
1348         entity nwp;
1349         //te_wizspike(e.origin);
1350         //bprint(etos(e));
1351         //bprint("\n");
1352         // update the cached spawnfunc_waypoint link on a dynamic item entity
1353         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1354         {
1355                 nwp = e;
1356         }
1357         else
1358         {
1359                 if(autocvar_g_waypointeditor && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1360                         e.nearestwaypoint = NULL;
1361
1362                 if ((!e.nearestwaypoint || e.navigation_dynamicgoal)
1363                         && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1364                 {
1365                         if(IS_BOT_CLIENT(e) && e.goalcurrent && e.goalcurrent.classname == "waypoint")
1366                                 e.nearestwaypoint = nwp = e.goalcurrent;
1367                         else
1368                                 e.nearestwaypoint = nwp = navigation_findnearestwaypoint(e, true);
1369                         if(!nwp)
1370                         {
1371                                 LOG_DEBUG("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e));
1372
1373                                 if(!e.navigation_dynamicgoal)
1374                                         e.blacklisted = true;
1375
1376                                 if(e.blacklisted)
1377                                 {
1378                                         LOG_DEBUG("The entity '", e.classname, "' is going to be excluded from path finding during this match");
1379                                         return;
1380                                 }
1381                         }
1382
1383                         if(e.navigation_dynamicgoal)
1384                                 e.nearestwaypointtimeout = time + 2;
1385                         else if(autocvar_g_waypointeditor)
1386                                 e.nearestwaypointtimeout = time + 3 + random() * 2;
1387                 }
1388                 nwp = e.nearestwaypoint;
1389         }
1390
1391         if (nwp && nwp.wpcost < 10000000)
1392         {
1393                 //te_wizspike(nwp.wpnearestpoint);
1394                 float nwptoitem_cost = 0;
1395                 if(nwp.wpflags & WAYPOINTFLAG_TELEPORT)
1396                         nwptoitem_cost = nwp.wp00mincost;
1397                 else
1398                         nwptoitem_cost = waypoint_gettravelcost(nwp.wpnearestpoint, goal_org, nwp, e);
1399                 float cost = nwp.wpcost + nwptoitem_cost;
1400                 LOG_DEBUG("checking ^5", e.classname, "^7 with base rating ^xf04", ftos(f), "^7 and rangebias ^xf40", ftos(rangebias));
1401                 f = f * rangebias / (rangebias + cost);
1402                 LOG_DEBUG("         ^5", e.classname, "^7 with cost ^6", ftos(cost), "^7 and final rating ^2", ftos(f));
1403                 if (navigation_bestrating < f)
1404                 {
1405                         LOG_DEBUG(" ground path: ^3added goal ^5", e.classname);
1406                         navigation_bestrating = f;
1407                         navigation_bestgoal = e;
1408                 }
1409         }
1410 }
1411
1412 // adds an item to the the goal stack with the path to a given item
1413 bool navigation_routetogoal(entity this, entity e, vector startposition)
1414 {
1415         // if there is no goal, just exit
1416         if (!e)
1417                 return false;
1418
1419         entity teleport_goal = NULL;
1420
1421         this.goalentity = e;
1422
1423         if(e.wpflags & WAYPOINTFLAG_TELEPORT)
1424         {
1425                 // force teleport destination as route destination
1426                 teleport_goal = e;
1427                 navigation_pushroute(this, e.wp00);
1428                 this.goalentity = e.wp00;
1429         }
1430
1431         // put the entity on the goal stack
1432         //print("routetogoal ", etos(e), "\n");
1433         navigation_pushroute(this, e);
1434
1435         if(teleport_goal)
1436                 e = this.goalentity;
1437
1438         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1439         {
1440                 this.wp_goal_prev1 = this.wp_goal_prev0;
1441                 this.wp_goal_prev0 = e;
1442         }
1443
1444         if(g_jetpack)
1445         if(e==this.navigation_jetpack_goal)
1446                 return true;
1447
1448         // if it can reach the goal there is nothing more to do
1449         set_tracewalk_dest(e, startposition, true);
1450         if ((!IS_MOVABLE(this.goalcurrent) || vdist(tracewalk_dest - this.origin, <, MAX_CHASE_DISTANCE))
1451                 && (trace_ent == this || tracewalk(this, startposition, STAT(PL_MIN, this), STAT(PL_MAX, this),
1452                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
1453         {
1454                 return true;
1455         }
1456
1457         entity nearest_wp = NULL;
1458         // see if there are waypoints describing a path to the item
1459         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
1460         {
1461                 e = e.nearestwaypoint;
1462                 nearest_wp = e;
1463         }
1464         else if(teleport_goal)
1465                 e = teleport_goal;
1466         else
1467                 e = e.enemy; // we already have added it, so...
1468
1469         if(e == NULL)
1470                 return false;
1471
1472         if(nearest_wp && nearest_wp.enemy)
1473         {
1474                 // often path can be optimized by not adding the nearest waypoint
1475                 if (this.goalentity.navigation_dynamicgoal || autocvar_g_waypointeditor)
1476                 {
1477                         if (nearest_wp.enemy.wpcost < autocvar_bot_ai_strategyinterval_movingtarget)
1478                         {
1479                                 if (vdist(vec2(this.goalentity.origin - nearest_wp.origin), <, 32))
1480                                         e = nearest_wp.enemy;
1481                                 else
1482                                 {
1483                                         set_tracewalk_dest(this.goalentity, nearest_wp.enemy.origin, true);
1484                                         if (trace_ent == this || (vdist(tracewalk_dest - nearest_wp.enemy.origin, <, 1050)
1485                                                 && vlen2(tracewalk_dest - nearest_wp.enemy.origin) < vlen2(nearest_wp.origin - nearest_wp.enemy.origin)
1486                                                 && tracewalk(this, nearest_wp.enemy.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
1487                                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
1488                                         {
1489                                                 e = nearest_wp.enemy;
1490                                         }
1491                                 }
1492                         }
1493                 }
1494                 else if(navigation_item_islinked(nearest_wp.enemy, this.goalentity))
1495                         e = nearest_wp.enemy;
1496         }
1497
1498         for (;;)
1499         {
1500                 // add the spawnfunc_waypoint to the path
1501                 navigation_pushroute(this, e);
1502                 e = e.enemy;
1503
1504                 if(e==NULL)
1505                         break;
1506         }
1507
1508         return false;
1509 }
1510
1511 // shorten path by removing intermediate goals
1512 void navigation_shortenpath(entity this)
1513 {
1514         if (!this.goalstack01 || wasfreed(this.goalstack01))
1515                 return;
1516         if (this.bot_tracewalk_time > time)
1517                 return;
1518         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
1519
1520         bool cut_allowed = false;
1521         entity next = this.goalentity;
1522         // evaluate whether bot can discard current route and chase directly a player, trying to
1523         // keep waypoint route as long as possible, as it is safer and faster (bot can bunnyhop)
1524         if (IS_MOVABLE(next))
1525         {
1526                 set_tracewalk_dest(next, this.origin, true);
1527                 if (vdist(this.origin - tracewalk_dest, <, 200))
1528                         cut_allowed = true;
1529                 else if (vdist(tracewalk_dest - this.origin, <, MAX_CHASE_DISTANCE)
1530                         && vdist(tracewalk_dest - this.goalcurrent.origin, >, 200)
1531                         && vdist(this.origin - this.goalcurrent.origin, >, 100)
1532                         && checkpvs(this.origin + this.view_ofs, next))
1533                 {
1534                         if (vlen2(next.origin - this.origin) < vlen2(this.goalcurrent.origin - this.origin))
1535                                 cut_allowed = true;
1536                         else
1537                         {
1538                                 vector deviation = vectoangles(this.goalcurrent.origin - this.origin) - vectoangles(next.origin - this.origin);
1539                                 while (deviation.y < -180) deviation.y += 360;
1540                                 while (deviation.y > 180) deviation.y -= 360;
1541                                 if (fabs(deviation.y) > 25)
1542                                         cut_allowed = true;
1543                         }
1544                 }
1545                 if (cut_allowed)
1546                 {
1547                         if (trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
1548                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1549                         {
1550                                 LOG_DEBUG("path optimized for ", this.netname, ", route cleared");
1551                                 do
1552                                 {
1553                                         navigation_poproute(this);
1554                                 }
1555                                 while (this.goalcurrent != next);
1556                         }
1557                         return;
1558                 }
1559         }
1560
1561         next = this.goalstack01;
1562         // if for some reason the bot is closer to the next goal, pop the current one
1563         if (!IS_MOVABLE(next) // already checked in the previous case
1564                 && vlen2(this.goalcurrent.origin - next.origin) > vlen2(next.origin - this.origin)
1565                 && checkpvs(this.origin + this.view_ofs, next))
1566         {
1567                 set_tracewalk_dest(next, this.origin, true);
1568                 cut_allowed = true;
1569         }
1570
1571         if (cut_allowed)
1572         {
1573                 if (trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
1574                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1575                 {
1576                         LOG_DEBUG("path optimized for ", this.netname, ", removed a goal from the queue");
1577                         navigation_poproute(this);
1578                 }
1579         }
1580 }
1581
1582 // removes any currently touching waypoints from the goal stack
1583 // (this is how bots detect if they reached a goal)
1584 int navigation_poptouchedgoals(entity this)
1585 {
1586         int removed_goals = 0;
1587
1588         if(!this.goalcurrent)
1589                 return removed_goals;
1590
1591         if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1592         {
1593                 // make sure jumppad is really hit, don't rely on distance based checks
1594                 // as they may report a touch even if it didn't really happen
1595                 if(this.lastteleporttime > 0 && TELEPORT_USED(this, this.goalcurrent))
1596                 {
1597                         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1598                         if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1599                         {
1600                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1601                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1602                         }
1603                         navigation_poproute(this);
1604                         this.lastteleporttime = 0;
1605                         ++removed_goals;
1606                 }
1607                 else
1608                         return removed_goals;
1609         }
1610         else if (this.lastteleporttime > 0)
1611         {
1612                 // sometimes bot is pushed so hard (by a jumppad or a shot) that ends up touching the next
1613                 // teleport / jumppad / warpzone present in its path skipping check of one or more goals
1614                 // if so immediately fix bot path by removing skipped goals
1615                 entity tele_ent = NULL;
1616                 if (this.goalstack01 && (this.goalstack01.wpflags & WAYPOINTFLAG_TELEPORT))
1617                         tele_ent = this.goalstack01;
1618                 else if (this.goalstack02 && (this.goalstack02.wpflags & WAYPOINTFLAG_TELEPORT))
1619                         tele_ent = this.goalstack02;
1620                 else if (this.goalstack03 && (this.goalstack03.wpflags & WAYPOINTFLAG_TELEPORT))
1621                         tele_ent = this.goalstack03;
1622                 if (tele_ent && TELEPORT_USED(this, tele_ent))
1623                 {
1624                         if (this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1625                         if (tele_ent.wpflags & WAYPOINTFLAG_PERSONAL && tele_ent.owner == this)
1626                         {
1627                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1628                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1629                         }
1630                         while (this.goalcurrent != tele_ent)
1631                         {
1632                                 navigation_poproute(this);
1633                                 ++removed_goals;
1634                         }
1635                         navigation_poproute(this);
1636                         this.lastteleporttime = 0;
1637                         ++removed_goals;
1638                         return removed_goals;
1639                 }
1640         }
1641
1642         // Loose goal touching check when running
1643         if(this.aistatus & AI_STATUS_RUNNING)
1644         if(this.goalcurrent.classname=="waypoint")
1645         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
1646         {
1647                 if(vdist(this.origin - this.goalcurrent.origin, <, 150))
1648                 {
1649                         traceline(this.origin + this.view_ofs , this.goalcurrent.origin, true, NULL);
1650                         if(trace_fraction==1)
1651                         {
1652                                 // Detect personal waypoints
1653                                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1654                                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1655                                 {
1656                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1657                                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1658                                 }
1659
1660                                 navigation_poproute(this);
1661                                 ++removed_goals;
1662                                 if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1663                                         return removed_goals;
1664                         }
1665                 }
1666         }
1667
1668         while (this.goalcurrent && !IS_PLAYER(this.goalcurrent))
1669         {
1670                 vector gc_min = this.goalcurrent.absmin;
1671                 vector gc_max = this.goalcurrent.absmax;
1672                 if(this.goalcurrent.classname == "waypoint" && !this.goalcurrent.wpisbox)
1673                 {
1674                         gc_min = this.goalcurrent.origin - '1 1 1' * 12;
1675                         gc_max = this.goalcurrent.origin + '1 1 1' * 12;
1676                 }
1677                 if(!boxesoverlap(this.absmin, this.absmax, gc_min, gc_max))
1678                         break;
1679
1680                 // Detect personal waypoints
1681                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1682                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1683                 {
1684                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1685                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1686                 }
1687
1688                 navigation_poproute(this);
1689                 ++removed_goals;
1690                 if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1691                         return removed_goals;
1692         }
1693         return removed_goals;
1694 }
1695
1696 entity navigation_get_really_close_waypoint(entity this)
1697 {
1698         entity wp = this.goalcurrent;
1699         if(!wp)
1700                 wp = this.goalcurrent_prev;
1701         if(!wp)
1702                 return NULL;
1703         if(wp != this.goalcurrent_prev && vdist(wp.origin - this.origin, >, 50))
1704         {
1705                 wp = this.goalcurrent_prev;
1706                 if(!wp)
1707                         return NULL;
1708         }
1709         if(wp.classname != "waypoint")
1710         {
1711                 wp = wp.nearestwaypoint;
1712                 if(!wp)
1713                         return NULL;
1714         }
1715         if(vdist(wp.origin - this.origin, >, 50))
1716         {
1717                 wp = NULL;
1718                 IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1719                 {
1720                         if(vdist(it.origin - this.origin, <, 50))
1721                         {
1722                                 wp = it;
1723                                 break;
1724                         }
1725                 });
1726                 if(!wp)
1727                         return NULL;
1728         }
1729         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1730                 return NULL;
1731
1732         set_tracewalk_dest(wp, this.origin, false);
1733         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
1734                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1735         {
1736                 return NULL;
1737         }
1738         return wp;
1739 }
1740
1741 // begin a goal selection session (queries spawnfunc_waypoint network)
1742 void navigation_goalrating_start(entity this)
1743 {
1744         if(this.aistatus & AI_STATUS_STUCK)
1745                 return;
1746
1747         this.navigation_jetpack_goal = NULL;
1748         navigation_bestrating = -1;
1749         entity wp = navigation_get_really_close_waypoint(this);
1750         navigation_clearroute(this);
1751         navigation_bestgoal = NULL;
1752         navigation_markroutes(this, wp);
1753 }
1754
1755 // ends a goal selection session (updates goal stack to the best goal)
1756 void navigation_goalrating_end(entity this)
1757 {
1758         if(this.aistatus & AI_STATUS_STUCK)
1759                 return;
1760
1761         navigation_routetogoal(this, navigation_bestgoal, this.origin);
1762         LOG_DEBUG("best goal ", this.goalcurrent.classname);
1763
1764         // If the bot got stuck then try to reach the farthest waypoint
1765         if (!this.goalentity && autocvar_bot_wander_enable)
1766         {
1767                 if (!(this.aistatus & AI_STATUS_STUCK))
1768                 {
1769                         LOG_DEBUG(this.netname, " cannot walk to any goal");
1770                         this.aistatus |= AI_STATUS_STUCK;
1771                 }
1772         }
1773         this.goalentity_shouldbefrozen = boolean(STAT(FROZEN, this.goalentity));
1774 }
1775
1776 void botframe_updatedangerousobjects(float maxupdate)
1777 {
1778         vector m1, m2, v, o;
1779         float c, d, danger;
1780         c = 0;
1781         entity wp_cur;
1782         IL_EACH(g_waypoints, true,
1783         {
1784                 danger = 0;
1785                 m1 = it.absmin;
1786                 m2 = it.absmax;
1787                 wp_cur = it;
1788                 IL_EACH(g_bot_dodge, it.bot_dodge,
1789                 {
1790                         v = it.origin;
1791                         v.x = bound(m1_x, v.x, m2_x);
1792                         v.y = bound(m1_y, v.y, m2_y);
1793                         v.z = bound(m1_z, v.z, m2_z);
1794                         o = (it.absmin + it.absmax) * 0.5;
1795                         d = waypoint_getlinearcost(it.bot_dodgerating) - waypoint_gettravelcost(o, v, it, wp_cur);
1796                         if (d > 0)
1797                         {
1798                                 traceline(o, v, true, NULL);
1799                                 if (trace_fraction == 1)
1800                                         danger = danger + d;
1801                         }
1802                 });
1803                 it.dmg = danger;
1804                 c = c + 1;
1805                 if (c >= maxupdate)
1806                         break;
1807         });
1808 }
1809
1810 void navigation_unstuck(entity this)
1811 {
1812         if (!autocvar_bot_wander_enable)
1813                 return;
1814
1815         bool has_user_waypoints = false;
1816         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_GENERATED),
1817         {
1818                 has_user_waypoints = true;
1819                 break;
1820         });
1821         if (!has_user_waypoints)
1822                 return;
1823
1824         float search_radius = 1000;
1825
1826         if (!bot_waypoint_queue_owner)
1827         {
1828                 LOG_DEBUG(this.netname, " stuck, taking over the waypoints queue");
1829                 bot_waypoint_queue_owner = this;
1830                 bot_waypoint_queue_bestgoal = NULL;
1831                 bot_waypoint_queue_bestgoalrating = 0;
1832         }
1833
1834         if(bot_waypoint_queue_owner!=this)
1835                 return;
1836
1837         if (bot_waypoint_queue_goal)
1838         {
1839                 // evaluate the next goal on the queue
1840                 float d = vlen2(this.origin - bot_waypoint_queue_goal.origin);
1841                 LOG_DEBUG(this.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d));
1842                 set_tracewalk_dest(bot_waypoint_queue_goal, this.origin, false);
1843                 if (tracewalk(bot_waypoint_queue_goal, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
1844                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1845                 {
1846                         if( d > bot_waypoint_queue_bestgoalrating)
1847                         {
1848                                 bot_waypoint_queue_bestgoalrating = d;
1849                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1850                         }
1851                 }
1852                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1853
1854                 if (!bot_waypoint_queue_goal)
1855                 {
1856                         if (bot_waypoint_queue_bestgoal)
1857                         {
1858                                 LOG_DEBUG(this.netname, " stuck, reachable waypoint found, heading to it");
1859                                 navigation_routetogoal(this, bot_waypoint_queue_bestgoal, this.origin);
1860                                 navigation_goalrating_timeout_set(this);
1861                                 this.aistatus &= ~AI_STATUS_STUCK;
1862                         }
1863                         else
1864                         {
1865                                 LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1866                         }
1867
1868                         bot_waypoint_queue_owner = NULL;
1869                 }
1870         }
1871         else
1872         {
1873                 if(bot_strategytoken!=this)
1874                         return;
1875
1876                 // build a new queue
1877                 LOG_DEBUG(this.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu");
1878
1879                 entity first = NULL;
1880
1881                 FOREACH_ENTITY_RADIUS(this.origin, search_radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
1882                 {
1883                         if(bot_waypoint_queue_goal)
1884                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = it;
1885                         else
1886                                 first = it;
1887
1888                         bot_waypoint_queue_goal = it;
1889                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = NULL;
1890                 });
1891
1892                 if (first)
1893                         bot_waypoint_queue_goal = first;
1894                 else
1895                 {
1896                         LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1897                         bot_waypoint_queue_owner = NULL;
1898                 }
1899         }
1900 }
1901
1902 // Support for debugging tracewalk visually
1903
1904 void debugresetnodes()
1905 {
1906         debuglastnode = '0 0 0';
1907 }
1908
1909 void debugnode(entity this, vector node)
1910 {
1911         if (!IS_PLAYER(this))
1912                 return;
1913
1914         if(debuglastnode=='0 0 0')
1915         {
1916                 debuglastnode = node;
1917                 return;
1918         }
1919
1920         te_lightning2(NULL, node, debuglastnode);
1921         debuglastnode = node;
1922 }
1923
1924 void debugnodestatus(vector position, float status)
1925 {
1926         vector c;
1927
1928         switch (status)
1929         {
1930                 case DEBUG_NODE_SUCCESS:
1931                         c = '0 15 0';
1932                         break;
1933                 case DEBUG_NODE_WARNING:
1934                         c = '15 15 0';
1935                         break;
1936                 case DEBUG_NODE_FAIL:
1937                         c = '15 0 0';
1938                         break;
1939                 default:
1940                         c = '15 15 15';
1941         }
1942
1943         te_customflash(position, 40,  2, c);
1944 }
1945
1946 // Support for debugging the goal stack visually
1947
1948 .float goalcounter;
1949 .vector lastposition;
1950
1951 // Debug the goal stack visually
1952 void debuggoalstack(entity this)
1953 {
1954         entity goal;
1955         vector org, go;
1956
1957         if(this.goalcounter==0)goal=this.goalcurrent;
1958         else if(this.goalcounter==1)goal=this.goalstack01;
1959         else if(this.goalcounter==2)goal=this.goalstack02;
1960         else if(this.goalcounter==3)goal=this.goalstack03;
1961         else if(this.goalcounter==4)goal=this.goalstack04;
1962         else if(this.goalcounter==5)goal=this.goalstack05;
1963         else if(this.goalcounter==6)goal=this.goalstack06;
1964         else if(this.goalcounter==7)goal=this.goalstack07;
1965         else if(this.goalcounter==8)goal=this.goalstack08;
1966         else if(this.goalcounter==9)goal=this.goalstack09;
1967         else if(this.goalcounter==10)goal=this.goalstack10;
1968         else if(this.goalcounter==11)goal=this.goalstack11;
1969         else if(this.goalcounter==12)goal=this.goalstack12;
1970         else if(this.goalcounter==13)goal=this.goalstack13;
1971         else if(this.goalcounter==14)goal=this.goalstack14;
1972         else if(this.goalcounter==15)goal=this.goalstack15;
1973         else if(this.goalcounter==16)goal=this.goalstack16;
1974         else if(this.goalcounter==17)goal=this.goalstack17;
1975         else if(this.goalcounter==18)goal=this.goalstack18;
1976         else if(this.goalcounter==19)goal=this.goalstack19;
1977         else if(this.goalcounter==20)goal=this.goalstack20;
1978         else if(this.goalcounter==21)goal=this.goalstack21;
1979         else if(this.goalcounter==22)goal=this.goalstack22;
1980         else if(this.goalcounter==23)goal=this.goalstack23;
1981         else if(this.goalcounter==24)goal=this.goalstack24;
1982         else if(this.goalcounter==25)goal=this.goalstack25;
1983         else if(this.goalcounter==26)goal=this.goalstack26;
1984         else if(this.goalcounter==27)goal=this.goalstack27;
1985         else if(this.goalcounter==28)goal=this.goalstack28;
1986         else if(this.goalcounter==29)goal=this.goalstack29;
1987         else if(this.goalcounter==30)goal=this.goalstack30;
1988         else if(this.goalcounter==31)goal=this.goalstack31;
1989         else goal=NULL;
1990
1991         if(goal==NULL)
1992         {
1993                 this.goalcounter = 0;
1994                 this.lastposition='0 0 0';
1995                 return;
1996         }
1997
1998         if(this.lastposition=='0 0 0')
1999                 org = this.origin;
2000         else
2001                 org = this.lastposition;
2002
2003
2004         go = ( goal.absmin + goal.absmax ) * 0.5;
2005         te_lightning2(NULL, org, go);
2006         this.lastposition = go;
2007
2008         this.goalcounter++;
2009 }