qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14
  15 #include <lib/warpzone/common.qh>
  16 #include <lib/warpzone/util_server.qh>
  17
  18 void waypoint_setupmodel(entity wp)
  19 {
  20         if (autocvar_g_waypointeditor)
  21         {
  22                 // TODO: add some sort of visible box in edit mode for box waypoints
  23                 vector m1 = wp.mins;
  24                 vector m2 = wp.maxs;
  25                 setmodel(wp, MDL_WAYPOINT);
  26                 setsize(wp, m1, m2);
  27                 wp.effects = EF_LOWPRECISION;
  28                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
  29                         wp.colormod = '1 0 0';
  30                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
  31                         wp.colormod = '1 1 0';
  32                 else
  33                         wp.colormod = '1 1 1';
  34         }
  35         else
  36                 wp.model = "";
  37 }
  38
  39 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
  40 // them back to it as well
  41 // (suitable for spawnfunc_waypoint editor)
  42 entity waypoint_spawn(vector m1, vector m2, float f)
  43 {
  44         if(!(f & WAYPOINTFLAG_PERSONAL))
  45         {
  46                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
  47                 {
  48                         return it;
  49                 });
  50         }
  51
  52         entity w = new(waypoint);
  53         IL_PUSH(g_waypoints, w);
  54         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  55         w.wpflags = f;
  56         w.solid = SOLID_TRIGGER;
  57         setorigin(w, (m1 + m2) * 0.5);
  58         setsize(w, m1 - w.origin, m2 - w.origin);
  59         if (w.size)
  60                 w.wpisbox = true;
  61
  62         if(!w.wpisbox)
  63         {
  64                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
  65                 if(!move_out_of_solid(w))
  66                 {
  67                         if(!(f & WAYPOINTFLAG_GENERATED))
  68                         {
  69                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
  70                                 delete(w);
  71                                 return NULL;
  72                         }
  73                         else
  74                         {
  75                                 if(autocvar_developer)
  76                                 {
  77                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  78                                         backtrace("Waypoint stuck");
  79                                 }
  80                         }
  81                 }
  82                 setsize(w, '0 0 0', '0 0 0');
  83         }
  84
  85         waypoint_clearlinks(w);
  86         //waypoint_schedulerelink(w);
  87
  88         waypoint_setupmodel(w);
  89
  90         return w;
  91 }
  92
  93 bool waypoint_islinked(entity from, entity to)
  94 {
  95         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
  96         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
  97         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
  98         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
  99         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 100         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 101         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 102         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 103         return false;
 104 }
 105
 106 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 107 void waypoint_addlink(entity from, entity to)
 108 {
 109         float c;
 110
 111         if (from == to)
 112                 return;
 113         if (from.wpflags & WAYPOINTFLAG_NORELINK)
 114                 return;
 115
 116         if (waypoint_islinked(from, to))
 117                 return;
 118
 119         if (to.wpisbox || from.wpisbox)
 120         {
 121                 // if either is a box we have to find the nearest points on them to
 122                 // calculate the distance properly
 123                 vector v1, v2, m1, m2;
 124                 v1 = from.origin;
 125                 m1 = to.absmin;
 126                 m2 = to.absmax;
 127                 v1_x = bound(m1_x, v1_x, m2_x);
 128                 v1_y = bound(m1_y, v1_y, m2_y);
 129                 v1_z = bound(m1_z, v1_z, m2_z);
 130                 v2 = to.origin;
 131                 m1 = from.absmin;
 132                 m2 = from.absmax;
 133                 v2_x = bound(m1_x, v2_x, m2_x);
 134                 v2_y = bound(m1_y, v2_y, m2_y);
 135                 v2_z = bound(m1_z, v2_z, m2_z);
 136                 v2 = to.origin;
 137                 c = vlen(v2 - v1);
 138         }
 139         else
 140                 c = vlen(to.origin - from.origin);
 141
 142         if (from.wp31mincost < c) return;
 143         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 144         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 145         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 146         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 147         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 148         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 149         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 150         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 151         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 152         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 153         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 154         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 155         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 156         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 157         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 158         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 159         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 160         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 161         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 162         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 163         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 164         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 165         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 166         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 167         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 168         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 169         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 170         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 171         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 172         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 173         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 174         from.wp00 = to;from.wp00mincost = c;return;
 175 }
 176
 177 // relink this spawnfunc_waypoint
 178 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 179 // (SLOW!)
 180 void waypoint_think(entity this)
 181 {
 182         vector sv, sm1, sm2, ev, em1, em2, dv;
 183
 184         bot_calculate_stepheightvec();
 185
 186         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 187
 188         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 189         sm1 = this.origin + this.mins;
 190         sm2 = this.origin + this.maxs;
 191         IL_EACH(g_waypoints, true,
 192         {
 193                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 194                 {
 195                         waypoint_addlink(this, it);
 196                         waypoint_addlink(it, this);
 197                 }
 198                 else
 199                 {
 200                         ++relink_total;
 201                         if(!checkpvs(this.origin, it))
 202                         {
 203                                 ++relink_pvsculled;
 204                                 continue;
 205                         }
 206                         sv = it.origin;
 207                         sv.x = bound(sm1_x, sv.x, sm2_x);
 208                         sv.y = bound(sm1_y, sv.y, sm2_y);
 209                         sv.z = bound(sm1_z, sv.z, sm2_z);
 210                         ev = this.origin;
 211                         em1 = it.origin + it.mins;
 212                         em2 = it.origin + it.maxs;
 213                         ev.x = bound(em1_x, ev.x, em2_x);
 214                         ev.y = bound(em1_y, ev.y, em2_y);
 215                         ev.z = bound(em1_z, ev.z, em2_z);
 216                         dv = ev - sv;
 217                         dv.z = 0;
 218                         if(vdist(dv, >=, 1050)) // max search distance in XY
 219                         {
 220                                 ++relink_lengthculled;
 221                                 continue;
 222                         }
 223                         navigation_testtracewalk = 0;
 224                         if (!this.wpisbox)
 225                         {
 226                                 tracebox(sv - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, sv, false, this);
 227                                 if (!trace_startsolid)
 228                                 {
 229                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 230                                         sv = trace_endpos + '0 0 1';
 231                                 }
 232                         }
 233                         if (!it.wpisbox)
 234                         {
 235                                 tracebox(ev - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, ev, false, it);
 236                                 if (!trace_startsolid)
 237                                 {
 238                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 239                                         ev = trace_endpos + '0 0 1';
 240                                 }
 241                         }
 242                         //traceline(this.origin, it.origin, false, NULL);
 243                         //if (trace_fraction == 1)
 244                         if (!this.wpisbox && tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev, MOVE_NOMONSTERS))
 245                                 waypoint_addlink(this, it);
 246                         else
 247                                 relink_walkculled += 0.5;
 248                         if (!it.wpisbox && tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv, MOVE_NOMONSTERS))
 249                                 waypoint_addlink(it, this);
 250                         else
 251                                 relink_walkculled += 0.5;
 252                 }
 253         });
 254         navigation_testtracewalk = 0;
 255         this.wplinked = true;
 256 }
 257
 258 void waypoint_clearlinks(entity wp)
 259 {
 260         // clear links to other waypoints
 261         float f = 10000000;
 262         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 263         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 264         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 265         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 266
 267         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 268         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 269         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 270         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 271
 272         wp.wplinked = false;
 273 }
 274
 275 // tell a spawnfunc_waypoint to relink
 276 void waypoint_schedulerelink(entity wp)
 277 {
 278         if (wp == NULL)
 279                 return;
 280
 281         waypoint_setupmodel(wp);
 282         wp.wpisbox = vdist(wp.size, >, 0);
 283         wp.enemy = NULL;
 284         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 285                 wp.owner = NULL;
 286         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 287                 waypoint_clearlinks(wp);
 288         // schedule an actual relink on next frame
 289         setthink(wp, waypoint_think);
 290         wp.nextthink = time;
 291         wp.effects = EF_LOWPRECISION;
 292 }
 293
 294 // spawnfunc_waypoint map entity
 295 spawnfunc(waypoint)
 296 {
 297         IL_PUSH(g_waypoints, this);
 298
 299         setorigin(this, this.origin);
 300         // schedule a relink after other waypoints have had a chance to spawn
 301         waypoint_clearlinks(this);
 302         //waypoint_schedulerelink(this);
 303 }
 304
 305 void waypoint_remove(entity wp)
 306 {
 307         // tell all waypoints linked to wp that they need to relink
 308         IL_EACH(g_waypoints, it != wp,
 309         {
 310                 if (waypoint_islinked(it, wp))
 311                         waypoint_schedulerelink(it);
 312         });
 313         delete(wp);
 314 }
 315
 316 void waypoint_removeall()
 317 {
 318         IL_EACH(g_waypoints, true,
 319         {
 320                 delete(it);
 321         });
 322 }
 323
 324 // tell all waypoints to relink
 325 // actually this is useful only to update relink_* stats
 326 void waypoint_schedulerelinkall()
 327 {
 328         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 329         IL_EACH(g_waypoints, true,
 330         {
 331                 waypoint_schedulerelink(it);
 332         });
 333         waypoint_load_links_hardwired();
 334 }
 335
 336 // Load waypoint links from file
 337 float waypoint_load_links()
 338 {
 339         string filename, s;
 340         float file, tokens, c = 0, found;
 341         entity wp_from = NULL, wp_to;
 342         vector wp_to_pos, wp_from_pos;
 343         filename = strcat("maps/", mapname);
 344         filename = strcat(filename, ".waypoints.cache");
 345         file = fopen(filename, FILE_READ);
 346
 347         if (file < 0)
 348         {
 349                 LOG_TRACE("waypoint links load from ");
 350                 LOG_TRACE(filename);
 351                 LOG_TRACE(" failed");
 352                 return false;
 353         }
 354
 355         while ((s = fgets(file)))
 356         {
 357                 tokens = tokenizebyseparator(s, "*");
 358
 359                 if (tokens!=2)
 360                 {
 361                         // bad file format
 362                         fclose(file);
 363                         return false;
 364                 }
 365
 366                 wp_from_pos     = stov(argv(0));
 367                 wp_to_pos       = stov(argv(1));
 368
 369                 // Search "from" waypoint
 370                 if(!wp_from || wp_from.origin!=wp_from_pos)
 371                 {
 372                         wp_from = findradius(wp_from_pos, 1);
 373                         found = false;
 374                         while(wp_from)
 375                         {
 376                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 377                                 if(wp_from.classname == "waypoint")
 378                                 {
 379                                         found = true;
 380                                         break;
 381                                 }
 382                                 wp_from = wp_from.chain;
 383                         }
 384
 385                         if(!found)
 386                         {
 387                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin));
 388                                 continue;
 389                         }
 390
 391                 }
 392
 393                 // Search "to" waypoint
 394                 wp_to = findradius(wp_to_pos, 1);
 395                 found = false;
 396                 while(wp_to)
 397                 {
 398                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 399                         if(wp_to.classname == "waypoint")
 400                         {
 401                                 found = true;
 402                                 break;
 403                         }
 404                         wp_to = wp_to.chain;
 405                 }
 406
 407                 if(!found)
 408                 {
 409                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin));
 410                         continue;
 411                 }
 412
 413                 ++c;
 414                 waypoint_addlink(wp_from, wp_to);
 415         }
 416
 417         fclose(file);
 418
 419         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 420
 421         botframe_cachedwaypointlinks = true;
 422         return true;
 423 }
 424
 425 void waypoint_load_links_hardwired()
 426 {
 427         string filename, s;
 428         float file, tokens, c = 0, found;
 429         entity wp_from = NULL, wp_to;
 430         vector wp_to_pos, wp_from_pos;
 431         filename = strcat("maps/", mapname);
 432         filename = strcat(filename, ".waypoints.hardwired");
 433         file = fopen(filename, FILE_READ);
 434
 435         botframe_loadedforcedlinks = true;
 436
 437         if (file < 0)
 438         {
 439                 LOG_TRACE("waypoint links load from ", filename, " failed");
 440                 return;
 441         }
 442
 443         while ((s = fgets(file)))
 444         {
 445                 if(substring(s, 0, 2)=="//")
 446                         continue;
 447
 448                 if(substring(s, 0, 1)=="#")
 449                         continue;
 450
 451                 tokens = tokenizebyseparator(s, "*");
 452
 453                 if (tokens!=2)
 454                         continue;
 455
 456                 wp_from_pos     = stov(argv(0));
 457                 wp_to_pos       = stov(argv(1));
 458
 459                 // Search "from" waypoint
 460                 if(!wp_from || wp_from.origin!=wp_from_pos)
 461                 {
 462                         wp_from = findradius(wp_from_pos, 5);
 463                         found = false;
 464                         while(wp_from)
 465                         {
 466                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 467                                 if(wp_from.classname == "waypoint")
 468                                 {
 469                                         found = true;
 470                                         break;
 471                                 }
 472                                 wp_from = wp_from.chain;
 473                         }
 474
 475                         if(!found)
 476                         {
 477                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 478                                 continue;
 479                         }
 480                 }
 481
 482                 // Search "to" waypoint
 483                 wp_to = findradius(wp_to_pos, 5);
 484                 found = false;
 485                 while(wp_to)
 486                 {
 487                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 488                         if(wp_to.classname == "waypoint")
 489                         {
 490                                 found = true;
 491                                 break;
 492                         }
 493                         wp_to = wp_to.chain;
 494                 }
 495
 496                 if(!found)
 497                 {
 498                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 499                         continue;
 500                 }
 501
 502                 ++c;
 503                 waypoint_addlink(wp_from, wp_to);
 504                 wp_from.wphardwired = true;
 505                 wp_to.wphardwired = true;
 506         }
 507
 508         fclose(file);
 509
 510         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 511 }
 512
 513 entity waypoint_get_link(entity w, float i)
 514 {
 515         switch(i)
 516         {
 517                 case  0:return w.wp00;
 518                 case  1:return w.wp01;
 519                 case  2:return w.wp02;
 520                 case  3:return w.wp03;
 521                 case  4:return w.wp04;
 522                 case  5:return w.wp05;
 523                 case  6:return w.wp06;
 524                 case  7:return w.wp07;
 525                 case  8:return w.wp08;
 526                 case  9:return w.wp09;
 527                 case 10:return w.wp10;
 528                 case 11:return w.wp11;
 529                 case 12:return w.wp12;
 530                 case 13:return w.wp13;
 531                 case 14:return w.wp14;
 532                 case 15:return w.wp15;
 533                 case 16:return w.wp16;
 534                 case 17:return w.wp17;
 535                 case 18:return w.wp18;
 536                 case 19:return w.wp19;
 537                 case 20:return w.wp20;
 538                 case 21:return w.wp21;
 539                 case 22:return w.wp22;
 540                 case 23:return w.wp23;
 541                 case 24:return w.wp24;
 542                 case 25:return w.wp25;
 543                 case 26:return w.wp26;
 544                 case 27:return w.wp27;
 545                 case 28:return w.wp28;
 546                 case 29:return w.wp29;
 547                 case 30:return w.wp30;
 548                 case 31:return w.wp31;
 549                 default:return NULL;
 550         }
 551 }
 552
 553 // Save all waypoint links to a file
 554 void waypoint_save_links()
 555 {
 556         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 557         int file = fopen(filename, FILE_WRITE);
 558         if (file < 0)
 559         {
 560                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 561                 return;
 562         }
 563
 564         int c = 0;
 565         IL_EACH(g_waypoints, true,
 566         {
 567                 for(int j = 0; j < 32; ++j)
 568                 {
 569                         entity link = waypoint_get_link(it, j);
 570                         if(link)
 571                         {
 572                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 573                                 fputs(file, s);
 574                                 ++c;
 575                         }
 576                 }
 577         });
 578         fclose(file);
 579         botframe_cachedwaypointlinks = true;
 580
 581         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 582 }
 583
 584 // save waypoints to gamedir/data/maps/mapname.waypoints
 585 void waypoint_saveall()
 586 {
 587         string filename = sprintf("maps/%s.waypoints", mapname);
 588         int file = fopen(filename, FILE_WRITE);
 589         if (file < 0)
 590         {
 591                 waypoint_save_links(); // save anyway?
 592                 botframe_loadedforcedlinks = false;
 593
 594                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 595                 return;
 596         }
 597
 598         int c = 0;
 599         IL_EACH(g_waypoints, true,
 600         {
 601                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 602                         continue;
 603
 604                 string s;
 605                 s = strcat(vtos(it.origin + it.mins), "\n");
 606                 s = strcat(s, vtos(it.origin + it.maxs));
 607                 s = strcat(s, "\n");
 608                 s = strcat(s, ftos(it.wpflags));
 609                 s = strcat(s, "\n");
 610                 fputs(file, s);
 611                 c++;
 612         });
 613         fclose(file);
 614         waypoint_save_links();
 615         botframe_loadedforcedlinks = false;
 616
 617         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 618 }
 619
 620 // load waypoints from file
 621 float waypoint_loadall()
 622 {
 623         string filename, s;
 624         float file, cwp, cwb, fl;
 625         vector m1, m2;
 626         cwp = 0;
 627         cwb = 0;
 628         filename = strcat("maps/", mapname);
 629         filename = strcat(filename, ".waypoints");
 630         file = fopen(filename, FILE_READ);
 631         if (file >= 0)
 632         {
 633                 while ((s = fgets(file)))
 634                 {
 635                         m1 = stov(s);
 636                         s = fgets(file);
 637                         if (!s)
 638                                 break;
 639                         m2 = stov(s);
 640                         s = fgets(file);
 641                         if (!s)
 642                                 break;
 643                         fl = stof(s);
 644                         waypoint_spawn(m1, m2, fl);
 645                         if (m1 == m2)
 646                                 cwp = cwp + 1;
 647                         else
 648                                 cwb = cwb + 1;
 649                 }
 650                 fclose(file);
 651                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
 652         }
 653         else
 654         {
 655                 LOG_TRACE("waypoint load from ", filename, " failed");
 656         }
 657         return cwp + cwb;
 658 }
 659
 660 vector waypoint_fixorigin(vector position)
 661 {
 662         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 663         if(trace_fraction < 1)
 664                 position = trace_endpos;
 665         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 666         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 667         return position;
 668 }
 669
 670 void waypoint_spawnforitem_force(entity e, vector org)
 671 {
 672         // Fix the waypoint altitude if necessary
 673         org = waypoint_fixorigin(org);
 674
 675         // don't spawn an item spawnfunc_waypoint if it already exists
 676         IL_EACH(g_waypoints, true,
 677         {
 678                 if(it.wpisbox)
 679                 {
 680                         if(boxesoverlap(org, org, it.absmin, it.absmax))
 681                         {
 682                                 e.nearestwaypoint = it;
 683                                 return;
 684                         }
 685                 }
 686                 else
 687                 {
 688                         if(vdist(it.origin - org, <, 16))
 689                         {
 690                                 e.nearestwaypoint = it;
 691                                 return;
 692                         }
 693                 }
 694         });
 695
 696         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 697 }
 698
 699 void waypoint_spawnforitem(entity e)
 700 {
 701         if(!bot_waypoints_for_items)
 702                 return;
 703
 704         waypoint_spawnforitem_force(e, e.origin);
 705 }
 706
 707 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 708 {
 709         entity w;
 710         entity dw;
 711         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 712         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 713         // one way link to the destination
 714         w.wp00 = dw;
 715         w.wp00mincost = timetaken; // this is just for jump pads
 716         // the teleporter's nearest spawnfunc_waypoint is this one
 717         // (teleporters are not goals, so this is probably useless)
 718         e.nearestwaypoint = w;
 719         e.nearestwaypointtimeout = -1;
 720 }
 721
 722 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 723 {
 724         org = waypoint_fixorigin(org);
 725         destination = waypoint_fixorigin(destination);
 726         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 727 }
 728
 729 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 730 {
 731         destination = waypoint_fixorigin(destination);
 732         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 733 }
 734
 735 entity waypoint_spawnpersonal(entity this, vector position)
 736 {
 737         entity w;
 738
 739         // drop the waypoint to a proper location:
 740         //   first move it up by a player height
 741         //   then move it down to hit the floor with player bbox size
 742         position = waypoint_fixorigin(position);
 743
 744         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 745         w.nearestwaypoint = NULL;
 746         w.nearestwaypointtimeout = 0;
 747         w.owner = this;
 748
 749         waypoint_schedulerelink(w);
 750
 751         return w;
 752 }
 753
 754 void waypoint_showlink(entity wp1, entity wp2, int display_type)
 755 {
 756         if (!(wp1 && wp2))
 757                 return;
 758
 759         if (wp1.wphardwired && wp2.wphardwired)
 760                 te_beam(NULL, wp1.origin, wp2.origin);
 761         else if (display_type == 1)
 762                 te_lightning2(NULL, wp1.origin, wp2.origin);
 763 }
 764
 765 void botframe_showwaypointlinks()
 766 {
 767         if (time < botframe_waypointeditorlightningtime)
 768                 return;
 769         botframe_waypointeditorlightningtime = time + 0.5;
 770         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
 771         {
 772                 int display_type = 0;
 773                 entity head = navigation_findnearestwaypoint(it, false);
 774                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
 775                         display_type = 1; // default
 776                 else if(head && (head.wphardwired))
 777                         display_type = 2; // only hardwired
 778
 779                 if (display_type)
 780                 {
 781                         //navigation_testtracewalk = true;
 782                         //print("currently selected WP is ", etos(head), "\n");
 783                         //navigation_testtracewalk = false;
 784                         if (head)
 785                         {
 786                                 te_lightning2(NULL, head.origin, it.origin);
 787                                 waypoint_showlink(head.wp00, head, display_type);
 788                                 waypoint_showlink(head.wp01, head, display_type);
 789                                 waypoint_showlink(head.wp02, head, display_type);
 790                                 waypoint_showlink(head.wp03, head, display_type);
 791                                 waypoint_showlink(head.wp04, head, display_type);
 792                                 waypoint_showlink(head.wp05, head, display_type);
 793                                 waypoint_showlink(head.wp06, head, display_type);
 794                                 waypoint_showlink(head.wp07, head, display_type);
 795                                 waypoint_showlink(head.wp08, head, display_type);
 796                                 waypoint_showlink(head.wp09, head, display_type);
 797                                 waypoint_showlink(head.wp10, head, display_type);
 798                                 waypoint_showlink(head.wp11, head, display_type);
 799                                 waypoint_showlink(head.wp12, head, display_type);
 800                                 waypoint_showlink(head.wp13, head, display_type);
 801                                 waypoint_showlink(head.wp14, head, display_type);
 802                                 waypoint_showlink(head.wp15, head, display_type);
 803                                 waypoint_showlink(head.wp16, head, display_type);
 804                                 waypoint_showlink(head.wp17, head, display_type);
 805                                 waypoint_showlink(head.wp18, head, display_type);
 806                                 waypoint_showlink(head.wp19, head, display_type);
 807                                 waypoint_showlink(head.wp20, head, display_type);
 808                                 waypoint_showlink(head.wp21, head, display_type);
 809                                 waypoint_showlink(head.wp22, head, display_type);
 810                                 waypoint_showlink(head.wp23, head, display_type);
 811                                 waypoint_showlink(head.wp24, head, display_type);
 812                                 waypoint_showlink(head.wp25, head, display_type);
 813                                 waypoint_showlink(head.wp26, head, display_type);
 814                                 waypoint_showlink(head.wp27, head, display_type);
 815                                 waypoint_showlink(head.wp28, head, display_type);
 816                                 waypoint_showlink(head.wp29, head, display_type);
 817                                 waypoint_showlink(head.wp30, head, display_type);
 818                                 waypoint_showlink(head.wp31, head, display_type);
 819                         }
 820                 }
 821         });
 822 }
 823
 824 float botframe_autowaypoints_fixdown(vector v)
 825 {
 826         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
 827         if(trace_fraction >= 1)
 828                 return 0;
 829         return 1;
 830 }
 831
 832 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
 833 {
 834         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
 835         {
 836                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 837                 return 0;
 838         });
 839
 840         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
 841         return 1;
 842 }
 843
 844 // return value:
 845 //    1 = WP created
 846 //    0 = no action needed
 847 //   -1 = temp fail, try from world too
 848 //   -2 = permanent fail, do not retry
 849 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
 850 {
 851         // make it possible to go from p to wp, if we can
 852         // if wp is NULL, nearest is chosen
 853
 854         entity w;
 855         vector porg;
 856         float t, tmin, tmax;
 857         vector o;
 858         vector save;
 859
 860         if(!botframe_autowaypoints_fixdown(p.origin))
 861                 return -2;
 862         porg = trace_endpos;
 863
 864         if(wp)
 865         {
 866                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
 867
 868                 // if wp -> porg, then OK
 869                 float maxdist;
 870                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
 871                 {
 872                         // we may find a better one
 873                         maxdist = vlen(wp.origin - porg);
 874                 }
 875                 else
 876                 {
 877                         // accept any "good"
 878                         maxdist = 2100;
 879                 }
 880
 881                 float bestdist = maxdist;
 882                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
 883                 {
 884                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
 885                         if(d < bestdist)
 886                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, walkfromwp, 1050))
 887                         if(navigation_waypoint_will_link(it.origin, porg, p, walkfromwp, 1050))
 888                         {
 889                                 bestdist = d;
 890                                 p.(fld) = it;
 891                         }
 892                 });
 893                 if(bestdist < maxdist)
 894                 {
 895                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
 896                         return 0;
 897                 }
 898
 899                 if(bestdist < 2100)
 900                 {
 901                         // we know maxdist < 2100
 902                         // so wp -> porg is still valid
 903                         // all is good
 904                         p.(fld) = wp;
 905                         return 0;
 906                 }
 907
 908                 // otherwise, no existing WP can fix our issues
 909         }
 910         else
 911         {
 912                 save = p.origin;
 913                 setorigin(p, porg);
 914                 w = navigation_findnearestwaypoint(p, walkfromwp);
 915                 setorigin(p, save);
 916                 if(w)
 917                 {
 918                         p.(fld) = w;
 919                         return 0;
 920                 }
 921         }
 922
 923         tmin = 0;
 924         tmax = 1;
 925         for (;;)
 926         {
 927                 if(tmax - tmin < 0.001)
 928                 {
 929                         // did not get a good candidate
 930                         return -1;
 931                 }
 932
 933                 t = (tmin + tmax) * 0.5;
 934                 o = antilag_takebackorigin(p, CS(p), time - t);
 935                 if(!botframe_autowaypoints_fixdown(o))
 936                         return -2;
 937                 o = trace_endpos;
 938
 939                 if(wp)
 940                 {
 941                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
 942                         {
 943                                 // we cannot walk from wp.origin to o
 944                                 // get closer to tmax
 945                                 tmin = t;
 946                                 continue;
 947                         }
 948                 }
 949                 else
 950                 {
 951                         save = p.origin;
 952                         setorigin(p, o);
 953                         w = navigation_findnearestwaypoint(p, walkfromwp);
 954                         setorigin(p, save);
 955                         if(!w)
 956                         {
 957                                 // we cannot walk from any WP to o
 958                                 // get closer to tmax
 959                                 tmin = t;
 960                                 continue;
 961                         }
 962                 }
 963
 964                 // if we get here, o is valid regarding waypoints
 965                 // check if o is connected right to the player
 966                 // we break if it succeeds, as that means o is a good waypoint location
 967                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
 968                         break;
 969
 970                 // o is no good, we need to get closer to the player
 971                 tmax = t;
 972         }
 973
 974         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
 975         botframe_autowaypoints_createwp(o, p, fld, 0);
 976         return 1;
 977 }
 978
 979 // automatically create missing waypoints
 980 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
 981 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
 982 {
 983         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
 984         if(r != -1)
 985                 return;
 986         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
 987         if(r != -1)
 988                 return;
 989
 990         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
 991         if(!botframe_autowaypoints_fixdown(p.origin))
 992                 return; // shouldn't happen, caught above
 993         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
 994 }
 995
 996 void botframe_deleteuselesswaypoints()
 997 {
 998         IL_EACH(g_items, it.bot_pickup,
 999         {
1000                 // NOTE: this protects waypoints if they're the ONLY nearest
1001                 // waypoint. That's the intention.
1002                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1003                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1004         });
1005         IL_EACH(g_waypoints, true,
1006         {
1007                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1008                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1009                 // WP is useful if:
1010                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1011                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1012                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1013                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1014                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1015                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1016                 // b) WP is closest WP for an item/spawnpoint/other entity
1017                 //    This has been done above by protecting these WPs.
1018         });
1019         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1020         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1021         {
1022                 for (int m = 0; m < 32; ++m)
1023                 {
1024                         entity w = waypoint_get_link(it, m);
1025                         if (!w)
1026                                 break;
1027                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1028                                 continue;
1029                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1030                                 continue;
1031                         for (int j = 0; j < 32; ++j)
1032                         {
1033                                 entity w2 = waypoint_get_link(w, j);
1034                                 if (!w2)
1035                                         break;
1036                                 if (it == w2)
1037                                         continue;
1038                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1039                                         continue;
1040                                 // If we got here, it != w2 exist with it -> w
1041                                 // and w -> w2. That means the waypoint is not
1042                                 // a dead end.
1043                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1044                                 for (int k = 0; k < 32; ++k)
1045                                 {
1046                                         if (waypoint_get_link(it, k) == w2)
1047                                                 continue;
1048                                         // IF WE GET HERE, w is proven useful
1049                                         // to get from it to w2!
1050                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1051                                         goto next;
1052                                 }
1053                         }
1054 LABEL(next)
1055                 }
1056         });
1057         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1058         //     they are needed to complete routes while autowaypointing.
1059
1060         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1061         {
1062                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1063                 te_explosion(it.origin);
1064                 waypoint_remove(it);
1065                 break;
1066         });
1067
1068         IL_EACH(g_waypoints, true,
1069         {
1070                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1071         });
1072 }
1073
1074 void botframe_autowaypoints()
1075 {
1076         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1077                 // going back is broken, so only fix waypoints to walk TO the player
1078                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1079                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1080                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1081         ));
1082
1083         if (autocvar_g_waypointeditor_auto >= 2) {
1084                 botframe_deleteuselesswaypoints();
1085         }
1086 }
1087