qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/gamemodes/_mod.qh>
  17 #include <common/mapobjects/trigger/jumppads.qh>
  18 #include <common/net_linked.qh>
  19 #include <common/physics/player.qh>
  20
  21 #include <lib/warpzone/common.qh>
  22 #include <lib/warpzone/util_server.qh>
  23
  24 .entity spawnpointmodel;
  25 void waypoint_unreachable(entity pl)
  26 {
  27         IL_EACH(g_waypoints, true,
  28         {
  29                 it.colormod = '0.5 0.5 0.5';
  30                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  31         });
  32
  33         entity e2 = navigation_findnearestwaypoint(pl, false);
  34         if(!e2)
  35         {
  36                 LOG_INFO("Can't find any waypoint nearby\n");
  37                 return;
  38         }
  39
  40         navigation_markroutes(pl, e2);
  41
  42         int j = 0;
  43         int m = 0;
  44         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  45         {
  46                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  47                 it.colormod_z = 8;
  48                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  49                 j++;
  50                 m++;
  51         });
  52         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  53         navigation_markroutes_inverted(e2);
  54
  55         j = 0;
  56         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  57         {
  58                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  59                 it.colormod_x = 8;
  60                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  61                         m++;
  62                 it.effects |= EF_NODEPTHTEST | EF_RED;
  63                 j++;
  64         });
  65         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  66         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  67
  68         j = 0;
  69         IL_EACH(g_spawnpoints, true,
  70         {
  71                 if (navigation_findnearestwaypoint(it, false))
  72                 {
  73                         if(it.spawnpointmodel)
  74                         {
  75                                 delete(it.spawnpointmodel);
  76                                 it.spawnpointmodel = NULL;
  77                         }
  78                 }
  79                 else
  80                 {
  81                         if(!it.spawnpointmodel)
  82                         {
  83                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  84                                 entity e = new(spawnpointmodel);
  85                                 vector org = trace_endpos + eZ;
  86                                 setorigin(e, org);
  87                                 e.solid = SOLID_TRIGGER;
  88                                 it.spawnpointmodel = e;
  89                         }
  90                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  91                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  92                         _setmodel(it.spawnpointmodel, pl.model);
  93                         it.spawnpointmodel.frame = pl.frame;
  94                         it.spawnpointmodel.skin = pl.skin;
  95                         it.spawnpointmodel.colormap = pl.colormap;
  96                         it.spawnpointmodel.colormod = pl.colormod;
  97                         it.spawnpointmodel.glowmod = pl.glowmod;
  98                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  99                         j++;
 100                 }
 101         });
 102         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 103
 104         j = 0;
 105         IL_EACH(g_items, true,
 106         {
 107                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 108                 it.colormod = '0.5 0.5 0.5';
 109         });
 110         IL_EACH(g_items, true,
 111         {
 112                 if (navigation_findnearestwaypoint(it, false))
 113                         continue;
 114                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 115                 it.effects |= EF_NODEPTHTEST | EF_RED;
 116                 it.colormod_x = 8;
 117                 j++;
 118         });
 119         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 120
 121         j = 0;
 122         IL_EACH(g_items, true,
 123         {
 124                 if (navigation_findnearestwaypoint(it, true))
 125                         continue;
 126                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 127                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 128                 it.colormod_z = 8;
 129                 j++;
 130         });
 131         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 132 }
 133
 134 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 135 {
 136         vector v1 = stov(argv(arg_idx++));
 137         vector v2 = stov(argv(arg_idx++));
 138         vector mid = (v1 + v2) / 2;
 139
 140         float diffy = (v2.y - v1.y);
 141         float diffx = (v2.x - v1.x);
 142         if (v1.y == v2.y)
 143                 diffy = 0.000001;
 144         if (v1.x == v2.x)
 145                 diffx = 0.000001;
 146         float m = - diffx / diffy;
 147         float q = - m * mid.x + mid.y;
 148         if (fabs(m) <= 0.000001) m = 0;
 149         if (fabs(q) <= 0.000001) q = 0;
 150
 151         string axis_str =  strcat(ftos(m), " ", ftos(q));
 152         if (save)
 153                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 154         axis_str = strcat("\"", axis_str, "\"");
 155         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 156         if (save)
 157                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 158         if (save)
 159         {
 160                 cvar_set("g_waypointeditor_symmetrical", "-2");
 161                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 162                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 163         }
 164 }
 165
 166 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 167 {
 168         vector org = '0 0 0';
 169         int ctf_flags = 0;
 170         for (int i = 0; i < 6; i++)
 171         {
 172                 if (argv(arg_idx + i) != "")
 173                         ctf_flags++;
 174         }
 175         if (ctf_flags < 2)
 176         {
 177                 ctf_flags = 0;
 178                 org = vec2(havocbot_middlepoint);
 179                 if (argv(arg_idx) != "")
 180                         sprint(caller, "WARNING: Ignoring single input point\n");
 181                 if (havocbot_middlepoint_radius == 0)
 182                 {
 183                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 184                         return;
 185                 }
 186         }
 187         else
 188         {
 189                 vector v1, v2, v3, v4, v5, v6;
 190                 for (int i = 1; i <= ctf_flags; i++)
 191                 {
 192                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 193                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 194                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 195                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 196                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 197                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 198                 }
 199         }
 200
 201         if (fabs(org.x) <= 0.000001) org.x = 0;
 202         if (fabs(org.y) <= 0.000001) org.y = 0;
 203         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 204         if (save)
 205         {
 206                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 207                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 208         }
 209         org_str = strcat("\"", org_str, "\"");
 210
 211         if (ctf_flags < 2)
 212                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 213         else
 214                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 215         if (save)
 216                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 217
 218         if (ctf_flags < 2)
 219                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 220         else
 221                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 222         if (save)
 223                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 224
 225         if (save)
 226         {
 227                 if (ctf_flags < 2)
 228                         cvar_set("g_waypointeditor_symmetrical", "0");
 229                 else
 230                         cvar_set("g_waypointeditor_symmetrical", "-1");
 231                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 232                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 233         }
 234 }
 235
 236 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 237 {
 238         vector new_org = org;
 239         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 240         {
 241                 vector map_center = havocbot_middlepoint;
 242                 if (autocvar_g_waypointeditor_symmetrical == -1)
 243                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 244
 245                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 246         }
 247         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 248         {
 249                 float m = havocbot_symmetry_axis_m;
 250                 float q = havocbot_symmetry_axis_q;
 251                 if (autocvar_g_waypointeditor_symmetrical == -2)
 252                 {
 253                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 254                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 255                 }
 256
 257                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 258                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 259         }
 260         new_org.z = org.z;
 261         return new_org;
 262 }
 263
 264 void crosshair_trace_waypoints(entity pl);
 265 void waypoint_lock(entity pl)
 266 {
 267         crosshair_trace_waypoints(pl);
 268         pl.wp_locked = trace_ent;
 269 }
 270
 271 bool waypoint_has_hardwiredlinks(entity wp)
 272 {
 273         if (!wp)
 274                 return false;
 275         return (wp.wphw00 != NULL);
 276 }
 277
 278 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 279 {
 280         if (!(wp_from && wp_to))
 281                 return false;
 282
 283         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 284         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 285         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 286         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 287         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 288         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 289         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 290         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 291
 292         return false;
 293 }
 294
 295 void waypoint_setupmodel(entity wp);
 296 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 297 {
 298         if (!(wp_from && wp_to))
 299                 return;
 300
 301         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 302         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 303         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 304         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 305         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 306         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 307         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 308         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 309
 310         return;
 311 }
 312
 313 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 314 {
 315         if (!(wp_from && wp_to))
 316                 return;
 317
 318         int removed = -1;
 319         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 320         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 321         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 322         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 323         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 324         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 325         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 326         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 327
 328         if (removed >= 0)
 329         {
 330                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 331                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 332                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 333                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 334                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 335                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 336                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 337                 if (removed <= 7) wp_from.wphw07 = NULL;
 338                 if (!wp_from.wphw00)
 339                         waypoint_setupmodel(wp_from);
 340         }
 341
 342         return;
 343 }
 344
 345 void waypoint_restore_hardwiredlinks(entity wp)
 346 {
 347         if (wp.wphw00) waypoint_addlink(wp, wp.wphw00);
 348         if (wp.wphw01) waypoint_addlink(wp, wp.wphw01);
 349         if (wp.wphw02) waypoint_addlink(wp, wp.wphw02);
 350         if (wp.wphw03) waypoint_addlink(wp, wp.wphw03);
 351         if (wp.wphw04) waypoint_addlink(wp, wp.wphw04);
 352         if (wp.wphw05) waypoint_addlink(wp, wp.wphw05);
 353         if (wp.wphw06) waypoint_addlink(wp, wp.wphw06);
 354         if (wp.wphw07) waypoint_addlink(wp, wp.wphw07);
 355 }
 356
 357 void waypoint_setupmodel(entity wp)
 358 {
 359         if (autocvar_g_waypointeditor)
 360         {
 361                 // TODO: add some sort of visible box in edit mode for box waypoints
 362                 vector m1 = wp.mins;
 363                 vector m2 = wp.maxs;
 364                 setmodel(wp, MDL_WAYPOINT);
 365                 setsize(wp, m1, m2);
 366                 wp.effects = EF_LOWPRECISION;
 367                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 368                         wp.colormod = '1 0 0'; // red
 369                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 370                         wp.colormod = '1 1 0'; // yellow
 371                 else if (wp.wpflags & WAYPOINTFLAG_SUPPORT)
 372                         wp.colormod = '0 1 0'; // green
 373                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP)
 374                         wp.colormod = '1 0.5 0'; // orange
 375                 else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 376                         wp.colormod = '1 0.5 0'; // orange
 377                 else if (wp.wpflags & WAYPOINTFLAG_LADDER)
 378                         wp.colormod = '1 0.5 0'; // orange
 379                 else if (wp.wpflags & WAYPOINTFLAG_JUMP)
 380                         wp.colormod = '1 0.5 0'; // orange
 381                 else if (wp.wpflags & WAYPOINTFLAG_CROUCH)
 382                         wp.colormod = '0 1 1'; // cyan
 383                 else if (waypoint_has_hardwiredlinks(wp))
 384                         wp.colormod = '0.5 0 1'; // purple
 385                 else
 386                         wp.colormod = '1 1 1';
 387         }
 388         else
 389                 wp.model = "";
 390 }
 391
 392 string waypoint_get_type_name(entity wp)
 393 {
 394         if (wp.wpflags & WAYPOINTFLAG_ITEM) return "^1Item waypoint";
 395         else if (wp.wpflags & WAYPOINTFLAG_CROUCH) return "^5Crouch waypoint";
 396         else if (wp.wpflags & WAYPOINTFLAG_JUMP) return "^xf80Jump waypoint";
 397         else if (wp.wpflags & WAYPOINTFLAG_SUPPORT) return "^2Support waypoint";
 398         else if (waypoint_has_hardwiredlinks(wp)) return "^x80fHardwired waypoint";
 399         else if (wp.wpflags & WAYPOINTFLAG_LADDER) return "^3Ladder waypoint";
 400         else if (wp.wpflags & WAYPOINTFLAG_TELEPORT)
 401         {
 402                 if (!wp.wpisbox) return "^3Warpzone waypoint";
 403                 else if (wp.wpflags & WAYPOINTFLAG_CUSTOM_JP) return "^3Custom jumppad waypoint";
 404                 else
 405                 {
 406                         IL_EACH(g_jumppads, boxesoverlap(wp.absmin, wp.absmax, it.absmin, it.absmax),
 407                                 { return "^3Jumppad waypoint"; });
 408                         return "^3Teleport waypoint";
 409                 }
 410         }
 411
 412         return "^7Waypoint";
 413 }
 414
 415 entity waypoint_get(vector m1, vector m2)
 416 {
 417         if (m1 == m2)
 418         {
 419                 m1 -= '8 8 8';
 420                 m2 += '8 8 8';
 421         }
 422         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 423
 424         return NULL;
 425 }
 426
 427 .float createdtime;
 428 entity waypoint_spawn(vector m1, vector m2, float f)
 429 {
 430         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 431         {
 432                 entity wp_found = waypoint_get(m1, m2);
 433                 if (wp_found)
 434                         return wp_found;
 435         }
 436         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 437         // otherwise links loaded from file would be applied only to the first destination
 438         // waypoint since link format doesn't specify waypoint entities but just positions
 439         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WPFLAGMASK_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 440         {
 441                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 442                 {
 443                         return it;
 444                 });
 445         }
 446
 447         entity w = new(waypoint);
 448         IL_PUSH(g_waypoints, w);
 449         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 450         w.wpflags = f;
 451         w.solid = SOLID_TRIGGER;
 452         w.createdtime = time;
 453         setorigin(w, (m1 + m2) * 0.5);
 454         setsize(w, m1 - w.origin, m2 - w.origin);
 455         if (w.size)
 456                 w.wpisbox = true;
 457
 458         if(!w.wpisbox)
 459         {
 460                 if (f & WAYPOINTFLAG_CROUCH)
 461                         setsize(w, PL_CROUCH_MIN_CONST - '1 1 0', PL_CROUCH_MAX_CONST + '1 1 0');
 462                 else
 463                         setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 464                 if(!move_out_of_solid(w))
 465                 {
 466                         if(!(f & WAYPOINTFLAG_GENERATED))
 467                         {
 468                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 469                                 delete(w);
 470                                 return NULL;
 471                         }
 472                         else
 473                         {
 474                                 if(autocvar_developer > 0)
 475                                 {
 476                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 477                                         backtrace("Waypoint stuck");
 478                                 }
 479                         }
 480                 }
 481                 setsize(w, '0 0 0', '0 0 0');
 482         }
 483
 484         waypoint_clearlinks(w);
 485         //waypoint_schedulerelink(w);
 486
 487         waypoint_setupmodel(w);
 488
 489         return w;
 490 }
 491
 492 float trigger_push_get_push_time(entity this, vector endpos);
 493 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 494 {
 495         entity jp = NULL;
 496         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 497         {
 498                 jp = it;
 499                 break;
 500         });
 501         if (!jp)
 502                 return;
 503
 504         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 505         wp_from.wp00 = wp_to;
 506         wp_from.wp00mincost = cost;
 507         jp.nearestwaypoint = wp_from;
 508         jp.nearestwaypointtimeout = -1;
 509 }
 510
 511 bool start_wp_is_spawned;
 512 vector start_wp_origin;
 513 bool start_wp_is_hardwired;
 514 bool start_wp_is_support;
 515
 516 void waypoint_clear_start_wp_globals(entity pl, bool warn)
 517 {
 518         start_wp_is_spawned = false;
 519         start_wp_origin = '0 0 0';
 520         pl.wp_locked = NULL;
 521         start_wp_is_hardwired = false;
 522         start_wp_is_support = false;
 523         if (warn)
 524                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 525 }
 526
 527 void waypoint_start_hardwiredlink(entity pl, bool at_crosshair)
 528 {
 529         entity wp = pl.nearestwaypoint;
 530         if (at_crosshair)
 531         {
 532                 crosshair_trace_waypoints(pl);
 533                 wp = trace_ent;
 534         }
 535         string err = "";
 536         if (start_wp_is_spawned && !start_wp_is_hardwired)
 537                 err = "can't hardwire while in the process of creating a special link";
 538         else if (!wp)
 539         {
 540                 if (at_crosshair)
 541                         err = "couldn't find any waypoint at crosshair";
 542                 else
 543                         err = "couldn't find any waypoint nearby";
 544         }
 545         else if (wp.wpflags & WPFLAGMASK_NORELINK)
 546                 err = "can't hardwire a waypoint with special links";
 547
 548         if (err == "")
 549         {
 550                 start_wp_is_hardwired = true;
 551                 start_wp_is_spawned = true;
 552                 start_wp_origin = wp.origin;
 553                 pl.wp_locked = wp;
 554                 LOG_INFOF("^x80fWaypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 555         }
 556         else
 557         {
 558                 start_wp_is_hardwired = false;
 559                 LOG_INFO("Error: ", err, "\n");
 560         }
 561 }
 562
 563 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp, bool is_crouch_wp, bool is_support_wp)
 564 {
 565         if (WAYPOINT_VERSION < waypoint_version_loaded)
 566         {
 567                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 568                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 569                 return;
 570         }
 571
 572         entity e = NULL, jp = NULL;
 573         vector org = pl.origin;
 574         if (at_crosshair)
 575         {
 576                 crosshair_trace_waypoints(pl);
 577                 org = trace_endpos;
 578                 if (!trace_ent)
 579                         org.z -= PL_MIN_CONST.z;
 580                 if (!(start_wp_is_hardwired || start_wp_is_support))
 581                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 582                         {
 583                                 jp = it;
 584                                 break;
 585                         });
 586                 if (!jp && !start_wp_is_spawned && trace_ent)
 587                 {
 588                         if (trace_ent.wpflags & (WAYPOINTFLAG_JUMP))
 589                                 is_jump_wp = true;
 590                         else if (trace_ent.wpflags & (WAYPOINTFLAG_SUPPORT))
 591                                 is_support_wp = true;
 592                 }
 593         }
 594         if (jp || is_jump_wp || is_support_wp)
 595         {
 596                 if (start_wp_is_spawned)
 597                         start_wp_is_spawned = false;
 598                 LOG_INFO("^xf80Spawning start waypoint...\n");
 599         }
 600         int ctf_flags = havocbot_symmetry_origin_order;
 601         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 602                    || (autocvar_g_waypointeditor_symmetrical < 0));
 603         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 604                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 605         if (sym && ctf_flags < 2)
 606                 ctf_flags = 2;
 607         int wp_num = ctf_flags;
 608
 609         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp && !is_support_wp)
 610         {
 611                 // snap waypoint to item's origin if close enough
 612                 IL_EACH(g_items, true,
 613                 {
 614                         vector item_org = (it.absmin + it.absmax) * 0.5;
 615                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 616                         if (vlen(item_org - org) < 20)
 617                         {
 618                                 org = item_org;
 619                                 break;
 620                         }
 621                 });
 622         }
 623
 624         vector start_org = '0 0 0';
 625         if (start_wp_is_spawned)
 626         {
 627                 if (!start_wp_is_hardwired)
 628                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 629                 start_org = start_wp_origin;
 630         }
 631
 632         // save org as it can be modified spawning symmetrycal waypoints
 633         vector initial_origin = '0 0 0';
 634         bool initial_origin_is_set = false;
 635
 636         LABEL(add_wp);
 637
 638         if (jp)
 639         {
 640                 e = NULL;
 641                 IL_EACH(g_waypoints, (it.wpflags & WPFLAGMASK_NORELINK)
 642                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 643                 {
 644                         e = it; break;
 645                 });
 646                 if (!e)
 647                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT);
 648                 if (!pl.wp_locked)
 649                         pl.wp_locked = e;
 650         }
 651         else if (is_jump_wp || is_support_wp)
 652         {
 653                 int type_flag = (is_jump_wp) ? WAYPOINTFLAG_JUMP : WAYPOINTFLAG_SUPPORT;
 654
 655                 entity wp_found = waypoint_get(org, org);
 656                 if (wp_found && !(wp_found.wpflags & type_flag))
 657                 {
 658                         LOG_INFOF("Error: can't spawn a %s waypoint over an existent waypoint of a different type\n", (is_jump_wp) ? "Jump" : "Support");
 659                         return;
 660                 }
 661                 e = waypoint_spawn(org, org, type_flag);
 662                 if (!pl.wp_locked)
 663                         pl.wp_locked = e;
 664         }
 665         else
 666                 e = waypoint_spawn(org, org, (is_crouch_wp) ? WAYPOINTFLAG_CROUCH : 0);
 667         if(!e)
 668         {
 669                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 670                 if (start_wp_is_spawned)
 671                         waypoint_clear_start_wp_globals(pl, true);
 672                 return;
 673         }
 674
 675         if (!initial_origin_is_set)
 676         {
 677                 initial_origin = e.origin;
 678                 initial_origin_is_set = true;
 679         }
 680
 681         entity start_wp = NULL;
 682         if (start_wp_is_spawned)
 683         {
 684                 IL_EACH(g_waypoints, (start_wp_is_hardwired || (it.wpflags & WPFLAGMASK_NORELINK))
 685                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 686                 {
 687                         start_wp = it; break;
 688                 });
 689                 if(!start_wp)
 690                 {
 691                         // should not happen
 692                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 693                         waypoint_clear_start_wp_globals(pl, true);
 694                         return;
 695                 }
 696                 if (start_wp_is_hardwired)
 697                 {
 698                         if (waypoint_is_hardwiredlink(start_wp, e))
 699                         {
 700                                 waypoint_unmark_hardwiredlink(start_wp, e);
 701                                 waypoint_removelink(start_wp, e);
 702                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 703                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 704                         }
 705                         else
 706                         {
 707                                 if (e.createdtime == time)
 708                                 {
 709                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 710                                         waypoint_remove(e);
 711                                         waypoint_clear_start_wp_globals(pl, true);
 712                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp, is_crouch_wp, is_support_wp);
 713                                         return;
 714                                 }
 715                                 if (start_wp == e)
 716                                 {
 717                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 718                                         waypoint_clear_start_wp_globals(pl, true);
 719                                         return;
 720                                 }
 721                                 if (waypoint_islinked(start_wp, e))
 722                                 {
 723                                         LOG_INFO("Error: waypoints are already linked.\n");
 724                                         waypoint_clear_start_wp_globals(pl, true);
 725                                         return;
 726                                 }
 727                                 waypoint_addlink(start_wp, e);
 728                                 waypoint_mark_hardwiredlink(start_wp, e);
 729                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 730                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 731                         }
 732                 }
 733                 else
 734                 {
 735                         if (start_wp_is_support)
 736                         {
 737                                 if (e.SUPPORT_WP)
 738                                 {
 739                                         LOG_INFOF("Waypoint %v has already a support waypoint, delete it first.\n", e.origin);
 740                                         waypoint_clear_start_wp_globals(pl, true);
 741                                         return;
 742                                 }
 743                                 // clear all links to e
 744                                 IL_EACH(g_waypoints, it != e,
 745                                 {
 746                                         if (waypoint_islinked(it, e) && !waypoint_is_hardwiredlink(it, e))
 747                                                 waypoint_removelink(it, e);
 748                                 });
 749                         }
 750                         waypoint_addlink(start_wp, e);
 751                 }
 752         }
 753
 754         if (!(jp || is_jump_wp || is_support_wp || start_wp_is_hardwired))
 755                 waypoint_schedulerelink(e);
 756
 757         string wp_type_str = waypoint_get_type_name(e);
 758
 759         bprint(strcat(wp_type_str, "^7 spawned at ", vtos(e.origin), "\n"));
 760
 761         if (start_wp_is_spawned)
 762         {
 763                 pl.wp_locked = NULL;
 764                 if (!start_wp_is_hardwired)
 765                         waypoint_schedulerelink(start_wp);
 766                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 767                 {
 768                         if (start_wp.wp00_original == start_wp.wp00)
 769                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 770                         else
 771                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 772                 }
 773         }
 774
 775         if (sym)
 776         {
 777                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 778                 if (jp)
 779                 {
 780                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 781                         {
 782                                 jp = it; break;
 783                         });
 784                 }
 785                 if (start_wp_is_spawned)
 786                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 787                 if (vdist(org - pl.origin, >, 32))
 788                 {
 789                         if(wp_num > 2)
 790                                 wp_num--;
 791                         else
 792                                 sym = false;
 793                         goto add_wp;
 794                 }
 795         }
 796         if (jp || is_jump_wp || is_support_wp)
 797         {
 798                 if (!start_wp_is_spawned)
 799                 {
 800                         // we've just created a custom jumppad waypoint
 801                         // the next one created by the user will be the destination waypoint
 802                         start_wp_is_spawned = true;
 803                         start_wp_origin = initial_origin;
 804                         if (is_support_wp)
 805                                 start_wp_is_support = true;
 806                 }
 807         }
 808         else if (start_wp_is_spawned)
 809         {
 810                 waypoint_clear_start_wp_globals(pl, false);
 811         }
 812 }
 813
 814 void waypoint_remove(entity wp)
 815 {
 816         IL_EACH(g_waypoints, it != wp,
 817         {
 818                 if (it.SUPPORT_WP == wp)
 819                 {
 820                         it.SUPPORT_WP = NULL;
 821                         waypoint_schedulerelink(it); // restore incoming links
 822                 }
 823                 if (waypoint_islinked(it, wp))
 824                 {
 825                         if (waypoint_is_hardwiredlink(it, wp))
 826                                 waypoint_unmark_hardwiredlink(it, wp);
 827                         waypoint_removelink(it, wp);
 828                 }
 829         });
 830         delete(wp);
 831 }
 832
 833 void waypoint_remove_fromeditor(entity pl)
 834 {
 835         if (WAYPOINT_VERSION < waypoint_version_loaded)
 836         {
 837                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 838                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 839                 return;
 840         }
 841
 842         entity e = navigation_findnearestwaypoint(pl, false);
 843
 844         int ctf_flags = havocbot_symmetry_origin_order;
 845         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 846                    || (autocvar_g_waypointeditor_symmetrical < 0));
 847         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 848                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 849         if (sym && ctf_flags < 2)
 850                 ctf_flags = 2;
 851         int wp_num = ctf_flags;
 852
 853         LABEL(remove_wp);
 854         if (!e) return;
 855
 856         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 857         {
 858                 if (start_wp_is_spawned)
 859                         waypoint_clear_start_wp_globals(pl, true);
 860                 return;
 861         }
 862
 863         if (waypoint_has_hardwiredlinks(e))
 864         {
 865                 LOG_INFO("Can't remove a waypoint with hardwired links, remove links with \"wpeditor hardwire\" first\n");
 866                 return;
 867         }
 868
 869         entity wp_sym = NULL;
 870         if (sym)
 871         {
 872                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 873                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 874                         if(vdist(org - it.origin, <, 3))
 875                         {
 876                                 wp_sym = it;
 877                                 break;
 878                         }
 879                 });
 880         }
 881
 882         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 883         te_explosion(e.origin);
 884         waypoint_remove(e);
 885
 886         if (sym && wp_sym)
 887         {
 888                 e = wp_sym;
 889                 if(wp_num > 2)
 890                         wp_num--;
 891                 else
 892                         sym = false;
 893                 goto remove_wp;
 894         }
 895
 896         if (start_wp_is_spawned)
 897                 waypoint_clear_start_wp_globals(pl, true);
 898 }
 899
 900 void waypoint_removelink(entity from, entity to)
 901 {
 902         if (from == to || ((from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))))
 903                 return;
 904
 905         entity fromwp31_prev = from.wp31;
 906
 907         switch (waypoint_getlinknum(from, to))
 908         {
 909                 // fallthrough all the way
 910                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 911                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 912                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 913                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 914                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 915                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 916                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 917                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 918                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 919                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 920                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 921                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 922                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 923                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 924                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 925                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 926                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 927                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 928                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 929                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 930                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 931                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 932                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 933                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 934                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 935                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 936                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 937                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 938                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 939                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 940                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 941                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 942         }
 943
 944         if (fromwp31_prev && !from.wp31)
 945                 waypoint_schedulerelink(from);
 946 }
 947
 948 int waypoint_getlinknum(entity from, entity to)
 949 {
 950         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 951         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 952         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 953         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 954         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 955         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 956         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 957         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 958         return -1;
 959 }
 960
 961 bool waypoint_islinked(entity from, entity to)
 962 {
 963         return (waypoint_getlinknum(from, to) >= 0);
 964 }
 965
 966 void waypoint_updatecost_foralllinks()
 967 {
 968         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 969         {
 970                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 971                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 972                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 973                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 974                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 975                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 976                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 977                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 978                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 979                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 980                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 981                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 982                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 983                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 984                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 985                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 986                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 987                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 988                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 989                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 990                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 991                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 992                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 993                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 994                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 995                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 996                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 997                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 998                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 999                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
1000                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
1001                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
1002         });
1003 }
1004
1005 float waypoint_getlinearcost(float dist)
1006 {
1007         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
1008                 return dist / (autocvar_sv_maxspeed * 1.25);
1009         return dist / autocvar_sv_maxspeed;
1010 }
1011
1012 float waypoint_getlinearcost_underwater(float dist)
1013 {
1014         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
1015         return dist / (autocvar_sv_maxspeed * 0.7);
1016 }
1017
1018 float waypoint_getlinearcost_crouched(float dist)
1019 {
1020         return dist / (autocvar_sv_maxspeed * 0.5);
1021 }
1022
1023 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
1024 {
1025         bool submerged_from = navigation_check_submerged_state(from_ent, from);
1026         bool submerged_to = navigation_check_submerged_state(to_ent, to);
1027
1028         if (submerged_from && submerged_to)
1029                 return waypoint_getlinearcost_underwater(vlen(to - from));
1030
1031         if ((from_ent.wpflags & WAYPOINTFLAG_CROUCH) && (to_ent.wpflags & WAYPOINTFLAG_CROUCH))
1032                 return waypoint_getlinearcost_crouched(vlen(to - from));
1033
1034         float c = waypoint_getlinearcost(vlen(to - from));
1035
1036         float height = from.z - to.z;
1037         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
1038         {
1039                 float height_cost; // fall cost
1040                 if (from_ent.wpflags & WAYPOINTFLAG_JUMP)
1041                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
1042                 else
1043                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
1044                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
1045                 if(height_cost > c)
1046                         c = height_cost;
1047         }
1048
1049         // consider half path underwater
1050         if (submerged_from || submerged_to)
1051                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
1052
1053         // consider half path crouched
1054         if ((from_ent.wpflags & WAYPOINTFLAG_CROUCH) || (to_ent.wpflags & WAYPOINTFLAG_CROUCH))
1055                 return (c + waypoint_getlinearcost_crouched(vlen(to - from))) / 2;
1056
1057         return c;
1058 }
1059
1060 float waypoint_getlinkcost(entity from, entity to)
1061 {
1062         vector v1 = from.origin;
1063         vector v2 = to.origin;
1064         if (from.wpisbox)
1065         {
1066                 vector m1 = from.absmin, m2 = from.absmax;
1067                 v1.x = bound(m1.x, v2.x, m2.x);
1068                 v1.y = bound(m1.y, v2.y, m2.y);
1069                 v1.z = bound(m1.z, v2.z, m2.z);
1070         }
1071         if (to.wpisbox)
1072         {
1073                 vector m1 = to.absmin, m2 = to.absmax;
1074                 v2.x = bound(m1.x, v1.x, m2.x);
1075                 v2.y = bound(m1.y, v1.y, m2.y);
1076                 v2.z = bound(m1.z, v1.z, m2.z);
1077         }
1078         return waypoint_gettravelcost(v1, v2, from, to);
1079 }
1080
1081 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
1082 // if c == -1 automatically determine cost of the link
1083 void waypoint_addlink_customcost(entity from, entity to, float c)
1084 {
1085         if (from == to || waypoint_islinked(from, to))
1086                 return;
1087         if (c == -1 && (from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1088                 return;
1089
1090         if(c == -1)
1091                 c = waypoint_getlinkcost(from, to);
1092
1093         if (from.wp31mincost < c) return;
1094         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
1095         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
1096         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
1097         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
1098         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
1099         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
1100         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
1101         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
1102         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
1103         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
1104         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
1105         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
1106         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
1107         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
1108         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
1109         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
1110         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
1111         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
1112         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
1113         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
1114         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
1115         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
1116         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
1117         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
1118         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
1119         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
1120         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
1121         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
1122         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
1123         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
1124         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
1125         from.wp00 = to;from.wp00mincost = c;return;
1126 }
1127
1128 void waypoint_addlink(entity from, entity to)
1129 {
1130         if ((from.wpflags & WPFLAGMASK_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)))
1131                 waypoint_addlink_for_custom_jumppad(from, to);
1132         else
1133                 waypoint_addlink_customcost(from, to, -1);
1134
1135         if (from.wpflags & WAYPOINTFLAG_SUPPORT)
1136                 to.SUPPORT_WP = from;
1137 }
1138
1139 // relink this spawnfunc_waypoint
1140 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1141 // (SLOW!)
1142 void waypoint_think(entity this)
1143 {
1144         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1145         float sv2_height = 0, ev2_height = 0;
1146
1147         bot_calculate_stepheightvec();
1148
1149         int dphitcontentsmask_save = this.dphitcontentsmask;
1150         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1151
1152         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1153
1154         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1155         IL_EACH(g_waypoints, this != it,
1156         {
1157                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1158                 {
1159                         if (!(this.wpflags & WPFLAGMASK_NORELINK))
1160                                 waypoint_addlink(this, it);
1161                         if (!(it.wpflags & WPFLAGMASK_NORELINK))
1162                                 waypoint_addlink(it, this);
1163                 }
1164                 else
1165                 {
1166                         ++relink_total;
1167                         if(!checkpvs(this.origin, it))
1168                         {
1169                                 ++relink_pvsculled;
1170                                 continue;
1171                         }
1172
1173                         sv = set_tracewalk_dest_2(this, it.origin);
1174                         sv2 = tracewalk_dest;
1175                         sv2_height = tracewalk_dest_height;
1176                         ev = set_tracewalk_dest_2(it, this.origin);
1177                         ev2 = tracewalk_dest;
1178                         ev2_height = tracewalk_dest_height;
1179
1180                         dv = ev - sv;
1181                         dv.z = 0;
1182                         int maxdist = 1050;
1183                         vector m1 = PL_MIN_CONST;
1184                         vector m2 = PL_MAX_CONST;
1185
1186                         if ((this.wpflags & WAYPOINTFLAG_CROUCH) || (it.wpflags & WAYPOINTFLAG_CROUCH))
1187                         {
1188                                 m1 = PL_CROUCH_MIN_CONST;
1189                                 m2 = PL_CROUCH_MAX_CONST;
1190                                 // links from crouch wp to normal wp (and viceversa) are very short to avoid creating many links
1191                                 // that would be wasted due to rough travel cost calculation (the longer link is, the higher cost is)
1192                                 // links from crouch wp to crouch wp can be as long as normal links
1193                                 if (!((this.wpflags & WAYPOINTFLAG_CROUCH) && (it.wpflags & WAYPOINTFLAG_CROUCH)))
1194                                         maxdist = 100;
1195                         }
1196
1197                         if (vdist(dv, >=, maxdist)) // max search distance in XY
1198                         {
1199                                 ++relink_lengthculled;
1200                                 continue;
1201                         }
1202
1203                         navigation_testtracewalk = 0;
1204
1205                         //traceline(this.origin, it.origin, false, NULL);
1206                         //if (trace_fraction == 1)
1207                         if (this.wpisbox || (this.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)) // forbid outgoing links
1208                                 || it.SUPPORT_WP) // forbid incoming links
1209                         {
1210                                 relink_walkculled += 0.5;
1211                         }
1212                         else
1213                         {
1214                                 if (tracewalk(this, sv, m1, m2, ev2, ev2_height, MOVE_NOMONSTERS))
1215                                         waypoint_addlink(this, it);
1216                                 else
1217                                         relink_walkculled += 0.5;
1218                         }
1219
1220                         // reverse direction
1221                         if (it.wpisbox || (it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT)) // forbid incoming links
1222                                 || this.SUPPORT_WP) // forbid outgoing links
1223                         {
1224                                 relink_walkculled += 0.5;
1225                         }
1226                         else
1227                         {
1228                                 if (tracewalk(this, ev, m1, m2, sv2, sv2_height, MOVE_NOMONSTERS))
1229                                         waypoint_addlink(it, this);
1230                                 else
1231                                         relink_walkculled += 0.5;
1232                         }
1233                 }
1234         });
1235
1236         // waypoint_clearlinks preserves references to old hardwired links (.wphwXX links)
1237         // so they can be restored here when a wp is spawned over an existing one
1238         waypoint_restore_hardwiredlinks(this);
1239
1240         navigation_testtracewalk = 0;
1241         this.wplinked = true;
1242         this.dphitcontentsmask = dphitcontentsmask_save;
1243
1244         setthink(this, func_null);
1245         this.nextthink = 0;
1246 }
1247
1248 void waypoint_clearlinks(entity wp)
1249 {
1250         // clear links to other waypoints
1251         float f = 10000000;
1252         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1253         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1254         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1255         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1256
1257         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1258         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1259         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1260         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1261
1262         // don't remove references to hardwired links (.wphwXX fields)
1263
1264         wp.wplinked = false;
1265 }
1266
1267 // tell a spawnfunc_waypoint to relink
1268 void waypoint_schedulerelink(entity wp)
1269 {
1270         if (wp == NULL)
1271                 return;
1272
1273         waypoint_setupmodel(wp);
1274         wp.wpisbox = vdist(wp.size, >, 0);
1275         wp.enemy = NULL;
1276         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1277                 wp.owner = NULL;
1278         if (!(wp.wpflags & WPFLAGMASK_NORELINK))
1279                 waypoint_clearlinks(wp);
1280         // schedule an actual relink on next frame
1281         setthink(wp, waypoint_think);
1282         wp.nextthink = time;
1283         wp.effects = EF_LOWPRECISION;
1284 }
1285
1286 // spawnfunc_waypoint map entity
1287 spawnfunc(waypoint)
1288 {
1289         IL_PUSH(g_waypoints, this);
1290
1291         setorigin(this, this.origin);
1292         // schedule a relink after other waypoints have had a chance to spawn
1293         waypoint_clearlinks(this);
1294         //waypoint_schedulerelink(this);
1295 }
1296
1297 // tell all waypoints to relink
1298 // actually this is useful only to update relink_* stats
1299 void waypoint_schedulerelinkall()
1300 {
1301         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1302         IL_EACH(g_waypoints, true,
1303         {
1304                 waypoint_schedulerelink(it);
1305         });
1306         waypoint_load_hardwiredlinks();
1307 }
1308
1309 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1310
1311 // Load waypoint links from file
1312 bool waypoint_load_links()
1313 {
1314         string s;
1315         float file, tokens, c = 0, found;
1316         entity wp_from = NULL, wp_to;
1317         vector wp_to_pos, wp_from_pos;
1318
1319         string gt_ext = GET_GAMETYPE_EXTENSION();
1320
1321         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1322         file = fopen(filename, FILE_READ);
1323
1324         if (gt_ext != "" && file < 0)
1325         {
1326                 // if race waypoint file doesn't exist load the default one
1327                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1328                 file = fopen(filename, FILE_READ);
1329         }
1330
1331         if (file < 0)
1332         {
1333                 LOG_TRACE("waypoint links load from ", filename, " failed");
1334                 waypoint_schedulerelinkall();
1335                 return false;
1336         }
1337
1338         bool parse_comments = true;
1339         float ver = 0;
1340         string links_time = string_null;
1341
1342         while ((s = fgets(file)))
1343         {
1344                 if(parse_comments)
1345                 {
1346                         if(substring(s, 0, 2) == "//")
1347                         {
1348                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1349                                         ver = stof(substring(s, 19, -1));
1350                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1351                                         links_time = substring(s, 16, -1);
1352                                 continue;
1353                         }
1354                         else
1355                         {
1356                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1357                                 {
1358                                         if (links_time != waypoint_time)
1359                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1360                                         else
1361                                                 LOG_TRACE("waypoint links for this map are outdated.");
1362                                         if (g_assault)
1363                                         {
1364                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1365                                         }
1366                                         else
1367                                         {
1368                                                 LOG_TRACE("automatically updating...");
1369                                                 waypoint_schedulerelinkall();
1370                                                 fclose(file);
1371                                                 return false;
1372                                         }
1373                                 }
1374                                 parse_comments = false;
1375                         }
1376                 }
1377
1378                 tokens = tokenizebyseparator(s, "*");
1379
1380                 if (tokens!=2)
1381                 {
1382                         // bad file format
1383                         fclose(file);
1384                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1385                         return false;
1386                 }
1387
1388                 wp_from_pos     = stov(argv(0));
1389                 wp_to_pos       = stov(argv(1));
1390
1391                 // Search "from" waypoint
1392                 if(!wp_from || wp_from.origin!=wp_from_pos)
1393                 {
1394                         wp_from = findradius(wp_from_pos, 1);
1395                         found = false;
1396                         while(wp_from)
1397                         {
1398                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1399                                 if(wp_from.classname == "waypoint")
1400                                 {
1401                                         found = true;
1402                                         break;
1403                                 }
1404                                 wp_from = wp_from.chain;
1405                         }
1406
1407                         if(!found)
1408                         {
1409                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1410                                 continue;
1411                         }
1412                 }
1413
1414                 // Search "to" waypoint
1415                 wp_to = findradius(wp_to_pos, 1);
1416                 found = false;
1417                 while(wp_to)
1418                 {
1419                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1420                         if(wp_to.classname == "waypoint")
1421                         {
1422                                 found = true;
1423                                 break;
1424                         }
1425                         wp_to = wp_to.chain;
1426                 }
1427
1428                 if(!found)
1429                 {
1430                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1431                         continue;
1432                 }
1433
1434                 ++c;
1435                 waypoint_addlink(wp_from, wp_to);
1436                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1437                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1438         }
1439
1440         fclose(file);
1441
1442         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1443
1444         bool scheduled = false;
1445         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1446         {
1447                 if (!it.wp00)
1448                 {
1449                         waypoint_schedulerelink(it);
1450                         scheduled = true;
1451                 }
1452         });
1453         if (scheduled)
1454                 return false;
1455
1456         botframe_cachedwaypointlinks = true;
1457         return true;
1458 }
1459
1460 void waypoint_load_hardwiredlinks()
1461 {
1462         string s;
1463         float file, tokens, c = 0, found;
1464         entity wp_from = NULL, wp_to;
1465         vector wp_to_pos, wp_from_pos;
1466
1467         string gt_ext = GET_GAMETYPE_EXTENSION();
1468
1469         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1470         file = fopen(filename, FILE_READ);
1471
1472         if (gt_ext != "" && file < 0)
1473         {
1474                 // if race waypoint file doesn't exist load the default one
1475                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1476                 file = fopen(filename, FILE_READ);
1477         }
1478
1479         botframe_loadedforcedlinks = true;
1480
1481         if (file < 0)
1482         {
1483                 LOG_TRACE("waypoint links load from ", filename, " failed");
1484                 return;
1485         }
1486
1487         bool is_special = false;
1488         while ((s = fgets(file)))
1489         {
1490                 if(substring(s, 0, 2)=="//")
1491                         continue;
1492
1493                 if(substring(s, 0, 1)=="#")
1494                         continue;
1495
1496                 // special links start with *, so old xonotic versions don't load them
1497                 is_special = false;
1498                 if (substring(s, 0, 1) == "*")
1499                 {
1500                         is_special = true;
1501                         s = substring(s, 1, -1);
1502                 }
1503
1504                 tokens = tokenizebyseparator(s, "*");
1505
1506                 if (tokens!=2)
1507                         continue;
1508
1509                 wp_from_pos     = stov(argv(0));
1510                 wp_to_pos       = stov(argv(1));
1511
1512                 // Search "from" waypoint
1513                 if(!wp_from || wp_from.origin!=wp_from_pos)
1514                 {
1515                         wp_from = findradius(wp_from_pos, 5);
1516                         found = false;
1517                         while(wp_from)
1518                         {
1519                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1520                                 if(wp_from.classname == "waypoint")
1521                                 {
1522                                         found = true;
1523                                         break;
1524                                 }
1525                                 wp_from = wp_from.chain;
1526                         }
1527
1528                         if(!found)
1529                         {
1530                                 s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1531                                 LOG_INFO("NOTICE: Can not find origin waypoint of the ", s, ". Path skipped");
1532                                 continue;
1533                         }
1534                 }
1535
1536                 // Search "to" waypoint
1537                 wp_to = findradius(wp_to_pos, 5);
1538                 found = false;
1539                 while(wp_to)
1540                 {
1541                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1542                         if(wp_to.classname == "waypoint")
1543                         {
1544                                 found = true;
1545                                 break;
1546                         }
1547                         wp_to = wp_to.chain;
1548                 }
1549
1550                 if(!found)
1551                 {
1552                         s = strcat(((is_special) ? "special link " : "hardwired link "), s);
1553                         LOG_INFO("NOTICE: Can not find destination waypoint of the ", s, ". Path skipped");
1554                         continue;
1555                 }
1556
1557                 ++c;
1558
1559                 if (!is_special)
1560                 {
1561                         waypoint_addlink(wp_from, wp_to);
1562                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1563                 } else if (wp_from.wpflags & WPFLAGMASK_NORELINK
1564                         && ((wp_from.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT))
1565                                 || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1566                 {
1567                         waypoint_addlink(wp_from, wp_to);
1568                 }
1569         }
1570
1571         fclose(file);
1572
1573         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1574 }
1575
1576 float waypoint_get_assigned_link_cost(entity w, float i)
1577 {
1578         switch(i)
1579         {
1580                 case  0: return w.wp00mincost;
1581                 case  1: return w.wp01mincost;
1582                 case  2: return w.wp02mincost;
1583                 case  3: return w.wp03mincost;
1584                 case  4: return w.wp04mincost;
1585                 case  5: return w.wp05mincost;
1586                 case  6: return w.wp06mincost;
1587                 case  7: return w.wp07mincost;
1588                 case  8: return w.wp08mincost;
1589                 case  9: return w.wp09mincost;
1590                 case 10: return w.wp10mincost;
1591                 case 11: return w.wp11mincost;
1592                 case 12: return w.wp12mincost;
1593                 case 13: return w.wp13mincost;
1594                 case 14: return w.wp14mincost;
1595                 case 15: return w.wp15mincost;
1596                 case 16: return w.wp16mincost;
1597                 case 17: return w.wp17mincost;
1598                 case 18: return w.wp18mincost;
1599                 case 19: return w.wp19mincost;
1600                 case 20: return w.wp20mincost;
1601                 case 21: return w.wp21mincost;
1602                 case 22: return w.wp22mincost;
1603                 case 23: return w.wp23mincost;
1604                 case 24: return w.wp24mincost;
1605                 case 25: return w.wp25mincost;
1606                 case 26: return w.wp26mincost;
1607                 case 27: return w.wp27mincost;
1608                 case 28: return w.wp28mincost;
1609                 case 29: return w.wp29mincost;
1610                 case 30: return w.wp30mincost;
1611                 case 31: return w.wp31mincost;
1612                 default: return -1;
1613         }
1614 }
1615
1616 entity waypoint_get_link(entity w, float i)
1617 {
1618         switch(i)
1619         {
1620                 case  0:return w.wp00;
1621                 case  1:return w.wp01;
1622                 case  2:return w.wp02;
1623                 case  3:return w.wp03;
1624                 case  4:return w.wp04;
1625                 case  5:return w.wp05;
1626                 case  6:return w.wp06;
1627                 case  7:return w.wp07;
1628                 case  8:return w.wp08;
1629                 case  9:return w.wp09;
1630                 case 10:return w.wp10;
1631                 case 11:return w.wp11;
1632                 case 12:return w.wp12;
1633                 case 13:return w.wp13;
1634                 case 14:return w.wp14;
1635                 case 15:return w.wp15;
1636                 case 16:return w.wp16;
1637                 case 17:return w.wp17;
1638                 case 18:return w.wp18;
1639                 case 19:return w.wp19;
1640                 case 20:return w.wp20;
1641                 case 21:return w.wp21;
1642                 case 22:return w.wp22;
1643                 case 23:return w.wp23;
1644                 case 24:return w.wp24;
1645                 case 25:return w.wp25;
1646                 case 26:return w.wp26;
1647                 case 27:return w.wp27;
1648                 case 28:return w.wp28;
1649                 case 29:return w.wp29;
1650                 case 30:return w.wp30;
1651                 case 31:return w.wp31;
1652                 default:return NULL;
1653         }
1654 }
1655
1656 // Save all hardwired waypoint links to a file
1657 void waypoint_save_hardwiredlinks()
1658 {
1659         string gt_ext = GET_GAMETYPE_EXTENSION();
1660
1661         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1662         int file = fopen(filename, FILE_WRITE);
1663         if (file < 0)
1664         {
1665                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1666                 return;
1667         }
1668
1669         // write hardwired links to file
1670         int count = 0;
1671         fputs(file, "// HARDWIRED LINKS\n");
1672         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1673         {
1674                 for (int j = 0; j < 32; ++j)
1675                 {
1676                         entity link = waypoint_get_link(it, j);
1677                         if (waypoint_is_hardwiredlink(it, link))
1678                         {
1679                                 // NOTE: vtos rounds vector components to 1 decimal place
1680                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1681                                 fputs(file, s);
1682                                 ++count;
1683                         }
1684                 }
1685         });
1686
1687         // write special links to file
1688         int count2 = 0;
1689         fputs(file, "\n// SPECIAL LINKS\n");
1690         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP),
1691         {
1692                 for (int j = 0; j < 32; ++j)
1693                 {
1694                         entity link = waypoint_get_link(it, j);
1695                         if (link)
1696                         {
1697                                 // NOTE: vtos rounds vector components to 1 decimal place
1698                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1699                                 fputs(file, s);
1700                                 ++count2;
1701                         }
1702                 }
1703         });
1704
1705         fclose(file);
1706
1707         LOG_INFOF("saved %d hardwired links and %d special links to %s", count, count2, filename);
1708 }
1709
1710 // Save all waypoint links to a file
1711 void waypoint_save_links()
1712 {
1713         string gt_ext = GET_GAMETYPE_EXTENSION();
1714
1715         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1716         int file = fopen(filename, FILE_WRITE);
1717         if (file < 0)
1718         {
1719                 LOG_INFOF("waypoint link save to %s failed", filename);
1720                 return;
1721         }
1722
1723         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1724         if (waypoint_time != "")
1725                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1726
1727         int c = 0;
1728         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)),
1729         {
1730                 for(int j = 0; j < 32; ++j)
1731                 {
1732                         entity link = waypoint_get_link(it, j);
1733                         if (link && !waypoint_is_hardwiredlink(it, link))
1734                         {
1735                                 // NOTE: vtos rounds vector components to 1 decimal place
1736                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1737                                 fputs(file, s);
1738                                 ++c;
1739                         }
1740                 }
1741         });
1742         fclose(file);
1743
1744         botframe_cachedwaypointlinks = true;
1745
1746         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1747 }
1748
1749 // save waypoints to gamedir/data/maps/mapname.waypoints
1750 void waypoint_saveall()
1751 {
1752         if (WAYPOINT_VERSION < waypoint_version_loaded)
1753         {
1754                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1755                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1756                 return;
1757         }
1758         string gt_ext = GET_GAMETYPE_EXTENSION();
1759
1760         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1761         int file = fopen(filename, FILE_WRITE);
1762         if (file < 0)
1763         {
1764                 waypoint_save_links(); // save anyway?
1765                 botframe_loadedforcedlinks = false;
1766
1767                 LOG_INFOF("waypoint links: save to %s failed", filename);
1768                 return;
1769         }
1770
1771         float sym = autocvar_g_waypointeditor_symmetrical;
1772         string sym_str = ftos(sym);
1773         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1774         {
1775                 if (sym == 1)
1776                 {
1777                         sym_str = cons(sym_str, "-");
1778                         sym_str = cons(sym_str, "-");
1779                 }
1780                 else
1781                 {
1782                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1783                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1784                 }
1785                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1786                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1787         }
1788         else if (autocvar_g_waypointeditor_symmetrical == -2)
1789         {
1790                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1791                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1792         }
1793
1794         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1795         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1796         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1797         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1798
1799         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1800         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1801         //fputs(file, strcat("//", "\n"));
1802         //fputs(file, strcat("//", "\n"));
1803         //fputs(file, strcat("//", "\n"));
1804
1805         int c = 0;
1806         IL_EACH(g_waypoints, true,
1807         {
1808                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1809                         continue;
1810
1811                 string s;
1812                 // NOTE: vtos rounds vector components to 1 decimal place
1813                 s = strcat(vtos(it.origin + it.mins), "\n");
1814                 s = strcat(s, vtos(it.origin + it.maxs));
1815                 s = strcat(s, "\n");
1816                 s = strcat(s, ftos(it.wpflags));
1817                 s = strcat(s, "\n");
1818                 fputs(file, s);
1819                 c++;
1820         });
1821         fclose(file);
1822         waypoint_save_links();
1823         waypoint_save_hardwiredlinks();
1824
1825         botframe_loadedforcedlinks = false;
1826
1827         waypoint_version_loaded = WAYPOINT_VERSION;
1828         LOG_INFOF("saved %d waypoints to %s", c, filename);
1829 }
1830
1831 // load waypoints from file
1832 float waypoint_loadall()
1833 {
1834         string s;
1835         int file, cwp, cwb, fl;
1836         vector m1, m2;
1837         cwp = 0;
1838         cwb = 0;
1839
1840         string gt_ext = GET_GAMETYPE_EXTENSION();
1841
1842         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1843         file = fopen(filename, FILE_READ);
1844
1845         if (gt_ext != "" && file < 0)
1846         {
1847                 // if race waypoint file doesn't exist load the default one
1848                 filename = sprintf("maps/%s.waypoints", mapname);
1849                 file = fopen(filename, FILE_READ);
1850         }
1851
1852         if (file < 0)
1853         {
1854                 LOG_TRACE("waypoint load from ", filename, " failed");
1855                 return 0;
1856         }
1857
1858         bool parse_comments = true;
1859         float ver = 0;
1860         float sym = 0;
1861         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1862
1863         while ((s = fgets(file)))
1864         {
1865                 if(parse_comments)
1866                 {
1867                         if(substring(s, 0, 2) == "//")
1868                         {
1869                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1870                                         ver = stof(substring(s, 19, -1));
1871                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1872                                 {
1873                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1874                                         if (tokens) { sym = stof(argv(0)); }
1875                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1876                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1877                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1878                                 }
1879                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1880                                         strcpy(waypoint_time, substring(s, 16, -1));
1881                                 continue;
1882                         }
1883                         else
1884                         {
1885                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1886                                 {
1887                                         LOG_TRACE("waypoints for this map are outdated");
1888                                         LOG_TRACE("please update them in the editor");
1889                                 }
1890                                 parse_comments = false;
1891                         }
1892                 }
1893                 m1 = stov(s);
1894                 s = fgets(file);
1895                 if (!s)
1896                         break;
1897                 m2 = stov(s);
1898                 s = fgets(file);
1899                 if (!s)
1900                         break;
1901                 fl = stof(s);
1902                 fl &= ~WAYPOINTFLAG_NORELINK__DEPRECATED;
1903                 waypoint_spawn(m1, m2, fl);
1904                 if (m1 == m2)
1905                         cwp = cwp + 1;
1906                 else
1907                         cwb = cwb + 1;
1908         }
1909         fclose(file);
1910         waypoint_version_loaded = ver;
1911         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1912
1913         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1914         {
1915                 string sym_str = "";
1916                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1917                 if (sym == 1 && sym_param3 < 2)
1918                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1919                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1920                 {
1921                         string params;
1922                         if (sym == 1)
1923                                 params = cons("-", "-");
1924                         else
1925                         {
1926                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1927                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1928                         }
1929                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1930                         sym_str = strcat(ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1931                 }
1932                 else if (sym == -2)
1933                 {
1934                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1935                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1936                         sym_str = strcat(ftos(sym), " with axis ", params);
1937                 }
1938                 else
1939                         sym_str = ftos(sym);
1940                 if (sym_str != "")
1941                         LOG_INFO("Waypoint editor: loaded symmetry ", sym_str);
1942                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1943         }
1944
1945         if (WAYPOINT_VERSION < waypoint_version_loaded)
1946                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1947                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1948
1949         return cwp + cwb;
1950 }
1951
1952 #define waypoint_fixorigin(position, tracetest_ent) \
1953         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1954
1955 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1956 {
1957         vector endpos = position + down_dir * 3000;
1958         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1959         if(trace_startsolid)
1960                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1961         if(trace_startsolid)
1962                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1963         if(trace_fraction < 1)
1964                 position = trace_endpos;
1965         return position;
1966 }
1967
1968 void waypoint_spawnforitem_force(entity e, vector org)
1969 {
1970         // Fix the waypoint altitude if necessary
1971         org = waypoint_fixorigin(org, NULL);
1972
1973         // don't spawn an item spawnfunc_waypoint if it already exists
1974         IL_EACH(g_waypoints, true,
1975         {
1976                 if(it.wpisbox)
1977                 {
1978                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1979                         {
1980                                 e.nearestwaypoint = it;
1981                                 return;
1982                         }
1983                 }
1984                 else
1985                 {
1986                         if(vdist(it.origin - org, <, 16))
1987                         {
1988                                 e.nearestwaypoint = it;
1989                                 return;
1990                         }
1991                 }
1992         });
1993
1994         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1995 }
1996
1997 void waypoint_spawnforitem(entity e)
1998 {
1999         if(!bot_waypoints_for_items)
2000                 return;
2001
2002         waypoint_spawnforitem_force(e, e.origin);
2003 }
2004
2005 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
2006 {
2007         entity w;
2008         entity dw;
2009         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag);
2010         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
2011         // one way link to the destination
2012         w.wp00_original = dw;
2013         w.wp00 = dw;
2014         w.wp00mincost = timetaken; // this is just for jump pads
2015         // the teleporter's nearest spawnfunc_waypoint is this one
2016         // (teleporters are not goals, so this is probably useless)
2017         e.nearestwaypoint = w;
2018         e.nearestwaypointtimeout = -1;
2019 }
2020
2021 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
2022 {
2023         float src_angle = e.warpzone_angles.x;
2024         while (src_angle < -180) src_angle += 360;
2025         while (src_angle > 180) src_angle -= 360;
2026
2027         float dest_angle = e.enemy.warpzone_angles.x;
2028         while (dest_angle < -180) dest_angle += 360;
2029         while (dest_angle > 180) dest_angle -= 360;
2030
2031         // no waypoints for warpzones pointing upwards, they can't be used by the bots
2032         if (src_angle == -90 || dest_angle == -90)
2033                 return;
2034
2035         makevectors(e.warpzone_angles);
2036         vector src = (e.absmin + e.absmax) * 0.5;
2037         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
2038         vector down_dir_src = -v_up;
2039
2040         makevectors(e.enemy.warpzone_angles);
2041         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
2042         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
2043         vector down_dir_dest = -v_up;
2044
2045         int extra_flag = 0;
2046         // don't snap to the ground waypoints for source warpzones pointing downwards
2047         if (src_angle != 90)
2048         {
2049                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
2050                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
2051                 // oblique warpzones need a jump otherwise bots gets stuck
2052                 if (src_angle != 0)
2053                         extra_flag = WAYPOINTFLAG_JUMP;
2054         }
2055
2056         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
2057 }
2058
2059 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
2060 {
2061         destination = waypoint_fixorigin(destination, tracetest_ent);
2062         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
2063 }
2064
2065 entity waypoint_spawnpersonal(entity this, vector position)
2066 {
2067         entity w;
2068
2069         // drop the waypoint to a proper location:
2070         //   first move it up by a player height
2071         //   then move it down to hit the floor with player bbox size
2072         position = waypoint_fixorigin(position, this);
2073
2074         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
2075         w.nearestwaypoint = NULL;
2076         w.nearestwaypointtimeout = 0;
2077         w.owner = this;
2078
2079         waypoint_schedulerelink(w);
2080
2081         return w;
2082 }
2083
2084 void waypoint_showlink(entity wp1, entity wp2, int display_type)
2085 {
2086         if (!(wp1 && wp2))
2087                 return;
2088
2089         if (waypoint_is_hardwiredlink(wp1, wp2) || (wp1.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_SUPPORT | WAYPOINTFLAG_CUSTOM_JP)))
2090                 te_beam(NULL, wp1.origin, wp2.origin);
2091         else if (display_type == 1)
2092                 te_lightning2(NULL, wp1.origin, wp2.origin);
2093 }
2094
2095 void waypoint_showlinks_to(entity wp, int display_type)
2096 {
2097         IL_EACH(g_waypoints, it != wp,
2098         {
2099                 if (waypoint_islinked(it, wp))
2100                         waypoint_showlink(it, wp, display_type);
2101         });
2102 }
2103
2104 void waypoint_showlinks_from(entity wp, int display_type)
2105 {
2106         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
2107         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
2108         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
2109         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
2110         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
2111         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
2112         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
2113         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
2114         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
2115         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
2116         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
2117         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
2118         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
2119         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
2120         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
2121         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
2122 }
2123
2124 void crosshair_trace_waypoints(entity pl)
2125 {
2126         IL_EACH(g_waypoints, true, {
2127                 it.solid = SOLID_BSP;
2128                 if (!it.wpisbox)
2129                         setsize(it, '-16 -16 -16', '16 16 16');
2130         });
2131
2132         WarpZone_crosshair_trace(pl);
2133
2134         IL_EACH(g_waypoints, true, {
2135                 it.solid = SOLID_TRIGGER;
2136                 if (!it.wpisbox)
2137                         setsize(it, '0 0 0', '0 0 0');
2138         });
2139
2140         if (trace_ent.classname != "waypoint")
2141                 trace_ent = NULL;
2142         else if (!trace_ent.wpisbox)
2143                 trace_endpos = trace_ent.origin;
2144 }
2145
2146 void botframe_showwaypointlinks()
2147 {
2148         if (time < botframe_waypointeditorlightningtime)
2149                 return;
2150         botframe_waypointeditorlightningtime = time + 0.5;
2151         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
2152         {
2153                 int display_type = 0;
2154                 if (wasfreed(it.wp_aimed))
2155                         it.wp_aimed = NULL;
2156                 if (wasfreed(it.wp_locked))
2157                         it.wp_locked = NULL;
2158                 entity head = it.wp_locked;
2159                 if (!head)
2160                         head = navigation_findnearestwaypoint(it, false);
2161                 it.nearestwaypoint = head; // mainly useful for debug
2162                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
2163                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
2164                         display_type = 1; // default
2165                 else if(waypoint_has_hardwiredlinks(head))
2166                         display_type = 2; // only hardwired
2167
2168                 if (display_type)
2169                 {
2170                         //navigation_testtracewalk = true;
2171                         //print("currently selected WP is ", etos(head), "\n");
2172                         //navigation_testtracewalk = false;
2173                         if (head)
2174                         {
2175                                 te_lightning2(NULL, head.origin, it.origin);
2176                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
2177                                         waypoint_showlinks_to(head, display_type);
2178                                 else
2179                                         waypoint_showlinks_from(head, display_type);
2180                         }
2181                 }
2182                 string str;
2183                 entity wp = NULL;
2184                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
2185                 {
2186                         crosshair_trace_waypoints(it);
2187                         if (trace_ent)
2188                         {
2189                                 wp = trace_ent;
2190                                 if (wp != it.wp_aimed)
2191                                 {
2192                                         string wp_type_str = waypoint_get_type_name(wp);
2193                                         str = sprintf("\necho Entity %d: %s^7, flags: %d, origin: %s\n", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2194                                         if (wp.wpisbox)
2195                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
2196                                         stuffcmd(it, str);
2197                                         str = sprintf("Entity %d: %s^7\nflags: %d\norigin: %s", etof(wp), wp_type_str, wp.wpflags, vtos(wp.origin));
2198                                         if (wp.wpisbox)
2199                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
2200                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
2201                                 }
2202                         }
2203                 }
2204                 if (it.wp_aimed != wp)
2205                         it.wp_aimed = wp;
2206         });
2207 }
2208
2209 float botframe_autowaypoints_fixdown(vector v)
2210 {
2211         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2212         if(trace_fraction >= 1)
2213                 return 0;
2214         return 1;
2215 }
2216
2217 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2218 {
2219         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2220         {
2221                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2222                 return 0;
2223         });
2224
2225         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2226         return 1;
2227 }
2228
2229 // return value:
2230 //    1 = WP created
2231 //    0 = no action needed
2232 //   -1 = temp fail, try from world too
2233 //   -2 = permanent fail, do not retry
2234 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2235 {
2236         // make it possible to go from p to wp, if we can
2237         // if wp is NULL, nearest is chosen
2238
2239         entity w;
2240         vector porg;
2241         float t, tmin, tmax;
2242         vector o;
2243         vector save;
2244
2245         if(!botframe_autowaypoints_fixdown(p.origin))
2246                 return -2;
2247         porg = trace_endpos;
2248
2249         if(wp)
2250         {
2251                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2252
2253                 // if wp -> porg, then OK
2254                 float maxdist;
2255                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2256                 {
2257                         // we may find a better one
2258                         maxdist = vlen(wp.origin - porg);
2259                 }
2260                 else
2261                 {
2262                         // accept any "good"
2263                         maxdist = 2100;
2264                 }
2265
2266                 float bestdist = maxdist;
2267                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WPFLAGMASK_NORELINK),
2268                 {
2269                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2270                         if(d < bestdist)
2271                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2272                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2273                         {
2274                                 bestdist = d;
2275                                 p.(fld) = it;
2276                         }
2277                 });
2278                 if(bestdist < maxdist)
2279                 {
2280                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2281                         return 0;
2282                 }
2283
2284                 if(bestdist < 2100)
2285                 {
2286                         // we know maxdist < 2100
2287                         // so wp -> porg is still valid
2288                         // all is good
2289                         p.(fld) = wp;
2290                         return 0;
2291                 }
2292
2293                 // otherwise, no existing WP can fix our issues
2294         }
2295         else
2296         {
2297                 save = p.origin;
2298                 setorigin(p, porg);
2299                 w = navigation_findnearestwaypoint(p, walkfromwp);
2300                 setorigin(p, save);
2301                 if(w)
2302                 {
2303                         p.(fld) = w;
2304                         return 0;
2305                 }
2306         }
2307
2308         tmin = 0;
2309         tmax = 1;
2310         for (;;)
2311         {
2312                 if(tmax - tmin < 0.001)
2313                 {
2314                         // did not get a good candidate
2315                         return -1;
2316                 }
2317
2318                 t = (tmin + tmax) * 0.5;
2319                 o = antilag_takebackorigin(p, CS(p), time - t);
2320                 if(!botframe_autowaypoints_fixdown(o))
2321                         return -2;
2322                 o = trace_endpos;
2323
2324                 if(wp)
2325                 {
2326                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2327                         {
2328                                 // we cannot walk from wp.origin to o
2329                                 // get closer to tmax
2330                                 tmin = t;
2331                                 continue;
2332                         }
2333                 }
2334                 else
2335                 {
2336                         save = p.origin;
2337                         setorigin(p, o);
2338                         w = navigation_findnearestwaypoint(p, walkfromwp);
2339                         setorigin(p, save);
2340                         if(!w)
2341                         {
2342                                 // we cannot walk from any WP to o
2343                                 // get closer to tmax
2344                                 tmin = t;
2345                                 continue;
2346                         }
2347                 }
2348
2349                 // if we get here, o is valid regarding waypoints
2350                 // check if o is connected right to the player
2351                 // we break if it succeeds, as that means o is a good waypoint location
2352                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2353                         break;
2354
2355                 // o is no good, we need to get closer to the player
2356                 tmax = t;
2357         }
2358
2359         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2360         botframe_autowaypoints_createwp(o, p, fld, 0);
2361         return 1;
2362 }
2363
2364 // automatically create missing waypoints
2365 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2366 {
2367         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2368         if(r != -1)
2369                 return;
2370         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2371         if(r != -1)
2372                 return;
2373
2374         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2375         if(!botframe_autowaypoints_fixdown(p.origin))
2376                 return; // shouldn't happen, caught above
2377         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2378 }
2379
2380 void botframe_deleteuselesswaypoints()
2381 {
2382         IL_EACH(g_items, it.bot_pickup,
2383         {
2384                 // NOTE: this protects waypoints if they're the ONLY nearest
2385                 // waypoint. That's the intention.
2386                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2387                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2388         });
2389         IL_EACH(g_waypoints, true,
2390         {
2391                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2392                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2393                 // WP is useful if:
2394                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2395                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2396                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2397                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2398                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2399                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2400                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2401                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2402                 // b) WP is closest WP for an item/spawnpoint/other entity
2403                 //    This has been done above by protecting these WPs.
2404         });
2405         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2406         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2407         {
2408                 for (int m = 0; m < 32; ++m)
2409                 {
2410                         entity w = waypoint_get_link(it, m);
2411                         if (!w)
2412                                 break;
2413                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2414                                 continue;
2415                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2416                                 continue;
2417                         for (int j = 0; j < 32; ++j)
2418                         {
2419                                 entity w2 = waypoint_get_link(w, j);
2420                                 if (!w2)
2421                                         break;
2422                                 if (it == w2)
2423                                         continue;
2424                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2425                                         continue;
2426                                 // If we got here, it != w2 exist with it -> w
2427                                 // and w -> w2. That means the waypoint is not
2428                                 // a dead end.
2429                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2430                                 for (int k = 0; k < 32; ++k)
2431                                 {
2432                                         if (waypoint_get_link(it, k) == w2)
2433                                                 continue;
2434                                         // IF WE GET HERE, w is proven useful
2435                                         // to get from it to w2!
2436                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2437                                         goto next;
2438                                 }
2439                         }
2440 LABEL(next)
2441                 }
2442         });
2443         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2444         //     they are needed to complete routes while autowaypointing.
2445
2446         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2447         {
2448                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2449                 te_explosion(it.origin);
2450                 waypoint_remove(it);
2451                 break;
2452         });
2453
2454         IL_EACH(g_waypoints, true,
2455         {
2456                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2457         });
2458 }
2459
2460 //.entity botframe_autowaypoints_lastwp0;
2461 .entity botframe_autowaypoints_lastwp1;
2462 void botframe_autowaypoints()
2463 {
2464         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2465                 // going back is broken, so only fix waypoints to walk TO the player
2466                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2467                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2468                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2469         });
2470
2471         if (autocvar_g_waypointeditor_auto >= 2) {
2472                 botframe_deleteuselesswaypoints();
2473         }
2474 }
2475