qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14
  15 #include <lib/warpzone/common.qh>
  16 #include <lib/warpzone/util_server.qh>
  17
  18 void waypoint_setupmodel(entity wp)
  19 {
  20         if (autocvar_g_waypointeditor)
  21         {
  22                 // TODO: add some sort of visible box in edit mode for box waypoints
  23                 vector m1 = wp.mins;
  24                 vector m2 = wp.maxs;
  25                 setmodel(wp, MDL_WAYPOINT);
  26                 setsize(wp, m1, m2);
  27                 wp.effects = EF_LOWPRECISION;
  28                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
  29                         wp.colormod = '1 0 0';
  30                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
  31                         wp.colormod = '1 1 0';
  32                 else
  33                         wp.colormod = '1 1 1';
  34         }
  35         else
  36                 wp.model = "";
  37 }
  38
  39 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
  40 // them back to it as well
  41 // (suitable for spawnfunc_waypoint editor)
  42 entity waypoint_spawn(vector m1, vector m2, float f)
  43 {
  44         if(!(f & WAYPOINTFLAG_PERSONAL))
  45         {
  46                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
  47                 {
  48                         return it;
  49                 });
  50         }
  51
  52         entity w = new(waypoint);
  53         IL_PUSH(g_waypoints, w);
  54         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
  55         w.wpflags = f;
  56         w.solid = SOLID_TRIGGER;
  57         setorigin(w, (m1 + m2) * 0.5);
  58         setsize(w, m1 - w.origin, m2 - w.origin);
  59         if (w.size)
  60                 w.wpisbox = true;
  61
  62         if(!w.wpisbox)
  63         {
  64                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
  65                 if(!move_out_of_solid(w))
  66                 {
  67                         if(!(f & WAYPOINTFLAG_GENERATED))
  68                         {
  69                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
  70                                 delete(w);
  71                                 return NULL;
  72                         }
  73                         else
  74                         {
  75                                 if(autocvar_developer)
  76                                 {
  77                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
  78                                         backtrace("Waypoint stuck");
  79                                 }
  80                         }
  81                 }
  82                 setsize(w, '0 0 0', '0 0 0');
  83         }
  84
  85         waypoint_clearlinks(w);
  86         //waypoint_schedulerelink(w);
  87
  88         waypoint_setupmodel(w);
  89
  90         return w;
  91 }
  92
  93 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
  94 void waypoint_addlink(entity from, entity to)
  95 {
  96         float c;
  97
  98         if (from == to)
  99                 return;
 100         if (from.wpflags & WAYPOINTFLAG_NORELINK)
 101                 return;
 102
 103         if (from.wp00 == to) return;if (from.wp01 == to) return;if (from.wp02 == to) return;if (from.wp03 == to) return;
 104         if (from.wp04 == to) return;if (from.wp05 == to) return;if (from.wp06 == to) return;if (from.wp07 == to) return;
 105         if (from.wp08 == to) return;if (from.wp09 == to) return;if (from.wp10 == to) return;if (from.wp11 == to) return;
 106         if (from.wp12 == to) return;if (from.wp13 == to) return;if (from.wp14 == to) return;if (from.wp15 == to) return;
 107         if (from.wp16 == to) return;if (from.wp17 == to) return;if (from.wp18 == to) return;if (from.wp19 == to) return;
 108         if (from.wp20 == to) return;if (from.wp21 == to) return;if (from.wp22 == to) return;if (from.wp23 == to) return;
 109         if (from.wp24 == to) return;if (from.wp25 == to) return;if (from.wp26 == to) return;if (from.wp27 == to) return;
 110         if (from.wp28 == to) return;if (from.wp29 == to) return;if (from.wp30 == to) return;if (from.wp31 == to) return;
 111
 112         if (to.wpisbox || from.wpisbox)
 113         {
 114                 // if either is a box we have to find the nearest points on them to
 115                 // calculate the distance properly
 116                 vector v1, v2, m1, m2;
 117                 v1 = from.origin;
 118                 m1 = to.absmin;
 119                 m2 = to.absmax;
 120                 v1_x = bound(m1_x, v1_x, m2_x);
 121                 v1_y = bound(m1_y, v1_y, m2_y);
 122                 v1_z = bound(m1_z, v1_z, m2_z);
 123                 v2 = to.origin;
 124                 m1 = from.absmin;
 125                 m2 = from.absmax;
 126                 v2_x = bound(m1_x, v2_x, m2_x);
 127                 v2_y = bound(m1_y, v2_y, m2_y);
 128                 v2_z = bound(m1_z, v2_z, m2_z);
 129                 v2 = to.origin;
 130                 c = vlen(v2 - v1);
 131         }
 132         else
 133                 c = vlen(to.origin - from.origin);
 134
 135         if (from.wp31mincost < c) return;
 136         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 137         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 138         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 139         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 140         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 141         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 142         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 143         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 144         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 145         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 146         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 147         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 148         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 149         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 150         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 151         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 152         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 153         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 154         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 155         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 156         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 157         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 158         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 159         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 160         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 161         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 162         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 163         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 164         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 165         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 166         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 167         from.wp00 = to;from.wp00mincost = c;return;
 168 }
 169
 170 // relink this spawnfunc_waypoint
 171 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 172 // (SLOW!)
 173 void waypoint_think(entity this)
 174 {
 175         vector sv, sm1, sm2, ev, em1, em2, dv;
 176
 177         bot_calculate_stepheightvec();
 178
 179         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 180
 181         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 182         sm1 = this.origin + this.mins;
 183         sm2 = this.origin + this.maxs;
 184         IL_EACH(g_waypoints, true,
 185         {
 186                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 187                 {
 188                         waypoint_addlink(this, it);
 189                         waypoint_addlink(it, this);
 190                 }
 191                 else
 192                 {
 193                         ++relink_total;
 194                         if(!checkpvs(this.origin, it))
 195                         {
 196                                 ++relink_pvsculled;
 197                                 continue;
 198                         }
 199                         sv = it.origin;
 200                         sv.x = bound(sm1_x, sv.x, sm2_x);
 201                         sv.y = bound(sm1_y, sv.y, sm2_y);
 202                         sv.z = bound(sm1_z, sv.z, sm2_z);
 203                         ev = this.origin;
 204                         em1 = it.origin + it.mins;
 205                         em2 = it.origin + it.maxs;
 206                         ev.x = bound(em1_x, ev.x, em2_x);
 207                         ev.y = bound(em1_y, ev.y, em2_y);
 208                         ev.z = bound(em1_z, ev.z, em2_z);
 209                         dv = ev - sv;
 210                         dv.z = 0;
 211                         if(vdist(dv, >=, 1050)) // max search distance in XY
 212                         {
 213                                 ++relink_lengthculled;
 214                                 continue;
 215                         }
 216                         navigation_testtracewalk = 0;
 217                         if (!this.wpisbox)
 218                         {
 219                                 tracebox(sv - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, sv, false, this);
 220                                 if (!trace_startsolid)
 221                                 {
 222                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 223                                         sv = trace_endpos + '0 0 1';
 224                                 }
 225                         }
 226                         if (!it.wpisbox)
 227                         {
 228                                 tracebox(ev - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, ev, false, it);
 229                                 if (!trace_startsolid)
 230                                 {
 231                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 232                                         ev = trace_endpos + '0 0 1';
 233                                 }
 234                         }
 235                         //traceline(this.origin, it.origin, false, NULL);
 236                         //if (trace_fraction == 1)
 237                         if (!this.wpisbox && tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev, MOVE_NOMONSTERS))
 238                                 waypoint_addlink(this, it);
 239                         else
 240                                 relink_walkculled += 0.5;
 241                         if (!it.wpisbox && tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv, MOVE_NOMONSTERS))
 242                                 waypoint_addlink(it, this);
 243                         else
 244                                 relink_walkculled += 0.5;
 245                 }
 246         });
 247         navigation_testtracewalk = 0;
 248         this.wplinked = true;
 249 }
 250
 251 void waypoint_clearlinks(entity wp)
 252 {
 253         // clear links to other waypoints
 254         float f;
 255         f = 10000000;
 256         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 257         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 258         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 259         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 260
 261         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 262         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 263         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 264         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 265
 266         wp.wplinked = false;
 267 }
 268
 269 // tell a spawnfunc_waypoint to relink
 270 void waypoint_schedulerelink(entity wp)
 271 {
 272         if (wp == NULL)
 273                 return;
 274
 275         waypoint_setupmodel(wp);
 276         wp.wpisbox = vdist(wp.size, >, 0);
 277         wp.enemy = NULL;
 278         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 279                 wp.owner = NULL;
 280         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 281                 waypoint_clearlinks(wp);
 282         // schedule an actual relink on next frame
 283         setthink(wp, waypoint_think);
 284         wp.nextthink = time;
 285         wp.effects = EF_LOWPRECISION;
 286 }
 287
 288 // spawnfunc_waypoint map entity
 289 spawnfunc(waypoint)
 290 {
 291         IL_PUSH(g_waypoints, this);
 292
 293         setorigin(this, this.origin);
 294         // schedule a relink after other waypoints have had a chance to spawn
 295         waypoint_clearlinks(this);
 296         //waypoint_schedulerelink(this);
 297 }
 298
 299 // remove a spawnfunc_waypoint, and schedule all neighbors to relink
 300 void waypoint_remove(entity e)
 301 {
 302         // tell all linked waypoints that they need to relink
 303         waypoint_schedulerelink(e.wp00);
 304         waypoint_schedulerelink(e.wp01);
 305         waypoint_schedulerelink(e.wp02);
 306         waypoint_schedulerelink(e.wp03);
 307         waypoint_schedulerelink(e.wp04);
 308         waypoint_schedulerelink(e.wp05);
 309         waypoint_schedulerelink(e.wp06);
 310         waypoint_schedulerelink(e.wp07);
 311         waypoint_schedulerelink(e.wp08);
 312         waypoint_schedulerelink(e.wp09);
 313         waypoint_schedulerelink(e.wp10);
 314         waypoint_schedulerelink(e.wp11);
 315         waypoint_schedulerelink(e.wp12);
 316         waypoint_schedulerelink(e.wp13);
 317         waypoint_schedulerelink(e.wp14);
 318         waypoint_schedulerelink(e.wp15);
 319         waypoint_schedulerelink(e.wp16);
 320         waypoint_schedulerelink(e.wp17);
 321         waypoint_schedulerelink(e.wp18);
 322         waypoint_schedulerelink(e.wp19);
 323         waypoint_schedulerelink(e.wp20);
 324         waypoint_schedulerelink(e.wp21);
 325         waypoint_schedulerelink(e.wp22);
 326         waypoint_schedulerelink(e.wp23);
 327         waypoint_schedulerelink(e.wp24);
 328         waypoint_schedulerelink(e.wp25);
 329         waypoint_schedulerelink(e.wp26);
 330         waypoint_schedulerelink(e.wp27);
 331         waypoint_schedulerelink(e.wp28);
 332         waypoint_schedulerelink(e.wp29);
 333         waypoint_schedulerelink(e.wp30);
 334         waypoint_schedulerelink(e.wp31);
 335         // and now remove the spawnfunc_waypoint
 336         delete(e);
 337 }
 338
 339 // empties the map of waypoints
 340 void waypoint_removeall()
 341 {
 342         IL_EACH(g_waypoints, true,
 343         {
 344                 delete(it);
 345         });
 346 }
 347
 348 // tell all waypoints to relink
 349 // (is this useful at all?)
 350 void waypoint_schedulerelinkall()
 351 {
 352         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 353         IL_EACH(g_waypoints, true,
 354         {
 355                 waypoint_schedulerelink(it);
 356         });
 357 }
 358
 359 // Load waypoint links from file
 360 float waypoint_load_links()
 361 {
 362         string filename, s;
 363         float file, tokens, c = 0, found;
 364         entity wp_from = NULL, wp_to;
 365         vector wp_to_pos, wp_from_pos;
 366         filename = strcat("maps/", mapname);
 367         filename = strcat(filename, ".waypoints.cache");
 368         file = fopen(filename, FILE_READ);
 369
 370         if (file < 0)
 371         {
 372                 LOG_TRACE("waypoint links load from ");
 373                 LOG_TRACE(filename);
 374                 LOG_TRACE(" failed");
 375                 return false;
 376         }
 377
 378         while ((s = fgets(file)))
 379         {
 380                 tokens = tokenizebyseparator(s, "*");
 381
 382                 if (tokens!=2)
 383                 {
 384                         // bad file format
 385                         fclose(file);
 386                         return false;
 387                 }
 388
 389                 wp_from_pos     = stov(argv(0));
 390                 wp_to_pos       = stov(argv(1));
 391
 392                 // Search "from" waypoint
 393                 if(!wp_from || wp_from.origin!=wp_from_pos)
 394                 {
 395                         wp_from = findradius(wp_from_pos, 1);
 396                         found = false;
 397                         while(wp_from)
 398                         {
 399                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 400                                 if(wp_from.classname == "waypoint")
 401                                 {
 402                                         found = true;
 403                                         break;
 404                                 }
 405                                 wp_from = wp_from.chain;
 406                         }
 407
 408                         if(!found)
 409                         {
 410                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from.origin));
 411                                 continue;
 412                         }
 413
 414                 }
 415
 416                 // Search "to" waypoint
 417                 wp_to = findradius(wp_to_pos, 1);
 418                 found = false;
 419                 while(wp_to)
 420                 {
 421                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 422                         if(wp_to.classname == "waypoint")
 423                         {
 424                                 found = true;
 425                                 break;
 426                         }
 427                         wp_to = wp_to.chain;
 428                 }
 429
 430                 if(!found)
 431                 {
 432                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to.origin));
 433                         continue;
 434                 }
 435
 436                 ++c;
 437                 waypoint_addlink(wp_from, wp_to);
 438         }
 439
 440         fclose(file);
 441
 442         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 443
 444         botframe_cachedwaypointlinks = true;
 445         return true;
 446 }
 447
 448 void waypoint_load_links_hardwired()
 449 {
 450         string filename, s;
 451         float file, tokens, c = 0, found;
 452         entity wp_from = NULL, wp_to;
 453         vector wp_to_pos, wp_from_pos;
 454         filename = strcat("maps/", mapname);
 455         filename = strcat(filename, ".waypoints.hardwired");
 456         file = fopen(filename, FILE_READ);
 457
 458         botframe_loadedforcedlinks = true;
 459
 460         if (file < 0)
 461         {
 462                 LOG_TRACE("waypoint links load from ", filename, " failed");
 463                 return;
 464         }
 465
 466         while ((s = fgets(file)))
 467         {
 468                 if(substring(s, 0, 2)=="//")
 469                         continue;
 470
 471                 if(substring(s, 0, 1)=="#")
 472                         continue;
 473
 474                 tokens = tokenizebyseparator(s, "*");
 475
 476                 if (tokens!=2)
 477                         continue;
 478
 479                 wp_from_pos     = stov(argv(0));
 480                 wp_to_pos       = stov(argv(1));
 481
 482                 // Search "from" waypoint
 483                 if(!wp_from || wp_from.origin!=wp_from_pos)
 484                 {
 485                         wp_from = findradius(wp_from_pos, 5);
 486                         found = false;
 487                         while(wp_from)
 488                         {
 489                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 490                                 if(wp_from.classname == "waypoint")
 491                                 {
 492                                         found = true;
 493                                         break;
 494                                 }
 495                                 wp_from = wp_from.chain;
 496                         }
 497
 498                         if(!found)
 499                         {
 500                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 501                                 continue;
 502                         }
 503                 }
 504
 505                 // Search "to" waypoint
 506                 wp_to = findradius(wp_to_pos, 5);
 507                 found = false;
 508                 while(wp_to)
 509                 {
 510                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 511                         if(wp_to.classname == "waypoint")
 512                         {
 513                                 found = true;
 514                                 break;
 515                         }
 516                         wp_to = wp_to.chain;
 517                 }
 518
 519                 if(!found)
 520                 {
 521                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 522                         continue;
 523                 }
 524
 525                 ++c;
 526                 waypoint_addlink(wp_from, wp_to);
 527                 wp_from.wphardwired = true;
 528                 wp_to.wphardwired = true;
 529         }
 530
 531         fclose(file);
 532
 533         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 534 }
 535
 536 entity waypoint_get_link(entity w, float i)
 537 {
 538         switch(i)
 539         {
 540                 case  0:return w.wp00;
 541                 case  1:return w.wp01;
 542                 case  2:return w.wp02;
 543                 case  3:return w.wp03;
 544                 case  4:return w.wp04;
 545                 case  5:return w.wp05;
 546                 case  6:return w.wp06;
 547                 case  7:return w.wp07;
 548                 case  8:return w.wp08;
 549                 case  9:return w.wp09;
 550                 case 10:return w.wp10;
 551                 case 11:return w.wp11;
 552                 case 12:return w.wp12;
 553                 case 13:return w.wp13;
 554                 case 14:return w.wp14;
 555                 case 15:return w.wp15;
 556                 case 16:return w.wp16;
 557                 case 17:return w.wp17;
 558                 case 18:return w.wp18;
 559                 case 19:return w.wp19;
 560                 case 20:return w.wp20;
 561                 case 21:return w.wp21;
 562                 case 22:return w.wp22;
 563                 case 23:return w.wp23;
 564                 case 24:return w.wp24;
 565                 case 25:return w.wp25;
 566                 case 26:return w.wp26;
 567                 case 27:return w.wp27;
 568                 case 28:return w.wp28;
 569                 case 29:return w.wp29;
 570                 case 30:return w.wp30;
 571                 case 31:return w.wp31;
 572                 default:return NULL;
 573         }
 574 }
 575
 576 // Save all waypoint links to a file
 577 void waypoint_save_links()
 578 {
 579         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 580         int file = fopen(filename, FILE_WRITE);
 581         if (file < 0)
 582         {
 583                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 584                 return;
 585         }
 586
 587         int c = 0;
 588         IL_EACH(g_waypoints, true,
 589         {
 590                 for(int j = 0; j < 32; ++j)
 591                 {
 592                         entity link = waypoint_get_link(it, j);
 593                         if(link)
 594                         {
 595                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 596                                 fputs(file, s);
 597                                 ++c;
 598                         }
 599                 }
 600         });
 601         fclose(file);
 602         botframe_cachedwaypointlinks = true;
 603
 604         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 605 }
 606
 607 // save waypoints to gamedir/data/maps/mapname.waypoints
 608 void waypoint_saveall()
 609 {
 610         string filename = sprintf("maps/%s.waypoints", mapname);
 611         int file = fopen(filename, FILE_WRITE);
 612         if (file < 0)
 613         {
 614                 waypoint_save_links(); // save anyway?
 615                 botframe_loadedforcedlinks = false;
 616
 617                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 618                 return;
 619         }
 620
 621         int c = 0;
 622         IL_EACH(g_waypoints, true,
 623         {
 624                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 625                         continue;
 626
 627                 string s;
 628                 s = strcat(vtos(it.origin + it.mins), "\n");
 629                 s = strcat(s, vtos(it.origin + it.maxs));
 630                 s = strcat(s, "\n");
 631                 s = strcat(s, ftos(it.wpflags));
 632                 s = strcat(s, "\n");
 633                 fputs(file, s);
 634                 c++;
 635         });
 636         fclose(file);
 637         waypoint_save_links();
 638         botframe_loadedforcedlinks = false;
 639
 640         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 641 }
 642
 643 // load waypoints from file
 644 float waypoint_loadall()
 645 {
 646         string filename, s;
 647         float file, cwp, cwb, fl;
 648         vector m1, m2;
 649         cwp = 0;
 650         cwb = 0;
 651         filename = strcat("maps/", mapname);
 652         filename = strcat(filename, ".waypoints");
 653         file = fopen(filename, FILE_READ);
 654         if (file >= 0)
 655         {
 656                 while ((s = fgets(file)))
 657                 {
 658                         m1 = stov(s);
 659                         s = fgets(file);
 660                         if (!s)
 661                                 break;
 662                         m2 = stov(s);
 663                         s = fgets(file);
 664                         if (!s)
 665                                 break;
 666                         fl = stof(s);
 667                         waypoint_spawn(m1, m2, fl);
 668                         if (m1 == m2)
 669                                 cwp = cwp + 1;
 670                         else
 671                                 cwb = cwb + 1;
 672                 }
 673                 fclose(file);
 674                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
 675         }
 676         else
 677         {
 678                 LOG_TRACE("waypoint load from ", filename, " failed");
 679         }
 680         return cwp + cwb;
 681 }
 682
 683 vector waypoint_fixorigin(vector position)
 684 {
 685         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 686         if(trace_fraction < 1)
 687                 position = trace_endpos;
 688         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 689         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 690         return position;
 691 }
 692
 693 void waypoint_spawnforitem_force(entity e, vector org)
 694 {
 695         // Fix the waypoint altitude if necessary
 696         org = waypoint_fixorigin(org);
 697
 698         // don't spawn an item spawnfunc_waypoint if it already exists
 699         IL_EACH(g_waypoints, true,
 700         {
 701                 if(it.wpisbox)
 702                 {
 703                         if(boxesoverlap(org, org, it.absmin, it.absmax))
 704                         {
 705                                 e.nearestwaypoint = it;
 706                                 return;
 707                         }
 708                 }
 709                 else
 710                 {
 711                         if(vdist(it.origin - org, <, 16))
 712                         {
 713                                 e.nearestwaypoint = it;
 714                                 return;
 715                         }
 716                 }
 717         });
 718
 719         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
 720 }
 721
 722 void waypoint_spawnforitem(entity e)
 723 {
 724         if(!bot_waypoints_for_items)
 725                 return;
 726
 727         waypoint_spawnforitem_force(e, e.origin);
 728 }
 729
 730 void waypoint_spawnforteleporter_boxes(entity e, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
 731 {
 732         entity w;
 733         entity dw;
 734         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 735         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
 736         // one way link to the destination
 737         w.wp00 = dw;
 738         w.wp00mincost = timetaken; // this is just for jump pads
 739         // the teleporter's nearest spawnfunc_waypoint is this one
 740         // (teleporters are not goals, so this is probably useless)
 741         e.nearestwaypoint = w;
 742         e.nearestwaypointtimeout = time + 1000000000;
 743 }
 744
 745 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
 746 {
 747         org = waypoint_fixorigin(org);
 748         destination = waypoint_fixorigin(destination);
 749         waypoint_spawnforteleporter_boxes(e, org, org, destination, destination, timetaken);
 750 }
 751
 752 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
 753 {
 754         destination = waypoint_fixorigin(destination);
 755         waypoint_spawnforteleporter_boxes(e, e.absmin, e.absmax, destination, destination, timetaken);
 756 }
 757
 758 entity waypoint_spawnpersonal(entity this, vector position)
 759 {
 760         entity w;
 761
 762         // drop the waypoint to a proper location:
 763         //   first move it up by a player height
 764         //   then move it down to hit the floor with player bbox size
 765         position = waypoint_fixorigin(position);
 766
 767         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
 768         w.nearestwaypoint = NULL;
 769         w.nearestwaypointtimeout = 0;
 770         w.owner = this;
 771
 772         waypoint_schedulerelink(w);
 773
 774         return w;
 775 }
 776
 777 void botframe_showwaypointlinks()
 778 {
 779         if (time < botframe_waypointeditorlightningtime)
 780                 return;
 781         botframe_waypointeditorlightningtime = time + 0.5;
 782         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
 783         {
 784                 if(IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
 785                 {
 786                         //navigation_testtracewalk = true;
 787                         entity head = navigation_findnearestwaypoint(it, false);
 788                 //      print("currently selected WP is ", etos(head), "\n");
 789                         //navigation_testtracewalk = false;
 790                         if (head)
 791                         {
 792                                 entity w;
 793                                 w = head     ;if (w) te_lightning2(NULL, w.origin, it.origin);
 794                                 w = head.wp00;if (w) te_lightning2(NULL, w.origin, head.origin);
 795                                 w = head.wp01;if (w) te_lightning2(NULL, w.origin, head.origin);
 796                                 w = head.wp02;if (w) te_lightning2(NULL, w.origin, head.origin);
 797                                 w = head.wp03;if (w) te_lightning2(NULL, w.origin, head.origin);
 798                                 w = head.wp04;if (w) te_lightning2(NULL, w.origin, head.origin);
 799                                 w = head.wp05;if (w) te_lightning2(NULL, w.origin, head.origin);
 800                                 w = head.wp06;if (w) te_lightning2(NULL, w.origin, head.origin);
 801                                 w = head.wp07;if (w) te_lightning2(NULL, w.origin, head.origin);
 802                                 w = head.wp08;if (w) te_lightning2(NULL, w.origin, head.origin);
 803                                 w = head.wp09;if (w) te_lightning2(NULL, w.origin, head.origin);
 804                                 w = head.wp10;if (w) te_lightning2(NULL, w.origin, head.origin);
 805                                 w = head.wp11;if (w) te_lightning2(NULL, w.origin, head.origin);
 806                                 w = head.wp12;if (w) te_lightning2(NULL, w.origin, head.origin);
 807                                 w = head.wp13;if (w) te_lightning2(NULL, w.origin, head.origin);
 808                                 w = head.wp14;if (w) te_lightning2(NULL, w.origin, head.origin);
 809                                 w = head.wp15;if (w) te_lightning2(NULL, w.origin, head.origin);
 810                                 w = head.wp16;if (w) te_lightning2(NULL, w.origin, head.origin);
 811                                 w = head.wp17;if (w) te_lightning2(NULL, w.origin, head.origin);
 812                                 w = head.wp18;if (w) te_lightning2(NULL, w.origin, head.origin);
 813                                 w = head.wp19;if (w) te_lightning2(NULL, w.origin, head.origin);
 814                                 w = head.wp20;if (w) te_lightning2(NULL, w.origin, head.origin);
 815                                 w = head.wp21;if (w) te_lightning2(NULL, w.origin, head.origin);
 816                                 w = head.wp22;if (w) te_lightning2(NULL, w.origin, head.origin);
 817                                 w = head.wp23;if (w) te_lightning2(NULL, w.origin, head.origin);
 818                                 w = head.wp24;if (w) te_lightning2(NULL, w.origin, head.origin);
 819                                 w = head.wp25;if (w) te_lightning2(NULL, w.origin, head.origin);
 820                                 w = head.wp26;if (w) te_lightning2(NULL, w.origin, head.origin);
 821                                 w = head.wp27;if (w) te_lightning2(NULL, w.origin, head.origin);
 822                                 w = head.wp28;if (w) te_lightning2(NULL, w.origin, head.origin);
 823                                 w = head.wp29;if (w) te_lightning2(NULL, w.origin, head.origin);
 824                                 w = head.wp30;if (w) te_lightning2(NULL, w.origin, head.origin);
 825                                 w = head.wp31;if (w) te_lightning2(NULL, w.origin, head.origin);
 826                         }
 827                 }
 828         });
 829 }
 830
 831 float botframe_autowaypoints_fixdown(vector v)
 832 {
 833         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
 834         if(trace_fraction >= 1)
 835                 return 0;
 836         return 1;
 837 }
 838
 839 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
 840 {
 841         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
 842         {
 843                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
 844                 return 0;
 845         });
 846
 847         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
 848         return 1;
 849 }
 850
 851 // return value:
 852 //    1 = WP created
 853 //    0 = no action needed
 854 //   -1 = temp fail, try from world too
 855 //   -2 = permanent fail, do not retry
 856 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
 857 {
 858         // make it possible to go from p to wp, if we can
 859         // if wp is NULL, nearest is chosen
 860
 861         entity w;
 862         vector porg;
 863         float t, tmin, tmax;
 864         vector o;
 865         vector save;
 866
 867         if(!botframe_autowaypoints_fixdown(p.origin))
 868                 return -2;
 869         porg = trace_endpos;
 870
 871         if(wp)
 872         {
 873                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
 874
 875                 // if wp -> porg, then OK
 876                 float maxdist;
 877                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
 878                 {
 879                         // we may find a better one
 880                         maxdist = vlen(wp.origin - porg);
 881                 }
 882                 else
 883                 {
 884                         // accept any "good"
 885                         maxdist = 2100;
 886                 }
 887
 888                 float bestdist = maxdist;
 889                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
 890                 {
 891                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
 892                         if(d < bestdist)
 893                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, walkfromwp, 1050))
 894                         if(navigation_waypoint_will_link(it.origin, porg, p, walkfromwp, 1050))
 895                         {
 896                                 bestdist = d;
 897                                 p.(fld) = it;
 898                         }
 899                 });
 900                 if(bestdist < maxdist)
 901                 {
 902                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
 903                         return 0;
 904                 }
 905
 906                 if(bestdist < 2100)
 907                 {
 908                         // we know maxdist < 2100
 909                         // so wp -> porg is still valid
 910                         // all is good
 911                         p.(fld) = wp;
 912                         return 0;
 913                 }
 914
 915                 // otherwise, no existing WP can fix our issues
 916         }
 917         else
 918         {
 919                 save = p.origin;
 920                 setorigin(p, porg);
 921                 w = navigation_findnearestwaypoint(p, walkfromwp);
 922                 setorigin(p, save);
 923                 if(w)
 924                 {
 925                         p.(fld) = w;
 926                         return 0;
 927                 }
 928         }
 929
 930         tmin = 0;
 931         tmax = 1;
 932         for (;;)
 933         {
 934                 if(tmax - tmin < 0.001)
 935                 {
 936                         // did not get a good candidate
 937                         return -1;
 938                 }
 939
 940                 t = (tmin + tmax) * 0.5;
 941                 o = antilag_takebackorigin(p, CS(p), time - t);
 942                 if(!botframe_autowaypoints_fixdown(o))
 943                         return -2;
 944                 o = trace_endpos;
 945
 946                 if(wp)
 947                 {
 948                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
 949                         {
 950                                 // we cannot walk from wp.origin to o
 951                                 // get closer to tmax
 952                                 tmin = t;
 953                                 continue;
 954                         }
 955                 }
 956                 else
 957                 {
 958                         save = p.origin;
 959                         setorigin(p, o);
 960                         w = navigation_findnearestwaypoint(p, walkfromwp);
 961                         setorigin(p, save);
 962                         if(!w)
 963                         {
 964                                 // we cannot walk from any WP to o
 965                                 // get closer to tmax
 966                                 tmin = t;
 967                                 continue;
 968                         }
 969                 }
 970
 971                 // if we get here, o is valid regarding waypoints
 972                 // check if o is connected right to the player
 973                 // we break if it succeeds, as that means o is a good waypoint location
 974                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
 975                         break;
 976
 977                 // o is no good, we need to get closer to the player
 978                 tmax = t;
 979         }
 980
 981         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
 982         botframe_autowaypoints_createwp(o, p, fld, 0);
 983         return 1;
 984 }
 985
 986 // automatically create missing waypoints
 987 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
 988 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
 989 {
 990         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
 991         if(r != -1)
 992                 return;
 993         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
 994         if(r != -1)
 995                 return;
 996
 997         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
 998         if(!botframe_autowaypoints_fixdown(p.origin))
 999                 return; // shouldn't happen, caught above
1000         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1001 }
1002
1003 void botframe_deleteuselesswaypoints()
1004 {
1005         IL_EACH(g_items, it.bot_pickup,
1006         {
1007                 // NOTE: this protects waypoints if they're the ONLY nearest
1008                 // waypoint. That's the intention.
1009                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1010                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1011         });
1012         IL_EACH(g_waypoints, true,
1013         {
1014                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1015                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1016                 // WP is useful if:
1017                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1018                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1019                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1020                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1021                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1022                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1023                 // b) WP is closest WP for an item/spawnpoint/other entity
1024                 //    This has been done above by protecting these WPs.
1025         });
1026         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1027         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1028         {
1029                 for (int m = 0; m < 32; ++m)
1030                 {
1031                         entity w = waypoint_get_link(it, m);
1032                         if (!w)
1033                                 break;
1034                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1035                                 continue;
1036                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1037                                 continue;
1038                         for (int j = 0; j < 32; ++j)
1039                         {
1040                                 entity w2 = waypoint_get_link(w, j);
1041                                 if (!w2)
1042                                         break;
1043                                 if (it == w2)
1044                                         continue;
1045                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1046                                         continue;
1047                                 // If we got here, it != w2 exist with it -> w
1048                                 // and w -> w2. That means the waypoint is not
1049                                 // a dead end.
1050                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1051                                 for (int k = 0; k < 32; ++k)
1052                                 {
1053                                         if (waypoint_get_link(it, k) == w2)
1054                                                 continue;
1055                                         // IF WE GET HERE, w is proven useful
1056                                         // to get from it to w2!
1057                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1058                                         goto next;
1059                                 }
1060                         }
1061 LABEL(next)
1062                 }
1063         });
1064         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1065         //     they are needed to complete routes while autowaypointing.
1066
1067         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1068         {
1069                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1070                 te_explosion(it.origin);
1071                 waypoint_remove(it);
1072                 break;
1073         });
1074
1075         IL_EACH(g_waypoints, true,
1076         {
1077                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1078         });
1079 }
1080
1081 void botframe_autowaypoints()
1082 {
1083         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1084                 // going back is broken, so only fix waypoints to walk TO the player
1085                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1086                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1087                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1088         ));
1089
1090         if (autocvar_g_waypointeditor_auto >= 2) {
1091                 botframe_deleteuselesswaypoints();
1092         }
1093 }
1094