84cca9fe2cd7716b540370a88f57ec4f67050971
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / waypoints.qc
1 #include "waypoints.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include "cvars.qh"
6
7 #include "bot.qh"
8 #include "navigation.qh"
9
10 #include <common/state.qh>
11
12 #include "../../antilag.qh"
13
14 #include <common/constants.qh>
15 #include <common/net_linked.qh>
16 #include <common/physics/player.qh>
17
18 #include <lib/warpzone/common.qh>
19 #include <lib/warpzone/util_server.qh>
20
21 .entity spawnpointmodel;
22 void waypoint_unreachable(entity pl)
23 {
24         IL_EACH(g_waypoints, true,
25         {
26                 it.colormod = '0.5 0.5 0.5';
27                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
28         });
29
30         entity e2 = navigation_findnearestwaypoint(pl, false);
31         if(!e2)
32         {
33                 LOG_INFOF("Can't find any waypoint nearby\n");
34                 return;
35         }
36
37         navigation_markroutes(pl, e2);
38
39         int j = 0;
40         int m = 0;
41         IL_EACH(g_waypoints, it.wpcost >= 10000000,
42         {
43                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
44                 it.colormod_z = 8;
45                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
46                 j++;
47                 m++;
48         });
49         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
50         navigation_markroutes_inverted(e2);
51
52         j = 0;
53         IL_EACH(g_waypoints, it.wpcost >= 10000000,
54         {
55                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
56                 it.colormod_x = 8;
57                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
58                         m++;
59                 it.effects |= EF_NODEPTHTEST | EF_RED;
60                 j++;
61         });
62         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
63         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
64
65         j = 0;
66         IL_EACH(g_spawnpoints, true,
67         {
68                 if (navigation_findnearestwaypoint(it, false))
69                 {
70                         if(it.spawnpointmodel)
71                         {
72                                 delete(it.spawnpointmodel);
73                                 it.spawnpointmodel = NULL;
74                         }
75                 }
76                 else
77                 {
78                         if(!it.spawnpointmodel)
79                         {
80                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
81                                 entity e = new(spawnpointmodel);
82                                 vector org = trace_endpos + eZ;
83                                 setorigin(e, org);
84                                 e.solid = SOLID_TRIGGER;
85                                 it.spawnpointmodel = e;
86                         }
87                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
88                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
89                         _setmodel(it.spawnpointmodel, pl.model);
90                         it.spawnpointmodel.frame = pl.frame;
91                         it.spawnpointmodel.skin = pl.skin;
92                         it.spawnpointmodel.colormap = pl.colormap;
93                         it.spawnpointmodel.colormod = pl.colormod;
94                         it.spawnpointmodel.glowmod = pl.glowmod;
95                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
96                         j++;
97                 }
98         });
99         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
100
101         j = 0;
102         IL_EACH(g_items, true,
103         {
104                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
105                 it.colormod = '0.5 0.5 0.5';
106         });
107         IL_EACH(g_items, true,
108         {
109                 if (navigation_findnearestwaypoint(it, false))
110                         continue;
111                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
112                 it.effects |= EF_NODEPTHTEST | EF_RED;
113                 it.colormod_x = 8;
114                 j++;
115         });
116         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
117
118         j = 0;
119         IL_EACH(g_items, true,
120         {
121                 if (navigation_findnearestwaypoint(it, true))
122                         continue;
123                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
124                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
125                 it.colormod_z = 8;
126                 j++;
127         });
128         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
129 }
130
131 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
132 {
133         vector v1 = stov(argv(arg_idx++));
134         vector v2 = stov(argv(arg_idx++));
135         vector mid = (v1 + v2) / 2;
136
137         float diffy = (v2.y - v1.y);
138         float diffx = (v2.x - v1.x);
139         if (v1.y == v2.y)
140                 diffy = 0.000001;
141         if (v1.x == v2.x)
142                 diffx = 0.000001;
143         float m = - diffx / diffy;
144         float q = - m * mid.x + mid.y;
145         if (fabs(m) <= 0.000001) m = 0;
146         if (fabs(q) <= 0.000001) q = 0;
147
148         string axis_str =  strcat(ftos(m), " ", ftos(q));
149         if (save)
150                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
151         axis_str = strcat("\"", axis_str, "\"");
152         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
153         if (save)
154                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
155         if (save)
156         {
157                 cvar_set("g_waypointeditor_symmetrical", "-2");
158                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
159                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
160         }
161 }
162
163 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
164 {
165         vector org = '0 0 0';
166         int ctf_flags = 0;
167         for (int i = 0; i < 6; i++)
168         {
169                 if (argv(arg_idx + i) != "")
170                         ctf_flags++;
171         }
172         if (ctf_flags < 2)
173         {
174                 ctf_flags = 0;
175                 org = vec2(havocbot_middlepoint);
176                 if (argv(arg_idx) != "")
177                         sprint(caller, "WARNING: Ignoring single input point\n");
178                 if (havocbot_middlepoint_radius == 0)
179                 {
180                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
181                         return;
182                 }
183         }
184         else
185         {
186                 vector v1, v2, v3, v4, v5, v6;
187                 for (int i = 1; i <= ctf_flags; i++)
188                 {
189                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
190                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
191                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
192                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
193                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
194                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
195                 }
196         }
197
198         if (fabs(org.x) <= 0.000001) org.x = 0;
199         if (fabs(org.y) <= 0.000001) org.y = 0;
200         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
201         if (save)
202         {
203                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
204                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
205         }
206         org_str = strcat("\"", org_str, "\"");
207
208         if (ctf_flags < 2)
209                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
210         else
211                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
212         if (save)
213                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
214
215         if (ctf_flags < 2)
216                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
217         else
218                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
219         if (save)
220                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
221
222         if (save)
223         {
224                 if (ctf_flags < 2)
225                         cvar_set("g_waypointeditor_symmetrical", "0");
226                 else
227                         cvar_set("g_waypointeditor_symmetrical", "-1");
228                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
229                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
230         }
231 }
232
233 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
234 {
235         vector new_org = org;
236         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
237         {
238                 vector map_center = havocbot_middlepoint;
239                 if (autocvar_g_waypointeditor_symmetrical == -1)
240                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
241
242                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
243         }
244         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
245         {
246                 float m = havocbot_symmetry_axis_m;
247                 float q = havocbot_symmetry_axis_q;
248                 if (autocvar_g_waypointeditor_symmetrical == -2)
249                 {
250                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
251                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
252                 }
253
254                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
255                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
256         }
257         new_org.z = org.z;
258         return new_org;
259 }
260
261 void waypoint_setupmodel(entity wp)
262 {
263         if (autocvar_g_waypointeditor)
264         {
265                 // TODO: add some sort of visible box in edit mode for box waypoints
266                 vector m1 = wp.mins;
267                 vector m2 = wp.maxs;
268                 setmodel(wp, MDL_WAYPOINT);
269                 setsize(wp, m1, m2);
270                 wp.effects = EF_LOWPRECISION;
271                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
272                         wp.colormod = '1 0 0';
273                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
274                         wp.colormod = '1 1 0';
275                 else if (wp.wphardwired)
276                         wp.colormod = '0.5 0 1';
277                 else
278                         wp.colormod = '1 1 1';
279         }
280         else
281                 wp.model = "";
282 }
283
284 entity waypoint_spawn(vector m1, vector m2, float f)
285 {
286         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
287         {
288                 vector em1 = m1 - '8 8 8';
289                 vector em2 = m2 + '8 8 8';
290                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
291                 {
292                         return it;
293                 });
294         }
295         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
296         // otherwise links loaded from file would be applied only to the first destination
297         // waypoint since link format doesn't specify waypoint entities but just positions
298         if((f & WAYPOINTFLAG_GENERATED) && !(f & WAYPOINTFLAG_NORELINK) && m1 == m2)
299         {
300                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
301                 {
302                         return it;
303                 });
304         }
305
306         entity w = new(waypoint);
307         IL_PUSH(g_waypoints, w);
308         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
309         w.wpflags = f;
310         w.solid = SOLID_TRIGGER;
311         setorigin(w, (m1 + m2) * 0.5);
312         setsize(w, m1 - w.origin, m2 - w.origin);
313         if (w.size)
314                 w.wpisbox = true;
315
316         if(!w.wpisbox)
317         {
318                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
319                 if(!move_out_of_solid(w))
320                 {
321                         if(!(f & WAYPOINTFLAG_GENERATED))
322                         {
323                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
324                                 delete(w);
325                                 return NULL;
326                         }
327                         else
328                         {
329                                 if(autocvar_developer)
330                                 {
331                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
332                                         backtrace("Waypoint stuck");
333                                 }
334                         }
335                 }
336                 setsize(w, '0 0 0', '0 0 0');
337         }
338
339         waypoint_clearlinks(w);
340         //waypoint_schedulerelink(w);
341
342         waypoint_setupmodel(w);
343
344         return w;
345 }
346
347 void waypoint_spawn_fromeditor(entity pl)
348 {
349         entity e;
350         vector org = pl.origin;
351         int ctf_flags = havocbot_symmetry_origin_order;
352         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
353                    || (autocvar_g_waypointeditor_symmetrical < 0));
354         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
355                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
356         if (sym && ctf_flags < 2)
357                 ctf_flags = 2;
358         int wp_num = ctf_flags;
359
360         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
361         {
362                 // snap waypoint to item's origin if close enough
363                 IL_EACH(g_items, true,
364                 {
365                         vector item_org = (it.absmin + it.absmax) * 0.5;
366                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
367                         if (vlen(item_org - org) < 20)
368                         {
369                                 org = item_org;
370                                 break;
371                         }
372                 });
373         }
374
375         LABEL(add_wp);
376         e = waypoint_spawn(org, org, 0);
377         if(!e)
378         {
379                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
380                 return;
381         }
382         waypoint_schedulerelink(e);
383         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
384         if(sym)
385         {
386                 org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
387                 if (vdist(org - pl.origin, >, 32))
388                 {
389                         if(wp_num > 2)
390                                 wp_num--;
391                         else
392                                 sym = false;
393                         goto add_wp;
394                 }
395         }
396 }
397
398 void waypoint_remove(entity wp)
399 {
400         IL_EACH(g_waypoints, it != wp,
401         {
402                 if (waypoint_islinked(it, wp))
403                         waypoint_removelink(it, wp);
404         });
405         delete(wp);
406 }
407
408 void waypoint_remove_fromeditor(entity pl)
409 {
410         entity e = navigation_findnearestwaypoint(pl, false);
411
412         int ctf_flags = havocbot_symmetry_origin_order;
413         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
414                    || (autocvar_g_waypointeditor_symmetrical < 0));
415         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
416                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
417         if (sym && ctf_flags < 2)
418                 ctf_flags = 2;
419         int wp_num = ctf_flags;
420
421         LABEL(remove_wp);
422         if (!e) return;
423         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
424
425         if (e.wphardwired)
426         {
427                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
428                 return;
429         }
430
431         entity wp_sym = NULL;
432         if (sym)
433         {
434                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
435                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
436                         if(vdist(org - it.origin, <, 3))
437                         {
438                                 wp_sym = it;
439                                 break;
440                         }
441                 });
442         }
443
444         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
445         waypoint_remove(e);
446
447         if (sym && wp_sym)
448         {
449                 e = wp_sym;
450                 if(wp_num > 2)
451                         wp_num--;
452                 else
453                         sym = false;
454                 goto remove_wp;
455         }
456 }
457
458 void waypoint_removelink(entity from, entity to)
459 {
460         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
461                 return;
462
463         entity fromwp31_prev = from.wp31;
464
465         switch (waypoint_getlinknum(from, to))
466         {
467                 // fallthrough all the way
468                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
469                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
470                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
471                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
472                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
473                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
474                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
475                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
476                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
477                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
478                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
479                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
480                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
481                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
482                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
483                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
484                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
485                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
486                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
487                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
488                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
489                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
490                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
491                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
492                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
493                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
494                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
495                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
496                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
497                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
498                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
499                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
500         }
501
502         if (fromwp31_prev && !from.wp31)
503                 waypoint_schedulerelink(from);
504 }
505
506 int waypoint_getlinknum(entity from, entity to)
507 {
508         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
509         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
510         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
511         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
512         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
513         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
514         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
515         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
516         return -1;
517 }
518
519 bool waypoint_islinked(entity from, entity to)
520 {
521         return (waypoint_getlinknum(from, to) >= 0);
522 }
523
524 void waypoint_updatecost_foralllinks()
525 {
526         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
527         {
528                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
529                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
530                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
531                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
532                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
533                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
534                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
535                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
536                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
537                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
538                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
539                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
540                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
541                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
542                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
543                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
544                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
545                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
546                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
547                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
548                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
549                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
550                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
551                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
552                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
553                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
554                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
555                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
556                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
557                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
558                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
559                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
560         });
561 }
562
563 float waypoint_getlinearcost(float dist)
564 {
565         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
566                 return dist / (autocvar_sv_maxspeed * 1.25);
567         return dist / autocvar_sv_maxspeed;
568 }
569 float waypoint_getlinearcost_underwater(float dist)
570 {
571         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
572         return dist / (autocvar_sv_maxspeed * 0.7);
573 }
574
575 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
576 {
577         bool submerged_from = navigation_check_submerged_state(from_ent, from);
578         bool submerged_to = navigation_check_submerged_state(to_ent, to);
579
580         if (submerged_from && submerged_to)
581                 return waypoint_getlinearcost_underwater(vlen(to - from));
582
583         float c = waypoint_getlinearcost(vlen(to - from));
584
585         float height = from.z - to.z;
586         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
587         {
588                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
589                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
590                 if(height_cost > c)
591                         c = height_cost;
592         }
593
594         if (submerged_from || submerged_to)
595                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
596         return c;
597 }
598
599 float waypoint_getlinkcost(entity from, entity to)
600 {
601         vector v1 = from.origin;
602         vector v2 = to.origin;
603         if (from.wpisbox)
604         {
605                 vector m1 = from.absmin, m2 = from.absmax;
606                 v1.x = bound(m1.x, v2.x, m2.x);
607                 v1.y = bound(m1.y, v2.y, m2.y);
608                 v1.z = bound(m1.z, v2.z, m2.z);
609         }
610         if (to.wpisbox)
611         {
612                 vector m1 = to.absmin, m2 = to.absmax;
613                 v2.x = bound(m1.x, v1.x, m2.x);
614                 v2.y = bound(m1.y, v1.y, m2.y);
615                 v2.z = bound(m1.z, v1.z, m2.z);
616         }
617         return waypoint_gettravelcost(v1, v2, from, to);
618 }
619
620 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
621 // if c == -1 automatically determine cost of the link
622 void waypoint_addlink_customcost(entity from, entity to, float c)
623 {
624         if (from == to || waypoint_islinked(from, to))
625                 return;
626         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
627                 return;
628
629         if(c == -1)
630                 c = waypoint_getlinkcost(from, to);
631
632         if (from.wp31mincost < c) return;
633         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
634         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
635         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
636         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
637         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
638         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
639         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
640         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
641         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
642         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
643         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
644         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
645         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
646         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
647         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
648         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
649         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
650         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
651         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
652         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
653         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
654         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
655         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
656         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
657         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
658         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
659         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
660         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
661         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
662         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
663         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
664         from.wp00 = to;from.wp00mincost = c;return;
665 }
666
667 void waypoint_addlink(entity from, entity to)
668 {
669         waypoint_addlink_customcost(from, to, -1);
670 }
671
672 // relink this spawnfunc_waypoint
673 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
674 // (SLOW!)
675 void waypoint_think(entity this)
676 {
677         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
678         float sv2_height = 0, ev2_height = 0;
679
680         bot_calculate_stepheightvec();
681
682         int dphitcontentsmask_save = this.dphitcontentsmask;
683         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
684
685         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
686
687         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
688         IL_EACH(g_waypoints, this != it,
689         {
690                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
691                 {
692                         waypoint_addlink(this, it);
693                         waypoint_addlink(it, this);
694                 }
695                 else
696                 {
697                         ++relink_total;
698                         if(!checkpvs(this.origin, it))
699                         {
700                                 ++relink_pvsculled;
701                                 continue;
702                         }
703
704                         sv = set_tracewalk_dest_2(this, it.origin);
705                         sv2 = tracewalk_dest;
706                         sv2_height = tracewalk_dest_height;
707                         ev = set_tracewalk_dest_2(it, this.origin);
708                         ev2 = tracewalk_dest;
709                         ev2_height = tracewalk_dest_height;
710
711                         dv = ev - sv;
712                         dv.z = 0;
713                         if(vdist(dv, >=, 1050)) // max search distance in XY
714                         {
715                                 ++relink_lengthculled;
716                                 continue;
717                         }
718
719                         navigation_testtracewalk = 0;
720
721                         //traceline(this.origin, it.origin, false, NULL);
722                         //if (trace_fraction == 1)
723                         if (this.wpisbox)
724                                 relink_walkculled += 0.5;
725                         else
726                         {
727                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
728                                         waypoint_addlink(this, it);
729                                 else
730                                         relink_walkculled += 0.5;
731                         }
732
733                         if (it.wpisbox)
734                                 relink_walkculled += 0.5;
735                         else
736                         {
737                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
738                                         waypoint_addlink(it, this);
739                                 else
740                                         relink_walkculled += 0.5;
741                         }
742                 }
743         });
744         navigation_testtracewalk = 0;
745         this.wplinked = true;
746         this.dphitcontentsmask = dphitcontentsmask_save;
747 }
748
749 void waypoint_clearlinks(entity wp)
750 {
751         // clear links to other waypoints
752         float f = 10000000;
753         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
754         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
755         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
756         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
757
758         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
759         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
760         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
761         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
762
763         wp.wplinked = false;
764 }
765
766 // tell a spawnfunc_waypoint to relink
767 void waypoint_schedulerelink(entity wp)
768 {
769         if (wp == NULL)
770                 return;
771
772         waypoint_setupmodel(wp);
773         wp.wpisbox = vdist(wp.size, >, 0);
774         wp.enemy = NULL;
775         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
776                 wp.owner = NULL;
777         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
778                 waypoint_clearlinks(wp);
779         // schedule an actual relink on next frame
780         setthink(wp, waypoint_think);
781         wp.nextthink = time;
782         wp.effects = EF_LOWPRECISION;
783 }
784
785 // spawnfunc_waypoint map entity
786 spawnfunc(waypoint)
787 {
788         IL_PUSH(g_waypoints, this);
789
790         setorigin(this, this.origin);
791         // schedule a relink after other waypoints have had a chance to spawn
792         waypoint_clearlinks(this);
793         //waypoint_schedulerelink(this);
794 }
795
796 // tell all waypoints to relink
797 // actually this is useful only to update relink_* stats
798 void waypoint_schedulerelinkall()
799 {
800         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
801         IL_EACH(g_waypoints, true,
802         {
803                 waypoint_schedulerelink(it);
804         });
805         waypoint_load_links_hardwired();
806 }
807
808 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
809
810 // Load waypoint links from file
811 bool waypoint_load_links()
812 {
813         string s;
814         float file, tokens, c = 0, found;
815         entity wp_from = NULL, wp_to;
816         vector wp_to_pos, wp_from_pos;
817
818         string gt_ext = GET_GAMETYPE_EXTENSION();
819
820         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
821         file = fopen(filename, FILE_READ);
822
823         if (gt_ext != "" && file < 0)
824         {
825                 // if race waypoint file doesn't exist load the default one
826                 filename = sprintf("maps/%s.waypoints.cache", mapname);
827                 file = fopen(filename, FILE_READ);
828         }
829
830         if (file < 0)
831         {
832                 LOG_TRACE("waypoint links load from ", filename, " failed");
833                 waypoint_schedulerelinkall();
834                 return false;
835         }
836
837         bool parse_comments = true;
838         float ver = 0;
839         string links_time = string_null;
840
841         while ((s = fgets(file)))
842         {
843                 if(parse_comments)
844                 {
845                         if(substring(s, 0, 2) == "//")
846                         {
847                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
848                                         ver = stof(substring(s, 19, -1));
849                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
850                                         links_time = substring(s, 16, -1);
851                                 continue;
852                         }
853                         else
854                         {
855                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
856                                 {
857                                         if (links_time != waypoint_time)
858                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
859                                         else
860                                                 LOG_TRACE("waypoint links for this map are outdated.");
861                                         if (g_assault)
862                                         {
863                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
864                                         }
865                                         else
866                                         {
867                                                 LOG_TRACE("automatically updating...");
868                                                 waypoint_schedulerelinkall();
869                                                 fclose(file);
870                                                 return false;
871                                         }
872                                 }
873                                 parse_comments = false;
874                         }
875                 }
876
877                 tokens = tokenizebyseparator(s, "*");
878
879                 if (tokens!=2)
880                 {
881                         // bad file format
882                         fclose(file);
883                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
884                         return false;
885                 }
886
887                 wp_from_pos     = stov(argv(0));
888                 wp_to_pos       = stov(argv(1));
889
890                 // Search "from" waypoint
891                 if(!wp_from || wp_from.origin!=wp_from_pos)
892                 {
893                         wp_from = findradius(wp_from_pos, 1);
894                         found = false;
895                         while(wp_from)
896                         {
897                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
898                                 if(wp_from.classname == "waypoint")
899                                 {
900                                         found = true;
901                                         break;
902                                 }
903                                 wp_from = wp_from.chain;
904                         }
905
906                         if(!found)
907                         {
908                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
909                                 continue;
910                         }
911                 }
912
913                 // Search "to" waypoint
914                 wp_to = findradius(wp_to_pos, 1);
915                 found = false;
916                 while(wp_to)
917                 {
918                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
919                         if(wp_to.classname == "waypoint")
920                         {
921                                 found = true;
922                                 break;
923                         }
924                         wp_to = wp_to.chain;
925                 }
926
927                 if(!found)
928                 {
929                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
930                         continue;
931                 }
932
933                 ++c;
934                 waypoint_addlink(wp_from, wp_to);
935         }
936
937         fclose(file);
938
939         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
940
941         bool scheduled = false;
942         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
943         {
944                 if (!it.wp00)
945                 {
946                         waypoint_schedulerelink(it);
947                         scheduled = true;
948                 }
949         });
950         if (scheduled)
951                 return false;
952
953         botframe_cachedwaypointlinks = true;
954         return true;
955 }
956
957 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
958 {
959         string s;
960         float file, tokens, c = 0, found;
961         entity wp_from = NULL, wp_to;
962         vector wp_to_pos, wp_from_pos;
963
964         string gt_ext = GET_GAMETYPE_EXTENSION();
965
966         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
967         file = fopen(filename, FILE_READ);
968
969         if (gt_ext != "" && file < 0)
970         {
971                 // if race waypoint file doesn't exist load the default one
972                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
973                 file = fopen(filename, FILE_READ);
974         }
975
976         botframe_loadedforcedlinks = true;
977
978         if (file < 0)
979         {
980                 if(!removal_mode)
981                         LOG_TRACE("waypoint links load from ", filename, " failed");
982                 return;
983         }
984
985         while ((s = fgets(file)))
986         {
987                 if(substring(s, 0, 2)=="//")
988                         continue;
989
990                 if(substring(s, 0, 1)=="#")
991                         continue;
992
993                 tokens = tokenizebyseparator(s, "*");
994
995                 if (tokens!=2)
996                         continue;
997
998                 wp_from_pos     = stov(argv(0));
999                 wp_to_pos       = stov(argv(1));
1000
1001                 // Search "from" waypoint
1002                 if(!wp_from || wp_from.origin!=wp_from_pos)
1003                 {
1004                         wp_from = findradius(wp_from_pos, 5);
1005                         found = false;
1006                         while(wp_from)
1007                         {
1008                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1009                                 if(wp_from.classname == "waypoint")
1010                                 {
1011                                         found = true;
1012                                         break;
1013                                 }
1014                                 wp_from = wp_from.chain;
1015                         }
1016
1017                         if(!found)
1018                         {
1019                                 if(!removal_mode)
1020                                         LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1021                                 continue;
1022                         }
1023                 }
1024
1025                 // Search "to" waypoint
1026                 wp_to = findradius(wp_to_pos, 5);
1027                 found = false;
1028                 while(wp_to)
1029                 {
1030                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1031                         if(wp_to.classname == "waypoint")
1032                         {
1033                                 found = true;
1034                                 break;
1035                         }
1036                         wp_to = wp_to.chain;
1037                 }
1038
1039                 if(!found)
1040                 {
1041                         if(!removal_mode)
1042                                 LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1043                         continue;
1044                 }
1045
1046                 ++c;
1047                 if(removal_mode)
1048                 {
1049                         waypoint_removelink(wp_from, wp_to);
1050                         continue;
1051                 }
1052
1053                 waypoint_addlink(wp_from, wp_to);
1054                 wp_from.wphardwired = true;
1055                 wp_to.wphardwired = true;
1056                 waypoint_setupmodel(wp_from);
1057                 waypoint_setupmodel(wp_to);
1058         }
1059
1060         fclose(file);
1061
1062         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
1063                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1064 }
1065
1066 entity waypoint_get_link(entity w, float i)
1067 {
1068         switch(i)
1069         {
1070                 case  0:return w.wp00;
1071                 case  1:return w.wp01;
1072                 case  2:return w.wp02;
1073                 case  3:return w.wp03;
1074                 case  4:return w.wp04;
1075                 case  5:return w.wp05;
1076                 case  6:return w.wp06;
1077                 case  7:return w.wp07;
1078                 case  8:return w.wp08;
1079                 case  9:return w.wp09;
1080                 case 10:return w.wp10;
1081                 case 11:return w.wp11;
1082                 case 12:return w.wp12;
1083                 case 13:return w.wp13;
1084                 case 14:return w.wp14;
1085                 case 15:return w.wp15;
1086                 case 16:return w.wp16;
1087                 case 17:return w.wp17;
1088                 case 18:return w.wp18;
1089                 case 19:return w.wp19;
1090                 case 20:return w.wp20;
1091                 case 21:return w.wp21;
1092                 case 22:return w.wp22;
1093                 case 23:return w.wp23;
1094                 case 24:return w.wp24;
1095                 case 25:return w.wp25;
1096                 case 26:return w.wp26;
1097                 case 27:return w.wp27;
1098                 case 28:return w.wp28;
1099                 case 29:return w.wp29;
1100                 case 30:return w.wp30;
1101                 case 31:return w.wp31;
1102                 default:return NULL;
1103         }
1104 }
1105
1106 // Save all waypoint links to a file
1107 void waypoint_save_links()
1108 {
1109         // temporarily remove hardwired links so they don't get saved among normal links
1110         waypoint_remove_links_hardwired();
1111
1112         string gt_ext = GET_GAMETYPE_EXTENSION();
1113
1114         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1115         int file = fopen(filename, FILE_WRITE);
1116         if (file < 0)
1117         {
1118                 LOG_INFOF("waypoint link save to %s failed", filename);
1119                 return;
1120         }
1121
1122         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1123         if (waypoint_time != "")
1124                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1125
1126         int c = 0;
1127         IL_EACH(g_waypoints, true,
1128         {
1129                 for(int j = 0; j < 32; ++j)
1130                 {
1131                         entity link = waypoint_get_link(it, j);
1132                         if(link)
1133                         {
1134                                 // NOTE: vtos rounds vector components to 1 decimal place
1135                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1136                                 fputs(file, s);
1137                                 ++c;
1138                         }
1139                 }
1140         });
1141         fclose(file);
1142
1143         botframe_cachedwaypointlinks = true;
1144
1145         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1146
1147         waypoint_load_links_hardwired();
1148 }
1149
1150 // save waypoints to gamedir/data/maps/mapname.waypoints
1151 void waypoint_saveall()
1152 {
1153         string gt_ext = GET_GAMETYPE_EXTENSION();
1154
1155         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1156         int file = fopen(filename, FILE_WRITE);
1157         if (file < 0)
1158         {
1159                 waypoint_save_links(); // save anyway?
1160                 botframe_loadedforcedlinks = false;
1161
1162                 LOG_INFOF("waypoint links: save to %s failed", filename);
1163                 return;
1164         }
1165
1166         float sym = autocvar_g_waypointeditor_symmetrical;
1167         string sym_str = ftos(sym);
1168         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1169         {
1170                 if (sym == 1)
1171                 {
1172                         sym_str = cons(sym_str, "-");
1173                         sym_str = cons(sym_str, "-");
1174                 }
1175                 else
1176                 {
1177                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1178                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1179                 }
1180                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1181                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1182         }
1183         else if (autocvar_g_waypointeditor_symmetrical == -2)
1184         {
1185                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1186                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1187         }
1188
1189         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1190         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1191         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1192         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1193
1194         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1195         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1196         //fputs(file, strcat("//", "\n"));
1197         //fputs(file, strcat("//", "\n"));
1198         //fputs(file, strcat("//", "\n"));
1199
1200         int c = 0;
1201         IL_EACH(g_waypoints, true,
1202         {
1203                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1204                         continue;
1205
1206                 string s;
1207                 // NOTE: vtos rounds vector components to 1 decimal place
1208                 s = strcat(vtos(it.origin + it.mins), "\n");
1209                 s = strcat(s, vtos(it.origin + it.maxs));
1210                 s = strcat(s, "\n");
1211                 s = strcat(s, ftos(it.wpflags));
1212                 s = strcat(s, "\n");
1213                 fputs(file, s);
1214                 c++;
1215         });
1216         fclose(file);
1217         waypoint_save_links();
1218         botframe_loadedforcedlinks = false;
1219
1220         LOG_INFOF("saved %d waypoints to %s", c, filename);
1221 }
1222
1223 // load waypoints from file
1224 float waypoint_loadall()
1225 {
1226         string s;
1227         float file, cwp, cwb, fl;
1228         vector m1, m2;
1229         cwp = 0;
1230         cwb = 0;
1231
1232         string gt_ext = GET_GAMETYPE_EXTENSION();
1233
1234         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1235         file = fopen(filename, FILE_READ);
1236
1237         if (gt_ext != "" && file < 0)
1238         {
1239                 // if race waypoint file doesn't exist load the default one
1240                 filename = sprintf("maps/%s.waypoints", mapname);
1241                 file = fopen(filename, FILE_READ);
1242         }
1243
1244         if (file < 0)
1245         {
1246                 LOG_TRACE("waypoint load from ", filename, " failed");
1247                 return 0;
1248         }
1249
1250         bool parse_comments = true;
1251         float ver = 0;
1252         float sym = 0;
1253         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1254
1255         while ((s = fgets(file)))
1256         {
1257                 if(parse_comments)
1258                 {
1259                         if(substring(s, 0, 2) == "//")
1260                         {
1261                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1262                                         ver = stof(substring(s, 19, -1));
1263                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1264                                 {
1265                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1266                                         if (tokens) { sym = stof(argv(0)); }
1267                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1268                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1269                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1270                                 }
1271                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1272                                         strcpy(waypoint_time, substring(s, 16, -1));
1273                                 continue;
1274                         }
1275                         else
1276                         {
1277                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1278                                 {
1279                                         LOG_TRACE("waypoints for this map are outdated");
1280                                         LOG_TRACE("please update them in the editor");
1281                                 }
1282                                 parse_comments = false;
1283                         }
1284                 }
1285                 m1 = stov(s);
1286                 s = fgets(file);
1287                 if (!s)
1288                         break;
1289                 m2 = stov(s);
1290                 s = fgets(file);
1291                 if (!s)
1292                         break;
1293                 fl = stof(s);
1294                 waypoint_spawn(m1, m2, fl);
1295                 if (m1 == m2)
1296                         cwp = cwp + 1;
1297                 else
1298                         cwb = cwb + 1;
1299         }
1300         fclose(file);
1301         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1302
1303         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1304         {
1305                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1306                 if (sym == 1 && sym_param3 < 2)
1307                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1308                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1309                 {
1310                         string params;
1311                         if (sym == 1)
1312                                 params = cons("-", "-");
1313                         else
1314                         {
1315                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1316                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1317                         }
1318                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1319                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1320                 }
1321                 else if (sym == -2)
1322                 {
1323                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1324                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1325                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1326                 }
1327                 else
1328                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1329                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1330         }
1331
1332         return cwp + cwb;
1333 }
1334
1335 #define waypoint_fixorigin(position, tracetest_ent) \
1336         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1337
1338 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1339 {
1340         vector endpos = position + down_dir * 3000;
1341         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1342         if(trace_startsolid)
1343                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1344         if(trace_startsolid)
1345                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1346         if(trace_fraction < 1)
1347                 position = trace_endpos;
1348         return position;
1349 }
1350
1351 void waypoint_spawnforitem_force(entity e, vector org)
1352 {
1353         // Fix the waypoint altitude if necessary
1354         org = waypoint_fixorigin(org, NULL);
1355
1356         // don't spawn an item spawnfunc_waypoint if it already exists
1357         IL_EACH(g_waypoints, true,
1358         {
1359                 if(it.wpisbox)
1360                 {
1361                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1362                         {
1363                                 e.nearestwaypoint = it;
1364                                 return;
1365                         }
1366                 }
1367                 else
1368                 {
1369                         if(vdist(it.origin - org, <, 16))
1370                         {
1371                                 e.nearestwaypoint = it;
1372                                 return;
1373                         }
1374                 }
1375         });
1376
1377         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1378 }
1379
1380 void waypoint_spawnforitem(entity e)
1381 {
1382         if(!bot_waypoints_for_items)
1383                 return;
1384
1385         waypoint_spawnforitem_force(e, e.origin);
1386 }
1387
1388 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1389 {
1390         entity w;
1391         entity dw;
1392         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1393         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1394         // one way link to the destination
1395         w.wp00 = dw;
1396         w.wp00mincost = timetaken; // this is just for jump pads
1397         // the teleporter's nearest spawnfunc_waypoint is this one
1398         // (teleporters are not goals, so this is probably useless)
1399         e.nearestwaypoint = w;
1400         e.nearestwaypointtimeout = -1;
1401 }
1402
1403 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1404 {
1405         float src_angle = e.warpzone_angles.x;
1406         while (src_angle < -180) src_angle += 360;
1407         while (src_angle > 180) src_angle -= 360;
1408
1409         float dest_angle = e.enemy.warpzone_angles.x;
1410         while (dest_angle < -180) dest_angle += 360;
1411         while (dest_angle > 180) dest_angle -= 360;
1412
1413         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1414         if (src_angle == -90 || dest_angle == -90)
1415                 return;
1416
1417         makevectors(e.warpzone_angles);
1418         vector src = (e.absmin + e.absmax) * 0.5;
1419         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1420         vector down_dir_src = -v_up;
1421
1422         makevectors(e.enemy.warpzone_angles);
1423         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1424         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1425         vector down_dir_dest = -v_up;
1426
1427         int extra_flag = 0;
1428         // don't snap to the ground waypoints for source warpzones pointing downwards
1429         if (src_angle != 90)
1430         {
1431                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1432                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1433                 // oblique warpzones need a jump otherwise bots gets stuck
1434                 if (src_angle != 0)
1435                         extra_flag = WAYPOINTFLAG_JUMP;
1436         }
1437
1438         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1439 }
1440
1441 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1442 {
1443         destination = waypoint_fixorigin(destination, tracetest_ent);
1444         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1445 }
1446
1447 entity waypoint_spawnpersonal(entity this, vector position)
1448 {
1449         entity w;
1450
1451         // drop the waypoint to a proper location:
1452         //   first move it up by a player height
1453         //   then move it down to hit the floor with player bbox size
1454         position = waypoint_fixorigin(position, this);
1455
1456         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1457         w.nearestwaypoint = NULL;
1458         w.nearestwaypointtimeout = 0;
1459         w.owner = this;
1460
1461         waypoint_schedulerelink(w);
1462
1463         return w;
1464 }
1465
1466 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1467 {
1468         if (!(wp1 && wp2))
1469                 return;
1470
1471         if (wp1.wphardwired && wp2.wphardwired)
1472                 te_beam(NULL, wp1.origin, wp2.origin);
1473         else if (display_type == 1)
1474                 te_lightning2(NULL, wp1.origin, wp2.origin);
1475 }
1476
1477 void waypoint_showlinks_to(entity wp, int display_type)
1478 {
1479         IL_EACH(g_waypoints, it != wp,
1480         {
1481                 if (waypoint_islinked(it, wp))
1482                         waypoint_showlink(it, wp, display_type);
1483         });
1484 }
1485
1486 void waypoint_showlinks_from(entity wp, int display_type)
1487 {
1488         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1489         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1490         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1491         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1492         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1493         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1494         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1495         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1496         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1497         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1498         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1499         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1500         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1501         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1502         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1503         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1504 }
1505
1506 void crosshair_trace_waypoints(entity pl)
1507 {
1508         IL_EACH(g_waypoints, true, {
1509                 it.solid = SOLID_BSP;
1510                 if (!it.wpisbox)
1511                         setsize(it, '-16 -16 -16', '16 16 16');
1512         });
1513
1514         crosshair_trace(pl);
1515
1516         IL_EACH(g_waypoints, true, {
1517                 it.solid = SOLID_TRIGGER;
1518                 if (!it.wpisbox)
1519                         setsize(it, '0 0 0', '0 0 0');
1520         });
1521         if (trace_ent.classname != "waypoint")
1522                 trace_ent = NULL;
1523 }
1524
1525 void botframe_showwaypointlinks()
1526 {
1527         if (time < botframe_waypointeditorlightningtime)
1528                 return;
1529         botframe_waypointeditorlightningtime = time + 0.5;
1530         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1531         {
1532                 int display_type = 0;
1533                 if (wasfreed(it.wp_aimed))
1534                         it.wp_aimed = NULL;
1535                 if (wasfreed(it.wp_locked))
1536                         it.wp_locked = NULL;
1537                 if (PHYS_INPUT_BUTTON_USE(it))
1538                         it.wp_locked = it.wp_aimed;
1539                 entity head = it.wp_locked;
1540                 if (!head)
1541                         head = navigation_findnearestwaypoint(it, false);
1542                 it.nearestwaypoint = head; // mainly useful for debug
1543                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1544                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1545                         display_type = 1; // default
1546                 else if(head && (head.wphardwired))
1547                         display_type = 2; // only hardwired
1548
1549                 if (display_type)
1550                 {
1551                         //navigation_testtracewalk = true;
1552                         //print("currently selected WP is ", etos(head), "\n");
1553                         //navigation_testtracewalk = false;
1554                         if (head)
1555                         {
1556                                 te_lightning2(NULL, head.origin, it.origin);
1557                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1558                                         waypoint_showlinks_to(head, display_type);
1559                                 else
1560                                         waypoint_showlinks_from(head, display_type);
1561                         }
1562                 }
1563                 string str;
1564                 entity wp = NULL;
1565                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
1566                 {
1567                         crosshair_trace_waypoints(it);
1568                         if (trace_ent)
1569                         {
1570                                 wp = trace_ent;
1571                                 if (wp != it.wp_aimed)
1572                                 {
1573                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: '%s'\n", etof(wp), wp.wpflags, vtos(wp.origin));
1574                                         if (wp.wpisbox)
1575                                                 str = strcat(str, sprintf("echo \" absmin: '%s', absmax: '%s'\"\n", vtos(wp.absmin), vtos(wp.absmax)));
1576                                         stuffcmd(it, str);
1577                                         str = sprintf("entity: %d\nflags: %d\norigin: \'%s\'", etof(wp), wp.wpflags, vtos(wp.origin));
1578                                         if (wp.wpisbox)
1579                                                 str = strcat(str, sprintf(" \nabsmin: '%s'\nabsmax: '%s'", vtos(wp.absmin), vtos(wp.absmax)));
1580                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
1581                                 }
1582                         }
1583                 }
1584                 if (it.wp_aimed != wp)
1585                         it.wp_aimed = wp;
1586         });
1587 }
1588
1589 float botframe_autowaypoints_fixdown(vector v)
1590 {
1591         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1592         if(trace_fraction >= 1)
1593                 return 0;
1594         return 1;
1595 }
1596
1597 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1598 {
1599         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1600         {
1601                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1602                 return 0;
1603         });
1604
1605         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1606         return 1;
1607 }
1608
1609 // return value:
1610 //    1 = WP created
1611 //    0 = no action needed
1612 //   -1 = temp fail, try from world too
1613 //   -2 = permanent fail, do not retry
1614 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1615 {
1616         // make it possible to go from p to wp, if we can
1617         // if wp is NULL, nearest is chosen
1618
1619         entity w;
1620         vector porg;
1621         float t, tmin, tmax;
1622         vector o;
1623         vector save;
1624
1625         if(!botframe_autowaypoints_fixdown(p.origin))
1626                 return -2;
1627         porg = trace_endpos;
1628
1629         if(wp)
1630         {
1631                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1632
1633                 // if wp -> porg, then OK
1634                 float maxdist;
1635                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1636                 {
1637                         // we may find a better one
1638                         maxdist = vlen(wp.origin - porg);
1639                 }
1640                 else
1641                 {
1642                         // accept any "good"
1643                         maxdist = 2100;
1644                 }
1645
1646                 float bestdist = maxdist;
1647                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1648                 {
1649                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1650                         if(d < bestdist)
1651                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1652                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1653                         {
1654                                 bestdist = d;
1655                                 p.(fld) = it;
1656                         }
1657                 });
1658                 if(bestdist < maxdist)
1659                 {
1660                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1661                         return 0;
1662                 }
1663
1664                 if(bestdist < 2100)
1665                 {
1666                         // we know maxdist < 2100
1667                         // so wp -> porg is still valid
1668                         // all is good
1669                         p.(fld) = wp;
1670                         return 0;
1671                 }
1672
1673                 // otherwise, no existing WP can fix our issues
1674         }
1675         else
1676         {
1677                 save = p.origin;
1678                 setorigin(p, porg);
1679                 w = navigation_findnearestwaypoint(p, walkfromwp);
1680                 setorigin(p, save);
1681                 if(w)
1682                 {
1683                         p.(fld) = w;
1684                         return 0;
1685                 }
1686         }
1687
1688         tmin = 0;
1689         tmax = 1;
1690         for (;;)
1691         {
1692                 if(tmax - tmin < 0.001)
1693                 {
1694                         // did not get a good candidate
1695                         return -1;
1696                 }
1697
1698                 t = (tmin + tmax) * 0.5;
1699                 o = antilag_takebackorigin(p, CS(p), time - t);
1700                 if(!botframe_autowaypoints_fixdown(o))
1701                         return -2;
1702                 o = trace_endpos;
1703
1704                 if(wp)
1705                 {
1706                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1707                         {
1708                                 // we cannot walk from wp.origin to o
1709                                 // get closer to tmax
1710                                 tmin = t;
1711                                 continue;
1712                         }
1713                 }
1714                 else
1715                 {
1716                         save = p.origin;
1717                         setorigin(p, o);
1718                         w = navigation_findnearestwaypoint(p, walkfromwp);
1719                         setorigin(p, save);
1720                         if(!w)
1721                         {
1722                                 // we cannot walk from any WP to o
1723                                 // get closer to tmax
1724                                 tmin = t;
1725                                 continue;
1726                         }
1727                 }
1728
1729                 // if we get here, o is valid regarding waypoints
1730                 // check if o is connected right to the player
1731                 // we break if it succeeds, as that means o is a good waypoint location
1732                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1733                         break;
1734
1735                 // o is no good, we need to get closer to the player
1736                 tmax = t;
1737         }
1738
1739         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1740         botframe_autowaypoints_createwp(o, p, fld, 0);
1741         return 1;
1742 }
1743
1744 // automatically create missing waypoints
1745 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1746 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1747 {
1748         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1749         if(r != -1)
1750                 return;
1751         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1752         if(r != -1)
1753                 return;
1754
1755         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1756         if(!botframe_autowaypoints_fixdown(p.origin))
1757                 return; // shouldn't happen, caught above
1758         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1759 }
1760
1761 void botframe_deleteuselesswaypoints()
1762 {
1763         IL_EACH(g_items, it.bot_pickup,
1764         {
1765                 // NOTE: this protects waypoints if they're the ONLY nearest
1766                 // waypoint. That's the intention.
1767                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1768                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1769         });
1770         IL_EACH(g_waypoints, true,
1771         {
1772                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1773                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1774                 // WP is useful if:
1775                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1776                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1777                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1778                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1779                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1780                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1781                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1782                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1783                 // b) WP is closest WP for an item/spawnpoint/other entity
1784                 //    This has been done above by protecting these WPs.
1785         });
1786         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1787         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1788         {
1789                 for (int m = 0; m < 32; ++m)
1790                 {
1791                         entity w = waypoint_get_link(it, m);
1792                         if (!w)
1793                                 break;
1794                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1795                                 continue;
1796                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1797                                 continue;
1798                         for (int j = 0; j < 32; ++j)
1799                         {
1800                                 entity w2 = waypoint_get_link(w, j);
1801                                 if (!w2)
1802                                         break;
1803                                 if (it == w2)
1804                                         continue;
1805                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1806                                         continue;
1807                                 // If we got here, it != w2 exist with it -> w
1808                                 // and w -> w2. That means the waypoint is not
1809                                 // a dead end.
1810                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1811                                 for (int k = 0; k < 32; ++k)
1812                                 {
1813                                         if (waypoint_get_link(it, k) == w2)
1814                                                 continue;
1815                                         // IF WE GET HERE, w is proven useful
1816                                         // to get from it to w2!
1817                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1818                                         goto next;
1819                                 }
1820                         }
1821 LABEL(next)
1822                 }
1823         });
1824         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1825         //     they are needed to complete routes while autowaypointing.
1826
1827         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1828         {
1829                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1830                 te_explosion(it.origin);
1831                 waypoint_remove(it);
1832                 break;
1833         });
1834
1835         IL_EACH(g_waypoints, true,
1836         {
1837                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1838         });
1839 }
1840
1841 void botframe_autowaypoints()
1842 {
1843         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1844                 // going back is broken, so only fix waypoints to walk TO the player
1845                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1846                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1847                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1848         });
1849
1850         if (autocvar_g_waypointeditor_auto >= 2) {
1851                 botframe_deleteuselesswaypoints();
1852         }
1853 }
1854