qcsrc/server/bot/default/navigation.qc

   1 #include "navigation.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "waypoints.qh"
   9
  10 #include <common/t_items.qh>
  11
  12 #include <common/items/_mod.qh>
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/triggers/trigger/jumppads.qh>
  17
  18 .float speed;
  19
  20 void navigation_goalrating_timeout_set(entity this)
  21 {
  22         if(IS_MOVABLE(this.goalentity))
  23                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval_movingtarget;
  24         else
  25                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
  26 }
  27
  28 void navigation_goalrating_timeout_force(entity this)
  29 {
  30         this.bot_strategytime = 0;
  31 }
  32
  33 bool navigation_goalrating_timeout(entity this)
  34 {
  35         return this.bot_strategytime < time;
  36 }
  37
  38 void navigation_dynamicgoal_init(entity this, bool initially_static)
  39 {
  40         this.navigation_dynamicgoal = true;
  41         this.bot_basewaypoint = this.nearestwaypoint;
  42         if(initially_static)
  43                 this.nearestwaypointtimeout = -1;
  44         else
  45                 this.nearestwaypointtimeout = time;
  46 }
  47
  48 void navigation_dynamicgoal_set(entity this)
  49 {
  50         this.nearestwaypointtimeout = time;
  51 }
  52
  53 void navigation_dynamicgoal_unset(entity this)
  54 {
  55         if(this.bot_basewaypoint)
  56                 this.nearestwaypoint = this.bot_basewaypoint;
  57         this.nearestwaypointtimeout = -1;
  58 }
  59
  60 bool navigation_check_submerged_state(entity ent, vector pos)
  61 {
  62         bool submerged;
  63         if(IS_PLAYER(ent))
  64                 submerged = (ent.waterlevel == WATERLEVEL_SUBMERGED);
  65         else if(ent.nav_submerged_state != SUBMERGED_UNDEFINED)
  66                 submerged = (ent.nav_submerged_state == SUBMERGED_YES);
  67         else
  68         {
  69                 submerged = SUBMERGED(pos);
  70                 // NOTE: SUBMERGED check of box waypoint origin may fail even if origin
  71                 //  is actually submerged because often they are inside some solid.
  72                 //  That's why submerged state is saved now that we know current pos is
  73                 //  not stuck in solid (previous tracewalk call to this pos was successfully)
  74                 if(!ent.navigation_dynamicgoal)
  75                         ent.nav_submerged_state = (submerged) ? SUBMERGED_YES : SUBMERGED_NO;
  76         }
  77         return submerged;
  78 }
  79
  80 bool navigation_checkladders(entity e, vector org, vector m1, vector m2, vector end, vector end2, int movemode)
  81 {
  82         IL_EACH(g_ladders, it.classname == "func_ladder",
  83         {
  84                 if(it.bot_pickup)
  85                 if(boxesoverlap(org + m1 + '-1 -1 -1', org + m2 + '1 1 1', it.absmin, it.absmax))
  86                 if(boxesoverlap(end, end2, it.absmin + vec2(m1) + '-1 -1 0', it.absmax + vec2(m2) + '1 1 0'))
  87                 {
  88                         vector top = org;
  89                         top.z = it.absmax.z + (PL_MAX_CONST.z - PL_MIN_CONST.z);
  90                         tracebox(org, m1, m2, top, movemode, e);
  91                         if(trace_fraction == 1)
  92                                 return true;
  93                 }
  94         });
  95         return false;
  96 }
  97
  98 vector resurface_limited(vector org, float lim, vector m1)
  99 {
 100         if (WETFEET(org + eZ * (lim - org.z)))
 101                 org.z = lim;
 102         else
 103         {
 104                 float RES_min_h = org.z;
 105                 float RES_max_h = lim;
 106                 do {
 107                         org.z = 0.5 * (RES_min_h + RES_max_h);
 108                         if(WETFEET(org))
 109                                 RES_min_h = org.z;
 110                         else
 111                                 RES_max_h = org.z;
 112                 } while (RES_max_h - RES_min_h >= 1);
 113                 org.z = RES_min_h;
 114         }
 115         return org;
 116 }
 117 #define RESURFACE_LIMITED(org, lim) org = resurface_limited(org, lim, m1)
 118
 119 #define NAV_WALK 0
 120 #define NAV_SWIM_ONWATER 1
 121 #define NAV_SWIM_UNDERWATER 2
 122
 123 // rough simulation of walking from one point to another to test if a path
 124 // can be traveled, used for waypoint linking and havocbot
 125 // if end_height is > 0 destination is any point in the vertical segment [end, end + end_height * eZ]
 126 bool tracewalk(entity e, vector start, vector m1, vector m2, vector end, float end_height, float movemode)
 127 {
 128         if(autocvar_bot_debug_tracewalk)
 129         {
 130                 debugresetnodes();
 131                 debugnode(e, start);
 132         }
 133
 134         vector org = start;
 135         vector flatdir = end - start;
 136         flatdir.z = 0;
 137         float flatdist = vlen(flatdir);
 138         flatdir = normalize(flatdir);
 139         float stepdist = 32;
 140         bool ignorehazards = false;
 141         int nav_action;
 142
 143         // Analyze starting point
 144         traceline(start, start, MOVE_NORMAL, e);
 145         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 146                 ignorehazards = true;
 147
 148         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
 149         if (trace_startsolid)
 150         {
 151                 // Bad start
 152                 if(autocvar_bot_debug_tracewalk)
 153                         debugnodestatus(start, DEBUG_NODE_FAIL);
 154
 155                 //print("tracewalk: ", vtos(start), " is a bad start\n");
 156                 return false;
 157         }
 158
 159         vector end2 = end;
 160         if(end_height)
 161                 end2.z += end_height;
 162
 163         vector fixed_end = end;
 164         vector move;
 165
 166         if (flatdist > 0 && WETFEET(org))
 167         {
 168                 if (SUBMERGED(org))
 169                         nav_action = NAV_SWIM_UNDERWATER;
 170                 else
 171                 {
 172                         // tracebox down by player's height
 173                         // useful to know if water level is so low that bot can still walk
 174                         tracebox(org, m1, m2, org - eZ * (m2.z - m1.z), movemode, e);
 175                         if (SUBMERGED(trace_endpos))
 176                         {
 177                                 org = trace_endpos;
 178                                 nav_action = NAV_SWIM_UNDERWATER;
 179                         }
 180                         else
 181                                 nav_action = NAV_WALK;
 182                 }
 183         }
 184         else
 185                 nav_action =  NAV_WALK;
 186
 187         // Movement loop
 188         while (true)
 189         {
 190                 if (flatdist <= 0)
 191                 {
 192                         bool success = true;
 193                         if (org.z > end2.z + 1)
 194                         {
 195                                 tracebox(org, m1, m2, end2, movemode, e);
 196                                 org = trace_endpos;
 197                                 if (org.z > end2.z + 1)
 198                                         success = false;
 199                         }
 200                         else if (org.z < end.z - 1)
 201                         {
 202                                 tracebox(org, m1, m2, org - jumpheight_vec, movemode, e);
 203                                 if (SUBMERGED(trace_endpos))
 204                                 {
 205                                         vector v = trace_endpos;
 206                                         tracebox(v, m1, m2, end, movemode, e);
 207                                         if(trace_endpos.z >= end.z - 1)
 208                                         {
 209                                                 RESURFACE_LIMITED(v, trace_endpos.z);
 210                                                 trace_endpos = v;
 211                                         }
 212                                 }
 213                                 else if (trace_endpos.z > org.z - jumpheight_vec.z)
 214                                         tracebox(trace_endpos, m1, m2, trace_endpos + jumpheight_vec, movemode, e);
 215                                 org = trace_endpos;
 216                                 if (org.z < end.z - 1)
 217                                         success = false;
 218                         }
 219
 220                         if (success)
 221                         {
 222                                 // Succeeded
 223                                 if(autocvar_bot_debug_tracewalk)
 224                                 {
 225                                         debugnode(e, org);
 226                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 227                                 }
 228
 229                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 230                                 return true;
 231                         }
 232                 }
 233
 234                 if(autocvar_bot_debug_tracewalk)
 235                         debugnode(e, org);
 236
 237                 if (flatdist <= 0)
 238                         break;
 239
 240                 if (stepdist > flatdist)
 241                         stepdist = flatdist;
 242                 if(nav_action == NAV_SWIM_UNDERWATER || (nav_action == NAV_SWIM_ONWATER && org.z > end2.z))
 243                 {
 244                         // can't use movement direction here to calculate move because of
 245                         // precision errors especially when direction has a high enough z value
 246                         //water_dir = normalize(water_end - org);
 247                         //move = org + water_dir * stepdist;
 248                         fixed_end.z = bound(end.z, org.z, end2.z);
 249                         if (stepdist == flatdist) {
 250                                 move = fixed_end;
 251                                 flatdist = 0;
 252                         } else {
 253                                 move = org + (fixed_end - org) * (stepdist / flatdist);
 254                                 flatdist = vlen(vec2(fixed_end - move));
 255                         }
 256                 }
 257                 else // horiz. direction
 258                 {
 259                         flatdist -= stepdist;
 260                         move = org + flatdir * stepdist;
 261                 }
 262
 263                 if(nav_action == NAV_SWIM_ONWATER)
 264                 {
 265                         tracebox(org, m1, m2, move, movemode, e); // swim
 266
 267                         // hit something
 268                         if (trace_fraction < 1)
 269                         {
 270                                 // stepswim
 271                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 272
 273                                 if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 274                                 {
 275                                         org = trace_endpos;
 276                                         if(navigation_checkladders(e, org, m1, m2, end, end2, movemode))
 277                                         {
 278                                                 if(autocvar_bot_debug_tracewalk)
 279                                                 {
 280                                                         debugnode(e, org);
 281                                                         debugnodestatus(org, DEBUG_NODE_SUCCESS);
 282                                                 }
 283
 284                                                 //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 285                                                 return true;
 286                                         }
 287
 288                                         if(autocvar_bot_debug_tracewalk)
 289                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 290
 291                                         return false;
 292                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 293                                 }
 294
 295                                 //succesful stepswim
 296
 297                                 if (flatdist <= 0)
 298                                 {
 299                                         org = trace_endpos;
 300                                         continue;
 301                                 }
 302
 303                                 if (org.z <= move.z) // going horiz.
 304                                 {
 305                                         tracebox(trace_endpos, m1, m2, move, movemode, e);
 306                                         org = trace_endpos;
 307                                         nav_action = NAV_WALK;
 308                                         continue;
 309                                 }
 310                         }
 311
 312                         if (org.z <= move.z) // going horiz.
 313                         {
 314                                 org = trace_endpos;
 315                                 nav_action = NAV_SWIM_ONWATER;
 316                         }
 317                         else // going down
 318                         {
 319                                 org = trace_endpos;
 320                                 if (SUBMERGED(org))
 321                                         nav_action = NAV_SWIM_UNDERWATER;
 322                                 else
 323                                         nav_action = NAV_SWIM_ONWATER;
 324                         }
 325                 }
 326                 else if(nav_action == NAV_SWIM_UNDERWATER)
 327                 {
 328                         if (move.z >= org.z) // swimming upwards or horiz.
 329                         {
 330                                 tracebox(org, m1, m2, move, movemode, e); // swim
 331
 332                                 bool stepswum = false;
 333
 334                                 // hit something
 335                                 if (trace_fraction < 1)
 336                                 {
 337                                         // stepswim
 338                                         vector stepswim_move = move + stepheightvec;
 339                                         if (flatdist > 0 && stepswim_move.z > end2.z + stepheightvec.z) // don't allow stepswim to go higher than destination
 340                                                 stepswim_move.z = end2.z;
 341
 342                                         tracebox(org + stepheightvec, m1, m2, stepswim_move, movemode, e);
 343
 344                                         // hit something
 345                                         if (trace_startsolid)
 346                                         {
 347                                                 if(autocvar_bot_debug_tracewalk)
 348                                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 349
 350                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 351                                                 return false;
 352                                         }
 353
 354                                         if (trace_fraction < 1)
 355                                         {
 356                                                 float org_z_prev = org.z;
 357                                                 RESURFACE_LIMITED(org, end2.z);
 358                                                 if(org.z == org_z_prev)
 359                                                 {
 360                                                         if(autocvar_bot_debug_tracewalk)
 361                                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 362
 363                                                         //print("tracewalk: ", vtos(start), " can't reach ", vtos(end), "\n");
 364                                                         return false;
 365                                                 }
 366                                                 if(SUBMERGED(org))
 367                                                         nav_action = NAV_SWIM_UNDERWATER;
 368                                                 else
 369                                                         nav_action = NAV_SWIM_ONWATER;
 370
 371                                                 // we didn't advance horiz. in this step, flatdist decrease should be reverted
 372                                                 // but we can't do it properly right now... apply this workaround instead
 373                                                 if (flatdist <= 0)
 374                                                         flatdist = 1;
 375
 376                                                 continue;
 377                                         }
 378
 379                                         //succesful stepswim
 380
 381                                         if (flatdist <= 0)
 382                                         {
 383                                                 org = trace_endpos;
 384                                                 continue;
 385                                         }
 386
 387                                         stepswum = true;
 388                                 }
 389
 390                                 if (!WETFEET(trace_endpos))
 391                                 {
 392                                         tracebox(trace_endpos, m1, m2, trace_endpos - eZ * (stepdist + (m2.z - m1.z)), movemode, e);
 393                                         // if stepswum we'll land on the obstacle, avoid the SUBMERGED check
 394                                         if (!stepswum && SUBMERGED(trace_endpos))
 395                                         {
 396                                                 RESURFACE_LIMITED(trace_endpos, end2.z);
 397                                                 org = trace_endpos;
 398                                                 nav_action = NAV_SWIM_ONWATER;
 399                                                 continue;
 400                                         }
 401
 402                                         // not submerged
 403                                         org = trace_endpos;
 404                                         nav_action = NAV_WALK;
 405                                         continue;
 406                                 }
 407
 408                                 // wetfeet
 409                                 org = trace_endpos;
 410                                 nav_action = NAV_SWIM_UNDERWATER;
 411                                 continue;
 412                         }
 413                         else //if (move.z < org.z) // swimming downwards
 414                         {
 415                                 tracebox(org, m1, m2, move, movemode, e); // swim
 416
 417                                 // hit something
 418                                 if (trace_fraction < 1)
 419                                 {
 420                                         // stepswim
 421                                         tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 422
 423                                         // hit something
 424                                         if (trace_fraction < 1 || trace_startsolid) // can't jump obstacle out of water
 425                                         {
 426                                                 if(autocvar_bot_debug_tracewalk)
 427                                                         debugnodestatus(move, DEBUG_NODE_FAIL);
 428
 429                                                 //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 430                                                 return false;
 431                                         }
 432
 433                                         //succesful stepswim
 434
 435                                         if (flatdist <= 0)
 436                                         {
 437                                                 org = trace_endpos;
 438                                                 continue;
 439                                         }
 440
 441                                         if (trace_endpos.z > org.z && !SUBMERGED(trace_endpos))
 442                                         {
 443                                                 // stepswim caused upwards direction
 444                                                 tracebox(trace_endpos, m1, m2, trace_endpos - stepheightvec, movemode, e);
 445                                                 if (!SUBMERGED(trace_endpos))
 446                                                 {
 447                                                         org = trace_endpos;
 448                                                         nav_action = NAV_WALK;
 449                                                         continue;
 450                                                 }
 451                                         }
 452                                 }
 453
 454                                 org = trace_endpos;
 455                                 nav_action = NAV_SWIM_UNDERWATER;
 456                                 continue;
 457                         }
 458                 }
 459                 else if(nav_action == NAV_WALK)
 460                 {
 461                         // walk
 462                         tracebox(org, m1, m2, move, movemode, e);
 463
 464                         if(autocvar_bot_debug_tracewalk)
 465                                 debugnode(e, trace_endpos);
 466
 467                         // hit something
 468                         if (trace_fraction < 1)
 469                         {
 470                                 // check if we can walk over this obstacle, possibly by jumpstepping
 471                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 472                                 if (trace_fraction < 1 || trace_startsolid)
 473                                 {
 474                                         if (trace_startsolid) // hit ceiling above org
 475                                         {
 476                                                 // reduce stepwalk height
 477                                                 tracebox(org, m1, m2, org + stepheightvec, movemode, e);
 478                                                 tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 479                                         }
 480                                         else //if (trace_fraction < 1)
 481                                         {
 482                                                 tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 483                                                 if (trace_startsolid) // hit ceiling above org
 484                                                 {
 485                                                         // reduce jumpstepwalk height
 486                                                         tracebox(org, m1, m2, org + jumpstepheightvec, movemode, e);
 487                                                         tracebox(trace_endpos, m1, m2, move + eZ * (trace_endpos.z - move.z), movemode, e);
 488                                                 }
 489                                         }
 490
 491                                         if (trace_fraction < 1)
 492                                         {
 493                                                 vector v = trace_endpos;
 494                                                 v.z = org.z + jumpheight_vec.z;
 495                                                 if(navigation_checkladders(e, v, m1, m2, end, end2, movemode))
 496                                                 {
 497                                                         if(autocvar_bot_debug_tracewalk)
 498                                                         {
 499                                                                 debugnode(e, v);
 500                                                                 debugnodestatus(v, DEBUG_NODE_SUCCESS);
 501                                                         }
 502
 503                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 504                                                         return true;
 505                                                 }
 506
 507                                                 if(autocvar_bot_debug_tracewalk)
 508                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 509
 510                                                 traceline( org, move, movemode, e);
 511
 512                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 513                                                 {
 514                                                         vector nextmove;
 515                                                         move = trace_endpos;
 516                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 517                                                         {
 518                                                                 nextmove = move + (flatdir * stepdist);
 519                                                                 traceline( move, nextmove, movemode, e);
 520                                                                 move = nextmove;
 521                                                         }
 522                                                         flatdist = vlen(vec2(end - move));
 523                                                 }
 524                                                 else
 525                                                 {
 526                                                         if(autocvar_bot_debug_tracewalk)
 527                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 528
 529                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 530                                                         //te_explosion(trace_endpos);
 531                                                         //print(ftos(e.dphitcontentsmask), "\n");
 532                                                         return false; // failed
 533                                                 }
 534                                         }
 535                                         else
 536                                                 move = trace_endpos;
 537                                 }
 538                                 else
 539                                         move = trace_endpos;
 540                         }
 541                         else
 542                                 move = trace_endpos;
 543
 544                         // trace down from stepheight as far as possible and move there,
 545                         // if this starts in solid we try again without the stepup, and
 546                         // if that also fails we assume it is a wall
 547                         // (this is the same logic as the Quake walkmove function used)
 548                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 549
 550                         org = trace_endpos;
 551
 552                         if (!ignorehazards)
 553                         {
 554                                 if (IN_LAVA(org))
 555                                 {
 556                                         if(autocvar_bot_debug_tracewalk)
 557                                         {
 558                                                 debugnode(e, trace_endpos);
 559                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 560                                         }
 561
 562                                         //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 563                                         return false;
 564                                 }
 565                         }
 566
 567                         if (flatdist <= 0)
 568                         {
 569                                 if(move.z >= end2.z && org.z < end2.z)
 570                                         org.z = end2.z;
 571                                 continue;
 572                         }
 573
 574                         if(org.z > move.z - 1 || !SUBMERGED(org))
 575                         {
 576                                 nav_action = NAV_WALK;
 577                                 continue;
 578                         }
 579
 580                         // ended up submerged while walking
 581                         if(autocvar_bot_debug_tracewalk)
 582                                 debugnode(e, org);
 583
 584                         RESURFACE_LIMITED(org, move.z);
 585                         nav_action = NAV_SWIM_ONWATER;
 586                         continue;
 587                 }
 588         }
 589
 590         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 591
 592         // moved but didn't arrive at the intended destination
 593         if(autocvar_bot_debug_tracewalk)
 594                 debugnodestatus(org, DEBUG_NODE_FAIL);
 595
 596         return false;
 597 }
 598
 599 /////////////////////////////////////////////////////////////////////////////
 600 // goal stack
 601 /////////////////////////////////////////////////////////////////////////////
 602
 603 // completely empty the goal stack, used when deciding where to go
 604 void navigation_clearroute(entity this)
 605 {
 606         this.goalcurrent_prev = this.goalcurrent;
 607         this.goalcurrent_distance = 10000000;
 608         this.goalcurrent_distance_time = 0;
 609         //print("bot ", etos(this), " clear\n");
 610         this.goalentity = NULL;
 611         this.goalcurrent = NULL;
 612         this.goalstack01 = NULL;
 613         this.goalstack02 = NULL;
 614         this.goalstack03 = NULL;
 615         this.goalstack04 = NULL;
 616         this.goalstack05 = NULL;
 617         this.goalstack06 = NULL;
 618         this.goalstack07 = NULL;
 619         this.goalstack08 = NULL;
 620         this.goalstack09 = NULL;
 621         this.goalstack10 = NULL;
 622         this.goalstack11 = NULL;
 623         this.goalstack12 = NULL;
 624         this.goalstack13 = NULL;
 625         this.goalstack14 = NULL;
 626         this.goalstack15 = NULL;
 627         this.goalstack16 = NULL;
 628         this.goalstack17 = NULL;
 629         this.goalstack18 = NULL;
 630         this.goalstack19 = NULL;
 631         this.goalstack20 = NULL;
 632         this.goalstack21 = NULL;
 633         this.goalstack22 = NULL;
 634         this.goalstack23 = NULL;
 635         this.goalstack24 = NULL;
 636         this.goalstack25 = NULL;
 637         this.goalstack26 = NULL;
 638         this.goalstack27 = NULL;
 639         this.goalstack28 = NULL;
 640         this.goalstack29 = NULL;
 641         this.goalstack30 = NULL;
 642         this.goalstack31 = NULL;
 643 }
 644
 645 // add a new goal at the beginning of the stack
 646 // (in other words: add a new prerequisite before going to the later goals)
 647 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 648 // next-closest WP on the shortest path to the WP
 649 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 650 // steps to the goal, and then recalculate the path.
 651 void navigation_pushroute(entity this, entity e)
 652 {
 653         this.goalcurrent_prev = this.goalcurrent;
 654         this.goalcurrent_distance = 10000000;
 655         this.goalcurrent_distance_time = 0;
 656         //print("bot ", etos(this), " push ", etos(e), "\n");
 657         if(this.goalstack31 == this.goalentity)
 658                 this.goalentity = NULL;
 659         this.goalstack31 = this.goalstack30;
 660         this.goalstack30 = this.goalstack29;
 661         this.goalstack29 = this.goalstack28;
 662         this.goalstack28 = this.goalstack27;
 663         this.goalstack27 = this.goalstack26;
 664         this.goalstack26 = this.goalstack25;
 665         this.goalstack25 = this.goalstack24;
 666         this.goalstack24 = this.goalstack23;
 667         this.goalstack23 = this.goalstack22;
 668         this.goalstack22 = this.goalstack21;
 669         this.goalstack21 = this.goalstack20;
 670         this.goalstack20 = this.goalstack19;
 671         this.goalstack19 = this.goalstack18;
 672         this.goalstack18 = this.goalstack17;
 673         this.goalstack17 = this.goalstack16;
 674         this.goalstack16 = this.goalstack15;
 675         this.goalstack15 = this.goalstack14;
 676         this.goalstack14 = this.goalstack13;
 677         this.goalstack13 = this.goalstack12;
 678         this.goalstack12 = this.goalstack11;
 679         this.goalstack11 = this.goalstack10;
 680         this.goalstack10 = this.goalstack09;
 681         this.goalstack09 = this.goalstack08;
 682         this.goalstack08 = this.goalstack07;
 683         this.goalstack07 = this.goalstack06;
 684         this.goalstack06 = this.goalstack05;
 685         this.goalstack05 = this.goalstack04;
 686         this.goalstack04 = this.goalstack03;
 687         this.goalstack03 = this.goalstack02;
 688         this.goalstack02 = this.goalstack01;
 689         this.goalstack01 = this.goalcurrent;
 690         this.goalcurrent = e;
 691 }
 692
 693 // remove first goal from stack
 694 // (in other words: remove a prerequisite for reaching the later goals)
 695 // (used when a spawnfunc_waypoint is reached)
 696 void navigation_poproute(entity this)
 697 {
 698         this.goalcurrent_prev = this.goalcurrent;
 699         this.goalcurrent_distance = 10000000;
 700         this.goalcurrent_distance_time = 0;
 701         //print("bot ", etos(this), " pop\n");
 702         if(this.goalcurrent == this.goalentity)
 703                 this.goalentity = NULL;
 704         this.goalcurrent = this.goalstack01;
 705         this.goalstack01 = this.goalstack02;
 706         this.goalstack02 = this.goalstack03;
 707         this.goalstack03 = this.goalstack04;
 708         this.goalstack04 = this.goalstack05;
 709         this.goalstack05 = this.goalstack06;
 710         this.goalstack06 = this.goalstack07;
 711         this.goalstack07 = this.goalstack08;
 712         this.goalstack08 = this.goalstack09;
 713         this.goalstack09 = this.goalstack10;
 714         this.goalstack10 = this.goalstack11;
 715         this.goalstack11 = this.goalstack12;
 716         this.goalstack12 = this.goalstack13;
 717         this.goalstack13 = this.goalstack14;
 718         this.goalstack14 = this.goalstack15;
 719         this.goalstack15 = this.goalstack16;
 720         this.goalstack16 = this.goalstack17;
 721         this.goalstack17 = this.goalstack18;
 722         this.goalstack18 = this.goalstack19;
 723         this.goalstack19 = this.goalstack20;
 724         this.goalstack20 = this.goalstack21;
 725         this.goalstack21 = this.goalstack22;
 726         this.goalstack22 = this.goalstack23;
 727         this.goalstack23 = this.goalstack24;
 728         this.goalstack24 = this.goalstack25;
 729         this.goalstack25 = this.goalstack26;
 730         this.goalstack26 = this.goalstack27;
 731         this.goalstack27 = this.goalstack28;
 732         this.goalstack28 = this.goalstack29;
 733         this.goalstack29 = this.goalstack30;
 734         this.goalstack30 = this.goalstack31;
 735         this.goalstack31 = NULL;
 736 }
 737
 738 // walking to wp (walkfromwp == false) v2 and v2_height will be used as
 739 // waypoint destination coordinates instead of v (only useful for box waypoints)
 740 // for normal waypoints v2 == v and v2_height == 0
 741 float navigation_waypoint_will_link(vector v, vector org, entity ent, vector v2, float v2_height, vector o2, float o2_height, float walkfromwp, float bestdist)
 742 {
 743         if (vdist(v - org, <, bestdist))
 744         {
 745                 traceline(v, org, true, ent);
 746                 if (trace_fraction == 1)
 747                 {
 748                         if (walkfromwp)
 749                         {
 750                                 if (tracewalk(ent, v, PL_MIN_CONST, PL_MAX_CONST, v2, v2_height, bot_navigation_movemode))
 751                                         return true;
 752                         }
 753                         else
 754                         {
 755                                 if (tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, o2, o2_height, bot_navigation_movemode))
 756                                         return true;
 757                         }
 758                 }
 759         }
 760         return false;
 761 }
 762
 763 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 764 entity navigation_findnearestwaypoint_withdist_except(entity ent, float walkfromwp, float bestdist, entity except)
 765 {
 766         if(ent.tag_entity)
 767                 ent = ent.tag_entity;
 768
 769         vector pm1 = ent.origin + ent.mins;
 770         vector pm2 = ent.origin + ent.maxs;
 771
 772         // do two scans, because box test is cheaper
 773         IL_EACH(g_waypoints, it != ent && it != except,
 774         {
 775                 if(boxesoverlap(pm1, pm2, it.absmin, it.absmax))
 776                         return it;
 777         });
 778
 779         vector org = ent.origin;
 780         if (navigation_testtracewalk)
 781                 te_plasmaburn(org);
 782
 783         entity best = NULL;
 784         vector v = '0 0 0', v2 = '0 0 0';
 785         float v2_height = 0;
 786
 787         if(ent.size && !IS_PLAYER(ent))
 788         {
 789                 org += 0.5 * (ent.mins + ent.maxs);
 790                 org.z = ent.origin.z + ent.mins.z - PL_MIN_CONST.z; // player height
 791         }
 792
 793         if(!autocvar_g_waypointeditor && walkfromwp && !ent.navigation_dynamicgoal)
 794         {
 795                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 796                 IL_EACH(g_waypoints, it != ent,
 797                 {
 798                         if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 799                                 continue;
 800
 801                         SET_TRACEWALK_DESTCOORDS(it, org, v2, v2_height);
 802                         if(vdist(v2 - org, <, 1050))
 803                         if(tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, v2, v2_height, bot_navigation_movemode))
 804                                 navigation_item_addlink(it, ent);
 805                 });
 806         }
 807
 808         // box check failed, try walk
 809         IL_EACH(g_waypoints, it != ent,
 810         {
 811                 if(walkfromwp && (it.wpflags & WAYPOINTFLAG_NORELINK))
 812                         continue;
 813                 v = it.origin;
 814                 if(walkfromwp)
 815                         SET_TRACEWALK_DESTCOORDS(ent, v, v2, v2_height);
 816                 else
 817                         SET_TRACEWALK_DESTCOORDS(it, org, v2, v2_height);
 818                 if(navigation_waypoint_will_link(v, org, ent, v2, v2_height, v2, v2_height, walkfromwp, bestdist))
 819                 {
 820                         bestdist = vlen(v - org);
 821                         best = it;
 822                 }
 823         });
 824         return best;
 825 }
 826 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 827 {
 828         entity wp = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, NULL);
 829         if (autocvar_g_waypointeditor_auto)
 830         {
 831                 entity wp2 = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, wp);
 832                 if (wp && !wp2)
 833                         wp.wpflags |= WAYPOINTFLAG_PROTECTED;
 834         }
 835         return wp;
 836 }
 837
 838 // finds the waypoints near the bot initiating a navigation query
 839 float navigation_markroutes_nearestwaypoints(entity this, float maxdist)
 840 {
 841         vector v = '0 0 0';
 842         //navigation_testtracewalk = true;
 843         int c = 0;
 844         float v_height = 0;
 845         IL_EACH(g_waypoints, !it.wpconsidered,
 846         {
 847                 SET_TRACEWALK_DESTCOORDS(it, this.origin, v, v_height);
 848
 849                 vector diff = v - this.origin;
 850                 diff.z = max(0, diff.z);
 851                 if(vdist(diff, <, maxdist))
 852                 {
 853                         it.wpconsidered = true;
 854                         if (tracewalk(this, this.origin, this.mins, this.maxs, v, v_height, bot_navigation_movemode))
 855                         {
 856                                 it.wpnearestpoint = v;
 857                                 it.wpcost = waypoint_gettravelcost(this.origin, v, this, it) + it.dmg;
 858                                 it.wpfire = 1;
 859                                 it.enemy = NULL;
 860                                 c = c + 1;
 861                         }
 862                 }
 863         });
 864         //navigation_testtracewalk = false;
 865         return c;
 866 }
 867
 868 // updates a path link if a spawnfunc_waypoint link is better than the current one
 869 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost, vector p)
 870 {
 871         vector m1, m2;
 872         vector v;
 873         if (wp.wpisbox)
 874         {
 875                 m1 = wp.origin + wp.mins;
 876                 m2 = wp.origin + wp.maxs;
 877                 v.x = bound(m1_x, p.x, m2_x);
 878                 v.y = bound(m1_y, p.y, m2_y);
 879                 v.z = bound(m1_z, p.z, m2_z);
 880         }
 881         else
 882                 v = wp.origin;
 883         if (w.wpflags & WAYPOINTFLAG_TELEPORT)
 884                 cost += w.wp00mincost; // assuming teleport has exactly one destination
 885         else
 886                 cost += waypoint_gettravelcost(p, v, w, wp);
 887         if (wp.wpcost > cost)
 888         {
 889                 wp.wpcost = cost;
 890                 wp.enemy = w;
 891                 wp.wpfire = 1;
 892                 wp.wpnearestpoint = v;
 893         }
 894 }
 895
 896 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 897 void navigation_markroutes(entity this, entity fixed_source_waypoint)
 898 {
 899         float cost, cost2;
 900         vector p;
 901
 902         IL_EACH(g_waypoints, true,
 903         {
 904                 it.wpconsidered = false;
 905                 it.wpnearestpoint = '0 0 0';
 906                 it.wpcost = 10000000;
 907                 it.wpfire = 0;
 908                 it.enemy = NULL;
 909         });
 910
 911         if(fixed_source_waypoint)
 912         {
 913                 fixed_source_waypoint.wpconsidered = true;
 914                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 915                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 916                 fixed_source_waypoint.wpfire = 1;
 917                 fixed_source_waypoint.enemy = NULL;
 918         }
 919         else
 920         {
 921                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 922                 // as this search is expensive we will use lower values if the bot is on the air
 923                 float increment, maxdistance;
 924                 if(IS_ONGROUND(this))
 925                 {
 926                         increment = 750;
 927                         maxdistance = 50000;
 928                 }
 929                 else
 930                 {
 931                         increment = 500;
 932                         maxdistance = 1500;
 933                 }
 934
 935                 for(int j = increment; !navigation_markroutes_nearestwaypoints(this, j) && j < maxdistance; j += increment);
 936         }
 937
 938         bool searching = true;
 939         while (searching)
 940         {
 941                 searching = false;
 942                 IL_EACH(g_waypoints, it.wpfire,
 943                 {
 944                         searching = true;
 945                         it.wpfire = 0;
 946                         cost = it.wpcost;
 947                         p = it.wpnearestpoint;
 948                         entity wp;
 949                         wp = it.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp00mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 950                         wp = it.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp01mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 951                         wp = it.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp02mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 952                         wp = it.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp03mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 953                         wp = it.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp04mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 954                         wp = it.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp05mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 955                         wp = it.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp06mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 956                         wp = it.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp07mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 957                         wp = it.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp08mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 958                         wp = it.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp09mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 959                         wp = it.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp10mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 960                         wp = it.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp11mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 961                         wp = it.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp12mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 962                         wp = it.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp13mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 963                         wp = it.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp14mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 964                         wp = it.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp15mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 965                         wp = it.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp16mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 966                         wp = it.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp17mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 967                         wp = it.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp18mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 968                         wp = it.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp19mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 969                         wp = it.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp20mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 970                         wp = it.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp21mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 971                         wp = it.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp22mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 972                         wp = it.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp23mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 973                         wp = it.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp24mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 974                         wp = it.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp25mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 975                         wp = it.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp26mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 976                         wp = it.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp27mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 977                         wp = it.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp28mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 978                         wp = it.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp29mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 979                         wp = it.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp30mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 980                         wp = it.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp31mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 981                         }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 982                 });
 983         }
 984 }
 985
 986 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 987 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 988 {
 989         float cost, cost2;
 990         vector p;
 991         IL_EACH(g_waypoints, true,
 992         {
 993                 it.wpconsidered = false;
 994                 it.wpnearestpoint = '0 0 0';
 995                 it.wpcost = 10000000;
 996                 it.wpfire = 0;
 997                 it.enemy = NULL;
 998         });
 999
1000         if(fixed_source_waypoint)
1001         {
1002                 fixed_source_waypoint.wpconsidered = true;
1003                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
1004                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
1005                 fixed_source_waypoint.wpfire = 1;
1006                 fixed_source_waypoint.enemy = NULL;
1007         }
1008         else
1009         {
1010                 error("need to start with a waypoint\n");
1011         }
1012
1013         bool searching = true;
1014         while (searching)
1015         {
1016                 searching = false;
1017                 IL_EACH(g_waypoints, it.wpfire,
1018                 {
1019                         searching = true;
1020                         it.wpfire = 0;
1021                         cost = it.wpcost; // cost to walk from it to home
1022                         p = it.wpnearestpoint;
1023                         entity wp = it;
1024                         IL_EACH(g_waypoints, it != wp,
1025                         {
1026                                 if(!waypoint_islinked(it, wp))
1027                                         continue;
1028                                 cost2 = cost + it.dmg;
1029                                 navigation_markroutes_checkwaypoint(wp, it, cost2, p);
1030                         });
1031                 });
1032         }
1033 }
1034
1035 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
1036 void navigation_routerating(entity this, entity e, float f, float rangebias)
1037 {
1038         if (!e)
1039                 return;
1040
1041         if(e.blacklisted)
1042                 return;
1043
1044         rangebias = waypoint_getlinearcost(rangebias);
1045         f = waypoint_getlinearcost(f);
1046
1047         if (IS_PLAYER(e))
1048         {
1049                 bool rate_wps = false;
1050                 if((e.flags & FL_INWATER) || (e.flags & FL_PARTIALGROUND))
1051                         rate_wps = true;
1052
1053                 if(!IS_ONGROUND(e))
1054                 {
1055                         traceline(e.origin, e.origin + '0 0 -1500', true, NULL);
1056                         int t = pointcontents(trace_endpos + '0 0 1');
1057                         if(t != CONTENT_SOLID )
1058                         {
1059                                 if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
1060                                         rate_wps = true;
1061                                 else if(tracebox_hits_trigger_hurt(e.origin, e.mins, e.maxs, trace_endpos))
1062                                         return;
1063                         }
1064                 }
1065
1066                 if(rate_wps)
1067                 {
1068                         entity theEnemy = e;
1069                         entity best_wp = NULL;
1070                         float best_dist = 10000;
1071                         IL_EACH(g_waypoints, vdist(it.origin - theEnemy.origin, <, 500)
1072                                 && vdist(it.origin - this.origin, >, 100)
1073                                 && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1074                         {
1075                                 float dist = vlen(it.origin - theEnemy.origin);
1076                                 if (dist < best_dist)
1077                                 {
1078                                         best_wp = it;
1079                                         best_dist = dist;
1080                                 }
1081                         });
1082                         if (!best_wp)
1083                                 return;
1084                         e = best_wp;
1085                 }
1086         }
1087
1088         vector goal_org = (e.absmin + e.absmax) * 0.5;
1089
1090         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
1091
1092         // Evaluate path using jetpack
1093         if(g_jetpack)
1094         if(this.items & IT_JETPACK)
1095         if(autocvar_bot_ai_navigation_jetpack)
1096         if(vdist(this.origin - goal_org, >, autocvar_bot_ai_navigation_jetpack_mindistance))
1097         {
1098                 vector pointa, pointb;
1099
1100                 LOG_DEBUG("jetpack ai: evaluating path for ", e.classname);
1101
1102                 // Point A
1103                 traceline(this.origin, this.origin + '0 0 65535', MOVE_NORMAL, this);
1104                 pointa = trace_endpos - '0 0 1';
1105
1106                 // Point B
1107                 traceline(goal_org, goal_org + '0 0 65535', MOVE_NORMAL, e);
1108                 pointb = trace_endpos - '0 0 1';
1109
1110                 // Can I see these two points from the sky?
1111                 traceline(pointa, pointb, MOVE_NORMAL, this);
1112
1113                 if(trace_fraction==1)
1114                 {
1115                         LOG_DEBUG("jetpack ai: can bridge these two points");
1116
1117                         // Lower the altitude of these points as much as possible
1118                         float zdistance, xydistance, cost, t, fuel;
1119                         vector down, npa, npb;
1120
1121                         down = '0 0 -1' * (STAT(PL_MAX, this).z - STAT(PL_MIN, this).z) * 10;
1122
1123                         do{
1124                                 npa = pointa + down;
1125                                 npb = pointb + down;
1126
1127                                 if(npa.z<=this.absmax.z)
1128                                         break;
1129
1130                                 if(npb.z<=e.absmax.z)
1131                                         break;
1132
1133                                 traceline(npa, npb, MOVE_NORMAL, this);
1134                                 if(trace_fraction==1)
1135                                 {
1136                                         pointa = npa;
1137                                         pointb = npb;
1138                                 }
1139                         }
1140                         while(trace_fraction == 1);
1141
1142
1143                         // Rough estimation of fuel consumption
1144                         // (ignores acceleration and current xyz velocity)
1145                         xydistance = vlen(pointa - pointb);
1146                         zdistance = fabs(pointa.z - this.origin.z);
1147
1148                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
1149                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
1150                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
1151
1152                         LOG_DEBUG("jetpack ai: required fuel ", ftos(fuel), " this.ammo_fuel ", ftos(this.ammo_fuel));
1153
1154                         // enough fuel ?
1155                         if(this.ammo_fuel>fuel)
1156                         {
1157                                 // Estimate cost
1158                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
1159                                 //  - between air and ground speeds)
1160
1161                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
1162                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
1163                                 cost *= 1.5;
1164
1165                                 // Compare against other goals
1166                                 f = f * rangebias / (rangebias + cost);
1167
1168                                 if (navigation_bestrating < f)
1169                                 {
1170                                         LOG_DEBUG("jetpack path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1171                                         navigation_bestrating = f;
1172                                         navigation_bestgoal = e;
1173                                         this.navigation_jetpack_goal = e;
1174                                         this.navigation_jetpack_point = pointb;
1175                                 }
1176                                 return;
1177                         }
1178                 }
1179         }
1180
1181         entity nwp;
1182         //te_wizspike(e.origin);
1183         //bprint(etos(e));
1184         //bprint("\n");
1185         // update the cached spawnfunc_waypoint link on a dynamic item entity
1186         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1187         {
1188                 nwp = e;
1189         }
1190         else
1191         {
1192                 if(autocvar_g_waypointeditor && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1193                         e.nearestwaypoint = NULL;
1194
1195                 if ((!e.nearestwaypoint || e.navigation_dynamicgoal)
1196                         && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
1197                 {
1198                         nwp = navigation_findnearestwaypoint(e, true);
1199                         if(nwp)
1200                         {
1201                                 e.nearestwaypoint = nwp;
1202
1203                                 vector m1 = nwp.absmin, m2 = nwp.absmax;
1204                                 m1.x = nwp.origin.x; m1.y = nwp.origin.y;
1205                                 m2.x = nwp.origin.x; m2.y = nwp.origin.y;
1206                                 vector ve = (e.absmin - e.absmax) * 0.5;
1207                                 ve.x = bound(m1.x, ve.x, m2.x);
1208                                 ve.y = bound(m1.y, ve.y, m2.y);
1209                                 ve.z = bound(m1.z, ve.z, m2.z);
1210
1211                                 m1 = e.absmin; m2 = e.absmax;
1212                                 m1.x = e.origin.x; m1.y = e.origin.y;
1213                                 m2.x = e.origin.x; m2.y = e.origin.y;
1214                                 vector vnwp = nwp.origin;
1215                                 vnwp.x = bound(m1.x, vnwp.x, m2.x);
1216                                 vnwp.y = bound(m1.y, vnwp.y, m2.y);
1217                                 vnwp.z = bound(m1.z, vnwp.z, m2.z);
1218                                 e.nearestwaypoint_dist = vlen(ve - vnwp);
1219                         }
1220                         else
1221                         {
1222                                 LOG_DEBUG("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e));
1223
1224                                 if(!e.navigation_dynamicgoal)
1225                                         e.blacklisted = true;
1226
1227                                 if(e.blacklisted)
1228                                 {
1229                                         LOG_DEBUG("The entity '", e.classname, "' is going to be excluded from path finding during this match");
1230                                         return;
1231                                 }
1232                         }
1233
1234                         if(e.navigation_dynamicgoal)
1235                                 e.nearestwaypointtimeout = time + 2;
1236                         else if(autocvar_g_waypointeditor)
1237                                 e.nearestwaypointtimeout = time + 3 + random() * 2;
1238                 }
1239                 nwp = e.nearestwaypoint;
1240         }
1241
1242         LOG_DEBUG("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")");
1243         if (nwp)
1244         if (nwp.wpcost < 10000000)
1245         {
1246                 //te_wizspike(nwp.wpnearestpoint);
1247                 float cost = nwp.wpcost + waypoint_gettravelcost(nwp.wpnearestpoint, goal_org, nwp, e);
1248                 LOG_DEBUG(e.classname, " ", ftos(f), "/(1+", ftos(cost), "/", ftos(rangebias), ") = ");
1249                 f = f * rangebias / (rangebias + cost);
1250                 LOG_DEBUG("considering ", e.classname, " (with rating ", ftos(f), ")");
1251                 if (navigation_bestrating < f)
1252                 {
1253                         LOG_DEBUG("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")");
1254                         navigation_bestrating = f;
1255                         navigation_bestgoal = e;
1256                 }
1257         }
1258 }
1259
1260 // adds an item to the the goal stack with the path to a given item
1261 bool navigation_routetogoal(entity this, entity e, vector startposition)
1262 {
1263         // if there is no goal, just exit
1264         if (!e)
1265                 return false;
1266
1267         entity teleport_goal = NULL;
1268
1269         this.goalentity = e;
1270
1271         if(e.wpflags & WAYPOINTFLAG_TELEPORT)
1272         {
1273                 // force teleport destination as route destination
1274                 teleport_goal = e;
1275                 navigation_pushroute(this, e.wp00);
1276                 this.goalentity = e.wp00;
1277         }
1278
1279         // put the entity on the goal stack
1280         //print("routetogoal ", etos(e), "\n");
1281         navigation_pushroute(this, e);
1282
1283         if(teleport_goal)
1284                 e = this.goalentity;
1285
1286         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
1287         {
1288                 this.wp_goal_prev1 = this.wp_goal_prev0;
1289                 this.wp_goal_prev0 = e;
1290         }
1291
1292         if(g_jetpack)
1293         if(e==this.navigation_jetpack_goal)
1294                 return true;
1295
1296         // if it can reach the goal there is nothing more to do
1297         vector dest = '0 0 0';
1298         float dest_height = 0;
1299         SET_TRACEWALK_DESTCOORDS(e, startposition, dest, dest_height);
1300         if (tracewalk(this, startposition, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1301                 return true;
1302
1303         entity nearest_wp = NULL;
1304         // see if there are waypoints describing a path to the item
1305         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
1306         {
1307                 e = e.nearestwaypoint;
1308                 nearest_wp = e;
1309         }
1310         else if(teleport_goal)
1311                 e = teleport_goal;
1312         else
1313                 e = e.enemy; // we already have added it, so...
1314
1315         if(e == NULL)
1316                 return false;
1317
1318         if(nearest_wp && nearest_wp.enemy)
1319         {
1320                 // often path can be optimized by not adding the nearest waypoint
1321                 if (this.goalentity.nearestwaypoint_dist < 8)
1322                         e = nearest_wp.enemy;
1323                 else
1324                 {
1325                         if (this.goalentity.navigation_dynamicgoal || autocvar_g_waypointeditor)
1326                         {
1327                                 SET_TRACEWALK_DESTCOORDS(e, nearest_wp.enemy.origin, dest, dest_height);
1328                                 if(vdist(dest - nearest_wp.enemy.origin, <, 1050))
1329                                 if(tracewalk(this, nearest_wp.enemy.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1330                                         e = nearest_wp.enemy;
1331                         }
1332                         else if(navigation_item_islinked(nearest_wp.enemy, this.goalentity))
1333                                 e = nearest_wp.enemy;
1334                 }
1335         }
1336
1337         for (;;)
1338         {
1339                 // add the spawnfunc_waypoint to the path
1340                 navigation_pushroute(this, e);
1341                 e = e.enemy;
1342
1343                 if(e==NULL)
1344                         break;
1345         }
1346
1347         return false;
1348 }
1349
1350 // removes any currently touching waypoints from the goal stack
1351 // (this is how bots detect if they reached a goal)
1352 int navigation_poptouchedgoals(entity this)
1353 {
1354         int removed_goals = 0;
1355         if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1356         {
1357                 // make sure jumppad is really hit, don't rely on distance based checks
1358                 // as they may report a touch even if it didn't really happen
1359                 if(this.lastteleporttime > 0
1360                         && time - this.lastteleporttime < ((this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL) ? 2 : 0.15))
1361                 {
1362                         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1363                         if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1364                         {
1365                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1366                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1367                         }
1368                         navigation_poproute(this);
1369                         ++removed_goals;
1370                 }
1371                 else
1372                         return removed_goals;
1373         }
1374
1375         // If for some reason the bot is closer to the next goal, pop the current one
1376         if(this.goalstack01 && !wasfreed(this.goalstack01))
1377         if(vlen2(this.goalcurrent.origin - this.origin) > vlen2(this.goalstack01.origin - this.origin))
1378         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
1379         {
1380                 vector dest = '0 0 0';
1381                 float dest_height = 0;
1382                 SET_TRACEWALK_DESTCOORDS(this.goalstack01, this.origin, dest, dest_height);
1383                 if(tracewalk(this, this.origin, this.mins, this.maxs, dest, dest_height, bot_navigation_movemode))
1384                 {
1385                         LOG_DEBUG("path optimized for ", this.netname, ", removed a goal from the queue");
1386                         navigation_poproute(this);
1387                         ++removed_goals;
1388                         if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1389                                 return removed_goals;
1390                         // TODO this may also be a nice idea to do "early" (e.g. by
1391                         // manipulating the vlen() comparisons) to shorten paths in
1392                         // general - this would make bots walk more "on rails" than
1393                         // "zigzagging" which they currently do with sufficiently
1394                         // random-like waypoints, and thus can make a nice bot
1395                         // personality property
1396                 }
1397         }
1398
1399         // Loose goal touching check when running
1400         if(this.aistatus & AI_STATUS_RUNNING)
1401         if(this.goalcurrent.classname=="waypoint")
1402         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
1403         {
1404                 if(vdist(this.origin - this.goalcurrent.origin, <, 150))
1405                 {
1406                         traceline(this.origin + this.view_ofs , this.goalcurrent.origin, true, NULL);
1407                         if(trace_fraction==1)
1408                         {
1409                                 // Detect personal waypoints
1410                                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1411                                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1412                                 {
1413                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1414                                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1415                                 }
1416
1417                                 navigation_poproute(this);
1418                                 ++removed_goals;
1419                                 if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1420                                         return removed_goals;
1421                         }
1422                 }
1423         }
1424
1425         while (this.goalcurrent && !IS_PLAYER(this.goalcurrent))
1426         {
1427                 vector gc_min = this.goalcurrent.absmin;
1428                 vector gc_max = this.goalcurrent.absmax;
1429                 if(this.goalcurrent.classname == "waypoint" && !this.goalcurrent.wpisbox)
1430                 {
1431                         gc_min = this.goalcurrent.origin - '1 1 1' * 12;
1432                         gc_max = this.goalcurrent.origin + '1 1 1' * 12;
1433                 }
1434                 if(!boxesoverlap(this.absmin, this.absmax, gc_min, gc_max))
1435                         break;
1436
1437                 // Detect personal waypoints
1438                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1439                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1440                 {
1441                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1442                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1443                 }
1444
1445                 navigation_poproute(this);
1446                 ++removed_goals;
1447                 if(this.goalcurrent && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
1448                         return removed_goals;
1449         }
1450         return removed_goals;
1451 }
1452
1453 entity navigation_get_really_close_waypoint(entity this)
1454 {
1455         entity wp = this.goalcurrent;
1456         if(!wp || vdist(wp.origin - this.origin, >, 50))
1457                 wp = this.goalcurrent_prev;
1458         if(!wp)
1459                 return NULL;
1460         if(wp.classname != "waypoint")
1461         {
1462                 wp = wp.nearestwaypoint;
1463                 if(!wp)
1464                         return NULL;
1465         }
1466         if(vdist(wp.origin - this.origin, >, 50))
1467         {
1468                 IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
1469                 {
1470                         if(vdist(it.origin - this.origin, <, 50))
1471                         {
1472                                 wp = it;
1473                                 break;
1474                         }
1475                 });
1476         }
1477         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1478                 return NULL;
1479
1480         vector dest = '0 0 0';
1481         float dest_height = 0;
1482         SET_TRACEWALK_DESTCOORDS(wp, this.origin, dest, dest_height);
1483         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1484                 return NULL;
1485         return wp;
1486 }
1487
1488 // begin a goal selection session (queries spawnfunc_waypoint network)
1489 void navigation_goalrating_start(entity this)
1490 {
1491         if(this.aistatus & AI_STATUS_STUCK)
1492                 return;
1493
1494         this.navigation_jetpack_goal = NULL;
1495         navigation_bestrating = -1;
1496         entity wp = navigation_get_really_close_waypoint(this);
1497         navigation_clearroute(this);
1498         navigation_bestgoal = NULL;
1499         navigation_markroutes(this, wp);
1500 }
1501
1502 // ends a goal selection session (updates goal stack to the best goal)
1503 void navigation_goalrating_end(entity this)
1504 {
1505         if(this.aistatus & AI_STATUS_STUCK)
1506                 return;
1507
1508         navigation_routetogoal(this, navigation_bestgoal, this.origin);
1509         LOG_DEBUG("best goal ", this.goalcurrent.classname);
1510
1511         // If the bot got stuck then try to reach the farthest waypoint
1512         if (!this.goalentity && autocvar_bot_wander_enable)
1513         {
1514                 if (!(this.aistatus & AI_STATUS_STUCK))
1515                 {
1516                         LOG_DEBUG(this.netname, " cannot walk to any goal");
1517                         this.aistatus |= AI_STATUS_STUCK;
1518                 }
1519         }
1520 }
1521
1522 void botframe_updatedangerousobjects(float maxupdate)
1523 {
1524         vector m1, m2, v, o;
1525         float c, d, danger;
1526         c = 0;
1527         entity wp_cur;
1528         IL_EACH(g_waypoints, true,
1529         {
1530                 danger = 0;
1531                 m1 = it.absmin;
1532                 m2 = it.absmax;
1533                 wp_cur = it;
1534                 IL_EACH(g_bot_dodge, it.bot_dodge,
1535                 {
1536                         v = it.origin;
1537                         v.x = bound(m1_x, v.x, m2_x);
1538                         v.y = bound(m1_y, v.y, m2_y);
1539                         v.z = bound(m1_z, v.z, m2_z);
1540                         o = (it.absmin + it.absmax) * 0.5;
1541                         d = waypoint_getlinearcost(it.bot_dodgerating) - waypoint_gettravelcost(o, v, it, wp_cur);
1542                         if (d > 0)
1543                         {
1544                                 traceline(o, v, true, NULL);
1545                                 if (trace_fraction == 1)
1546                                         danger = danger + d;
1547                         }
1548                 });
1549                 it.dmg = danger;
1550                 c = c + 1;
1551                 if (c >= maxupdate)
1552                         break;
1553         });
1554 }
1555
1556 void navigation_unstuck(entity this)
1557 {
1558         float search_radius = 1000;
1559
1560         if (!autocvar_bot_wander_enable)
1561                 return;
1562
1563         if (!bot_waypoint_queue_owner)
1564         {
1565                 LOG_DEBUG(this.netname, " stuck, taking over the waypoints queue");
1566                 bot_waypoint_queue_owner = this;
1567                 bot_waypoint_queue_bestgoal = NULL;
1568                 bot_waypoint_queue_bestgoalrating = 0;
1569         }
1570
1571         if(bot_waypoint_queue_owner!=this)
1572                 return;
1573
1574         if (bot_waypoint_queue_goal)
1575         {
1576                 // evaluate the next goal on the queue
1577                 float d = vlen2(this.origin - bot_waypoint_queue_goal.origin);
1578                 LOG_DEBUG(this.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d));
1579                 vector dest = '0 0 0';
1580                 float dest_height = 0;
1581                 SET_TRACEWALK_DESTCOORDS(bot_waypoint_queue_goal, this.origin, dest, dest_height);
1582                 if(tracewalk(bot_waypoint_queue_goal, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), dest, dest_height, bot_navigation_movemode))
1583                 {
1584                         if( d > bot_waypoint_queue_bestgoalrating)
1585                         {
1586                                 bot_waypoint_queue_bestgoalrating = d;
1587                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1588                         }
1589                 }
1590                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1591
1592                 if (!bot_waypoint_queue_goal)
1593                 {
1594                         if (bot_waypoint_queue_bestgoal)
1595                         {
1596                                 LOG_DEBUG(this.netname, " stuck, reachable waypoint found, heading to it");
1597                                 navigation_routetogoal(this, bot_waypoint_queue_bestgoal, this.origin);
1598                                 navigation_goalrating_timeout_set(this);
1599                                 this.aistatus &= ~AI_STATUS_STUCK;
1600                         }
1601                         else
1602                         {
1603                                 LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1604                         }
1605
1606                         bot_waypoint_queue_owner = NULL;
1607                 }
1608         }
1609         else
1610         {
1611                 if(bot_strategytoken!=this)
1612                         return;
1613
1614                 // build a new queue
1615                 LOG_DEBUG(this.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu");
1616
1617                 entity first = NULL;
1618
1619                 FOREACH_ENTITY_RADIUS(this.origin, search_radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
1620                 {
1621                         if(bot_waypoint_queue_goal)
1622                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = it;
1623                         else
1624                                 first = it;
1625
1626                         bot_waypoint_queue_goal = it;
1627                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = NULL;
1628                 });
1629
1630                 if (first)
1631                         bot_waypoint_queue_goal = first;
1632                 else
1633                 {
1634                         LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1635                         bot_waypoint_queue_owner = NULL;
1636                 }
1637         }
1638 }
1639
1640 // Support for debugging tracewalk visually
1641
1642 void debugresetnodes()
1643 {
1644         debuglastnode = '0 0 0';
1645 }
1646
1647 void debugnode(entity this, vector node)
1648 {
1649         if (!IS_PLAYER(this))
1650                 return;
1651
1652         if(debuglastnode=='0 0 0')
1653         {
1654                 debuglastnode = node;
1655                 return;
1656         }
1657
1658         te_lightning2(NULL, node, debuglastnode);
1659         debuglastnode = node;
1660 }
1661
1662 void debugnodestatus(vector position, float status)
1663 {
1664         vector c;
1665
1666         switch (status)
1667         {
1668                 case DEBUG_NODE_SUCCESS:
1669                         c = '0 15 0';
1670                         break;
1671                 case DEBUG_NODE_WARNING:
1672                         c = '15 15 0';
1673                         break;
1674                 case DEBUG_NODE_FAIL:
1675                         c = '15 0 0';
1676                         break;
1677                 default:
1678                         c = '15 15 15';
1679         }
1680
1681         te_customflash(position, 40,  2, c);
1682 }
1683
1684 // Support for debugging the goal stack visually
1685
1686 .float goalcounter;
1687 .vector lastposition;
1688
1689 // Debug the goal stack visually
1690 void debuggoalstack(entity this)
1691 {
1692         entity goal;
1693         vector org, go;
1694
1695         if(this.goalcounter==0)goal=this.goalcurrent;
1696         else if(this.goalcounter==1)goal=this.goalstack01;
1697         else if(this.goalcounter==2)goal=this.goalstack02;
1698         else if(this.goalcounter==3)goal=this.goalstack03;
1699         else if(this.goalcounter==4)goal=this.goalstack04;
1700         else if(this.goalcounter==5)goal=this.goalstack05;
1701         else if(this.goalcounter==6)goal=this.goalstack06;
1702         else if(this.goalcounter==7)goal=this.goalstack07;
1703         else if(this.goalcounter==8)goal=this.goalstack08;
1704         else if(this.goalcounter==9)goal=this.goalstack09;
1705         else if(this.goalcounter==10)goal=this.goalstack10;
1706         else if(this.goalcounter==11)goal=this.goalstack11;
1707         else if(this.goalcounter==12)goal=this.goalstack12;
1708         else if(this.goalcounter==13)goal=this.goalstack13;
1709         else if(this.goalcounter==14)goal=this.goalstack14;
1710         else if(this.goalcounter==15)goal=this.goalstack15;
1711         else if(this.goalcounter==16)goal=this.goalstack16;
1712         else if(this.goalcounter==17)goal=this.goalstack17;
1713         else if(this.goalcounter==18)goal=this.goalstack18;
1714         else if(this.goalcounter==19)goal=this.goalstack19;
1715         else if(this.goalcounter==20)goal=this.goalstack20;
1716         else if(this.goalcounter==21)goal=this.goalstack21;
1717         else if(this.goalcounter==22)goal=this.goalstack22;
1718         else if(this.goalcounter==23)goal=this.goalstack23;
1719         else if(this.goalcounter==24)goal=this.goalstack24;
1720         else if(this.goalcounter==25)goal=this.goalstack25;
1721         else if(this.goalcounter==26)goal=this.goalstack26;
1722         else if(this.goalcounter==27)goal=this.goalstack27;
1723         else if(this.goalcounter==28)goal=this.goalstack28;
1724         else if(this.goalcounter==29)goal=this.goalstack29;
1725         else if(this.goalcounter==30)goal=this.goalstack30;
1726         else if(this.goalcounter==31)goal=this.goalstack31;
1727         else goal=NULL;
1728
1729         if(goal==NULL)
1730         {
1731                 this.goalcounter = 0;
1732                 this.lastposition='0 0 0';
1733                 return;
1734         }
1735
1736         if(this.lastposition=='0 0 0')
1737                 org = this.origin;
1738         else
1739                 org = this.lastposition;
1740
1741
1742         go = ( goal.absmin + goal.absmax ) * 0.5;
1743         te_lightning2(NULL, org, go);
1744         this.lastposition = go;
1745
1746         this.goalcounter++;
1747 }