qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/debug.qh>
  16 #include <common/mapobjects/trigger/jumppads.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19
  20 #include <lib/warpzone/common.qh>
  21 #include <lib/warpzone/util_server.qh>
  22
  23 .entity spawnpointmodel;
  24 void waypoint_unreachable(entity pl)
  25 {
  26         IL_EACH(g_waypoints, true,
  27         {
  28                 it.colormod = '0.5 0.5 0.5';
  29                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  30         });
  31
  32         entity e2 = navigation_findnearestwaypoint(pl, false);
  33         if(!e2)
  34         {
  35                 LOG_INFO("Can't find any waypoint nearby\n");
  36                 return;
  37         }
  38
  39         navigation_markroutes(pl, e2);
  40
  41         int j = 0;
  42         int m = 0;
  43         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  44         {
  45                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  46                 it.colormod_z = 8;
  47                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  48                 j++;
  49                 m++;
  50         });
  51         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  52         navigation_markroutes_inverted(e2);
  53
  54         j = 0;
  55         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  56         {
  57                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  58                 it.colormod_x = 8;
  59                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  60                         m++;
  61                 it.effects |= EF_NODEPTHTEST | EF_RED;
  62                 j++;
  63         });
  64         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  65         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  66
  67         j = 0;
  68         IL_EACH(g_spawnpoints, true,
  69         {
  70                 if (navigation_findnearestwaypoint(it, false))
  71                 {
  72                         if(it.spawnpointmodel)
  73                         {
  74                                 delete(it.spawnpointmodel);
  75                                 it.spawnpointmodel = NULL;
  76                         }
  77                 }
  78                 else
  79                 {
  80                         if(!it.spawnpointmodel)
  81                         {
  82                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  83                                 entity e = new(spawnpointmodel);
  84                                 vector org = trace_endpos + eZ;
  85                                 setorigin(e, org);
  86                                 e.solid = SOLID_TRIGGER;
  87                                 it.spawnpointmodel = e;
  88                         }
  89                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  90                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  91                         _setmodel(it.spawnpointmodel, pl.model);
  92                         it.spawnpointmodel.frame = pl.frame;
  93                         it.spawnpointmodel.skin = pl.skin;
  94                         it.spawnpointmodel.colormap = pl.colormap;
  95                         it.spawnpointmodel.colormod = pl.colormod;
  96                         it.spawnpointmodel.glowmod = pl.glowmod;
  97                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  98                         j++;
  99                 }
 100         });
 101         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 102
 103         j = 0;
 104         IL_EACH(g_items, true,
 105         {
 106                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 107                 it.colormod = '0.5 0.5 0.5';
 108         });
 109         IL_EACH(g_items, true,
 110         {
 111                 if (navigation_findnearestwaypoint(it, false))
 112                         continue;
 113                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 114                 it.effects |= EF_NODEPTHTEST | EF_RED;
 115                 it.colormod_x = 8;
 116                 j++;
 117         });
 118         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 119
 120         j = 0;
 121         IL_EACH(g_items, true,
 122         {
 123                 if (navigation_findnearestwaypoint(it, true))
 124                         continue;
 125                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 126                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 127                 it.colormod_z = 8;
 128                 j++;
 129         });
 130         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 131 }
 132
 133 void waypoint_getSymmetricalAxis_cmd(entity caller, bool save, int arg_idx)
 134 {
 135         vector v1 = stov(argv(arg_idx++));
 136         vector v2 = stov(argv(arg_idx++));
 137         vector mid = (v1 + v2) / 2;
 138
 139         float diffy = (v2.y - v1.y);
 140         float diffx = (v2.x - v1.x);
 141         if (v1.y == v2.y)
 142                 diffy = 0.000001;
 143         if (v1.x == v2.x)
 144                 diffx = 0.000001;
 145         float m = - diffx / diffy;
 146         float q = - m * mid.x + mid.y;
 147         if (fabs(m) <= 0.000001) m = 0;
 148         if (fabs(q) <= 0.000001) q = 0;
 149
 150         string axis_str =  strcat(ftos(m), " ", ftos(q));
 151         if (save)
 152                 cvar_set("g_waypointeditor_symmetrical_axis", axis_str);
 153         axis_str = strcat("\"", axis_str, "\"");
 154         sprint(caller, strcat("Axis of symmetry based on input points: ", axis_str, "\n"));
 155         if (save)
 156                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_axis"));
 157         if (save)
 158         {
 159                 cvar_set("g_waypointeditor_symmetrical", "-2");
 160                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 161                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 162         }
 163 }
 164
 165 void waypoint_getSymmetricalOrigin_cmd(entity caller, bool save, int arg_idx)
 166 {
 167         vector org = '0 0 0';
 168         int ctf_flags = 0;
 169         for (int i = 0; i < 6; i++)
 170         {
 171                 if (argv(arg_idx + i) != "")
 172                         ctf_flags++;
 173         }
 174         if (ctf_flags < 2)
 175         {
 176                 ctf_flags = 0;
 177                 org = vec2(havocbot_middlepoint);
 178                 if (argv(arg_idx) != "")
 179                         sprint(caller, "WARNING: Ignoring single input point\n");
 180                 if (havocbot_middlepoint_radius == 0)
 181                 {
 182                         sprint(caller, "Origin of symmetry can't be automatically determined\n");
 183                         return;
 184                 }
 185         }
 186         else
 187         {
 188                 vector v1, v2, v3, v4, v5, v6;
 189                 for (int i = 1; i <= ctf_flags; i++)
 190                 {
 191                         if (i == 1) { v1 = stov(argv(arg_idx++)); org = v1 / ctf_flags; }
 192                         else if (i == 2) { v2 = stov(argv(arg_idx++)); org += v2 / ctf_flags; }
 193                         else if (i == 3) { v3 = stov(argv(arg_idx++)); org += v3 / ctf_flags; }
 194                         else if (i == 4) { v4 = stov(argv(arg_idx++)); org += v4 / ctf_flags; }
 195                         else if (i == 5) { v5 = stov(argv(arg_idx++)); org += v5 / ctf_flags; }
 196                         else if (i == 6) { v6 = stov(argv(arg_idx++)); org += v6 / ctf_flags; }
 197                 }
 198         }
 199
 200         if (fabs(org.x) <= 0.000001) org.x = 0;
 201         if (fabs(org.y) <= 0.000001) org.y = 0;
 202         string org_str = strcat(ftos(org.x), " ", ftos(org.y));
 203         if (save)
 204         {
 205                 cvar_set("g_waypointeditor_symmetrical_origin", org_str);
 206                 cvar_set("g_waypointeditor_symmetrical_order", ftos(ctf_flags));
 207         }
 208         org_str = strcat("\"", org_str, "\"");
 209
 210         if (ctf_flags < 2)
 211                 sprint(caller, strcat("Origin of symmetry based on flag positions: ", org_str, "\n"));
 212         else
 213                 sprint(caller, strcat("Origin of symmetry based on input points: ", org_str, "\n"));
 214         if (save)
 215                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_origin"));
 216
 217         if (ctf_flags < 2)
 218                 sprint(caller, "Order of symmetry: 0 (autodetected)\n");
 219         else
 220                 sprint(caller, strcat("Order of symmetry: ", ftos(ctf_flags), "\n"));
 221         if (save)
 222                 sprint(caller, sprintf(" ^3saved to %s\n", "g_waypointeditor_symmetrical_order"));
 223
 224         if (save)
 225         {
 226                 if (ctf_flags < 2)
 227                         cvar_set("g_waypointeditor_symmetrical", "0");
 228                 else
 229                         cvar_set("g_waypointeditor_symmetrical", "-1");
 230                 sprint(caller, strcat("g_waypointeditor_symmetrical", " has been set to ",
 231                         cvar_string("g_waypointeditor_symmetrical"), "\n"));
 232         }
 233 }
 234
 235 vector waypoint_getSymmetricalPoint(vector org, int ctf_flags)
 236 {
 237         vector new_org = org;
 238         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 239         {
 240                 vector map_center = havocbot_middlepoint;
 241                 if (autocvar_g_waypointeditor_symmetrical == -1)
 242                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 243
 244                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 245         }
 246         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 247         {
 248                 float m = havocbot_symmetry_axis_m;
 249                 float q = havocbot_symmetry_axis_q;
 250                 if (autocvar_g_waypointeditor_symmetrical == -2)
 251                 {
 252                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 253                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 254                 }
 255
 256                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 257                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 258         }
 259         new_org.z = org.z;
 260         return new_org;
 261 }
 262
 263 void waypoint_setupmodel(entity wp)
 264 {
 265         if (autocvar_g_waypointeditor)
 266         {
 267                 // TODO: add some sort of visible box in edit mode for box waypoints
 268                 vector m1 = wp.mins;
 269                 vector m2 = wp.maxs;
 270                 setmodel(wp, MDL_WAYPOINT);
 271                 setsize(wp, m1, m2);
 272                 wp.effects = EF_LOWPRECISION;
 273                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 274                         wp.colormod = '1 0 0';
 275                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 276                         wp.colormod = '1 1 0';
 277                 else if (wp.wpflags & WAYPOINTFLAG_NORELINK)
 278                         wp.colormod = '1 0.5 0'; // orange
 279                 else if (wp.wphardwired)
 280                         wp.colormod = '0.5 0 1'; // violet
 281                 else
 282                         wp.colormod = '1 1 1';
 283         }
 284         else
 285                 wp.model = "";
 286 }
 287
 288 entity waypoint_spawn(vector m1, vector m2, float f)
 289 {
 290         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 291         {
 292                 vector em1 = m1 - '8 8 8';
 293                 vector em2 = m2 + '8 8 8';
 294                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 295                 {
 296                         return it;
 297                 });
 298         }
 299         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 300         // otherwise links loaded from file would be applied only to the first destination
 301         // waypoint since link format doesn't specify waypoint entities but just positions
 302         if((f & WAYPOINTFLAG_GENERATED) && !(f & (WAYPOINTFLAG_NORELINK | WAYPOINTFLAG_PERSONAL)) && m1 == m2)
 303         {
 304                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 305                 {
 306                         return it;
 307                 });
 308         }
 309
 310         entity w = new(waypoint);
 311         IL_PUSH(g_waypoints, w);
 312         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 313         w.wpflags = f;
 314         w.solid = SOLID_TRIGGER;
 315         setorigin(w, (m1 + m2) * 0.5);
 316         setsize(w, m1 - w.origin, m2 - w.origin);
 317         if (w.size)
 318                 w.wpisbox = true;
 319
 320         if(!w.wpisbox)
 321         {
 322                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 323                 if(!move_out_of_solid(w))
 324                 {
 325                         if(!(f & WAYPOINTFLAG_GENERATED))
 326                         {
 327                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 328                                 delete(w);
 329                                 return NULL;
 330                         }
 331                         else
 332                         {
 333                                 if(autocvar_developer)
 334                                 {
 335                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 336                                         backtrace("Waypoint stuck");
 337                                 }
 338                         }
 339                 }
 340                 setsize(w, '0 0 0', '0 0 0');
 341         }
 342
 343         waypoint_clearlinks(w);
 344         //waypoint_schedulerelink(w);
 345
 346         waypoint_setupmodel(w);
 347
 348         return w;
 349 }
 350
 351 float trigger_push_get_push_time(entity this, vector endpos);
 352 void waypoint_addlink_for_custom_jumppad(entity wp_from, entity wp_to)
 353 {
 354         entity jp = NULL;
 355         IL_EACH(g_jumppads, boxesoverlap(wp_from.absmin, wp_from.absmax, it.absmin, it.absmax),
 356         {
 357                 jp = it;
 358         });
 359         float cost = trigger_push_get_push_time(jp, wp_to.origin);
 360         wp_from.wp00 = wp_to;
 361         wp_from.wp00mincost = cost;
 362         jp.nearestwaypoint = wp_from;
 363         jp.nearestwaypointtimeout = -1;
 364 }
 365
 366 bool start_wp_is_spawned;
 367 vector start_wp_origin;
 368
 369 void waypoint_clear_start_wp(entity pl)
 370 {
 371         start_wp_is_spawned = false;
 372         start_wp_origin = '0 0 0';
 373         pl.wp_locked = NULL;
 374         LOG_INFO("^xf80Start waypoint has been cleared\n");
 375 }
 376
 377 void waypoint_spawn_fromeditor(entity pl, bool at_crosshair)
 378 {
 379         entity e = NULL, jp = NULL;
 380         vector org = pl.origin;
 381         if (at_crosshair)
 382         {
 383                 crosshair_trace(pl);
 384                 org = trace_endpos - eZ * PL_MIN_CONST.z;
 385                 IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 386                 {
 387                         jp = it;
 388                         break;
 389                 });
 390                 if (jp && start_wp_is_spawned)
 391                         start_wp_is_spawned = false;
 392                 LOG_INFO("^xf80Spawning start waypoint\n");
 393         }
 394         int ctf_flags = havocbot_symmetry_origin_order;
 395         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 396                    || (autocvar_g_waypointeditor_symmetrical < 0));
 397         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 398                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 399         if (sym && ctf_flags < 2)
 400                 ctf_flags = 2;
 401         int wp_num = ctf_flags;
 402
 403         if(!PHYS_INPUT_BUTTON_CROUCH(pl) && !at_crosshair)
 404         {
 405                 // snap waypoint to item's origin if close enough
 406                 IL_EACH(g_items, true,
 407                 {
 408                         vector item_org = (it.absmin + it.absmax) * 0.5;
 409                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 410                         if (vlen(item_org - org) < 20)
 411                         {
 412                                 org = item_org;
 413                                 break;
 414                         }
 415                 });
 416         }
 417
 418         vector start_org = '0 0 0';
 419         if (start_wp_is_spawned)
 420         {
 421                 LOG_INFO("^xf80Spawning destination waypoint\n");
 422                 start_org = start_wp_origin;
 423         }
 424
 425         // save org as it can be modified spawning symmetrycal waypoints
 426         vector org_save = org;
 427
 428         LABEL(add_wp);
 429
 430         if (jp)
 431         {
 432                 e = NULL;
 433                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 434                         && boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 435                 {
 436                         e = it; break;
 437                 });
 438                 if (!e)
 439                         e = waypoint_spawn(jp.absmin - PL_MAX_CONST + '1 1 1', jp.absmax - PL_MIN_CONST + '-1 -1 -1', WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_NORELINK);
 440                 if (!pl.wp_locked)
 441                         pl.wp_locked = e;
 442         }
 443         else
 444                 e = waypoint_spawn(org, org, 0);
 445         if(!e)
 446         {
 447                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 448                 if (start_wp_is_spawned)
 449                         waypoint_clear_start_wp(pl);
 450                 return;
 451         }
 452
 453         entity start_wp = NULL;
 454         if (start_wp_is_spawned)
 455         {
 456                 IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_NORELINK
 457                         && boxesoverlap(start_org, start_org, it.absmin, it.absmax),
 458                 {
 459                         start_wp = it; break;
 460                 });
 461                 if(!start_wp)
 462                 {
 463                         // should not happen
 464                         LOG_INFOF("Couldn't find start waypoint at %v\n", start_org);
 465                         waypoint_clear_start_wp(pl);
 466                         return;
 467                 }
 468                 waypoint_addlink_for_custom_jumppad(start_wp, e);
 469         }
 470
 471         waypoint_schedulerelink(e);
 472         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 473
 474         if (start_wp_is_spawned)
 475         {
 476                 pl.wp_locked = NULL;
 477                 waypoint_schedulerelink(start_wp);
 478         }
 479
 480         if (sym)
 481         {
 482                 org = waypoint_getSymmetricalPoint(org, ctf_flags);
 483                 if (jp)
 484                 {
 485                         IL_EACH(g_jumppads, boxesoverlap(org + PL_MIN_CONST, org + PL_MAX_CONST, it.absmin, it.absmax),
 486                         {
 487                                 jp = it; break;
 488                         });
 489                 }
 490                 if (start_wp_is_spawned)
 491                         start_org = waypoint_getSymmetricalPoint(start_org, ctf_flags);
 492                 if (vdist(org - pl.origin, >, 32))
 493                 {
 494                         if(wp_num > 2)
 495                                 wp_num--;
 496                         else
 497                                 sym = false;
 498                         goto add_wp;
 499                 }
 500         }
 501
 502         if (jp)
 503         {
 504                 if (!start_wp_is_spawned)
 505                 {
 506                         // we've just created a custom jumppad waypoint
 507                         // the next one created by the user will be the destination waypoint
 508                         start_wp_is_spawned = true;
 509                         start_wp_origin = org_save;
 510                 }
 511         }
 512 }
 513
 514 void waypoint_remove(entity wp)
 515 {
 516         IL_EACH(g_waypoints, it != wp,
 517         {
 518                 if (waypoint_islinked(it, wp))
 519                         waypoint_removelink(it, wp);
 520         });
 521         delete(wp);
 522 }
 523
 524 void waypoint_remove_fromeditor(entity pl)
 525 {
 526         entity e = navigation_findnearestwaypoint(pl, false);
 527
 528         int ctf_flags = havocbot_symmetry_origin_order;
 529         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 530                    || (autocvar_g_waypointeditor_symmetrical < 0));
 531         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 532                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 533         if (sym && ctf_flags < 2)
 534                 ctf_flags = 2;
 535         int wp_num = ctf_flags;
 536
 537         LABEL(remove_wp);
 538         if (!e) return;
 539         if (e.wpflags & WAYPOINTFLAG_GENERATED)
 540         {
 541                 if (start_wp_is_spawned)
 542                         waypoint_clear_start_wp(pl);
 543                 return;
 544         }
 545
 546         if (e.wphardwired)
 547         {
 548                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 549                 return;
 550         }
 551
 552         entity wp_sym = NULL;
 553         if (sym)
 554         {
 555                 vector org = waypoint_getSymmetricalPoint(e.origin, ctf_flags);
 556                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 557                         if(vdist(org - it.origin, <, 3))
 558                         {
 559                                 wp_sym = it;
 560                                 break;
 561                         }
 562                 });
 563         }
 564
 565         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 566         waypoint_remove(e);
 567
 568         if (sym && wp_sym)
 569         {
 570                 e = wp_sym;
 571                 if(wp_num > 2)
 572                         wp_num--;
 573                 else
 574                         sym = false;
 575                 goto remove_wp;
 576         }
 577
 578         if (start_wp_is_spawned)
 579                 waypoint_clear_start_wp(pl);
 580 }
 581
 582 void waypoint_removelink(entity from, entity to)
 583 {
 584         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 585                 return;
 586
 587         entity fromwp31_prev = from.wp31;
 588
 589         switch (waypoint_getlinknum(from, to))
 590         {
 591                 // fallthrough all the way
 592                 case  0: from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;
 593                 case  1: from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;
 594                 case  2: from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;
 595                 case  3: from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;
 596                 case  4: from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;
 597                 case  5: from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;
 598                 case  6: from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;
 599                 case  7: from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;
 600                 case  8: from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;
 601                 case  9: from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;
 602                 case 10: from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;
 603                 case 11: from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;
 604                 case 12: from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;
 605                 case 13: from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;
 606                 case 14: from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;
 607                 case 15: from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;
 608                 case 16: from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;
 609                 case 17: from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;
 610                 case 18: from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;
 611                 case 19: from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;
 612                 case 20: from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;
 613                 case 21: from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;
 614                 case 22: from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;
 615                 case 23: from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;
 616                 case 24: from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;
 617                 case 25: from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;
 618                 case 26: from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;
 619                 case 27: from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;
 620                 case 28: from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;
 621                 case 29: from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;
 622                 case 30: from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;
 623                 case 31: from.wp31 = NULL; from.wp31mincost = 10000000;
 624         }
 625
 626         if (fromwp31_prev && !from.wp31)
 627                 waypoint_schedulerelink(from);
 628 }
 629
 630 int waypoint_getlinknum(entity from, entity to)
 631 {
 632         if (from.wp00 == to) return  0; if (from.wp01 == to) return  1; if (from.wp02 == to) return  2; if (from.wp03 == to) return  3;
 633         if (from.wp04 == to) return  4; if (from.wp05 == to) return  5; if (from.wp06 == to) return  6; if (from.wp07 == to) return  7;
 634         if (from.wp08 == to) return  8; if (from.wp09 == to) return  9; if (from.wp10 == to) return 10; if (from.wp11 == to) return 11;
 635         if (from.wp12 == to) return 12; if (from.wp13 == to) return 13; if (from.wp14 == to) return 14; if (from.wp15 == to) return 15;
 636         if (from.wp16 == to) return 16; if (from.wp17 == to) return 17; if (from.wp18 == to) return 18; if (from.wp19 == to) return 19;
 637         if (from.wp20 == to) return 20; if (from.wp21 == to) return 21; if (from.wp22 == to) return 22; if (from.wp23 == to) return 23;
 638         if (from.wp24 == to) return 24; if (from.wp25 == to) return 25; if (from.wp26 == to) return 26; if (from.wp27 == to) return 27;
 639         if (from.wp28 == to) return 28; if (from.wp29 == to) return 29; if (from.wp30 == to) return 30; if (from.wp31 == to) return 31;
 640         return -1;
 641 }
 642
 643 bool waypoint_islinked(entity from, entity to)
 644 {
 645         return (waypoint_getlinknum(from, to) >= 0);
 646 }
 647
 648 void waypoint_updatecost_foralllinks()
 649 {
 650         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 651         {
 652                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 653                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 654                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 655                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 656                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 657                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 658                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 659                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 660                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 661                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 662                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 663                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 664                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 665                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 666                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 667                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 668                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 669                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 670                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 671                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 672                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 673                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 674                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 675                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 676                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 677                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 678                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 679                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 680                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 681                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 682                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 683                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 684         });
 685 }
 686
 687 float waypoint_getlinearcost(float dist)
 688 {
 689         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 690                 return dist / (autocvar_sv_maxspeed * 1.25);
 691         return dist / autocvar_sv_maxspeed;
 692 }
 693 float waypoint_getlinearcost_underwater(float dist)
 694 {
 695         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 696         return dist / (autocvar_sv_maxspeed * 0.7);
 697 }
 698
 699 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 700 {
 701         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 702         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 703
 704         if (submerged_from && submerged_to)
 705                 return waypoint_getlinearcost_underwater(vlen(to - from));
 706
 707         float c = waypoint_getlinearcost(vlen(to - from));
 708
 709         float height = from.z - to.z;
 710         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 711         {
 712                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 713                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 714                 if(height_cost > c)
 715                         c = height_cost;
 716         }
 717
 718         if (submerged_from || submerged_to)
 719                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 720         return c;
 721 }
 722
 723 float waypoint_getlinkcost(entity from, entity to)
 724 {
 725         vector v1 = from.origin;
 726         vector v2 = to.origin;
 727         if (from.wpisbox)
 728         {
 729                 vector m1 = from.absmin, m2 = from.absmax;
 730                 v1.x = bound(m1.x, v2.x, m2.x);
 731                 v1.y = bound(m1.y, v2.y, m2.y);
 732                 v1.z = bound(m1.z, v2.z, m2.z);
 733         }
 734         if (to.wpisbox)
 735         {
 736                 vector m1 = to.absmin, m2 = to.absmax;
 737                 v2.x = bound(m1.x, v1.x, m2.x);
 738                 v2.y = bound(m1.y, v1.y, m2.y);
 739                 v2.z = bound(m1.z, v1.z, m2.z);
 740         }
 741         return waypoint_gettravelcost(v1, v2, from, to);
 742 }
 743
 744 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 745 // if c == -1 automatically determine cost of the link
 746 void waypoint_addlink_customcost(entity from, entity to, float c)
 747 {
 748         if (from == to || waypoint_islinked(from, to))
 749                 return;
 750         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 751                 return;
 752
 753         if(c == -1)
 754                 c = waypoint_getlinkcost(from, to);
 755
 756         if (from.wp31mincost < c) return;
 757         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 758         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 759         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 760         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 761         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 762         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 763         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 764         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 765         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 766         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 767         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 768         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 769         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 770         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 771         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 772         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 773         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 774         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 775         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 776         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 777         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 778         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 779         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 780         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 781         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 782         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 783         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 784         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 785         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 786         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 787         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 788         from.wp00 = to;from.wp00mincost = c;return;
 789 }
 790
 791 void waypoint_addlink(entity from, entity to)
 792 {
 793         waypoint_addlink_customcost(from, to, -1);
 794 }
 795
 796 // relink this spawnfunc_waypoint
 797 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 798 // (SLOW!)
 799 void waypoint_think(entity this)
 800 {
 801         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 802         float sv2_height = 0, ev2_height = 0;
 803
 804         bot_calculate_stepheightvec();
 805
 806         int dphitcontentsmask_save = this.dphitcontentsmask;
 807         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 808
 809         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 810
 811         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 812         IL_EACH(g_waypoints, this != it,
 813         {
 814                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 815                 {
 816                         waypoint_addlink(this, it);
 817                         waypoint_addlink(it, this);
 818                 }
 819                 else
 820                 {
 821                         ++relink_total;
 822                         if(!checkpvs(this.origin, it))
 823                         {
 824                                 ++relink_pvsculled;
 825                                 continue;
 826                         }
 827
 828                         sv = set_tracewalk_dest_2(this, it.origin);
 829                         sv2 = tracewalk_dest;
 830                         sv2_height = tracewalk_dest_height;
 831                         ev = set_tracewalk_dest_2(it, this.origin);
 832                         ev2 = tracewalk_dest;
 833                         ev2_height = tracewalk_dest_height;
 834
 835                         dv = ev - sv;
 836                         dv.z = 0;
 837                         if(vdist(dv, >=, 1050)) // max search distance in XY
 838                         {
 839                                 ++relink_lengthculled;
 840                                 continue;
 841                         }
 842
 843                         navigation_testtracewalk = 0;
 844
 845                         //traceline(this.origin, it.origin, false, NULL);
 846                         //if (trace_fraction == 1)
 847                         if (this.wpisbox)
 848                                 relink_walkculled += 0.5;
 849                         else
 850                         {
 851                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 852                                         waypoint_addlink(this, it);
 853                                 else
 854                                         relink_walkculled += 0.5;
 855                         }
 856
 857                         if (it.wpisbox)
 858                                 relink_walkculled += 0.5;
 859                         else
 860                         {
 861                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 862                                         waypoint_addlink(it, this);
 863                                 else
 864                                         relink_walkculled += 0.5;
 865                         }
 866                 }
 867         });
 868         navigation_testtracewalk = 0;
 869         this.wplinked = true;
 870         this.dphitcontentsmask = dphitcontentsmask_save;
 871
 872         setthink(this, func_null);
 873         this.nextthink = 0;
 874 }
 875
 876 void waypoint_clearlinks(entity wp)
 877 {
 878         // clear links to other waypoints
 879         float f = 10000000;
 880         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 881         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 882         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 883         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 884
 885         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 886         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 887         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 888         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 889
 890         wp.wplinked = false;
 891 }
 892
 893 // tell a spawnfunc_waypoint to relink
 894 void waypoint_schedulerelink(entity wp)
 895 {
 896         if (wp == NULL)
 897                 return;
 898
 899         waypoint_setupmodel(wp);
 900         wp.wpisbox = vdist(wp.size, >, 0);
 901         wp.enemy = NULL;
 902         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 903                 wp.owner = NULL;
 904         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 905                 waypoint_clearlinks(wp);
 906         // schedule an actual relink on next frame
 907         setthink(wp, waypoint_think);
 908         wp.nextthink = time;
 909         wp.effects = EF_LOWPRECISION;
 910 }
 911
 912 // spawnfunc_waypoint map entity
 913 spawnfunc(waypoint)
 914 {
 915         IL_PUSH(g_waypoints, this);
 916
 917         setorigin(this, this.origin);
 918         // schedule a relink after other waypoints have had a chance to spawn
 919         waypoint_clearlinks(this);
 920         //waypoint_schedulerelink(this);
 921 }
 922
 923 // tell all waypoints to relink
 924 // actually this is useful only to update relink_* stats
 925 void waypoint_schedulerelinkall()
 926 {
 927         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 928         IL_EACH(g_waypoints, true,
 929         {
 930                 waypoint_schedulerelink(it);
 931         });
 932         waypoint_load_links_hardwired();
 933 }
 934
 935 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 936
 937 // Load waypoint links from file
 938 bool waypoint_load_links()
 939 {
 940         string s;
 941         float file, tokens, c = 0, found;
 942         entity wp_from = NULL, wp_to;
 943         vector wp_to_pos, wp_from_pos;
 944
 945         string gt_ext = GET_GAMETYPE_EXTENSION();
 946
 947         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 948         file = fopen(filename, FILE_READ);
 949
 950         if (gt_ext != "" && file < 0)
 951         {
 952                 // if race waypoint file doesn't exist load the default one
 953                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 954                 file = fopen(filename, FILE_READ);
 955         }
 956
 957         if (file < 0)
 958         {
 959                 LOG_TRACE("waypoint links load from ", filename, " failed");
 960                 waypoint_schedulerelinkall();
 961                 return false;
 962         }
 963
 964         bool parse_comments = true;
 965         float ver = 0;
 966         string links_time = string_null;
 967
 968         while ((s = fgets(file)))
 969         {
 970                 if(parse_comments)
 971                 {
 972                         if(substring(s, 0, 2) == "//")
 973                         {
 974                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 975                                         ver = stof(substring(s, 19, -1));
 976                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
 977                                         links_time = substring(s, 16, -1);
 978                                 continue;
 979                         }
 980                         else
 981                         {
 982                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
 983                                 {
 984                                         if (links_time != waypoint_time)
 985                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
 986                                         else
 987                                                 LOG_TRACE("waypoint links for this map are outdated.");
 988                                         if (g_assault)
 989                                         {
 990                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
 991                                         }
 992                                         else
 993                                         {
 994                                                 LOG_TRACE("automatically updating...");
 995                                                 waypoint_schedulerelinkall();
 996                                                 fclose(file);
 997                                                 return false;
 998                                         }
 999                                 }
1000                                 parse_comments = false;
1001                         }
1002                 }
1003
1004                 tokens = tokenizebyseparator(s, "*");
1005
1006                 if (tokens!=2)
1007                 {
1008                         // bad file format
1009                         fclose(file);
1010                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
1011                         return false;
1012                 }
1013
1014                 wp_from_pos     = stov(argv(0));
1015                 wp_to_pos       = stov(argv(1));
1016
1017                 // Search "from" waypoint
1018                 if(!wp_from || wp_from.origin!=wp_from_pos)
1019                 {
1020                         wp_from = findradius(wp_from_pos, 1);
1021                         found = false;
1022                         while(wp_from)
1023                         {
1024                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
1025                                 if(wp_from.classname == "waypoint")
1026                                 {
1027                                         found = true;
1028                                         break;
1029                                 }
1030                                 wp_from = wp_from.chain;
1031                         }
1032
1033                         if(!found)
1034                         {
1035                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
1036                                 continue;
1037                         }
1038                 }
1039
1040                 // Search "to" waypoint
1041                 wp_to = findradius(wp_to_pos, 1);
1042                 found = false;
1043                 while(wp_to)
1044                 {
1045                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
1046                         if(wp_to.classname == "waypoint")
1047                         {
1048                                 found = true;
1049                                 break;
1050                         }
1051                         wp_to = wp_to.chain;
1052                 }
1053
1054                 if(!found)
1055                 {
1056                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
1057                         continue;
1058                 }
1059
1060                 ++c;
1061                 if ((wp_from.wpflags & WAYPOINTFLAG_NORELINK) && !(wp_from.wpflags & WAYPOINTFLAG_GENERATED))
1062                         waypoint_addlink_for_custom_jumppad(wp_from, wp_to);
1063                 else
1064                         waypoint_addlink(wp_from, wp_to);
1065         }
1066
1067         fclose(file);
1068
1069         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
1070
1071         bool scheduled = false;
1072         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
1073         {
1074                 if (!it.wp00)
1075                 {
1076                         waypoint_schedulerelink(it);
1077                         scheduled = true;
1078                 }
1079         });
1080         if (scheduled)
1081                 return false;
1082
1083         botframe_cachedwaypointlinks = true;
1084         return true;
1085 }
1086
1087 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
1088 {
1089         string s;
1090         float file, tokens, c = 0, found;
1091         entity wp_from = NULL, wp_to;
1092         vector wp_to_pos, wp_from_pos;
1093
1094         string gt_ext = GET_GAMETYPE_EXTENSION();
1095
1096         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
1097         file = fopen(filename, FILE_READ);
1098
1099         if (gt_ext != "" && file < 0)
1100         {
1101                 // if race waypoint file doesn't exist load the default one
1102                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
1103                 file = fopen(filename, FILE_READ);
1104         }
1105
1106         botframe_loadedforcedlinks = true;
1107
1108         if (file < 0)
1109         {
1110                 if(!removal_mode)
1111                         LOG_TRACE("waypoint links load from ", filename, " failed");
1112                 return;
1113         }
1114
1115         while ((s = fgets(file)))
1116         {
1117                 if(substring(s, 0, 2)=="//")
1118                         continue;
1119
1120                 if(substring(s, 0, 1)=="#")
1121                         continue;
1122
1123                 tokens = tokenizebyseparator(s, "*");
1124
1125                 if (tokens!=2)
1126                         continue;
1127
1128                 wp_from_pos     = stov(argv(0));
1129                 wp_to_pos       = stov(argv(1));
1130
1131                 // Search "from" waypoint
1132                 if(!wp_from || wp_from.origin!=wp_from_pos)
1133                 {
1134                         wp_from = findradius(wp_from_pos, 5);
1135                         found = false;
1136                         while(wp_from)
1137                         {
1138                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
1139                                 if(wp_from.classname == "waypoint")
1140                                 {
1141                                         found = true;
1142                                         break;
1143                                 }
1144                                 wp_from = wp_from.chain;
1145                         }
1146
1147                         if(!found)
1148                         {
1149                                 if(!removal_mode)
1150                                         LOG_INFO("NOTICE: Can not find origin waypoint for the hardwired link ", s, ". Path skipped");
1151                                 continue;
1152                         }
1153                 }
1154
1155                 // Search "to" waypoint
1156                 wp_to = findradius(wp_to_pos, 5);
1157                 found = false;
1158                 while(wp_to)
1159                 {
1160                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
1161                         if(wp_to.classname == "waypoint")
1162                         {
1163                                 found = true;
1164                                 break;
1165                         }
1166                         wp_to = wp_to.chain;
1167                 }
1168
1169                 if(!found)
1170                 {
1171                         if(!removal_mode)
1172                                 LOG_INFO("NOTICE: Can not find destination waypoint for the hardwired link ", s, ". Path skipped");
1173                         continue;
1174                 }
1175
1176                 ++c;
1177                 if(removal_mode)
1178                 {
1179                         waypoint_removelink(wp_from, wp_to);
1180                         continue;
1181                 }
1182
1183                 waypoint_addlink(wp_from, wp_to);
1184                 wp_from.wphardwired = true;
1185                 wp_to.wphardwired = true;
1186                 waypoint_setupmodel(wp_from);
1187                 waypoint_setupmodel(wp_to);
1188         }
1189
1190         fclose(file);
1191
1192         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
1193                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
1194 }
1195
1196 entity waypoint_get_link(entity w, float i)
1197 {
1198         switch(i)
1199         {
1200                 case  0:return w.wp00;
1201                 case  1:return w.wp01;
1202                 case  2:return w.wp02;
1203                 case  3:return w.wp03;
1204                 case  4:return w.wp04;
1205                 case  5:return w.wp05;
1206                 case  6:return w.wp06;
1207                 case  7:return w.wp07;
1208                 case  8:return w.wp08;
1209                 case  9:return w.wp09;
1210                 case 10:return w.wp10;
1211                 case 11:return w.wp11;
1212                 case 12:return w.wp12;
1213                 case 13:return w.wp13;
1214                 case 14:return w.wp14;
1215                 case 15:return w.wp15;
1216                 case 16:return w.wp16;
1217                 case 17:return w.wp17;
1218                 case 18:return w.wp18;
1219                 case 19:return w.wp19;
1220                 case 20:return w.wp20;
1221                 case 21:return w.wp21;
1222                 case 22:return w.wp22;
1223                 case 23:return w.wp23;
1224                 case 24:return w.wp24;
1225                 case 25:return w.wp25;
1226                 case 26:return w.wp26;
1227                 case 27:return w.wp27;
1228                 case 28:return w.wp28;
1229                 case 29:return w.wp29;
1230                 case 30:return w.wp30;
1231                 case 31:return w.wp31;
1232                 default:return NULL;
1233         }
1234 }
1235
1236 // Save all waypoint links to a file
1237 void waypoint_save_links()
1238 {
1239         // temporarily remove hardwired links so they don't get saved among normal links
1240         waypoint_remove_links_hardwired();
1241
1242         string gt_ext = GET_GAMETYPE_EXTENSION();
1243
1244         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
1245         int file = fopen(filename, FILE_WRITE);
1246         if (file < 0)
1247         {
1248                 LOG_INFOF("waypoint link save to %s failed", filename);
1249                 return;
1250         }
1251
1252         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1253         if (waypoint_time != "")
1254                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1255
1256         int c = 0;
1257         IL_EACH(g_waypoints, true,
1258         {
1259                 for(int j = 0; j < 32; ++j)
1260                 {
1261                         entity link = waypoint_get_link(it, j);
1262                         if(link)
1263                         {
1264                                 // NOTE: vtos rounds vector components to 1 decimal place
1265                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1266                                 fputs(file, s);
1267                                 ++c;
1268                         }
1269                 }
1270         });
1271         fclose(file);
1272
1273         botframe_cachedwaypointlinks = true;
1274
1275         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1276
1277         waypoint_load_links_hardwired();
1278 }
1279
1280 // save waypoints to gamedir/data/maps/mapname.waypoints
1281 void waypoint_saveall()
1282 {
1283         string gt_ext = GET_GAMETYPE_EXTENSION();
1284
1285         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1286         int file = fopen(filename, FILE_WRITE);
1287         if (file < 0)
1288         {
1289                 waypoint_save_links(); // save anyway?
1290                 botframe_loadedforcedlinks = false;
1291
1292                 LOG_INFOF("waypoint links: save to %s failed", filename);
1293                 return;
1294         }
1295
1296         float sym = autocvar_g_waypointeditor_symmetrical;
1297         string sym_str = ftos(sym);
1298         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1299         {
1300                 if (sym == 1)
1301                 {
1302                         sym_str = cons(sym_str, "-");
1303                         sym_str = cons(sym_str, "-");
1304                 }
1305                 else
1306                 {
1307                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1308                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1309                 }
1310                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1311                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1312         }
1313         else if (autocvar_g_waypointeditor_symmetrical == -2)
1314         {
1315                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1316                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1317         }
1318
1319         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1320         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1321         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1322         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1323
1324         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1325         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1326         //fputs(file, strcat("//", "\n"));
1327         //fputs(file, strcat("//", "\n"));
1328         //fputs(file, strcat("//", "\n"));
1329
1330         int c = 0;
1331         IL_EACH(g_waypoints, true,
1332         {
1333                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1334                         continue;
1335
1336                 string s;
1337                 // NOTE: vtos rounds vector components to 1 decimal place
1338                 s = strcat(vtos(it.origin + it.mins), "\n");
1339                 s = strcat(s, vtos(it.origin + it.maxs));
1340                 s = strcat(s, "\n");
1341                 s = strcat(s, ftos(it.wpflags));
1342                 s = strcat(s, "\n");
1343                 fputs(file, s);
1344                 c++;
1345         });
1346         fclose(file);
1347         waypoint_save_links();
1348         botframe_loadedforcedlinks = false;
1349
1350         LOG_INFOF("saved %d waypoints to %s", c, filename);
1351 }
1352
1353 // load waypoints from file
1354 float waypoint_loadall()
1355 {
1356         string s;
1357         float file, cwp, cwb, fl;
1358         vector m1, m2;
1359         cwp = 0;
1360         cwb = 0;
1361
1362         string gt_ext = GET_GAMETYPE_EXTENSION();
1363
1364         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1365         file = fopen(filename, FILE_READ);
1366
1367         if (gt_ext != "" && file < 0)
1368         {
1369                 // if race waypoint file doesn't exist load the default one
1370                 filename = sprintf("maps/%s.waypoints", mapname);
1371                 file = fopen(filename, FILE_READ);
1372         }
1373
1374         if (file < 0)
1375         {
1376                 LOG_TRACE("waypoint load from ", filename, " failed");
1377                 return 0;
1378         }
1379
1380         bool parse_comments = true;
1381         float ver = 0;
1382         float sym = 0;
1383         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1384
1385         while ((s = fgets(file)))
1386         {
1387                 if(parse_comments)
1388                 {
1389                         if(substring(s, 0, 2) == "//")
1390                         {
1391                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1392                                         ver = stof(substring(s, 19, -1));
1393                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1394                                 {
1395                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1396                                         if (tokens) { sym = stof(argv(0)); }
1397                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1398                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1399                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1400                                 }
1401                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1402                                         strcpy(waypoint_time, substring(s, 16, -1));
1403                                 continue;
1404                         }
1405                         else
1406                         {
1407                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1408                                 {
1409                                         LOG_TRACE("waypoints for this map are outdated");
1410                                         LOG_TRACE("please update them in the editor");
1411                                 }
1412                                 parse_comments = false;
1413                         }
1414                 }
1415                 m1 = stov(s);
1416                 s = fgets(file);
1417                 if (!s)
1418                         break;
1419                 m2 = stov(s);
1420                 s = fgets(file);
1421                 if (!s)
1422                         break;
1423                 fl = stof(s);
1424                 waypoint_spawn(m1, m2, fl);
1425                 if (m1 == m2)
1426                         cwp = cwp + 1;
1427                 else
1428                         cwb = cwb + 1;
1429         }
1430         fclose(file);
1431         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1432
1433         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1434         {
1435                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1436                 if (sym == 1 && sym_param3 < 2)
1437                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1438                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1439                 {
1440                         string params;
1441                         if (sym == 1)
1442                                 params = cons("-", "-");
1443                         else
1444                         {
1445                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1446                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1447                         }
1448                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1449                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1450                 }
1451                 else if (sym == -2)
1452                 {
1453                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1454                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1455                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1456                 }
1457                 else
1458                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1459                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1460         }
1461
1462         return cwp + cwb;
1463 }
1464
1465 #define waypoint_fixorigin(position, tracetest_ent) \
1466         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1467
1468 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1469 {
1470         vector endpos = position + down_dir * 3000;
1471         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1472         if(trace_startsolid)
1473                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1474         if(trace_startsolid)
1475                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, endpos, MOVE_NOMONSTERS, tracetest_ent);
1476         if(trace_fraction < 1)
1477                 position = trace_endpos;
1478         return position;
1479 }
1480
1481 void waypoint_spawnforitem_force(entity e, vector org)
1482 {
1483         // Fix the waypoint altitude if necessary
1484         org = waypoint_fixorigin(org, NULL);
1485
1486         // don't spawn an item spawnfunc_waypoint if it already exists
1487         IL_EACH(g_waypoints, true,
1488         {
1489                 if(it.wpisbox)
1490                 {
1491                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1492                         {
1493                                 e.nearestwaypoint = it;
1494                                 return;
1495                         }
1496                 }
1497                 else
1498                 {
1499                         if(vdist(it.origin - org, <, 16))
1500                         {
1501                                 e.nearestwaypoint = it;
1502                                 return;
1503                         }
1504                 }
1505         });
1506
1507         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1508 }
1509
1510 void waypoint_spawnforitem(entity e)
1511 {
1512         if(!bot_waypoints_for_items)
1513                 return;
1514
1515         waypoint_spawnforitem_force(e, e.origin);
1516 }
1517
1518 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1519 {
1520         entity w;
1521         entity dw;
1522         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1523         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1524         // one way link to the destination
1525         w.wp00 = dw;
1526         w.wp00mincost = timetaken; // this is just for jump pads
1527         // the teleporter's nearest spawnfunc_waypoint is this one
1528         // (teleporters are not goals, so this is probably useless)
1529         e.nearestwaypoint = w;
1530         e.nearestwaypointtimeout = -1;
1531 }
1532
1533 void waypoint_spawnforteleporter_wz(entity e, entity tracetest_ent)
1534 {
1535         float src_angle = e.warpzone_angles.x;
1536         while (src_angle < -180) src_angle += 360;
1537         while (src_angle > 180) src_angle -= 360;
1538
1539         float dest_angle = e.enemy.warpzone_angles.x;
1540         while (dest_angle < -180) dest_angle += 360;
1541         while (dest_angle > 180) dest_angle -= 360;
1542
1543         // no waypoints for warpzones pointing upwards, they can't be used by the bots
1544         if (src_angle == -90 || dest_angle == -90)
1545                 return;
1546
1547         makevectors(e.warpzone_angles);
1548         vector src = (e.absmin + e.absmax) * 0.5;
1549         src += ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
1550         vector down_dir_src = -v_up;
1551
1552         makevectors(e.enemy.warpzone_angles);
1553         vector dest = (e.enemy.absmin + e.enemy.absmax) * 0.5;
1554         dest += ((e.enemy.warpzone_origin - dest) * v_forward) * v_forward - 16 * v_right;
1555         vector down_dir_dest = -v_up;
1556
1557         int extra_flag = 0;
1558         // don't snap to the ground waypoints for source warpzones pointing downwards
1559         if (src_angle != 90)
1560         {
1561                 src = waypoint_fixorigin_down_dir(src, tracetest_ent, down_dir_src);
1562                 dest = waypoint_fixorigin_down_dir(dest, tracetest_ent, down_dir_dest);
1563                 // oblique warpzones need a jump otherwise bots gets stuck
1564                 if (src_angle != 0)
1565                         extra_flag = WAYPOINTFLAG_JUMP;
1566         }
1567
1568         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT | extra_flag, src, src, dest, dest, 0);
1569 }
1570
1571 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1572 {
1573         destination = waypoint_fixorigin(destination, tracetest_ent);
1574         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1575 }
1576
1577 entity waypoint_spawnpersonal(entity this, vector position)
1578 {
1579         entity w;
1580
1581         // drop the waypoint to a proper location:
1582         //   first move it up by a player height
1583         //   then move it down to hit the floor with player bbox size
1584         position = waypoint_fixorigin(position, this);
1585
1586         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1587         w.nearestwaypoint = NULL;
1588         w.nearestwaypointtimeout = 0;
1589         w.owner = this;
1590
1591         waypoint_schedulerelink(w);
1592
1593         return w;
1594 }
1595
1596 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1597 {
1598         if (!(wp1 && wp2))
1599                 return;
1600
1601         if (wp1.wphardwired && wp2.wphardwired)
1602                 te_beam(NULL, wp1.origin, wp2.origin);
1603         else if (display_type == 1)
1604                 te_lightning2(NULL, wp1.origin, wp2.origin);
1605 }
1606
1607 void waypoint_showlinks_to(entity wp, int display_type)
1608 {
1609         IL_EACH(g_waypoints, it != wp,
1610         {
1611                 if (waypoint_islinked(it, wp))
1612                         waypoint_showlink(it, wp, display_type);
1613         });
1614 }
1615
1616 void waypoint_showlinks_from(entity wp, int display_type)
1617 {
1618         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1619         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1620         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1621         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1622         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1623         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1624         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1625         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1626         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1627         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1628         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1629         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1630         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1631         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1632         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1633         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1634 }
1635
1636 void crosshair_trace_waypoints(entity pl)
1637 {
1638         IL_EACH(g_waypoints, true, {
1639                 it.solid = SOLID_BSP;
1640                 if (!it.wpisbox)
1641                         setsize(it, '-16 -16 -16', '16 16 16');
1642         });
1643
1644         crosshair_trace(pl);
1645
1646         IL_EACH(g_waypoints, true, {
1647                 it.solid = SOLID_TRIGGER;
1648                 if (!it.wpisbox)
1649                         setsize(it, '0 0 0', '0 0 0');
1650         });
1651         if (trace_ent.classname != "waypoint")
1652                 trace_ent = NULL;
1653 }
1654
1655 void botframe_showwaypointlinks()
1656 {
1657         if (time < botframe_waypointeditorlightningtime)
1658                 return;
1659         botframe_waypointeditorlightningtime = time + 0.5;
1660         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1661         {
1662                 int display_type = 0;
1663                 if (wasfreed(it.wp_aimed))
1664                         it.wp_aimed = NULL;
1665                 if (wasfreed(it.wp_locked))
1666                         it.wp_locked = NULL;
1667                 if (PHYS_INPUT_BUTTON_USE(it))
1668                         it.wp_locked = it.wp_aimed;
1669                 entity head = it.wp_locked;
1670                 if (!head)
1671                         head = navigation_findnearestwaypoint(it, false);
1672                 it.nearestwaypoint = head; // mainly useful for debug
1673                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1674                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE || it.wp_locked)
1675                         display_type = 1; // default
1676                 else if(head && (head.wphardwired))
1677                         display_type = 2; // only hardwired
1678
1679                 if (display_type)
1680                 {
1681                         //navigation_testtracewalk = true;
1682                         //print("currently selected WP is ", etos(head), "\n");
1683                         //navigation_testtracewalk = false;
1684                         if (head)
1685                         {
1686                                 te_lightning2(NULL, head.origin, it.origin);
1687                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1688                                         waypoint_showlinks_to(head, display_type);
1689                                 else
1690                                         waypoint_showlinks_from(head, display_type);
1691                         }
1692                 }
1693                 string str;
1694                 entity wp = NULL;
1695                 if (vdist(vec2(it.velocity), <, autocvar_sv_maxspeed * 1.1))
1696                 {
1697                         crosshair_trace_waypoints(it);
1698                         if (trace_ent)
1699                         {
1700                                 wp = trace_ent;
1701                                 if (wp != it.wp_aimed)
1702                                 {
1703                                         str = sprintf("\necho ^2WP info^7: entity: %d, flags: %d, origin: '%s'\n", etof(wp), wp.wpflags, vtos(wp.origin));
1704                                         if (wp.wpisbox)
1705                                                 str = strcat(str, sprintf("echo \" absmin: '%s', absmax: '%s'\"\n", vtos(wp.absmin), vtos(wp.absmax)));
1706                                         stuffcmd(it, str);
1707                                         str = sprintf("entity: %d\nflags: %d\norigin: \'%s\'", etof(wp), wp.wpflags, vtos(wp.origin));
1708                                         if (wp.wpisbox)
1709                                                 str = strcat(str, sprintf(" \nabsmin: '%s'\nabsmax: '%s'", vtos(wp.absmin), vtos(wp.absmax)));
1710                                         debug_text_3d(wp.origin, str, 0, 7, '0 0 0');
1711                                 }
1712                         }
1713                 }
1714                 if (it.wp_aimed != wp)
1715                         it.wp_aimed = wp;
1716         });
1717 }
1718
1719 float botframe_autowaypoints_fixdown(vector v)
1720 {
1721         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1722         if(trace_fraction >= 1)
1723                 return 0;
1724         return 1;
1725 }
1726
1727 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1728 {
1729         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1730         {
1731                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1732                 return 0;
1733         });
1734
1735         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1736         return 1;
1737 }
1738
1739 // return value:
1740 //    1 = WP created
1741 //    0 = no action needed
1742 //   -1 = temp fail, try from world too
1743 //   -2 = permanent fail, do not retry
1744 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1745 {
1746         // make it possible to go from p to wp, if we can
1747         // if wp is NULL, nearest is chosen
1748
1749         entity w;
1750         vector porg;
1751         float t, tmin, tmax;
1752         vector o;
1753         vector save;
1754
1755         if(!botframe_autowaypoints_fixdown(p.origin))
1756                 return -2;
1757         porg = trace_endpos;
1758
1759         if(wp)
1760         {
1761                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1762
1763                 // if wp -> porg, then OK
1764                 float maxdist;
1765                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1766                 {
1767                         // we may find a better one
1768                         maxdist = vlen(wp.origin - porg);
1769                 }
1770                 else
1771                 {
1772                         // accept any "good"
1773                         maxdist = 2100;
1774                 }
1775
1776                 float bestdist = maxdist;
1777                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1778                 {
1779                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1780                         if(d < bestdist)
1781                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1782                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1783                         {
1784                                 bestdist = d;
1785                                 p.(fld) = it;
1786                         }
1787                 });
1788                 if(bestdist < maxdist)
1789                 {
1790                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1791                         return 0;
1792                 }
1793
1794                 if(bestdist < 2100)
1795                 {
1796                         // we know maxdist < 2100
1797                         // so wp -> porg is still valid
1798                         // all is good
1799                         p.(fld) = wp;
1800                         return 0;
1801                 }
1802
1803                 // otherwise, no existing WP can fix our issues
1804         }
1805         else
1806         {
1807                 save = p.origin;
1808                 setorigin(p, porg);
1809                 w = navigation_findnearestwaypoint(p, walkfromwp);
1810                 setorigin(p, save);
1811                 if(w)
1812                 {
1813                         p.(fld) = w;
1814                         return 0;
1815                 }
1816         }
1817
1818         tmin = 0;
1819         tmax = 1;
1820         for (;;)
1821         {
1822                 if(tmax - tmin < 0.001)
1823                 {
1824                         // did not get a good candidate
1825                         return -1;
1826                 }
1827
1828                 t = (tmin + tmax) * 0.5;
1829                 o = antilag_takebackorigin(p, CS(p), time - t);
1830                 if(!botframe_autowaypoints_fixdown(o))
1831                         return -2;
1832                 o = trace_endpos;
1833
1834                 if(wp)
1835                 {
1836                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1837                         {
1838                                 // we cannot walk from wp.origin to o
1839                                 // get closer to tmax
1840                                 tmin = t;
1841                                 continue;
1842                         }
1843                 }
1844                 else
1845                 {
1846                         save = p.origin;
1847                         setorigin(p, o);
1848                         w = navigation_findnearestwaypoint(p, walkfromwp);
1849                         setorigin(p, save);
1850                         if(!w)
1851                         {
1852                                 // we cannot walk from any WP to o
1853                                 // get closer to tmax
1854                                 tmin = t;
1855                                 continue;
1856                         }
1857                 }
1858
1859                 // if we get here, o is valid regarding waypoints
1860                 // check if o is connected right to the player
1861                 // we break if it succeeds, as that means o is a good waypoint location
1862                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1863                         break;
1864
1865                 // o is no good, we need to get closer to the player
1866                 tmax = t;
1867         }
1868
1869         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1870         botframe_autowaypoints_createwp(o, p, fld, 0);
1871         return 1;
1872 }
1873
1874 // automatically create missing waypoints
1875 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1876 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1877 {
1878         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1879         if(r != -1)
1880                 return;
1881         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1882         if(r != -1)
1883                 return;
1884
1885         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1886         if(!botframe_autowaypoints_fixdown(p.origin))
1887                 return; // shouldn't happen, caught above
1888         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1889 }
1890
1891 void botframe_deleteuselesswaypoints()
1892 {
1893         IL_EACH(g_items, it.bot_pickup,
1894         {
1895                 // NOTE: this protects waypoints if they're the ONLY nearest
1896                 // waypoint. That's the intention.
1897                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1898                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1899         });
1900         IL_EACH(g_waypoints, true,
1901         {
1902                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1903                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1904                 // WP is useful if:
1905                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1906                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1907                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1908                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1909                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1910                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1911                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1912                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1913                 // b) WP is closest WP for an item/spawnpoint/other entity
1914                 //    This has been done above by protecting these WPs.
1915         });
1916         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1917         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1918         {
1919                 for (int m = 0; m < 32; ++m)
1920                 {
1921                         entity w = waypoint_get_link(it, m);
1922                         if (!w)
1923                                 break;
1924                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1925                                 continue;
1926                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1927                                 continue;
1928                         for (int j = 0; j < 32; ++j)
1929                         {
1930                                 entity w2 = waypoint_get_link(w, j);
1931                                 if (!w2)
1932                                         break;
1933                                 if (it == w2)
1934                                         continue;
1935                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1936                                         continue;
1937                                 // If we got here, it != w2 exist with it -> w
1938                                 // and w -> w2. That means the waypoint is not
1939                                 // a dead end.
1940                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1941                                 for (int k = 0; k < 32; ++k)
1942                                 {
1943                                         if (waypoint_get_link(it, k) == w2)
1944                                                 continue;
1945                                         // IF WE GET HERE, w is proven useful
1946                                         // to get from it to w2!
1947                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1948                                         goto next;
1949                                 }
1950                         }
1951 LABEL(next)
1952                 }
1953         });
1954         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1955         //     they are needed to complete routes while autowaypointing.
1956
1957         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1958         {
1959                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1960                 te_explosion(it.origin);
1961                 waypoint_remove(it);
1962                 break;
1963         });
1964
1965         IL_EACH(g_waypoints, true,
1966         {
1967                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1968         });
1969 }
1970
1971 void botframe_autowaypoints()
1972 {
1973         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1974                 // going back is broken, so only fix waypoints to walk TO the player
1975                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1976                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1977                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1978         });
1979
1980         if (autocvar_g_waypointeditor_auto >= 2) {
1981                 botframe_deleteuselesswaypoints();
1982         }
1983 }
1984