qcsrc/server/bot/default/navigation.qc

   1 #include "navigation.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "waypoints.qh"
   7
   8 #include <common/t_items.qh>
   9
  10 #include <common/items/_mod.qh>
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/triggers/trigger/jumppads.qh>
  15
  16 .float speed;
  17
  18 void navigation_dynamicgoal_init(entity this, bool initially_static)
  19 {
  20         this.navigation_dynamicgoal = true;
  21         this.bot_basewaypoint = this.nearestwaypoint;
  22         if(initially_static)
  23                 this.nearestwaypointtimeout = -1;
  24         else
  25                 this.nearestwaypointtimeout = time;
  26 }
  27
  28 void navigation_dynamicgoal_set(entity this)
  29 {
  30         this.nearestwaypointtimeout = time;
  31 }
  32
  33 void navigation_dynamicgoal_unset(entity this)
  34 {
  35         if(this.bot_basewaypoint)
  36                 this.nearestwaypoint = this.bot_basewaypoint;
  37         this.nearestwaypointtimeout = -1;
  38 }
  39
  40 bool navigation_check_submerged_state(entity ent, vector pos)
  41 {
  42         bool submerged;
  43         if(IS_PLAYER(ent))
  44                 submerged = (ent.waterlevel == WATERLEVEL_SUBMERGED);
  45         else if(ent.nav_submerged_state != SUBMERGED_UNDEFINED)
  46                 submerged = (ent.nav_submerged_state == SUBMERGED_YES);
  47         else
  48         {
  49                 submerged = SUBMERGED(pos);
  50                 // NOTE: SUBMERGED check of box waypoint origin may fail even if origin
  51                 //  is actually submerged because often they are inside some solid.
  52                 //  That's why submerged state is saved now that we know current pos is
  53                 //  not stuck in solid (previous tracewalk call to this pos was successfully)
  54                 if(!ent.navigation_dynamicgoal)
  55                         ent.nav_submerged_state = (submerged) ? SUBMERGED_YES : SUBMERGED_NO;
  56         }
  57         return submerged;
  58 }
  59
  60 bool navigation_checkladders(entity e, vector org, vector m1, vector m2, vector end, vector end2, int movemode)
  61 {
  62         IL_EACH(g_ladders, it.classname == "func_ladder",
  63         {
  64                 if(it.bot_pickup)
  65                 if(boxesoverlap(org + m1 + '-1 -1 -1', org + m2 + '1 1 1', it.absmin, it.absmax))
  66                 if(boxesoverlap(end, end2, it.absmin + vec2(m1) + '-1 -1 0', it.absmax + vec2(m2) + '1 1 0'))
  67                 {
  68                         vector top = org;
  69                         top.z = it.absmax.z + (PL_MAX_CONST.z - PL_MIN_CONST.z);
  70                         tracebox(org, m1, m2, top, movemode, e);
  71                         if(trace_fraction == 1)
  72                                 return true;
  73                 }
  74         });
  75         return false;
  76 }
  77
  78 vector resurface_limited(vector org, float lim, vector m1)
  79 {
  80         if (WETFEET(org + eZ * (lim - org.z)))
  81                 org.z = lim;
  82         else
  83         {
  84                 float RES_min_h = org.z;
  85                 float RES_max_h = lim;
  86                 do {
  87                         org.z = 0.5 * (RES_min_h + RES_max_h);
  88                         if(WETFEET(org))
  89                                 RES_min_h = org.z;
  90                         else
  91                                 RES_max_h = org.z;
  92                 } while (RES_max_h - RES_min_h >= 1);
  93                 org.z = RES_min_h;
  94         }
  95         return org;
  96 }
  97 #define RESURFACE_LIMITED(org, lim) org = resurface_limited(org, lim, m1)
  98
  99 #define NAV_WALK 0
 100 #define NAV_SWIM_ONWATER 1
 101 #define NAV_SWIM_UNDERWATER 2
 102
 103 // rough simulation of walking from one point to another to test if a path
 104 // can be traveled, used for waypoint linking and havocbot
 105 // if end_height is > 0 destination is any point in the vertical segment [end, end + end_height * eZ]
 106 bool tracewalk(entity e, vector start, vector m1, vector m2, vector end, float end_height, float movemode)
 107 {
 108         if(autocvar_bot_debug_tracewalk)
 109         {
 110                 debugresetnodes();
 111                 debugnode(e, start);
 112         }
 113
 114         vector org = start;
 115         vector flatdir = end - start;
 116         flatdir.z = 0;
 117         float flatdist = vlen(flatdir);
 118         flatdir = normalize(flatdir);
 119         float stepdist = 32;
 120         bool ignorehazards = false;
 121         int nav_action;
 122
 123         // Analyze starting point
 124         traceline(start, start, MOVE_NORMAL, e);
 125         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 126                 ignorehazards = true;
 127
 128         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
 129         if (trace_startsolid)
 130         {
 131                 // Bad start
 132                 if(autocvar_bot_debug_tracewalk)
 133                         debugnodestatus(start, DEBUG_NODE_FAIL);
 134
 135                 //print("tracewalk: ", vtos(start), " is a bad start\n");
 136                 return false;
 137         }
 138
 139         vector end2 = end;
 140         if(end_height)
 141                 end2.z += end_height;
 142
 143         vector fixed_end = end;
 144         vector move;
 145
 146         if (flatdist > 0 && WETFEET(org))
 147         {
 148                 if (SUBMERGED(org))
 149                         nav_action = NAV_SWIM_UNDERWATER;
 150                 else
 151                 {
 152                         // tracebox down by player's height
 153                         // useful to know if water level is so low that bot can still walk
 154                         tracebox(org, m1, m2, org - eZ * (m2.z - m1.z), movemode, e);
 155                         if (SUBMERGED(trace_endpos))
 156                         {
 157                                 org = trace_endpos;
 158                                 nav_action = NAV_SWIM_UNDERWATER;
 159                         }
 160                         else
 161                                 nav_action = NAV_WALK;
 162                 }
 163         }
 164         else
 165                 nav_action =  NAV_WALK;
 166
 167         // Movement loop
 168         while (true)
 169         {
 170                 if (flatdist <= 0)
 171                 {
 172                         bool success = true;
 173                         if (org.z > end2.z + 1)
 174                         {
 175                                 tracebox(org, m1, m2, end2, movemode, e);
 176                                 org = trace_endpos;
 177                                 if (org.z > end2.z + 1)
 178                                         success = false;
 179                         }
 180                         else if (org.z < end.z - 1)
 181                         {
 182                                 tracebox(org, m1, m2, org - jumpheight_vec, movemode, e);
 183                                 if (SUBMERGED(trace_endpos))
 184                                         RESURFACE_LIMITED(trace_endpos, end.z);
 185                                 else if (trace_endpos.z > org.z - jumpheight_vec.z)
 186                                         tracebox(trace_endpos, m1, m2, trace_endpos + jumpheight_vec, movemode, e);
 187                                 org = trace_endpos;
 188                                 if (org.z < end.z - 1)
 189                                         success = false;
 190                         }
 191
 192                         if (success)
 193                         {
 194                                 // Succeeded
 195                                 if(autocvar_bot_debug_tracewalk)
 196                                 {
 197                                         debugnode(e, org);
 198                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 199                                 }
 200
 201                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 202                                 return true;
 203                         }
 204                 }
 205
 206                 if(autocvar_bot_debug_tracewalk)
 207                         debugnode(e, org);
 208
 209                 if (flatdist <= 0)
 210                         break;
 211
 212                 if (stepdist > flatdist)
 213                         stepdist = flatdist;
 214                 if(nav_action == NAV_SWIM_UNDERWATER || (nav_action == NAV_SWIM_ONWATER && org.z > end2.z))
 215                 {
 216                         // can't use movement direction here to calculate move because of
 217                         // precision errors especially when direction has a high enough z value
 218                         //water_dir = normalize(water_end - org);
 219                         //move = org + water_dir * stepdist;
 220                         fixed_end.z = bound(end.z, org.z, end2.z);
 221                         if (stepdist == flatdist) {
 222                                 move = fixed_end;
 223                                 flatdist = 0;
 224                         } else {
 225                                 move = org + (fixed_end - org) * (stepdist / flatdist);
 226                                 flatdist = vlen(vec2(fixed_end - move));
 227                         }
 228                 }
 229                 else // horiz. direction
 230                 {
 231                         flatdist -= stepdist;
 232                         move = org + flatdir * stepdist;
 233                 }
 234
 235                 if(nav_action == NAV_SWIM_ONWATER)
 236                 {
 237                         tracebox(org, m1, m2, move, movemode, e); // swim
 238
 239                         // hit something
 240                         if (trace_fraction < 1)
 241                         {
 242                                 // stepswim
 243                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 244
 245                                 if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 246                                 {
 247                                         org = trace_endpos;
 248                                         if(navigation_checkladders(e, org, m1, m2, end, end2, movemode))
 249                                         {
 250                                                 if(autocvar_bot_debug_tracewalk)
 251                                                 {
 252                                                         debugnode(e, org);
 253                                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 254                                                 }
 255
 256                                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 257                                                 return true;
 258                                         }
 259
 260                                         if(autocvar_bot_debug_tracewalk)
 261                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 262
 263                                         return false;
 264                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 265                                 }
 266
 267                                 //succesful stepswim
 268
 269                                 if (flatdist <= 0)
 270                                 {
 271                                         org = trace_endpos;
 272                                         continue;
 273                                 }
 274
 275                                 if (org.z <= move.z) // going horiz.
 276                                 {
 277                                         tracebox(trace_endpos, m1, m2, move, movemode, e);
 278                                         org = trace_endpos;
 279                                         nav_action = NAV_WALK;
 280                                         continue;
 281                                 }
 282                         }
 283
 284                         if (org.z <= move.z) // going horiz.
 285                         {
 286                                 org = trace_endpos;
 287                                 nav_action = NAV_SWIM_ONWATER;
 288                         }
 289                         else // going down
 290                         {
 291                                 org = trace_endpos;
 292                                 if (SUBMERGED(org))
 293                                         nav_action = NAV_SWIM_UNDERWATER;
 294                                 else
 295                                         nav_action = NAV_SWIM_ONWATER;
 296                         }
 297                 }
 298                 else if(nav_action == NAV_SWIM_UNDERWATER)
 299                 {
 300                         if (move.z >= org.z) // swimming upwards or horiz.
 301                         {
 302                                 tracebox(org, m1, m2, move, movemode, e); // swim
 303
 304                                 bool stepswimmed = false;
 305
 306                                 // hit something
 307                                 if (trace_fraction < 1)
 308                                 {
 309                                         // stepswim
 310                                         vector stepswim_move = move + stepheightvec;
 311                                         if (flatdist > 0 && stepswim_move.z > end2.z + stepheightvec.z) // don't allow stepswim to go higher than destination
 312                                                 stepswim_move.z = end2.z;
 313
 314                                         tracebox(org + stepheightvec, m1, m2, stepswim_move, movemode, e);
 315
 316                                         // hit something
 317                                         if (trace_startsolid)
 318                                         {
 319                                                 if(autocvar_bot_debug_tracewalk)
 320                                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 321
 322                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 323                                                 return false;
 324                                         }
 325
 326                                         if (trace_fraction < 1)
 327                                         {
 328                                                 float org_z_prev = org.z;
 329                                                 RESURFACE_LIMITED(org, end2.z);
 330                                                 if(org.z == org_z_prev)
 331                                                 {
 332                                                         if(autocvar_bot_debug_tracewalk)
 333                                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 334
 335                                                         //print("tracewalk: ", vtos(start), " can't reach ", vtos(end), "\n");
 336                                                         return false;
 337                                                 }
 338                                                 if(SUBMERGED(org))
 339                                                         nav_action = NAV_SWIM_UNDERWATER;
 340                                                 else
 341                                                         nav_action = NAV_SWIM_ONWATER;
 342
 343                                                 // we didn't advance horiz. in this step, flatdist decrease should be reverted
 344                                                 // but we can't do it properly right now... apply this workaround instead
 345                                                 if (flatdist <= 0)
 346                                                         flatdist = 1;
 347
 348                                                 continue;
 349                                         }
 350
 351                                         //succesful stepswim
 352
 353                                         if (flatdist <= 0)
 354                                         {
 355                                                 org = trace_endpos;
 356                                                 continue;
 357                                         }
 358
 359                                         stepswimmed = true;
 360                                 }
 361
 362                                 if (!WETFEET(trace_endpos))
 363                                 {
 364                                         tracebox(trace_endpos, m1, m2, trace_endpos - eZ * (stepdist + (m2.z - m1.z)), movemode, e);
 365                                         // if stepswimmed we'll land on the obstacle, avoid the SUBMERGED check
 366                                         if (!stepswimmed && SUBMERGED(trace_endpos))
 367                                         {
 368                                                 RESURFACE_LIMITED(trace_endpos, end2.z);
 369                                                 org = trace_endpos;
 370                                                 nav_action = NAV_SWIM_ONWATER;
 371                                                 continue;
 372                                         }
 373
 374                                         // not submerged
 375                                         org = trace_endpos;
 376                                         nav_action = NAV_WALK;
 377                                         continue;
 378                                 }
 379
 380                                 // wetfeet
 381                                 org = trace_endpos;
 382                                 nav_action = NAV_SWIM_UNDERWATER;
 383                                 continue;
 384                         }
 385                         else //if (move.z < org.z) // swimming downwards
 386                         {
 387                                 tracebox(org, m1, m2, move, movemode, e); // swim
 388
 389                                 // hit something
 390                                 if (trace_fraction < 1)
 391                                 {
 392                                         // stepswim
 393                                         tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 394
 395                                         // hit something
 396                                         if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 397                                         {
 398                                                 if(autocvar_bot_debug_tracewalk)
 399                                                         debugnodestatus(move, DEBUG_NODE_FAIL);
 400
 401                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 402                                                 return false;
 403                                         }
 404
 405                                         //succesful stepswim
 406
 407                                         if (flatdist <= 0)
 408                                         {
 409                                                 org = trace_endpos;
 410                                                 continue;
 411                                         }
 412
 413                                         if (trace_endpos.z > org.z && !SUBMERGED(trace_endpos))
 414                                         {
 415                                                 // stepswim caused upwards direction
 416                                                 tracebox(trace_endpos, m1, m2, trace_endpos - stepheightvec, movemode, e);
 417                                                 if (!SUBMERGED(trace_endpos))
 418                                                 {
 419                                                         org = trace_endpos;
 420                                                         nav_action = NAV_WALK;
 421                                                         continue;
 422                                                 }
 423                                         }
 424                                 }
 425
 426                                 org = trace_endpos;
 427                                 nav_action = NAV_SWIM_UNDERWATER;
 428                                 continue;
 429                         }
 430                 }
 431                 else if(nav_action == NAV_WALK)
 432                 {
 433                         // walk
 434                         tracebox(org, m1, m2, move, movemode, e);
 435
 436                         if(autocvar_bot_debug_tracewalk)
 437                                 debugnode(e, trace_endpos);
 438
 439                         // hit something
 440                         if (trace_fraction < 1)
 441                         {
 442                                 // check if we can walk over this obstacle, possibly by jumpstepping
 443                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 444                                 if (trace_fraction < 1 || trace_startsolid)
 445                                 {
 446                                         if (trace_startsolid) // hit ceiling above org
 447                                         {
 448                                                 // reduce stepwalk height
 449                                                 tracebox(org, m1, m2, org + stepheightvec, movemode, e);
 450                                                 tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 451                                         }
 452                                         else //if (trace_fraction < 1)
 453                                         {
 454                                                 tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 455                                                 if (trace_startsolid) // hit ceiling above org
 456                                                 {
 457                                                         // reduce jumpstepwalk height
 458                                                         tracebox(org, m1, m2, org + jumpstepheightvec, movemode, e);
 459                                                         tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 460                                                 }
 461                                         }
 462
 463                                         if (trace_fraction < 1)
 464                                         {
 465                                                 vector v = trace_endpos;
 466                                                 v.z = org.z + jumpheight_vec.z;
 467                                                 if(navigation_checkladders(e, v, m1, m2, end, end2, movemode))
 468                                                 {
 469                                                         if(autocvar_bot_debug_tracewalk)
 470                                                         {
 471                                                                 debugnode(e, v);
 472                                                                 debugnodestatus(v, DEBUG_NODE_SUCCESS);
 473                                                         }
 474
 475                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 476                                                         return true;
 477                                                 }
 478
 479                                                 if(autocvar_bot_debug_tracewalk)
 480                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 481
 482                                                 traceline( org, move, movemode, e);
 483
 484                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 485                                                 {
 486                                                         vector nextmove;
 487                                                         move = trace_endpos;
 488                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 489                                                         {
 490                                                                 nextmove = move + (flatdir * stepdist);
 491                                                                 traceline( move, nextmove, movemode, e);
 492                                                                 move = nextmove;
 493                                                         }
 494                                                         flatdist = vlen(vec2(end - move));
 495                                                 }
 496                                                 else
 497                                                 {
 498                                                         if(autocvar_bot_debug_tracewalk)
 499                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 500
 501                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 502                                                         //te_explosion(trace_endpos);
 503                                                         //print(ftos(e.dphitcontentsmask), "\n");
 504                                                         return false; // failed
 505                                                 }
 506                                         }
 507                                         else
 508                                                 move = trace_endpos;
 509                                 }
 510                                 else
 511                                         move = trace_endpos;
 512                         }
 513                         else
 514                                 move = trace_endpos;
 515
 516                         // trace down from stepheight as far as possible and move there,
 517                         // if this starts in solid we try again without the stepup, and
 518                         // if that also fails we assume it is a wall
 519                         // (this is the same logic as the Quake walkmove function used)
 520                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 521
 522                         org = trace_endpos;
 523
 524                         if (!ignorehazards)
 525                         {
 526                                 if (IN_LAVA(org))
 527                                 {
 528                                         if(autocvar_bot_debug_tracewalk)
 529                                         {
 530                                                 debugnode(e, trace_endpos);
 531                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 532                                         }
 533
 534                                         //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 535                                         return false;
 536                                 }
 537                         }
 538
 539                         if (flatdist <= 0)
 540                         {
 541                                 if(move.z >= end2.z && org.z < end2.z)
 542                                         org.z = end2.z;
 543                                 continue;
 544                         }
 545
 546                         if(org.z > move.z - 1 || !SUBMERGED(org))
 547                         {
 548                                 nav_action = NAV_WALK;
 549                                 continue;
 550                         }
 551
 552                         // ended up submerged while walking
 553                         if(autocvar_bot_debug_tracewalk)
 554                                 debugnode(e, org);
 555
 556                         RESURFACE_LIMITED(org, move.z);
 557                         nav_action = NAV_SWIM_ONWATER;
 558                         continue;
 559                 }
 560         }
 561
 562         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 563
 564         // moved but didn't arrive at the intended destination
 565         if(autocvar_bot_debug_tracewalk)
 566                 debugnodestatus(org, DEBUG_NODE_FAIL);
 567
 568         return false;
 569 }
 570
 571 /////////////////////////////////////////////////////////////////////////////
 572 // goal stack
 573 /////////////////////////////////////////////////////////////////////////////
 574
 575 // completely empty the goal stack, used when deciding where to go
 576 void navigation_clearroute(entity this)
 577 {
 578         this.goalcurrent_prev = this.goalcurrent;
 579         this.goalcurrent_distance = 10000000;
 580         this.goalcurrent_distance_time = 0;
 581         //print("bot ", etos(this), " clear\n");
 582         this.goalentity = NULL;
 583         this.goalcurrent = NULL;
 584         this.goalstack01 = NULL;
 585         this.goalstack02 = NULL;
 586         this.goalstack03 = NULL;
 587         this.goalstack04 = NULL;
 588         this.goalstack05 = NULL;
 589         this.goalstack06 = NULL;
 590         this.goalstack07 = NULL;
 591         this.goalstack08 = NULL;
 592         this.goalstack09 = NULL;
 593         this.goalstack10 = NULL;
 594         this.goalstack11 = NULL;
 595         this.goalstack12 = NULL;
 596         this.goalstack13 = NULL;
 597         this.goalstack14 = NULL;
 598         this.goalstack15 = NULL;
 599         this.goalstack16 = NULL;
 600         this.goalstack17 = NULL;
 601         this.goalstack18 = NULL;
 602         this.goalstack19 = NULL;
 603         this.goalstack20 = NULL;
 604         this.goalstack21 = NULL;
 605         this.goalstack22 = NULL;
 606         this.goalstack23 = NULL;
 607         this.goalstack24 = NULL;
 608         this.goalstack25 = NULL;
 609         this.goalstack26 = NULL;
 610         this.goalstack27 = NULL;
 611         this.goalstack28 = NULL;
 612         this.goalstack29 = NULL;
 613         this.goalstack30 = NULL;
 614         this.goalstack31 = NULL;
 615 }
 616
 617 // add a new goal at the beginning of the stack
 618 // (in other words: add a new prerequisite before going to the later goals)
 619 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 620 // next-closest WP on the shortest path to the WP
 621 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 622 // steps to the goal, and then recalculate the path.
 623 void navigation_pushroute(entity this, entity e)
 624 {
 625         this.goalcurrent_prev = this.goalcurrent;
 626         this.goalcurrent_distance = 10000000;
 627         this.goalcurrent_distance_time = 0;
 628         //print("bot ", etos(this), " push ", etos(e), "\n");
 629         if(this.goalstack31 == this.goalentity)
 630                 this.goalentity = NULL;
 631         this.goalstack31 = this.goalstack30;
 632         this.goalstack30 = this.goalstack29;
 633         this.goalstack29 = this.goalstack28;
 634         this.goalstack28 = this.goalstack27;
 635         this.goalstack27 = this.goalstack26;
 636         this.goalstack26 = this.goalstack25;
 637         this.goalstack25 = this.goalstack24;
 638         this.goalstack24 = this.goalstack23;
 639         this.goalstack23 = this.goalstack22;
 640         this.goalstack22 = this.goalstack21;
 641         this.goalstack21 = this.goalstack20;
 642         this.goalstack20 = this.goalstack19;
 643         this.goalstack19 = this.goalstack18;
 644         this.goalstack18 = this.goalstack17;
 645         this.goalstack17 = this.goalstack16;
 646         this.goalstack16 = this.goalstack15;
 647         this.goalstack15 = this.goalstack14;
 648         this.goalstack14 = this.goalstack13;
 649         this.goalstack13 = this.goalstack12;
 650         this.goalstack12 = this.goalstack11;
 651         this.goalstack11 = this.goalstack10;
 652         this.goalstack10 = this.goalstack09;
 653         this.goalstack09 = this.goalstack08;
 654         this.goalstack08 = this.goalstack07;
 655         this.goalstack07 = this.goalstack06;
 656         this.goalstack06 = this.goalstack05;
 657         this.goalstack05 = this.goalstack04;
 658         this.goalstack04 = this.goalstack03;
 659         this.goalstack03 = this.goalstack02;
 660         this.goalstack02 = this.goalstack01;
 661         this.goalstack01 = this.goalcurrent;
 662         this.goalcurrent = e;
 663 }
 664
 665 // remove first goal from stack
 666 // (in other words: remove a prerequisite for reaching the later goals)
 667 // (used when a spawnfunc_waypoint is reached)
 668 void navigation_poproute(entity this)
 669 {
 670         this.goalcurrent_prev = this.goalcurrent;
 671         this.goalcurrent_distance = 10000000;
 672         this.goalcurrent_distance_time = 0;
 673         //print("bot ", etos(this), " pop\n");
 674         if(this.goalcurrent == this.goalentity)
 675                 this.goalentity = NULL;
 676         this.goalcurrent = this.goalstack01;
 677         this.goalstack01 = this.goalstack02;
 678         this.goalstack02 = this.goalstack03;
 679         this.goalstack03 = this.goalstack04;
 680         this.goalstack04 = this.goalstack05;
 681         this.goalstack05 = this.goalstack06;
 682         this.goalstack06 = this.goalstack07;
 683         this.goalstack07 = this.goalstack08;
 684         this.goalstack08 = this.goalstack09;
 685         this.goalstack09 = this.goalstack10;
 686         this.goalstack10 = this.goalstack11;
 687         this.goalstack11 = this.goalstack12;
 688         this.goalstack12 = this.goalstack13;
 689         this.goalstack13 = this.goalstack14;
 690         this.goalstack14 = this.goalstack15;
 691         this.goalstack15 = this.goalstack16;
 692         this.goalstack16 = this.goalstack17;
 693         this.goalstack17 = this.goalstack18;
 694         this.goalstack18 = this.goalstack19;
 695         this.goalstack19 = this.goalstack20;
 696         this.goalstack20 = this.goalstack21;
 697         this.goalstack21 = this.goalstack22;
 698         this.goalstack22 = this.goalstack23;
 699         this.goalstack23 = this.goalstack24;
 700         this.goalstack24 = this.goalstack25;
 701         this.goalstack25 = this.goalstack26;
 702         this.goalstack26 = this.goalstack27;
 703         this.goalstack27 = this.goalstack28;
 704         this.goalstack28 = this.goalstack29;
 705         this.goalstack29 = this.goalstack30;
 706         this.goalstack30 = this.goalstack31;
 707         this.goalstack31 = NULL;
 708 }
 709
 710 // walking to wp (walkfromwp == false) v2 and v2_height will be used as
 711 // waypoint destination coordinates instead of v (only useful for box waypoints)
 712 // for normal waypoints v2 == v and v2_height == 0
 713 float navigation_waypoint_will_link(vector v, vector org, entity ent, vector v2, float v2_height, float walkfromwp, float bestdist)
 714 {
 715         if (vdist(v - org, <, bestdist))
 716         {
 717                 traceline(v, org, true, ent);
 718                 if (trace_fraction == 1)
 719                 {
 720                         if (walkfromwp)
 721                         {
 722                                 if (tracewalk(ent, v, PL_MIN_CONST, PL_MAX_CONST, org, 0, bot_navigation_movemode))
 723                                         return true;
 724                         }
 725                         else
 726                         {
 727                                 if (tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, v2, v2_height, bot_navigation_movemode))
 728                                         return true;
 729                         }
 730                 }
 731         }
 732         return false;
 733 }
 734
 735 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 736 entity navigation_findnearestwaypoint_withdist_except(entity ent, float walkfromwp, float bestdist, entity except)
 737 {
 738         vector pm1 = ent.origin + ent.mins;
 739         vector pm2 = ent.origin + ent.maxs;
 740
 741         // do two scans, because box test is cheaper
 742         IL_EACH(g_waypoints, it != ent && it != except,
 743         {
 744                 if(boxesoverlap(pm1, pm2, it.absmin, it.absmax))
 745                         return it;
 746         });
 747
 748         vector org = ent.origin + 0.5 * (ent.mins + ent.maxs);
 749         org.z = ent.origin.z + ent.mins.z - PL_MIN_CONST.z; // player height
 750         // TODO possibly make other code have the same support for bboxes
 751         if(ent.tag_entity)
 752                 org = org + ent.tag_entity.origin;
 753         if (navigation_testtracewalk)
 754                 te_plasmaburn(org);
 755
 756         entity best = NULL;
 757         vector v, v2;
 758         float v2_height;
 759
 760         if(!autocvar_g_waypointeditor && !ent.navigation_dynamicgoal)
 761         {
 762                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 763                 IL_EACH(g_waypoints, it != ent,
 764                 {
 765                         if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 766                                 continue;
 767
 768                         SET_TRACEWALK_DESTCOORDS_2(it, org, v, v2, v2_height);
 769                         if(navigation_waypoint_will_link(v, org, ent, v2, v2_height, walkfromwp, 1050))
 770                                 navigation_item_addlink(it, ent);
 771                 });
 772         }
 773
 774         // box check failed, try walk
 775         IL_EACH(g_waypoints, it != ent,
 776         {
 777                 if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 778                         continue;
 779                 SET_TRACEWALK_DESTCOORDS_2(it, org, v, v2, v2_height);
 780                 if(navigation_waypoint_will_link(v, org, ent, v2, v2_height, walkfromwp, bestdist))
 781                 {
 782                         bestdist = vlen(v - org);
 783                         best = it;
 784                 }
 785         });
 786         return best;
 787 }
 788 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 789 {
 790         entity wp = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, NULL);
 791         if (autocvar_g_waypointeditor_auto)
 792         {
 793                 entity wp2 = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, wp);
 794                 if (wp && !wp2)
 795                         wp.wpflags |= WAYPOINTFLAG_PROTECTED;
 796         }
 797         return wp;
 798 }
 799
 800 // finds the waypoints near the bot initiating a navigation query
 801 float navigation_markroutes_nearestwaypoints(entity this, float maxdist)
 802 {
 803         vector v;
 804         //navigation_testtracewalk = true;
 805         int c = 0;
 806         float v_height;
 807         IL_EACH(g_waypoints, !it.wpconsidered,
 808         {
 809                 SET_TRACEWALK_DESTCOORDS(it, this.origin, v, v_height);
 810
 811                 vector diff = v - this.origin;
 812                 diff.z = max(0, diff.z);
 813                 if(vdist(diff, <, maxdist))
 814                 {
 815                         it.wpconsidered = true;
 816                         if (tracewalk(this, this.origin, this.mins, this.maxs, v, v_height, bot_navigation_movemode))
 817                         {
 818                                 it.wpnearestpoint = v;
 819                                 it.wpcost = waypoint_gettravelcost(this.origin, v, this, it) + it.dmg;
 820                                 it.wpfire = 1;
 821                                 it.enemy = NULL;
 822                                 c = c + 1;
 823                         }
 824                 }
 825         });
 826         //navigation_testtracewalk = false;
 827         return c;
 828 }
 829
 830 // updates a path link if a spawnfunc_waypoint link is better than the current one
 831 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost, vector p)
 832 {
 833         vector m1, m2;
 834         vector v;
 835         if (wp.wpisbox)
 836         {
 837                 m1 = wp.origin + wp.mins;
 838                 m2 = wp.origin + wp.maxs;
 839                 v.x = bound(m1_x, p.x, m2_x);
 840                 v.y = bound(m1_y, p.y, m2_y);
 841                 v.z = bound(m1_z, p.z, m2_z);
 842         }
 843         else
 844                 v = wp.origin;
 845         if (w.wpflags & WAYPOINTFLAG_TELEPORT)
 846                 cost += w.wp00mincost; // assuming teleport has exactly one destination
 847         else
 848                 cost += waypoint_gettravelcost(p, v, w, wp);
 849         if (wp.wpcost > cost)
 850         {
 851                 wp.wpcost = cost;
 852                 wp.enemy = w;
 853                 wp.wpfire = 1;
 854                 wp.wpnearestpoint = v;
 855         }
 856 }
 857
 858 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 859 void navigation_markroutes(entity this, entity fixed_source_waypoint)
 860 {
 861         float cost, cost2;
 862         vector p;
 863
 864         IL_EACH(g_waypoints, true,
 865         {
 866                 it.wpconsidered = false;
 867                 it.wpnearestpoint = '0 0 0';
 868                 it.wpcost = 10000000;
 869                 it.wpfire = 0;
 870                 it.enemy = NULL;
 871         });
 872
 873         if(fixed_source_waypoint)
 874         {
 875                 fixed_source_waypoint.wpconsidered = true;
 876                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 877                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 878                 fixed_source_waypoint.wpfire = 1;
 879                 fixed_source_waypoint.enemy = NULL;
 880         }
 881         else
 882         {
 883                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 884                 // as this search is expensive we will use lower values if the bot is on the air
 885                 float increment, maxdistance;
 886                 if(IS_ONGROUND(this))
 887                 {
 888                         increment = 750;
 889                         maxdistance = 50000;
 890                 }
 891                 else
 892                 {
 893                         increment = 500;
 894                         maxdistance = 1500;
 895                 }
 896
 897                 for(int j = increment; !navigation_markroutes_nearestwaypoints(this, j) && j < maxdistance; j += increment);
 898         }
 899
 900         bool searching = true;
 901         while (searching)
 902         {
 903                 searching = false;
 904                 IL_EACH(g_waypoints, it.wpfire,
 905                 {
 906                         searching = true;
 907                         it.wpfire = 0;
 908                         cost = it.wpcost;
 909                         p = it.wpnearestpoint;
 910                         entity wp;
 911                         wp = it.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp00mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 912                         wp = it.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp01mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 913                         wp = it.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp02mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 914                         wp = it.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp03mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 915                         wp = it.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp04mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 916                         wp = it.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp05mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 917                         wp = it.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp06mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 918                         wp = it.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp07mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 919                         wp = it.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp08mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 920                         wp = it.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp09mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 921                         wp = it.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp10mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 922                         wp = it.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp11mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 923                         wp = it.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp12mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 924                         wp = it.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp13mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 925                         wp = it.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp14mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 926                         wp = it.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp15mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 927                         wp = it.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp16mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 928                         wp = it.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp17mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 929                         wp = it.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp18mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 930                         wp = it.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp19mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 931                         wp = it.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp20mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 932                         wp = it.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp21mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 933                         wp = it.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp22mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 934                         wp = it.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp23mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 935                         wp = it.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp24mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 936                         wp = it.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp25mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 937                         wp = it.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp26mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 938                         wp = it.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp27mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 939                         wp = it.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp28mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 940                         wp = it.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp29mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 941                         wp = it.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp30mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 942                         wp = it.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp31mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 943                         }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 944                 });
 945         }
 946 }
 947
 948 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 949 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 950 {
 951         float cost, cost2;
 952         vector p;
 953         IL_EACH(g_waypoints, true,
 954         {
 955                 it.wpconsidered = false;
 956                 it.wpnearestpoint = '0 0 0';
 957                 it.wpcost = 10000000;
 958                 it.wpfire = 0;
 959                 it.enemy = NULL;
 960         });
 961
 962         if(fixed_source_waypoint)
 963         {
 964                 fixed_source_waypoint.wpconsidered = true;
 965                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 966                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
 967                 fixed_source_waypoint.wpfire = 1;
 968                 fixed_source_waypoint.enemy = NULL;
 969         }
 970         else
 971         {
 972                 error("need to start with a waypoint\n");
 973         }
 974
 975         bool searching = true;
 976         while (searching)
 977         {
 978                 searching = false;
 979                 IL_EACH(g_waypoints, it.wpfire,
 980                 {
 981                         searching = true;
 982                         it.wpfire = 0;
 983                         cost = it.wpcost; // cost to walk from it to home
 984                         p = it.wpnearestpoint;
 985                         entity wp = it;
 986                         IL_EACH(g_waypoints, it != wp,
 987                         {
 988                                 if(!waypoint_islinked(it, wp))
 989                                         continue;
 990                                 cost2 = cost + it.dmg;
 991                                 navigation_markroutes_checkwaypoint(wp, it, cost2, p);
 992                         });
 993                 });
 994         }
 995 }
 996
 997 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
 998 void navigation_routerating(entity this, entity e, float f, float rangebias)
 999 {
1000         if (!e)
1001                 return;
1002
1003         if(e.blacklisted)
1004                 return;
1005
1006         rangebias = waypoint_getlinearcost(rangebias);
1007         f = waypoint_getlinearcost(f);
1008
1009         if (IS_PLAYER(e))
1010         {
1011                 bool rate_wps = false;
1012                 if((e.flags & FL_INWATER) || (e.flags & FL_PARTIALGROUND))
1013                         rate_wps = true;
1014
1015                 if(!IS_ONGROUND(e))
1016                 {
1017                         traceline(e.origin, e.origin + '0 0 -1500', true, NULL);
1018                         int t = pointcontents(trace_endpos + '0 0 1');
1019                         if(t != CONTENT_SOLID )
1020                         {
1021                                 if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
1022                                         rate_wps = true;
1023                                 else if(tracebox_hits_trigger_hurt(e.origin, e.mins, e.maxs, trace_endpos))
1024                                         return;
1025                         }
1026                 }
1027
1028                 if(rate_wps)
1029                 {
1030                         entity theEnemy = e;
1031                         entity best_wp = NULL;
1032                         float best_dist = 10000;
1033                         IL_EACH(g_waypoints, vdist(it.origin - theEnemy.origin, <, 500)
1034                                 && vdist(it.origin - this.origin, >, 100)
1035                                 && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1036                         {
1037                                 float dist = vlen(it.origin - theEnemy.origin);
1038                                 if (dist < best_dist)
1039                                 {
1040                                         best_wp = it;
1041                                         best_dist = dist;
1042                                 }
1043                         });
1044                         if (!best_wp)
1045                                 return;
1046                         e = best_wp;
1047                 }
1048         }
1049
1050         vector goal_org = (e.absmin + e.absmax) * 0.5;
1051
1052         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
1053
1054         // Evaluate path using jetpack
1055         if(g_jetpack)
1056         if(this.items & IT_JETPACK)
1057         if(autocvar_bot_ai_navigation_jetpack)
1058         if(vdist(this.origin - goal_org, >, autocvar_bot_ai_navigation_jetpack_mindistance))
1059         {
1060                 vector pointa, pointb;
1061
1062                 LOG_DEBUG("jetpack ai: evaluating path for ", e.classname);
1063
1064                 // Point A
1065                 traceline(this.origin, this.origin + '0 0 65535', MOVE_NORMAL, this);
1066                 pointa = trace_endpos - '0 0 1';
1067
1068                 // Point B
1069                 traceline(goal_org, goal_org + '0 0 65535', MOVE_NORMAL, e);
1070                 pointb = trace_endpos - '0 0 1';
1071
1072                 // Can I see these two points from the sky?
1073                 traceline(pointa, pointb, MOVE_NORMAL, this);
1074
1075                 if(trace_fraction==1)
1076                 {
1077                         LOG_DEBUG("jetpack ai: can bridge these two points");
1078
1079                         // Lower the altitude of these points as much as possible
1080                         float zdistance, xydistance, cost, t, fuel;
1081                         vector down, npa, npb;
1082
1083                         down = '0 0 -1' * (STAT(PL_MAX, this).z - STAT(PL_MIN, this).z) * 10;
1084
1085                         do{
1086                                 npa = pointa + down;
1087                                 npb = pointb + down;
1088
1089                                 if(npa.z<=this.absmax.z)
1090                                         break;
1091
1092                                 if(npb.z<=e.absmax.z)
1093                                         break;
1094
1095                                 traceline(npa, npb, MOVE_NORMAL, this);
1096                                 if(trace_fraction==1)
1097                                 {
1098                                         pointa = npa;
1099                                         pointb = npb;
1100                                 }
1101                         }
1102                         while(trace_fraction == 1);
1103
1104
1105                         // Rough estimation of fuel consumption
1106                         // (ignores acceleration and current xyz velocity)
1107                         xydistance = vlen(pointa - pointb);
1108                         zdistance = fabs(pointa.z - this.origin.z);
1109
1110                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
1111                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
1112                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
1113
1114                         LOG_DEBUG("jetpack ai: required fuel ", ftos(fuel), " this.ammo_fuel ", ftos(this.ammo_fuel));
1115
1116                         // enough fuel ?
1117                         if(this.ammo_fuel>fuel)
1118                         {
1119                                 // Estimate cost
1120                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
1121                                 //  - between air and ground speeds)
1122
1123                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
1124                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
1125                                 cost *= 1.5;
1126
1127                                 // Compare against other goals
1128                                 f = f * rangebias / (rangebias + cost);
1129
1130                                 if (navigation_bestrating < f)
1131                                 {
1132                                         LOG_DEBUG("jetpack path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1133                                         navigation_bestrating = f;
1134                                         navigation_bestgoal = e;
1135                                         this.navigation_jetpack_goal = e;
1136                                         this.navigation_jetpack_point = pointb;
1137                                 }
1138                                 return;
1139                         }
1140                 }
1141         }
1142
1143         entity nwp;
1144         //te_wizspike(e.origin);
1145         //bprint(etos(e));
1146         //bprint("\n");
1147         // update the cached spawnfunc_waypoint link on a dynamic item entity
1148         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1149         {
1150                 nwp = e;
1151         }
1152         else
1153         {
1154                 if(autocvar_g_waypointeditor && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1155                         e.nearestwaypoint = NULL;
1156
1157                 if ((!e.nearestwaypoint || e.navigation_dynamicgoal)
1158                         && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1159                 {
1160                         nwp = navigation_findnearestwaypoint(e, true);
1161                         if(nwp)
1162                         {
1163                                 e.nearestwaypoint = nwp;
1164
1165                                 vector m1 = nwp.absmin, m2 = nwp.absmax;
1166                                 m1.x = nwp.origin.x; m1.y = nwp.origin.y;
1167                                 m2.x = nwp.origin.x; m2.y = nwp.origin.y;
1168                                 vector ve = (e.absmin - e.absmax) * 0.5;
1169                                 ve.x = bound(m1.x, ve.x, m2.x);
1170                                 ve.y = bound(m1.y, ve.y, m2.y);
1171                                 ve.z = bound(m1.z, ve.z, m2.z);
1172
1173                                 m1 = e.absmin; m2 = e.absmax;
1174                                 m1.x = e.origin.x; m1.y = e.origin.y;
1175                                 m2.x = e.origin.x; m2.y = e.origin.y;
1176                                 vector vnwp = nwp.origin;
1177                                 vnwp.x = bound(m1.x, vnwp.x, m2.x);
1178                                 vnwp.y = bound(m1.y, vnwp.y, m2.y);
1179                                 vnwp.z = bound(m1.z, vnwp.z, m2.z);
1180                                 e.nearestwaypoint_dist = vlen(ve - vnwp);
1181                         }
1182                         else
1183                         {
1184                                 LOG_DEBUG("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e));
1185
1186                                 if(!e.navigation_dynamicgoal)
1187                                         e.blacklisted = true;
1188
1189                                 if(e.blacklisted)
1190                                 {
1191                                         LOG_DEBUG("The entity '", e.classname, "' is going to be excluded from path finding during this match");
1192                                         return;
1193                                 }
1194                         }
1195
1196                         if(e.navigation_dynamicgoal)
1197                                 e.nearestwaypointtimeout = time + 2;
1198                         else if(autocvar_g_waypointeditor)
1199                                 e.nearestwaypointtimeout = time + 3 + random() * 2;
1200                 }
1201                 nwp = e.nearestwaypoint;
1202         }
1203
1204         LOG_DEBUG("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")");
1205         if (nwp)
1206         if (nwp.wpcost < 10000000)
1207         {
1208                 //te_wizspike(nwp.wpnearestpoint);
1209                 float cost = nwp.wpcost + waypoint_gettravelcost(nwp.wpnearestpoint, goal_org, nwp, e);
1210                 LOG_DEBUG(e.classname, " ", ftos(f), "/(1+", ftos(cost), "/", ftos(rangebias), ") = ");
1211                 f = f * rangebias / (rangebias + cost);
1212                 LOG_DEBUG("considering ", e.classname, " (with rating ", ftos(f), ")");
1213                 if (navigation_bestrating < f)
1214                 {
1215                         LOG_DEBUG("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1216                         navigation_bestrating = f;
1217                         navigation_bestgoal = e;
1218                 }
1219         }
1220 }
1221
1222 // adds an item to the the goal stack with the path to a given item
1223 bool navigation_routetogoal(entity this, entity e, vector startposition)
1224 {
1225         // if there is no goal, just exit
1226         if (!e)
1227                 return false;
1228
1229         if(e.wpflags & WAYPOINTFLAG_TELEPORT)
1230         {
1231                 // force teleport destination as route destination
1232                 e.wp00.enemy = e;
1233                 e = e.wp00;
1234         }
1235
1236         this.goalentity = e;
1237
1238         // put the entity on the goal stack
1239         //print("routetogoal ", etos(e), "\n");
1240         navigation_pushroute(this, e);
1241
1242         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1243         {
1244                 this.wp_goal_prev1 = this.wp_goal_prev0;
1245                 this.wp_goal_prev0 = e;
1246         }
1247
1248         if(g_jetpack)
1249         if(e==this.navigation_jetpack_goal)
1250                 return true;
1251
1252         // if it can reach the goal there is nothing more to do
1253         vector dest = (e.absmin + e.absmax) * 0.5;
1254         dest.z = e.absmin.z;
1255         float dest_height = e.absmax.z - e.absmin.z;
1256         if (tracewalk(this, startposition, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1257                 return true;
1258
1259         entity nearest_wp = NULL;
1260         // see if there are waypoints describing a path to the item
1261         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
1262         {
1263                 e = e.nearestwaypoint;
1264                 nearest_wp = e;
1265         }
1266         else
1267                 e = e.enemy; // we already have added it, so...
1268
1269         if(e == NULL)
1270                 return false;
1271
1272         if(nearest_wp && nearest_wp.enemy)
1273         {
1274                 // often path can be optimized by not adding the nearest waypoint
1275                 if (this.goalentity.nearestwaypoint_dist < 8)
1276                         e = nearest_wp.enemy;
1277                 else
1278                 {
1279                         if (this.goalentity.navigation_dynamicgoal)
1280                         {
1281                                 vector dest = (this.goalentity.absmin + this.goalentity.absmax) * 0.5;
1282                                 dest.z = this.goalentity.absmin.z;
1283                                 float dest_height = this.goalentity.absmax.z - this.goalentity.absmin.z;
1284                                 if(tracewalk(this, nearest_wp.enemy.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1285                                         e = nearest_wp.enemy;
1286                         }
1287                         else if(navigation_item_islinked(nearest_wp.enemy, this.goalentity))
1288                                 e = nearest_wp.enemy;
1289                 }
1290         }
1291
1292         for (;;)
1293         {
1294                 // add the spawnfunc_waypoint to the path
1295                 navigation_pushroute(this, e);
1296                 e = e.enemy;
1297
1298                 if(e==NULL)
1299                         break;
1300         }
1301
1302         return false;
1303 }
1304
1305 // removes any currently touching waypoints from the goal stack
1306 // (this is how bots detect if they reached a goal)
1307 void navigation_poptouchedgoals(entity this)
1308 {
1309         if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1310         {
1311                 // make sure jumppad is really hit, don't rely on distance based checks
1312                 // as they may report a touch even if it didn't really happen
1313                 if(this.lastteleporttime > 0
1314                         && time - this.lastteleporttime < ((this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL) ? 2 : 0.15))
1315                 {
1316                         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1317                         if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1318                         {
1319                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1320                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1321                         }
1322                         navigation_poproute(this);
1323                 }
1324                 else
1325                         return;
1326         }
1327
1328         // If for some reason the bot is closer to the next goal, pop the current one
1329         if(this.goalstack01 && !wasfreed(this.goalstack01))
1330         if(vlen2(this.goalcurrent.origin - this.origin) > vlen2(this.goalstack01.origin - this.origin))
1331         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
1332         {
1333                 vector dest = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1334                 dest.z = this.goalstack01.absmin.z;
1335                 float dest_height = this.goalstack01.absmax.z - this.goalstack01.absmin.z;
1336                 if(tracewalk(this, this.origin, this.mins, this.maxs, dest, dest_height, bot_navigation_movemode))
1337                 {
1338                         LOG_DEBUG("path optimized for ", this.netname, ", removed a goal from the queue");
1339                         navigation_poproute(this);
1340                         // TODO this may also be a nice idea to do "early" (e.g. by
1341                         // manipulating the vlen() comparisons) to shorten paths in
1342                         // general - this would make bots walk more "on rails" than
1343                         // "zigzagging" which they currently do with sufficiently
1344                         // random-like waypoints, and thus can make a nice bot
1345                         // personality property
1346                 }
1347         }
1348
1349         // Loose goal touching check when running
1350         if(this.aistatus & AI_STATUS_RUNNING)
1351         if(this.goalcurrent.classname=="waypoint")
1352         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
1353         {
1354                 if(vdist(this.origin - this.goalcurrent.origin, <, 150))
1355                 {
1356                         traceline(this.origin + this.view_ofs , this.goalcurrent.origin, true, NULL);
1357                         if(trace_fraction==1)
1358                         {
1359                                 // Detect personal waypoints
1360                                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1361                                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1362                                 {
1363                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1364                                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1365                                 }
1366
1367                                 navigation_poproute(this);
1368                         }
1369                 }
1370         }
1371
1372         while (this.goalcurrent && !IS_PLAYER(this.goalcurrent))
1373         {
1374                 vector gc_min = this.goalcurrent.absmin;
1375                 vector gc_max = this.goalcurrent.absmax;
1376                 if(this.goalcurrent.classname == "waypoint" && !this.goalcurrent.wpisbox)
1377                 {
1378                         gc_min = this.goalcurrent.origin - '1 1 1' * 12;
1379                         gc_max = this.goalcurrent.origin + '1 1 1' * 12;
1380                 }
1381                 if(!boxesoverlap(this.absmin, this.absmax, gc_min, gc_max))
1382                         break;
1383
1384                 // Detect personal waypoints
1385                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1386                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1387                 {
1388                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1389                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1390                 }
1391
1392                 navigation_poproute(this);
1393         }
1394 }
1395
1396 // begin a goal selection session (queries spawnfunc_waypoint network)
1397 void navigation_goalrating_start(entity this)
1398 {
1399         if(this.aistatus & AI_STATUS_STUCK)
1400                 return;
1401
1402         this.navigation_jetpack_goal = NULL;
1403         navigation_bestrating = -1;
1404         navigation_clearroute(this);
1405         navigation_bestgoal = NULL;
1406         navigation_markroutes(this, NULL);
1407 }
1408
1409 // ends a goal selection session (updates goal stack to the best goal)
1410 void navigation_goalrating_end(entity this)
1411 {
1412         if(this.aistatus & AI_STATUS_STUCK)
1413                 return;
1414
1415         navigation_routetogoal(this, navigation_bestgoal, this.origin);
1416         LOG_DEBUG("best goal ", this.goalcurrent.classname);
1417
1418         // If the bot got stuck then try to reach the farthest waypoint
1419         if (!this.goalentity && autocvar_bot_wander_enable)
1420         {
1421                 if (!(this.aistatus & AI_STATUS_STUCK))
1422                 {
1423                         LOG_DEBUG(this.netname, " cannot walk to any goal");
1424                         this.aistatus |= AI_STATUS_STUCK;
1425                 }
1426         }
1427 }
1428
1429 void botframe_updatedangerousobjects(float maxupdate)
1430 {
1431         vector m1, m2, v, o;
1432         float c, d, danger;
1433         c = 0;
1434         entity wp_cur;
1435         IL_EACH(g_waypoints, true,
1436         {
1437                 danger = 0;
1438                 m1 = it.absmin;
1439                 m2 = it.absmax;
1440                 wp_cur = it;
1441                 IL_EACH(g_bot_dodge, it.bot_dodge,
1442                 {
1443                         v = it.origin;
1444                         v.x = bound(m1_x, v.x, m2_x);
1445                         v.y = bound(m1_y, v.y, m2_y);
1446                         v.z = bound(m1_z, v.z, m2_z);
1447                         o = (it.absmin + it.absmax) * 0.5;
1448                         d = waypoint_getlinearcost(it.bot_dodgerating) - waypoint_gettravelcost(o, v, it, wp_cur);
1449                         if (d > 0)
1450                         {
1451                                 traceline(o, v, true, NULL);
1452                                 if (trace_fraction == 1)
1453                                         danger = danger + d;
1454                         }
1455                 });
1456                 it.dmg = danger;
1457                 c = c + 1;
1458                 if (c >= maxupdate)
1459                         break;
1460         });
1461 }
1462
1463 void navigation_unstuck(entity this)
1464 {
1465         float search_radius = 1000;
1466
1467         if (!autocvar_bot_wander_enable)
1468                 return;
1469
1470         if (!bot_waypoint_queue_owner)
1471         {
1472                 LOG_DEBUG(this.netname, " stuck, taking over the waypoints queue");
1473                 bot_waypoint_queue_owner = this;
1474                 bot_waypoint_queue_bestgoal = NULL;
1475                 bot_waypoint_queue_bestgoalrating = 0;
1476         }
1477
1478         if(bot_waypoint_queue_owner!=this)
1479                 return;
1480
1481         if (bot_waypoint_queue_goal)
1482         {
1483                 // evaluate the next goal on the queue
1484                 float d = vlen2(this.origin - bot_waypoint_queue_goal.origin);
1485                 LOG_DEBUG(this.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d));
1486                 vector dest = (bot_waypoint_queue_goal.absmin + bot_waypoint_queue_goal.absmax) * 0.5;
1487                 dest.z = bot_waypoint_queue_goal.absmin.z;
1488                 float dest_height = bot_waypoint_queue_goal.absmax.z - bot_waypoint_queue_goal.absmin.z;
1489                 if(tracewalk(bot_waypoint_queue_goal, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1490                 {
1491                         if( d > bot_waypoint_queue_bestgoalrating)
1492                         {
1493                                 bot_waypoint_queue_bestgoalrating = d;
1494                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1495                         }
1496                 }
1497                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1498
1499                 if (!bot_waypoint_queue_goal)
1500                 {
1501                         if (bot_waypoint_queue_bestgoal)
1502                         {
1503                                 LOG_DEBUG(this.netname, " stuck, reachable waypoint found, heading to it");
1504                                 navigation_routetogoal(this, bot_waypoint_queue_bestgoal, this.origin);
1505                                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1506                                 this.aistatus &= ~AI_STATUS_STUCK;
1507                         }
1508                         else
1509                         {
1510                                 LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1511                         }
1512
1513                         bot_waypoint_queue_owner = NULL;
1514                 }
1515         }
1516         else
1517         {
1518                 if(bot_strategytoken!=this)
1519                         return;
1520
1521                 // build a new queue
1522                 LOG_DEBUG(this.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu");
1523
1524                 entity first = NULL;
1525
1526                 FOREACH_ENTITY_RADIUS(this.origin, search_radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
1527                 {
1528                         if(bot_waypoint_queue_goal)
1529                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = it;
1530                         else
1531                                 first = it;
1532
1533                         bot_waypoint_queue_goal = it;
1534                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = NULL;
1535                 });
1536
1537                 if (first)
1538                         bot_waypoint_queue_goal = first;
1539                 else
1540                 {
1541                         LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1542                         bot_waypoint_queue_owner = NULL;
1543                 }
1544         }
1545 }
1546
1547 // Support for debugging tracewalk visually
1548
1549 void debugresetnodes()
1550 {
1551         debuglastnode = '0 0 0';
1552 }
1553
1554 void debugnode(entity this, vector node)
1555 {
1556         if (!IS_PLAYER(this))
1557                 return;
1558
1559         if(debuglastnode=='0 0 0')
1560         {
1561                 debuglastnode = node;
1562                 return;
1563         }
1564
1565         te_lightning2(NULL, node, debuglastnode);
1566         debuglastnode = node;
1567 }
1568
1569 void debugnodestatus(vector position, float status)
1570 {
1571         vector c;
1572
1573         switch (status)
1574         {
1575                 case DEBUG_NODE_SUCCESS:
1576                         c = '0 15 0';
1577                         break;
1578                 case DEBUG_NODE_WARNING:
1579                         c = '15 15 0';
1580                         break;
1581                 case DEBUG_NODE_FAIL:
1582                         c = '15 0 0';
1583                         break;
1584                 default:
1585                         c = '15 15 15';
1586         }
1587
1588         te_customflash(position, 40,  2, c);
1589 }
1590
1591 // Support for debugging the goal stack visually
1592
1593 .float goalcounter;
1594 .vector lastposition;
1595
1596 // Debug the goal stack visually
1597 void debuggoalstack(entity this)
1598 {
1599         entity goal;
1600         vector org, go;
1601
1602         if(this.goalcounter==0)goal=this.goalcurrent;
1603         else if(this.goalcounter==1)goal=this.goalstack01;
1604         else if(this.goalcounter==2)goal=this.goalstack02;
1605         else if(this.goalcounter==3)goal=this.goalstack03;
1606         else if(this.goalcounter==4)goal=this.goalstack04;
1607         else if(this.goalcounter==5)goal=this.goalstack05;
1608         else if(this.goalcounter==6)goal=this.goalstack06;
1609         else if(this.goalcounter==7)goal=this.goalstack07;
1610         else if(this.goalcounter==8)goal=this.goalstack08;
1611         else if(this.goalcounter==9)goal=this.goalstack09;
1612         else if(this.goalcounter==10)goal=this.goalstack10;
1613         else if(this.goalcounter==11)goal=this.goalstack11;
1614         else if(this.goalcounter==12)goal=this.goalstack12;
1615         else if(this.goalcounter==13)goal=this.goalstack13;
1616         else if(this.goalcounter==14)goal=this.goalstack14;
1617         else if(this.goalcounter==15)goal=this.goalstack15;
1618         else if(this.goalcounter==16)goal=this.goalstack16;
1619         else if(this.goalcounter==17)goal=this.goalstack17;
1620         else if(this.goalcounter==18)goal=this.goalstack18;
1621         else if(this.goalcounter==19)goal=this.goalstack19;
1622         else if(this.goalcounter==20)goal=this.goalstack20;
1623         else if(this.goalcounter==21)goal=this.goalstack21;
1624         else if(this.goalcounter==22)goal=this.goalstack22;
1625         else if(this.goalcounter==23)goal=this.goalstack23;
1626         else if(this.goalcounter==24)goal=this.goalstack24;
1627         else if(this.goalcounter==25)goal=this.goalstack25;
1628         else if(this.goalcounter==26)goal=this.goalstack26;
1629         else if(this.goalcounter==27)goal=this.goalstack27;
1630         else if(this.goalcounter==28)goal=this.goalstack28;
1631         else if(this.goalcounter==29)goal=this.goalstack29;
1632         else if(this.goalcounter==30)goal=this.goalstack30;
1633         else if(this.goalcounter==31)goal=this.goalstack31;
1634         else goal=NULL;
1635
1636         if(goal==NULL)
1637         {
1638                 this.goalcounter = 0;
1639                 this.lastposition='0 0 0';
1640                 return;
1641         }
1642
1643         if(this.lastposition=='0 0 0')
1644                 org = this.origin;
1645         else
1646                 org = this.lastposition;
1647
1648
1649         go = ( goal.absmin + goal.absmax ) * 0.5;
1650         te_lightning2(NULL, org, go);
1651         this.lastposition = go;
1652
1653         this.goalcounter++;
1654 }