qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 bool waypoint_has_hardwiredlinks(entity wp)
 264 {
 265         if (!wp)
 266                 return false;
 267         return (wp.wphw00 != NULL);
 268 }
 269
 270 bool waypoint_is_hardwiredlink(entity wp_from, entity wp_to)
 271 {
 272         if (!(wp_from && wp_to))
 273                 return false;
 274
 275         if (!wp_from.wphw00) return false; else if (wp_from.wphw00 == wp_to) return true;
 276         if (!wp_from.wphw01) return false; else if (wp_from.wphw01 == wp_to) return true;
 277         if (!wp_from.wphw02) return false; else if (wp_from.wphw02 == wp_to) return true;
 278         if (!wp_from.wphw03) return false; else if (wp_from.wphw03 == wp_to) return true;
 279         if (!wp_from.wphw04) return false; else if (wp_from.wphw04 == wp_to) return true;
 280         if (!wp_from.wphw05) return false; else if (wp_from.wphw05 == wp_to) return true;
 281         if (!wp_from.wphw06) return false; else if (wp_from.wphw06 == wp_to) return true;
 282         if (!wp_from.wphw07) return false; else if (wp_from.wphw07 == wp_to) return true;
 283
 284         return false;
 285 }
 286
 287 void waypoint_setupmodel(entity wp);
 288 void waypoint_mark_hardwiredlink(entity wp_from, entity wp_to)
 289 {
 290         if (!(wp_from && wp_to))
 291                 return;
 292
 293         if (!wp_from.wphw00 || wp_from.wphw00 == wp_to) { wp_from.wphw00 = wp_to; waypoint_setupmodel(wp_from); return; }
 294         if (!wp_from.wphw01 || wp_from.wphw01 == wp_to) { wp_from.wphw01 = wp_to; return; }
 295         if (!wp_from.wphw02 || wp_from.wphw02 == wp_to) { wp_from.wphw02 = wp_to; return; }
 296         if (!wp_from.wphw03 || wp_from.wphw03 == wp_to) { wp_from.wphw03 = wp_to; return; }
 297         if (!wp_from.wphw04 || wp_from.wphw04 == wp_to) { wp_from.wphw04 = wp_to; return; }
 298         if (!wp_from.wphw05 || wp_from.wphw05 == wp_to) { wp_from.wphw05 = wp_to; return; }
 299         if (!wp_from.wphw06 || wp_from.wphw06 == wp_to) { wp_from.wphw06 = wp_to; return; }
 300         if (!wp_from.wphw07 || wp_from.wphw07 == wp_to) { wp_from.wphw07 = wp_to; return; }
 301
 302         return;
 303 }
 304
 305 void waypoint_unmark_hardwiredlink(entity wp_from, entity wp_to)
 306 {
 307         if (!(wp_from && wp_to))
 308                 return;
 309
 310         int removed = -1;
 311         if (removed < 0 && wp_from.wphw00 == wp_to) removed = 0;
 312         if (removed < 0 && wp_from.wphw01 == wp_to) removed = 1;
 313         if (removed < 0 && wp_from.wphw02 == wp_to) removed = 2;
 314         if (removed < 0 && wp_from.wphw03 == wp_to) removed = 3;
 315         if (removed < 0 && wp_from.wphw04 == wp_to) removed = 4;
 316         if (removed < 0 && wp_from.wphw05 == wp_to) removed = 5;
 317         if (removed < 0 && wp_from.wphw06 == wp_to) removed = 6;
 318         if (removed < 0 && wp_from.wphw07 == wp_to) removed = 7;
 319
 320         if (removed >= 0)
 321         {
 322                 if (removed <= 0) wp_from.wphw00 = wp_from.wphw01;
 323                 if (removed <= 1) wp_from.wphw01 = wp_from.wphw02;
 324                 if (removed <= 2) wp_from.wphw02 = wp_from.wphw03;
 325                 if (removed <= 3) wp_from.wphw03 = wp_from.wphw04;
 326                 if (removed <= 4) wp_from.wphw04 = wp_from.wphw05;
 327                 if (removed <= 5) wp_from.wphw05 = wp_from.wphw06;
 328                 if (removed <= 6) wp_from.wphw06 = wp_from.wphw07;
 329                 if (removed <= 7) wp_from.wphw07 = NULL;
 330                 if (!wp_from.wphw00)
 331                         waypoint_setupmodel(wp_from);
 332         }
 333
 334         return;
 335 }
 336
 337 void waypoint_setupmodel(entity wp)
 338 {
 339         if (autocvar_g_waypointeditor)
 340         {
 341                 // TODO: add some sort of visible box in edit mode for box waypoints
 342                 vector m1 = wp.mins;
 343                 vector m2 = wp.maxs;
 344                 setmodel(wp, MDL_WAYPOINT);
 345                 setsize(wp, m1, m2);
 346                 wp.effects = EF_LOWPRECISION;
 347                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 348                         wp.colormod = '1 0 0'; // red
 349                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 350                         wp.colormod = '1 1 0'; // yellow
 351                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 352                         wp.colormod = '1 0.5 0'; // orange
 353                 else if (wp.wpflags & WAYPOINTFLAG_CROUCH)
 354                         wp.colormod = '0 1 1'; // cyan
 355                 else if (waypoint_has_hardwiredlinks(wp))
 356                         wp.colormod = '0.5 0 1'; // purple
 357                 else
 358                         wp.colormod = '1 1 1';
 359         }
 360         else
 361                 wp.model = "";
 362 }
 363
 364 entity waypoint_get(vector m1, vector m2)
 365 {
 366         if (m1 == m2)
 367         {
 368                 m1 -= '8 8 8';
 369                 m2 += '8 8 8';
 370         }
 371         IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax), { return it; });
 372
 373         return NULL;
 374 }
 375
 376 .float createdtime;
 377 entity waypoint_spawn(vector m1, vector m2, float f)
 378 {
 379         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 380         {
 381                 entity wp_found = waypoint_get(m1, m2);
 382                 if (wp_found)
 383                         return wp_found;
 384         }
 385         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 386         // otherwise links loaded from file would be applied only to the first destination
 387         // waypoint since link format doesn't specify waypoint entities but just positions
 388         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 389         {
 390                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 391                 {
 392                         return it;
 393                 });
 394         }
 395
 396         entity w = new(waypoint);
 397         IL_PUSH(g_waypoints, w);
 398         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 399         w.wpflags = f;
 400         w.solid = SOLID_TRIGGER;
 401         w.createdtime = time;
 402         setorigin(w, (m1 + m2) * 0.5);
 403         setsize(w, m1 - w.origin, m2 - w.origin);
 404         if (w.size)
 405                 w.wpisbox = true;
 406
 407         if(!w.wpisbox)
 408         {
 409                 if (f & WAYPOINTFLAG_CROUCH)
 410                         setsize(w, PL_CROUCH_MIN_CONST - '1 1 0', PL_CROUCH_MAX_CONST + '1 1 0');
 411                 else
 412                         setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 413                 if(!move_out_of_solid(w))
 414                 {
 415                         if(!(f & WAYPOINTFLAG_GENERATED))
 416                         {
 417                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 418                                 delete(w);
 419                                 return NULL;
 420                         }
 421                         else
 422                         {
 423                                 if(autocvar_developer)
 424                                 {
 425                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 426                                         backtrace("Waypoint stuck");
 427                                 }
 428                         }
 429                 }
 430                 setsize(w, '0 0 0', '0 0 0');
 431         }
 432
 433         waypoint_clearlinks(w);
 434         //waypoint_schedulerelink(w);
 435
 436         waypoint_setupmodel(w);
 437
 438         return w;
 439 }
 440
 441 float trigger_push_get_push_time(entity this, vector endpos);
 442 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 443 {
 444         entity jp = NULL;
 445         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 446         {
 447                 jp = it;
 448                 break;
 449         });
 450         if (!jp)
 451                 return;
 452
 453         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 454         wp_from.wp00 = wp_to;
 455         wp_from.wp00mincost = cost;
 456         jp.nearestwaypoint = wp_from;
 457         jp.nearestwaypointtimeout = -1;
 458 }
 459
 460 bool start_wp_is_spawned;
 461 vector start_wp_origin;
 462 bool start_wp_is_hardwired;
 463
 464 void waypoint_clear_start_wp(entity pl, bool warn)
 465 {
 466         start_wp_is_spawned = false;
 467         start_wp_origin = '0 0 0';
 468         pl.wp_locked = NULL;
 469         start_wp_is_hardwired = false;
 470         if (warn)
 471                 LOG_INFO("^xf80Start waypoint has been cleared.\n");
 472 }
 473
 474 void waypoint_start_hardwiredlink(entity pl)
 475 {
 476         entity wp = pl.nearestwaypoint;
 477         if ((!start_wp_is_spawned || start_wp_is_hardwired) && wp && !(wp.wpflags & WAYPOINTFLAG_NORELINK))
 478         {
 479                 start_wp_is_hardwired = true;
 480                 start_wp_is_spawned = true;
 481                 start_wp_origin = wp.origin;
 482                 pl.wp_locked = wp;
 483                 LOG_INFOF("^x80fNearest waypoint %s marked as hardwired link origin.\n", vtos(wp.origin));
 484         }
 485         else
 486                 start_wp_is_hardwired = false;
 487 }
 488
 489 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair, bool is_jump_wp, bool is_crouch_wp)
 490 {
 491         if (WAYPOINT_VERSION < waypoint_version_loaded)
 492         {
 493                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 494                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 495                 return;
 496         }
 497
 498         entity e = NULL, jp = NULL;
 499         vector org = pl.origin;
 500         if (at_crosshair)
 501         {
 502                 crosshair_trace(pl);
 503                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 504                 IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 505                 {
 506                         jp = it;
 507                         break;
 508                 });
 509         }
 510         if (jp || is_jump_wp)
 511         {
 512                 if (start_wp_is_spawned)
 513                         start_wp_is_spawned = false;
 514                 LOG_INFO("^xf80Spawning start waypoint...\n");
 515         }
 516         int ctf_flags = havocbot_symmetry_origin_order;
 517         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 518                    || (autocvar_g_waypointeditor_symmetrical < 0));
 519         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 520                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 521         if (sym && ctf_flags < 2)
 522                 ctf_flags = 2;
 523         int wp_num = ctf_flags;
 524
 525         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair && !is_jump_wp)
 526         {
 527                 // snap waypoint to item's origin if close enough
 528                 IL_EACH(g_items, true,
 529                 {
 530                         vector item_org = (it.absmin + it.absmax) * 0.5;
 531                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 532                         if (vlen(item_org - org) < 20)
 533                         {
 534                                 org = item_org;
 535                                 break;
 536                         }
 537                 });
 538         }
 539
 540         vector start_org = '0 0 0';
 541         if (start_wp_is_spawned)
 542         {
 543                 if (!start_wp_is_hardwired)
 544                         LOG_INFO("^xf80Spawning destination waypoint...\n");
 545                 start_org = start_wp_origin;
 546         }
 547
 548         // save org as it can be modified spawning symmetrycal waypoints
 549         vector initial_origin = '0 0 0';
 550         bool initial_origin_is_set = false;
 551
 552         LABEL(add_wp);
 553
 554         if (jp)
 555         {
 556                 e = NULL;
 557                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 558                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 559                 {
 560                         e = it; break;
 561                 });
 562                 if (!e)
 563                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 564                 if (!pl.wp_locked)
 565                         pl.wp_locked = e;
 566         }
 567         else if (is_jump_wp)
 568         {
 569                 entity wp_found = waypoint_get(org, org);
 570                 if (wp_found && !(wp_found.wpflags & WAYPOINTFLAG_JUMP))
 571                 {
 572                         LOG_INFO("Error: can't spawn a jump waypoint over an existent waypoint of a different type\n");
 573                         return;
 574                 }
 575                 e = waypoint_spawn(org, org, WAYPOINTFLAG_JUMP | WAYPOINTFLAG_NORELINK);
 576                 if (!pl.wp_locked)
 577                         pl.wp_locked = e;
 578         }
 579         else
 580                 e = waypoint_spawn(org, org, (is_crouch_wp) ? WAYPOINTFLAG_CROUCH : 0);
 581         if(!e)
 582         {
 583                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 584                 if (start_wp_is_spawned)
 585                         waypoint_clear_start_wp(pl, true);
 586                 return;
 587         }
 588
 589         if (!initial_origin_is_set)
 590         {
 591                 initial_origin = e.origin;
 592                 initial_origin_is_set = true;
 593         }
 594
 595         entity start_wp = NULL;
 596         if (start_wp_is_spawned)
 597         {
 598                 IL_EACH(g_waypoints, (start_wp_is_hardwired || it.wpflags & WAYPOINTFLAG_NORELINK)
 599                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 600                 {
 601                         start_wp = it; break;
 602                 });
 603                 if(!start_wp)
 604                 {
 605                         // should not happen
 606                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 607                         waypoint_clear_start_wp(pl, true);
 608                         return;
 609                 }
 610                 if (start_wp_is_hardwired)
 611                 {
 612                         if (waypoint_is_hardwiredlink(start_wp, e))
 613                         {
 614                                 waypoint_unmark_hardwiredlink(start_wp, e);
 615                                 waypoint_removelink(start_wp, e);
 616                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 617                                 LOG_INFOF("^x80fRemoved hardwired link %s.\n", s);
 618                         }
 619                         else
 620                         {
 621                                 if (e.createdtime == time)
 622                                 {
 623                                         LOG_INFO("Error: hardwired links can be created only between 2 existing (and unconnected) waypoints.\n");
 624                                         waypoint_remove(e);
 625                                         waypoint_clear_start_wp(pl, true);
 626                                         waypoint_spawn_fromeditor(pl, at_crosshair, is_jump_wp, is_crouch_wp);
 627                                         return;
 628                                 }
 629                                 if (start_wp == e)
 630                                 {
 631                                         LOG_INFO("Error: start and destination waypoints coincide.\n");
 632                                         waypoint_clear_start_wp(pl, true);
 633                                         return;
 634                                 }
 635                                 if (waypoint_islinked(start_wp, e))
 636                                 {
 637                                         LOG_INFO("Error: waypoints are already linked.\n");
 638                                         waypoint_clear_start_wp(pl, true);
 639                                         return;
 640                                 }
 641                                 waypoint_addlink(start_wp, e);
 642                                 waypoint_mark_hardwiredlink(start_wp, e);
 643                                 string s = strcat(vtos(start_wp.origin), "*", vtos(e.origin));
 644                                 LOG_INFOF("^x80fAdded hardwired link %s.\n", s);
 645                         }
 646                 }
 647                 else
 648                         waypoint_addlink(start_wp, e);
 649         }
 650
 651         if (!(jp || is_jump_wp || start_wp_is_hardwired))
 652                 waypoint_schedulerelink(e);
 653
 654         string wp_type_str = "Waypoint";
 655         if (is_crouch_wp)               wp_type_str = "Crouch waypoint";
 656         else if (is_jump_wp)    wp_type_str = "Jump waypoint";
 657         else if (jp)                    wp_type_str = "Custom jumppad waypoint";
 658
 659         bprint(strcat(wp_type_str, " spawned at ", vtos(e.origin), "\n"));
 660
 661         if (start_wp_is_spawned)
 662         {
 663                 pl.wp_locked = NULL;
 664                 if (!start_wp_is_hardwired)
 665                         waypoint_schedulerelink(start_wp);
 666                 if (start_wp.wpflags & WAYPOINTFLAG_TELEPORT)
 667                 {
 668                         if (start_wp.wp00_original == start_wp.wp00)
 669                                 start_wp.wpflags &= ~WAYPOINTFLAG_CUSTOM_JP;
 670                         else
 671                                 start_wp.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
 672                 }
 673         }
 674
 675         if (sym)
 676         {
 677                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 678                 if (jp)
 679                 {
 680                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 681                         {
 682                                 jp = it; break;
 683                         });
 684                 }
 685                 if (start_wp_is_spawned)
 686                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 687                 if (vdist(org - pl.origin, >, 32))
 688                 {
 689                         if(wp_num > 2)
 690                                 wp_num--;
 691                         else
 692                                 sym = false;
 693                         goto add_wp;
 694                 }
 695         }
 696         if (jp || is_jump_wp)
 697         {
 698                 if (!start_wp_is_spawned)
 699                 {
 700                         // we've just created a custom jumppad waypoint
 701                         // the next one created by the user will be the destination waypoint
 702                         start_wp_is_spawned = true;
 703                         start_wp_origin = initial_origin;
 704                 }
 705         }
 706         else if (start_wp_is_spawned)
 707         {
 708                 waypoint_clear_start_wp(pl, false);
 709         }
 710 }
 711
 712 void waypoint_remove(entity wp)
 713 {
 714         IL_EACH(g_waypoints, it != wp,
 715         {
 716                 if (waypoint_islinked(it, wp))
 717                 {
 718                         if (waypoint_is_hardwiredlink(it, wp))
 719                                 waypoint_unmark_hardwiredlink(it, wp);
 720                         waypoint_removelink(it, wp);
 721                 }
 722         });
 723         delete(wp);
 724 }
 725
 726 void waypoint_remove_fromeditor(entity pl)
 727 {
 728         if (WAYPOINT_VERSION < waypoint_version_loaded)
 729         {
 730                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
 731                         "Update Xonotic to make them editable.", waypoint_version_loaded);
 732                 return;
 733         }
 734
 735         entity e = navigation_findnearestwaypoint(pl, false);
 736
 737         int ctf_flags = havocbot_symmetry_origin_order;
 738         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 739                    || (autocvar_g_waypointeditor_symmetrical < 0));
 740         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 741                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 742         if (sym && ctf_flags < 2)
 743                 ctf_flags = 2;
 744         int wp_num = ctf_flags;
 745
 746         LABEL(remove_wp);
 747         if (!e) return;
 748
 749         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 750         {
 751                 if (start_wp_is_spawned)
 752                         waypoint_clear_start_wp(pl, true);
 753                 return;
 754         }
 755
 756         if (waypoint_has_hardwiredlinks(e))
 757         {
 758                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 759                 return;
 760         }
 761
 762         entity wp_sym = NULL;
 763         if (sym)
 764         {
 765                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 766                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 767                         if(vdist(org - it.origin, <, 3))
 768                         {
 769                                 wp_sym = it;
 770                                 break;
 771                         }
 772                 });
 773         }
 774
 775         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 776         waypoint_remove(e);
 777
 778         if (sym && wp_sym)
 779         {
 780                 e = wp_sym;
 781                 if(wp_num > 2)
 782                         wp_num--;
 783                 else
 784                         sym = false;
 785                 goto remove_wp;
 786         }
 787
 788         if (start_wp_is_spawned)
 789                 waypoint_clear_start_wp(pl, true);
 790 }
 791
 792 void waypoint_removelink(entity from, entity to)
 793 {
 794         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK && !(from.wpflags & WAYPOINTFLAG_JUMP)))
 795                 return;
 796
 797         entity fromwp31_prev = from.wp31;
 798
 799         switch (waypoint_getlinknum(from, to))
 800         {
 801                 // fallthrough all the way
 802                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 803                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 804                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 805                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 806                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 807                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 808                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 809                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 810                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 811                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 812                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 813                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 814                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 815                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 816                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 817                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 818                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 819                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 820                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 821                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 822                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 823                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 824                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 825                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 826                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 827                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 828                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 829                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 830                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 831                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 832                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 833                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 834         }
 835
 836         if (fromwp31_prev && !from.wp31)
 837                 waypoint_schedulerelink(from);
 838 }
 839
 840 int waypoint_getlinknum(entity from, entity to)
 841 {
 842         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 843         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 844         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 845         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 846         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 847         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 848         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 849         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 850         return -1;
 851 }
 852
 853 bool waypoint_islinked(entity from, entity to)
 854 {
 855         return (waypoint_getlinknum(from, to) >= 0);
 856 }
 857
 858 void waypoint_updatecost_foralllinks()
 859 {
 860         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 861         {
 862                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 863                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 864                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 865                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 866                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 867                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 868                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 869                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 870                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 871                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 872                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 873                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 874                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 875                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 876                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 877                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 878                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 879                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 880                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 881                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 882                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 883                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 884                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 885                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 886                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 887                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 888                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 889                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 890                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 891                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 892                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 893                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 894         });
 895 }
 896
 897 float waypoint_getlinearcost(float dist)
 898 {
 899         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 900                 return dist / (autocvar_sv_maxspeed * 1.25);
 901         return dist / autocvar_sv_maxspeed;
 902 }
 903
 904 float waypoint_getlinearcost_underwater(float dist)
 905 {
 906         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 907         return dist / (autocvar_sv_maxspeed * 0.7);
 908 }
 909
 910 float waypoint_getlinearcost_crouched(float dist)
 911 {
 912         return dist / (autocvar_sv_maxspeed * 0.5);
 913 }
 914
 915 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 916 {
 917         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 918         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 919
 920         if (submerged_from && submerged_to)
 921                 return waypoint_getlinearcost_underwater(vlen(to - from));
 922
 923         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH && to_ent.wpflags & WAYPOINTFLAG_CROUCH)
 924                 return waypoint_getlinearcost_crouched(vlen(to - from));
 925
 926         float c = waypoint_getlinearcost(vlen(to - from));
 927
 928         float height = from.z - to.z;
 929         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 930         {
 931                 float height_cost; // fall cost
 932                 if (boolean(from_ent.wpflags & WAYPOINTFLAG_JUMP))
 933                         height_cost = jumpheight_time + sqrt((height + jumpheight_vec.z) / (autocvar_sv_gravity / 2));
 934                 else
 935                         height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 936                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 937                 if(height_cost > c)
 938                         c = height_cost;
 939         }
 940
 941         // consider half path underwater
 942         if (submerged_from || submerged_to)
 943                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 944
 945         // consider half path crouched
 946         if (from_ent.wpflags & WAYPOINTFLAG_CROUCH || to_ent.wpflags & WAYPOINTFLAG_CROUCH)
 947                 return (c + waypoint_getlinearcost_crouched(vlen(to - from))) / 2;
 948
 949         return c;
 950 }
 951
 952 float waypoint_getlinkcost(entity from, entity to)
 953 {
 954         vector v1 = from.origin;
 955         vector v2 = to.origin;
 956         if (from.wpisbox)
 957         {
 958                 vector m1 = from.absmin, m2 = from.absmax;
 959                 v1.x = bound(m1.x, v2.x, m2.x);
 960                 v1.y = bound(m1.y, v2.y, m2.y);
 961                 v1.z = bound(m1.z, v2.z, m2.z);
 962         }
 963         if (to.wpisbox)
 964         {
 965                 vector m1 = to.absmin, m2 = to.absmax;
 966                 v2.x = bound(m1.x, v1.x, m2.x);
 967                 v2.y = bound(m1.y, v1.y, m2.y);
 968                 v2.z = bound(m1.z, v1.z, m2.z);
 969         }
 970         return waypoint_gettravelcost(v1, v2, from, to);
 971 }
 972
 973 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 974 // if c == -1 automatically determine cost of the link
 975 void waypoint_addlink_customcost(entity from, entity to, float c)
 976 {
 977         if (from == to || waypoint_islinked(from, to))
 978                 return;
 979         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & WAYPOINTFLAG_JUMP))
 980                 return;
 981
 982         if(c == -1)
 983                 c = waypoint_getlinkcost(from, to);
 984
 985         if (from.wp31mincost < c) return;
 986         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 987         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 988         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 989         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 990         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 991         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 992         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 993         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 994         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 995         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 996         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 997         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 998         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 999         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
