qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 void waypoint_setupmodel(entity wp)
 264 {
 265         if (autocvar_g_waypointeditor)
 266         {
 267                 // TODO: add some sort of visible box in edit mode for box waypoints
 268                 vector m1 = wp.mins;
 269                 vector m2 = wp.maxs;
 270                 setmodel(wp, MDL_WAYPOINT);
 271                 setsize(wp, m1, m2);
 272                 wp.effects = EF_LOWPRECISION;
 273                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 274                         wp.colormod = '1 0 0';
 275                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 276                         wp.colormod = '1 1 0';
 277                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 278                         wp.colormod = '1 0.5 0'; // orange
 279                 else if (wp.wphardwired)
 280                         wp.colormod = '0.5 0 1'; // violet
 281                 else
 282                         wp.colormod = '1 1 1';
 283         }
 284         else
 285                 wp.model = "";
 286 }
 287
 288 entity waypoint_get(vector m1, vector m2)
 289 {
 290         if (m1 == m2)
 291         {
 292                 m1 -= '8 8 8';
 293                 m2 += '8 8 8';
 294         }
 295         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 296
 297         return NULL;
 298 }
 299
 300 entity waypoint_spawn(vector m1, vector m2, float f)
 301 {
 302         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 303         {
 304                 entity wp_found = waypoint_get(m1, m2);
 305                 if (wp_found)
 306                         return wp_found;
 307         }
 308         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 309         // otherwise links loaded from file would be applied only to the first destination
 310         // waypoint since link format doesn't specify waypoint entities but just positions
 311         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 312         {
 313                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 314                 {
 315                         return it;
 316                 });
 317         }
 318
 319         entity w = new(waypoint);
 320         IL_PUSH(g_waypoints, w);
 321         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 322         w.wpflags = f;
 323         w.solid = SOLID_TRIGGER;
 324         setorigin(w, (m1 + m2) * 0.5);
 325         setsize(w, m1 - w.origin, m2 - w.origin);
 326         if (w.size)
 327                 w.wpisbox = true;
 328
 329         if(!w.wpisbox)
 330         {
 331                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 332                 if(!move_out_of_solid(w))
 333                 {
 334                         if(!(f & WAYPOINTFLAG_GENERATED))
 335                         {
 336                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 337                                 delete(w);
 338                                 return NULL;
 339                         }
 340                         else
 341                         {
 342                                 if(autocvar_developer)
 343                                 {
 344                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 345                                         backtrace("Waypoint stuck");
 346                                 }
 347                         }
 348                 }
 349                 setsize(w, '0 0 0', '0 0 0');
 350         }
 351
 352         waypoint_clearlinks(w);
 353         //waypoint_schedulerelink(w);
 354
 355         waypoint_setupmodel(w);
 356
 357         return w;
 358 }
 359
 360 float trigger_push_get_push_time(entity this, vector endpos);
 361 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 362 {
 363         entity jp = NULL;
 364         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 365         {
 366                 jp = it;
 367                 break;
 368         });
 369         if (!jp)
 370                 return;
 371
 372         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 373         wp_from.wp00 = wp_to;
 374         wp_from.wp00mincost = cost;
 375         jp.nearestwaypoint = wp_from;
 376         jp.nearestwaypointtimeout = -1;
 377 }
 378
 379 bool start_wp_is_spawned;
 380 vector start_wp_origin;
 381
 382 void waypoint_clear_start_wp(entity pl, bool warn)
 383 {
 384         start_wp_is_spawned = false;
 385         start_wp_origin = '0 0 0';
 386         pl.wp_locked = NULL;
 387         if (warn)
 388                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 389 }
 390
 391 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp)
 392 {
 393         if (WAYPOINT_VERSION < waypoint_version_loaded)
 394         {
 395                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 396                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 397                 return;
 398         }
 399
 400         entity e = NULL, jp = NULL;
 401         vector org = pl.origin;
 402         if (at_crosshair)
 403         {
 404                 crosshair_trace(pl);
 405                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 406                 IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 407                 {
 408                         jp = it;
 409                         break;
 410                 });
 411         }
 412         if (jp || is_jump_wp)
 413         {
 414                 if (start_wp_is_spawned)
 415                         start_wp_is_spawned = false;
 416                 LOG_INFO("^xf80Spawning start waypoint...\n");
 417         }
 418         int ctf_flags = havocbot_symmetry_origin_order;
 419         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 420                    || (autocvar_g_waypointeditor_symmetrical < 0));
 421         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 422                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 423         if (sym && ctf_flags < 2)
 424                 ctf_flags = 2;
 425         int wp_num = ctf_flags;
 426
 427         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp)
 428         {
 429                 // snap waypoint to item's origin if close enough
 430                 IL_EACH(g_items, true,
 431                 {
 432                         vector item_org = (it.absmin + it.absmax) * 0.5;
 433                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 434                         if (vlen(item_org - org) < 20)
 435                         {
 436                                 org = item_org;
 437                                 break;
 438                         }
 439                 });
 440         }
 441
 442         vector start_org = '0 0 0';
 443         if (start_wp_is_spawned)
 444         {
 445                 LOG_INFO("^xf80Spawning destination waypoint...\n");
 446                 start_org = start_wp_origin;
 447         }
 448
 449         // save org as it can be modified spawning symmetrycal waypoints
 450         vector initial_origin = '0 0 0';
 451         bool initial_origin_is_set = false;
 452
 453         LABEL(add_wp);
 454
 455         if (jp)
 456         {
 457                 e = NULL;
 458                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 459                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 460                 {
 461                         e = it; break;
 462                 });
 463                 if (!e)
 464                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 465                 if (!pl.wp_locked)
 466                         pl.wp_locked = e;
 467         }
 468         else if (is_jump_wp)
 469         {
 470                 entity wp_found = waypoint_get(org, org);
 471                 if (wp_found && !(wp_found.wpflags & WAYPOINTFLAG_JUMP))
 472                 {
 473                         LOG_INFO("Error: can't spawn a jump waypoint over an existent waypoint of a different type\n");
 474                         return;
 475                 }
 476                 e = waypoint_spawn(org, org, WAYPOINTFLAG_JUMP | WAYPOINTFLAG_NORELINK);
 477                 if (!pl.wp_locked)
 478                         pl.wp_locked = e;
 479         }
 480         else
 481                 e = waypoint_spawn(org, org, 0);
 482         if(!e)
 483         {
 484                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 485                 if (start_wp_is_spawned)
 486                         waypoint_clear_start_wp(pl, true);
 487                 return;
 488         }
 489
 490         if (!initial_origin_is_set)
 491         {
 492                 initial_origin = e.origin;
 493                 initial_origin_is_set = true;
 494         }
 495
 496         entity start_wp = NULL;
 497         if (start_wp_is_spawned)
 498         {
 499                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 500                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 501                 {
 502                         start_wp = it; break;
 503                 });
 504                 if(!start_wp)
 505                 {
 506                         // should not happen
 507                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 508                         waypoint_clear_start_wp(pl, true);
 509                         return;
 510                 }
 511                 waypoint_addlink(start_wp, e);
 512         }
 513
 514         if (!(jp || is_jump_wp))
 515                 waypoint_schedulerelink(e);
 516         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 517
 518         if (start_wp_is_spawned)
 519         {
 520                 pl.wp_locked = NULL;
 521                 waypoint_schedulerelink(start_wp);
 522                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 523                 {
 524                         if (start_wp.wp00_original == start_wp.wp00)
 525                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 526                         else
 527                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 528                 }
 529         }
 530
 531         if (sym)
 532         {
 533                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 534                 if (jp)
 535                 {
 536                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 537                         {
 538                                 jp = it; break;
 539                         });
 540                 }
 541                 if (start_wp_is_spawned)
 542                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 543                 if (vdist(org - pl.origin, >, 32))
 544                 {
 545                         if(wp_num > 2)
 546                                 wp_num--;
 547                         else
 548                                 sym = false;
 549                         goto add_wp;
 550                 }
 551         }
 552         if (jp || is_jump_wp)
 553         {
 554                 if (!start_wp_is_spawned)
 555                 {
 556                         // we've just created a custom jumppad waypoint
 557                         // the next one created by the user will be the destination waypoint
 558                         start_wp_is_spawned = true;
 559                         start_wp_origin = initial_origin;
 560                 }
 561         }
 562         else if (start_wp_is_spawned)
 563         {
 564                 waypoint_clear_start_wp(pl, false);
 565         }
 566 }
 567
 568 void waypoint_remove(entity wp)
 569 {
 570         IL_EACH(g_waypoints, it != wp,
 571         {
 572                 if (waypoint_islinked(it, wp))
 573                         waypoint_removelink(it, wp);
 574         });
 575         delete(wp);
 576 }
 577
 578 void waypoint_remove_fromeditor(entity pl)
 579 {
 580         if (WAYPOINT_VERSION < waypoint_version_loaded)
 581         {
 582                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 583                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 584                 return;
 585         }
 586
 587         entity e = navigation_findnearestwaypoint(pl, false);
 588
 589         int ctf_flags = havocbot_symmetry_origin_order;
 590         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 591                    || (autocvar_g_waypointeditor_symmetrical < 0));
 592         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 593                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 594         if (sym && ctf_flags < 2)
 595                 ctf_flags = 2;
 596         int wp_num = ctf_flags;
 597
 598         LABEL(remove_wp);
 599         if (!e) return;
 600
 601         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 602         {
 603                 if (start_wp_is_spawned)
 604                         waypoint_clear_start_wp(pl, true);
 605                 return;
 606         }
 607
 608         if (e.wphardwired)
 609         {
 610                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 611                 return;
 612         }
 613
 614         entity wp_sym = NULL;
 615         if (sym)
 616         {
 617                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 618                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 619                         if(vdist(org - it.origin, <, 3))
 620                         {
 621                                 wp_sym = it;
 622                                 break;
 623                         }
 624                 });
 625         }
 626
 627         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 628         waypoint_remove(e);
 629
 630         if (sym && wp_sym)
 631         {
 632                 e = wp_sym;
 633                 if(wp_num > 2)
 634                         wp_num--;
 635                 else
 636                         sym = false;
 637                 goto remove_wp;
 638         }
 639
 640         if (start_wp_is_spawned)
 641                 waypoint_clear_start_wp(pl, true);
 642 }
 643
 644 void waypoint_removelink(entity from, entity to)
 645 {
 646         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK && !(from.wpflags & WAYPOINTFLAG_JUMP)))
 647                 return;
 648
 649         entity fromwp31_prev = from.wp31;
 650
 651         switch (waypoint_getlinknum(from, to))
 652         {
 653                 // fallthrough all the way
 654                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 655                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 656                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 657                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 658                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 659                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 660                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 661                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 662                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 663                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 664                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 665                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 666                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 667                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 668                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 669                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 670                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 671                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 672                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 673                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 674                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 675                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 676                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 677                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 678                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 679                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 680                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 681                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 682                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 683                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 684                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 685                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 686         }
 687
 688         if (fromwp31_prev && !from.wp31)
 689                 waypoint_schedulerelink(from);
 690 }
 691
 692 int waypoint_getlinknum(entity from, entity to)
 693 {
 694         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 695         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 696         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 697         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 698         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 699         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 700         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 701         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 702         return -1;
 703 }
 704
 705 bool waypoint_islinked(entity from, entity to)
 706 {
 707         return (waypoint_getlinknum(from, to) >= 0);
 708 }
 709
 710 void waypoint_updatecost_foralllinks()
 711 {
 712         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 713         {
 714                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 715                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 716                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 717                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 718                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 719                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 720                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 721                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 722                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 723                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 724                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 725                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 726                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 727                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 728                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 729                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 730                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 731                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 732                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 733                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 734                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 735                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 736                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 737                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 738                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 739                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 740                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 741                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 742                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 743                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 744                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 745                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 746         });
 747 }
 748
 749 float waypoint_getlinearcost(float dist)
 750 {
 751         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 752                 return dist / (autocvar_sv_maxspeed * 1.25);
 753         return dist / autocvar_sv_maxspeed;
 754 }
 755 float waypoint_getlinearcost_underwater(float dist)
 756 {
 757         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 758         return dist / (autocvar_sv_maxspeed * 0.7);
 759 }
 760
 761 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 762 {
 763         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 764         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 765
 766         if (submerged_from && submerged_to)
 767                 return waypoint_getlinearcost_underwater(vlen(to - from));
 768
 769         float c = waypoint_getlinearcost(vlen(to - from));
 770
 771         float height = from.z - to.z;
 772         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 773         {
 774                 float height_cost;
 775                 if (boolean(from_ent.wpflags & WAYPOINTFLAG_JUMP))
 776                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
 777                 else
 778                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 779                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 780                 if(height_cost > c)
 781                         c = height_cost;
 782         }
 783
 784         if (submerged_from || submerged_to)
 785                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 786         return c;
 787 }
 788
 789 float waypoint_getlinkcost(entity from, entity to)
 790 {
 791         vector v1 = from.origin;
 792         vector v2 = to.origin;
 793         if (from.wpisbox)
 794         {
 795                 vector m1 = from.absmin, m2 = from.absmax;
 796                 v1.x = bound(m1.x, v2.x, m2.x);
 797                 v1.y = bound(m1.y, v2.y, m2.y);
 798                 v1.z = bound(m1.z, v2.z, m2.z);
 799         }
 800         if (to.wpisbox)
 801         {
 802                 vector m1 = to.absmin, m2 = to.absmax;
 803                 v2.x = bound(m1.x, v1.x, m2.x);
 804                 v2.y = bound(m1.y, v1.y, m2.y);
 805                 v2.z = bound(m1.z, v1.z, m2.z);
 806         }
 807         return waypoint_gettravelcost(v1, v2, from, to);
 808 }
 809
 810 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 811 // if c == -1 automatically determine cost of the link
 812 void waypoint_addlink_customcost(entity from, entity to, float c)
 813 {
 814         if (from == to || waypoint_islinked(from, to))
 815                 return;
 816         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & WAYPOINTFLAG_JUMP))
 817                 return;
 818
 819         if(c == -1)
 820                 c = waypoint_getlinkcost(from, to);
 821
 822         if (from.wp31mincost < c) return;
 823         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 824         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 825         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 826         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 827         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 828         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 829         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 830         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 831         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 832         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 833         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 834         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 835         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 836         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 837         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 838         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 839         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 840         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 841         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 842         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 843         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 844         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 845         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 846         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 847         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 848         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 849         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 850         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 851         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 852         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 853         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 854         from.wp00 = to;from.wp00mincost = c;return;
 855 }
 856
 857 void waypoint_addlink(entity from, entity to)
 858 {
 859         if ((from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP)))
 860                 waypoint_addlink_for_custom_jumppad(from, to);
 861         else
 862                 waypoint_addlink_customcost(from, to, -1);
 863 }
 864
 865 // relink this spawnfunc_waypoint
 866 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 867 // (SLOW!)
 868 void waypoint_think(entity this)
 869 {
 870         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 871         float sv2_height = 0, ev2_height = 0;
 872
 873         bot_calculate_stepheightvec();
 874
 875         int dphitcontentsmask_save = this.dphitcontentsmask;
 876         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 877
 878         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 879
 880         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 881         IL_EACH(g_waypoints, this != it,
 882         {
 883                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 884                 {
 885                         waypoint_addlink(this, it);
 886                         waypoint_addlink(it, this);
 887                 }
 888                 else
 889                 {
 890                         ++relink_total;
 891                         if(!checkpvs(this.origin, it))
 892                         {
 893                                 ++relink_pvsculled;
 894                                 continue;
 895                         }
 896
 897                         sv = set_tracewalk_dest_2(this, it.origin);
 898                         sv2 = tracewalk_dest;
 899                         sv2_height = tracewalk_dest_height;
 900                         ev = set_tracewalk_dest_2(it, this.origin);
 901                         ev2 = tracewalk_dest;
 902                         ev2_height = tracewalk_dest_height;
 903
 904                         dv = ev - sv;
 905                         dv.z = 0;
 906                         if(vdist(dv, >=, 1050)) // max search distance in XY
 907                         {
 908                                 ++relink_lengthculled;
 909                                 continue;
 910                         }
 911
 912                         navigation_testtracewalk = 0;
 913
 914                         //traceline(this.origin, it.origin, false, NULL);
 915                         //if (trace_fraction == 1)
 916                         if (this.wpisbox || this.wpflags & WAYPOINTFLAG_JUMP)
 917                                 relink_walkculled += 0.5;
 918                         else
 919                         {
 920                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 921                                         waypoint_addlink(this, it);
 922                                 else
 923                                         relink_walkculled += 0.5;
 924                         }
 925
 926                         if (it.wpisbox || it.wpflags & WAYPOINTFLAG_JUMP)
 927                                 relink_walkculled += 0.5;
 928                         else
 929                         {
 930                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 931                                         waypoint_addlink(it, this);
 932                                 else
 933                                         relink_walkculled += 0.5;
 934                         }
 935                 }
 936         });
 937         navigation_testtracewalk = 0;
 938         this.wplinked = true;
 939         this.dphitcontentsmask = dphitcontentsmask_save;
 940
 941         setthink(this, func_null);
 942         this.nextthink = 0;
 943 }
 944
 945 void waypoint_clearlinks(entity wp)
 946 {
 947         // clear links to other waypoints
 948         float f = 10000000;
 949         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 950         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 951         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 952         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 953
 954         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 955         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 956         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 957         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 958
 959         wp.wplinked = false;
 960 }
 961
 962 // tell a spawnfunc_waypoint to relink
 963 void waypoint_schedulerelink(entity wp)
 964 {
 965         if (wp == NULL)
 966                 return;
 967
 968         waypoint_setupmodel(wp);
 969         wp.wpisbox = vdist(wp.size, >, 0);
 970         wp.enemy = NULL;
 971         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 972                 wp.owner = NULL;
 973         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 974                 waypoint_clearlinks(wp);
 975         // schedule an actual relink on next frame
 976         setthink(wp, waypoint_think);
 977         wp.nextthink = time;
 978         wp.effects = EF_LOWPRECISION;
 979 }
 980
 981 // spawnfunc_waypoint map entity
 982 spawnfunc(waypoint)
 983 {
 984         IL_PUSH(g_waypoints, this);
 985
 986         setorigin(this, this.origin);
 987         // schedule a relink after other waypoints have had a chance to spawn
 988         waypoint_clearlinks(this);
 989         //waypoint_schedulerelink(this);
 990 }
 991
 992 // tell all waypoints to relink
 993 // actually this is useful only to update relink_* stats
 994 void waypoint_schedulerelinkall()
 995 {
 996         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 997         IL_EACH(g_waypoints, true,
 998         {
 999                 waypoint_schedulerelink(it);
1000         });
1001         waypoint_load_links_hardwired();
1002 }
1003
1004 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1005
1006 // Load waypoint links from file
1007 bool waypoint_load_links()
1008 {
1009         string s;
1010         float file, tokens, c = 0, found;
1011         entity wp_from = NULL, wp_to;
1012         vector wp_to_pos, wp_from_pos;
1013
1014         string gt_ext = GET_GAMETYPE_EXTENSION();
1015
1016         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1017         file = fopen(filename, FILE_READ);
1018
1019         if (gt_ext != "" && file < 0)
1020         {
1021                 // if race waypoint file doesn't exist load the default one
1022                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1023                 file = fopen(filename, FILE_READ);
1024         }
1025
1026         if (file < 0)
1027         {
1028                 LOG_TRACE("waypoint links load from ", filename, " failed");
1029                 waypoint_schedulerelinkall();
1030                 return false;
1031         }
1032
1033         bool parse_comments = true;
1034         float ver = 0;
1035         string links_time = string_null;
1036
1037         while ((s = fgets(file)))
1038         {
1039                 if(parse_comments)
1040                 {
1041                         if(substring(s, 0, 2) == "//")
1042                         {
1043                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1044                                         ver = stof(substring(s, 19, -1));
1045                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1046                                         links_time = substring(s, 16, -1);
1047                                 continue;
1048                         }
1049                         else
1050                         {
1051                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1052                                 {
1053                                         if (links_time != waypoint_time)
1054                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1055                                         else
1056                                                 LOG_TRACE("waypoint links for this map are outdated.");
1057                                         if (g_assault)
1058                                         {
1059                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1060                                         }
1061                                         else
1062                                         {
1063                                                 LOG_TRACE("automatically updating...");
1064                                                 waypoint_schedulerelinkall();
1065                                                 fclose(file);
1066                                                 return false;
1067                                         }
1068                                 }
1069                                 parse_comments = false;
1070                         }
1071                 }
1072
1073                 tokens = tokenizebyseparator(s, "*");
1074
1075                 if (tokens!=2)
1076                 {
1077                         // bad file format
1078                         fclose(file);
1079                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1080                         return false;
1081                 }
1082
1083                 wp_from_pos     = stov(argv(0));
1084                 wp_to_pos       = stov(argv(1));
1085
1086                 // Search "from" waypoint
1087                 if(!wp_from || wp_from.origin!=wp_from_pos)
1088                 {
1089                         wp_from = findradius(wp_from_pos, 1);
1090                         found = false;
1091                         while(wp_from)
1092                         {
1093                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1094                                 if(wp_from.classname == "waypoint")
1095                                 {
1096                                         found = true;
1097                                         break;
1098                                 }
1099                                 wp_from = wp_from.chain;
1100                         }
1101
1102                         if(!found)
1103                         {
1104                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1105                                 continue;
1106                         }
1107                 }
1108
1109                 // Search "to" waypoint
1110                 wp_to = findradius(wp_to_pos, 1);
1111                 found = false;
1112                 while(wp_to)
1113                 {
1114                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1115                         if(wp_to.classname == "waypoint")
1116                         {
1117                                 found = true;
1118                                 break;
1119                         }
1120                         wp_to = wp_to.chain;
1121                 }
1122
1123                 if(!found)
1124                 {
1125                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1126                         continue;
1127                 }
1128
1129                 ++c;
1130                 waypoint_addlink(wp_from, wp_to);
1131                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1132                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1133         }
1134
1135         fclose(file);
1136
1137         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1138
1139         bool scheduled = false;
1140         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1141         {
1142                 if (!it.wp00)
1143                 {
1144                         waypoint_schedulerelink(it);
1145                         scheduled = true;
1146                 }
1147         });
1148         if (scheduled)
1149                 return false;
1150
1151         botframe_cachedwaypointlinks = true;
1152         return true;
1153 }
1154
1155 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
1156 {
1157         string s;
1158         float file, tokens, c = 0, found;
1159         entity wp_from = NULL, wp_to;
1160         vector wp_to_pos, wp_from_pos;
1161
1162         string gt_ext = GET_GAMETYPE_EXTENSION();
1163
1164         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1165         file = fopen(filename, FILE_READ);
1166
1167         if (gt_ext != "" && file < 0)
1168         {
1169                 // if race waypoint file doesn't exist load the default one
1170                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1171                 file = fopen(filename, FILE_READ);
1172         }
1173
1174         botframe_loadedforcedlinks = true;
1175
1176         if (file < 0)
1177         {
1178                 if(!removal_mode)
1179                         LOG_TRACE("waypoint links load from ", filename, " failed");
1180                 return;
1181         }
1182
1183         bool is_special = false;
1184         while ((s = fgets(file)))
1185         {
1186                 if(substring(s, 0, 2)=="//")
1187                         continue;
1188
1189                 if(substring(s, 0, 1)=="#")
1190                         continue;
1191
1192                 // special links start with *, so old xonotic versions don't load them
1193                 is_special = false;
1194                 if (substring(s, 0, 1) == "*")
1195                 {
1196                         is_special = true;
1197                         s = substring(s, 1, -1);
1198                 }
1199
1200                 tokens = tokenizebyseparator(s, "*");
1201
1202                 if (tokens!=2)
1203                         continue;
1204
1205                 wp_from_pos     = stov(argv(0));
1206                 wp_to_pos       = stov(argv(1));
1207
1208                 // Search "from" waypoint
1209                 if(!wp_from || wp_from.origin!=wp_from_pos)
1210                 {
1211                         wp_from = findradius(wp_from_pos, 5);
1212                         found = false;
1213                         while(wp_from)
1214                         {
1215                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1216                                 if(wp_from.classname == "waypoint")
1217                                 {
1218                                         found = true;
1219                                         break;
1220                                 }
1221                                 wp_from = wp_from.chain;
1222                         }
1223
1224                         if(!found)
1225                         {
1226                                 if(!removal_mode)
1227                                         LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1228                                 continue;
1229                         }
1230                 }
1231
1232                 // Search "to" waypoint
1233                 wp_to = findradius(wp_to_pos, 5);
1234                 found = false;
1235                 while(wp_to)
1236                 {
1237                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1238                         if(wp_to.classname == "waypoint")
1239                         {
1240                                 found = true;
1241                                 break;
1242                         }
1243                         wp_to = wp_to.chain;
1244                 }
1245
1246                 if(!found)
1247                 {
1248                         if(!removal_mode)
1249                                 LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1250                         continue;
1251                 }
1252
1253                 ++c;
1254                 if (removal_mode && !is_special)
1255                 {
1256                         waypoint_removelink(wp_from, wp_to);
1257                         continue;
1258                 }
1259
1260                 if (!is_special)
1261                 {
1262                         waypoint_addlink(wp_from, wp_to);
1263                         wp_from.wphardwired = true;
1264                         wp_to.wphardwired = true;
1265                         waypoint_setupmodel(wp_from);
1266                         waypoint_setupmodel(wp_to);
1267                 } else if (wp_from.wpflags & WAYPOINTFLAG_NORELINK
1268                         && (wp_from.wpflags & WAYPOINTFLAG_JUMP || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1269                 {
1270                         waypoint_addlink(wp_from, wp_to);
1271                 }
1272         }
1273
1274         fclose(file);
1275
1276         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
1277                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1278 }
1279
1280 entity waypoint_get_link(entity w, float i)
1281 {
1282         switch(i)
1283         {
1284                 case  0:return w.wp00;
1285                 case  1:return w.wp01;
1286                 case  2:return w.wp02;
1287                 case  3:return w.wp03;
1288                 case  4:return w.wp04;
1289                 case  5:return w.wp05;
1290                 case  6:return w.wp06;
1291                 case  7:return w.wp07;
1292                 case  8:return w.wp08;
1293                 case  9:return w.wp09;
1294                 case 10:return w.wp10;
1295                 case 11:return w.wp11;
1296                 case 12:return w.wp12;
1297                 case 13:return w.wp13;
1298                 case 14:return w.wp14;
1299                 case 15:return w.wp15;
1300                 case 16:return w.wp16;
1301                 case 17:return w.wp17;
1302                 case 18:return w.wp18;
1303                 case 19:return w.wp19;
1304                 case 20:return w.wp20;
1305                 case 21:return w.wp21;
1306                 case 22:return w.wp22;
1307                 case 23:return w.wp23;
1308                 case 24:return w.wp24;
1309                 case 25:return w.wp25;
1310                 case 26:return w.wp26;
1311                 case 27:return w.wp27;
1312                 case 28:return w.wp28;
1313                 case 29:return w.wp29;
1314                 case 30:return w.wp30;
1315                 case 31:return w.wp31;
1316                 default:return NULL;
1317         }
1318 }
1319
1320 // Save all hardwired waypoint links to a file
1321 void waypoint_save_links_hardwired()
1322 {
1323         string gt_ext = GET_GAMETYPE_EXTENSION();
1324
1325         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1326         int file = fopen(filename, FILE_READ);
1327
1328         if (gt_ext != "" && file < 0)
1329         {
1330                 // if race waypoint file doesn't exist load the default one
1331                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1332                 file = fopen(filename, FILE_READ);
1333         }
1334
1335         if (file < 0)
1336         {
1337                 filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1338                 file = fopen(filename, FILE_WRITE);
1339                 if (file < 0)
1340                 {
1341                         LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1342                         return;
1343                 }
1344                 fputs(file, "// HARDWIRED LINKS\n\n");
1345                 fclose(file);
1346                 fopen(filename, FILE_READ);
1347                 if (file < 0)
1348                 {
1349                         LOG_TRACE("waypoint hardwired links load from ", filename, " failed");
1350                         return;
1351                 }
1352         }
1353
1354         int buf = buf_create();
1355         string s;
1356         int pos = 0;
1357
1358         // read comments and hardwired links from file to buf, they won't be changed
1359         while ((s = fgets(file)))
1360         {
1361                 // special links start with *, so old xonotic versions don't load them
1362                 if (substring(s, 0, 1) == "*")
1363                         break;
1364                 bufstr_add(buf, s, false);
1365                 ++pos;
1366         }
1367         fclose(file);
1368
1369         // read links to buf
1370         bool special_link_found = false;
1371         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP),
1372         {
1373                 for (int j = 0; j < 32; ++j)
1374                 {
1375                         entity link = waypoint_get_link(it, j);
1376                         if (link)
1377                         {
1378                                 if (!special_link_found)
1379                                 {
1380                                         special_link_found = true;
1381                                         if (pos == 0 || substring(bufstr_get(buf, pos - 1), 0, 16) != "// SPECIAL LINKS")
1382                                         {
1383                                                 bufstr_add(buf, "// SPECIAL LINKS (saved in the waypoint editor, comments added hereby won't be preserved)", false);
1384                                         }
1385                                 }
1386                                 // NOTE: vtos rounds vector components to 1 decimal place
1387                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin));
1388                                 bufstr_add(buf, s, false);
1389                         }
1390                 }
1391         });
1392
1393         // write buf to file
1394         gt_ext = GET_GAMETYPE_EXTENSION();
1395         filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1396         file = fopen(filename, FILE_WRITE);
1397         if (file < 0)
1398         {
1399                 LOG_INFOF("waypoint hardwired link save to %s failed", filename);
1400                 return;
1401         }
1402         int n = buf_getsize(buf);
1403         for (int i = 0; i < n; ++i)
1404         {
1405                 fputs(file, (strcat(bufstr_get(buf, i), "\n")));
1406         }
1407         buf_del(buf);
1408         fclose(file);
1409
1410         LOG_INFOF("saved hardwired waypoint links to %s", filename);
1411 }
1412
1413 // Save all waypoint links to a file
1414 void waypoint_save_links()
1415 {
1416         // temporarily remove hardwired links so they don't get saved among normal links
1417         waypoint_remove_links_hardwired();
1418
1419         string gt_ext = GET_GAMETYPE_EXTENSION();
1420
1421         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1422         int file = fopen(filename, FILE_WRITE);
1423         if (file < 0)
1424         {
1425                 LOG_INFOF("waypoint link save to %s failed", filename);
1426                 return;
1427         }
1428
1429         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1430         if (waypoint_time != "")
1431                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1432
1433         int c = 0;
1434         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP)),
1435         {
1436                 for(int j = 0; j < 32; ++j)
1437                 {
1438                         entity link = waypoint_get_link(it, j);
1439                         if(link)
1440                         {
1441                                 // NOTE: vtos rounds vector components to 1 decimal place
1442                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1443                                 fputs(file, s);
1444                                 ++c;
1445                         }
1446                 }
1447         });
1448         fclose(file);
1449
1450         botframe_cachedwaypointlinks = true;
1451
1452         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1453
1454         waypoint_load_links_hardwired();
1455 }
1456
1457 // save waypoints to gamedir/data/maps/mapname.waypoints
1458 void waypoint_saveall()
1459 {
1460         if (WAYPOINT_VERSION < waypoint_version_loaded)
1461         {
1462                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1463                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1464                 return;
1465         }
1466         string gt_ext = GET_GAMETYPE_EXTENSION();
1467
1468         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1469         int file = fopen(filename, FILE_WRITE);
1470         if (file < 0)
1471         {
1472                 waypoint_save_links(); // save anyway?
1473                 botframe_loadedforcedlinks = false;
1474
1475                 LOG_INFOF("waypoint links: save to %s failed", filename);
1476                 return;
1477         }
1478
1479         float sym = autocvar_g_waypointeditor_symmetrical;
1480         string sym_str = ftos(sym);
1481         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1482         {
1483                 if (sym == 1)
1484                 {
1485                         sym_str = cons(sym_str, "-");
1486                         sym_str = cons(sym_str, "-");
1487                 }
1488                 else
1489                 {
1490                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1491                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1492                 }
1493                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1494                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1495         }
1496         else if (autocvar_g_waypointeditor_symmetrical == -2)
1497         {
1498                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1499                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1500         }
1501
1502         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1503         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1504         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1505         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1506
1507         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1508         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1509         //fputs(file, strcat("//", "\n"));
1510         //fputs(file, strcat("//", "\n"));
1511         //fputs(file, strcat("//", "\n"));
1512
1513         int c = 0;
1514         IL_EACH(g_waypoints, true,
1515         {
1516                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1517                         continue;
1518
1519                 string s;
1520                 // NOTE: vtos rounds vector components to 1 decimal place
1521                 s = strcat(vtos(it.origin + it.mins), "\n");
1522                 s = strcat(s, vtos(it.origin + it.maxs));
1523                 s = strcat(s, "\n");
1524                 s = strcat(s, ftos(it.wpflags));
1525                 s = strcat(s, "\n");
1526                 fputs(file, s);
1527                 c++;
1528         });
1529         fclose(file);
1530         waypoint_save_links();
1531         waypoint_save_links_hardwired();
1532
1533         botframe_loadedforcedlinks = false;
1534
1535         waypoint_version_loaded = WAYPOINT_VERSION;
1536         LOG_INFOF("saved %d waypoints to %s", c, filename);
1537 }
1538
1539 // load waypoints from file
1540 float waypoint_loadall()
1541 {
1542         string s;
1543         float file, cwp, cwb, fl;
1544         vector m1, m2;
1545         cwp = 0;
1546         cwb = 0;
1547
1548         string gt_ext = GET_GAMETYPE_EXTENSION();
1549
1550         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1551         file = fopen(filename, FILE_READ);
1552
1553         if (gt_ext != "" && file < 0)
1554         {
1555                 // if race waypoint file doesn't exist load the default one
1556                 filename = sprintf("maps/%s.waypoints", mapname);
1557                 file = fopen(filename, FILE_READ);
1558         }
1559
1560         if (file < 0)
1561         {
1562                 LOG_TRACE("waypoint load from ", filename, " failed");
1563                 return 0;
1564         }
1565
1566         bool parse_comments = true;
1567         float ver = 0;
1568         float sym = 0;
1569         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1570
1571         while ((s = fgets(file)))
1572         {
1573                 if(parse_comments)
1574                 {
1575                         if(substring(s, 0, 2) == "//")
1576                         {
1577                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1578                                         ver = stof(substring(s, 19, -1));
1579                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1580                                 {
1581                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1582                                         if (tokens) { sym = stof(argv(0)); }
1583                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1584                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1585                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1586                                 }
1587                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1588                                         strcpy(waypoint_time, substring(s, 16, -1));
1589                                 continue;
1590                         }
1591                         else
1592                         {
1593                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1594                                 {
1595                                         LOG_TRACE("waypoints for this map are outdated");
1596                                         LOG_TRACE("please update them in the editor");
1597                                 }
1598                                 parse_comments = false;
1599                         }
1600                 }
1601                 m1 = stov(s);
1602                 s = fgets(file);
1603                 if (!s)
1604                         break;
1605                 m2 = stov(s);
1606                 s = fgets(file);
1607                 if (!s)
1608                         break;
1609                 fl = stof(s);
1610                 waypoint_spawn(m1, m2, fl);
1611                 if (m1 == m2)
1612                         cwp = cwp + 1;
1613                 else
1614                         cwb = cwb + 1;
1615         }
1616         fclose(file);
1617         waypoint_version_loaded = ver;
1618         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1619
1620         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1621         {
1622                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1623                 if (sym == 1 && sym_param3 < 2)
1624                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1625                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1626                 {
1627                         string params;
1628                         if (sym == 1)
1629                                 params = cons("-", "-");
1630                         else
1631                         {
1632                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1633                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1634                         }
1635                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1636                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1637                 }
1638                 else if (sym == -2)
1639                 {
1640                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1641                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1642                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1643                 }
1644                 else
1645                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1646                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1647         }
1648
1649         if (WAYPOINT_VERSION < waypoint_version_loaded)
1650                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1651                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1652
1653         return cwp + cwb;
1654 }
1655
1656 #define waypoint_fixorigin(position, tracetest_ent) \
1657         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1658
1659 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1660 {
1661         vector endpos = position + down_dir * 3000;
1662         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1663         if(trace_startsolid)
1664                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1665         if(trace_startsolid)
1666                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1667         if(trace_fraction < 1)
1668                 position = trace_endpos;
1669         return position;
1670 }
1671
1672 void waypoint_spawnforitem_force(entity e, vector org)
1673 {
1674         // Fix the waypoint altitude if necessary
1675         org = waypoint_fixorigin(org, NULL);
1676
1677         // don't spawn an item spawnfunc_waypoint if it already exists
1678         IL_EACH(g_waypoints, true,
1679         {
1680                 if(it.wpisbox)
1681                 {
1682                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1683                         {
1684                                 e.nearestwaypoint = it;
1685                                 return;
1686                         }
1687                 }
1688                 else
1689                 {
1690                         if(vdist(it.origin - org, <, 16))
1691                         {
1692                                 e.nearestwaypoint = it;
1693                                 return;
1694                         }
1695                 }
1696         });
1697
1698         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1699 }
1700
1701 void waypoint_spawnforitem(entity e)
1702 {
1703         if(!bot_waypoints_for_items)
1704                 return;
1705
1706         waypoint_spawnforitem_force(e, e.origin);
1707 }
1708
1709 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1710 {
1711         entity w;
1712         entity dw;
1713         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1714         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1715         // one way link to the destination
1716         w.wp00_original = dw;
1717         w.wp00 = dw;
1718         w.wp00mincost = timetaken; // this is just for jump pads
1719         // the teleporter's nearest spawnfunc_waypoint is this one
1720         // (teleporters are not goals, so this is probably useless)
1721         e.nearestwaypoint = w;
1722         e.nearestwaypointtimeout = -1;
1723 }
1724
1725 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1726 {
1727         float src_angle = e.warpzone_angles.x;
1728         while (src_angle < -180) src_angle += 360;
1729         while (src_angle > 180) src_angle -= 360;
1730
1731         float dest_angle = e.enemy.warpzone_angles.x;
1732         while (dest_angle < -180) dest_angle += 360;
1733         while (dest_angle > 180) dest_angle -= 360;
1734
1735         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1736         if (src_angle == -90 || dest_angle == -90)
1737                 return;
1738
1739         makevectors(e.warpzone_angles);
1740         vector src = (e.absmin + e.absmax) * 0.5;
1741         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1742         vector down_dir_src = -v_up;
1743
1744         makevectors(e.enemy.warpzone_angles);
1745         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1746         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1747         vector down_dir_dest = -v_up;
1748
1749         int extra_flag = 0;
1750         // don't snap to the ground waypoints for source warpzones pointing downwards
1751         if (src_angle != 90)
1752         {
1753                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1754                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1755                 // oblique warpzones need a jump otherwise bots gets stuck
1756                 if (src_angle != 0)
1757                         extra_flag = WAYPOINTFLAG_JUMP;
1758         }
1759
1760         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1761 }
1762
1763 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1764 {
1765         destination = waypoint_fixorigin(destination, tracetest_ent);
1766         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1767 }
1768
1769 entity waypoint_spawnpersonal(entity this, vector position)
1770 {
1771         entity w;
1772
1773         // drop the waypoint to a proper location:
1774         //   first move it up by a player height
1775         //   then move it down to hit the floor with player bbox size
1776         position = waypoint_fixorigin(position, this);
1777
1778         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1779         w.nearestwaypoint = NULL;
1780         w.nearestwaypointtimeout = 0;
1781         w.owner = this;
1782
1783         waypoint_schedulerelink(w);
1784
1785         return w;
1786 }
1787
1788 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1789 {
1790         if (!(wp1 && wp2))
1791                 return;
1792
1793         if (wp1.wphardwired && wp2.wphardwired)
1794                 te_beam(NULL, wp1.origin, wp2.origin);
1795         else if (display_type == 1)
1796                 te_lightning2(NULL, wp1.origin, wp2.origin);
1797 }
1798
1799 void waypoint_showlinks_to(entity wp, int display_type)
1800 {
1801         IL_EACH(g_waypoints, it != wp,
1802         {
1803                 if (waypoint_islinked(it, wp))
1804                         waypoint_showlink(it, wp, display_type);
1805         });
1806 }
1807
1808 void waypoint_showlinks_from(entity wp, int display_type)
1809 {
1810         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1811         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1812         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1813         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1814         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1815         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1816         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1817         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1818         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1819         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1820         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1821         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1822         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1823         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1824         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1825         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1826 }
1827
1828 void crosshair_trace_waypoints(entity pl)
1829 {
1830         IL_EACH(g_waypoints, true, {
1831                 it.solid = SOLID_BSP;
1832                 if (!it.wpisbox)
1833                         setsize(it, '-16 -16 -16', '16 16 16');
1834         });
1835
1836         crosshair_trace(pl);
1837
1838         IL_EACH(g_waypoints, true, {
1839                 it.solid = SOLID_TRIGGER;
1840                 if (!it.wpisbox)
1841                         setsize(it, '0 0 0', '0 0 0');
1842         });
1843         if (trace_ent.classname != "waypoint")
1844                 trace_ent = NULL;
1845 }
1846
1847 void botframe_showwaypointlinks()
1848 {
1849         if (time < botframe_waypointeditorlightningtime)
1850                 return;
1851         botframe_waypointeditorlightningtime = time + 0.5;
1852         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1853         {
1854                 int display_type = 0;
1855                 if (wasfreed(it.wp_aimed))
1856                         it.wp_aimed = NULL;
1857                 if (wasfreed(it.wp_locked))
1858                         it.wp_locked = NULL;
1859                 if (PHYS_INPUT_BUTTON_USE(it))
1860                         it.wp_locked = it.wp_aimed;
1861                 entity head = it.wp_locked;
1862                 if (!head)
1863                         head = navigation_findnearestwaypoint(it, false);
1864                 it.nearestwaypoint = head; // mainly useful for debug
1865                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1866                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1867                         display_type = 1; // default
1868                 else if(head && (head.wphardwired))
1869                         display_type = 2; // only hardwired
1870
1871                 if (display_type)
1872                 {
1873                         //navigation_testtracewalk = true;
1874                         //print("currently selected WP is ", etos(head), "\n");
1875                         //navigation_testtracewalk = false;
1876                         if (head)
1877                         {
1878                                 te_lightning2(NULL, head.origin, it.origin);
1879                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1880                                         waypoint_showlinks_to(head, display_type);
1881                                 else
1882                                         waypoint_showlinks_from(head, display_type);
1883                         }
1884                 }
1885                 string str;
1886                 entity wp = NULL;
1887                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
1888                 {
1889                         crosshair_trace_waypoints(it);
1890                         if (trace_ent)
1891                         {
1892                                 wp = trace_ent;
1893                                 if (wp != it.wp_aimed)
1894                                 {
1895                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: '%s'\n", etof(wp), wp.wpflags, vtos(wp.origin));
1896                                         if (wp.wpisbox)
1897                                                 str = strcat(str, sprintf("echo \" absmin: '%s', absmax: '%s'\"\n", vtos(wp.absmin), vtos(wp.absmax)));
1898                                         stuffcmd(it, str);
1899                                         str = sprintf("entity: %d\nflags: %d\norigin: \'%s\'", etof(wp), wp.wpflags, vtos(wp.origin));
1900                                         if (wp.wpisbox)
1901                                                 str = strcat(str, sprintf(" \nabsmin: '%s'\nabsmax: '%s'", vtos(wp.absmin), vtos(wp.absmax)));
1902                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
1903                                 }
1904                         }
1905                 }
1906                 if (it.wp_aimed != wp)
1907                         it.wp_aimed = wp;
1908         });
1909 }
1910
1911 float botframe_autowaypoints_fixdown(vector v)
1912 {
1913         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1914         if(trace_fraction >= 1)
1915                 return 0;
1916         return 1;
1917 }
1918
1919 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1920 {
1921         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1922         {
1923                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1924                 return 0;
1925         });
1926
1927         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1928         return 1;
1929 }
1930
1931 // return value:
1932 //    1 = WP created
1933 //    0 = no action needed
1934 //   -1 = temp fail, try from world too
1935 //   -2 = permanent fail, do not retry
1936 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1937 {
1938         // make it possible to go from p to wp, if we can
1939         // if wp is NULL, nearest is chosen
1940
1941         entity w;
1942         vector porg;
1943         float t, tmin, tmax;
1944         vector o;
1945         vector save;
1946
1947         if(!botframe_autowaypoints_fixdown(p.origin))
1948                 return -2;
1949         porg = trace_endpos;
1950
1951         if(wp)
1952         {
1953                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1954
1955                 // if wp -> porg, then OK
1956                 float maxdist;
1957                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1958                 {
1959                         // we may find a better one
1960                         maxdist = vlen(wp.origin - porg);
1961                 }
1962                 else
1963                 {
1964                         // accept any "good"
1965                         maxdist = 2100;
1966                 }
1967
1968                 float bestdist = maxdist;
1969                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1970                 {
1971                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1972                         if(d < bestdist)
1973                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1974                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1975                         {
1976                                 bestdist = d;
1977                                 p.(fld) = it;
1978                         }
1979                 });
1980                 if(bestdist < maxdist)
1981                 {
1982                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1983                         return 0;
1984                 }
1985
1986                 if(bestdist < 2100)
1987                 {
1988                         // we know maxdist < 2100
1989                         // so wp -> porg is still valid
1990                         // all is good
1991                         p.(fld) = wp;
1992                         return 0;
1993                 }
1994
1995                 // otherwise, no existing WP can fix our issues
1996         }
1997         else
1998         {
1999                 save = p.origin;
2000                 setorigin(p, porg);
2001                 w = navigation_findnearestwaypoint(p, walkfromwp);
2002                 setorigin(p, save);
2003                 if(w)
2004                 {
2005                         p.(fld) = w;
2006                         return 0;
2007                 }
2008         }
2009
2010         tmin = 0;
2011         tmax = 1;
2012         for (;;)
2013         {
2014                 if(tmax - tmin < 0.001)
2015                 {
2016                         // did not get a good candidate
2017                         return -1;
2018                 }
2019
2020                 t = (tmin + tmax) * 0.5;
2021                 o = antilag_takebackorigin(p, CS(p), time - t);
2022                 if(!botframe_autowaypoints_fixdown(o))
2023                         return -2;
2024                 o = trace_endpos;
2025
2026                 if(wp)
2027                 {
2028                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2029                         {
2030                                 // we cannot walk from wp.origin to o
2031                                 // get closer to tmax
2032                                 tmin = t;
2033                                 continue;
2034                         }
2035                 }
2036                 else
2037                 {
2038                         save = p.origin;
2039                         setorigin(p, o);
2040                         w = navigation_findnearestwaypoint(p, walkfromwp);
2041                         setorigin(p, save);
2042                         if(!w)
2043                         {
2044                                 // we cannot walk from any WP to o
2045                                 // get closer to tmax
2046                                 tmin = t;
2047                                 continue;
2048                         }
2049                 }
2050
2051                 // if we get here, o is valid regarding waypoints
2052                 // check if o is connected right to the player
2053                 // we break if it succeeds, as that means o is a good waypoint location
2054                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2055                         break;
2056
2057                 // o is no good, we need to get closer to the player
2058                 tmax = t;
2059         }
2060
2061         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2062         botframe_autowaypoints_createwp(o, p, fld, 0);
2063         return 1;
2064 }
2065
2066 // automatically create missing waypoints
2067 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
2068 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2069 {
2070         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2071         if(r != -1)
2072                 return;
2073         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2074         if(r != -1)
2075                 return;
2076
2077         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2078         if(!botframe_autowaypoints_fixdown(p.origin))
2079                 return; // shouldn't happen, caught above
2080         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2081 }
2082
2083 void botframe_deleteuselesswaypoints()
2084 {
2085         IL_EACH(g_items, it.bot_pickup,
2086         {
2087                 // NOTE: this protects waypoints if they're the ONLY nearest
2088                 // waypoint. That's the intention.
2089                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2090                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2091         });
2092         IL_EACH(g_waypoints, true,
2093         {
2094                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2095                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2096                 // WP is useful if:
2097                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2098                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2099                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2100                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2101                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2102                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2103                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2104                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2105                 // b) WP is closest WP for an item/spawnpoint/other entity
2106                 //    This has been done above by protecting these WPs.
2107         });
2108         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2109         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2110         {
2111                 for (int m = 0; m < 32; ++m)
2112                 {
2113                         entity w = waypoint_get_link(it, m);
2114                         if (!w)
2115                                 break;
2116                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2117                                 continue;
2118                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2119                                 continue;
2120                         for (int j = 0; j < 32; ++j)
2121                         {
2122                                 entity w2 = waypoint_get_link(w, j);
2123                                 if (!w2)
2124                                         break;
2125                                 if (it == w2)
2126                                         continue;
2127                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2128                                         continue;
2129                                 // If we got here, it != w2 exist with it -> w
2130                                 // and w -> w2. That means the waypoint is not
2131                                 // a dead end.
2132                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2133                                 for (int k = 0; k < 32; ++k)
2134                                 {
2135                                         if (waypoint_get_link(it, k) == w2)
2136                                                 continue;
2137                                         // IF WE GET HERE, w is proven useful
2138                                         // to get from it to w2!
2139                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2140                                         goto next;
2141                                 }
2142                         }
2143 LABEL(next)
2144                 }
2145         });
2146         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2147         //     they are needed to complete routes while autowaypointing.
2148
2149         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2150         {
2151                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2152                 te_explosion(it.origin);
2153                 waypoint_remove(it);
2154                 break;
2155         });
2156
2157         IL_EACH(g_waypoints, true,
2158         {
2159                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2160         });
2161 }
2162
2163 void botframe_autowaypoints()
2164 {
2165         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2166                 // going back is broken, so only fix waypoints to walk TO the player
2167                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2168                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2169                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2170         });
2171
2172         if (autocvar_g_waypointeditor_auto >= 2) {
2173                 botframe_deleteuselesswaypoints();
2174         }
2175 }
2176