qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17
  18 #include <lib/warpzone/common.qh>
  19 #include <lib/warpzone/util_server.qh>
  20
  21 .entity spawnpointmodel;
  22 void waypoint_unreachable(entity pl)
  23 {
  24         IL_EACH(g_waypoints, true,
  25         {
  26                 it.colormod = '0.5 0.5 0.5';
  27                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  28         });
  29
  30         entity e2 = navigation_findnearestwaypoint(pl, false);
  31         if(!e2)
  32         {
  33                 LOG_INFOF("Can't find any waypoint nearby\n");
  34                 return;
  35         }
  36
  37         navigation_markroutes(pl, e2);
  38
  39         int j = 0;
  40         int m = 0;
  41         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  42         {
  43                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  44                 it.colormod_z = 8;
  45                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  46                 j++;
  47                 m++;
  48         });
  49         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  50         navigation_markroutes_inverted(e2);
  51
  52         j = 0;
  53         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  54         {
  55                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  56                 it.colormod_x = 8;
  57                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  58                         m++;
  59                 it.effects |= EF_NODEPTHTEST | EF_RED;
  60                 j++;
  61         });
  62         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  63         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  64
  65         j = 0;
  66         IL_EACH(g_spawnpoints, true,
  67         {
  68                 if (navigation_findnearestwaypoint(it, false))
  69                 {
  70                         if(it.spawnpointmodel)
  71                         {
  72                                 delete(it.spawnpointmodel);
  73                                 it.spawnpointmodel = NULL;
  74                         }
  75                 }
  76                 else
  77                 {
  78                         if(!it.spawnpointmodel)
  79                         {
  80                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  81                                 entity e = new(spawnpointmodel);
  82                                 vector org = trace_endpos + eZ;
  83                                 setorigin(e, org);
  84                                 e.solid = SOLID_TRIGGER;
  85                                 it.spawnpointmodel = e;
  86                         }
  87                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  88                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  89                         _setmodel(it.spawnpointmodel, pl.model);
  90                         it.spawnpointmodel.frame = pl.frame;
  91                         it.spawnpointmodel.skin = pl.skin;
  92                         it.spawnpointmodel.colormap = pl.colormap;
  93                         it.spawnpointmodel.colormod = pl.colormod;
  94                         it.spawnpointmodel.glowmod = pl.glowmod;
  95                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  96                         j++;
  97                 }
  98         });
  99         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 100
 101         j = 0;
 102         IL_EACH(g_items, true,
 103         {
 104                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 105                 it.colormod = '0.5 0.5 0.5';
 106         });
 107         IL_EACH(g_items, true,
 108         {
 109                 if (navigation_findnearestwaypoint(it, false))
 110                         continue;
 111                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 112                 it.effects |= EF_NODEPTHTEST | EF_RED;
 113                 it.colormod_x = 8;
 114                 j++;
 115         });
 116         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 117
 118         j = 0;
 119         IL_EACH(g_items, true,
 120         {
 121                 if (navigation_findnearestwaypoint(it, true))
 122                         continue;
 123                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 124                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 125                 it.colormod_z = 8;
 126                 j++;
 127         });
 128         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 129 }
 130
 131 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 132 {
 133         vector new_org = org;
 134         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 135         {
 136                 vector map_center = havocbot_middlepoint;
 137                 if (autocvar_g_waypointeditor_symmetrical == -1)
 138                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 139
 140                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 141         }
 142         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 143         {
 144                 float m = havocbot_symmetry_axis_m;
 145                 float q = havocbot_symmetry_axis_q;
 146                 if (autocvar_g_waypointeditor_symmetrical == -2)
 147                 {
 148                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 149                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 150                 }
 151
 152                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 153                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 154         }
 155         new_org.z = org.z;
 156         return new_org;
 157 }
 158
 159 void waypoint_setupmodel(entity wp)
 160 {
 161         if (autocvar_g_waypointeditor)
 162         {
 163                 // TODO: add some sort of visible box in edit mode for box waypoints
 164                 vector m1 = wp.mins;
 165                 vector m2 = wp.maxs;
 166                 setmodel(wp, MDL_WAYPOINT);
 167                 setsize(wp, m1, m2);
 168                 wp.effects = EF_LOWPRECISION;
 169                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 170                         wp.colormod = '1 0 0';
 171                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 172                         wp.colormod = '1 1 0';
 173                 else if (wp.wphardwired)
 174                         wp.colormod = '0.5 0 1';
 175                 else
 176                         wp.colormod = '1 1 1';
 177         }
 178         else
 179                 wp.model = "";
 180 }
 181
 182 entity waypoint_spawn(vector m1, vector m2, float f)
 183 {
 184         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 185         {
 186                 vector em1 = m1 - '8 8 8';
 187                 vector em2 = m2 + '8 8 8';
 188                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 189                 {
 190                         return it;
 191                 });
 192         }
 193         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 194         // otherwise links loaded from file would be applied only to the first destination
 195         // waypoint since link format doesn't specify waypoint entities but just positions
 196         if((f & WAYPOINTFLAG_GENERATED) && !(f & WAYPOINTFLAG_NORELINK) && m1 == m2)
 197         {
 198                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 199                 {
 200                         return it;
 201                 });
 202         }
 203
 204         entity w = new(waypoint);
 205         IL_PUSH(g_waypoints, w);
 206         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 207         w.wpflags = f;
 208         w.solid = SOLID_TRIGGER;
 209         setorigin(w, (m1 + m2) * 0.5);
 210         setsize(w, m1 - w.origin, m2 - w.origin);
 211         if (w.size)
 212                 w.wpisbox = true;
 213
 214         if(!w.wpisbox)
 215         {
 216                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 217                 if(!move_out_of_solid(w))
 218                 {
 219                         if(!(f & WAYPOINTFLAG_GENERATED))
 220                         {
 221                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 222                                 delete(w);
 223                                 return NULL;
 224                         }
 225                         else
 226                         {
 227                                 if(autocvar_developer)
 228                                 {
 229                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 230                                         backtrace("Waypoint stuck");
 231                                 }
 232                         }
 233                 }
 234                 setsize(w, '0 0 0', '0 0 0');
 235         }
 236
 237         waypoint_clearlinks(w);
 238         //waypoint_schedulerelink(w);
 239
 240         waypoint_setupmodel(w);
 241
 242         return w;
 243 }
 244
 245 void waypoint_spawn_fromeditor(entity pl)
 246 {
 247         entity e;
 248         vector org = pl.origin;
 249         int ctf_flags = havocbot_symmetry_origin_order;
 250         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 251                    || (autocvar_g_waypointeditor_symmetrical < 0));
 252         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 253                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 254         if (sym && ctf_flags < 2)
 255                 ctf_flags = 2;
 256         int wp_num = ctf_flags;
 257
 258         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 259         {
 260                 // snap waypoint to item's origin if close enough
 261                 IL_EACH(g_items, true,
 262                 {
 263                         vector item_org = (it.absmin + it.absmax) * 0.5;
 264                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 265                         if (vlen(item_org - org) < 20)
 266                         {
 267                                 org = item_org;
 268                                 break;
 269                         }
 270                 });
 271         }
 272
 273         LABEL(add_wp);
 274         e = waypoint_spawn(org, org, 0);
 275         if(!e)
 276         {
 277                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 278                 return;
 279         }
 280         waypoint_schedulerelink(e);
 281         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 282         if(sym)
 283         {
 284                 org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 285                 if (vdist(org - pl.origin, >, 32))
 286                 {
 287                         if(wp_num > 2)
 288                                 wp_num--;
 289                         else
 290                                 sym = false;
 291                         goto add_wp;
 292                 }
 293         }
 294 }
 295
 296 void waypoint_remove(entity wp)
 297 {
 298         IL_EACH(g_waypoints, it != wp,
 299         {
 300                 if (waypoint_islinked(it, wp))
 301                         waypoint_removelink(it, wp);
 302         });
 303         delete(wp);
 304 }
 305
 306 void waypoint_remove_fromeditor(entity pl)
 307 {
 308         entity e = navigation_findnearestwaypoint(pl, false);
 309
 310         int ctf_flags = havocbot_symmetry_origin_order;
 311         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 312                    || (autocvar_g_waypointeditor_symmetrical < 0));
 313         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 314                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 315         if (sym && ctf_flags < 2)
 316                 ctf_flags = 2;
 317         int wp_num = ctf_flags;
 318
 319         LABEL(remove_wp);
 320         if (!e) return;
 321         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 322
 323         if (e.wphardwired)
 324         {
 325                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 326                 return;
 327         }
 328
 329         entity wp_sym = NULL;
 330         if (sym)
 331         {
 332                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 333                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 334                         if(vdist(org - it.origin, <, 3))
 335                         {
 336                                 wp_sym = it;
 337                                 break;
 338                         }
 339                 });
 340         }
 341
 342         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 343         waypoint_remove(e);
 344
 345         if (sym && wp_sym)
 346         {
 347                 e = wp_sym;
 348                 if(wp_num > 2)
 349                         wp_num--;
 350                 else
 351                         sym = false;
 352                 goto remove_wp;
 353         }
 354 }
 355
 356 void waypoint_removelink(entity from, entity to)
 357 {
 358         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 359                 return;
 360
 361         entity fromwp31_prev = from.wp31;
 362
 363         bool found = false;
 364         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 365         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 366         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 367         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 368         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 369         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 370         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 371         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 372         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 373         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 374         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 375         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 376         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 377         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 378         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 379         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 380         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 381         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 382         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 383         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 384         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 385         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 386         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 387         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 388         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 389         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 390         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 391         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 392         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 393         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 394         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 395         if (!found && from.wp31 == to) found = true; if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 396
 397         if (fromwp31_prev && !from.wp31)
 398                 waypoint_schedulerelink(from);
 399 }
 400
 401 bool waypoint_islinked(entity from, entity to)
 402 {
 403         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 404         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 405         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 406         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 407         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 408         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 409         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 410         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 411         return false;
 412 }
 413
 414 void waypoint_updatecost_foralllinks()
 415 {
 416         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 417         {
 418                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 419                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 420                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 421                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 422                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 423                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 424                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 425                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 426                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 427                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 428                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 429                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 430                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 431                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 432                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 433                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 434                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 435                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 436                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 437                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 438                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 439                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 440                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 441                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 442                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 443                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 444                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 445                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 446                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 447                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 448                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 449                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 450         });
 451 }
 452
 453 float waypoint_getlinearcost(float dist)
 454 {
 455         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 456                 return dist / (autocvar_sv_maxspeed * 1.25);
 457         return dist / autocvar_sv_maxspeed;
 458 }
 459 float waypoint_getlinearcost_underwater(float dist)
 460 {
 461         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 462         return dist / (autocvar_sv_maxspeed * 0.7);
 463 }
 464
 465 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 466 {
 467         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 468         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 469
 470         if (submerged_from && submerged_to)
 471                 return waypoint_getlinearcost_underwater(vlen(to - from));
 472
 473         float c = waypoint_getlinearcost(vlen(to - from));
 474
 475         float height = from.z - to.z;
 476         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 477         {
 478                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 479                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 480                 if(height_cost > c)
 481                         c = height_cost;
 482         }
 483
 484         if (submerged_from || submerged_to)
 485                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 486         return c;
 487 }
 488
 489 float waypoint_getlinkcost(entity from, entity to)
 490 {
 491         vector v1 = from.origin;
 492         vector v2 = to.origin;
 493         if (from.wpisbox)
 494         {
 495                 vector m1 = from.absmin, m2 = from.absmax;
 496                 v1.x = bound(m1.x, v2.x, m2.x);
 497                 v1.y = bound(m1.y, v2.y, m2.y);
 498                 v1.z = bound(m1.z, v2.z, m2.z);
 499         }
 500         if (to.wpisbox)
 501         {
 502                 vector m1 = to.absmin, m2 = to.absmax;
 503                 v2.x = bound(m1.x, v1.x, m2.x);
 504                 v2.y = bound(m1.y, v1.y, m2.y);
 505                 v2.z = bound(m1.z, v1.z, m2.z);
 506         }
 507         return waypoint_gettravelcost(v1, v2, from, to);
 508 }
 509
 510 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 511 // if c == -1 automatically determine cost of the link
 512 void waypoint_addlink_customcost(entity from, entity to, float c)
 513 {
 514         if (from == to || waypoint_islinked(from, to))
 515                 return;
 516         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 517                 return;
 518
 519         if(c == -1)
 520                 c = waypoint_getlinkcost(from, to);
 521
 522         if (from.wp31mincost < c) return;
 523         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 524         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 525         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 526         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 527         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 528         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 529         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 530         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 531         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 532         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 533         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 534         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 535         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 536         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 537         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 538         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 539         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 540         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 541         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 542         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 543         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 544         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 545         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 546         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 547         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 548         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 549         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 550         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 551         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 552         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 553         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 554         from.wp00 = to;from.wp00mincost = c;return;
 555 }
 556
 557 void waypoint_addlink(entity from, entity to)
 558 {
 559         waypoint_addlink_customcost(from, to, -1);
 560 }
 561
 562 // relink this spawnfunc_waypoint
 563 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 564 // (SLOW!)
 565 void waypoint_think(entity this)
 566 {
 567         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 568         float sv2_height = 0, ev2_height = 0;
 569
 570         bot_calculate_stepheightvec();
 571
 572         int dphitcontentsmask_save = this.dphitcontentsmask;
 573         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 574
 575         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 576
 577         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 578         IL_EACH(g_waypoints, this != it,
 579         {
 580                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 581                 {
 582                         waypoint_addlink(this, it);
 583                         waypoint_addlink(it, this);
 584                 }
 585                 else
 586                 {
 587                         ++relink_total;
 588                         if(!checkpvs(this.origin, it))
 589                         {
 590                                 ++relink_pvsculled;
 591                                 continue;
 592                         }
 593
 594                         sv = set_tracewalk_dest_2(this, it.origin);
 595                         sv2 = tracewalk_dest;
 596                         sv2_height = tracewalk_dest_height;
 597                         ev = set_tracewalk_dest_2(it, this.origin);
 598                         ev2 = tracewalk_dest;
 599                         ev2_height = tracewalk_dest_height;
 600
 601                         dv = ev - sv;
 602                         dv.z = 0;
 603                         if(vdist(dv, >=, 1050)) // max search distance in XY
 604                         {
 605                                 ++relink_lengthculled;
 606                                 continue;
 607                         }
 608
 609                         navigation_testtracewalk = 0;
 610
 611                         //traceline(this.origin, it.origin, false, NULL);
 612                         //if (trace_fraction == 1)
 613                         if (this.wpisbox)
 614                                 relink_walkculled += 0.5;
 615                         else
 616                         {
 617                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 618                                         waypoint_addlink(this, it);
 619                                 else
 620                                         relink_walkculled += 0.5;
 621                         }
 622
 623                         if (it.wpisbox)
 624                                 relink_walkculled += 0.5;
 625                         else
 626                         {
 627                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 628                                         waypoint_addlink(it, this);
 629                                 else
 630                                         relink_walkculled += 0.5;
 631                         }
 632                 }
 633         });
 634         navigation_testtracewalk = 0;
 635         this.wplinked = true;
 636         this.dphitcontentsmask = dphitcontentsmask_save;
 637 }
 638
 639 void waypoint_clearlinks(entity wp)
 640 {
 641         // clear links to other waypoints
 642         float f = 10000000;
 643         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 644         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 645         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 646         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 647
 648         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 649         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 650         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 651         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 652
 653         wp.wplinked = false;
 654 }
 655
 656 // tell a spawnfunc_waypoint to relink
 657 void waypoint_schedulerelink(entity wp)
 658 {
 659         if (wp == NULL)
 660                 return;
 661
 662         waypoint_setupmodel(wp);
 663         wp.wpisbox = vdist(wp.size, >, 0);
 664         wp.enemy = NULL;
 665         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 666                 wp.owner = NULL;
 667         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 668                 waypoint_clearlinks(wp);
 669         // schedule an actual relink on next frame
 670         setthink(wp, waypoint_think);
 671         wp.nextthink = time;
 672         wp.effects = EF_LOWPRECISION;
 673 }
 674
 675 // spawnfunc_waypoint map entity
 676 spawnfunc(waypoint)
 677 {
 678         IL_PUSH(g_waypoints, this);
 679
 680         setorigin(this, this.origin);
 681         // schedule a relink after other waypoints have had a chance to spawn
 682         waypoint_clearlinks(this);
 683         //waypoint_schedulerelink(this);
 684 }
 685
 686 // tell all waypoints to relink
 687 // actually this is useful only to update relink_* stats
 688 void waypoint_schedulerelinkall()
 689 {
 690         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 691         IL_EACH(g_waypoints, true,
 692         {
 693                 waypoint_schedulerelink(it);
 694         });
 695         waypoint_load_links_hardwired();
 696 }
 697
 698 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 699
 700 // Load waypoint links from file
 701 bool waypoint_load_links()
 702 {
 703         string s;
 704         float file, tokens, c = 0, found;
 705         entity wp_from = NULL, wp_to;
 706         vector wp_to_pos, wp_from_pos;
 707
 708         string gt_ext = GET_GAMETYPE_EXTENSION();
 709
 710         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 711         file = fopen(filename, FILE_READ);
 712
 713         if (gt_ext != "" && file < 0)
 714         {
 715                 // if race waypoint file doesn't exist load the default one
 716                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 717                 file = fopen(filename, FILE_READ);
 718         }
 719
 720         if (file < 0)
 721         {
 722                 LOG_TRACE("waypoint links load from ", filename, " failed");
 723                 waypoint_schedulerelinkall();
 724                 return false;
 725         }
 726
 727         bool parse_comments = true;
 728         float ver = 0;
 729         string links_time = string_null;
 730
 731         while ((s = fgets(file)))
 732         {
 733                 if(parse_comments)
 734                 {
 735                         if(substring(s, 0, 2) == "//")
 736                         {
 737                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 738                                         ver = stof(substring(s, 19, -1));
 739                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
 740                                         links_time = substring(s, 16, -1);
 741                                 continue;
 742                         }
 743                         else
 744                         {
 745                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
 746                                 {
 747                                         if (links_time != waypoint_time)
 748                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
 749                                         else
 750                                                 LOG_TRACE("waypoint links for this map are outdated.");
 751                                         if (g_assault)
 752                                         {
 753                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
 754                                         }
 755                                         else
 756                                         {
 757                                                 LOG_TRACE("automatically updating...");
 758                                                 waypoint_schedulerelinkall();
 759                                                 fclose(file);
 760                                                 return false;
 761                                         }
 762                                 }
 763                                 parse_comments = false;
 764                         }
 765                 }
 766
 767                 tokens = tokenizebyseparator(s, "*");
 768
 769                 if (tokens!=2)
 770                 {
 771                         // bad file format
 772                         fclose(file);
 773                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
 774                         return false;
 775                 }
 776
 777                 wp_from_pos     = stov(argv(0));
 778                 wp_to_pos       = stov(argv(1));
 779
 780                 // Search "from" waypoint
 781                 if(!wp_from || wp_from.origin!=wp_from_pos)
 782                 {
 783                         wp_from = findradius(wp_from_pos, 1);
 784                         found = false;
 785                         while(wp_from)
 786                         {
 787                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 788                                 if(wp_from.classname == "waypoint")
 789                                 {
 790                                         found = true;
 791                                         break;
 792                                 }
 793                                 wp_from = wp_from.chain;
 794                         }
 795
 796                         if(!found)
 797                         {
 798                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 799                                 continue;
 800                         }
 801                 }
 802
 803                 // Search "to" waypoint
 804                 wp_to = findradius(wp_to_pos, 1);
 805                 found = false;
 806                 while(wp_to)
 807                 {
 808                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 809                         if(wp_to.classname == "waypoint")
 810                         {
 811                                 found = true;
 812                                 break;
 813                         }
 814                         wp_to = wp_to.chain;
 815                 }
 816
 817                 if(!found)
 818                 {
 819                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 820                         continue;
 821                 }
 822
 823                 ++c;
 824                 waypoint_addlink(wp_from, wp_to);
 825         }
 826
 827         fclose(file);
 828
 829         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
 830
 831         bool scheduled = false;
 832         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
 833         {
 834                 if (!it.wp00)
 835                 {
 836                         waypoint_schedulerelink(it);
 837                         scheduled = true;
 838                 }
 839         });
 840         if (scheduled)
 841                 return false;
 842
 843         botframe_cachedwaypointlinks = true;
 844         return true;
 845 }
 846
 847 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 848 {
 849         string s;
 850         float file, tokens, c = 0, found;
 851         entity wp_from = NULL, wp_to;
 852         vector wp_to_pos, wp_from_pos;
 853
 854         string gt_ext = GET_GAMETYPE_EXTENSION();
 855
 856         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
 857         file = fopen(filename, FILE_READ);
 858
 859         if (gt_ext != "" && file < 0)
 860         {
 861                 // if race waypoint file doesn't exist load the default one
 862                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
 863                 file = fopen(filename, FILE_READ);
 864         }
 865
 866         botframe_loadedforcedlinks = true;
 867
 868         if (file < 0)
 869         {
 870                 if(!removal_mode)
 871                         LOG_TRACE("waypoint links load from ", filename, " failed");
 872                 return;
 873         }
 874
 875         while ((s = fgets(file)))
 876         {
 877                 if(substring(s, 0, 2)=="//")
 878                         continue;
 879
 880                 if(substring(s, 0, 1)=="#")
 881                         continue;
 882
 883                 tokens = tokenizebyseparator(s, "*");
 884
 885                 if (tokens!=2)
 886                         continue;
 887
 888                 wp_from_pos     = stov(argv(0));
 889                 wp_to_pos       = stov(argv(1));
 890
 891                 // Search "from" waypoint
 892                 if(!wp_from || wp_from.origin!=wp_from_pos)
 893                 {
 894                         wp_from = findradius(wp_from_pos, 5);
 895                         found = false;
 896                         while(wp_from)
 897                         {
 898                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 899                                 if(wp_from.classname == "waypoint")
 900                                 {
 901                                         found = true;
 902                                         break;
 903                                 }
 904                                 wp_from = wp_from.chain;
 905                         }
 906
 907                         if(!found)
 908                         {
 909                                 if(!removal_mode)
 910                                         LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
 911                                 continue;
 912                         }
 913                 }
 914
 915                 // Search "to" waypoint
 916                 wp_to = findradius(wp_to_pos, 5);
 917                 found = false;
 918                 while(wp_to)
 919                 {
 920                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 921                         if(wp_to.classname == "waypoint")
 922                         {
 923                                 found = true;
 924                                 break;
 925                         }
 926                         wp_to = wp_to.chain;
 927                 }
 928
 929                 if(!found)
 930                 {
 931                         if(!removal_mode)
 932                                 LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
 933                         continue;
 934                 }
 935
 936                 ++c;
 937                 if(removal_mode)
 938                 {
 939                         waypoint_removelink(wp_from, wp_to);
 940                         continue;
 941                 }
 942
 943                 waypoint_addlink(wp_from, wp_to);
 944                 wp_from.wphardwired = true;
 945                 wp_to.wphardwired = true;
 946                 waypoint_setupmodel(wp_from);
 947                 waypoint_setupmodel(wp_to);
 948         }
 949
 950         fclose(file);
 951
 952         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
 953                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 954 }
 955
 956 entity waypoint_get_link(entity w, float i)
 957 {
 958         switch(i)
 959         {
 960                 case  0:return w.wp00;
 961                 case  1:return w.wp01;
 962                 case  2:return w.wp02;
 963                 case  3:return w.wp03;
 964                 case  4:return w.wp04;
 965                 case  5:return w.wp05;
 966                 case  6:return w.wp06;
 967                 case  7:return w.wp07;
 968                 case  8:return w.wp08;
 969                 case  9:return w.wp09;
 970                 case 10:return w.wp10;
 971                 case 11:return w.wp11;
 972                 case 12:return w.wp12;
 973                 case 13:return w.wp13;
 974                 case 14:return w.wp14;
 975                 case 15:return w.wp15;
 976                 case 16:return w.wp16;
 977                 case 17:return w.wp17;
 978                 case 18:return w.wp18;
 979                 case 19:return w.wp19;
 980                 case 20:return w.wp20;
 981                 case 21:return w.wp21;
 982                 case 22:return w.wp22;
 983                 case 23:return w.wp23;
 984                 case 24:return w.wp24;
 985                 case 25:return w.wp25;
 986                 case 26:return w.wp26;
 987                 case 27:return w.wp27;
 988                 case 28:return w.wp28;
 989                 case 29:return w.wp29;
 990                 case 30:return w.wp30;
 991                 case 31:return w.wp31;
 992                 default:return NULL;
 993         }
 994 }
 995
 996 // Save all waypoint links to a file
 997 void waypoint_save_links()
 998 {
 999         // temporarily remove hardwired links so they don't get saved among normal links
1000         waypoint_remove_links_hardwired();
1001
1002         string gt_ext = GET_GAMETYPE_EXTENSION();
1003
1004         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1005         int file = fopen(filename, FILE_WRITE);
1006         if (file < 0)
1007         {
1008                 LOG_INFOF("waypoint link save to %s failed", filename);
1009                 return;
1010         }
1011
1012         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1013         if (waypoint_time != "")
1014                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1015
1016         int c = 0;
1017         IL_EACH(g_waypoints, true,
1018         {
1019                 for(int j = 0; j < 32; ++j)
1020                 {
1021                         entity link = waypoint_get_link(it, j);
1022                         if(link)
1023                         {
1024                                 // NOTE: vtos rounds vector components to 1 decimal place
1025                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1026                                 fputs(file, s);
1027                                 ++c;
1028                         }
1029                 }
1030         });
1031         fclose(file);
1032
1033         botframe_cachedwaypointlinks = true;
1034
1035         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1036
1037         waypoint_load_links_hardwired();
1038 }
1039
1040 // save waypoints to gamedir/data/maps/mapname.waypoints
1041 void waypoint_saveall()
1042 {
1043         string gt_ext = GET_GAMETYPE_EXTENSION();
1044
1045         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1046         int file = fopen(filename, FILE_WRITE);
1047         if (file < 0)
1048         {
1049                 waypoint_save_links(); // save anyway?
1050                 botframe_loadedforcedlinks = false;
1051
1052                 LOG_INFOF("waypoint links: save to %s failed", filename);
1053                 return;
1054         }
1055
1056         float sym = autocvar_g_waypointeditor_symmetrical;
1057         string sym_str = ftos(sym);
1058         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1059         {
1060                 if (sym == 1)
1061                 {
1062                         sym_str = cons(sym_str, "-");
1063                         sym_str = cons(sym_str, "-");
1064                 }
1065                 else
1066                 {
1067                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1068                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1069                 }
1070                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1071                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1072         }
1073         else if (autocvar_g_waypointeditor_symmetrical == -2)
1074         {
1075                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1076                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1077         }
1078
1079         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1080         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1081         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1082         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1083
1084         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1085         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1086         //fputs(file, strcat("//", "\n"));
1087         //fputs(file, strcat("//", "\n"));
1088         //fputs(file, strcat("//", "\n"));
1089
1090         int c = 0;
1091         IL_EACH(g_waypoints, true,
1092         {
1093                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1094                         continue;
1095
1096                 string s;
1097                 // NOTE: vtos rounds vector components to 1 decimal place
1098                 s = strcat(vtos(it.origin + it.mins), "\n");
1099                 s = strcat(s, vtos(it.origin + it.maxs));
1100                 s = strcat(s, "\n");
1101                 s = strcat(s, ftos(it.wpflags));
1102                 s = strcat(s, "\n");
1103                 fputs(file, s);
1104                 c++;
1105         });
1106         fclose(file);
1107         waypoint_save_links();
1108         botframe_loadedforcedlinks = false;
1109
1110         LOG_INFOF("saved %d waypoints to %s", c, filename);
1111 }
1112
1113 // load waypoints from file
1114 float waypoint_loadall()
1115 {
1116         string s;
1117         float file, cwp, cwb, fl;
1118         vector m1, m2;
1119         cwp = 0;
1120         cwb = 0;
1121
1122         string gt_ext = GET_GAMETYPE_EXTENSION();
1123
1124         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1125         file = fopen(filename, FILE_READ);
1126
1127         if (gt_ext != "" && file < 0)
1128         {
1129                 // if race waypoint file doesn't exist load the default one
1130                 filename = sprintf("maps/%s.waypoints", mapname);
1131                 file = fopen(filename, FILE_READ);
1132         }
1133
1134         if (file < 0)
1135         {
1136                 LOG_TRACE("waypoint load from ", filename, " failed");
1137                 return 0;
1138         }
1139
1140         bool parse_comments = true;
1141         float ver = 0;
1142         float sym = 0;
1143         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1144
1145         while ((s = fgets(file)))
1146         {
1147                 if(parse_comments)
1148                 {
1149                         if(substring(s, 0, 2) == "//")
1150                         {
1151                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1152                                         ver = stof(substring(s, 19, -1));
1153                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1154                                 {
1155                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1156                                         if (tokens) { sym = stof(argv(0)); }
1157                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1158                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1159                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1160                                 }
1161                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1162                                         strcpy(waypoint_time, substring(s, 16, -1));
1163                                 continue;
1164                         }
1165                         else
1166                         {
1167                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1168                                 {
1169                                         LOG_TRACE("waypoints for this map are outdated");
1170                                         LOG_TRACE("please update them in the editor");
1171                                 }
1172                                 parse_comments = false;
1173                         }
1174                 }
1175                 m1 = stov(s);
1176                 s = fgets(file);
1177                 if (!s)
1178                         break;
1179                 m2 = stov(s);
1180                 s = fgets(file);
1181                 if (!s)
1182                         break;
1183                 fl = stof(s);
1184                 waypoint_spawn(m1, m2, fl);
1185                 if (m1 == m2)
1186                         cwp = cwp + 1;
1187                 else
1188                         cwb = cwb + 1;
1189         }
1190         fclose(file);
1191         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1192
1193         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1194         {
1195                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1196                 if (sym == 1 && sym_param3 < 2)
1197                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1198                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1199                 {
1200                         string params;
1201                         if (sym == 1)
1202                                 params = cons("-", "-");
1203                         else
1204                         {
1205                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1206                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1207                         }
1208                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1209                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1210                 }
1211                 else if (sym == -2)
1212                 {
1213                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1214                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1215                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1216                 }
1217                 else
1218                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1219                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1220         }
1221
1222         return cwp + cwb;
1223 }
1224
1225 #define waypoint_fixorigin(position, tracetest_ent) \
1226         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1227
1228 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1229 {
1230         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1231         if(trace_startsolid)
1232                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1233         if(trace_startsolid)
1234                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1235         if(trace_fraction < 1)
1236                 position = trace_endpos;
1237         return position;
1238 }
1239
1240 void waypoint_spawnforitem_force(entity e, vector org)
1241 {
1242         // Fix the waypoint altitude if necessary
1243         org = waypoint_fixorigin(org, NULL);
1244
1245         // don't spawn an item spawnfunc_waypoint if it already exists
1246         IL_EACH(g_waypoints, true,
1247         {
1248                 if(it.wpisbox)
1249                 {
1250                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1251                         {
1252                                 e.nearestwaypoint = it;
1253                                 return;
1254                         }
1255                 }
1256                 else
1257                 {
1258                         if(vdist(it.origin - org, <, 16))
1259                         {
1260                                 e.nearestwaypoint = it;
1261                                 return;
1262                         }
1263                 }
1264         });
1265
1266         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1267 }
1268
1269 void waypoint_spawnforitem(entity e)
1270 {
1271         if(!bot_waypoints_for_items)
1272                 return;
1273
1274         waypoint_spawnforitem_force(e, e.origin);
1275 }
1276
1277 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1278 {
1279         entity w;
1280         entity dw;
1281         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1282         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1283         // one way link to the destination
1284         w.wp00 = dw;
1285         w.wp00mincost = timetaken; // this is just for jump pads
1286         // the teleporter's nearest spawnfunc_waypoint is this one
1287         // (teleporters are not goals, so this is probably useless)
1288         e.nearestwaypoint = w;
1289         e.nearestwaypointtimeout = -1;
1290 }
1291
1292 void waypoint_spawnforteleporter_wz(entity e, vector org, vector destination, float timetaken, vector down_dir, entity tracetest_ent)
1293 {
1294         // warpzones with oblique warp plane rely on down_dir to snap waypoints
1295         // to the ground without leaving the warp plane
1296         // warpzones with horizontal warp plane (down_dir.x == -1) generate
1297         // destination waypoint snapped to the ground (leaving warpzone), source
1298         // waypoint in the center of the warp plane
1299         if(down_dir.x != -1)
1300                 org = waypoint_fixorigin_down_dir(org, tracetest_ent, down_dir);
1301         if(down_dir.x == -1)
1302                 down_dir = '0 0 -1';
1303         destination = waypoint_fixorigin_down_dir(destination, tracetest_ent, down_dir);
1304         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1305 }
1306
1307 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1308 {
1309         destination = waypoint_fixorigin(destination, tracetest_ent);
1310         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1311 }
1312
1313 entity waypoint_spawnpersonal(entity this, vector position)
1314 {
1315         entity w;
1316
1317         // drop the waypoint to a proper location:
1318         //   first move it up by a player height
1319         //   then move it down to hit the floor with player bbox size
1320         position = waypoint_fixorigin(position, this);
1321
1322         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1323         w.nearestwaypoint = NULL;
1324         w.nearestwaypointtimeout = 0;
1325         w.owner = this;
1326
1327         waypoint_schedulerelink(w);
1328
1329         return w;
1330 }
1331
1332 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1333 {
1334         if (!(wp1 && wp2))
1335                 return;
1336
1337         if (wp1.wphardwired && wp2.wphardwired)
1338                 te_beam(NULL, wp1.origin, wp2.origin);
1339         else if (display_type == 1)
1340                 te_lightning2(NULL, wp1.origin, wp2.origin);
1341 }
1342
1343 void waypoint_showlinks_to(entity wp, int display_type)
1344 {
1345         IL_EACH(g_waypoints, it != wp,
1346         {
1347                 if (waypoint_islinked(it, wp))
1348                         waypoint_showlink(it, wp, display_type);
1349         });
1350 }
1351
1352 void waypoint_showlinks_from(entity wp, int display_type)
1353 {
1354         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1355         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1356         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1357         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1358         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1359         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1360         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1361         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1362         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1363         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1364         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1365         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1366         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1367         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1368         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1369         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1370 }
1371
1372 void botframe_showwaypointlinks()
1373 {
1374         if (time < botframe_waypointeditorlightningtime)
1375                 return;
1376         botframe_waypointeditorlightningtime = time + 0.5;
1377         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1378         {
1379                 int display_type = 0;
1380                 entity head = navigation_findnearestwaypoint(it, false);
1381                 it.nearestwaypoint = head; // mainly useful for debug
1382                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1383                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1384                         display_type = 1; // default
1385                 else if(head && (head.wphardwired))
1386                         display_type = 2; // only hardwired
1387
1388                 if (display_type)
1389                 {
1390                         //navigation_testtracewalk = true;
1391                         //print("currently selected WP is ", etos(head), "\n");
1392                         //navigation_testtracewalk = false;
1393                         if (head)
1394                         {
1395                                 te_lightning2(NULL, head.origin, it.origin);
1396                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1397                                         waypoint_showlinks_to(head, display_type);
1398                                 else
1399                                         waypoint_showlinks_from(head, display_type);
1400                         }
1401                 }
1402         });
1403 }
1404
1405 float botframe_autowaypoints_fixdown(vector v)
1406 {
1407         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1408         if(trace_fraction >= 1)
1409                 return 0;
1410         return 1;
1411 }
1412
1413 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1414 {
1415         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1416         {
1417                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1418                 return 0;
1419         });
1420
1421         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1422         return 1;
1423 }
1424
1425 // return value:
1426 //    1 = WP created
1427 //    0 = no action needed
1428 //   -1 = temp fail, try from world too
1429 //   -2 = permanent fail, do not retry
1430 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1431 {
1432         // make it possible to go from p to wp, if we can
1433         // if wp is NULL, nearest is chosen
1434
1435         entity w;
1436         vector porg;
1437         float t, tmin, tmax;
1438         vector o;
1439         vector save;
1440
1441         if(!botframe_autowaypoints_fixdown(p.origin))
1442                 return -2;
1443         porg = trace_endpos;
1444
1445         if(wp)
1446         {
1447                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1448
1449                 // if wp -> porg, then OK
1450                 float maxdist;
1451                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1452                 {
1453                         // we may find a better one
1454                         maxdist = vlen(wp.origin - porg);
1455                 }
1456                 else
1457                 {
1458                         // accept any "good"
1459                         maxdist = 2100;
1460                 }
1461
1462                 float bestdist = maxdist;
1463                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1464                 {
1465                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1466                         if(d < bestdist)
1467                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1468                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1469                         {
1470                                 bestdist = d;
1471                                 p.(fld) = it;
1472                         }
1473                 });
1474                 if(bestdist < maxdist)
1475                 {
1476                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1477                         return 0;
1478                 }
1479
1480                 if(bestdist < 2100)
1481                 {
1482                         // we know maxdist < 2100
1483                         // so wp -> porg is still valid
1484                         // all is good
1485                         p.(fld) = wp;
1486                         return 0;
1487                 }
1488
1489                 // otherwise, no existing WP can fix our issues
1490         }
1491         else
1492         {
1493                 save = p.origin;
1494                 setorigin(p, porg);
1495                 w = navigation_findnearestwaypoint(p, walkfromwp);
1496                 setorigin(p, save);
1497                 if(w)
1498                 {
1499                         p.(fld) = w;
1500                         return 0;
1501                 }
1502         }
1503
1504         tmin = 0;
1505         tmax = 1;
1506         for (;;)
1507         {
1508                 if(tmax - tmin < 0.001)
1509                 {
1510                         // did not get a good candidate
1511                         return -1;
1512                 }
1513
1514                 t = (tmin + tmax) * 0.5;
1515                 o = antilag_takebackorigin(p, CS(p), time - t);
1516                 if(!botframe_autowaypoints_fixdown(o))
1517                         return -2;
1518                 o = trace_endpos;
1519
1520                 if(wp)
1521                 {
1522                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1523                         {
1524                                 // we cannot walk from wp.origin to o
1525                                 // get closer to tmax
1526                                 tmin = t;
1527                                 continue;
1528                         }
1529                 }
1530                 else
1531                 {
1532                         save = p.origin;
1533                         setorigin(p, o);
1534                         w = navigation_findnearestwaypoint(p, walkfromwp);
1535                         setorigin(p, save);
1536                         if(!w)
1537                         {
1538                                 // we cannot walk from any WP to o
1539                                 // get closer to tmax
1540                                 tmin = t;
1541                                 continue;
1542                         }
1543                 }
1544
1545                 // if we get here, o is valid regarding waypoints
1546                 // check if o is connected right to the player
1547                 // we break if it succeeds, as that means o is a good waypoint location
1548                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1549                         break;
1550
1551                 // o is no good, we need to get closer to the player
1552                 tmax = t;
1553         }
1554
1555         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1556         botframe_autowaypoints_createwp(o, p, fld, 0);
1557         return 1;
1558 }
1559
1560 // automatically create missing waypoints
1561 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1562 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1563 {
1564         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1565         if(r != -1)
1566                 return;
1567         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1568         if(r != -1)
1569                 return;
1570
1571         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1572         if(!botframe_autowaypoints_fixdown(p.origin))
1573                 return; // shouldn't happen, caught above
1574         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1575 }
1576
1577 void botframe_deleteuselesswaypoints()
1578 {
1579         IL_EACH(g_items, it.bot_pickup,
1580         {
1581                 // NOTE: this protects waypoints if they're the ONLY nearest
1582                 // waypoint. That's the intention.
1583                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1584                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1585         });
1586         IL_EACH(g_waypoints, true,
1587         {
1588                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1589                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1590                 // WP is useful if:
1591                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1592                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1593                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1594                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1595                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1596                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1597                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1598                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1599                 // b) WP is closest WP for an item/spawnpoint/other entity
1600                 //    This has been done above by protecting these WPs.
1601         });
1602         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1603         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1604         {
1605                 for (int m = 0; m < 32; ++m)
1606                 {
1607                         entity w = waypoint_get_link(it, m);
1608                         if (!w)
1609                                 break;
1610                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1611                                 continue;
1612                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1613                                 continue;
1614                         for (int j = 0; j < 32; ++j)
1615                         {
1616                                 entity w2 = waypoint_get_link(w, j);
1617                                 if (!w2)
1618                                         break;
1619                                 if (it == w2)
1620                                         continue;
1621                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1622                                         continue;
1623                                 // If we got here, it != w2 exist with it -> w
1624                                 // and w -> w2. That means the waypoint is not
1625                                 // a dead end.
1626                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1627                                 for (int k = 0; k < 32; ++k)
1628                                 {
1629                                         if (waypoint_get_link(it, k) == w2)
1630                                                 continue;
1631                                         // IF WE GET HERE, w is proven useful
1632                                         // to get from it to w2!
1633                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1634                                         goto next;
1635                                 }
1636                         }
1637 LABEL(next)
1638                 }
1639         });
1640         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1641         //     they are needed to complete routes while autowaypointing.
1642
1643         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1644         {
1645                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1646                 te_explosion(it.origin);
1647                 waypoint_remove(it);
1648                 break;
1649         });
1650
1651         IL_EACH(g_waypoints, true,
1652         {
1653                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1654         });
1655 }
1656
1657 void botframe_autowaypoints()
1658 {
1659         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1660                 // going back is broken, so only fix waypoints to walk TO the player
1661                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1662                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1663                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1664         });
1665
1666         if (autocvar_g_waypointeditor_auto >= 2) {
1667                 botframe_deleteuselesswaypoints();
1668         }
1669 }
1670