qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17
  18 #include <lib/warpzone/common.qh>
  19 #include <lib/warpzone/util_server.qh>
  20
  21 .entity spawnpointmodel;
  22 void waypoint_unreachable(entity pl)
  23 {
  24         IL_EACH(g_waypoints, true,
  25         {
  26                 it.colormod = '0.5 0.5 0.5';
  27                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  28         });
  29
  30         entity e2 = navigation_findnearestwaypoint(pl, false);
  31         if(!e2)
  32         {
  33                 LOG_INFOF("Can't find any waypoint nearby\n");
  34                 return;
  35         }
  36
  37         navigation_markroutes(pl, e2);
  38
  39         int j = 0;
  40         int m = 0;
  41         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  42         {
  43                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  44                 it.colormod_z = 8;
  45                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  46                 j++;
  47                 m++;
  48         });
  49         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  50         navigation_markroutes_inverted(e2);
  51
  52         j = 0;
  53         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  54         {
  55                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  56                 it.colormod_x = 8;
  57                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  58                         m++;
  59                 it.effects |= EF_NODEPTHTEST | EF_RED;
  60                 j++;
  61         });
  62         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  63         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  64
  65         j = 0;
  66         IL_EACH(g_spawnpoints, true,
  67         {
  68                 if (navigation_findnearestwaypoint(it, false))
  69                 {
  70                         if(it.spawnpointmodel)
  71                         {
  72                                 delete(it.spawnpointmodel);
  73                                 it.spawnpointmodel = NULL;
  74                         }
  75                 }
  76                 else
  77                 {
  78                         if(!it.spawnpointmodel)
  79                         {
  80                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  81                                 entity e = new(spawnpointmodel);
  82                                 vector org = trace_endpos + eZ;
  83                                 setorigin(e, org);
  84                                 e.solid = SOLID_TRIGGER;
  85                                 it.spawnpointmodel = e;
  86                         }
  87                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  88                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  89                         _setmodel(it.spawnpointmodel, pl.model);
  90                         it.spawnpointmodel.frame = pl.frame;
  91                         it.spawnpointmodel.skin = pl.skin;
  92                         it.spawnpointmodel.colormap = pl.colormap;
  93                         it.spawnpointmodel.colormod = pl.colormod;
  94                         it.spawnpointmodel.glowmod = pl.glowmod;
  95                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  96                         j++;
  97                 }
  98         });
  99         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 100
 101         j = 0;
 102         IL_EACH(g_items, true,
 103         {
 104                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 105                 it.colormod = '0.5 0.5 0.5';
 106         });
 107         IL_EACH(g_items, true,
 108         {
 109                 if (navigation_findnearestwaypoint(it, false))
 110                         continue;
 111                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 112                 it.effects |= EF_NODEPTHTEST | EF_RED;
 113                 it.colormod_x = 8;
 114                 j++;
 115         });
 116         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 117
 118         j = 0;
 119         IL_EACH(g_items, true,
 120         {
 121                 if (navigation_findnearestwaypoint(it, true))
 122                         continue;
 123                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 124                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 125                 it.colormod_z = 8;
 126                 j++;
 127         });
 128         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 129 }
 130
 131 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 132 {
 133         vector new_org = org;
 134         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 135         {
 136                 vector map_center = havocbot_middlepoint;
 137                 if (autocvar_g_waypointeditor_symmetrical == -1)
 138                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 139
 140                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 141         }
 142         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 143         {
 144                 float m = havocbot_symmetryaxis_equation.x;
 145                 float q = havocbot_symmetryaxis_equation.y;
 146                 if (autocvar_g_waypointeditor_symmetrical == -2)
 147                 {
 148                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 149                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 150                 }
 151
 152                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 153                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 154         }
 155         new_org.z = org.z;
 156         return new_org;
 157 }
 158
 159 void waypoint_setupmodel(entity wp)
 160 {
 161         if (autocvar_g_waypointeditor)
 162         {
 163                 // TODO: add some sort of visible box in edit mode for box waypoints
 164                 vector m1 = wp.mins;
 165                 vector m2 = wp.maxs;
 166                 setmodel(wp, MDL_WAYPOINT);
 167                 setsize(wp, m1, m2);
 168                 wp.effects = EF_LOWPRECISION;
 169                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 170                         wp.colormod = '1 0 0';
 171                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 172                         wp.colormod = '1 1 0';
 173                 else if (wp.wphardwired)
 174                         wp.colormod = '0.5 0 1';
 175                 else
 176                         wp.colormod = '1 1 1';
 177         }
 178         else
 179                 wp.model = "";
 180 }
 181
 182 entity waypoint_spawn(vector m1, vector m2, float f)
 183 {
 184         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 185         {
 186                 vector em1 = m1 - '8 8 8';
 187                 vector em2 = m2 + '8 8 8';
 188                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 189                 {
 190                         return it;
 191                 });
 192         }
 193
 194         entity w = new(waypoint);
 195         IL_PUSH(g_waypoints, w);
 196         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 197         w.wpflags = f;
 198         w.solid = SOLID_TRIGGER;
 199         setorigin(w, (m1 + m2) * 0.5);
 200         setsize(w, m1 - w.origin, m2 - w.origin);
 201         if (w.size)
 202                 w.wpisbox = true;
 203
 204         if(!w.wpisbox)
 205         {
 206                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 207                 if(!move_out_of_solid(w))
 208                 {
 209                         if(!(f & WAYPOINTFLAG_GENERATED))
 210                         {
 211                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 212                                 delete(w);
 213                                 return NULL;
 214                         }
 215                         else
 216                         {
 217                                 if(autocvar_developer)
 218                                 {
 219                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 220                                         backtrace("Waypoint stuck");
 221                                 }
 222                         }
 223                 }
 224                 setsize(w, '0 0 0', '0 0 0');
 225         }
 226
 227         waypoint_clearlinks(w);
 228         //waypoint_schedulerelink(w);
 229
 230         waypoint_setupmodel(w);
 231
 232         return w;
 233 }
 234
 235 void waypoint_spawn_fromeditor(entity pl)
 236 {
 237         entity e;
 238         vector org = pl.origin;
 239         int ctf_flags = havocbot_symmetryaxis_equation.z;
 240         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 241                    || (autocvar_g_waypointeditor_symmetrical < 0));
 242         int order = ctf_flags;
 243         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 244         {
 245                 order = autocvar_g_waypointeditor_symmetrical_order;
 246                 ctf_flags = order;
 247         }
 248
 249         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 250         {
 251                 // snap waypoint to item's origin if close enough
 252                 IL_EACH(g_items, true,
 253                 {
 254                         vector item_org = (it.absmin + it.absmax) * 0.5;
 255                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 256                         if(vlen(item_org - org) < 30)
 257                         {
 258                                 org = item_org;
 259                                 break;
 260                         }
 261                 });
 262         }
 263
 264         LABEL(add_wp);
 265         e = waypoint_spawn(org, org, 0);
 266         if(!e)
 267         {
 268                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 269                 return;
 270         }
 271         waypoint_schedulerelink(e);
 272         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 273         if(sym)
 274         {
 275                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 276                 if (vdist(org - pl.origin, >, 32))
 277                 {
 278                         if(order > 2)
 279                                 order--;
 280                         else
 281                                 sym = false;
 282                         goto add_wp;
 283                 }
 284         }
 285 }
 286
 287 void waypoint_remove(entity wp)
 288 {
 289         // tell all waypoints linked to wp that they need to relink
 290         IL_EACH(g_waypoints, it != wp,
 291         {
 292                 if (waypoint_islinked(it, wp))
 293                         waypoint_removelink(it, wp);
 294         });
 295         delete(wp);
 296 }
 297
 298 void waypoint_remove_fromeditor(entity pl)
 299 {
 300         entity e = navigation_findnearestwaypoint(pl, false);
 301
 302         int ctf_flags = havocbot_symmetryaxis_equation.z;
 303         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 304                    || (autocvar_g_waypointeditor_symmetrical < 0));
 305         int order = ctf_flags;
 306         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 307         {
 308                 order = autocvar_g_waypointeditor_symmetrical_order;
 309                 ctf_flags = order;
 310         }
 311
 312         LABEL(remove_wp);
 313         if (!e) return;
 314         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 315
 316         if (e.wphardwired)
 317         {
 318                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 319                 return;
 320         }
 321
 322         entity wp_sym = NULL;
 323         if (sym)
 324         {
 325                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 326                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 327                         if(vdist(org - it.origin, <, 3))
 328                         {
 329                                 wp_sym = it;
 330                                 break;
 331                         }
 332                 });
 333         }
 334
 335         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 336         waypoint_remove(e);
 337
 338         if (sym && wp_sym)
 339         {
 340                 e = wp_sym;
 341                 if(order > 2)
 342                         order--;
 343                 else
 344                         sym = false;
 345                 goto remove_wp;
 346         }
 347 }
 348
 349 void waypoint_removelink(entity from, entity to)
 350 {
 351         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 352                 return;
 353
 354         bool found = false;
 355         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 356         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 357         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 358         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 359         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 360         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 361         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 362         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 363         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 364         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 365         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 366         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 367         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 368         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 369         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 370         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 371         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 372         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 373         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 374         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 375         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 376         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 377         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 378         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 379         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 380         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 381         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 382         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 383         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 384         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 385         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 386         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 387 }
 388
 389 bool waypoint_islinked(entity from, entity to)
 390 {
 391         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 392         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 393         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 394         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 395         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 396         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 397         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 398         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 399         return false;
 400 }
 401
 402 void waypoint_updatecost_foralllinks()
 403 {
 404         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 405         {
 406                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 407                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 408                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 409                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 410                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 411                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 412                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 413                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 414                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 415                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 416                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 417                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 418                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 419                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 420                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 421                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 422                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 423                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 424                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 425                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 426                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 427                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 428                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 429                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 430                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 431                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 432                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 433                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 434                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 435                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 436                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 437                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 438         });
 439 }
 440
 441 float waypoint_getlinearcost(float dist)
 442 {
 443         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 444                 return dist / (autocvar_sv_maxspeed * 1.25);
 445         return dist / autocvar_sv_maxspeed;
 446 }
 447 float waypoint_getlinearcost_underwater(float dist)
 448 {
 449         // NOTE: this value is hardcoded on the engine too, see SV_WaterMove
 450         return dist / (autocvar_sv_maxspeed * 0.7);
 451 }
 452
 453 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 454 {
 455         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 456         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 457
 458         if (submerged_from && submerged_to)
 459                 return waypoint_getlinearcost_underwater(vlen(to - from));
 460
 461         float c = waypoint_getlinearcost(vlen(to - from));
 462
 463         float height = from.z - to.z;
 464         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 465         {
 466                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 467                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 468                 if(height_cost > c)
 469                         c = height_cost;
 470         }
 471
 472         if (submerged_from || submerged_to)
 473                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 474         return c;
 475 }
 476
 477 float waypoint_getlinkcost(entity from, entity to)
 478 {
 479         vector v1 = from.origin;
 480         vector v2 = to.origin;
 481         if (from.wpisbox)
 482         {
 483                 vector m1 = from.absmin, m2 = from.absmax;
 484                 v1.x = bound(m1.x, v2.x, m2.x);
 485                 v1.y = bound(m1.y, v2.y, m2.y);
 486                 v1.z = bound(m1.z, v2.z, m2.z);
 487         }
 488         if (to.wpisbox)
 489         {
 490                 vector m1 = to.absmin, m2 = to.absmax;
 491                 v2.x = bound(m1.x, v1.x, m2.x);
 492                 v2.y = bound(m1.y, v1.y, m2.y);
 493                 v2.z = bound(m1.z, v1.z, m2.z);
 494         }
 495         return waypoint_gettravelcost(v1, v2, from, to);
 496 }
 497
 498 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 499 // if c == -1 automatically determine cost of the link
 500 void waypoint_addlink_customcost(entity from, entity to, float c)
 501 {
 502         if (from == to || waypoint_islinked(from, to))
 503                 return;
 504         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 505                 return;
 506
 507         if(c == -1)
 508                 c = waypoint_getlinkcost(from, to);
 509
 510         if (from.wp31mincost < c) return;
 511         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 512         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 513         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 514         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 515         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 516         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 517         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 518         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 519         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 520         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 521         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 522         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 523         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 524         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 525         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 526         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 527         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 528         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 529         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 530         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 531         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 532         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 533         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 534         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 535         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 536         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 537         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 538         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 539         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 540         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 541         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 542         from.wp00 = to;from.wp00mincost = c;return;
 543 }
 544
 545 void waypoint_addlink(entity from, entity to)
 546 {
 547         waypoint_addlink_customcost(from, to, -1);
 548 }
 549
 550 // relink this spawnfunc_waypoint
 551 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 552 // (SLOW!)
 553 void waypoint_think(entity this)
 554 {
 555         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 556         float sv2_height = 0, ev2_height = 0;
 557
 558         bot_calculate_stepheightvec();
 559
 560         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 561
 562         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 563         IL_EACH(g_waypoints, this != it,
 564         {
 565                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 566                 {
 567                         waypoint_addlink(this, it);
 568                         waypoint_addlink(it, this);
 569                 }
 570                 else
 571                 {
 572                         ++relink_total;
 573                         if(!checkpvs(this.origin, it))
 574                         {
 575                                 ++relink_pvsculled;
 576                                 continue;
 577                         }
 578
 579                         sv = set_tracewalk_dest_2(this, it.origin);
 580                         sv2 = tracewalk_dest;
 581                         sv2_height = tracewalk_dest_height;
 582                         ev = set_tracewalk_dest_2(it, this.origin);
 583                         ev2 = tracewalk_dest;
 584                         ev2_height = tracewalk_dest_height;
 585
 586                         dv = ev - sv;
 587                         dv.z = 0;
 588                         if(vdist(dv, >=, 1050)) // max search distance in XY
 589                         {
 590                                 ++relink_lengthculled;
 591                                 continue;
 592                         }
 593
 594                         navigation_testtracewalk = 0;
 595
 596                         //traceline(this.origin, it.origin, false, NULL);
 597                         //if (trace_fraction == 1)
 598                         if (this.wpisbox)
 599                                 relink_walkculled += 0.5;
 600                         else
 601                         {
 602                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 603                                         waypoint_addlink(this, it);
 604                                 else
 605                                         relink_walkculled += 0.5;
 606                         }
 607
 608                         if (it.wpisbox)
 609                                 relink_walkculled += 0.5;
 610                         else
 611                         {
 612                                 if (tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 613                                         waypoint_addlink(it, this);
 614                                 else
 615                                         relink_walkculled += 0.5;
 616                         }
 617                 }
 618         });
 619         navigation_testtracewalk = 0;
 620         this.wplinked = true;
 621 }
 622
 623 void waypoint_clearlinks(entity wp)
 624 {
 625         // clear links to other waypoints
 626         float f = 10000000;
 627         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 628         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 629         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 630         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 631
 632         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 633         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 634         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 635         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 636
 637         wp.wplinked = false;
 638 }
 639
 640 // tell a spawnfunc_waypoint to relink
 641 void waypoint_schedulerelink(entity wp)
 642 {
 643         if (wp == NULL)
 644                 return;
 645
 646         waypoint_setupmodel(wp);
 647         wp.wpisbox = vdist(wp.size, >, 0);
 648         wp.enemy = NULL;
 649         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 650                 wp.owner = NULL;
 651         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 652                 waypoint_clearlinks(wp);
 653         // schedule an actual relink on next frame
 654         setthink(wp, waypoint_think);
 655         wp.nextthink = time;
 656         wp.effects = EF_LOWPRECISION;
 657 }
 658
 659 // spawnfunc_waypoint map entity
 660 spawnfunc(waypoint)
 661 {
 662         IL_PUSH(g_waypoints, this);
 663
 664         setorigin(this, this.origin);
 665         // schedule a relink after other waypoints have had a chance to spawn
 666         waypoint_clearlinks(this);
 667         //waypoint_schedulerelink(this);
 668 }
 669
 670 // tell all waypoints to relink
 671 // actually this is useful only to update relink_* stats
 672 void waypoint_schedulerelinkall()
 673 {
 674         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 675         IL_EACH(g_waypoints, true,
 676         {
 677                 waypoint_schedulerelink(it);
 678         });
 679         waypoint_load_links_hardwired();
 680 }
 681
 682 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 683
 684 // Load waypoint links from file
 685 bool waypoint_load_links()
 686 {
 687         string s;
 688         float file, tokens, c = 0, found;
 689         entity wp_from = NULL, wp_to;
 690         vector wp_to_pos, wp_from_pos;
 691
 692         string gt_ext = GET_GAMETYPE_EXTENSION();
 693
 694         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 695         file = fopen(filename, FILE_READ);
 696
 697         if (gt_ext != "" && file < 0)
 698         {
 699                 // if race waypoint file doesn't exist load the default one
 700                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 701                 file = fopen(filename, FILE_READ);
 702         }
 703
 704         if (file < 0)
 705         {
 706                 LOG_TRACE("waypoint links load from ", filename, " failed");
 707                 waypoint_schedulerelinkall();
 708                 return false;
 709         }
 710
 711         bool parse_comments = true;
 712         float ver = 0;
 713
 714         while ((s = fgets(file)))
 715         {
 716                 if(parse_comments)
 717                 {
 718                         if(substring(s, 0, 2) == "//")
 719                         {
 720                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 721                                         ver = stof(substring(s, 19, -1));
 722                                 continue;
 723                         }
 724                         else
 725                         {
 726                                 if(ver < WAYPOINT_VERSION)
 727                                 {
 728                                         LOG_TRACE("waypoint links for this map are outdated.");
 729                                         if (g_assault)
 730                                         {
 731                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
 732                                         }
 733                                         else
 734                                         {
 735                                                 LOG_TRACE("automatically updating...");
 736                                                 waypoint_schedulerelinkall();
 737                                                 fclose(file);
 738                                                 return false;
 739                                         }
 740                                 }
 741                                 parse_comments = false;
 742                         }
 743                 }
 744
 745                 tokens = tokenizebyseparator(s, "*");
 746
 747                 if (tokens!=2)
 748                 {
 749                         // bad file format
 750                         fclose(file);
 751                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
 752                         return false;
 753                 }
 754
 755                 wp_from_pos     = stov(argv(0));
 756                 wp_to_pos       = stov(argv(1));
 757
 758                 // Search "from" waypoint
 759                 if(!wp_from || wp_from.origin!=wp_from_pos)
 760                 {
 761                         wp_from = findradius(wp_from_pos, 1);
 762                         found = false;
 763                         while(wp_from)
 764                         {
 765                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 766                                 if(wp_from.classname == "waypoint")
 767                                 {
 768                                         found = true;
 769                                         break;
 770                                 }
 771                                 wp_from = wp_from.chain;
 772                         }
 773
 774                         if(!found)
 775                         {
 776                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 777                                 continue;
 778                         }
 779                 }
 780
 781                 // Search "to" waypoint
 782                 wp_to = findradius(wp_to_pos, 1);
 783                 found = false;
 784                 while(wp_to)
 785                 {
 786                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 787                         if(wp_to.classname == "waypoint")
 788                         {
 789                                 found = true;
 790                                 break;
 791                         }
 792                         wp_to = wp_to.chain;
 793                 }
 794
 795                 if(!found)
 796                 {
 797                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 798                         continue;
 799                 }
 800
 801                 ++c;
 802                 waypoint_addlink(wp_from, wp_to);
 803         }
 804
 805         fclose(file);
 806
 807         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
 808
 809         bool scheduled = false;
 810         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
 811         {
 812                 if (!it.wp00)
 813                 {
 814                         waypoint_schedulerelink(it);
 815                         scheduled = true;
 816                 }
 817         });
 818         if (scheduled)
 819                 return false;
 820
 821         botframe_cachedwaypointlinks = true;
 822         return true;
 823 }
 824
 825 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 826 {
 827         string s;
 828         float file, tokens, c = 0, found;
 829         entity wp_from = NULL, wp_to;
 830         vector wp_to_pos, wp_from_pos;
 831
 832         string gt_ext = GET_GAMETYPE_EXTENSION();
 833
 834         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
 835         file = fopen(filename, FILE_READ);
 836
 837         if (gt_ext != "" && file < 0)
 838         {
 839                 // if race waypoint file doesn't exist load the default one
 840                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
 841                 file = fopen(filename, FILE_READ);
 842         }
 843
 844         botframe_loadedforcedlinks = true;
 845
 846         if (file < 0)
 847         {
 848                 if(!removal_mode)
 849                         LOG_TRACE("waypoint links load from ", filename, " failed");
 850                 return;
 851         }
 852
 853         while ((s = fgets(file)))
 854         {
 855                 if(substring(s, 0, 2)=="//")
 856                         continue;
 857
 858                 if(substring(s, 0, 1)=="#")
 859                         continue;
 860
 861                 tokens = tokenizebyseparator(s, "*");
 862
 863                 if (tokens!=2)
 864                         continue;
 865
 866                 wp_from_pos     = stov(argv(0));
 867                 wp_to_pos       = stov(argv(1));
 868
 869                 // Search "from" waypoint
 870                 if(!wp_from || wp_from.origin!=wp_from_pos)
 871                 {
 872                         wp_from = findradius(wp_from_pos, 5);
 873                         found = false;
 874                         while(wp_from)
 875                         {
 876                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 877                                 if(wp_from.classname == "waypoint")
 878                                 {
 879                                         found = true;
 880                                         break;
 881                                 }
 882                                 wp_from = wp_from.chain;
 883                         }
 884
 885                         if(!found)
 886                         {
 887                                 if(!removal_mode)
 888                                         LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped");
 889                                 continue;
 890                         }
 891                 }
 892
 893                 // Search "to" waypoint
 894                 wp_to = findradius(wp_to_pos, 5);
 895                 found = false;
 896                 while(wp_to)
 897                 {
 898                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 899                         if(wp_to.classname == "waypoint")
 900                         {
 901                                 found = true;
 902                                 break;
 903                         }
 904                         wp_to = wp_to.chain;
 905                 }
 906
 907                 if(!found)
 908                 {
 909                         if(!removal_mode)
 910                                 LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped");
 911                         continue;
 912                 }
 913
 914                 ++c;
 915                 if(removal_mode)
 916                 {
 917                         waypoint_removelink(wp_from, wp_to);
 918                         continue;
 919                 }
 920
 921                 waypoint_addlink(wp_from, wp_to);
 922                 wp_from.wphardwired = true;
 923                 wp_to.wphardwired = true;
 924                 waypoint_setupmodel(wp_from);
 925                 waypoint_setupmodel(wp_to);
 926         }
 927
 928         fclose(file);
 929
 930         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
 931                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 932 }
 933
 934 entity waypoint_get_link(entity w, float i)
 935 {
 936         switch(i)
 937         {
 938                 case  0:return w.wp00;
 939                 case  1:return w.wp01;
 940                 case  2:return w.wp02;
 941                 case  3:return w.wp03;
 942                 case  4:return w.wp04;
 943                 case  5:return w.wp05;
 944                 case  6:return w.wp06;
 945                 case  7:return w.wp07;
 946                 case  8:return w.wp08;
 947                 case  9:return w.wp09;
 948                 case 10:return w.wp10;
 949                 case 11:return w.wp11;
 950                 case 12:return w.wp12;
 951                 case 13:return w.wp13;
 952                 case 14:return w.wp14;
 953                 case 15:return w.wp15;
 954                 case 16:return w.wp16;
 955                 case 17:return w.wp17;
 956                 case 18:return w.wp18;
 957                 case 19:return w.wp19;
 958                 case 20:return w.wp20;
 959                 case 21:return w.wp21;
 960                 case 22:return w.wp22;
 961                 case 23:return w.wp23;
 962                 case 24:return w.wp24;
 963                 case 25:return w.wp25;
 964                 case 26:return w.wp26;
 965                 case 27:return w.wp27;
 966                 case 28:return w.wp28;
 967                 case 29:return w.wp29;
 968                 case 30:return w.wp30;
 969                 case 31:return w.wp31;
 970                 default:return NULL;
 971         }
 972 }
 973
 974 // Save all waypoint links to a file
 975 void waypoint_save_links()
 976 {
 977         // temporarily remove hardwired links so they don't get saved among normal links
 978         waypoint_remove_links_hardwired();
 979
 980         string gt_ext = GET_GAMETYPE_EXTENSION();
 981
 982         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 983         int file = fopen(filename, FILE_WRITE);
 984         if (file < 0)
 985         {
 986                 LOG_INFOF("waypoint link save to %s failed", filename);
 987                 return;
 988         }
 989
 990         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
 991
 992         int c = 0;
 993         IL_EACH(g_waypoints, true,
 994         {
 995                 for(int j = 0; j < 32; ++j)
 996                 {
 997                         entity link = waypoint_get_link(it, j);
 998                         if(link)
 999                         {
1000                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1001                                 fputs(file, s);
1002                                 ++c;
1003                         }
1004                 }
1005         });
1006         fclose(file);
1007
1008         botframe_cachedwaypointlinks = true;
1009
1010         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1011
1012         waypoint_load_links_hardwired();
1013 }
1014
1015 // save waypoints to gamedir/data/maps/mapname.waypoints
1016 void waypoint_saveall()
1017 {
1018         string gt_ext = GET_GAMETYPE_EXTENSION();
1019
1020         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1021         int file = fopen(filename, FILE_WRITE);
1022         if (file < 0)
1023         {
1024                 waypoint_save_links(); // save anyway?
1025                 botframe_loadedforcedlinks = false;
1026
1027                 LOG_INFOF("waypoint links: save to %s failed", filename);
1028                 return;
1029         }
1030
1031         float sym = autocvar_g_waypointeditor_symmetrical;
1032         string sym_str = ftos(sym);
1033         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1034         {
1035                 if (sym == 1)
1036                 {
1037                         sym_str = cons(sym_str, "-");
1038                         sym_str = cons(sym_str, "-");
1039                 }
1040                 else
1041                 {
1042                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1043                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1044                 }
1045                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1046                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1047         }
1048         else if (autocvar_g_waypointeditor_symmetrical == -2)
1049         {
1050                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1051                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1052         }
1053
1054         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1055         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1056         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1057         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1058         fputs(file, strcat("//", "\n"));
1059
1060         int c = 0;
1061         IL_EACH(g_waypoints, true,
1062         {
1063                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1064                         continue;
1065
1066                 string s;
1067                 s = strcat(vtos(it.origin + it.mins), "\n");
1068                 s = strcat(s, vtos(it.origin + it.maxs));
1069                 s = strcat(s, "\n");
1070                 s = strcat(s, ftos(it.wpflags));
1071                 s = strcat(s, "\n");
1072                 fputs(file, s);
1073                 c++;
1074         });
1075         fclose(file);
1076         waypoint_save_links();
1077         botframe_loadedforcedlinks = false;
1078
1079         LOG_INFOF("saved %d waypoints to %s", c, filename);
1080 }
1081
1082 // load waypoints from file
1083 float waypoint_loadall()
1084 {
1085         string s;
1086         float file, cwp, cwb, fl;
1087         vector m1, m2;
1088         cwp = 0;
1089         cwb = 0;
1090
1091         string gt_ext = GET_GAMETYPE_EXTENSION();
1092
1093         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1094         file = fopen(filename, FILE_READ);
1095
1096         if (gt_ext != "" && file < 0)
1097         {
1098                 // if race waypoint file doesn't exist load the default one
1099                 filename = sprintf("maps/%s.waypoints", mapname);
1100                 file = fopen(filename, FILE_READ);
1101         }
1102
1103         if (file < 0)
1104         {
1105                 LOG_TRACE("waypoint load from ", filename, " failed");
1106                 return 0;
1107         }
1108
1109         bool parse_comments = true;
1110         float ver = 0;
1111         float sym = 0;
1112         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1113
1114         while ((s = fgets(file)))
1115         {
1116                 if(parse_comments)
1117                 {
1118                         if(substring(s, 0, 2) == "//")
1119                         {
1120                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1121                                         ver = stof(substring(s, 19, -1));
1122                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1123                                 {
1124                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1125                                         if (tokens) { sym = stof(argv(0)); }
1126                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1127                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1128                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1129                                 }
1130                                 continue;
1131                         }
1132                         else
1133                         {
1134                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1135                                 {
1136                                         LOG_TRACE("waypoints for this map are outdated");
1137                                         LOG_TRACE("please update them in the editor");
1138                                 }
1139                                 parse_comments = false;
1140                         }
1141                 }
1142                 m1 = stov(s);
1143                 s = fgets(file);
1144                 if (!s)
1145                         break;
1146                 m2 = stov(s);
1147                 s = fgets(file);
1148                 if (!s)
1149                         break;
1150                 fl = stof(s);
1151                 waypoint_spawn(m1, m2, fl);
1152                 if (m1 == m2)
1153                         cwp = cwp + 1;
1154                 else
1155                         cwb = cwb + 1;
1156         }
1157         fclose(file);
1158         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1159
1160         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1161         {
1162                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1163                 if (sym == 1 && sym_param3 < 2)
1164                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1165                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1166                 {
1167                         string params;
1168                         if (sym == 1)
1169                                 params = cons("-", "-");
1170                         else
1171                         {
1172                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1173                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1174                         }
1175                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1176                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1177                 }
1178                 else if (sym == -2)
1179                 {
1180                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1181                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1182                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1183                 }
1184                 else
1185                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1186                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1187         }
1188
1189         return cwp + cwb;
1190 }
1191
1192 #define waypoint_fixorigin(position, tracetest_ent) \
1193         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1194
1195 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1196 {
1197         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1198         if(trace_startsolid)
1199                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1200         if(trace_startsolid)
1201                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1202         if(trace_fraction < 1)
1203                 position = trace_endpos;
1204         return position;
1205 }
1206
1207 void waypoint_spawnforitem_force(entity e, vector org)
1208 {
1209         // Fix the waypoint altitude if necessary
1210         org = waypoint_fixorigin(org, NULL);
1211
1212         // don't spawn an item spawnfunc_waypoint if it already exists
1213         IL_EACH(g_waypoints, true,
1214         {
1215                 if(it.wpisbox)
1216                 {
1217                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1218                         {
1219                                 e.nearestwaypoint = it;
1220                                 return;
1221                         }
1222                 }
1223                 else
1224                 {
1225                         if(vdist(it.origin - org, <, 16))
1226                         {
1227                                 e.nearestwaypoint = it;
1228                                 return;
1229                         }
1230                 }
1231         });
1232
1233         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1234 }
1235
1236 void waypoint_spawnforitem(entity e)
1237 {
1238         if(!bot_waypoints_for_items)
1239                 return;
1240
1241         waypoint_spawnforitem_force(e, e.origin);
1242 }
1243
1244 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1245 {
1246         entity w;
1247         entity dw;
1248         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1249         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1250         // one way link to the destination
1251         w.wp00 = dw;
1252         w.wp00mincost = timetaken; // this is just for jump pads
1253         // the teleporter's nearest spawnfunc_waypoint is this one
1254         // (teleporters are not goals, so this is probably useless)
1255         e.nearestwaypoint = w;
1256         e.nearestwaypointtimeout = -1;
1257 }
1258
1259 void waypoint_spawnforteleporter_wz(entity e, vector org, vector destination, float timetaken, vector down_dir, entity tracetest_ent)
1260 {
1261         // warpzones with oblique warp plane rely on down_dir to snap waypoints
1262         // to the ground without leaving the warp plane
1263         // warpzones with horizontal warp plane (down_dir.x == -1) generate
1264         // destination waypoint snapped to the ground (leaving warpzone), source
1265         // waypoint in the center of the warp plane
1266         if(down_dir.x != -1)
1267                 org = waypoint_fixorigin_down_dir(org, tracetest_ent, down_dir);
1268         if(down_dir.x == -1)
1269                 down_dir = '0 0 -1';
1270         destination = waypoint_fixorigin_down_dir(destination, tracetest_ent, down_dir);
1271         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1272 }
1273
1274 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1275 {
1276         destination = waypoint_fixorigin(destination, tracetest_ent);
1277         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1278 }
1279
1280 entity waypoint_spawnpersonal(entity this, vector position)
1281 {
1282         entity w;
1283
1284         // drop the waypoint to a proper location:
1285         //   first move it up by a player height
1286         //   then move it down to hit the floor with player bbox size
1287         position = waypoint_fixorigin(position, this);
1288
1289         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1290         w.nearestwaypoint = NULL;
1291         w.nearestwaypointtimeout = 0;
1292         w.owner = this;
1293
1294         waypoint_schedulerelink(w);
1295
1296         return w;
1297 }
1298
1299 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1300 {
1301         if (!(wp1 && wp2))
1302                 return;
1303
1304         if (wp1.wphardwired && wp2.wphardwired)
1305                 te_beam(NULL, wp1.origin, wp2.origin);
1306         else if (display_type == 1)
1307                 te_lightning2(NULL, wp1.origin, wp2.origin);
1308 }
1309
1310 void waypoint_showlinks_to(entity wp, int display_type)
1311 {
1312         IL_EACH(g_waypoints, it != wp,
1313         {
1314                 if (waypoint_islinked(it, wp))
1315                         waypoint_showlink(it, wp, display_type);
1316         });
1317 }
1318
1319 void waypoint_showlinks_from(entity wp, int display_type)
1320 {
1321         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1322         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1323         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1324         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1325         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1326         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1327         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1328         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1329         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1330         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1331         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1332         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1333         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1334         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1335         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1336         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1337 }
1338
1339 void botframe_showwaypointlinks()
1340 {
1341         if (time < botframe_waypointeditorlightningtime)
1342                 return;
1343         botframe_waypointeditorlightningtime = time + 0.5;
1344         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1345         {
1346                 int display_type = 0;
1347                 entity head = navigation_findnearestwaypoint(it, false);
1348                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1349                         display_type = 1; // default
1350                 else if(head && (head.wphardwired))
1351                         display_type = 2; // only hardwired
1352
1353                 if (display_type)
1354                 {
1355                         //navigation_testtracewalk = true;
1356                         //print("currently selected WP is ", etos(head), "\n");
1357                         //navigation_testtracewalk = false;
1358                         if (head)
1359                         {
1360                                 te_lightning2(NULL, head.origin, it.origin);
1361                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1362                                         waypoint_showlinks_to(head, display_type);
1363                                 else
1364                                         waypoint_showlinks_from(head, display_type);
1365                         }
1366                 }
1367         });
1368 }
1369
1370 float botframe_autowaypoints_fixdown(vector v)
1371 {
1372         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1373         if(trace_fraction >= 1)
1374                 return 0;
1375         return 1;
1376 }
1377
1378 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1379 {
1380         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1381         {
1382                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1383                 return 0;
1384         });
1385
1386         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1387         return 1;
1388 }
1389
1390 // return value:
1391 //    1 = WP created
1392 //    0 = no action needed
1393 //   -1 = temp fail, try from world too
1394 //   -2 = permanent fail, do not retry
1395 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1396 {
1397         // make it possible to go from p to wp, if we can
1398         // if wp is NULL, nearest is chosen
1399
1400         entity w;
1401         vector porg;
1402         float t, tmin, tmax;
1403         vector o;
1404         vector save;
1405
1406         if(!botframe_autowaypoints_fixdown(p.origin))
1407                 return -2;
1408         porg = trace_endpos;
1409
1410         if(wp)
1411         {
1412                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1413
1414                 // if wp -> porg, then OK
1415                 float maxdist;
1416                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1417                 {
1418                         // we may find a better one
1419                         maxdist = vlen(wp.origin - porg);
1420                 }
1421                 else
1422                 {
1423                         // accept any "good"
1424                         maxdist = 2100;
1425                 }
1426
1427                 float bestdist = maxdist;
1428                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1429                 {
1430                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1431                         if(d < bestdist)
1432                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1433                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1434                         {
1435                                 bestdist = d;
1436                                 p.(fld) = it;
1437                         }
1438                 });
1439                 if(bestdist < maxdist)
1440                 {
1441                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1442                         return 0;
1443                 }
1444
1445                 if(bestdist < 2100)
1446                 {
1447                         // we know maxdist < 2100
1448                         // so wp -> porg is still valid
1449                         // all is good
1450                         p.(fld) = wp;
1451                         return 0;
1452                 }
1453
1454                 // otherwise, no existing WP can fix our issues
1455         }
1456         else
1457         {
1458                 save = p.origin;
1459                 setorigin(p, porg);
1460                 w = navigation_findnearestwaypoint(p, walkfromwp);
1461                 setorigin(p, save);
1462                 if(w)
1463                 {
1464                         p.(fld) = w;
1465                         return 0;
1466                 }
1467         }
1468
1469         tmin = 0;
1470         tmax = 1;
1471         for (;;)
1472         {
1473                 if(tmax - tmin < 0.001)
1474                 {
1475                         // did not get a good candidate
1476                         return -1;
1477                 }
1478
1479                 t = (tmin + tmax) * 0.5;
1480                 o = antilag_takebackorigin(p, CS(p), time - t);
1481                 if(!botframe_autowaypoints_fixdown(o))
1482                         return -2;
1483                 o = trace_endpos;
1484
1485                 if(wp)
1486                 {
1487                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1488                         {
1489                                 // we cannot walk from wp.origin to o
1490                                 // get closer to tmax
1491                                 tmin = t;
1492                                 continue;
1493                         }
1494                 }
1495                 else
1496                 {
1497                         save = p.origin;
1498                         setorigin(p, o);
1499                         w = navigation_findnearestwaypoint(p, walkfromwp);
1500                         setorigin(p, save);
1501                         if(!w)
1502                         {
1503                                 // we cannot walk from any WP to o
1504                                 // get closer to tmax
1505                                 tmin = t;
1506                                 continue;
1507                         }
1508                 }
1509
1510                 // if we get here, o is valid regarding waypoints
1511                 // check if o is connected right to the player
1512                 // we break if it succeeds, as that means o is a good waypoint location
1513                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1514                         break;
1515
1516                 // o is no good, we need to get closer to the player
1517                 tmax = t;
1518         }
1519
1520         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1521         botframe_autowaypoints_createwp(o, p, fld, 0);
1522         return 1;
1523 }
1524
1525 // automatically create missing waypoints
1526 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1527 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1528 {
1529         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1530         if(r != -1)
1531                 return;
1532         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1533         if(r != -1)
1534                 return;
1535
1536         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1537         if(!botframe_autowaypoints_fixdown(p.origin))
1538                 return; // shouldn't happen, caught above
1539         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1540 }
1541
1542 void botframe_deleteuselesswaypoints()
1543 {
1544         IL_EACH(g_items, it.bot_pickup,
1545         {
1546                 // NOTE: this protects waypoints if they're the ONLY nearest
1547                 // waypoint. That's the intention.
1548                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1549                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1550         });
1551         IL_EACH(g_waypoints, true,
1552         {
1553                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1554                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1555                 // WP is useful if:
1556                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1557                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1558                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1559                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1560                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1561                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1562                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1563                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1564                 // b) WP is closest WP for an item/spawnpoint/other entity
1565                 //    This has been done above by protecting these WPs.
1566         });
1567         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1568         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1569         {
1570                 for (int m = 0; m < 32; ++m)
1571                 {
1572                         entity w = waypoint_get_link(it, m);
1573                         if (!w)
1574                                 break;
1575                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1576                                 continue;
1577                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1578                                 continue;
1579                         for (int j = 0; j < 32; ++j)
1580                         {
1581                                 entity w2 = waypoint_get_link(w, j);
1582                                 if (!w2)
1583                                         break;
1584                                 if (it == w2)
1585                                         continue;
1586                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1587                                         continue;
1588                                 // If we got here, it != w2 exist with it -> w
1589                                 // and w -> w2. That means the waypoint is not
1590                                 // a dead end.
1591                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1592                                 for (int k = 0; k < 32; ++k)
1593                                 {
1594                                         if (waypoint_get_link(it, k) == w2)
1595                                                 continue;
1596                                         // IF WE GET HERE, w is proven useful
1597                                         // to get from it to w2!
1598                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1599                                         goto next;
1600                                 }
1601                         }
1602 LABEL(next)
1603                 }
1604         });
1605         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1606         //     they are needed to complete routes while autowaypointing.
1607
1608         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1609         {
1610                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1611                 te_explosion(it.origin);
1612                 waypoint_remove(it);
1613                 break;
1614         });
1615
1616         IL_EACH(g_waypoints, true,
1617         {
1618                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1619         });
1620 }
1621
1622 void botframe_autowaypoints()
1623 {
1624         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1625                 // going back is broken, so only fix waypoints to walk TO the player
1626                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1627                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1628                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1629         });
1630
1631         if (autocvar_g_waypointeditor_auto >= 2) {
1632                 botframe_deleteuselesswaypoints();
1633         }
1634 }
1635