1000         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
1001         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
1002         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
1003         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
1004         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
1005         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
1006         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
1007         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
1008         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
1009         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
1010         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
1011         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
1012         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
1013         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
1014         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
1015         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
1016         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
1017         from.wp00 = to;from.wp00mincost = c;return;
1018 }
1019
1020 void waypoint_addlink(entity from, entity to)
1021 {
1022         if ((from.wpflags & WAYPOINTFLAG_NORELINK) && !(from.wpflags & (WAYPOINTFLAG_JUMP)))
1023                 waypoint_addlink_for_custom_jumppad(from, to);
1024         else
1025                 waypoint_addlink_customcost(from, to, -1);
1026 }
1027
1028 // relink this spawnfunc_waypoint
1029 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
1030 // (SLOW!)
1031 void waypoint_think(entity this)
1032 {
1033         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
1034         float sv2_height = 0, ev2_height = 0;
1035
1036         bot_calculate_stepheightvec();
1037
1038         int dphitcontentsmask_save = this.dphitcontentsmask;
1039         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1040
1041         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
1042
1043         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
1044         IL_EACH(g_waypoints, this != it,
1045         {
1046                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
1047                 {
1048                         waypoint_addlink(this, it);
1049                         waypoint_addlink(it, this);
1050                 }
1051                 else
1052                 {
1053                         ++relink_total;
1054                         if(!checkpvs(this.origin, it))
1055                         {
1056                                 ++relink_pvsculled;
1057                                 continue;
1058                         }
1059
1060                         sv = set_tracewalk_dest_2(this, it.origin);
1061                         sv2 = tracewalk_dest;
1062                         sv2_height = tracewalk_dest_height;
1063                         ev = set_tracewalk_dest_2(it, this.origin);
1064                         ev2 = tracewalk_dest;
1065                         ev2_height = tracewalk_dest_height;
1066
1067                         dv = ev - sv;
1068                         dv.z = 0;
1069                         int maxdist = 1050;
1070                         vector m1 = PL_MIN_CONST;
1071                         vector m2 = PL_MAX_CONST;
1072
1073                         if (this.wpflags & WAYPOINTFLAG_CROUCH || it.wpflags & WAYPOINTFLAG_CROUCH)
1074                         {
1075                                 m1 = PL_CROUCH_MIN_CONST;
1076                                 m2 = PL_CROUCH_MAX_CONST;
1077                                 // links from crouch wp to normal wp (and viceversa) are very short to avoid creating many links
1078                                 // that would be wasted due to rough travel cost calculation (the longer link is, the higher cost is)
1079                                 // links from crouch wp to crouch wp can be as long as normal links
1080                                 if (!(this.wpflags & WAYPOINTFLAG_CROUCH && it.wpflags & WAYPOINTFLAG_CROUCH))
1081                                         maxdist = 100;
1082                         }
1083
1084                         if (vdist(dv, >=, maxdist)) // max search distance in XY
1085                         {
1086                                 ++relink_lengthculled;
1087                                 continue;
1088                         }
1089
1090                         navigation_testtracewalk = 0;
1091
1092                         //traceline(this.origin, it.origin, false, NULL);
1093                         //if (trace_fraction == 1)
1094                         if (this.wpisbox || this.wpflags & WAYPOINTFLAG_JUMP)
1095                                 relink_walkculled += 0.5;
1096                         else
1097                         {
1098                                 if (tracewalk(this, sv, m1, m2, ev2, ev2_height, MOVE_NOMONSTERS))
1099                                         waypoint_addlink(this, it);
1100                                 else
1101                                         relink_walkculled += 0.5;
1102                         }
1103
1104                         if (it.wpisbox || it.wpflags & WAYPOINTFLAG_JUMP)
1105                                 relink_walkculled += 0.5;
1106                         else
1107                         {
1108                                 if (tracewalk(this, ev, m1, m2, sv2, sv2_height, MOVE_NOMONSTERS))
1109                                         waypoint_addlink(it, this);
1110                                 else
1111                                         relink_walkculled += 0.5;
1112                         }
1113                 }
1114         });
1115         navigation_testtracewalk = 0;
1116         this.wplinked = true;
1117         this.dphitcontentsmask = dphitcontentsmask_save;
1118
1119         setthink(this, func_null);
1120         this.nextthink = 0;
1121 }
1122
1123 void waypoint_clearlinks(entity wp)
1124 {
1125         // clear links to other waypoints
1126         float f = 10000000;
1127         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
1128         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
1129         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
1130         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
1131
1132         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
1133         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
1134         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
1135         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
1136
1137         wp.wplinked = false;
1138 }
1139
1140 // tell a spawnfunc_waypoint to relink
1141 void waypoint_schedulerelink(entity wp)
1142 {
1143         if (wp == NULL)
1144                 return;
1145
1146         waypoint_setupmodel(wp);
1147         wp.wpisbox = vdist(wp.size, >, 0);
1148         wp.enemy = NULL;
1149         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
1150                 wp.owner = NULL;
1151         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
1152                 waypoint_clearlinks(wp);
1153         // schedule an actual relink on next frame
1154         setthink(wp, waypoint_think);
1155         wp.nextthink = time;
1156         wp.effects = EF_LOWPRECISION;
1157 }
1158
1159 // spawnfunc_waypoint map entity
1160 spawnfunc(waypoint)
1161 {
1162         IL_PUSH(g_waypoints, this);
1163
1164         setorigin(this, this.origin);
1165         // schedule a relink after other waypoints have had a chance to spawn
1166         waypoint_clearlinks(this);
1167         //waypoint_schedulerelink(this);
1168 }
1169
1170 // tell all waypoints to relink
1171 // actually this is useful only to update relink_* stats
1172 void waypoint_schedulerelinkall()
1173 {
1174         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
1175         IL_EACH(g_waypoints, true,
1176         {
1177                 waypoint_schedulerelink(it);
1178         });
1179         waypoint_load_hardwiredlinks();
1180 }
1181
1182 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
1183
1184 // Load waypoint links from file
1185 bool waypoint_load_links()
1186 {
1187         string s;
1188         float file, tokens, c = 0, found;
1189         entity wp_from = NULL, wp_to;
1190         vector wp_to_pos, wp_from_pos;
1191
1192         string gt_ext = GET_GAMETYPE_EXTENSION();
1193
1194         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1195         file = fopen(filename, FILE_READ);
1196
1197         if (gt_ext != "" && file < 0)
1198         {
1199                 // if race waypoint file doesn't exist load the default one
1200                 filename = sprintf("maps/%s.waypoints.cache", mapname);
1201                 file = fopen(filename, FILE_READ);
1202         }
1203
1204         if (file < 0)
1205         {
1206                 LOG_TRACE("waypoint links load from ", filename, " failed");
1207                 waypoint_schedulerelinkall();
1208                 return false;
1209         }
1210
1211         bool parse_comments = true;
1212         float ver = 0;
1213         string links_time = string_null;
1214
1215         while ((s = fgets(file)))
1216         {
1217                 if(parse_comments)
1218                 {
1219                         if(substring(s, 0, 2) == "//")
1220                         {
1221                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1222                                         ver = stof(substring(s, 19, -1));
1223                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1224                                         links_time = substring(s, 16, -1);
1225                                 continue;
1226                         }
1227                         else
1228                         {
1229                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
1230                                 {
1231                                         if (links_time != waypoint_time)
1232                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
1233                                         else
1234                                                 LOG_TRACE("waypoint links for this map are outdated.");
1235                                         if (g_assault)
1236                                         {
1237                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
1238                                         }
1239                                         else
1240                                         {
1241                                                 LOG_TRACE("automatically updating...");
1242                                                 waypoint_schedulerelinkall();
1243                                                 fclose(file);
1244                                                 return false;
1245                                         }
1246                                 }
1247                                 parse_comments = false;
1248                         }
1249                 }
1250
1251                 tokens = tokenizebyseparator(s, "*");
1252
1253                 if (tokens!=2)
1254                 {
1255                         // bad file format
1256                         fclose(file);
1257                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1258                         return false;
1259                 }
1260
1261                 wp_from_pos     = stov(argv(0));
1262                 wp_to_pos       = stov(argv(1));
1263
1264                 // Search "from" waypoint
1265                 if(!wp_from || wp_from.origin!=wp_from_pos)
1266                 {
1267                         wp_from = findradius(wp_from_pos, 1);
1268                         found = false;
1269                         while(wp_from)
1270                         {
1271                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1272                                 if(wp_from.classname == "waypoint")
1273                                 {
1274                                         found = true;
1275                                         break;
1276                                 }
1277                                 wp_from = wp_from.chain;
1278                         }
1279
1280                         if(!found)
1281                         {
1282                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1283                                 continue;
1284                         }
1285                 }
1286
1287                 // Search "to" waypoint
1288                 wp_to = findradius(wp_to_pos, 1);
1289                 found = false;
1290                 while(wp_to)
1291                 {
1292                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1293                         if(wp_to.classname == "waypoint")
1294                         {
1295                                 found = true;
1296                                 break;
1297                         }
1298                         wp_to = wp_to.chain;
1299                 }
1300
1301                 if(!found)
1302                 {
1303                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1304                         continue;
1305                 }
1306
1307                 ++c;
1308                 waypoint_addlink(wp_from, wp_to);
1309                 if (wp_from.wp00_original && wp_from.wp00_original != wp_from.wp00)
1310                         wp_from.wpflags |= WAYPOINTFLAG_CUSTOM_JP;
1311         }
1312
1313         fclose(file);
1314
1315         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1316
1317         bool scheduled = false;
1318         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1319         {
1320                 if (!it.wp00)
1321                 {
1322                         waypoint_schedulerelink(it);
1323                         scheduled = true;
1324                 }
1325         });
1326         if (scheduled)
1327                 return false;
1328
1329         botframe_cachedwaypointlinks = true;
1330         return true;
1331 }
1332
1333 void waypoint_load_hardwiredlinks()
1334 {
1335         string s;
1336         float file, tokens, c = 0, found;
1337         entity wp_from = NULL, wp_to;
1338         vector wp_to_pos, wp_from_pos;
1339
1340         string gt_ext = GET_GAMETYPE_EXTENSION();
1341
1342         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1343         file = fopen(filename, FILE_READ);
1344
1345         if (gt_ext != "" && file < 0)
1346         {
1347                 // if race waypoint file doesn't exist load the default one
1348                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1349                 file = fopen(filename, FILE_READ);
1350         }
1351
1352         botframe_loadedforcedlinks = true;
1353
1354         if (file < 0)
1355         {
1356                 LOG_TRACE("waypoint links load from ", filename, " failed");
1357                 return;
1358         }
1359
1360         bool is_special = false;
1361         while ((s = fgets(file)))
1362         {
1363                 if(substring(s, 0, 2)=="//")
1364                         continue;
1365
1366                 if(substring(s, 0, 1)=="#")
1367                         continue;
1368
1369                 // special links start with *, so old xonotic versions don't load them
1370                 is_special = false;
1371                 if (substring(s, 0, 1) == "*")
1372                 {
1373                         is_special = true;
1374                         s = substring(s, 1, -1);
1375                 }
1376
1377                 tokens = tokenizebyseparator(s, "*");
1378
1379                 if (tokens!=2)
1380                         continue;
1381
1382                 wp_from_pos     = stov(argv(0));
1383                 wp_to_pos       = stov(argv(1));
1384
1385                 // Search "from" waypoint
1386                 if(!wp_from || wp_from.origin!=wp_from_pos)
1387                 {
1388                         wp_from = findradius(wp_from_pos, 5);
1389                         found = false;
1390                         while(wp_from)
1391                         {
1392                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1393                                 if(wp_from.classname == "waypoint")
1394                                 {
1395                                         found = true;
1396                                         break;
1397                                 }
1398                                 wp_from = wp_from.chain;
1399                         }
1400
1401                         if(!found)
1402                         {
1403                                 LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1404                                 continue;
1405                         }
1406                 }
1407
1408                 // Search "to" waypoint
1409                 wp_to = findradius(wp_to_pos, 5);
1410                 found = false;
1411                 while(wp_to)
1412                 {
1413                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1414                         if(wp_to.classname == "waypoint")
1415                         {
1416                                 found = true;
1417                                 break;
1418                         }
1419                         wp_to = wp_to.chain;
1420                 }
1421
1422                 if(!found)
1423                 {
1424                         LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1425                         continue;
1426                 }
1427
1428                 ++c;
1429
1430                 if (!is_special)
1431                 {
1432                         waypoint_addlink(wp_from, wp_to);
1433                         waypoint_mark_hardwiredlink(wp_from, wp_to);
1434                 } else if (wp_from.wpflags & WAYPOINTFLAG_NORELINK
1435                         && (wp_from.wpflags & WAYPOINTFLAG_JUMP || (wp_from.wpisbox && wp_from.wpflags & WAYPOINTFLAG_TELEPORT)))
1436                 {
1437                         waypoint_addlink(wp_from, wp_to);
1438                 }
1439         }
1440
1441         fclose(file);
1442
1443         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1444 }
1445
1446 entity waypoint_get_link(entity w, float i)
1447 {
1448         switch(i)
1449         {
1450                 case  0:return w.wp00;
1451                 case  1:return w.wp01;
1452                 case  2:return w.wp02;
1453                 case  3:return w.wp03;
1454                 case  4:return w.wp04;
1455                 case  5:return w.wp05;
1456                 case  6:return w.wp06;
1457                 case  7:return w.wp07;
1458                 case  8:return w.wp08;
1459                 case  9:return w.wp09;
1460                 case 10:return w.wp10;
1461                 case 11:return w.wp11;
1462                 case 12:return w.wp12;
1463                 case 13:return w.wp13;
1464                 case 14:return w.wp14;
1465                 case 15:return w.wp15;
1466                 case 16:return w.wp16;
1467                 case 17:return w.wp17;
1468                 case 18:return w.wp18;
1469                 case 19:return w.wp19;
1470                 case 20:return w.wp20;
1471                 case 21:return w.wp21;
1472                 case 22:return w.wp22;
1473                 case 23:return w.wp23;
1474                 case 24:return w.wp24;
1475                 case 25:return w.wp25;
1476                 case 26:return w.wp26;
1477                 case 27:return w.wp27;
1478                 case 28:return w.wp28;
1479                 case 29:return w.wp29;
1480                 case 30:return w.wp30;
1481                 case 31:return w.wp31;
1482                 default:return NULL;
1483         }
1484 }
1485
1486 // Save all hardwired waypoint links to a file
1487 void waypoint_save_hardwiredlinks()
1488 {
1489         string gt_ext = GET_GAMETYPE_EXTENSION();
1490
1491         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1492         int file = fopen(filename, FILE_WRITE);
1493         if (file < 0)
1494         {
1495                 LOG_TRACE("waypoint hardwired links ", filename, " creation failed");
1496                 return;
1497         }
1498
1499         // write hardwired links to file
1500         int count = 0;
1501         fputs(file, "// HARDWIRED LINKS\n");
1502         IL_EACH(g_waypoints, waypoint_has_hardwiredlinks(it),
1503         {
1504                 for (int j = 0; j < 32; ++j)
1505                 {
1506                         entity link = waypoint_get_link(it, j);
1507                         if (waypoint_is_hardwiredlink(it, link))
1508                         {
1509                                 // NOTE: vtos rounds vector components to 1 decimal place
1510                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1511                                 fputs(file, s);
1512                                 ++count;
1513                         }
1514                 }
1515         });
1516
1517         // write special links to file
1518         int count2 = 0;
1519         fputs(file, "\n// SPECIAL LINKS\n");
1520         IL_EACH(g_waypoints, it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP),
1521         {
1522                 for (int j = 0; j < 32; ++j)
1523                 {
1524                         entity link = waypoint_get_link(it, j);
1525                         if (link)
1526                         {
1527                                 // NOTE: vtos rounds vector components to 1 decimal place
1528                                 string s = strcat("*", vtos(it.origin), "*", vtos(link.origin), "\n");
1529                                 fputs(file, s);
1530                                 ++count2;
1531                         }
1532                 }
1533         });
1534
1535         fclose(file);
1536
1537         LOG_INFOF("saved %d hardwired links and %d special links to %s", count, count2, filename);
1538 }
1539
1540 // Save all waypoint links to a file
1541 void waypoint_save_links()
1542 {
1543         string gt_ext = GET_GAMETYPE_EXTENSION();
1544
1545         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1546         int file = fopen(filename, FILE_WRITE);
1547         if (file < 0)
1548         {
1549                 LOG_INFOF("waypoint link save to %s failed", filename);
1550                 return;
1551         }
1552
1553         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1554         if (waypoint_time != "")
1555                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1556
1557         int c = 0;
1558         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_JUMP | WAYPOINTFLAG_CUSTOM_JP)),
1559         {
1560                 for(int j = 0; j < 32; ++j)
1561                 {
1562                         entity link = waypoint_get_link(it, j);
1563                         if (link && !waypoint_is_hardwiredlink(it, link))
1564                         {
1565                                 // NOTE: vtos rounds vector components to 1 decimal place
1566                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1567                                 fputs(file, s);
1568                                 ++c;
1569                         }
1570                 }
1571         });
1572         fclose(file);
1573
1574         botframe_cachedwaypointlinks = true;
1575
1576         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1577 }
1578
1579 // save waypoints to gamedir/data/maps/mapname.waypoints
1580 void waypoint_saveall()
1581 {
1582         if (WAYPOINT_VERSION < waypoint_version_loaded)
1583         {
1584                 LOG_INFOF("^1Overwriting waypoints with a higher version number (%f) is not allowed.\n"
1585                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1586                 return;
1587         }
1588         string gt_ext = GET_GAMETYPE_EXTENSION();
1589
1590         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1591         int file = fopen(filename, FILE_WRITE);
1592         if (file < 0)
1593         {
1594                 waypoint_save_links(); // save anyway?
1595                 botframe_loadedforcedlinks = false;
1596
1597                 LOG_INFOF("waypoint links: save to %s failed", filename);
1598                 return;
1599         }
1600
1601         float sym = autocvar_g_waypointeditor_symmetrical;
1602         string sym_str = ftos(sym);
1603         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1604         {
1605                 if (sym == 1)
1606                 {
1607                         sym_str = cons(sym_str, "-");
1608                         sym_str = cons(sym_str, "-");
1609                 }
1610                 else
1611                 {
1612                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1613                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1614                 }
1615                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1616                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1617         }
1618         else if (autocvar_g_waypointeditor_symmetrical == -2)
1619         {
1620                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1621                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1622         }
1623
1624         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1625         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1626         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1627         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1628
1629         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1630         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1631         //fputs(file, strcat("//", "\n"));
1632         //fputs(file, strcat("//", "\n"));
1633         //fputs(file, strcat("//", "\n"));
1634
1635         int c = 0;
1636         IL_EACH(g_waypoints, true,
1637         {
1638                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1639                         continue;
1640
1641                 string s;
1642                 // NOTE: vtos rounds vector components to 1 decimal place
1643                 s = strcat(vtos(it.origin + it.mins), "\n");
1644                 s = strcat(s, vtos(it.origin + it.maxs));
1645                 s = strcat(s, "\n");
1646                 s = strcat(s, ftos(it.wpflags));
1647                 s = strcat(s, "\n");
1648                 fputs(file, s);
1649                 c++;
1650         });
1651         fclose(file);
1652         waypoint_save_links();
1653         waypoint_save_hardwiredlinks();
1654
1655         botframe_loadedforcedlinks = false;
1656
1657         waypoint_version_loaded = WAYPOINT_VERSION;
1658         LOG_INFOF("saved %d waypoints to %s", c, filename);
1659 }
1660
1661 // load waypoints from file
1662 float waypoint_loadall()
1663 {
1664         string s;
1665         float file, cwp, cwb, fl;
1666         vector m1, m2;
1667         cwp = 0;
1668         cwb = 0;
1669
1670         string gt_ext = GET_GAMETYPE_EXTENSION();
1671
1672         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1673         file = fopen(filename, FILE_READ);
1674
1675         if (gt_ext != "" && file < 0)
1676         {
1677                 // if race waypoint file doesn't exist load the default one
1678                 filename = sprintf("maps/%s.waypoints", mapname);
1679                 file = fopen(filename, FILE_READ);
1680         }
1681
1682         if (file < 0)
1683         {
1684                 LOG_TRACE("waypoint load from ", filename, " failed");
1685                 return 0;
1686         }
1687
1688         bool parse_comments = true;
1689         float ver = 0;
1690         float sym = 0;
1691         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1692
1693         while ((s = fgets(file)))
1694         {
1695                 if(parse_comments)
1696                 {
1697                         if(substring(s, 0, 2) == "//")
1698                         {
1699                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1700                                         ver = stof(substring(s, 19, -1));
1701                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1702                                 {
1703                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1704                                         if (tokens) { sym = stof(argv(0)); }
1705                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1706                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1707                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1708                                 }
1709                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1710                                         strcpy(waypoint_time, substring(s, 16, -1));
1711                                 continue;
1712                         }
1713                         else
1714                         {
1715                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1716                                 {
1717                                         LOG_TRACE("waypoints for this map are outdated");
1718                                         LOG_TRACE("please update them in the editor");
1719                                 }
1720                                 parse_comments = false;
1721                         }
1722                 }
1723                 m1 = stov(s);
1724                 s = fgets(file);
1725                 if (!s)
1726                         break;
1727                 m2 = stov(s);
1728                 s = fgets(file);
1729                 if (!s)
1730                         break;
1731                 fl = stof(s);
1732                 waypoint_spawn(m1, m2, fl);
1733                 if (m1 == m2)
1734                         cwp = cwp + 1;
1735                 else
1736                         cwb = cwb + 1;
1737         }
1738         fclose(file);
1739         waypoint_version_loaded = ver;
1740         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1741
1742         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1743         {
1744                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1745                 if (sym == 1 && sym_param3 < 2)
1746                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1747                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1748                 {
1749                         string params;
1750                         if (sym == 1)
1751                                 params = cons("-", "-");
1752                         else
1753                         {
1754                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1755                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1756                         }
1757                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1758                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1759                 }
1760                 else if (sym == -2)
1761                 {
1762                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1763                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1764                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1765                 }
1766                 else
1767                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1768                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1769         }
1770
1771         if (WAYPOINT_VERSION < waypoint_version_loaded)
1772                 LOG_INFOF("^1Editing waypoints with a higher version number (%f) is not allowed.\n"
1773                         "Update Xonotic to make them editable.", waypoint_version_loaded);
1774
1775         return cwp + cwb;
1776 }
1777
1778 #define waypoint_fixorigin(position, tracetest_ent) \
1779         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1780
1781 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1782 {
1783         vector endpos = position + down_dir * 3000;
1784         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1785         if(trace_startsolid)
1786                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1787         if(trace_startsolid)
1788                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1789         if(trace_fraction < 1)
1790                 position = trace_endpos;
1791         return position;
1792 }
1793
1794 void waypoint_spawnforitem_force(entity e, vector org)
1795 {
1796         // Fix the waypoint altitude if necessary
1797         org = waypoint_fixorigin(org, NULL);
1798
1799         // don't spawn an item spawnfunc_waypoint if it already exists
1800         IL_EACH(g_waypoints, true,
1801         {
1802                 if(it.wpisbox)
1803                 {
1804                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1805                         {
1806                                 e.nearestwaypoint = it;
1807                                 return;
1808                         }
1809                 }
1810                 else
1811                 {
1812                         if(vdist(it.origin - org, <, 16))
1813                         {
1814                                 e.nearestwaypoint = it;
1815                                 return;
1816                         }
1817                 }
1818         });
1819
1820         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1821 }
1822
1823 void waypoint_spawnforitem(entity e)
1824 {
1825         if(!bot_waypoints_for_items)
1826                 return;
1827
1828         waypoint_spawnforitem_force(e, e.origin);
1829 }
1830
1831 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1832 {
1833         entity w;
1834         entity dw;
1835         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1836         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1837         // one way link to the destination
1838         w.wp00_original = dw;
1839         w.wp00 = dw;
1840         w.wp00mincost = timetaken; // this is just for jump pads
1841         // the teleporter's nearest spawnfunc_waypoint is this one
1842         // (teleporters are not goals, so this is probably useless)
1843         e.nearestwaypoint = w;
1844         e.nearestwaypointtimeout = -1;
1845 }
1846
1847 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1848 {
1849         float src_angle = e.warpzone_angles.x;
1850         while (src_angle < -180) src_angle += 360;
1851         while (src_angle > 180) src_angle -= 360;
1852
1853         float dest_angle = e.enemy.warpzone_angles.x;
1854         while (dest_angle < -180) dest_angle += 360;
1855         while (dest_angle > 180) dest_angle -= 360;
1856
1857         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1858         if (src_angle == -90 || dest_angle == -90)
1859                 return;
1860
1861         makevectors(e.warpzone_angles);
1862         vector src = (e.absmin + e.absmax) * 0.5;
1863         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1864         vector down_dir_src = -v_up;
1865
1866         makevectors(e.enemy.warpzone_angles);
1867         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1868         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1869         vector down_dir_dest = -v_up;
1870
1871         int extra_flag = 0;
1872         // don't snap to the ground waypoints for source warpzones pointing downwards
1873         if (src_angle != 90)
1874         {
1875                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1876                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1877                 // oblique warpzones need a jump otherwise bots gets stuck
1878                 if (src_angle != 0)
1879                         extra_flag = WAYPOINTFLAG_JUMP;
1880         }
1881
1882         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1883 }
1884
1885 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1886 {
1887         destination = waypoint_fixorigin(destination, tracetest_ent);
1888         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1889 }
1890
1891 entity waypoint_spawnpersonal(entity this, vector position)
1892 {
1893         entity w;
1894
1895         // drop the waypoint to a proper location:
1896         //   first move it up by a player height
1897         //   then move it down to hit the floor with player bbox size
1898         position = waypoint_fixorigin(position, this);
1899
1900         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1901         w.nearestwaypoint = NULL;
1902         w.nearestwaypointtimeout = 0;
1903         w.owner = this;
1904
1905         waypoint_schedulerelink(w);
1906
1907         return w;
1908 }
1909
1910 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1911 {
1912         if (!(wp1 && wp2))
1913                 return;
1914
1915         if (waypoint_is_hardwiredlink(wp1, wp2))
1916                 te_beam(NULL, wp1.origin, wp2.origin);
1917         else if (display_type == 1)
1918                 te_lightning2(NULL, wp1.origin, wp2.origin);
1919 }
1920
1921 void waypoint_showlinks_to(entity wp, int display_type)
1922 {
1923         IL_EACH(g_waypoints, it != wp,
1924         {
1925                 if (waypoint_islinked(it, wp))
1926                         waypoint_showlink(it, wp, display_type);
1927         });
1928 }
1929
1930 void waypoint_showlinks_from(entity wp, int display_type)
1931 {
1932         waypoint_showlink(wp, wp.wp00, display_type); waypoint_showlink(wp, wp.wp16, display_type);
1933         waypoint_showlink(wp, wp.wp01, display_type); waypoint_showlink(wp, wp.wp17, display_type);
1934         waypoint_showlink(wp, wp.wp02, display_type); waypoint_showlink(wp, wp.wp18, display_type);
1935         waypoint_showlink(wp, wp.wp03, display_type); waypoint_showlink(wp, wp.wp19, display_type);
1936         waypoint_showlink(wp, wp.wp04, display_type); waypoint_showlink(wp, wp.wp20, display_type);
1937         waypoint_showlink(wp, wp.wp05, display_type); waypoint_showlink(wp, wp.wp21, display_type);
1938         waypoint_showlink(wp, wp.wp06, display_type); waypoint_showlink(wp, wp.wp22, display_type);
1939         waypoint_showlink(wp, wp.wp07, display_type); waypoint_showlink(wp, wp.wp23, display_type);
1940         waypoint_showlink(wp, wp.wp08, display_type); waypoint_showlink(wp, wp.wp24, display_type);
1941         waypoint_showlink(wp, wp.wp09, display_type); waypoint_showlink(wp, wp.wp25, display_type);
1942         waypoint_showlink(wp, wp.wp10, display_type); waypoint_showlink(wp, wp.wp26, display_type);
1943         waypoint_showlink(wp, wp.wp11, display_type); waypoint_showlink(wp, wp.wp27, display_type);
1944         waypoint_showlink(wp, wp.wp12, display_type); waypoint_showlink(wp, wp.wp28, display_type);
1945         waypoint_showlink(wp, wp.wp13, display_type); waypoint_showlink(wp, wp.wp29, display_type);
1946         waypoint_showlink(wp, wp.wp14, display_type); waypoint_showlink(wp, wp.wp30, display_type);
1947         waypoint_showlink(wp, wp.wp15, display_type); waypoint_showlink(wp, wp.wp31, display_type);
1948 }
1949
1950 void crosshair_trace_waypoints(entity pl)
1951 {
1952         IL_EACH(g_waypoints, true, {
1953                 it.solid = SOLID_BSP;
1954                 if (!it.wpisbox)
1955                         setsize(it, '-16 -16 -16', '16 16 16');
1956         });
1957
1958         crosshair_trace(pl);
1959
1960         IL_EACH(g_waypoints, true, {
1961                 it.solid = SOLID_TRIGGER;
1962                 if (!it.wpisbox)
1963                         setsize(it, '0 0 0', '0 0 0');
1964         });
1965         if (trace_ent.classname != "waypoint")
1966                 trace_ent = NULL;
1967 }
1968
1969 void botframe_showwaypointlinks()
1970 {
1971         if (time < botframe_waypointeditorlightningtime)
1972                 return;
1973         botframe_waypointeditorlightningtime = time + 0.5;
1974         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1975         {
1976                 int display_type = 0;
1977                 if (wasfreed(it.wp_aimed))
1978                         it.wp_aimed = NULL;
1979                 if (wasfreed(it.wp_locked))
1980                         it.wp_locked = NULL;
1981                 if (PHYS_INPUT_BUTTON_USE(it))
1982                         it.wp_locked = it.wp_aimed;
1983                 entity head = it.wp_locked;
1984                 if (!head)
1985                         head = navigation_findnearestwaypoint(it, false);
1986                 it.nearestwaypoint = head; // mainly useful for debug
1987                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1988                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1989                         display_type = 1; // default
1990                 else if(waypoint_has_hardwiredlinks(head))
1991                         display_type = 2; // only hardwired
1992
1993                 if (display_type)
1994                 {
1995                         //navigation_testtracewalk = true;
1996                         //print("currently selected WP is ", etos(head), "\n");
1997                         //navigation_testtracewalk = false;
1998                         if (head)
1999                         {
2000                                 te_lightning2(NULL, head.origin, it.origin);
2001                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
2002                                         waypoint_showlinks_to(head, display_type);
2003                                 else
2004                                         waypoint_showlinks_from(head, display_type);
2005                         }
2006                 }
2007                 string str;
2008                 entity wp = NULL;
2009                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
2010                 {
2011                         crosshair_trace_waypoints(it);
2012                         if (trace_ent)
2013                         {
2014                                 wp = trace_ent;
2015                                 if (wp != it.wp_aimed)
2016                                 {
2017                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: %s\n", etof(wp), wp.wpflags, vtos(wp.origin));
2018                                         if (wp.wpisbox)
2019                                                 str = strcat(str, sprintf("echo \" absmin: %s, absmax: %s\"\n", vtos(wp.absmin), vtos(wp.absmax)));
2020                                         stuffcmd(it, str);
2021                                         str = sprintf("entity: %d\nflags: %d\norigin: %s", etof(wp), wp.wpflags, vtos(wp.origin));
2022                                         if (wp.wpisbox)
2023                                                 str = strcat(str, sprintf(" \nabsmin: %s\nabsmax: %s", vtos(wp.absmin), vtos(wp.absmax)));
2024                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
2025                                 }
2026                         }
2027                 }
2028                 if (it.wp_aimed != wp)
2029                         it.wp_aimed = wp;
2030         });
2031 }
2032
2033 float botframe_autowaypoints_fixdown(vector v)
2034 {
2035         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
2036         if(trace_fraction >= 1)
2037                 return 0;
2038         return 1;
2039 }
2040
2041 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
2042 {
2043         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
2044         {
2045                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
2046                 return 0;
2047         });
2048
2049         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
2050         return 1;
2051 }
2052
2053 // return value:
2054 //    1 = WP created
2055 //    0 = no action needed
2056 //   -1 = temp fail, try from world too
2057 //   -2 = permanent fail, do not retry
2058 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
2059 {
2060         // make it possible to go from p to wp, if we can
2061         // if wp is NULL, nearest is chosen
2062
2063         entity w;
2064         vector porg;
2065         float t, tmin, tmax;
2066         vector o;
2067         vector save;
2068
2069         if(!botframe_autowaypoints_fixdown(p.origin))
2070                 return -2;
2071         porg = trace_endpos;
2072
2073         if(wp)
2074         {
2075                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
2076
2077                 // if wp -> porg, then OK
2078                 float maxdist;
2079                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
2080                 {
2081                         // we may find a better one
2082                         maxdist = vlen(wp.origin - porg);
2083                 }
2084                 else
2085                 {
2086                         // accept any "good"
2087                         maxdist = 2100;
2088                 }
2089
2090                 float bestdist = maxdist;
2091                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
2092                 {
2093                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
2094                         if(d < bestdist)
2095                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
2096                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
2097                         {
2098                                 bestdist = d;
2099                                 p.(fld) = it;
2100                         }
2101                 });
2102                 if(bestdist < maxdist)
2103                 {
2104                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
2105                         return 0;
2106                 }
2107
2108                 if(bestdist < 2100)
2109                 {
2110                         // we know maxdist < 2100
2111                         // so wp -> porg is still valid
2112                         // all is good
2113                         p.(fld) = wp;
2114                         return 0;
2115                 }
2116
2117                 // otherwise, no existing WP can fix our issues
2118         }
2119         else
2120         {
2121                 save = p.origin;
2122                 setorigin(p, porg);
2123                 w = navigation_findnearestwaypoint(p, walkfromwp);
2124                 setorigin(p, save);
2125                 if(w)
2126                 {
2127                         p.(fld) = w;
2128                         return 0;
2129                 }
2130         }
2131
2132         tmin = 0;
2133         tmax = 1;
2134         for (;;)
2135         {
2136                 if(tmax - tmin < 0.001)
2137                 {
2138                         // did not get a good candidate
2139                         return -1;
2140                 }
2141
2142                 t = (tmin + tmax) * 0.5;
2143                 o = antilag_takebackorigin(p, CS(p), time - t);
2144                 if(!botframe_autowaypoints_fixdown(o))
2145                         return -2;
2146                 o = trace_endpos;
2147
2148                 if(wp)
2149                 {
2150                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
2151                         {
2152                                 // we cannot walk from wp.origin to o
2153                                 // get closer to tmax
2154                                 tmin = t;
2155                                 continue;
2156                         }
2157                 }
2158                 else
2159                 {
2160                         save = p.origin;
2161                         setorigin(p, o);
2162                         w = navigation_findnearestwaypoint(p, walkfromwp);
2163                         setorigin(p, save);
2164                         if(!w)
2165                         {
2166                                 // we cannot walk from any WP to o
2167                                 // get closer to tmax
2168                                 tmin = t;
2169                                 continue;
2170                         }
2171                 }
2172
2173                 // if we get here, o is valid regarding waypoints
2174                 // check if o is connected right to the player
2175                 // we break if it succeeds, as that means o is a good waypoint location
2176                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
2177                         break;
2178
2179                 // o is no good, we need to get closer to the player
2180                 tmax = t;
2181         }
2182
2183         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
2184         botframe_autowaypoints_createwp(o, p, fld, 0);
2185         return 1;
2186 }
2187
2188 // automatically create missing waypoints
2189 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
2190 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
2191 {
2192         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
2193         if(r != -1)
2194                 return;
2195         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
2196         if(r != -1)
2197                 return;
2198
2199         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
2200         if(!botframe_autowaypoints_fixdown(p.origin))
2201                 return; // shouldn't happen, caught above
2202         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
2203 }
2204
2205 void botframe_deleteuselesswaypoints()
2206 {
2207         IL_EACH(g_items, it.bot_pickup,
2208         {
2209                 // NOTE: this protects waypoints if they're the ONLY nearest
2210                 // waypoint. That's the intention.
2211                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
2212                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
2213         });
2214         IL_EACH(g_waypoints, true,
2215         {
2216                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
2217                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
2218                 // WP is useful if:
2219                 if (it.wpflags & WAYPOINTFLAG_ITEM)
2220                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2221                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
2222                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2223                 if (it.wpflags & WAYPOINTFLAG_LADDER)
2224                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2225                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
2226                         it.wpflags |= WAYPOINTFLAG_USEFUL;
2227                 // b) WP is closest WP for an item/spawnpoint/other entity
2228                 //    This has been done above by protecting these WPs.
2229         });
2230         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
2231         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
2232         {
2233                 for (int m = 0; m < 32; ++m)
2234                 {
2235                         entity w = waypoint_get_link(it, m);
2236                         if (!w)
2237                                 break;
2238                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
2239                                 continue;
2240                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
2241                                 continue;
2242                         for (int j = 0; j < 32; ++j)
2243                         {
2244                                 entity w2 = waypoint_get_link(w, j);
2245                                 if (!w2)
2246                                         break;
2247                                 if (it == w2)
2248                                         continue;
2249                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
2250                                         continue;
2251                                 // If we got here, it != w2 exist with it -> w
2252                                 // and w -> w2. That means the waypoint is not
2253                                 // a dead end.
2254                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
2255                                 for (int k = 0; k < 32; ++k)
2256                                 {
2257                                         if (waypoint_get_link(it, k) == w2)
2258                                                 continue;
2259                                         // IF WE GET HERE, w is proven useful
2260                                         // to get from it to w2!
2261                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
2262                                         goto next;
2263                                 }
2264                         }
2265 LABEL(next)
2266                 }
2267         });
2268         // d) The waypoint is a dead end. Dead end waypoints must be kept as
2269         //     they are needed to complete routes while autowaypointing.
2270
2271         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
2272         {
2273                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
2274                 te_explosion(it.origin);
2275                 waypoint_remove(it);
2276                 break;
2277         });
2278
2279         IL_EACH(g_waypoints, true,
2280         {
2281                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
2282         });
2283 }
2284
2285 void botframe_autowaypoints()
2286 {
2287         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
2288                 // going back is broken, so only fix waypoints to walk TO the player
2289                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
2290                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
2291                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
2292         });
2293
2294         if (autocvar_g_waypointeditor_auto >= 2) {
2295                 botframe_deleteuselesswaypoints();
2296         }
2297 }
2298